data/qcsrc/server/gamec/cl_physics.c

   1 float sv_accelerate;
   2 float sv_maxairspeed;
   3 float sv_friction;
   4 float sv_maxspeed;
   5 float sv_stopspeed;
   6 float sv_gravity;
   7 .float ladder_time;
   8 .entity ladder_entity;
   9 .float gravity;
  10 .float swamp_slowdown;
  11 .float lastflags;
  12
  13 void Nixnex_GiveCurrentWeapon();
  14 void SV_PlayerPhysics()
  15 {
  16         local vector wishvel, wishdir, v;
  17         local float wishspeed, f, maxspd_mod, spd, maxairspd, airaccel, swapspd_mod;
  18         string temps;
  19
  20         Nixnex_GiveCurrentWeapon();
  21
  22         // MauveBot_AI();
  23         if (clienttype(self) == CLIENTTYPE_BOT)
  24         {
  25                 if (self.bot_type == BOT_TYPE_MAUVEBOT || self.bot_type == BOT_TYPE_AUTOMAUVE)
  26                         MauveBot_AI();
  27                 else if (self.bot_type == BOT_TYPE_URREBOT || self.bot_type == BOT_TYPE_AUTOURRE)
  28                         UrreBotThink();
  29         }
  30
  31         if (self.movetype == MOVETYPE_NONE)
  32                 return;
  33
  34         if (self.punchangle != '0 0 0')
  35         {
  36                 f = vlen(self.punchangle) - 10 * frametime;
  37                 if (f > 0)
  38                         self.punchangle = normalize(self.punchangle) * f;
  39                 else
  40                         self.punchangle = '0 0 0';
  41         }
  42
  43         if (self.punchvector != '0 0 0')
  44         {
  45                 f = vlen(self.punchvector) - 30 * frametime;
  46                 if (f > 0)
  47                         self.punchvector = normalize(self.punchvector) * f;
  48                 else
  49                         self.punchvector = '0 0 0';
  50         }
  51
  52         maxspd_mod = 1;
  53
  54         if(cvar("g_runematch"))
  55         {
  56                 if(self.runes & RUNE_SPEED)
  57                 {
  58                         if(self.runes & CURSE_SLOW)
  59                                 maxspd_mod = maxspd_mod * cvar("g_balance_rune_speed_combo_moverate");
  60                         else
  61                                 maxspd_mod = maxspd_mod * cvar("g_balance_rune_speed_moverate");
  62                 }
  63                 else if(self.runes & CURSE_SLOW)
  64                 {
  65                         maxspd_mod = maxspd_mod * cvar("g_balance_curse_slow_moverate");
  66                 }
  67         }
  68
  69         if(cvar("g_minstagib") && (self.items & IT_INVINCIBLE))
  70         {
  71                 maxspd_mod = maxspd_mod * cvar("g_balance_rune_speed_moverate");
  72         }
  73
  74         swapspd_mod = 1;
  75         if(self.in_swamp != 0) {
  76                 swapspd_mod = self.swamp_slowdown; //cvar("g_balance_swamp_moverate");
  77         }
  78
  79
  80         spd = sv_maxspeed * maxspd_mod;
  81         spd = sv_maxspeed * swapspd_mod;
  82
  83         if(self.speed != spd)
  84         {
  85                 self.speed = spd;
  86                 temps = ftos(spd);
  87                 stuffcmd(self, strcat("cl_forwardspeed ", temps, "\n"));
  88                 stuffcmd(self, strcat("cl_backspeed ", temps, "\n"));
  89                 stuffcmd(self, strcat("cl_sidespeed ", temps, "\n"));
  90                 stuffcmd(self, strcat("cl_upspeed ", temps, "\n"));
  91
  92                 temps = ftos(sv_accelerate * maxspd_mod);
  93                 stuffcmd(self, strcat("cl_movement_accelerate ", temps, "\n"));
  94         }
  95
  96         // if dead, behave differently
  97         if (self.deadflag)
  98                 return;
  99
 100         if (!self.fixangle)
 101         {
 102                 self.angles_x = 0;
 103                 self.angles_y = self.v_angle_y;
 104                 self.angles_z = 0;
 105         }
 106
 107         if (self.flags & FL_WATERJUMP )
 108         {
 109                 self.velocity_x = self.movedir_x;
 110                 self.velocity_y = self.movedir_y;
 111                 if (time > self.teleport_time || self.waterlevel == 0)
 112                 {
 113                         self.flags = self.flags - (self.flags & FL_WATERJUMP);
 114                         self.teleport_time = 0;
 115                 }
 116         }
 117         else if (self.movetype == MOVETYPE_NOCLIP || self.movetype == MOVETYPE_FLY)
 118         {
 119                 // noclipping or flying
 120                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 121
 122                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 123                 makevectors(self.v_angle);
 124                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 125                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 126                 // acceleration
 127                 wishdir = normalize(wishvel);
 128                 wishspeed = vlen(wishvel);
 129                 if (wishspeed > sv_maxspeed*maxspd_mod)
 130                         wishspeed = sv_maxspeed*maxspd_mod;
 131                 if (time >= self.teleport_time)
 132                 {
 133                         f = wishspeed - (self.velocity * wishdir);
 134                         if (f > 0)
 135                                 self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 136                 }
 137         }
 138         else if (self.waterlevel >= 2)
 139         {
 140                 // swimming
 141                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 142
 143                 makevectors(self.v_angle);
 144                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 145                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 146                 if (wishvel == '0 0 0')
 147                         wishvel = '0 0 -60'; // drift towards bottom
 148
 149                 wishdir = normalize(wishvel);
 150                 wishspeed = vlen(wishvel);
 151                 if (wishspeed > sv_maxspeed*maxspd_mod)
 152                         wishspeed = sv_maxspeed*maxspd_mod;
 153                 wishspeed = wishspeed * 0.7;
 154
 155                 // water friction
 156                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 157
 158                 // water acceleration
 159                 f = wishspeed - (self.velocity * wishdir);
 160                 if (f > 0)
 161                         self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 162         }
 163         else if (time < self.ladder_time)
 164         {
 165                 // on a func_ladder or swimming in func_water
 166                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 167
 168                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 169                 makevectors(self.v_angle);
 170                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 171                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 172                 if (self.gravity)
 173                         self.velocity_z = self.velocity_z + self.gravity * sv_gravity * frametime;
 174                 else
 175                         self.velocity_z = self.velocity_z + sv_gravity * frametime;
 176                 if (self.ladder_entity.classname == "func_water")
 177                 {
 178                         f = vlen(wishvel);
 179                         if (f > self.ladder_entity.speed)
 180                                 wishvel = wishvel * (self.ladder_entity.speed / f);
 181
 182                         self.watertype = self.ladder_entity.skin;
 183                         f = self.ladder_entity.origin_z + self.ladder_entity.maxs_z;
 184                         if ((self.origin_z + self.view_ofs_z) < f)
 185                                 self.waterlevel = 3;
 186                         else if ((self.origin_z + (self.mins_z + self.maxs_z) * 0.5) < f)
 187                                 self.waterlevel = 2;
 188                         else if ((self.origin_z + self.mins_z + 1) < f)
 189                                 self.waterlevel = 1;
 190                         else
 191                         {
 192                                 self.waterlevel = 0;
 193                                 self.watertype = CONTENT_EMPTY;
 194                         }
 195                 }
 196                 // acceleration
 197                 wishdir = normalize(wishvel);
 198                 wishspeed = vlen(wishvel);
 199                 if (wishspeed > sv_maxspeed)
 200                         wishspeed = sv_maxspeed;
 201                 if (time >= self.teleport_time)
 202                 {
 203                         f = wishspeed - (self.velocity * wishdir);
 204                         if (f > 0)
 205                                 self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 206                 }
 207         }
 208         else if (self.flags & FL_ONGROUND)
 209         {
 210                 // walking
 211                 makevectors(self.v_angle_y * '0 1 0');
 212                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
 213
 214                 if(!(self.lastflags & FL_ONGROUND))
 215                 {
 216                         dprint(strcat("landing velocity: ", vtos(self.velocity), " (abs: ", ftos(vlen(self.velocity)), ")\n"));
 217                         self.velocity = self.velocity * (1 - cvar("sv_friction_on_land"));
 218                 }
 219
 220                 if (self.velocity_x || self.velocity_y)
 221                 if (!(self.flags & FL_JUMPRELEASED) || !self.button2)
 222                 {
 223                         v = self.velocity;
 224                         v_z = 0;
 225                         f = vlen(v);
 226                         if (f < sv_stopspeed)
 227                                 f = 1 - frametime * (sv_stopspeed / f) * sv_friction;
 228                         else
 229                                 f = 1 - frametime * sv_friction;
 230                         if (f > 0)
 231                                 self.velocity = self.velocity * f;
 232                         else
 233                                 self.velocity = '0 0 0';
 234                 }
 235                 // acceleration
 236                 wishdir = normalize(wishvel);
 237                 wishspeed = vlen(wishvel);
 238                 if (wishspeed > sv_maxspeed*maxspd_mod)
 239                         wishspeed = sv_maxspeed*maxspd_mod;
 240                 if (self.crouch)
 241                         wishspeed = wishspeed * 0.5;
 242                 if (time >= self.teleport_time)
 243                 {
 244                         f = wishspeed - (self.velocity * wishdir);
 245                         if (f > 0)
 246                                 self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 247                 }
 248         }
 249         else
 250         {
 251                 if(maxspd_mod < 1)
 252                 {
 253                         maxairspd = sv_maxairspeed*maxspd_mod;
 254                         airaccel = sv_accelerate*maxspd_mod;
 255                 }
 256                 else
 257                 {
 258                         maxairspd = sv_maxairspeed;
 259                         airaccel = sv_accelerate;
 260                 }
 261                 // airborn
 262                 makevectors(self.v_angle_y * '0 1 0');
 263                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
 264                 // acceleration
 265                 wishdir = normalize(wishvel);
 266                 wishspeed = vlen(wishvel);
 267                 if (wishspeed > maxairspd)
 268                         wishspeed = maxairspd;
 269                 if (self.crouch)
 270                         wishspeed = wishspeed * 0.5;
 271                 if (time >= self.teleport_time)
 272                 {
 273                         f = wishspeed;// - (self.velocity * wishdir);
 274                         if (f > 0)
 275                                 self.velocity = self.velocity + wishdir * min(f, airaccel * frametime * wishspeed);
 276                 }
 277         }
 278         self.lastflags = self.flags;
 279 };