data/qcsrc/server/gamec/campaign.c

   1 // campaign cvars:
   2 //   _campaign_index: index of CURRENT map
   3 //   g_campaign_index: index of current LAST map (saved)
   4 //   g_campaign_skill: bot skill offset
   5
   6 float campaign_level;
   7 float campaign_won;
   8
   9 void(string s) CampaignBailout =
  10 {
  11         //bprint(strcat("campaign initialization failed: ", s, "\n"));
  12         cvar_set("g_campaign", "0");
  13         error(strcat("campaign initialization failed: ", s, "\n"));
  14         return;
  15 }
  16
  17 string fstrunzone(string s)
  18 {
  19         string t;
  20         t = strcat(s);
  21         strunzone(s);
  22         return t;
  23 }
  24
  25 // NOTE: s may not be a tempstring here
  26 string Campaign_wordwrap(string s, float l)
  27 {
  28         string t;
  29         string word;
  30
  31         float lleft;
  32         float i;
  33
  34         float startidx;
  35
  36         startidx = 0;
  37
  38         t = strzone("");
  39
  40         lleft = l;
  41         for(i = 0; i <= strlen(s); ++i)
  42         {
  43                 if(i != strlen(s) && substring(s, i, 1) != " ")
  44                         continue;
  45
  46                 word = substring(s, startidx, i - startidx);
  47                 startidx = i + 1;
  48
  49                 if(word == "+++")
  50                 {
  51                         t = fstrunzone(t);
  52                         t = strzone(strcat(t, "\n"));
  53                         lleft = l;
  54                 }
  55                 else if(strlen(word) < lleft)
  56                 {
  57                         t = fstrunzone(t);
  58                         if(lleft != l)
  59                         {
  60                                 t = strcat(t, " ");
  61                                 lleft = lleft - 1;
  62                         }
  63                         t = strzone(strcat(t, word));
  64                         lleft = lleft - strlen(word);
  65                 }
  66                 else
  67                 {
  68                         t = fstrunzone(t);
  69                         t = strzone(strcat(t, "\n", word));
  70                         lleft = l - strlen(word);
  71                 }
  72         }
  73         t = fstrunzone(t);
  74         return t;
  75 }
  76
  77 void() CampaignPreInit =
  78 {
  79         float baseskill;
  80         string title;
  81         campaign_level = cvar("_campaign_index");
  82         CampaignFile_Load(campaign_level, 2);
  83         if(campaign_entries < 1)
  84                 return CampaignBailout("unknown map");
  85         cvar_set("bot_number", ftos(campaign_bots[0]));
  86
  87         baseskill = cvar("g_campaign_skill");
  88         baseskill = baseskill + campaign_botskill[0];
  89         if(baseskill < 0)
  90                 baseskill = 0;
  91         cvar_set("skill", ftos(baseskill));
  92
  93         title = campaign_shortdesc[0];
  94         campaign_message = strzone(strcat("\n\n\n\n\n\n\n\n\n\n^1\n", title, "\n^3\n", Campaign_wordwrap(campaign_longdesc[0], 50)));
  95 }
  96
  97 string GetMapname();
  98 void() CampaignPostInit =
  99 {
 100         // now some sanity checks
 101         string thismapname;
 102         thismapname = GetMapname();
 103         if(campaign_mapcfgname[0] != thismapname)
 104                 return CampaignBailout(strcat("wrong map: ", campaign_mapcfgname[0], " != ", thismapname));
 105         cvar_set("fraglimit", ftos(campaign_fraglimit[0]));
 106         cvar_set("timelimit", "0");
 107 }
 108
 109 void() CampaignPreIntermission =
 110 {
 111         entity head;
 112         float won;
 113         float lost;
 114
 115         won = 0;
 116
 117         head = findchain(classname, "player");
 118         while(head)
 119         {
 120                 if(clienttype(head) == CLIENTTYPE_REAL)
 121                 {
 122                         if(head.winning)
 123                                 won = won + 1;
 124                         else
 125                                 lost = lost + 1;
 126                 }
 127                 head = head.chain;
 128         }
 129
 130         if(won == 1 && lost == 0)
 131         {
 132                 campaign_won = 1;
 133                 bprint("The current level has been WON.\n");
 134                 // sound!
 135         }
 136         else
 137         {
 138                 campaign_won = 0;
 139                 bprint("The current level has been LOST.\n");
 140                 // sound!
 141         }
 142
 143         if(campaign_won)
 144         {
 145                 if(campaign_level == cvar("g_campaign_index"))
 146                 {
 147                         // advance level
 148                         localcmd("set g_campaign_index ");
 149                         localcmd(ftos(campaign_level + 1));
 150                         localcmd("\n");
 151                 }
 152                 if(campaign_entries < 2)
 153                 {
 154                         localcmd("set g_campaign_index 0\n");
 155                         localcmd("set g_campaign_won 1\n");
 156                 }
 157         }
 158 }
 159
 160 void() CampaignPostIntermission =
 161 {
 162         // NOTE: campaign_won is 0 or 1, that is, points to the next level
 163
 164         if(campaign_won && campaign_entries < 2)
 165         {
 166                 // last map won!
 167                 localcmd("togglemenu\n");
 168                 CampaignFile_Unload();
 169                 return;
 170         }
 171
 172         CampaignSetup(campaign_won);
 173         CampaignFile_Unload();
 174         strunzone(campaign_message);
 175 }
 176
 177
 178
 179 void(float n) CampaignLevelWarp =
 180 {
 181         if(!cvar("sv_cheats"))
 182                 return;
 183         CampaignFile_Unload();
 184         CampaignFile_Load(n, 1);
 185         if(campaign_entries)
 186                 CampaignSetup(0);
 187         else
 188                 error("Sorry, cheater. You are NOT WELCOME.");
 189         CampaignFile_Unload();
 190 }