data/qcsrc/server/gamec/clientcommands.c

   1 void ReadyCount();
   2 float ValidateMap(string vote);
   3
   4 void SV_ParseClientCommand(string s) {
   5         local float index;
   6
   7         tokenize(s);
   8
   9         if(argv(0) == "clogin") {
  10                 if(cvar("sv_clientcommands")) {
  11                         if(self.adminstatus < -5) {
  12                                 sprint(self, "Too many unsuccessful tries.\n");
  13                         } else if(argv(1) == cvar_string("sv_clientcommands_password")) {
  14                                 self.adminstatus = 1;
  15                                 sprint(self, "You now have remote admin status.\n");
  16                                 ServerConsoleEcho(strcat("ClientCommands: ", self.netname, " received admin status"), TRUE);
  17                         } else {
  18                                 sprint(self, "Wrong password.\n");
  19                                 // use of -- produces compiler warning in the if() line???
  20                                 self.adminstatus = self.adminstatus - 1;
  21                                 if(self.adminstatus == 0)
  22                                 {
  23                                         sprint(self, "You lost remote admin status.\n");
  24                                         ServerConsoleEcho(strcat("ClientCommands: ", self.netname, " lost admin status"), TRUE);
  25                                 }
  26                         }
  27                 } else {
  28                         sprint(self, "Clientside commands NOT allowed.\n");
  29                 }
  30         } else if(argv(0) == "ccmd") {
  31                 if(cvar("sv_clientcommands")) {
  32                         if(self.adminstatus > 0) {
  33                                 local string command;
  34                                 command = argv(1);
  35                                 index = 2;
  36                                 while(argv(index) != "") {
  37                                         command = strcat(command, " ", argv(index));
  38                                         index++;
  39                                 }
  40                                 ServerConsoleEcho(strcat("ClientCommands: ", self.netname, " issued command '", command, "'"), TRUE);
  41                                 localcmd(command);
  42                         } else
  43                                 sprint(self, "You don't have remote admin status.\n");
  44                 } else {
  45                         sprint(self, "Clientside commands NOT allowed.\n");
  46                 }
  47         } else if(argv(0) == "vote") {
  48                 if(argv(1) == "help") {
  49                         local string vmasterdis;
  50                         if(!cvar("sv_vote_master")) {
  51                                 vmasterdis = " ^1(disabled)";
  52                         }
  53                         local string vcalldis;
  54                         if(!cvar("sv_vote_call")) {
  55                                 vcalldis = " ^1(disabled)";
  56                         }
  57                         sprint(self, "^7You can use voting with \"^2cmd vote help^7\" \"^2cmd vote status^7\" \"^2cmd vote call ^3COMMAND ARGUMENTS^7\" \"^2cmd vote stop^7\" \"^2cmd vote master^7\" \"^2cmd vote do ^3COMMAND ARGUMENTS^7\" \"^2cmd vote yes^7\" \"^2cmd vote no^7\".\n");
  58                         sprint(self, "^7Or if your version is up to date you can use these aliases \"^2vhelp^7\" \"^2vstatus^7\" \"^2vcall ^3COMMAND ARGUMENTS^7\" \"^2vstop^7\" \"^2vmaster^7\" \"^2vdo ^3COMMAND ARGUMENTS^7\" \"^2vyes^7\" \"^2vno^7\".\n");
  59                         sprint(self, "^7\"^2help^7\" shows this info.\n");
  60                         sprint(self, "^7\"^2status^7\" shows if there is a vote called and who called it.\n");
  61                         sprint(self, strcat("^7\"^2call^7\" is used to call a vote. See the list of allowed commands.", vcalldis, "^7\n"));
  62                         sprint(self, "^7\"^2stop^7\" can be used by the vote caller or an admin to stop a vote and maybe correct it.\n");
  63                         sprint(self, strcat("^7\"^2master^7\" is used to call a vote to become a master.", vmasterdis, "^7\n"));
  64                         sprint(self, "^7\"^2do^7\" If you are a master you can execute a command without a vote. See the list of allowed commands.\n");
  65                         sprint(self, "^7\"^2yes^7\" and \"^2no^7\" to make your vote.\n");
  66                         sprint(self, "^7If more then 50% of the players vote yes the vote is accepted.\n");
  67                         sprint(self, "^7If more then 50% of the players vote no the vote is rejected.\n");
  68                         sprint(self, strcat("^7The vote will end after ", cvar_string("sv_vote_timeout"), "^7 seconds.\n"));
  69                         sprint(self, "^7You can call a vote for or execute these commands:\n");
  70                         sprint(self, strcat("^3", cvar_string("sv_vote_commands"), "^7 and maybe further ^3arguments^7\n"));
  71                 } else if(argv(1) == "status") {
  72                         if(votecalled) {
  73                                 sprint(self, strcat("^7Vote for \"^1", votecalledvote, "^7\" called by \"^7", votecaller.netname, "^7\".\n"));
  74                         } else {
  75                                 sprint(self, "^1No vote called.\n");
  76                         }
  77                 } else if(argv(1) == "call") {
  78                         if(cvar("sv_vote_call")) {
  79                                 if(votecalled) {
  80                                         sprint(self, "^1There is already a vote called.\n");
  81                                 } else {
  82                                         local string vote;
  83                                         vote = VoteParse();
  84                                         if(vote == "") {
  85                                                 sprint(self, "^1Your vote is empty. See help for more info.\n");
  86                                         } else if(time < self.vote_next) {
  87                                                 sprint(self, strcat("^1You have to wait ^2", ftos(self.vote_next - time), "^1 seconds before you can again call a vote.\n"));
  88                                         } else if(VoteAllowed(strcat(argv(2)))) { // strcat seems to be necessary
  89                                                 if(!ValidateMap(vote))
  90                                                         return;
  91                                                 votecalled = TRUE;
  92                                                 votecalledmaster = FALSE;
  93                                                 votecalledvote = strzone(vote);
  94                                                 votecaller = self; // remember who called the vote
  95                                                 votefinished = time + cvar("sv_vote_timeout");
  96                                                 votecaller.vote_vote = 1; // of course you vote yes
  97                                                 votecaller.vote_next = time + cvar("sv_vote_wait");
  98                                                 bprint(strcat("^3Vote for \"^1", votecalledvote, "^3\" called by \"^7", votecaller.netname, "^3\".\n"));
  99                                                 VoteCount(); // needed if you are the only one
 100                                         } else {
 101                                                 sprint(self, "^1This vote is not ok. See help for more info.\n");
 102                                         }
 103                                 }
 104                         } else {
 105                                 sprint(self, "^1Vote calling is NOT allowed.\n");
 106                         }
 107                 } else if(argv(1) == "stop") {
 108                         if(!votecalled) {
 109                                 sprint(self, "^1No vote called.\n");
 110                         } else if(self == votecaller
 111                                   || self.adminstatus > 0) { // the votecaller and admins can stop a vote
 112                                 VoteStop(self);
 113                         } else {
 114                                 sprint(self, "^1You are not allowed to stop that Vote.\n");
 115                         }
 116                 } else if(argv(1) == "master") {
 117                         if(cvar("sv_vote_master")) {
 118                                 if(votecalled) {
 119                                         sprint(self, "^1There is already a vote called.\n");
 120                                 } else {
 121                                         votecalled = TRUE;
 122                                         votecalledmaster = TRUE;
 123                                         votecalledvote = strzone("^3master");
 124                                         votecaller = self; // remember who called the vote
 125                                         votefinished = time + cvar("sv_vote_timeout");
 126                                         votecaller.vote_vote = 1; // of course you vote yes
 127                                         votecaller.vote_next = time + cvar("sv_vote_wait");
 128                                         bprint(strcat("\"^3", votecaller.netname, "^3\" called a vote to become ^3master^3.\n"));
 129                                         VoteCount(); // needed if you are the only one
 130                                 }
 131                         } else {
 132                                 sprint(self, "^1Vote to become master is NOT allowed.\n");
 133                         }
 134                 } else if(argv(1) == "do") {
 135                         if(self.vote_master) {
 136                                 local string dovote;
 137                                 dovote = VoteParse();
 138                                 if(dovote == "") {
 139                                         sprint(self, "^1Your command was empty. See help for more info.\n");
 140                                 } else if(VoteAllowed(strcat(argv(2)))) { // strcat seems to be necessary
 141                                         bprint("\"^7", strcat(self.netname, "^2 used his ^3master^2 status to do \"^2", dovote, "^2\".\n"));
 142                                         localcmd(dovote);
 143                                 } else {
 144                                         sprint(self, "^1This command is not ok. See help for more info.\n");
 145                                 }
 146                         } else {
 147                                 sprint(self, "^1You are NOT a master.\n");
 148                         }
 149                 } else if(argv(1) == "yes") {
 150                         if(!votecalled) {
 151                                 sprint(self, "^1No vote called.\n");
 152                         } else if(self.vote_vote == 0
 153                                   || cvar("sv_vote_change")) {
 154                                 sprint(self, "^1You accepted the vote.\n");
 155                                 self.vote_vote = 1;
 156                                 if(!cvar("sv_vote_singlecount")) {
 157                                         VoteCount();
 158                                 }
 159                         } else {
 160                                 sprint(self, "^1You have already voted.\n");
 161                         }
 162                 } else if(argv(1) == "no") {
 163                         if(!votecalled) {
 164                                 sprint(self, "^1No vote called.\n");
 165                         } else if(self.vote_vote == 0
 166                                   || cvar("sv_vote_change")) {
 167                                 sprint(self, "^1You rejected the vote.\n");
 168                                 self.vote_vote = -1;
 169                                 if(!cvar("sv_vote_singlecount")) {
 170                                         VoteCount();
 171                                 }
 172                         } else {
 173                                 sprint(self, "^1You have already voted.\n");
 174                         }
 175                 } else {
 176                         // ignore this?
 177                         sprint(self, "^1Unknown vote command.\n");
 178                 }
 179         } else if(argv(0) == "autoswitch") {
 180                 // be backwards compatible with older clients (enabled)
 181                 self.autoswitch = ("0" != argv(1));
 182                 local string autoswitchmsg;
 183                 if (self.autoswitch) {
 184                         autoswitchmsg = "on";
 185                 } else {
 186                         autoswitchmsg = "off";
 187                 }
 188                 sprint(self, strcat("^1autoswitch turned ", autoswitchmsg, "\n"));
 189         } else if(argv(0) == "clientversion") {
 190                 if (argv(1) == "$gameversion") {
 191                         //versionmsg = "^1client is too old to get versioninfo.\nUPDATE!!! (http://www.nexuiz.com)^8";
 192                         // either that or someone wants to be funny
 193                         self.version = 1;
 194                 } else {
 195                         self.version = stof(argv(1));
 196                 }
 197                 if(self.version != cvar("gameversion"))
 198                 {
 199                         self.classname = "observer";
 200                         self.frags = -2;
 201                         PutClientInServer();
 202                 } else if(cvar("g_campaign") || cvar("g_balance_teams")) {
 203                         //JoinBestTeam(self, 0);
 204                 } else if(cvar("teamplay") && !cvar("sv_spectate")) {
 205                         self.classname = "observer";
 206                         stuffcmd(self,"menu_showteamselect\n");
 207                 }
 208         } else if(argv(0) == "spectate") {
 209                 if(cvar("g_lms") || cvar("g_arena"))
 210                         return; // don't allow spectating in lms, unless player runs out of lives
 211                 if(self.classname == "player" && cvar("sv_spectate") == 1) {
 212                         self.classname = "observer";
 213                         PutClientInServer();
 214                 }
 215         } else if(argv(0) == "join") {
 216                 if(!cvar("g_arena"))
 217                 if (self.classname != "player")
 218                 {
 219                         self.classname = "player";
 220                         self.frags = 0;
 221                         bprint (strcat("^4", self.netname, "^4 is playing now\n"));
 222                         PutClientInServer();
 223                 }
 224         } else if( argv(0) == "selectteam" ) {
 225                 if( !cvar("teamplay") ) {
 226                         sprint( self, "selecteam can only be used in teamgames\n");
 227                 } else if(cvar("g_campaign")) {
 228                         //JoinBestTeam(self, 0);
 229                 } else if( argv(1) == "none" ) {
 230                         SV_ChangeTeam( 0 );
 231                 } else if( argv(1) == "red" ) {
 232                         SV_ChangeTeam( COLOR_TEAM1 - 1 );
 233                 } else if( argv(1) == "blue" ) {
 234                         SV_ChangeTeam( COLOR_TEAM2 - 1 );
 235                 } else if( argv(1) == "pink" ) {
 236                         SV_ChangeTeam( COLOR_TEAM3 - 1 );
 237                 } else if( argv(1) == "yellow" ) {
 238                         SV_ChangeTeam( COLOR_TEAM4 - 1 );
 239                 } else if( argv(1) == "auto" ) {
 240                         self.team = -1;
 241                         JoinBestTeam( self, 0 );
 242                 } else {
 243                         sprint( self, strcat( "selectteam none/red/blue/pink/yellow/auto - \"", argv(1), "\" not recognised\n" ) );
 244                 }
 245         } else if(argv(0) == "ready") {
 246                 if(cvar("sv_ready_restart"))
 247                 {
 248                         self.ready = TRUE;
 249                         bprint(self.netname, "^2 is ready\n");
 250                         ReadyCount();
 251                 }
 252         } else if(argv(0) == "say") {
 253                 clientcommand(self, formatmessage(s));
 254         } else if(argv(0) == "say_team") {
 255                 clientcommand(self, formatmessage(s));
 256         } else {
 257                 clientcommand(self,s);
 258         }
 259 }
 260
 261 float ValidateMap(string vote)
 262 {
 263         string ext;
 264
 265         tokenize(vote);
 266         if(argv(0) == "map" || argv(0) == "changelevel")
 267                 ext = ".bsp";
 268         else if(argv(0) == "chmap")
 269                 ext = ".mapcfg";
 270         else
 271                 return TRUE;
 272
 273         if(!TryFile(strcat("maps/", argv(1), ext)))
 274         {
 275                 sprint(self, strcat("^1Invalid mapname, \"^3", argv(1), "^1\" does not exist on this server.\n"));
 276                 return FALSE;
 277         }
 278         return TRUE;
 279 }
 280
 281
 282 void VoteThink() {
 283         if(votefinished > 0 // a vote was called
 284             && time > votefinished) // time is up
 285         {
 286                 VoteCount();
 287         }
 288 }
 289
 290 string VoteParse() {
 291         local float index;
 292         index = 3;
 293         local string vote;
 294         vote = argv(2);
 295         while(argv(index) != "") {
 296                 vote = strcat(vote, " ", argv(index));
 297                 index++;
 298         }
 299
 300         // necessary for some of the string operations
 301         vote = strzone(vote);
 302
 303         // now we remove some things that could be misused
 304         index = 0;
 305         local float found;
 306         found = FALSE;
 307         local float votelength;
 308         votelength = strlen(vote);
 309         while(!found && index < votelength)
 310         {
 311                 local string badchar;
 312                 badchar = substring(vote, index, 1);
 313                 if(badchar == ";"
 314                    || badchar == "\r"
 315                    || badchar == "\n")
 316                 {
 317                         found = TRUE;
 318                 } else {
 319                         index++;
 320                 }
 321         }
 322         return substring(vote, 0, index);
 323 }
 324
 325 float VoteAllowed(string votecommand) {
 326         tokenize(cvar_string("sv_vote_commands"));
 327         local float index;
 328         index = 0;
 329         while(argv(index) != "") {
 330                 local string allowed;
 331                 allowed = argv(index);
 332                 if(votecommand == allowed) {
 333                         return TRUE;
 334                 }
 335                 index++;
 336         }
 337         return FALSE;
 338 }
 339
 340 void VoteReset() {
 341         local string searchclass;
 342         searchclass = "player";
 343
 344         while (TRUE)
 345         {
 346                 local entity player;
 347                 player = find(player, classname, searchclass);
 348                 while(player)
 349                 {
 350                         player.vote_vote = 0;
 351                         player = find(player, classname, searchclass);
 352                 }
 353
 354                 if("player" == searchclass) {
 355                         searchclass = "observer";
 356                 } else if("observer" == searchclass) {
 357                         searchclass = "spectator";
 358                 } else {
 359                         break;
 360                 }
 361         }
 362
 363         votecalled = FALSE;
 364         votecalledmaster = FALSE;
 365         votefinished = 0;
 366 }
 367
 368 void VoteAccept() {
 369         bprint(strcat("^2The vote for \"^1", votecalledvote, "^2\" from \"^7", votecaller.netname, "^2\" was accepted.\n"));
 370         if(votecalledmaster)
 371         {
 372                 votecaller.vote_master = 1;
 373         } else {
 374                 localcmd(votecalledvote);
 375         }
 376         votecaller.vote_next = 0; // people like your votes, no wait for next vote
 377         VoteReset();
 378 }
 379
 380 void VoteReject() {
 381         bprint(strcat("^2The vote for \"^1", votecalledvote, "^2\" from \"^7", votecaller.netname, "^2\" was rejected.\n"));
 382         VoteReset();
 383 }
 384
 385 void VoteTimeout() {
 386         bprint(strcat("^5The vote for \"^1", votecalledvote, "^5\" from \"^7", votecaller.netname, "^5\" did timeout.\n"));
 387         VoteReset();
 388 }
 389
 390 void VoteStop(entity stopper) {
 391         bprint(strcat("^5The vote for \"^1", votecalledvote, "^5\" from \"^7", votecaller.netname, "^5\" was stopped by \"^5", stopper.netname, "^5\".\n"));
 392         if(stopper == votecaller) {
 393                 // no wait for next vote so you can correct your vote
 394                 votecaller.vote_next = 0;
 395         }
 396         VoteReset();
 397 }
 398
 399 void VoteCount() {
 400         local float playercount;
 401         playercount = 0;
 402         local float yescount;
 403         yescount = 0;
 404         local float nocount;
 405         nocount = 0;
 406         local string searchclass;
 407         searchclass = "player";
 408
 409         while (TRUE)
 410         {
 411                 local entity player;
 412                 player = find(player, classname, searchclass);
 413
 414                 while(player)
 415                 {
 416                         if(clienttype(player) != CLIENTTYPE_BOT) {
 417                                 if(player.vote_vote < 0) {
 418                                         nocount++;
 419                                 } else if(player.vote_vote > 0) {
 420                                         yescount++;
 421                                 }
 422                                 playercount++;
 423                         }
 424                         player = find(player, classname, searchclass);
 425                 }
 426
 427                 if("player" == searchclass) {
 428                         searchclass = "observer";
 429                 } else if("observer" == searchclass) {
 430                         searchclass = "specator";
 431                 } else {
 432                         break;
 433                 }
 434         }
 435
 436         if((playercount == 1) && votecalledmaster) {
 437                 // if only one player is on the server becoming vote
 438                 // master is not allowed.  This could be used for
 439                 // trolling or worse. 'self' is the user who has
 440                 // called the vote because this function is called
 441                 // by SV_ParseClientCommand. Maybe all voting should
 442                 // be disabled for a single player?
 443                 sprint(self, "^1You are the only player on this server so you can not become vote master.\n");
 444                 votecaller.vote_next = 0;
 445                 VoteReset();
 446         } else if((playercount / 2) < yescount) { // vote accepted
 447                 VoteAccept();
 448         } else if((playercount / 2) < nocount) { // vote rejected
 449                 VoteReject();
 450         } else if(time > votefinished) { // vote timedout
 451                 VoteTimeout();
 452         } // else still running
 453 }
 454
 455
 456 void ReadyCount()
 457 {
 458         local entity e;
 459         local float r, p;
 460
 461         e = find(world, classname, "player");
 462
 463         while(e)
 464         {
 465                 if(clienttype(e) == CLIENTTYPE_REAL)
 466                 {
 467                         p += 1;
 468                         if(e.ready) r += 1;
 469                 }
 470                 e = find(e, classname, "player");
 471         }
 472
 473         if(p && r == p)
 474         {
 475                 bprint("^1Server is restarting...\n");
 476                 localcmd("restart\n");
 477         }
 478 }