data/qcsrc/server/gamec/clientcommands.c

   1 void ReadyCount();
   2
   3 void SV_ParseClientCommand(string s) {
   4         local float index;
   5
   6         tokenize(s);
   7
   8         if(argv(0) == "clogin") {
   9                 if(cvar("sv_clientcommands")) {
  10                         if(self.adminstatus < -5) {
  11                                 sprint(self, "Too many unsuccessful tries.\n");
  12                         } else if(argv(1) == cvar_string("sv_clientcommands_password")) {
  13                                 self.adminstatus = 1;
  14                                 sprint(self, "You now have remote admin status.\n");
  15                         } else {
  16                                 sprint(self, "Wrong password.\n");
  17                                 // use of -- produces compiler warning in the if() line???
  18                                 self.adminstatus = self.adminstatus - 1;
  19                                 if(self.adminstatus == 0)
  20                                         sprint(self, "You lost remote admin status.\n");
  21                         }
  22                 } else {
  23                         sprint(self, "Clientside commands NOT allowed.\n");
  24                 }
  25         } else if(argv(0) == "ccmd") {
  26                 if(cvar("sv_clientcommands")) {
  27                         if(self.adminstatus > 0) {
  28                                 local string command;
  29                                 command = argv(1);
  30                                 index = 2;
  31                                 while(argv(index) != "") {
  32                                         command = strcat(command, " ", argv(index));
  33                                         index++;
  34                                 }
  35                                 localcmd(command);
  36                         } else
  37                                 sprint(self, "You don't have remote admin status.\n");
  38                 } else {
  39                         sprint(self, "Clientside commands NOT allowed.\n");
  40                 }
  41         } else if(argv(0) == "vote") {
  42                 if(argv(1) == "help") {
  43                         local string vmasterdis;
  44                         if(!cvar("sv_vote_master")) {
  45                                 vmasterdis = " ^1(disabled)";
  46                         }
  47                         local string vcalldis;
  48                         if(!cvar("sv_vote_call")) {
  49                                 vcalldis = " ^1(disabled)";
  50                         }
  51                         sprint(self, "^7You can use voting with \"^2cmd vote help^7\" \"^2cmd vote status^7\" \"^2cmd vote call ^3COMMAND ARGUMENTS^7\" \"^2cmd vote stop^7\" \"^2cmd vote master^7\" \"^2cmd vote do ^3COMMAND ARGUMENTS^7\" \"^2cmd vote yes^7\" \"^2cmd vote no^7\".\n");
  52                         sprint(self, "^7Or if your version is up to date you can use these aliases \"^2vhelp^7\" \"^2vstatus^7\" \"^2vcall ^3COMMAND ARGUMENTS^7\" \"^2vstop^7\" \"^2vmaster^7\" \"^2vdo ^3COMMAND ARGUMENTS^7\" \"^2vyes^7\" \"^2vno^7\".\n");
  53                         sprint(self, "^7\"^2help^7\" shows this info.\n");
  54                         sprint(self, "^7\"^2status^7\" shows if there is a vote called and who called it.\n");
  55                         sprint(self, strcat("^7\"^2call^7\" is used to call a vote. See the list of allowed commands.", vcalldis, "^7\n"));
  56                         sprint(self, "^7\"^2stop^7\" can be used by the vote caller or an admin to stop a vote and maybe correct it.\n");
  57                         sprint(self, strcat("^7\"^2master^7\" is used to call a vote to become a master.", vmasterdis, "^7\n"));
  58                         sprint(self, "^7\"^2do^7\" If you are a master you can execute a command without a vote. See the list of allowed commands.\n");
  59                         sprint(self, "^7\"^2yes^7\" and \"^2no^7\" to make your vote.\n");
  60                         sprint(self, "^7If more then 50% of the players vote yes the vote is accepted.\n");
  61                         sprint(self, "^7If more then 50% of the players vote no the vote is rejected.\n");
  62                         sprint(self, strcat("^7The vote will end after ", cvar_string("sv_vote_timeout"), "^7 seconds.\n"));
  63                         sprint(self, "^7You can call a vote for or execute these commands:\n");
  64                         sprint(self, strcat("^3", cvar_string("sv_vote_commands"), "^7 and maybe further ^3arguments^7\n"));
  65                 } else if(argv(1) == "status") {
  66                         if(votecalled) {
  67                                 sprint(self, strcat("^7Vote for \"^1", votecalledvote, "^7\" called by \"^7", votecaller.netname, "^7\".\n"));
  68                         } else {
  69                                 sprint(self, "^1No vote called.\n");
  70                         }
  71                 } else if(argv(1) == "call") {
  72                         if(cvar("sv_vote_call")) {
  73                                 if(votecalled) {
  74                                         sprint(self, "^1There is already a vote called.\n");
  75                                 } else {
  76                                         local string vote;
  77                                         vote = VoteParse();
  78                                         if(vote == "") {
  79                                                 sprint(self, "^1Your vote is empty. See help for more info.\n");
  80                                         } else if(time < self.vote_next) {
  81                                                 sprint(self, strcat("^1You have to wait ^2", ftos(self.vote_next - time), "^1 seconds before you can again call a vote.\n"));
  82                                         } else if(VoteAllowed(strcat(argv(2)))) { // strcat seems to be necessary
  83                                                 votecalled = TRUE;
  84                                                 votecalledmaster = FALSE;
  85                                                 votecalledvote = strzone(vote);
  86                                                 votecaller = self; // remember who called the vote
  87                                                 votefinished = time + cvar("sv_vote_timeout");
  88                                                 votecaller.vote_vote = 1; // of course you vote yes
  89                                                 votecaller.vote_next = time + cvar("sv_vote_wait");
  90                                                 bprint(strcat("^3Vote for \"^1", votecalledvote, "^3\" called by \"^7", votecaller.netname, "^3\".\n"));
  91                                                 VoteCount(); // needed if you are the only one
  92                                         } else {
  93                                                 sprint(self, "^1This vote is not ok. See help for more info.\n");
  94                                         }
  95                                 }
  96                         } else {
  97                                 sprint(self, "^1Vote calling is NOT allowed.\n");
  98                         }
  99                 } else if(argv(1) == "stop") {
 100                         if(!votecalled) {
 101                                 sprint(self, "^1No vote called.\n");
 102                         } else if(self == votecaller
 103                                   || self.adminstatus > 0) { // the votecaller and admins can stop a vote
 104                                 VoteStop(self);
 105                         } else {
 106                                 sprint(self, "^1You are not allowed to stop that Vote.\n");
 107                         }
 108                 } else if(argv(1) == "master") {
 109                         if(cvar("sv_vote_master")) {
 110                                 if(votecalled) {
 111                                         sprint(self, "^1There is already a vote called.\n");
 112                                 } else {
 113                                         votecalled = TRUE;
 114                                         votecalledmaster = TRUE;
 115                                         votecalledvote = strzone("^3master");
 116                                         votecaller = self; // remember who called the vote
 117                                         votefinished = time + cvar("sv_vote_timeout");
 118                                         votecaller.vote_vote = 1; // of course you vote yes
 119                                         votecaller.vote_next = time + cvar("sv_vote_wait");
 120                                         bprint(strcat("\"^3", votecaller.netname, "^3\" called a vote to become ^3master^3.\n"));
 121                                         VoteCount(); // needed if you are the only one
 122                                 }
 123                         } else {
 124                                 sprint(self, "^1Vote to become master is NOT allowed.\n");
 125                         }
 126                 } else if(argv(1) == "do") {
 127                         if(self.vote_master) {
 128                                 local string dovote;
 129                                 dovote = VoteParse();
 130                                 if(dovote == "") {
 131                                         sprint(self, "^1Your command was empty. See help for more info.\n");
 132                                 } else if(VoteAllowed(strcat(argv(2)))) { // strcat seems to be necessary
 133                                         bprint("\"^7", strcat(self.netname, "^2 used his ^3master^2 status to do \"^2", dovote, "^2\".\n"));
 134                                         localcmd(dovote);
 135                                 } else {
 136                                         sprint(self, "^1This command is not ok. See help for more info.\n");
 137                                 }
 138                         } else {
 139                                 sprint(self, "^1You are NOT a master.\n");
 140                         }
 141                 } else if(argv(1) == "yes") {
 142                         if(!votecalled) {
 143                                 sprint(self, "^1No vote called.\n");
 144                         } else if(self.vote_vote == 0
 145                                   || cvar("sv_vote_change")) {
 146                                 sprint(self, "^1You accepted the vote.\n");
 147                                 self.vote_vote = 1;
 148                                 if(!cvar("sv_vote_singlecount")) {
 149                                         VoteCount();
 150                                 }
 151                         } else {
 152                                 sprint(self, "^1You have already voted.\n");
 153                         }
 154                 } else if(argv(1) == "no") {
 155                         if(!votecalled) {
 156                                 sprint(self, "^1No vote called.\n");
 157                         } else if(self.vote_vote == 0
 158                                   || cvar("sv_vote_change")) {
 159                                 sprint(self, "^1You rejected the vote.\n");
 160                                 self.vote_vote = -1;
 161                                 if(!cvar("sv_vote_singlecount")) {
 162                                         VoteCount();
 163                                 }
 164                         } else {
 165                                 sprint(self, "^1You have already voted.\n");
 166                         }
 167                 } else {
 168                         // ignore this?
 169                         sprint(self, "^1Unknown vote command.\n");
 170                 }
 171         } else if(argv(0) == "autoswitch") {
 172                 // be backwards compatible with older clients (enabled)
 173                 self.autoswitch = ("0" != argv(1));
 174                 local string autoswitchmsg;
 175                 if (self.autoswitch) {
 176                         autoswitchmsg = "on";
 177                 } else {
 178                         autoswitchmsg = "off";
 179                 }
 180                 sprint(self, strcat("^1autoswitch turned ", autoswitchmsg, "\n"));
 181         } else if(argv(0) == "clientversion") {
 182                 if (argv(1) == "$g_nexuizversion_major") {
 183                         //versionmsg = "^1client is too old to get versioninfo.\nUPDATE!!! (http://www.nexuiz.com)^8";
 184                         // either that or someone wants to be funny
 185                         self.version = 1;
 186                 } else {
 187                         self.version = stof(argv(1));
 188                 }
 189         } else if(argv(0) == "spectate") {
 190                 if(cvar("g_lms"))
 191                         return; // don't allow spectating in lms, unless player runs out of lives
 192                 if(self.classname == "player" && cvar("sv_spectate") == 1) {
 193                         self.classname = "observer";
 194                         PutClientInServer();
 195                 }
 196         } else if(argv(0) == "join") {
 197                 self.classname = "player";
 198                 self.frags = 0;
 199                 // TODO: I have no idea whether this is needed or not
 200                 if(!cvar("g_lms")) {
 201                         bprint (strcat("^4", self.netname, "^4 is playing now\n"));
 202                 }
 203                 PutClientInServer();
 204         } else if( argv(0) == "selectteam" ) {
 205                 if( argv(1) == "none" ) {
 206                         SV_ChangeTeam( 0 );
 207                 } else if( argv(1) == "red" ) {
 208                         SV_ChangeTeam( COLOR_TEAM1 - 1 );
 209                 } else if( argv(1) == "blue" ) {
 210                         SV_ChangeTeam( COLOR_TEAM2 - 1 );
 211                 } else if( argv(1) == "pink" ) {
 212                         SV_ChangeTeam( COLOR_TEAM3 - 1 );
 213                 } else if( argv(1) == "yellow" ) {
 214                         SV_ChangeTeam( COLOR_TEAM4 - 1 );
 215                 } else if( argv(1) == "auto" ) {
 216                         JoinBestTeam( self, 0 );
 217                 } else {
 218                         sprint( self, strcat( "selectteam none/red/blue/pink/yellow/auto - \"", argv(1), "\" not recognised\n" ) );
 219                 }
 220         } else if(argv(0) == "ready") {
 221                 if(cvar("sv_ready_restart"))
 222                 {
 223                         self.ready = TRUE;
 224                         bprint(self.netname, "^2 is ready\n");
 225                         ReadyCount();
 226                 }
 227         } else {
 228                 clientcommand(self,s);
 229         }
 230 }
 231
 232 void VoteThink() {
 233         if(votefinished > 0 // a vote was called
 234             && time > votefinished) // time is up
 235         {
 236                 VoteCount();
 237         }
 238 }
 239
 240 string VoteParse() {
 241         local float index;
 242         index = 3;
 243         local string vote;
 244         vote = argv(2);
 245         while(argv(index) != "") {
 246                 vote = strcat(vote, " ", argv(index));
 247                 index++;
 248         }
 249
 250         // necessary for some of the string operations
 251         vote = strzone(vote);
 252
 253         // now we remove some things that could be misused
 254         index = 0;
 255         local float found;
 256         found = FALSE;
 257         local float votelength;
 258         votelength = strlen(vote);
 259         while(!found && index < votelength)
 260         {
 261                 local string badchar;
 262                 badchar = substring(vote, index, 1);
 263                 if(badchar == ";"
 264                    || badchar == "\n")
 265                 {
 266                         found = TRUE;
 267                 } else {
 268                         index++;
 269                 }
 270         }
 271         return substring(vote, 0, index);
 272 }
 273
 274 float VoteAllowed(string votecommand) {
 275         tokenize(cvar_string("sv_vote_commands"));
 276         local float index;
 277         index = 0;
 278         while(argv(index) != "") {
 279                 local string allowed;
 280                 allowed = argv(index);
 281                 if(votecommand == allowed) {
 282                         return TRUE;
 283                 }
 284                 index++;
 285         }
 286         return FALSE;
 287 }
 288
 289 void VoteReset() {
 290         local string searchclass;
 291         searchclass = "player";
 292
 293         while (TRUE)
 294         {
 295                 local entity player;
 296                 player = find(player, classname, searchclass);
 297                 while(player)
 298                 {
 299                         player.vote_vote = 0;
 300                         player = find(player, classname, searchclass);
 301                 }
 302
 303                 if("player" == searchclass) {
 304                         searchclass = "observer";
 305                 } else if("observer" == searchclass) {
 306                         searchclass = "spectator";
 307                 } else {
 308                         break;
 309                 }
 310         }
 311
 312         votecalled = FALSE;
 313         votecalledmaster = FALSE;
 314         votefinished = 0;
 315 }
 316
 317 void VoteAccept() {
 318         bprint(strcat("^2The vote for \"^1", votecalledvote, "^2\" from \"^7", votecaller.netname, "^2\" was accepted.\n"));
 319         if(votecalledmaster)
 320         {
 321                 votecaller.vote_master = 1;
 322         } else {
 323                 localcmd(votecalledvote);
 324         }
 325         votecaller.vote_next = 0; // people like your votes, no wait for next vote
 326         VoteReset();
 327 }
 328
 329 void VoteReject() {
 330         bprint(strcat("^2The vote for \"^1", votecalledvote, "^2\" from \"^7", votecaller.netname, "^2\" was rejected.\n"));
 331         VoteReset();
 332 }
 333
 334 void VoteTimeout() {
 335         bprint(strcat("^5The vote for \"^1", votecalledvote, "^5\" from \"^7", votecaller.netname, "^5\" did timeout.\n"));
 336         VoteReset();
 337 }
 338
 339 void VoteStop(entity stopper) {
 340         bprint(strcat("^5The vote for \"^1", votecalledvote, "^5\" from \"^7", votecaller.netname, "^5\" was stopped by \"^5", stopper.netname, "^5\".\n"));
 341         if(stopper == votecaller) {
 342                 // no wait for next vote so you can correct your vote
 343                 votecaller.vote_next = 0;
 344         }
 345         VoteReset();
 346 }
 347
 348 void VoteCount() {
 349         local float playercount;
 350         playercount = 0;
 351         local float yescount;
 352         yescount = 0;
 353         local float nocount;
 354         nocount = 0;
 355         local string searchclass;
 356         searchclass = "player";
 357
 358         while (TRUE)
 359         {
 360                 local entity player;
 361                 player = find(player, classname, searchclass);
 362
 363                 while(player)
 364                 {
 365                         if(clienttype(player) != CLIENTTYPE_BOT) {
 366                                 if(player.vote_vote < 0) {
 367                                         nocount++;
 368                                 } else if(player.vote_vote > 0) {
 369                                         yescount++;
 370                                 }
 371                                 playercount++;
 372                         }
 373                         player = find(player, classname, searchclass);
 374                 }
 375
 376                 if("player" == searchclass) {
 377                         searchclass = "observer";
 378                 } else if("observer" == searchclass) {
 379                         searchclass = "specator";
 380                 } else {
 381                         break;
 382                 }
 383         }
 384
 385         if((playercount == 1) && votecalledmaster) {
 386                 // if only one player is on the server becoming vote
 387                 // master is not allowed.  This could be used for
 388                 // trolling or worse. 'self' is the user who has
 389                 // called the vote because this function is called
 390                 // by SV_ParseClientCommand. Maybe all voting should
 391                 // be disabled for a single player?
 392                 sprint(self, "^1You are the only player on this server so you can not become vote master.\n");
 393                 votecaller.vote_next = 0;
 394                 VoteReset();
 395         } else if((playercount / 2) < yescount) { // vote accepted
 396                 VoteAccept();
 397         } else if((playercount / 2) < nocount) { // vote rejected
 398                 VoteReject();
 399         } else if(time > votefinished) { // vote timedout
 400                 VoteTimeout();
 401         } // else still running
 402 }
 403
 404
 405 void ReadyCount()
 406 {
 407         local entity e;
 408         local float r, p;
 409
 410         e = find(world, classname, "player");
 411
 412         while(e)
 413         {
 414                 if(clienttype(e) == CLIENTTYPE_REAL)
 415                 {
 416                         p += 1;
 417                         if(e.ready) r += 1;
 418                 }
 419                 e = find(e, classname, "player");
 420         }
 421
 422         if(p && r == p)
 423         {
 424                 bprint("^1Server is restarting...\n");
 425                 localcmd("restart\n");
 426         }
 427 }