data/qcsrc/server/gamec/cl_client.c

   1 void info_player_start (void)
   2 {
   3         self.classname = "info_player_deathmatch";
   4 }
   5
   6 void info_player_deathmatch (void)
   7 {
   8 }
   9
  10 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
  11 {
  12         local entity spot, player, nextspot, previousspot, newfirstspot;
  13         local float pcount;
  14         spot = firstspot;
  15         newfirstspot = world;
  16         previousspot = world;
  17         while (spot)
  18         {
  19                 nextspot = spot.chain;
  20                 // count team mismatches as bad spots
  21                 if (spot.team == teamcheck)
  22                 {
  23                         pcount = 0;
  24                         player = playerlist;
  25                         while (player)
  26                         {
  27                                 if (player != self)
  28                                 if (vlen(player.origin - spot.origin) < mindist)
  29                                         pcount = pcount + 1;
  30                                 player = player.chain;
  31                         }
  32                         if (!pcount)
  33                         {
  34                                 if (newfirstspot)
  35                                         previousspot.chain = spot;
  36                                 else
  37                                         newfirstspot = spot;
  38                                 previousspot = spot;
  39                                 spot.chain = world;
  40                         }
  41                 }
  42                 spot = nextspot;
  43         }
  44         // if we couldn't find ANY good points, return the original list
  45         if (!newfirstspot)
  46                 newfirstspot = firstspot;
  47         return newfirstspot;
  48 }
  49
  50 entity Spawn_RandomPoint(entity firstspot)
  51 {
  52         local entity spot;
  53         local float numspots;
  54         // count number of spots
  55         numspots = 0;
  56         spot = firstspot;
  57         while (spot)
  58         {
  59                 numspots = numspots + 1;
  60                 spot = spot.chain;
  61         }
  62         // pick a random one
  63         numspots = numspots * random();
  64         spot = firstspot;
  65         while (spot.chain && numspots >= 1)
  66         {
  67                 numspots = numspots - 1;
  68                 spot = spot.chain;
  69         }
  70         return spot;
  71 }
  72
  73 entity Spawn_FurthestPoint(entity firstspot, entity playerlist)
  74 {
  75         local entity best, spot, player;
  76         local float bestrating, rating;
  77         best = world;
  78         bestrating = -1000000;
  79         spot = firstspot;
  80         while (spot)
  81         {
  82                 rating = 1000000000;
  83                 player = playerlist;
  84                 while (player)
  85                 {
  86                         if (player != self)
  87                                 rating = min(rating, vlen(player.origin - spot.origin));
  88                         player = player.chain;
  89                 }
  90                 rating = rating + random() * 16;
  91                 if (bestrating < rating)
  92                 {
  93                         best = spot;
  94                         bestrating = rating;
  95                 }
  96                 spot = spot.chain;
  97         }
  98         return best;
  99 }
 100
 101 /*
 102 =============
 103 SelectSpawnPoint
 104
 105 Finds a point to respawn
 106 =============
 107 */
 108 entity SelectSpawnPoint (float anypoint)
 109 {
 110         local float teamcheck;
 111         local entity spot, firstspot, playerlist;
 112         string spotname;
 113
 114         spot = find (world, classname, "testplayerstart");
 115         if (spot)
 116                 return spot;
 117
 118         spotname = "info_player_deathmatch";
 119         teamcheck = 0;
 120
 121         if(!anypoint && cvar("g_ctf") )
 122                 teamcheck = self.team;
 123
 124         // get the list of players
 125         playerlist = findchain(classname, "player");
 126         // get the entire list of spots
 127         firstspot = findchain(classname, "info_player_deathmatch");
 128         // filter out the bad ones
 129         // (note this returns the original list if none survived)
 130         firstspot = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 131
 132         // there is 50/50 chance of choosing a random spot or the furthest spot
 133         // (this means that roughly every other spawn will be furthest, so you
 134         // usually won't get fragged at spawn twice in a row)
 135         if (random() > 0.5)
 136                 spot = Spawn_RandomPoint(firstspot);
 137         else
 138                 spot = Spawn_FurthestPoint(firstspot, playerlist);
 139
 140         if (!spot)
 141                 error ("PutClientInServer: no start points on level");
 142
 143         return spot;
 144 }
 145
 146 /*
 147 =============
 148 CheckPlayerModel
 149
 150 Checks if the argument string can be a valid playermodel.
 151 Returns a valid one in doubt.
 152 =============
 153 */
 154 string CheckPlayerModel(string plyermodel) {
 155         if( substring(plyermodel,0,14) != "models/player/") plyermodel = "models/player/marine.zym";
 156
 157         /* Possible Fixme: Check if server can open the model?
 158            This would kill custom models, however. */
 159
 160         return plyermodel;
 161 }
 162
 163 /*
 164 =============
 165 PutObserverInServer
 166
 167 putting a client as observer in the server
 168 =============
 169 */
 170 void PutObserverInServer (void)
 171 {
 172         entity  spot;
 173         spot = SelectSpawnPoint (FALSE);
 174         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 175
 176         if(self.frags == 0 && cvar("g_lms") && self.killcount != -666)
 177                 bprint (strcat("^4", self.netname, "^4 has no more lives left\n"));
 178         else if(self.killcount != -666)
 179                 bprint (strcat("^4", self.netname, "^4 is spectating now\n"));
 180
 181         self.classname = "observer";
 182         self.health = -666;
 183         self.takedamage = DAMAGE_NO;
 184         self.solid = SOLID_NOT;
 185         self.movetype = MOVETYPE_NOCLIP;
 186         self.flags = FL_CLIENT | FL_NOTARGET;
 187         self.armorvalue = 666;
 188         self.effects = 0;
 189         self.armorvalue = cvar("g_balance_armor_start");
 190         self.pauserotarmor_finished = 0;
 191         self.pauserothealth_finished = 0;
 192         self.pauseregen_finished = 0;
 193         self.damageforcescale = 0;
 194         self.death_time = 0;
 195         self.dead_time = 0;
 196         self.dead_frame = 0;
 197         self.die_frame = 0;
 198         self.deaths = 0;
 199         self.alpha = 0;
 200         self.scale = 0;
 201         self.fade_time = 0;
 202         self.pain_frame = 0;
 203         self.pain_finished = 0;
 204         self.strength_finished = 0;
 205         self.invincible_finished = 0;
 206         self.pushltime = 0;
 207         self.think = SUB_Null;
 208         self.nextthink = 0;
 209         self.hook_time = 0;
 210         self.runes = 0;
 211         self.deadflag = DEAD_NO;
 212         self.angles = spot.angles;
 213         self.angles_z = 0;
 214         self.fixangle = TRUE;
 215         self.crouch = FALSE;
 216         self.view_ofs = PL_VIEW_OFS;
 217         setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 14));
 218         self.oldorigin = self.origin;
 219         self.items = 0;
 220         self.model = "";
 221         self.modelindex = 0;
 222         self.weapon = 0;
 223         self.weaponmodel = "";
 224         self.weaponframe = 0;
 225         self.weaponentity = world;
 226         self.killcount = -666;
 227         if(!cvar("g_lms"))
 228                 self.frags = -666;
 229         //stuffcmd(self, "set viewsize 120 \n");
 230 //      bprint (strcat("^4", self.netname, "^4 is spectating now\n"));
 231 }
 232
 233
 234 /*
 235 =============
 236 PutClientInServer
 237
 238 Called when a client spawns in the server
 239 =============
 240 */
 241 void PutClientInServer (void)
 242 {
 243         if(clienttype(self) ==  CLIENTTYPE_BOT)
 244         {
 245                 self.classname = "player";
 246         }
 247
 248         // player is dead and becomes observer
 249         if(cvar("g_lms") && self.frags < 1)
 250                 self.classname = "observer";
 251
 252         if(self.classname == "player") {
 253                 entity  spot;
 254
 255                 spot = SelectSpawnPoint (FALSE);
 256
 257                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 258
 259                 self.classname = "player";
 260                 self.iscreature = TRUE;
 261                 self.movetype = MOVETYPE_WALK;
 262                 self.solid = SOLID_SLIDEBOX;
 263                 self.flags = FL_CLIENT;
 264                 self.takedamage = DAMAGE_AIM;
 265                 self.effects = 0;
 266                 self.health = cvar("g_balance_health_start");
 267                 self.armorvalue = cvar("g_balance_armor_start");
 268                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 269                 self.pauserotarmor_finished = time + 10;
 270                 self.pauserothealth_finished = time + 10;
 271                 self.pauseregen_finished = 0;
 272                 self.damageforcescale = 2;
 273                 self.death_time = 0;
 274                 self.dead_time = 0;
 275                 self.dead_frame = 0;
 276                 self.die_frame = 0;
 277                 self.alpha = 0;
 278                 self.scale = 0;
 279                 self.fade_time = 0;
 280                 self.pain_frame = 0;
 281                 self.pain_finished = 0;
 282                 self.strength_finished = 0;
 283                 self.invincible_finished = 0;
 284                 self.pushltime = 0;
 285                 //self.speed_finished = 0;
 286                 //self.slowmo_finished = 0;
 287                 // players have no think function
 288                 self.think = SUB_Null;
 289                 self.nextthink = 0;
 290                 self.weapon = 0;
 291                 self.switchweapon = 0;
 292                 self.hook_time = 0;
 293
 294                 self.runes = 0;
 295
 296                 self.deadflag = DEAD_NO;
 297
 298                 self.angles = spot.angles;
 299
 300                 self.angles_z = 0; // never spawn tilted even if the spot says to
 301                 self.fixangle = TRUE; // turn this way immediately
 302                 self.velocity = '0 0 0';
 303                 self.avelocity = '0 0 0';
 304                 self.punchangle = '0 0 0';
 305                 self.punchvector = '0 0 0';
 306                 self.oldvelocity = self.velocity;
 307
 308                 self.viewzoom = 0.6;
 309
 310                 if(cvar("sv_defaultcharacter") == 1) {
 311                         local string defaultmodel;
 312                         defaultmodel = CheckPlayerModel(cvar_string("sv_defaultplayermodel"));
 313
 314                         precache_model (defaultmodel);
 315                         setmodel (self, defaultmodel);
 316                         self.skin = stof(cvar_string("sv_defaultplayerskin"));
 317                 } else {
 318                         self.playermodel = CheckPlayerModel(self.playermodel);
 319
 320                         precache_model (self.playermodel);
 321                         setmodel (self, self.playermodel);
 322                         self.skin = stof(self.playerskin);
 323
 324                 }
 325
 326                 self.crouch = FALSE;
 327                 self.view_ofs = PL_VIEW_OFS;
 328                 setsize (self, PL_MIN, PL_MAX);
 329                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 330                 // don't reset back to last position, even if new position is stuck in solid
 331                 self.oldorigin = self.origin;
 332
 333                 if(cvar("g_lms"))
 334                 {
 335                         self.ammo_shells = cvar("g_lms_start_ammo_shells");
 336                         self.ammo_nails = cvar("g_lms_start_ammo_nails");
 337                         self.ammo_rockets = cvar("g_lms_start_ammo_rockets");
 338                         self.ammo_cells = cvar("g_lms_start_ammo_cells");
 339                         self.health = cvar("g_lms_start_health");
 340                         self.armorvalue = cvar("g_lms_start_armor");
 341                 }
 342                 else if (cvar("g_use_ammunition")) {
 343                         self.ammo_shells = cvar("g_start_ammo_shells");
 344                         self.ammo_nails = cvar("g_start_ammo_nails");
 345                         self.ammo_rockets = cvar("g_start_ammo_rockets");
 346                         self.ammo_cells = cvar("g_start_ammo_cells");
 347                 } else {
 348                         self.ammo_shells = 999;
 349                         self.ammo_nails = 999;
 350                         self.ammo_rockets = 999;
 351                         self.ammo_cells = 999;
 352                 }
 353
 354                 self.items = 0;
 355                 if (cvar("g_start_weapon_laser") || cvar("g_lms"))
 356                 {
 357                         self.items = self.items | IT_LASER;
 358                         self.switchweapon = WEP_LASER;
 359                 }
 360                 if (cvar("g_start_weapon_shotgun") || cvar("g_lms"))
 361                 {
 362                         self.items = self.items | IT_SHOTGUN;
 363                         self.switchweapon = WEP_SHOTGUN;
 364                 }
 365                 if (cvar("g_start_weapon_uzi") || cvar("g_lms"))
 366                 {
 367                         self.items = self.items | IT_UZI;
 368                         self.switchweapon = WEP_UZI;
 369                 }
 370                 if (cvar("g_start_weapon_grenadelauncher") || cvar("g_lms"))
 371                 {
 372                         self.items = self.items | IT_GRENADE_LAUNCHER;
 373                         self.switchweapon = WEP_GRENADE_LAUNCHER;
 374                 }
 375                 if (cvar("g_start_weapon_electro") || cvar("g_lms"))
 376                 {
 377                         self.items = self.items | IT_ELECTRO;
 378                         self.switchweapon = WEP_ELECTRO;
 379                 }
 380                 if (cvar("g_start_weapon_crylink") || cvar("g_lms"))
 381                 {
 382                         self.items = self.items | IT_CRYLINK;
 383                         self.switchweapon = WEP_CRYLINK;
 384                 }
 385                 if (cvar("g_start_weapon_nex") || cvar("g_lms"))
 386                 {
 387                         self.items = self.items | IT_NEX;
 388                         self.switchweapon = WEP_NEX;
 389                 }
 390                 if (cvar("g_start_weapon_hagar") || cvar("g_lms"))
 391                 {
 392                         self.items = self.items | IT_HAGAR;
 393                         self.switchweapon = WEP_HAGAR;
 394                 }
 395                 if (cvar("g_start_weapon_rocketlauncher") || cvar("g_lms"))
 396                 {
 397                         self.items = self.items | IT_ROCKET_LAUNCHER;
 398                         self.switchweapon = WEP_ROCKET_LAUNCHER;
 399                 }
 400
 401                 if(cvar("g_instagib"))
 402                 {
 403                         self.items = IT_NEX;
 404                         self.switchweapon = WEP_NEX;
 405                         self.ammo_cells = 999;
 406                 }
 407
 408                 if(cvar("g_rocketarena"))
 409                 {
 410                         self.items = IT_ROCKET_LAUNCHER;
 411                         self.switchweapon = WEP_ROCKET_LAUNCHER;
 412                         self.ammo_rockets = 999;
 413                 }
 414
 415                 if(cvar("g_minstagib"))
 416                 {
 417                         self.health = 100;
 418                         self.armorvalue = 0;
 419                         self.items = IT_NEX;
 420                         self.switchweapon = WEP_NEX;
 421                         self.ammo_cells = cvar("g_minstagib_ammo_start");
 422                         self.extralives = 0;
 423                         self.jump_interval = time;
 424                 }
 425
 426                 self.event_damage = PlayerDamage;
 427
 428                 self.statdraintime = time + 5;
 429                 self.button0 = self.button1 = self.button2 = self.button3 = 0;
 430
 431                 if(self.killcount == -666) {
 432                         self.killcount = 0;
 433                         self.frags = 0;
 434                 }
 435
 436                 self.cnt = WEP_LASER;
 437
 438                 /*
 439                 W_UpdateWeapon();
 440                 W_UpdateAmmo();
 441                 */
 442                 CL_SpawnWeaponentity();
 443                 self.alpha = 1;
 444                 self.exteriorweaponentity.alpha = 1;
 445
 446                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 447                 self.lms_traveled_distance = 0;
 448
 449                 //stuffcmd(self, "chase_active 0");
 450                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 451         } else if(self.classname == "observer") {
 452                 PutObserverInServer ();
 453         }
 454 }
 455
 456 /*
 457 =============
 458 SetNewParms
 459 =============
 460 */
 461 void SetNewParms (void)
 462 {
 463
 464 }
 465
 466 /*
 467 =============
 468 SetChangeParms
 469 =============
 470 */
 471 void SetChangeParms (void)
 472 {
 473
 474 }
 475
 476 /*
 477 =============
 478 ClientKill
 479
 480 Called when a client types 'kill' in the console
 481 =============
 482 */
 483 void ClientKill (void)
 484 {
 485         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 486 }
 487
 488 /*
 489 =============
 490 ClientConnect
 491
 492 Called when a client connects to the server
 493 =============
 494 */
 495 string ColoredTeamName(float t);
 496 //void dom_player_join_team(entity pl);
 497 void ClientConnect (void)
 498 {
 499         self.classname = "player_joining";
 500
 501         if(player_count<0) player_count = 0;
 502
 503         //if(cvar("g_domination"))
 504         //      dom_player_join_team(self);
 505
 506         //JoinBestTeam(self, FALSE);
 507
 508         if(cvar("sv_spectate") == 1 && !cvar("g_lms")) {
 509                 self.classname = "observer";
 510         } else {
 511                 self.classname = "player";
 512         }
 513
 514         //stuffcmd(self, "set tmpviewsize $viewsize \n");
 515
 516         bprint ("^4",self.netname);
 517         bprint ("^4 connected");
 518
 519         if(cvar("g_domination") || cvar("g_ctf"))
 520         {
 521                 bprint(" and joined the ");
 522                 bprint(ColoredTeamName(self.team));
 523         }
 524
 525         bprint("\n");
 526
 527         self.welcomemessage_time = time + cvar("welcome_message_time");
 528         self.welcomemessage_time2 = 0;
 529
 530         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
 531         // send prediction settings to the client
 532         stuffcmd(self, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
 533         stuffcmd(self, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
 534         stuffcmd(self, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
 535         stuffcmd(self, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
 536         stuffcmd(self, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
 537         stuffcmd(self, strcat("cl_movement_jumpvelocity ", ftos(cvar("g_balance_jumpheight")), "\n"));
 538         stuffcmd(self, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
 539         stuffcmd(self, strcat("cl_movement_edgefriction 0\n"));
 540         // Wazat's grappling hook
 541         SetGrappleHookBindings();
 542
 543         // get autoswitch state from player
 544         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1; cmd autoswitch $1\"\n");
 545         stuffcmd(self, "cmd autoswitch $cl_autoswitch\n");
 546
 547         // get version info from player
 548         stuffcmd(self, "cmd clientversion $gameversion\n");
 549
 550         // set cvar for team scoreboard
 551         stuffcmd(self, strcat("set teamplay ", ftos(teams_matter), "\n"));
 552
 553         if(cvar("g_lms"))
 554         {
 555                 self.frags = cvar("fraglimit");
 556                 // no fraglimit was set, so player gets 999 lives
 557                 if(self.frags < 1)
 558                         self.frags = 999;
 559
 560                 // disallow player to join after the worst player has lost g_lms_last_join lives
 561                 // if "g_lms_join_anytime" new players spawn with same amount of lives as the worst active player
 562                 if(((cvar("fraglimit") - cvar("g_lms_last_join")) > lms_lowest_lives && !cvar("g_lms_join_anytime")) || lms_lowest_lives < 1)
 563                 {
 564                         self.frags = -1;
 565                         lms_dead_count += 1;
 566                 }
 567                 else if(cvar("fraglimit") > lms_lowest_lives)
 568                 {
 569                         self.frags = lms_lowest_lives;
 570                 }
 571         }
 572
 573         player_count += 1;
 574         self.jointime = time;
 575 }
 576
 577 /*
 578 =============
 579 ClientDisconnect
 580
 581 Called when a client disconnects from the server
 582 =============
 583 */
 584 void(entity e) DropFlag;
 585 .entity chatbubbleentity;
 586 .entity teambubbleentity;
 587 void ClientDisconnect (void)
 588 {
 589         bprint ("^4",self.netname);
 590         bprint ("^4 disconnected\n");
 591
 592         if (self.chatbubbleentity)
 593         {
 594                 remove (self.chatbubbleentity);
 595                 self.chatbubbleentity = world;
 596         }
 597
 598         if (self.teambubbleentity)
 599         {
 600                 remove (self.teambubbleentity);
 601                 self.teambubbleentity = world;
 602         }
 603
 604         DropAllRunes(self);
 605
 606         if(self.flagcarried)
 607                 DropFlag(self.flagcarried);
 608
 609         // decrease player count for lms
 610         player_count -= 1;
 611         // player was dead, decrease dead count
 612         if(cvar("g_lms") && self.frags < 1)
 613                 lms_dead_count -= 1;
 614         //stuffcmd(self, "set viewsize $tmpviewsize \n");
 615 }
 616
 617 .float buttonchat;
 618 void() ChatBubbleThink =
 619 {
 620         self.nextthink = time;
 621         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
 622         {
 623                 remove(self);
 624                 return;
 625         }
 626         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
 627         if (self.owner.buttonchat && !self.owner.deadflag)
 628                 self.model = self.mdl;
 629         else
 630                 self.model = "";
 631 };
 632
 633 void() UpdateChatBubble =
 634 {
 635         if (!self.modelindex)
 636                 return;
 637         // spawn a chatbubble entity if needed
 638         if (!self.chatbubbleentity)
 639         {
 640                 self.chatbubbleentity = spawn();
 641                 self.chatbubbleentity.owner = self;
 642                 self.chatbubbleentity.exteriormodeltoclient = self;
 643                 self.chatbubbleentity.think = ChatBubbleThink;
 644                 self.chatbubbleentity.nextthink = time;
 645                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr");
 646                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 647                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
 648                 self.chatbubbleentity.model = "";
 649         }
 650 }
 651
 652
 653 void() TeamBubbleThink =
 654 {
 655         self.nextthink = time;
 656         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
 657         {
 658                 remove(self);
 659                 return;
 660         }
 661 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
 662         if (self.owner.buttonchat || self.owner.deadflag)
 663                 self.model = "";
 664         else
 665                 self.model = self.mdl;
 666
 667 };
 668
 669 .float() customizeentityforclient;
 670 float() ChatBubble_customizeentityforclient = {return (self.owner.team == other.team && other.killcount > -666);};
 671
 672 void() UpdateTeamBubble =
 673 {
 674         if (!self.modelindex || !cvar("teamplay"))
 675                 return;
 676         // spawn a teambubble entity if needed
 677         if (!self.teambubbleentity && cvar("teamplay"))
 678         {
 679                 self.teambubbleentity = spawn();
 680                 self.teambubbleentity.owner = self;
 681                 self.teambubbleentity.exteriormodeltoclient = self;
 682                 self.teambubbleentity.think = TeamBubbleThink;
 683                 self.teambubbleentity.nextthink = time;
 684                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr");
 685 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 686                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
 687                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
 688                 self.teambubbleentity.mdl = self.teambubbleentity.model;
 689                 self.teambubbleentity.model = self.teambubbleentity.mdl;
 690                 self.teambubbleentity.customizeentityforclient = ChatBubble_customizeentityforclient;
 691         }
 692 }
 693
 694 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
 695 // added to the model skins
 696 /*void() UpdateColorModHack =
 697 {
 698         local float c;
 699         c = self.clientcolors & 15;
 700         // LordHavoc: only bothering to support white, green, red, yellow, blue
 701              if (teamplay == 0) self.colormod = '0 0 0';
 702         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
 703         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
 704         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
 705         else if (c == 12) self.colormod = '1.22 1.22 0.10';
 706         else if (c == 13) self.colormod = '0.10 0.10 1.73';
 707         else self.colormod = '1 1 1';
 708 };*/
 709
 710 void UpdatePlayerColors () {
 711         if(self.weaponentity) {
 712                 self.weaponentity.colormap = self.colormap;
 713                 self.exteriorweaponentity.colormap = self.colormap;
 714         }
 715 }
 716 /*
 717 =============
 718 PlayerJump
 719
 720 When you press the jump key
 721 =============
 722 */
 723 void PlayerJump (void)
 724 {
 725         float mjumpheight;
 726
 727         mjumpheight = cvar("g_balance_jumpheight");
 728         if (self.waterlevel >= 2)
 729         {
 730                 if (self.watertype == CONTENT_WATER)
 731                         self.velocity_z = 200;
 732                 else if (self.watertype == CONTENT_SLIME)
 733                         self.velocity_z = 80;
 734                 else
 735                         self.velocity_z = 50;
 736
 737                 return;
 738         }
 739
 740
 741         if (!(self.flags & FL_ONGROUND))
 742                 return;
 743
 744         if (!(self.flags & FL_JUMPRELEASED))
 745                 return;
 746
 747         if(cvar("g_runematch"))
 748         {
 749                 if(self.runes & RUNE_SPEED)
 750                 {
 751                         if(self.runes & CURSE_SLOW)
 752                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_combo_jumpheight");
 753                         else
 754                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
 755                 }
 756                 else if(self.runes & CURSE_SLOW)
 757                 {
 758                         mjumpheight = mjumpheight * cvar("g_balance_curse_slow_jumpheight");
 759                 }
 760         }
 761
 762         if(cvar("g_minstagib") && (self.items & IT_INVINCIBLE))
 763         {
 764                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
 765         }
 766
 767         self.velocity_z = self.velocity_z + mjumpheight;
 768         self.oldvelocity_z = self.velocity_z;
 769
 770         self.flags = self.flags - FL_ONGROUND;
 771         self.flags = self.flags - FL_JUMPRELEASED;
 772 }
 773
 774 void() CheckWaterJump =
 775 {
 776         local vector start, end;
 777
 778 // check for a jump-out-of-water
 779         makevectors (self.angles);
 780         start = self.origin;
 781         start_z = start_z + 8;
 782         v_forward_z = 0;
 783         normalize(v_forward);
 784         end = start + v_forward*24;
 785         traceline (start, end, TRUE, self);
 786         if (trace_fraction < 1)
 787         {       // solid at waist
 788                 start_z = start_z + self.maxs_z - 8;
 789                 end = start + v_forward*24;
 790                 self.movedir = trace_plane_normal * -50;
 791                 traceline (start, end, TRUE, self);
 792                 if (trace_fraction == 1)
 793                 {       // open at eye level
 794                         self.flags = self.flags | FL_WATERJUMP;
 795                         self.velocity_z = 225;
 796                         self.flags = self.flags - (self.flags & FL_JUMPRELEASED);
 797                         self.teleport_time = time + 2;  // safety net
 798                         return;
 799                 }
 800         }
 801 };
 802
 803
 804 void respawn(void)
 805 {
 806         CopyBody(1);
 807         PutClientInServer();
 808 }
 809
 810 void player_powerups (void)
 811 {
 812         if (cvar("g_minstagib"))
 813         {
 814                 self.effects = EF_FULLBRIGHT;
 815                 if (self.items & IT_STRENGTH)
 816                 {
 817                         if (time > self.strength_finished)
 818                         {
 819                                 self.alpha = 1;
 820                                 self.exteriorweaponentity.alpha = 1;
 821                                 self.items = self.items - (self.items & IT_STRENGTH);
 822                                 sprint(self, "^3Invisibility has worn off\n");
 823                         }
 824                 }
 825                 else
 826                 {
 827                         if (time < self.strength_finished)
 828                         {
 829                                 self.alpha = cvar("g_minstagib_invis_alpha");
 830                                 self.exteriorweaponentity.alpha = cvar("g_minstagib_invis_alpha");
 831                                 self.items = self.items | IT_STRENGTH;
 832                                 sprint(self, "^3You are invisible\n");
 833                         }
 834                 }
 835
 836                 if (self.items & IT_INVINCIBLE)
 837                 {
 838                         if (time > self.invincible_finished)
 839                         {
 840                                 self.items = self.items - (self.items & IT_INVINCIBLE);
 841                                 sprint(self, "^3Speed has worn off\n");
 842                         }
 843                 }
 844                 else
 845                 {
 846                         if (time < self.invincible_finished)
 847                         {
 848                                 self.items = self.items | IT_INVINCIBLE;
 849                                 sprint(self, "^3You are on speed\n");
 850                         }
 851                 }
 852                 return;
 853         }
 854
 855         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
 856         if (self.items & IT_STRENGTH)
 857         {
 858                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
 859                 if (time > self.strength_finished)
 860                 {
 861                         self.items = self.items - (self.items & IT_STRENGTH);
 862                         sprint(self, "^3Strength has worn off\n");
 863                 }
 864         }
 865         else
 866         {
 867                 if (time < self.strength_finished)
 868                 {
 869                         self.items = self.items | IT_STRENGTH;
 870                         sprint(self, "^3Strength infuses your weapons with devestating power\n");
 871                 }
 872         }
 873         if (self.items & IT_INVINCIBLE)
 874         {
 875                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
 876                 if (time > self.invincible_finished)
 877                 {
 878                         self.items = self.items - (self.items & IT_INVINCIBLE);
 879                         sprint(self, "^3Shield has worn off\n");
 880                 }
 881         }
 882         else
 883         {
 884                 if (time < self.invincible_finished)
 885                 {
 886                         self.items = self.items | IT_INVINCIBLE;
 887                         sprint(self, "^3Shield surrounds you\n");
 888                 }
 889         }
 890
 891         if (cvar("g_fullbrightplayers"))
 892                 self.effects = self.effects | EF_FULLBRIGHT;
 893
 894         // midair gamemode: damage only while in the air
 895         // if in midair mode, being on ground grants temporary invulnerability
 896         // (this is so that multishot weapon don't clear the ground flag on the
 897         // first damage in the frame, leaving the player vulnerable to the
 898         // remaining hits in the same frame)
 899         if (self.flags & FL_ONGROUND)
 900         if (cvar("g_midair"))
 901                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
 902
 903         if (time < self.spawnshieldtime)
 904                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
 905 }
 906
 907 void player_regen (void)
 908 {
 909         float maxh, maxa, max_mod, regen_mod, rot_mod;
 910         maxh = cvar("g_balance_health_stable");
 911         maxa = cvar("g_balance_armor_stable");
 912
 913         if (cvar("g_minstagib") || (cvar("g_lms") && !cvar("g_lms_regenerate")))
 914                 return;
 915
 916         if(cvar("g_runematch"))
 917         {
 918                 max_mod = regen_mod = rot_mod = 1;
 919                 if (self.runes & RUNE_REGEN)
 920                 {
 921                         if (self.runes & CURSE_VENOM) // do we have both rune/curse?
 922                         {
 923                                 regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
 924                                 max_mod = cvar("g_balance_rune_regen_combo_hpmod");
 925                         }
 926                         else
 927                         {
 928                                 regen_mod = cvar("g_balance_rune_regen_regenrate");
 929                                 max_mod = cvar("g_balance_rune_regen_hpmod");
 930                         }
 931                 }
 932                 else if (self.runes & CURSE_VENOM)
 933                 {
 934                         max_mod = cvar("g_balance_curse_venom_hpmod");
 935                         if (self.runes & RUNE_REGEN) // do we have both rune/curse?
 936                                 rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
 937                         else
 938                                 rot_mod = cvar("g_balance_curse_venom_rotrate");
 939                         //if (!self.runes & RUNE_REGEN)
 940                         //      rot_mod = cvar("g_balance_curse_venom_rotrate");
 941                 }
 942                 maxh = maxh * max_mod;
 943                 //maxa = maxa * max_mod;
 944
 945                 if (time > self.pauserotarmor_finished)
 946                 {
 947                         if (self.armorvalue > maxa)
 948                                 self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime, 1000);
 949                 }
 950                 if (time > self.pauserothealth_finished)
 951                 {
 952                         if (self.health > maxh)
 953                                 self.health = bound(0, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime, 1000);
 954                 }
 955                 if (time > self.pauseregen_finished)
 956                 {
 957                         if (self.health < maxh)
 958                                 self.health = bound(0, self.health + (maxh- self.health) * regen_mod*cvar("g_balance_health_regen") * frametime, 1000);
 959                         if (self.armorvalue < maxa)
 960                                 self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_regen") * frametime, 1000);
 961                 }
 962         }
 963         else
 964         {
 965                 if (time > self.pauserothealth_finished)
 966                 if (self.health > maxh)
 967                         self.health = bound(0, self.health + (maxh - self.health) * cvar("g_balance_health_rot") * frametime, 1000);
 968                 if (time > self.pauserotarmor_finished)
 969                 if (self.armorvalue > maxa)
 970                         self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime, 1000);
 971                 if (time > self.pauseregen_finished)
 972                 {
 973                         if (self.health < maxh)
 974                                  self.health = bound(0, self.health + (maxh - self.health) * cvar("g_balance_health_regen") * frametime + 0.001, 1000);
 975                         if (self.armorvalue < maxa)
 976                                 self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_regen") * frametime + 0.001, 1000);
 977                 }
 978         }
 979 }
 980
 981 /*
 982 ======================
 983 spectate mode routines
 984 ======================
 985 */
 986 void SpectateCopy(entity spectatee) {
 987         self.armortype = spectatee.armortype;
 988         self.armorvalue = spectatee.armorvalue;
 989         self.currentammo = spectatee.currentammo;
 990         self.effects = spectatee.effects;
 991         self.health = spectatee.health;
 992         self.impulse = 0;
 993         self.items = spectatee.items;
 994         self.punchangle = spectatee.punchangle;
 995         self.view_ofs = spectatee.view_ofs;
 996         self.v_angle = spectatee.v_angle;
 997         self.viewzoom = spectatee.viewzoom;
 998         setorigin(self, spectatee.origin);
 999         setsize(self, spectatee.mins, spectatee.maxs);
1000 }
1001
1002 void SpectateUpdate() {
1003         if (self != self.enemy) {
1004                 SpectateCopy(self.enemy);
1005                 msg_entity = self;
1006                 WriteByte(MSG_ONE, SVC_SETANGLE);
1007                 WriteAngle(MSG_ONE, self.enemy.v_angle_x);
1008                 WriteAngle(MSG_ONE, self.enemy.v_angle_y);
1009                 WriteAngle(MSG_ONE, self.enemy.v_angle_z);
1010         }
1011 }
1012
1013 float SpectateNext() {
1014         other = find(self.enemy, classname, "player");
1015         if (!other) {
1016                 other = find(other, classname, "player");
1017         }
1018         if (other) {
1019                 self.enemy = other;
1020         }
1021         if(self.enemy.classname == "player") {
1022                 msg_entity = self;
1023                 WriteByte(MSG_ONE, SVC_SETVIEW);
1024                 WriteEntity(MSG_ONE, self.enemy);
1025                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1026                 SpectateUpdate();
1027                 return 1;
1028         } else {
1029                 return 0;
1030         }
1031 }
1032
1033 /*
1034 =============
1035 PlayerPreThink
1036
1037 Called every frame for each client before the physics are run
1038 =============
1039 */
1040 void PlayerPreThink (void)
1041 {
1042         if(self.classname == "player") {
1043                 local vector m1, m2;
1044
1045 //              MauveBot_AI();
1046
1047 //              if(self.netname == "Wazat")
1048 //                      bprint(strcat(self.classname, "\n"));
1049
1050                 CheckRules_Player();
1051
1052                 if(self.button7)
1053                         PrintWelcomeMessage(self);
1054
1055                 if(cvar("g_lms") || !cvar("sv_spectate"))
1056                 if((time - self.jointime) <= cvar("welcome_message_time"))
1057                         PrintWelcomeMessage(self);
1058
1059                 if (intermission_running)
1060                 {
1061                         IntermissionThink ();   // otherwise a button could be missed between
1062                         return;                                 // the think tics
1063                 }
1064
1065                 if (self.deadflag != DEAD_NO)
1066                 {
1067                         player_anim();
1068                         weapon_freeze();
1069                         if (self.deadflag == DEAD_DYING)
1070                         {
1071                                 if (time > self.dead_time)
1072                                         self.deadflag = DEAD_DEAD;
1073                         }
1074                         else if (self.deadflag == DEAD_DEAD)
1075                         {
1076                                 if (cvar("g_lms") || cvar("g_forced_respawn"))
1077                                         self.button0 = self.button2 = self.button3 = 0;
1078
1079                                 if (!self.button0 && !self.button2 && !self.button3)
1080                                         self.deadflag = DEAD_RESPAWNABLE;
1081                         }
1082                         else if (self.deadflag == DEAD_RESPAWNABLE)
1083                         {
1084                                 if (self.button0  ||
1085                                     self.button2  ||
1086                                     self.button3  ||
1087                                     self.button4  ||
1088                                     cvar("g_lms") ||
1089                                     cvar("g_forced_respawn"))
1090                                         respawn();
1091                         }
1092                         return;
1093                 }
1094
1095                 if(cvar("g_lms") && !self.deadflag && cvar("g_lms_campcheck_interval"))
1096                 {
1097                         vector dist;
1098
1099                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
1100                         dist = self.oldorigin - self.origin;
1101                         dist_z = 0;
1102                         self.lms_traveled_distance += fabs(vlen(dist));
1103
1104                         if(time > self.lms_nextcheck)
1105                         {
1106                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
1107                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
1108                                 {
1109                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
1110                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
1111                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
1112                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
1113                                 }
1114                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
1115                                 self.lms_traveled_distance = 0;
1116                         }
1117                 }
1118
1119                 if (self.button5)
1120                 {
1121                         if (!self.crouch)
1122                         {
1123                                 self.crouch = TRUE;
1124                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
1125                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
1126                         }
1127                 }
1128                 else
1129                 {
1130                         if (self.crouch)
1131                         {
1132                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
1133                                 if (!trace_startsolid)
1134                                 {
1135                                         self.crouch = FALSE;
1136                                         self.view_ofs = PL_VIEW_OFS;
1137                                         setsize (self, PL_MIN, PL_MAX);
1138                                 }
1139                         }
1140                 }
1141
1142                 if(cvar("sv_defaultcharacter") == 1) {
1143                         local string defaultmodel;
1144                         defaultmodel = CheckPlayerModel(cvar_string("sv_defaultplayermodel"));
1145
1146                         if (defaultmodel != self.model)
1147                         {
1148                                 m1 = self.mins;
1149                                 m2 = self.maxs;
1150                                 precache_model (defaultmodel);
1151                                 setmodel (self, defaultmodel);
1152                                 setsize (self, m1, m2);
1153                         }
1154
1155                         if (self.skin != stof(cvar_string("sv_defaultplayerskin")))
1156                                 self.skin = stof(cvar_string("sv_defaultplayerskin"));
1157                 } else {
1158                         if (self.playermodel != self.model)
1159                         {
1160                                 self.playermodel = CheckPlayerModel(self.playermodel);
1161                                 m1 = self.mins;
1162                                 m2 = self.maxs;
1163                                 precache_model (self.playermodel);
1164                                 setmodel (self, self.playermodel);
1165                                 setsize (self, m1, m2);
1166                         }
1167
1168                         if (self.skin != stof(self.playerskin))
1169                                 self.skin = stof(self.playerskin);
1170                 }
1171                 // Savage: Check for nameless players
1172                 if (strlen(self.netname) < 1) {
1173                         self.netname = "Player";
1174                         stuffcmd(self, "name Player\n");
1175                 }
1176
1177                 GrapplingHookFrame();
1178
1179                 W_WeaponFrame();
1180
1181                 if (self.button4 || (self.weapon == WEP_NEX && self.button3))
1182                 {
1183                         if (cvar("g_minstagib") && self.button3)
1184                         {
1185                                 if (self.jump_interval <= (time + 0.1))
1186                                 {
1187                                         self.jump_interval = time + 1;
1188                                         weapon_doattack(laser_check, laser_check, W_Laser_Attack);
1189                                 }
1190                         }
1191                         else if (self.viewzoom > 0.4)
1192                                 self.viewzoom = max (0.4, self.viewzoom - frametime * 2);
1193                 }
1194                 else if (self.viewzoom < 1.0)
1195                         self.viewzoom = min (1.0, self.viewzoom + frametime);
1196
1197
1198                 if (self.button2)
1199                         PlayerJump ();
1200                 else
1201                         self.flags = self.flags | FL_JUMPRELEASED;
1202
1203                 player_powerups();
1204                 player_regen();
1205                 player_anim();
1206
1207                 //self.angles_y=self.v_angle_y + 90;   // temp
1208
1209                 if (self.waterlevel == 2)
1210                         CheckWaterJump ();
1211
1212                 //if (TetrisPreFrame()) return;
1213         } else if(gameover) {
1214                 if (intermission_running)
1215                         IntermissionThink ();   // otherwise a button could be missed between
1216                 return;
1217         } else if(self.classname == "observer") {
1218
1219                 if (self.flags & FL_JUMPRELEASED) {
1220                         if (self.button2 && self.version == cvar("gameversion")) {
1221                                 if(!cvar("teamplay")) {
1222                                         self.flags = self.flags & !FL_JUMPRELEASED;
1223                                         self.classname = "player";
1224                                         if(!cvar("g_lms"))
1225                                                 bprint (strcat("^4", self.netname, "^4 is playing now\n"));
1226                                         PutClientInServer();
1227                                         centerprint(self,"");
1228                                         return;
1229                                 } else {
1230                                         self.flags = self.flags & !FL_JUMPRELEASED;
1231                                         stuffcmd(self,"menu_showteamselect\n");
1232                                         return;
1233                                 }
1234                         } else if(self.button0 && self.version == cvar("gameversion")) {
1235                                 self.flags = self.flags & !FL_JUMPRELEASED;
1236                                 if(SpectateNext() == 1) {
1237                                         self.classname = "spectator";
1238                                 }
1239                         }
1240                 } else {
1241                         if (!(self.button0 || self.button2)) {
1242                                 self.flags = self.flags | FL_JUMPRELEASED;
1243                         }
1244                 }
1245                 if(cvar("g_lms") && self.frags == 0)
1246                         centerprint(self, "\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n^1You have no more lives left\nwait for next round\n\n\n^7press attack to spectate other players");
1247                 else if(cvar("g_lms") && self.frags == -1)
1248                         centerprint(self, "\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n^1Match has already begun\nwait for next round\n\n\n^7press attack to spectate other players");
1249                 else
1250                         PrintWelcomeMessage(self);
1251                         //centerprint(self, "\n\n\npress jump to play\npress attack to spectate other players");
1252         } else if(self.classname == "spectator") {
1253
1254                 if (self.flags & FL_JUMPRELEASED) {
1255                         if (self.button2 && self.version == cvar("gameversion")) {
1256                                 if(!cvar("teamplay")) {
1257                                         self.flags = self.flags & !FL_JUMPRELEASED;
1258                                         self.classname = "player";
1259                                         if(!cvar("g_lms"))
1260                                                 bprint (strcat("^4", self.netname, "^4 is playing now\n"));
1261
1262                                         msg_entity = self;
1263                                         WriteByte(MSG_ONE, SVC_SETVIEW);
1264                                         WriteEntity(MSG_ONE, self);
1265                                         PutClientInServer();
1266                                         centerprint(self,"");
1267                                         return;
1268                                 } else {
1269                                         self.flags = self.flags & !FL_JUMPRELEASED;
1270                                         stuffcmd(self,"menu_showteamselect\n");
1271                                         return;
1272                                 }
1273                         } else if(self.button0) {
1274                                 self.flags = self.flags & !FL_JUMPRELEASED;
1275                                 if(SpectateNext() == 1) {
1276                                         self.classname = "spectator";
1277                                 } else {
1278                                         self.classname = "observer";
1279                                         msg_entity = self;
1280                                         WriteByte(MSG_ONE, SVC_SETVIEW);
1281                                         WriteEntity(MSG_ONE, self);
1282                                         PutClientInServer();
1283                                 }
1284                         } else if (self.button3) {
1285                                 self.flags = self.flags & !FL_JUMPRELEASED;
1286                                 self.classname = "observer";
1287                                 msg_entity = self;
1288                                 WriteByte(MSG_ONE, SVC_SETVIEW);
1289                                 WriteEntity(MSG_ONE, self);
1290                                 PutClientInServer();
1291                         } else {
1292                                 SpectateUpdate();
1293                         }
1294         } else {
1295                 if (!(self.button0 || self.button3)) {
1296                         self.flags = self.flags | FL_JUMPRELEASED;
1297                 }
1298                 }
1299                 if (cvar("g_lms") && self.frags < 1)
1300                         centerprint(self, strcat("\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\nspectating ", self.enemy.netname, "\n\n\n^7press attack for next player\npress attack2 for free fly mode"));
1301                 else
1302                         centerprint(self, strcat("\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\nspectating ", self.enemy.netname, "\n\n\n^7press jump to play\n^7press attack for next player\npress attack2 for free fly mode"));
1303
1304         }
1305 }
1306
1307 /*
1308 =============
1309 PlayerPostThink
1310
1311 Called every frame for each client after the physics are run
1312 =============
1313 */
1314 void PlayerPostThink (void)
1315 {
1316         if(self.classname == "player") {
1317                 CheckRules_Player();
1318                 UpdateChatBubble();
1319                 UpdateTeamBubble();
1320                 UpdatePlayerColors();
1321                 if (self.deadflag == DEAD_NO)
1322                 if (self.impulse)
1323                         ImpulseCommands ();
1324                 if (intermission_running)
1325                         return;         // intermission or finale
1326
1327                 //PrintWelcomeMessage(self);
1328                 //if (TetrisPostFrame()) return;
1329         } else if (self.classname == "observer") {
1330                 //do nothing
1331         } else if (self.classname == "spectator") {
1332                 //do nothing
1333         }
1334 }