data/qcsrc/server/gamec/cl_player.c

   1 $frame die1 die2 draw duck duckwalk duckjump duckidle idle
   2 $frame jump pain1 pain2 shoot taunt run runbackwards
   3 $frame strafeleft straferight dead1 dead2 forwardright
   4 $frame forwardleft backright backleft
   5
   6 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
   7 // merged player_run and player_stand to player_anim
   8 // added death animations to player_anim
   9 // can now spawn thrown weapons from anywhere, not just from players
  10 // thrown weapons now fade out after 20 seconds
  11 // created PlayerGib function
  12 // PlayerDie no longer uses hitloc or damage
  13 // PlayerDie now supports dying animations as well as gibbing
  14 // cleaned up PlayerDie a lot
  15 // added CopyBody
  16
  17 .entity pusher;
  18 .float pushltime;
  19
  20 void CopyBody(float keepvelocity)
  21 {
  22         local entity oldself;
  23         if (self.effects & EF_NODRAW)
  24                 return;
  25         oldself = self;
  26         self = spawn();
  27         self.colormap = oldself.colormap;
  28         self.iscreature = oldself.iscreature;
  29         self.angles = oldself.angles;
  30         self.avelocity = oldself.avelocity;
  31         self.classname = "body";
  32         self.damageforcescale = oldself.damageforcescale;
  33         self.effects = oldself.effects;
  34         self.event_damage = oldself.event_damage;
  35         self.frame = oldself.frame;
  36         self.health = oldself.health;
  37         self.armorvalue = oldself.armorvalue;
  38         self.armortype = oldself.armortype;
  39         self.model = oldself.model;
  40         self.modelindex = oldself.modelindex;
  41         self.movetype = oldself.movetype;
  42         self.nextthink = oldself.nextthink;
  43         self.skin = oldself.skin;
  44         self.solid = oldself.solid;
  45         self.takedamage = oldself.takedamage;
  46         self.think = oldself.think;
  47         if (keepvelocity == 1)
  48                 self.velocity = oldself.velocity;
  49         self.oldvelocity = self.velocity;
  50         self.fade_time = oldself.fade_time;
  51         self.fade_rate = oldself.fade_rate;
  52         //self.weapon = oldself.weapon;
  53         setorigin(self, oldself.origin);
  54         setsize(self, oldself.mins, oldself.maxs);//'-16 -16 -24',  '16 16 5');
  55         self.oldorigin = oldself.origin;
  56         self = oldself;
  57 }
  58
  59 void player_anim (void)
  60 {
  61         if (self.deadflag != DEAD_NO)
  62         {
  63                 if (time > self.dead_time)
  64                 {
  65                         if (self.maxs_z > 5)
  66                                 setsize(self, '-16 -16 -24', '16 16 5');
  67                         self.frame = self.dead_frame;
  68                 }
  69                 else
  70                         self.frame = self.die_frame;
  71                 return;
  72         }
  73
  74
  75         if (self.crouch)
  76         {
  77                 if (self.movement_x * self.movement_x + self.movement_y * self.movement_y > 20)
  78                         self.frame = $duckwalk;
  79                 else
  80                         self.frame = $duckidle;
  81         }
  82         else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
  83         {
  84                 if (self.movement_x > 0 && self.movement_y == 0)
  85                         self.frame = $run;
  86                 else if (self.movement_x < 0 && self.movement_y == 0)
  87                         self.frame = $runbackwards;
  88                 else if (self.movement_x == 0 && self.movement_y > 0)
  89                         self.frame = $straferight;
  90                 else if (self.movement_x == 0 && self.movement_y < 0)
  91                         self.frame = $strafeleft;
  92                 else if (self.movement_x > 0 && self.movement_y > 0)
  93                         self.frame = $forwardright;
  94                 else if (self.movement_x > 0 && self.movement_y < 0)
  95                         self.frame = $forwardleft;
  96                 else if (self.movement_x < 0 && self.movement_y > 0)
  97                         self.frame = $backright;
  98                 else if (self.movement_x < 0 && self.movement_y < 0)
  99                         self.frame = $backleft;
 100                 else
 101                         self.frame = $run;
 102         }
 103         else if (self.pain_finished > time)
 104                 self.frame = self.pain_frame;
 105         else if (self.attack_finished > time)
 106                 self.frame = $shoot;
 107         else
 108                 self.frame = $idle;
 109
 110         if (!(self.flags & FL_ONGROUND))
 111         {
 112                 if (self.crouch)
 113                         self.frame = $duckidle;         // if player is crouching while in air, show crouch frame
 114                 else
 115                         self.frame = $jump;
 116         }
 117 }
 118 //End change by Supajoe on 11:44 PM EST 11/16/03 (Subject: Player animations)
 119
 120 void SpawnThrownWeapon (vector org, float w)
 121 {
 122         local entity oldself;
 123
 124         if (!cvar("g_pickup_items"))
 125         if (!cvar("g_minstagib"))
 126                 return;
 127         if (w == IT_LASER)
 128                 return;
 129
 130         oldself = self;
 131         self = spawn();
 132         // this will cause it to be removed later
 133         self.classname = "droppedweapon";
 134
 135         setorigin(self, org);
 136         self.velocity = randomvec() * 100 + '0 0 200';
 137         SUB_SetFade(self, time + 20, 1);
 138
 139         if (w == WEP_UZI)
 140                 weapon_uzi ();
 141         else if (w == WEP_SHOTGUN)
 142                 weapon_shotgun ();
 143         else if (w == WEP_GRENADE_LAUNCHER)
 144                 weapon_grenadelauncher ();
 145         else if (w == WEP_ELECTRO)
 146                 weapon_electro ();
 147         else if (w == WEP_CRYLINK)
 148                 weapon_crylink ();
 149         else if (w == WEP_NEX)
 150                 weapon_nex ();
 151         else if (w == WEP_HAGAR)
 152                 weapon_hagar ();
 153         else if (w == WEP_ROCKET_LAUNCHER)
 154                 weapon_rocketlauncher ();
 155
 156         // making absolutely sure...
 157         self.classname = "droppedweapon";
 158
 159         self = oldself;
 160 }
 161
 162 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 163 {
 164         local float take, save;
 165         te_blood (hitloc, force, damage);
 166         // damage resistance (ignore most of the damage from a bullet or similar)
 167         damage = max(damage - 5, 1);
 168
 169         save = bound(0, damage * cvar("g_balance_armor_blockpercent"), self.armorvalue);
 170         take = bound(0, damage - save, damage);
 171
 172         if (save > 10)
 173                 sound (self, CHAN_IMPACT, "misc/armorimpact.wav", 1, ATTN_NORM);
 174         else if (take > 30)
 175                 sound (self, CHAN_IMPACT, "misc/bodyimpact2.wav", 1, ATTN_NORM);
 176         else if (take > 10)
 177                 sound (self, CHAN_IMPACT, "misc/bodyimpact1.wav", 1, ATTN_NORM);
 178
 179         if (take > 50)
 180                 TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.1,1);
 181         if (take > 100)
 182                 TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.2,1);
 183
 184         if (!(self.flags & FL_GODMODE))
 185         {
 186                 self.armorvalue = self.armorvalue - save;
 187                 self.health = self.health - take;
 188                 // pause regeneration for 5 seconds
 189                 self.pauseregen_finished = max(self.pauseregen_finished, time + 5);
 190         }
 191         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 192         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 193         self.dmg_inflictor = inflictor;
 194
 195         if (self.health <= -50)
 196         {
 197                 // don't use any animations as a gib
 198                 self.frame = 0;
 199                 self.dead_frame = 0;
 200                 self.die_frame = 0;
 201                 // view just above the floor
 202                 self.view_ofs = '0 0 4';
 203
 204                 // make a juicy mess
 205                 te_bloodshower (self.origin + self.mins, self.origin + self.maxs, 800, 1000);
 206                 te_bloodshower (self.origin + self.mins, self.origin + self.maxs, 400, 1000);
 207
 208                 // make a meaty mess
 209                 TossGib (self, "models/gibs/eye.md3", self.origin, self.velocity,0);
 210                 TossGib (world, "models/gibs/bloodyskull.md3", self.origin, '0 0 600',0);
 211
 212                 TossGib (world, "models/gibs/gib1.md3", self.origin, self.velocity,0);
 213                 TossGib (world, "models/gibs/gib2.md3", self.origin, self.velocity,0);
 214                 TossGib (world, "models/gibs/gib3.md3", self.origin, self.velocity,0);
 215                 TossGib (world, "models/gibs/gib4.md3", self.origin, self.velocity,0);
 216
 217                 // these destory on impact
 218                 TossGib (world, "models/gibs/gib5.md3", self.origin, '-500 0 450',1);
 219                 TossGib (world, "models/gibs/gib6.md3", self.origin, '0 500 450',1);
 220                 TossGib (world, "models/gibs/chunk.mdl", self.origin, '0 -500 450',1);
 221                 TossGib (world, "models/gibs/chunk.mdl", self.origin, '500 0 450',1);
 222                 TossGib (world, "models/gibs/chunk.mdl", self.origin, self.velocity,1);
 223                 TossGib (world, "models/gibs/chunk.mdl", self.origin, '0 0 450',1);
 224
 225                 sound (trace_ent, CHAN_VOICE, "misc/gib.wav", 1, ATTN_NORM);
 226         }
 227 }
 228
 229 void DropAllRunes(entity pl);
 230
 231
 232 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 233 {
 234         local float take, save;
 235
 236         te_blood (hitloc, force, damage);
 237         if (self.pain_finished < time)          //Don't switch pain sequences like crazy
 238         {
 239                 if (random() > 0.5)
 240                         self.pain_frame = $pain1;
 241                 else
 242                         self.pain_frame = $pain2;
 243                 self.pain_finished = time + 0.5;        //Supajoe
 244         }
 245
 246         if (!cvar("g_minstagib"))
 247         {
 248                 save = bound(0, damage * cvar("g_balance_armor_blockpercent"), self.armorvalue);
 249                 take = bound(0, damage - save, damage);
 250         }
 251         else
 252         {
 253                 save = 0;
 254                 take = damage;
 255         }
 256
 257         if (save > 10)
 258                 sound (self, CHAN_IMPACT, "misc/armorimpact.wav", 1, ATTN_NORM);
 259         else if (take > 30)
 260                 sound (self, CHAN_IMPACT, "misc/bodyimpact2.wav", 1, ATTN_NORM);
 261         else if (take > 10)
 262                 sound (self, CHAN_IMPACT, "misc/bodyimpact1.wav", 1, ATTN_NORM);
 263
 264         if (take > 50)
 265                 TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.1,1);
 266         if (take > 100)
 267                 TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.2,1);
 268
 269         if (!(self.flags & FL_GODMODE))
 270         {
 271                 self.armorvalue = self.armorvalue - save;
 272                 self.health = self.health - take;
 273                 // pause regeneration for 5 seconds
 274                 self.pauseregen_finished = max(self.pauseregen_finished, time + 5);
 275         }
 276         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 277         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 278         self.dmg_inflictor = inflictor;
 279
 280         if(attacker == self)
 281         {
 282                 // don't reset pushltime for self damage as it may be an attempt to
 283                 // escape a lava pit or similar
 284                 //self.pushltime = 0;
 285         }
 286         else if(attacker.classname == "player" || attacker.classname == "gib")
 287         {
 288                 if (self.bot_type == BOT_TYPE_URREBOT || self.bot_type == BOT_TYPE_AUTOURRE)
 289                 if (!self.enemy)
 290                 if (vlen(self.origin - attacker.origin) < 1000)
 291                         self.enemy = attacker;
 292                 self.pusher = attacker;
 293                 self.pushltime = time + cvar("g_maxpushtime");
 294         }
 295         else if(time < self.pushltime)
 296         {
 297                 attacker = self.pusher;
 298                 self.pushltime = max(self.pushltime, time + 0.6);
 299         }
 300         else
 301                 self.pushltime = 0;
 302
 303         if (self.health <= 2)
 304         {
 305                 DropAllRunes(self);
 306                 self.deaths += 1;
 307
 308                 // throw a weapon
 309                 SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.weapon);
 310                 // print an obituary message
 311                 Obituary (attacker, self, deathtype);
 312                 // make the corpse upright (not tilted)
 313                 self.angles_x = 0;
 314                 self.angles_z = 0;
 315                 // don't spin
 316                 self.avelocity = '0 0 0';
 317                 // no weapon when dead
 318                 self.weaponmodel = "";
 319                 w_clear();
 320                 // view from the floor
 321                 self.view_ofs = '0 0 -8';
 322                 // toss the corpse
 323                 self.movetype = MOVETYPE_TOSS;
 324                 // shootable corpse
 325                 self.solid = SOLID_CORPSE;
 326                 // don't stick to the floor
 327                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 328                 // dying animation
 329                 self.deadflag = DEAD_DYING;
 330                 // when to allow respawn
 331                 self.death_time = time + 0.5;
 332                 // when to switch to the dead_frame
 333                 self.dead_time = time + 2;
 334                 if (random() < 0.5)
 335                 {
 336                         self.die_frame = $die1;
 337                         self.dead_frame = $dead1;
 338                 }
 339                 else
 340                 {
 341                         self.die_frame = $die2;
 342                         self.dead_frame = $dead2;
 343                 }
 344                 // start the animation
 345                 player_anim();
 346                 // set damage function to corpse damage
 347                 self.event_damage = PlayerCorpseDamage;
 348                 // call the corpse damage function just in case it wants to gib
 349                 self.event_damage(inflictor, attacker, 0, deathtype, hitloc, force);
 350                 // set up to fade out later
 351                 SUB_SetFade (self, time + 12 + random () * 4, 1);
 352         }
 353 }
 354