data/qcsrc/server/ipban.qc

   1 /*
   2  * Protocol of online ban list:
   3  *
   4  * - Reporting a ban:
   5  *     GET g_ban_sync_uri?action=ban&hostname=...&ip=xxx.xxx.xxx&duration=nnnn&reason=...................
   6  *     (IP 1, 2, 3, or 4 octets, 3 octets for example is a /24 mask)
   7  * - Removing a ban:
   8  *     GET g_ban_sync_uri?action=unban&hostname=...&ip=xxx.xxx.xxx
   9  * - Querying the ban list
  10  *     GET g_ban_sync_uri?action=list&hostname=...&servers=xxx.xxx.xxx.xxx;xxx.xxx.xxx.xxx;...
  11  *
  12  *     shows the bans from the listed servers, and possibly others.
  13  *     Format of a ban is ASCII plain text, four lines per ban, delimited by
  14  *     newline ONLY (no carriage return):
  15  *
  16  *     IP address (also 1, 2, 3, or 4 octets, delimited by dot)
  17  *     time left in seconds
  18  *     reason of the ban
  19  *     server IP that registered the ban
  20  */
  21
  22 float Ban_Insert(string ip, float bantime, string reason, float dosync);
  23
  24 void OnlineBanList_SendBan(string ip, float bantime, string reason)
  25 {
  26         string uri;
  27         float i, n;
  28
  29         uri = strcat(     "?action=ban&hostname=", uri_escape(cvar_string("hostname")));
  30         uri = strcat(uri, "&ip=", uri_escape(ip));
  31         uri = strcat(uri, "&duration=", ftos(bantime));
  32         uri = strcat(uri, "&reason=", uri_escape(reason));
  33
  34         n = tokenize_sane(cvar_string("g_ban_sync_uri"));
  35         if(n >= MAX_IPBAN_URIS)
  36                 n = MAX_IPBAN_URIS;
  37         for(i = 0; i < n; ++i)
  38                 uri_get(strcat(argv(i), uri), URI_GET_DISCARD); // 0 = "discard" callback target
  39 }
  40
  41 void OnlineBanList_SendUnban(string ip)
  42 {
  43         string uri;
  44         float i, n;
  45
  46         uri = strcat(     "?action=unban&hostname=", uri_escape(cvar_string("hostname")));
  47         uri = strcat(uri, "&ip=", uri_escape(ip));
  48
  49         n = tokenize_sane(cvar_string("g_ban_sync_uri"));
  50         if(n >= MAX_IPBAN_URIS)
  51                 n = MAX_IPBAN_URIS;
  52         for(i = 0; i < n; ++i)
  53                 uri_get(strcat(argv(i), uri), URI_GET_DISCARD); // 0 = "discard" callback target
  54 }
  55
  56 string OnlineBanList_Servers;
  57 float OnlineBanList_Timeout;
  58 float OnlineBanList_RequestWaiting[MAX_IPBAN_URIS];
  59
  60 void OnlineBanList_URI_Get_Callback(float id, float status, string data)
  61 {
  62         float n, i, j, l;
  63         string ip;
  64         float timeleft;
  65         string reason;
  66         string serverip;
  67         float syncinterval;
  68         string uri;
  69
  70         id -= URI_GET_IPBAN;
  71
  72         if(id >= MAX_IPBAN_URIS)
  73         {
  74                 print("Received ban list for invalid ID\n");
  75                 return;
  76         }
  77
  78         tokenize_sane(cvar_string("g_ban_sync_uri"));
  79         uri = argv(id);
  80
  81         print("Received ban list from ", uri, ": ");
  82
  83         if(OnlineBanList_RequestWaiting[id] == 0)
  84         {
  85                 print("rejected (unexpected)\n");
  86                 return;
  87         }
  88
  89         OnlineBanList_RequestWaiting[id] = 0;
  90
  91         if(time > OnlineBanList_Timeout)
  92         {
  93                 print("rejected (too late)\n");
  94                 return;
  95         }
  96
  97         syncinterval = cvar("g_ban_sync_interval");
  98         if(syncinterval == 0)
  99         {
 100                 print("rejected (syncing disabled)\n");
 101                 return;
 102         }
 103         if(syncinterval > 0)
 104                 syncinterval *= 60;
 105
 106         if(status != 0)
 107         {
 108                 print("error: status is ", ftos(status), "\n");
 109                 return;
 110         }
 111
 112         if(substring(data, 0, 1) == "<")
 113         {
 114                 print("error: received HTML instead of a ban list: ");
 115                 return;
 116         }
 117
 118         if(strstrofs(data, "\r", 0) != -1)
 119         {
 120                 print("error: received carriage returns: ");
 121                 return;
 122         }
 123
 124         if(data == "")
 125                 n = 0;
 126         else
 127                 n = tokenizebyseparator(data, "\n");
 128
 129         if(mod(n, 4) != 0)
 130         {
 131                 print("error: received invalid item count: ", ftos(n), "\n");
 132                 return;
 133         }
 134
 135         print("OK\n");
 136
 137         for(i = 0; i < n; i += 4)
 138         {
 139                 ip = argv(i);
 140                 timeleft = stof(argv(i + 1));
 141                 reason = argv(i + 2);
 142                 serverip = argv(i + 3);
 143
 144                 timeleft -= 1.5 * cvar("g_ban_sync_timeout");
 145                 if(timeleft < 0)
 146                         continue;
 147
 148                 l = strlen(ip);
 149                 for(j = 0; j < l; ++j)
 150                         if(strstrofs("0123456789.", substring(ip, j, 1), 0) == -1)
 151                         {
 152                                 print("Invalid character ", substring(ip, j, 1), " in IP address ", ip, ". Skipping this ban.\n");
 153                                 goto skip;
 154                         }
 155
 156                 if(cvar("g_ban_sync_trusted_servers_verify"))
 157                         if((strstrofs(strcat(";", OnlineBanList_Servers, ";"), strcat(";", serverip, ";"), 0) == -1))
 158                                 goto skip;
 159
 160                 if(syncinterval > 0)
 161                         timeleft = min(syncinterval + (OnlineBanList_Timeout - time) + 5, timeleft);
 162                         // the ban will be prolonged on the next sync
 163                         // or expire 5 seconds after the next timeout
 164                 Ban_Insert(ip, timeleft, strcat("ban synced from ", serverip, " at ", uri), 0);
 165                 print("Ban list syncing: accepted ban of ", ip, " by ", serverip, " at ", uri, ": ");
 166                 print(reason, "\n");
 167
 168                 continue;
 169 :skip
 170         }
 171 }
 172
 173 void OnlineBanList_Think()
 174 {
 175         float argc;
 176         string uri;
 177         float i, n;
 178
 179         if(cvar_string("g_ban_sync_uri") == "")
 180                 return;
 181         if(cvar("g_ban_sync_interval") == 0) // < 0 is okay, it means "sync on level start only"
 182                 return;
 183         argc = tokenize_sane(cvar_string("g_ban_sync_trusted_servers"));
 184         if(argc == 0)
 185                 return;
 186
 187         if(OnlineBanList_Servers)
 188                 strunzone(OnlineBanList_Servers);
 189         OnlineBanList_Servers = argv(0);
 190         for(i = 1; i < argc; ++i)
 191                 OnlineBanList_Servers = strcat(OnlineBanList_Servers, ";", argv(i));
 192         OnlineBanList_Servers = strzone(OnlineBanList_Servers);
 193
 194         uri = strcat(     "?action=list&hostname=", uri_escape(cvar_string("hostname")));
 195         uri = strcat(uri, "&servers=", uri_escape(OnlineBanList_Servers));
 196
 197         OnlineBanList_Timeout = time + cvar("g_ban_sync_timeout");
 198
 199         n = tokenize_sane(cvar_string("g_ban_sync_uri"));
 200         if(n >= MAX_IPBAN_URIS)
 201                 n = MAX_IPBAN_URIS;
 202         for(i = 0; i < n; ++i)
 203         {
 204                 if(OnlineBanList_RequestWaiting[i])
 205                         continue;
 206                 OnlineBanList_RequestWaiting[i] = 1;
 207                 uri_get(strcat(argv(i), uri), URI_GET_IPBAN + i); // 1000 = "banlist" callback target
 208         }
 209
 210         if(cvar("g_ban_sync_interval") > 0)
 211                 self.nextthink = time + max(60, cvar("g_ban_sync_interval") * 60);
 212 }
 213
 214 #define BAN_MAX 64
 215 float ban_loaded;
 216 string ban_ip[BAN_MAX];
 217 float ban_expire[BAN_MAX];
 218 float ban_count;
 219
 220 string ban_ip1;
 221 string ban_ip2;
 222 string ban_ip3;
 223 string ban_ip4;
 224
 225 void Ban_SaveBans()
 226 {
 227         string out;
 228         float i;
 229
 230         if(!ban_loaded)
 231                 return;
 232
 233         // version of list
 234         out = "1";
 235         for(i = 0; i < ban_count; ++i)
 236         {
 237                 if(time > ban_expire[i])
 238                         continue;
 239                 out = strcat(out, " ", ban_ip[i]);
 240                 out = strcat(out, " ", ftos(ban_expire[i] - time));
 241         }
 242         if(strlen(out) <= 1) // no real entries
 243                 cvar_set("g_banned_list", "");
 244         else
 245                 cvar_set("g_banned_list", out);
 246 }
 247
 248 float Ban_Delete(float i)
 249 {
 250         if(i < 0)
 251                 return FALSE;
 252         if(i >= ban_count)
 253                 return FALSE;
 254         if(ban_expire[i] == 0)
 255                 return FALSE;
 256         if(ban_expire[i] > 0)
 257         {
 258                 OnlineBanList_SendUnban(ban_ip[i]);
 259                 strunzone(ban_ip[i]);
 260         }
 261         ban_expire[i] = 0;
 262         ban_ip[i] = "";
 263         Ban_SaveBans();
 264         return TRUE;
 265 }
 266
 267 void Ban_LoadBans()
 268 {
 269         float i, n;
 270         for(i = 0; i < ban_count; ++i)
 271                 Ban_Delete(i);
 272         ban_count = 0;
 273         ban_loaded = TRUE;
 274         n = tokenize_sane(cvar_string("g_banned_list"));
 275         if(stof(argv(0)) == 1)
 276         {
 277                 ban_count = (n - 1) / 2;
 278                 for(i = 0; i < ban_count; ++i)
 279                 {
 280                         ban_ip[i] = strzone(argv(2*i+1));
 281                         ban_expire[i] = time + stof(argv(2*i+2));
 282                 }
 283         }
 284
 285         entity e;
 286         e = spawn();
 287         e.classname = "bansyncer";
 288         e.think = OnlineBanList_Think;
 289         e.nextthink = time + 1;
 290 }
 291
 292 void Ban_View()
 293 {
 294         float i;
 295         string msg;
 296         for(i = 0; i < ban_count; ++i)
 297         {
 298                 if(time > ban_expire[i])
 299                         continue;
 300                 msg = strcat("#", ftos(i), ": ");
 301                 msg = strcat(msg, ban_ip[i], " is still banned for ");
 302                 msg = strcat(msg, ftos(ban_expire[i] - time), " seconds");
 303                 print(msg, "\n");
 304         }
 305 }
 306
 307 float Ban_GetClientIP(entity client)
 308 {
 309         float n;
 310         n = tokenizebyseparator(client.netaddress, ".");
 311         if(n != 4)
 312                 return FALSE;
 313         ban_ip1 = strcat1(argv(0));
 314         ban_ip2 = strcat(ban_ip1, ".", argv(1));
 315         ban_ip3 = strcat(ban_ip2, ".", argv(2));
 316         ban_ip4 = strcat(ban_ip3, ".", argv(3));
 317         return TRUE;
 318 }
 319
 320 float Ban_IsClientBanned(entity client, float idx)
 321 {
 322         float i, b, e;
 323         if(!ban_loaded)
 324                 Ban_LoadBans();
 325         if(!Ban_GetClientIP(client))
 326                 return FALSE;
 327         if(idx < 0)
 328         {
 329                 b = 0;
 330                 e = ban_count;
 331         }
 332         else
 333         {
 334                 b = idx;
 335                 e = idx + 1;
 336         }
 337         for(i = b; i < e; ++i)
 338         {
 339                 string s;
 340                 if(time > ban_expire[i])
 341                         continue;
 342                 s = ban_ip[i];
 343                 if(ban_ip1 == s) return TRUE;
 344                 if(ban_ip2 == s) return TRUE;
 345                 if(ban_ip3 == s) return TRUE;
 346                 if(ban_ip4 == s) return TRUE;
 347         }
 348         return FALSE;
 349 }
 350
 351 float Ban_MaybeEnforceBan(entity client)
 352 {
 353         if(Ban_IsClientBanned(client, -1))
 354         {
 355                 string s;
 356                 s = strcat("^1NOTE:^7 banned client ", client.netaddress, " just tried to enter\n");
 357                 dropclient(client);
 358                 bprint(s);
 359                 return TRUE;
 360         }
 361         return FALSE;
 362 }
 363
 364 string Ban_Enforce(float i, string reason)
 365 {
 366         string s;
 367         entity e;
 368
 369         // Enforce our new ban
 370         s = "";
 371         FOR_EACH_REALCLIENT(e)
 372                 if(Ban_IsClientBanned(e, i))
 373                 {
 374                         if(reason != "")
 375                         {
 376                                 if(s == "")
 377                                         reason = strcat(reason, ": affects ");
 378                                 else
 379                                         reason = strcat(reason, ", ");
 380                                 reason = strcat(reason, e.netname);
 381                         }
 382                         s = strcat(s, "^1NOTE:^7 banned client ", e.netname, "^7 has to go\n");
 383                         dropclient(e);
 384                 }
 385         bprint(s);
 386
 387         return reason;
 388 }
 389
 390 float Ban_Insert(string ip, float bantime, string reason, float dosync)
 391 {
 392         float i;
 393         float j;
 394         float bestscore;
 395
 396         // already banned?
 397         for(i = 0; i < ban_count; ++i)
 398                 if(ban_ip[i] == ip)
 399                 {
 400                         // prolong the ban
 401                         if(time + bantime > ban_expire[i])
 402                         {
 403                                 ban_expire[i] = time + bantime;
 404                                 print(ip, "'s ban has been prolonged to ", ftos(bantime), " seconds from now\n");
 405                         }
 406
 407                         // and enforce
 408                         reason = Ban_Enforce(i, reason);
 409
 410                         // and abort
 411                         if(dosync)
 412                                 if(reason != "")
 413                                         if(substring(reason, 0, 1) != "~") // like IRC: unauthenticated banner
 414                                                 OnlineBanList_SendBan(ip, bantime, reason);
 415
 416                         return FALSE;
 417                 }
 418
 419         // do we have a free slot?
 420         for(i = 0; i < ban_count; ++i)
 421                 if(time > ban_expire[i])
 422                         break;
 423         // no free slot? Then look for the one who would get unbanned next
 424         if(i >= BAN_MAX)
 425         {
 426                 i = 0;
 427                 bestscore = ban_expire[i];
 428                 for(j = 1; j < ban_count; ++j)
 429                 {
 430                         if(ban_expire[j] < bestscore)
 431                         {
 432                                 i = j;
 433                                 bestscore = ban_expire[i];
 434                         }
 435                 }
 436         }
 437         // if we replace someone, will we be banned longer than him (so long-term
 438         // bans never get overridden by short-term bans)
 439         if(ban_expire[i] > time + bantime)
 440                 return FALSE;
 441         // okay, insert our new victim as i
 442         Ban_Delete(i);
 443         print(ip, " has been banned for ", ftos(bantime), " seconds\n");
 444         ban_expire[i] = time + bantime;
 445         ban_ip[i] = strzone(ip);
 446         ban_count = max(ban_count, i + 1);
 447
 448         Ban_SaveBans();
 449
 450         reason = Ban_Enforce(i, reason);
 451
 452         // and abort
 453         if(dosync)
 454                 if(reason != "")
 455                         if(substring(reason, 0, 1) != "~") // like IRC: unauthenticated banner
 456                                 OnlineBanList_SendBan(ip, bantime, reason);
 457
 458         return TRUE;
 459 }
 460
 461 void Ban_KickBanClient(entity client, float bantime, float masksize, string reason)
 462 {
 463         if(!Ban_GetClientIP(client))
 464         {
 465                 sprint(client, strcat("Kickbanned: ", reason, "\n"));
 466                 dropclient(client);
 467                 return;
 468         }
 469         // now ban him
 470         switch(masksize)
 471         {
 472                 case 1:
 473                         Ban_Insert(ban_ip1, bantime, reason, 1);
 474                         break;
 475                 case 2:
 476                         Ban_Insert(ban_ip2, bantime, reason, 1);
 477                         break;
 478                 case 3:
 479                         Ban_Insert(ban_ip3, bantime, reason, 1);
 480                         break;
 481                 default:
 482                         Ban_Insert(ban_ip4, bantime, reason, 1);
 483                         break;
 484         }
 485         /*
 486          * not needed, as we enforce the ban in Ban_Insert anyway
 487         // and kick him
 488         sprint(client, strcat("Kickbanned: ", reason, "\n"));
 489         dropclient(client);
 490          */
 491 }
 492
 493 float GameCommand_Ban(string command)
 494 {
 495         float argc;
 496         float bantime;
 497         entity client;
 498         float entno;
 499         float masksize;
 500         string reason;
 501         float reasonarg;
 502
 503         argc = tokenize_sane(command);
 504         if(argv(0) == "help")
 505         {
 506                 print("  kickban # n m p reason - kickban player n for m seconds, using mask size p (1 to 4)\n");
 507                 print("  ban ip m reason - ban an IP or range (incomplete IP, like 1.2.3) for m seconds\n");
 508                 print("  bans - list all existing bans\n");
 509                 print("  unban n - delete the entry #n from the bans list\n");
 510                 return TRUE;
 511         }
 512         if(argv(0) == "kickban")
 513         {
 514 #define INITARG(c) reasonarg = c
 515 #define GETARG(v,d) if((argc > reasonarg) && ((v = stof(argv(reasonarg))) != 0)) ++reasonarg; else v = d
 516 #define RESTARG(v) if(argc > reasonarg) v = substring(command, argv_start_index(reasonarg), strlen(command) - argv_start_index(reasonarg)); else v = ""
 517                 if(argc >= 3)
 518                 {
 519                         entno = stof(argv(2));
 520                         if(entno > maxclients || entno < 1)
 521                                 return TRUE;
 522                         client = edict_num(entno);
 523
 524                         INITARG(3);
 525                         GETARG(bantime, cvar("g_ban_default_bantime"));
 526                         GETARG(masksize, cvar("g_ban_default_masksize"));
 527                         RESTARG(reason);
 528
 529                         Ban_KickBanClient(client, bantime, masksize, reason);
 530                         return TRUE;
 531                 }
 532         }
 533         else if(argv(0) == "ban")
 534         {
 535                 if(argc >= 2)
 536                 {
 537                         string ip;
 538                         ip = argv(1);
 539
 540                         INITARG(2);
 541                         GETARG(bantime, cvar("g_ban_default_bantime"));
 542                         RESTARG(reason);
 543
 544                         Ban_Insert(ip, bantime, reason, 1);
 545                         return TRUE;
 546                 }
 547 #undef INITARG
 548 #undef GETARG
 549 #undef RESTARG
 550         }
 551         else if(argv(0) == "bans")
 552         {
 553                 Ban_View();
 554                 return TRUE;
 555         }
 556         else if(argv(0) == "unban")
 557         {
 558                 if(argc >= 2)
 559                 {
 560                         float who;
 561                         who = stof(argv(1));
 562                         Ban_Delete(who);
 563                         return TRUE;
 564                 }
 565         }
 566         return FALSE;
 567 }