data/qcsrc/server/keyhunt.qc

   1 string STR_ITEM_KH_KEY = "item_kh_key";
   2 #define FOR_EACH_KH_KEY(v) for(v = world; (v = find(v, classname, STR_ITEM_KH_KEY)); )
   3
   4 typedef void(void) kh_Think_t;
   5 var kh_Think_t kh_Controller_Thinkfunc;
   6 string kh_Controller_Waitmsg;
   7
   8 float kh_Team_ByID(float t)
   9 {
  10         if(t == 0) return COLOR_TEAM1;
  11         if(t == 1) return COLOR_TEAM2;
  12         if(t == 2) return COLOR_TEAM3;
  13         if(t == 3) return COLOR_TEAM4;
  14         return 0;
  15 }
  16
  17 entity kh_controller;
  18 float kh_tracking_enabled;
  19 float kh_teams;
  20 float kh_interferemsg_time, kh_interferemsg_team;
  21 .entity kh_next, kh_prev; // linked list
  22 .float kh_droptime;
  23
  24 string kh_sound_capture = "sound/ctf/capture.wav";
  25 string kh_sound_destroy = "sound/ctf/return.wav";
  26 string kh_sound_drop = "sound/misc/mouseclick.wav";
  27 string kh_sound_collect = "sound/ctf/take.wav";
  28
  29 float kh_sprite_dropped, kh_sprite_finish, kh_sprite_red, kh_sprite_blue, kh_sprite_pink, kh_sprite_yellow, kh_sprite_friend;
  30
  31 float kh_GetCarrierSprite(float t, float e)
  32 {
  33         if(t == e)           return kh_sprite_friend;
  34         if(t == COLOR_TEAM1) return kh_sprite_red;
  35         if(t == COLOR_TEAM2) return kh_sprite_blue;
  36         if(t == COLOR_TEAM3) return kh_sprite_yellow;
  37         if(t == COLOR_TEAM4) return kh_sprite_pink;
  38         return 0;
  39 }
  40
  41 void kh_Controller_SetThink(float t, string msg, kh_Think_t func)
  42 {
  43         kh_Controller_Thinkfunc = func;
  44         kh_controller.cnt = t;
  45         if(kh_Controller_Waitmsg != "")
  46                 strunzone(kh_Controller_Waitmsg);
  47         if(msg == "")
  48                 kh_Controller_Waitmsg = "";
  49         else
  50                 kh_Controller_Waitmsg = strzone(msg);
  51         if(t == 0)
  52                 kh_controller.nextthink = time; // force
  53 }
  54
  55 void kh_Controller_Think()
  56 {
  57         entity e;
  58         if(intermission_running)
  59                 return;
  60         if(self.cnt > 0)
  61         {
  62                 if(kh_Controller_Waitmsg != "")
  63                 {
  64                         string s;
  65                         if(substring(kh_Controller_Waitmsg, strlen(kh_Controller_Waitmsg)-1, 1) == " ")
  66                                 s = strcat(kh_Controller_Waitmsg, ftos(self.cnt));
  67                         else
  68                                 s = kh_Controller_Waitmsg;
  69
  70                         dprint(s, "\n");
  71
  72                         FOR_EACH_PLAYER(e)
  73                                 if(clienttype(e) == CLIENTTYPE_REAL)
  74                                         centerprint_atprio(e, CENTERPRIO_SPAM, s);
  75                 }
  76                 self.cnt -= 1;
  77         }
  78         else if(self.cnt == 0)
  79         {
  80                 self.cnt -= 1;
  81                 kh_Controller_Thinkfunc();
  82         }
  83         self.nextthink = time + 1;
  84 }
  85
  86 // frags f: take from cvar * f
  87 // frags 0: no frags
  88 void kh_Scores_Event(entity player, entity key, string what, float frags_player, float frags_owner)
  89 {
  90         string s;
  91         if(frags_player)
  92                 player.frags = player.frags + floor(0.5 + frags_player);
  93         if(frags_owner)
  94                 key.owner.frags = key.owner.frags + floor(0.5 + frags_owner);
  95         if(!cvar("sv_eventlog"))
  96                 return;
  97         s = strcat(":keyhunt:", what, ":", ftos(player.playerid));
  98         s = strcat(s, ":", ftos(frags_player));
  99         if(key && key.owner)
 100                 s = strcat(s, ":", ftos(key.owner.playerid));
 101         else
 102                 s = strcat(s, ":0");
 103         s = strcat(s, ":", ftos(frags_owner), ":");
 104         if(key)
 105                 s = strcat(s, key.netname);
 106         GameLogEcho(s, FALSE);
 107 }
 108
 109 void kh_Key_Attach(entity key)
 110 {
 111         setattachment(key, key.owner, "");
 112         setorigin(key, '0 0 -15'); // x/y fixed later in think, z has to be -15 to make the key fit even in the crouchbox
 113         key.angles_y -= key.owner.angles_y;
 114         key.flags = 0;
 115         key.solid = SOLID_NOT;
 116         key.movetype = MOVETYPE_NONE;
 117         key.team = key.owner.team;
 118         key.nextthink = time;
 119         key.damageforcescale = 0;
 120 }
 121
 122 vector kh_AttachedOrigin(entity e)
 123 {
 124         if(e.tag_entity)
 125         {
 126                 makevectors(e.tag_entity.angles);
 127                 return e.tag_entity.origin + e.origin_x * v_forward - e.origin_y * v_right + e.origin_z * v_up;
 128         }
 129         else
 130                 return e.origin;
 131 }
 132
 133 void kh_Key_Detach(entity key)
 134 {
 135         setorigin(key, key.owner.origin + key.origin_z * '0 0 1');
 136         setattachment(key, world, "");
 137         key.angles_y += key.owner.angles_y;
 138         key.aiment = world;
 139         key.flags = FL_ITEM;
 140         key.solid = SOLID_TRIGGER;
 141         key.movetype = MOVETYPE_TOSS;
 142         key.pain_finished = time + cvar("g_balance_keyhunt_delay_return");
 143         key.damageforcescale = cvar("g_balance_keyhunt_damageforcescale");
 144         // let key.team stay
 145 }
 146
 147 void kh_Key_AssignTo(entity key, entity player)
 148 {
 149         if(key.owner == player)
 150                 return;
 151
 152         if(key.owner)
 153         {
 154                 kh_Key_Detach(key);
 155
 156                 // remove from linked list
 157                 if(key.kh_next)
 158                         key.kh_next.kh_prev = key.kh_prev;
 159                 key.kh_prev.kh_next = key.kh_next;
 160                 key.kh_next = world;
 161                 key.kh_prev = world;
 162
 163                 if(key.owner.kh_next == world)
 164                 {
 165                         // No longer a key carrier
 166                         WaypointSprite_DetachCarrier(key.owner);
 167                 }
 168         }
 169
 170         key.owner = player;
 171
 172         if(player)
 173         {
 174                 // insert into linked list
 175                 key.kh_next = player.kh_next;
 176                 key.kh_prev = player;
 177                 player.kh_next = key;
 178                 if(key.kh_next)
 179                         key.kh_next.kh_prev = key;
 180
 181                 kh_Key_Attach(key);
 182
 183                 if(key.kh_next == world)
 184                 {
 185                         // player is now a key carrier
 186                         WaypointSprite_AttachCarrier("", player);
 187                         player.waypointsprite_attachedforcarrier.waypointsprite_for_player = kh_KeyCarrier_waypointsprite_for_player;
 188                         player.waypointsprite_attachedforcarrier.team = player.team;
 189                 }
 190         }
 191
 192         key.pusher = world;
 193 }
 194
 195 void kh_Key_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 196 {
 197         if(self.owner)
 198                 return;
 199         if(vlen(force) <= 0)
 200                 return;
 201         if(time > self.pushltime)
 202                 if(attacker.classname == "player")
 203                         self.team = attacker.team;
 204 }
 205
 206 void kh_Key_Spawn(entity initial_owner, float angle)
 207 {
 208         entity key;
 209         key = spawn();
 210         key.classname = STR_ITEM_KH_KEY;
 211         key.touch = kh_Key_Touch;
 212         key.think = kh_Key_Think;
 213         key.nextthink = time;
 214         key.items = IT_KEY1 | IT_KEY2;
 215         key.cnt = angle;
 216         key.angles = '0 360 0' * random();
 217         key.event_damage = kh_Key_Damage;
 218         setmodel(key, "models/keyhunt/key.md3");
 219         setsize(key, '-8 -8 -8', '8 8 40');
 220
 221         switch(initial_owner.team)
 222         {
 223                 case COLOR_TEAM1:
 224                         key.netname = "^1red key";
 225                         key.colormod = '103 0 0' * (1/96);
 226                         break;
 227                 case COLOR_TEAM2:
 228                         key.netname = "^4blue key";
 229                         key.colormod = '35 35 191' * (1/96);
 230                         break;
 231                 case COLOR_TEAM3:
 232                         key.netname = "^3yellow key";
 233                         key.colormod = '187 167 15' * (1/96);
 234                         break;
 235                 case COLOR_TEAM4:
 236                         key.netname = "^6pink key";
 237                         key.colormod = '139 79 107' * (1/96);
 238                         break;
 239                 default:
 240                         key.netname = "NETGIER key";
 241                         key.colormod = '1 1 1';
 242                         break;
 243         }
 244
 245         sprint(initial_owner, strcat("You got the ^2", key.netname, "\n"));
 246
 247         WaypointSprite_AttachCarrier("", key);
 248         key.waypointsprite_attachedforcarrier.waypointsprite_for_player = kh_Key_waypointsprite_for_player;
 249
 250         kh_Key_AssignTo(key, initial_owner);
 251 }
 252
 253 void kh_Key_Remove(entity key)
 254 {
 255         entity o;
 256         o = key.owner;
 257         kh_Key_AssignTo(key, world);
 258         if(o) // it was attached
 259                 WaypointSprite_Kill(key.waypointsprite_attachedforcarrier);
 260         else // it was dropped
 261                 WaypointSprite_DetachCarrier(key);
 262
 263         remove(key);
 264 }
 265
 266 // -1 when no team completely owns all keys yet
 267 float kh_Key_AllOwnedByWhichTeam()
 268 {
 269         entity key;
 270         float teem;
 271
 272         teem = -1;
 273         FOR_EACH_KH_KEY(key)
 274         {
 275                 if(!key.owner)
 276                         return -1;
 277                 if(teem == -1)
 278                         teem = key.team;
 279                 else if(teem != key.team)
 280                         return -1;
 281         }
 282         return teem;
 283 }
 284
 285 void kh_Key_Collect(entity key, entity player)
 286 {
 287         sound(key, CHAN_AUTO, kh_sound_collect, 1, ATTN_NORM);
 288
 289         kh_Scores_Event(player, key, "collect", cvar("g_balance_keyhunt_score_collect"), 0);
 290         bprint(player.netname, "^7 collected the ", key.netname, "\n");
 291         kh_Key_AssignTo(key, player);
 292
 293         if(kh_Key_AllOwnedByWhichTeam() != -1)
 294         {
 295                 kh_interferemsg_time = time + 0.2;
 296                 kh_interferemsg_team = player.team;
 297         }
 298 }
 299
 300 void kh_Key_DropAll(entity player)
 301 {
 302         entity key;
 303         entity mypusher;
 304         if(player.kh_next)
 305         {
 306                 mypusher = world;
 307                 if(player.pusher)
 308                         if(time < player.pushltime)
 309                                 mypusher = player.pusher;
 310                 while((key = player.kh_next))
 311                 {
 312                         kh_Scores_Event(player, key, "losekey", 0, 0);
 313                         bprint(player.netname, "^7 lost the ", key.netname, "\n");
 314                         kh_Key_AssignTo(key, world);
 315                         makevectors('-1 0 0' * (45 + 45 * random()) + '0 360 0' * random());
 316                         key.velocity = W_CalculateProjectileVelocity(player.velocity, cvar("g_balance_keyhunt_dropvelocity") * v_forward);
 317                         key.pusher = mypusher;
 318                         key.pushltime = time + cvar("g_balance_keyhunt_protecttime");
 319                 }
 320                 sound(player, CHAN_AUTO, kh_sound_drop, 1, ATTN_NORM);
 321         }
 322 }
 323
 324 void kh_Key_Touch()
 325 {
 326         if(self.owner) // already carried
 327                 return;
 328         if(other.classname != "player")
 329                 return;
 330         if(other.deadflag != DEAD_NO)
 331                 return;
 332         if(other == self.enemy)
 333                 if(time < self.kh_droptime + cvar("g_balance_keyhunt_delay_collect"))
 334                         return; // you just dropped it!
 335         kh_Key_Collect(self, other);
 336 }
 337
 338 void kh_Key_Think()
 339 {
 340         entity head;
 341
 342         //self.angles_y = math_mod(self.angles_y + 0.05 * 135, 360);
 343         // model is EF_ROTATING now
 344
 345         if(self.owner)
 346         {
 347                 makevectors('0 1 0' * (self.cnt + math_mod(time, 360) * 45));
 348                 setorigin(self, v_forward * 24 + '0 0 1' * self.origin_z);
 349
 350                 if(self.owner.buttonuse)
 351                 if(time >= self.owner.kh_droptime + cvar("g_balance_keyhunt_delay_drop"))
 352                 {
 353                         self.owner.kh_droptime = time;
 354                         self.kh_droptime = time; // prevent collecting this one for some time
 355                         self.enemy = self.owner;
 356                         self.pusher = world;
 357                         kh_Scores_Event(self.owner, self, "dropkey", 0, 0);
 358                         bprint(self.owner.netname, "^7 dropped the ", self.netname, "\n");
 359                         sound(self.owner, CHAN_AUTO, kh_sound_drop, 1, ATTN_NORM);
 360                         makevectors(self.owner.v_angle);
 361                         self.velocity = W_CalculateProjectileVelocity(self.owner.velocity, cvar("g_balance_keyhunt_throwvelocity") * v_forward);
 362                         kh_Key_AssignTo(self, world);
 363                         self.pushltime = time + cvar("g_balance_keyhunt_protecttime");
 364                 }
 365         }
 366
 367         // if in nodrop or time over, end the round
 368         if(!self.owner)
 369                 if(time > self.pain_finished)
 370                         kh_LoserTeam(self.team, self);
 371
 372         if(self.owner)
 373         if(kh_Key_AllOwnedByWhichTeam() != -1)
 374         {
 375                 entity key;
 376                 vector p;
 377                 p = self.owner.origin;
 378                 FOR_EACH_KH_KEY(key)
 379                         if(vlen(key.owner.origin - p) > cvar("g_balance_keyhunt_maxdist"))
 380                                 goto not_winning;
 381                 kh_WinnerTeam(self.team);
 382 :not_winning
 383         }
 384
 385         if(kh_interferemsg_time && time > kh_interferemsg_time)
 386         {
 387                 kh_interferemsg_time = 0;
 388                 FOR_EACH_PLAYER(head)
 389                 {
 390                         if(head.team == kh_interferemsg_team)
 391                                 if(head.kh_next)
 392                                         centerprint(head, "All keys are in your team's hands!\n\nMeet the other key carriers ^1NOW^7!\n");
 393                                 else
 394                                         centerprint(head, "All keys are in your team's hands!\n\nHelp the key carriers to meet!\n");
 395                         else
 396                                 centerprint(head, "All keys are in the enemy's hands!\n\nInterfere ^1NOW^7!\n");
 397                 }
 398         }
 399
 400         self.nextthink = time + 0.05;
 401 }
 402
 403 void kh_WinnerTeam(float teem)
 404 {
 405         // all key carriers get some points
 406         vector firstorigin, lastorigin;
 407         float first;
 408         entity key;
 409         float score;
 410         score = (kh_teams - 1) * cvar("g_balance_keyhunt_score_capture");
 411         DistributeEvenly_Init(score, kh_teams);
 412         // twice the score for 3 team games, three times the score for 4 team games!
 413         // note: for a win by destroying the key, this should NOT be applied
 414         first = TRUE;
 415         FOR_EACH_KH_KEY(key)
 416         {
 417                 kh_Scores_Event(key.owner, key, "capture", DistributeEvenly_Get(1), 0);
 418                 if(key.owner.kh_next == key)
 419                 {
 420                         if(!first)
 421                                 bprint("^7, ");
 422                         bprint(key.owner.netname);
 423                         first = FALSE;
 424                 }
 425         }
 426
 427         first = TRUE;
 428         FOR_EACH_KH_KEY(key)
 429         {
 430                 vector thisorigin;
 431
 432                 thisorigin = kh_AttachedOrigin(key);
 433
 434                 if(!first)
 435                         te_lightning2(world, lastorigin, thisorigin);
 436                 lastorigin = thisorigin;
 437                 if(first)
 438                         firstorigin = thisorigin;
 439                 first = FALSE;
 440         }
 441         if(kh_teams > 2)
 442         {
 443                 te_lightning2(world, lastorigin, firstorigin);
 444         }
 445
 446         bprint("^7 captured the keys for the ", ColoredTeamName(teem), "\n");
 447         sound(world, CHAN_AUTO, kh_sound_capture, 1, ATTN_NONE);
 448         kh_FinishRound();
 449 }
 450
 451 void kh_LoserTeam(float teem, entity lostkey)
 452 {
 453         entity player, key, attacker;
 454         float players;
 455         float keys;
 456
 457         attacker = world;
 458         if(lostkey.pusher)
 459                 if(lostkey.pusher.team != teem)
 460                         if(lostkey.pusher.classname == "player")
 461                                 attacker = lostkey.pusher;
 462
 463         players = keys = 0;
 464
 465         if(attacker)
 466         {
 467                 kh_Scores_Event(attacker, world, "push", 1, 0);
 468                 centerprint(attacker, "Your push is the best!\n\n\n");
 469                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "\n");
 470         }
 471         else
 472         {
 473                 float of, fragsleft, i, thisteam;
 474                 of = cvar("g_balance_keyhunt_score_destroyed_ownfactor");
 475
 476                 FOR_EACH_PLAYER(player)
 477                         if(player.team != teem)
 478                                 ++players;
 479
 480                 FOR_EACH_KH_KEY(key)
 481                         if(key.owner && key.team != teem)
 482                                 ++keys;
 483
 484                 DistributeEvenly_Init(cvar("g_balance_keyhunt_score_destroyed"), keys * of + players);
 485
 486                 FOR_EACH_KH_KEY(key)
 487                         if(key.owner && key.team != teem)
 488                                 kh_Scores_Event(key.owner, world, "destroyed_holdingkey", DistributeEvenly_Get(of), 0);
 489
 490                 fragsleft = DistributeEvenly_Get(players);
 491
 492                 // Now distribute these among all other teams...
 493                 for(i = 0; i < kh_teams; ++i)
 494                 {
 495                         thisteam = kh_Team_ByID(i);
 496                         players = 0;
 497                         FOR_EACH_PLAYER(player)
 498                                 if(player.team == thisteam)
 499                                         ++players;
 500
 501                         DistributeEvenly_Init(fragsleft, kh_teams - i);
 502                         fragsleft = DistributeEvenly_Get(kh_teams - i - 1);
 503                         DistributeEvenly_Init(DistributeEvenly_Get(1), players);
 504
 505                         FOR_EACH_PLAYER(player)
 506                                 if(player.team == thisteam)
 507                                         kh_Scores_Event(player, world, "destroyed", DistributeEvenly_Get(1), 0);
 508                 }
 509
 510                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "\n");
 511         }
 512         sound(world, CHAN_AUTO, kh_sound_destroy, 1, ATTN_NONE);
 513
 514         kh_FinishRound();
 515 }
 516
 517 void kh_FinishRound()
 518 {
 519         // prepare next round
 520         kh_interferemsg_time = 0;
 521         entity key;
 522         FOR_EACH_KH_KEY(key)
 523                 kh_Key_Remove(key);
 524
 525         kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_round"), "Round starts in ", kh_StartRound);
 526 }
 527
 528 float kh_EnoughPlayers()
 529 {
 530         float i, players, teem;
 531         entity player;
 532
 533         // find a random player per team
 534         for(i = 0; i < kh_teams; ++i)
 535         {
 536                 teem = kh_Team_ByID(i);
 537                 players = 0;
 538                 FOR_EACH_PLAYER(player)
 539                         if(player.deadflag == DEAD_NO)
 540                                 if(player.team == teem)
 541                                         ++players;
 542                 if(players == 0)
 543                         return FALSE;
 544         }
 545         return TRUE;
 546 }
 547
 548 void kh_WaitForPlayers()
 549 {
 550         if(kh_EnoughPlayers())
 551                 kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_round"), "Round starts in ", kh_StartRound);
 552         else
 553                 kh_Controller_SetThink(1, "Waiting for players to join...", kh_WaitForPlayers);
 554 }
 555
 556 void kh_StartRound()
 557 {
 558         float i, players, teem;
 559         entity player;
 560
 561         if(!kh_EnoughPlayers())
 562         {
 563                 kh_Controller_SetThink(1, "Waiting for players to join...", kh_WaitForPlayers);
 564                 return;
 565         }
 566
 567         FOR_EACH_PLAYER(player)
 568                 if(clienttype(player) == CLIENTTYPE_REAL)
 569                         centerprint_expire(player, CENTERPRIO_SPAM);
 570
 571         for(i = 0; i < kh_teams; ++i)
 572         {
 573                 teem = kh_Team_ByID(i);
 574                 players = 0;
 575                 entity my_player;
 576                 FOR_EACH_PLAYER(player)
 577                         if(player.deadflag == DEAD_NO)
 578                                 if(player.team == teem)
 579                                 {
 580                                         ++players;
 581                                         if(random() * players <= 1)
 582                                                 my_player = player;
 583                                 }
 584                 kh_Key_Spawn(my_player, 360 * i / kh_teams);
 585         }
 586
 587         kh_tracking_enabled = FALSE;
 588         kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_tracking"), "Scanning frequency range...", kh_EnableTrackingDevice);
 589 }
 590
 591 void kh_setstatus()
 592 {
 593         if(kh_teams)
 594         {
 595                 float kh_KEY;
 596                 kh_KEY = (IT_RED_FLAG_TAKEN | IT_RED_FLAG_LOST | IT_BLUE_FLAG_TAKEN | IT_BLUE_FLAG_LOST); // the one impossible combination
 597                 if(self.kh_next)
 598                         self.items = self.items | kh_KEY;
 599                 else
 600                         self.items = self.items - (self.items & kh_KEY);
 601         }
 602 }
 603
 604 void kh_EnableTrackingDevice()
 605 {
 606         entity player;
 607
 608         FOR_EACH_PLAYER(player)
 609                 if(clienttype(player) == CLIENTTYPE_REAL)
 610                         centerprint_expire(player, CENTERPRIO_SPAM);
 611
 612         kh_tracking_enabled = TRUE;
 613 }
 614
 615 float kh_Key_waypointsprite_for_player(entity e)
 616 {
 617         if(!kh_tracking_enabled)
 618                 return 0;
 619         if(!self.owner)
 620                 return kh_sprite_dropped;
 621         if(!self.owner.owner)
 622                 return kh_sprite_dropped;
 623         return 0; // draw only when key is not owned
 624 }
 625
 626 float kh_KeyCarrier_waypointsprite_for_player(entity e)
 627 {
 628         if(e.classname != "player" || self.team != e.team)
 629                 if(!kh_tracking_enabled)
 630                         return 0;
 631
 632         // e is spectator? That's no team mate...
 633         if(e.classname != "player")
 634                 return kh_GetCarrierSprite(self.team, -1);
 635
 636         // e is no key carrier: simple case...
 637         if(!e.kh_next)
 638                 return kh_GetCarrierSprite(self.team, e.team);
 639
 640         // e is a key carrier: if any key is dropped or owned by another team, show
 641         // the carrier sprite; otherwise show run here
 642         if(kh_Key_AllOwnedByWhichTeam() == e.team)
 643                 return kh_sprite_finish;
 644
 645         return kh_GetCarrierSprite(self.team, e.team);
 646 }
 647
 648 float kh_HandleFrags(entity attacker, entity targ, float f)
 649 {
 650         if(f <= 0)
 651                 return f;
 652         if(attacker == targ)
 653                 return f;
 654
 655         if(targ.kh_next)
 656                 kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", cvar("g_balance_keyhunt_score_carrierfrag")-1, 0);
 657
 658         return f;
 659 }
 660
 661 void kh_init()
 662 {
 663         precache_sound(kh_sound_capture);
 664         precache_sound(kh_sound_destroy);
 665         precache_sound(kh_sound_drop);
 666         precache_sound(kh_sound_collect);
 667
 668         precache_model("models/sprites/key-dropped.sp2");
 669         precache_model("models/sprites/keycarrier-finish.sp2");
 670         precache_model("models/sprites/keycarrier-friend.sp2");
 671         precache_model("models/sprites/keycarrier-red.sp2");
 672         precache_model("models/sprites/keycarrier-blue.sp2");
 673         precache_model("models/sprites/keycarrier-yellow.sp2");
 674         precache_model("models/sprites/keycarrier-pink.sp2");
 675         precache_model("models/keyhunt/key.md3");
 676
 677         // setup variables
 678         kh_teams = cvar("g_keyhunt_teams_override");
 679         if(kh_teams < 2)
 680                 kh_teams = cvar("g_keyhunt_teams");
 681         kh_teams = bound(2, kh_teams, 4);
 682
 683         // make a KH entity for controlling the game
 684         kh_controller = spawn();
 685         kh_controller.think = kh_Controller_Think;
 686         kh_Controller_SetThink(0, "", kh_WaitForPlayers);
 687
 688         setmodel(kh_controller, "models/sprites/key-dropped.sp2");
 689         kh_sprite_dropped = kh_controller.modelindex;
 690         setmodel(kh_controller, "models/sprites/keycarrier-finish.sp2");
 691         kh_sprite_finish = kh_controller.modelindex;
 692         setmodel(kh_controller, "models/sprites/keycarrier-friend.sp2");
 693         kh_sprite_friend = kh_controller.modelindex;
 694         setmodel(kh_controller, "models/sprites/keycarrier-red.sp2");
 695         kh_sprite_red = kh_controller.modelindex;
 696         setmodel(kh_controller, "models/sprites/keycarrier-blue.sp2");
 697         kh_sprite_blue = kh_controller.modelindex;
 698         setmodel(kh_controller, "models/sprites/keycarrier-pink.sp2");
 699         kh_sprite_pink = kh_controller.modelindex;
 700         setmodel(kh_controller, "models/sprites/keycarrier-yellow.sp2");
 701         kh_sprite_yellow = kh_controller.modelindex;
 702         setmodel(kh_controller, "");
 703 }
 704
 705 void kh_finalize()
 706 {
 707         // to be called before intermission
 708         kh_FinishRound();
 709         remove(kh_controller);
 710         kh_controller = world;
 711 }