data/qcsrc/server/g_world.qc

   1 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
   2 string redirection_target;
   3 float world_initialized;
   4
   5 string GetMapname();
   6 string GetGametype();
   7 void GotoNextMap();
   8 void ShuffleMaplist()
   9 float() DoNextMapOverride;
  10
  11 void SetDefaultAlpha()
  12 {
  13         if(cvar("g_running_guns"))
  14         {
  15                 default_player_alpha = -1;
  16                 default_weapon_alpha = +1;
  17         }
  18         else if(g_cloaked)
  19         {
  20                 default_player_alpha = cvar("g_balance_cloaked_alpha");
  21                 default_weapon_alpha = default_player_alpha;
  22         }
  23         else
  24         {
  25                 default_player_alpha = cvar("g_player_alpha");
  26                 if(default_player_alpha <= 0)
  27                         default_player_alpha = 1;
  28                 default_weapon_alpha = default_player_alpha;
  29         }
  30 }
  31
  32 void fteqcc_testbugs()
  33 {
  34         float a, b;
  35
  36         if(!cvar("developer_fteqccbugs"))
  37                 return;
  38
  39         dprint("*** fteqcc test: checking for bugs...\n");
  40
  41         a = 1;
  42         b = 5;
  43         if(sqrt(a) - sqrt(b - a) == 0)
  44                 dprint("*** fteqcc test: found same-function-twice bug\n");
  45         else
  46                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  47
  48         world.cnt = -10;
  49         world.enemy = world;
  50         world.enemy.cnt += 10;
  51         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
  52                 dprint("*** fteqcc test: found += bug\n");
  53         else
  54                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  55         world.cnt = 0;
  56 }
  57
  58 /**
  59  * Takes care of pausing and unpausing the game.
  60  * Centerprints the information about an upcoming or active timeout to all active
  61  * players. Also plays reminder sounds.
  62  */
  63 void timeoutHandler_Think() {
  64         local string timeStr;
  65         local entity plr;
  66         if (timeoutStatus == 1) {
  67                 if (remainingLeadTime > 0) {
  68                         //centerprint the information to every player
  69                         timeStr = getTimeoutText(0);
  70                         FOR_EACH_REALCLIENT(plr) {
  71                                 if(plr.classname == "player") {
  72                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
  73                                 }
  74                         }
  75                         remainingLeadTime -= 1;
  76                         //think again in 1 second:
  77                         self.nextthink = time + 1;
  78                 }
  79                 else {
  80                         //now pause the game:
  81                         timeoutStatus = 2;
  82                         cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
  83                         //copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
  84                         FOR_EACH_REALPLAYER(plr) {
  85                                 plr.lastV_angle = plr.v_angle;
  86                         }
  87                         self.nextthink = time;
  88                 }
  89         }
  90         else if (timeoutStatus == 2) {
  91                 if (remainingTimeoutTime > 0) {
  92                         timeStr = getTimeoutText(0);
  93                         FOR_EACH_REALCLIENT(plr) {
  94                                 if(plr.classname == "player") {
  95                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
  96                                 }
  97                         }
  98                         if(remainingTimeoutTime == cvar("sv_timeout_resumetime")) { //play a warning sound when only <sv_timeout_resumetime> seconds are left
  99                                 play2all("announcer/robotic/prepareforbattle.wav");
 100                         }
 101                         remainingTimeoutTime -= 1;
 102                         self.nextthink = time + TIMEOUT_SLOWMO_VALUE;
 103                 }
 104                 else {
 105                         //unpause the game again
 106                         remainingTimeoutTime = timeoutStatus = 0;
 107                         cvar_set("slowmo", ftos(orig_slowmo));
 108                         //and unlock the fixed view again once there is no timeout active anymore
 109                         FOR_EACH_REALPLAYER(plr) {
 110                                 plr.fixangle = FALSE;
 111                         }
 112                         //get rid of the countdown message
 113                         FOR_EACH_REALCLIENT(plr) {
 114                                 if(plr.classname == "player") {
 115                                         centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 116                                 }
 117                         }
 118                         remove(self);
 119                         return;
 120                 }
 121
 122         }
 123         else if (timeoutStatus == 0) { //if a player called the resumegame command (which set timeoutStatus to 0 already)
 124                 FOR_EACH_REALCLIENT(plr) {
 125                         if(plr.classname == "player") {
 126                                 centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 127                         }
 128                 }
 129                 remove(self);
 130                 return;
 131         }
 132 }
 133
 134 float GotoFirstMap()
 135 {
 136         if(cvar("_sv_init"))
 137         {
 138                 cvar_set("_sv_init", "0");
 139                 if(cvar("g_maplist_shuffle"))
 140                         ShuffleMaplist();
 141                 tokenizebyseparator(cvar_string("g_maplist"), " ");
 142                 {
 143                         cvar_set("nextmap", argv(0));
 144
 145                         MapInfo_Enumerate();
 146                         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? MAPINFO_FLAG_HIDDEN : 0), 0);
 147
 148                         if(!DoNextMapOverride())
 149                                 GotoNextMap();
 150
 151                         return 1;
 152                 }
 153         }
 154         return 0;
 155 }
 156
 157 void cvar_changes_init()
 158 {
 159         float fh;
 160         string s, k, v, d;
 161         float n;
 162
 163         if(cvar_changes)
 164                 strunzone(cvar_changes);
 165         cvar_changes = string_null;
 166         fh = fopen("cvars.txt", FILE_READ);
 167         if(fh < 0)
 168                 return;
 169         while((s = fgets(fh)))
 170         {
 171                 n = tokenize_sane(s);
 172                 if(n < 1)
 173                         continue;
 174                 if(argv(0) == "//")
 175                         continue;
 176                 k = argv(0);
 177                 v = cvar_string(k);
 178                 d = cvar_defstring(k);
 179                 if(v != d)
 180                 {
 181                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 182                         if(strlen(cvar_changes) > 16384)
 183                         {
 184                                 cvar_changes = "// too many settings have been changed to show them here\n";
 185                                 break;
 186                         }
 187                 }
 188         }
 189         fclose(fh);
 190         if(cvar_changes == "")
 191                 cvar_changes = "// this server runs at default settings\n";
 192         else
 193                 cvar_changes = strcat("// this server runs at modified settings:\n", cvar_changes);
 194         cvar_changes = strzone(cvar_changes);
 195 }
 196
 197 float world_already_spawned;
 198 void RegisterWeapons();
 199 void Nagger_Init();
 200 void spawnfunc_worldspawn (void)
 201 {
 202         float fd, l;
 203         string s;
 204
 205         dprint_load(); // load dprint status from cvar
 206
 207         if(world_already_spawned)
 208                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 209         world_already_spawned = TRUE;
 210
 211         remove = remove_safely; // during spawning, watch what you remove!
 212
 213         compressShortVector_init();
 214
 215         local entity head;
 216         head = nextent(world);
 217         maxclients = 0;
 218         while(head)
 219         {
 220                 ++maxclients;
 221                 head = nextent(head);
 222         }
 223
 224         // needs to be done so early as they would still spawn
 225         RegisterWeapons();
 226
 227         if(GotoFirstMap())
 228         {
 229                 world_initialized = -1; // don't complain
 230                 return;
 231         }
 232
 233         if(sv_cheats)
 234                 ServerProgsDB = db_create();
 235         else
 236                 ServerProgsDB = db_load("server.db");
 237
 238         TemporaryDB = db_create();
 239
 240         /*
 241         TODO sound pack system
 242         // initialize sound pack system
 243         soundpack = cvar_string("g_soundpack");
 244         if(soundpack != "")
 245                 soundpack = strcat(soundpack, "/");
 246         soundpack = strzone(soundpack);
 247         */
 248
 249         // 0 normal
 250         lightstyle(0, "m");
 251
 252         // 1 FLICKER (first variety)
 253         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 254
 255         // 2 SLOW STRONG PULSE
 256         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 257
 258         // 3 CANDLE (first variety)
 259         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 260
 261         // 4 FAST STROBE
 262         lightstyle(4, "mamamamamama");
 263
 264         // 5 GENTLE PULSE 1
 265         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 266
 267         // 6 FLICKER (second variety)
 268         lightstyle(6, "nmonqnmomnmomomno");
 269
 270         // 7 CANDLE (second variety)
 271         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 272
 273         // 8 CANDLE (third variety)
 274         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 275
 276         // 9 SLOW STROBE (fourth variety)
 277         lightstyle(9, "aaaaaaaazzzzzzzz");
 278
 279         // 10 FLUORESCENT FLICKER
 280         lightstyle(10, "mmamammmmammamamaaamammma");
 281
 282         // 11 SLOW PULSE NOT FADE TO BLACK
 283         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 284
 285         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 286
 287         // 63 testing
 288         lightstyle(63, "a");
 289
 290         if(cvar("g_campaign"))
 291                 CampaignPreInit();
 292
 293         InitGameplayMode();
 294         readlevelcvars();
 295         GrappleHookInit();
 296
 297         player_count = 0;
 298         bot_waypoints_for_items = cvar("g_waypoints_for_items");
 299         if(bot_waypoints_for_items == 1)
 300                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 301                         bot_waypoints_for_items = 0;
 302
 303         // for setting by mapinfo
 304         q3acompat_machineshotgunswap = cvar("sv_q3acompat_machineshotgunswap");
 305         cvar_set("sv_q3acompat_machineshotgunswap", "0");
 306
 307         precache();
 308
 309         WaypointSprite_Init();
 310
 311         //if (g_domination)
 312         //      dom_init();
 313
 314         GameLogInit(); // prepare everything
 315         if(cvar("sv_eventlog"))
 316         {
 317                 s = strcat(cvar_string("sv_eventlog_files_counter"), ".");
 318                 s = strcat(s, ftos(random()));
 319                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 320                 s = ":gameinfo:mutators:LIST";
 321                 if(cvar("g_grappling_hook"))
 322                         s = strcat(s, ":grappling_hook");
 323                 if(!cvar("g_use_ammunition"))
 324                         s = strcat(s, ":no_use_ammunition");
 325                 if(!cvar("g_pickup_items"))
 326                         s = strcat(s, ":no_pickup_items");
 327                 if(cvar("g_instagib"))
 328                         s = strcat(s, ":instagib");
 329                 if(cvar_string("g_weaponarena") != "0")
 330                         s = strcat(s, ":", cvar_string("g_weaponarena"), " arena");
 331                 if(cvar("g_nixnex"))
 332                         s = strcat(s, ":nixnex");
 333                 if(cvar("g_vampire"))
 334                         s = strcat(s, ":vampire");
 335                 if(cvar("g_laserguided_missile"))
 336                         s = strcat(s, ":laserguided_missile");
 337                 if(cvar("g_norecoil"))
 338                         s = strcat(s, ":norecoil");
 339                 if(cvar("g_midair"))
 340                         s = strcat(s, ":midair");
 341                 if(cvar("g_minstagib"))
 342                         s = strcat(s, ":minstagib");
 343                 GameLogEcho(s);
 344                 GameLogEcho(":gameinfo:end");
 345         }
 346
 347         cvar_set("nextmap", "");
 348
 349         SetDefaultAlpha();
 350
 351         if(cvar("g_campaign"))
 352                 CampaignPostInit();
 353
 354         fteqcc_testbugs();
 355
 356         Ban_LoadBans();
 357
 358         //initialise globals related to sv_timeout
 359         sys_ticrate = cvar("sys_ticrate");
 360         orig_slowmo = cvar("slowmo");
 361
 362         MapInfo_Enumerate();
 363         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? MAPINFO_FLAG_HIDDEN : 0), 1);
 364
 365         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 366         {
 367                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 368                 if(fd != -1)
 369                 {
 370                         while((s = fgets(fd)))
 371                         {
 372                                 l = tokenize_sane(s);
 373                                 if(l < 2)
 374                                         continue;
 375                                 if(argv(0) == "cd")
 376                                 {
 377                                         print("Found ^1DEPRECATED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 378                                         print("  cdtrack ", argv(2), "\n");
 379                                 }
 380                                 else if(argv(0) == "fog")
 381                                 {
 382                                         print("Found ^1DEPRECATED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 383                                         print("  \"fog\" \"", s, "\"\n");
 384                                 }
 385                                 else if(argv(0) == "set")
 386                                 {
 387                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 388                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 389                                 }
 390                                 else if(argv(0) != "//")
 391                                 {
 392                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 393                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 394                                 }
 395                         }
 396                         fclose(fd);
 397                 }
 398         }
 399
 400         addstat(STAT_SYS_TICRATE, AS_FLOAT, stat_sys_ticrate);
 401         addstat(STAT_WEAPONS, AS_INT, weapons);
 402         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 403         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 404         Nagger_Init();
 405
 406         next_pingtime = time + 5;
 407         InitializeEntity(self, cvar_changes_init, INITPRIO_CVARS);
 408
 409         world_initialized = 1;
 410 }
 411
 412 void spawnfunc_light (void)
 413 {
 414         //makestatic (self); // Who the f___ did that?
 415         remove(self);
 416 }
 417
 418 float TryFile( string pFilename )
 419 {
 420         local float lHandle;
 421         dprint("TryFile(\"", pFilename, "\")\n");
 422         lHandle = fopen( pFilename, FILE_READ );
 423         if( lHandle != -1 ) {
 424                 fclose( lHandle );
 425                 return TRUE;
 426         } else {
 427                 return FALSE;
 428         }
 429 };
 430
 431 string GetGametype()
 432 {
 433         return GametypeNameFromType(game);
 434 }
 435
 436 string getmapname_stored;
 437 string GetMapname()
 438 {
 439         return mapname;
 440 }
 441
 442 float Map_Count, Map_Current;
 443 string Map_Current_Name;
 444
 445 // NOTE: this now expects the map list to be already tokenize()d and the count in Map_Count
 446 float GetMaplistPosition()
 447 {
 448         float pos, idx;
 449         string map;
 450
 451         map = GetMapname();
 452         idx = cvar("g_maplist_index");
 453
 454         if(idx >= 0)
 455                 if(idx < Map_Count)
 456                         if(map == argv(idx))
 457                                 return idx;
 458
 459         for(pos = 0; pos < Map_Count; ++pos)
 460                 if(map == argv(pos))
 461                         return pos;
 462
 463         // resume normal maplist rotation if current map is not in g_maplist
 464         return idx;
 465 }
 466
 467 float MapHasRightSize(string map)
 468 {
 469         float fh;
 470         if(currentbots || cvar("bot_number") || player_count < cvar("minplayers"))
 471         if(cvar("g_maplist_check_waypoints"))
 472         {
 473                 dprint("checkwp "); dprint(map);
 474                 fh = fopen(strcat("maps/", map, ".waypoints"), FILE_READ);
 475                 if(fh < 0)
 476                 {
 477                         dprint(": no waypoints\n");
 478                         return FALSE;
 479                 }
 480                 dprint(": has waypoints\n");
 481                 fclose(fh);
 482         }
 483
 484         // open map size restriction file
 485         dprint("opensize "); dprint(map);
 486         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 487         if(fh >= 0)
 488         {
 489                 float mapmin, mapmax;
 490                 dprint(": ok, ");
 491                 mapmin = stof(fgets(fh));
 492                 mapmax = stof(fgets(fh));
 493                 fclose(fh);
 494                 if(player_count < mapmin)
 495                 {
 496                         dprint("not enough\n");
 497                         return FALSE;
 498                 }
 499                 if(player_count > mapmax)
 500                 {
 501                         dprint("too many\n");
 502                         return FALSE;
 503                 }
 504                 dprint("right size\n");
 505                 return TRUE;
 506         }
 507         dprint(": not found\n");
 508         return TRUE;
 509 }
 510
 511 string Map_Filename(float position)
 512 {
 513         return strcat("maps/", argv(position), ".bsp");
 514 }
 515
 516 string strwords(string s, float w)
 517 {
 518         float endpos;
 519         for(endpos = 0; w && endpos >= 0; --w)
 520                 endpos = strstrofs(s, " ", endpos + 1);
 521         if(endpos < 0)
 522                 return s;
 523         else
 524                 return substring(s, 0, endpos);
 525 }
 526
 527 float strhasword(string s, string w)
 528 {
 529         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
 530 }
 531
 532 void Map_MarkAsRecent(string m)
 533 {
 534         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", cvar_string("g_maplist_mostrecent")), cvar("g_maplist_mostrecent_count")));
 535 }
 536
 537 float Map_IsRecent(string m)
 538 {
 539         return strhasword(cvar_string("g_maplist_mostrecent"), m);
 540 }
 541
 542 float Map_Check(float position, float pass)
 543 {
 544         string filename;
 545         string map_next;
 546         map_next = argv(position);
 547         if(pass <= 1)
 548         {
 549                 if(map_next == Map_Current_Name) // same map again in first pass?
 550                         return 0;
 551                 if(Map_IsRecent(map_next))
 552                         return 0;
 553         }
 554         filename = Map_Filename(position);
 555         if(MapInfo_CheckMap(map_next))
 556         {
 557                 if(pass == 2)
 558                         return 1;
 559                 if(MapHasRightSize(map_next))
 560                         return 1;
 561                 return 0;
 562         }
 563         else
 564                 dprint( "Couldn't select '", filename, "'..\n" );
 565
 566         return 0;
 567 }
 568
 569 void Map_Goto_SetStr(string nextmapname)
 570 {
 571         if(getmapname_stored != "")
 572                 strunzone(getmapname_stored);
 573         if(nextmapname == "")
 574                 getmapname_stored = "";
 575         else
 576                 getmapname_stored = strzone(nextmapname);
 577 }
 578
 579 void Map_Goto_SetFloat(float position)
 580 {
 581         cvar_set("g_maplist_index", ftos(position));
 582         Map_Goto_SetStr(argv(position));
 583 }
 584
 585 void GameResetCfg()
 586 {
 587         // settings persist, except...
 588         if(cvar("g_campaign"))
 589                 localcmd("\nexec mutator_reset.cfg\n");
 590         localcmd("\nsettemp_restore\n");
 591 };
 592
 593 void Map_Goto()
 594 {
 595         Map_MarkAsRecent(getmapname_stored);
 596         GameResetCfg();
 597         MapInfo_LoadMap(getmapname_stored);
 598 }
 599
 600 // return codes of map selectors:
 601 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
 602 //   -2 = permanent failure
 603 float() MaplistMethod_Iterate = // usual method
 604 {
 605         float pass, i;
 606
 607         for(pass = 1; pass <= 2; ++pass)
 608         {
 609                 for(i = 1; i < Map_Count; ++i)
 610                 {
 611                         float mapindex;
 612                         mapindex = mod(i + Map_Current, Map_Count);
 613                         if(Map_Check(mapindex, pass))
 614                                 return mapindex;
 615                 }
 616         }
 617         return -1;
 618 }
 619
 620 float() MaplistMethod_Repeat = // fallback method
 621 {
 622         if(Map_Check(Map_Current, 2))
 623                 return Map_Current;
 624         return -2;
 625 }
 626
 627 float() MaplistMethod_Random = // random map selection
 628 {
 629         float i, imax;
 630
 631         imax = 42;
 632
 633         for(i = 0; i <= imax; ++i)
 634         {
 635                 float mapindex;
 636                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
 637                 if(Map_Check(mapindex, 1))
 638                         return mapindex;
 639         }
 640         return -1;
 641 }
 642
 643 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
 644 // the exponent sets a bias on the map selection:
 645 // the higher the exponent, the less likely "shortly repeated" same maps are
 646 {
 647         float i, j, imax, insertpos;
 648
 649         imax = 42;
 650
 651         for(i = 0; i <= imax; ++i)
 652         {
 653                 string newlist;
 654
 655                 // now reinsert this at another position
 656                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
 657                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
 658                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
 659                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
 660
 661                 // insert the current map there
 662                 newlist = "";
 663                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
 664                         newlist = strcat(newlist, " ", argv(j));
 665                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
 666                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
 667                         newlist = strcat(newlist, " ", argv(j));
 668                 newlist = substring(newlist, 1, strlen(newlist) - 1);
 669                 cvar_set("g_maplist", newlist);
 670                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 671
 672                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
 673                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
 674                 if(Map_Check(Map_Current, 1))
 675                         return Map_Current;
 676         }
 677         return -1;
 678 }
 679
 680 void Maplist_Init()
 681 {
 682         string temp;
 683         temp = cvar_string("g_maplist");
 684         Map_Count = tokenizebyseparator(temp, " ");
 685         if(Map_Count == 0)
 686         {
 687                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
 688                 cvar_set("g_maplist", temp = MapInfo_ListAllowedMaps(0, MAPINFO_FLAG_HIDDEN));
 689                 localcmd("\nmenu_cmd sync\n");
 690                 Map_Count = tokenizebyseparator(temp, " ");
 691         }
 692         if(Map_Count == 0)
 693                 error("empty maplist, cannot select a new map");
 694         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
 695
 696         if(Map_Current_Name)
 697                 strunzone(Map_Current_Name);
 698         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
 699         // this may or may not be correct, but who cares, in the worst case a map
 700         // isn't chosen in the first pass that should have been
 701 }
 702
 703 string GetNextMap()
 704 {
 705         float nextMap;
 706
 707         Maplist_Init();
 708         nextMap = -1;
 709
 710         if(nextMap == -1)
 711                 if(cvar("g_maplist_shuffle") > 0)
 712                         nextMap = MaplistMethod_Shuffle(cvar("g_maplist_shuffle") + 1);
 713
 714         if(nextMap == -1)
 715                 if(cvar("g_maplist_selectrandom"))
 716                         nextMap = MaplistMethod_Random();
 717
 718         if(nextMap == -1)
 719                 nextMap = MaplistMethod_Iterate();
 720
 721         if(nextMap == -1)
 722                 nextMap = MaplistMethod_Repeat();
 723
 724         if(nextMap >= 0)
 725         {
 726                 Map_Goto_SetFloat(nextMap);
 727                 return getmapname_stored;
 728         }
 729
 730         return "";
 731 };
 732
 733 float DoNextMapOverride()
 734 {
 735         if(cvar("g_campaign"))
 736         {
 737                 CampaignPostIntermission();
 738                 alreadychangedlevel = TRUE;
 739                 return TRUE;
 740         }
 741         if(cvar("quit_when_empty"))
 742         {
 743                 if(player_count <= currentbots)
 744                 {
 745                         localcmd("quit\n");
 746                         alreadychangedlevel = TRUE;
 747                         return TRUE;
 748                 }
 749         }
 750         if(cvar_string("quit_and_redirect") != "")
 751         {
 752                 redirection_target = strzone(cvar_string("quit_and_redirect"));
 753                 alreadychangedlevel = TRUE;
 754                 return TRUE;
 755         }
 756         if (cvar("samelevel")) // if samelevel is set, stay on same level
 757         {
 758                 // this does not work because it tries to exec maps/nexdm01.mapcfg (which doesn't exist, it should be trying maps/dm_nexdm01.mapcfg for example)
 759                 //localcmd(strcat("exec \"maps/", mapname, ".mapcfg\"\n"));
 760                 // so instead just restart the current map using the restart command (DOES NOT WORK PROPERLY WITH exit_cfg STUFF)
 761                 localcmd("restart\n");
 762                 //changelevel (mapname);
 763                 alreadychangedlevel = TRUE;
 764                 return TRUE;
 765         }
 766         if(cvar_string("nextmap") != "")
 767                 if(MapInfo_CheckMap(cvar_string("nextmap")))
 768                 {
 769                         Map_Goto_SetStr(cvar_string("nextmap"));
 770                         Map_Goto();
 771                         alreadychangedlevel = TRUE;
 772                         return TRUE;
 773                 }
 774         if(cvar("lastlevel"))
 775         {
 776                 GameResetCfg();
 777                 localcmd("set lastlevel 0\ntogglemenu\n");
 778                 alreadychangedlevel = TRUE;
 779                 return TRUE;
 780         }
 781         return FALSE;
 782 };
 783
 784 void GotoNextMap()
 785 {
 786         //local string nextmap;
 787         //local float n, nummaps;
 788         //local string s;
 789         if (alreadychangedlevel)
 790                 return;
 791         alreadychangedlevel = TRUE;
 792
 793         {
 794                 string nextMap;
 795                 float allowReset;
 796
 797                 for(allowReset = 1; allowReset >= 0; --allowReset)
 798                 {
 799                         nextMap = GetNextMap();
 800                         if(nextMap != "")
 801                                 break;
 802
 803                         if(allowReset)
 804                         {
 805                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
 806                                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(0, MAPINFO_FLAG_HIDDEN));
 807                                 localcmd("\nmenu_cmd sync\n");
 808                         }
 809                         else
 810                         {
 811                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
 812                         }
 813                 }
 814                 Map_Goto();
 815         }
 816 };
 817
 818
 819 /*
 820 ============
 821 IntermissionThink
 822
 823 When the player presses attack or jump, change to the next level
 824 ============
 825 */
 826 .float autoscreenshot;
 827 void() MapVote_Start;
 828 void() MapVote_Think;
 829 float mapvote_initialized;
 830 void IntermissionThink()
 831 {
 832         FixIntermissionClient(self);
 833
 834         if(cvar("sv_autoscreenshot"))
 835         if(self.autoscreenshot > 0)
 836         if(time > self.autoscreenshot)
 837         {
 838                 self.autoscreenshot = -1;
 839                 if(clienttype(self) == CLIENTTYPE_REAL)
 840                         stuffcmd(self, "\nscreenshot\necho \"^5A screenshot has been taken at request of the server.\"\n");
 841                 return;
 842         }
 843
 844         if (time < intermission_exittime)
 845                 return;
 846
 847         if(!mapvote_initialized)
 848                 if (time < intermission_exittime + 10 && !self.BUTTON_ATCK && !self.BUTTON_JUMP && !self.BUTTON_ATCK2 && !self.BUTTON_HOOK && !self.BUTTON_USE)
 849                         return;
 850
 851         MapVote_Start();
 852 };
 853
 854 /*
 855 ============
 856 FindIntermission
 857
 858 Returns the entity to view from
 859 ============
 860 */
 861 /*
 862 entity FindIntermission()
 863 {
 864         local   entity spot;
 865         local   float cyc;
 866
 867 // look for info_intermission first
 868         spot = find (world, classname, "info_intermission");
 869         if (spot)
 870         {       // pick a random one
 871                 cyc = random() * 4;
 872                 while (cyc > 1)
 873                 {
 874                         spot = find (spot, classname, "info_intermission");
 875                         if (!spot)
 876                                 spot = find (spot, classname, "info_intermission");
 877                         cyc = cyc - 1;
 878                 }
 879                 return spot;
 880         }
 881
 882 // then look for the start position
 883         spot = find (world, classname, "info_player_start");
 884         if (spot)
 885                 return spot;
 886
 887 // testinfo_player_start is only found in regioned levels
 888         spot = find (world, classname, "testplayerstart");
 889         if (spot)
 890                 return spot;
 891
 892 // then look for the start position
 893         spot = find (world, classname, "info_player_deathmatch");
 894         if (spot)
 895                 return spot;
 896
 897         //objerror ("FindIntermission: no spot");
 898         return world;
 899 };
 900 */
 901
 902 /*
 903 ===============================================================================
 904
 905 RULES
 906
 907 ===============================================================================
 908 */
 909
 910 void DumpStats(float final)
 911 {
 912         local float file;
 913         local string s;
 914         local float to_console;
 915         local float to_eventlog;
 916         local float to_file;
 917         local float i;
 918
 919         to_console = cvar("sv_logscores_console");
 920         to_eventlog = cvar("sv_eventlog");
 921         to_file = cvar("sv_logscores_file");
 922
 923         if(!final)
 924         {
 925                 to_console = TRUE; // always print printstats replies
 926                 to_eventlog = FALSE; // but never print them to the event log
 927         }
 928
 929         if(to_eventlog)
 930                 if(cvar("sv_eventlog_console"))
 931                         to_console = FALSE; // otherwise we get the output twice
 932
 933         if(final)
 934                 s = ":scores:";
 935         else
 936                 s = ":status:";
 937         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
 938
 939         if(to_console)
 940                 print(s, "\n");
 941         if(to_eventlog)
 942                 GameLogEcho(s);
 943         if(to_file)
 944         {
 945                 file = fopen(cvar_string("sv_logscores_filename"), FILE_APPEND);
 946                 if(file == -1)
 947                         to_file = FALSE;
 948                 else
 949                         fputs(file, strcat(s, "\n"));
 950         }
 951
 952         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
 953         if(to_console)
 954                 print(s, "\n");
 955         if(to_eventlog)
 956                 GameLogEcho(s);
 957         if(to_file)
 958                 fputs(file, strcat(s, "\n"));
 959
 960         FOR_EACH_CLIENT(other)
 961         {
 962                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && cvar("sv_logscores_bots")))
 963                 {
 964                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
 965                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
 966                         if(other.classname == "player" || g_arena || g_lms)
 967                                 s = strcat(s, ftos(other.team), ":");
 968                         else
 969                                 s = strcat(s, "spectator:");
 970
 971                         if(to_console)
 972                                 print(s, other.netname, "\n");
 973                         if(to_eventlog)
 974                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
 975                         if(to_file)
 976                                 fputs(file, strcat(s, other.netname, "\n"));
 977                 }
 978         }
 979
 980         if(teamplay)
 981         {
 982                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
 983                 if(to_console)
 984                         print(s, "\n");
 985                 if(to_eventlog)
 986                         GameLogEcho(s);
 987                 if(to_file)
 988                         fputs(file, strcat(s, "\n"));
 989
 990                 for(i = 1; i < 16; ++i)
 991                 {
 992                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
 993                         s = strcat(s, ":", ftos(i));
 994                         if(to_console)
 995                                 print(s, "\n");
 996                         if(to_eventlog)
 997                                 GameLogEcho(s);
 998                         if(to_file)
 999                                 fputs(file, strcat(s, "\n"));
1000                 }
1001         }
1002
1003         if(to_console)
1004                 print(":end\n");
1005         if(to_eventlog)
1006                 GameLogEcho(":end");
1007         if(to_file)
1008         {
1009                 fputs(file, ":end\n");
1010                 fclose(file);
1011         }
1012 }
1013
1014 void FixIntermissionClient(entity e)
1015 {
1016         string s;
1017         if(!e.autoscreenshot) // initial call
1018         {
1019                 e.angles = e.v_angle;
1020                 e.angles_x = -e.angles_x;
1021                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1022                 e.health = -2342;
1023                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1024                 e.solid = SOLID_NOT;
1025                 e.movetype = MOVETYPE_NONE;
1026                 e.takedamage = DAMAGE_NO;
1027                 if(e.weaponentity)
1028                         e.weaponentity.effects = EF_NODRAW;
1029                 if(clienttype(e) == CLIENTTYPE_REAL)
1030                 {
1031                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1032                         s = cvar_string("sv_intermission_cdtrack");
1033                         if(s != "")
1034                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1035                         msg_entity = e;
1036                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1037                 }
1038         }
1039
1040         //e.velocity = '0 0 0';
1041         //e.fixangle = TRUE;
1042
1043         // TODO halt weapon animation
1044 }
1045
1046
1047 /*
1048 go to the next level for deathmatch
1049 only called if a time or frag limit has expired
1050 */
1051 void NextLevel()
1052 {
1053         float minTotalFrags;
1054         float maxTotalFrags;
1055         float score;
1056         float f;
1057
1058         gameover = TRUE;
1059
1060         intermission_running = 1;
1061
1062 // enforce a wait time before allowing changelevel
1063         if(player_count > 0)
1064                 intermission_exittime = time + cvar("sv_mapchange_delay");
1065         else
1066                 intermission_exittime = -1;
1067
1068         /*
1069         WriteByte (MSG_ALL, SVC_CDTRACK);
1070         WriteByte (MSG_ALL, 3);
1071         WriteByte (MSG_ALL, 3);
1072         // done in FixIntermission
1073         */
1074
1075         //pos = FindIntermission ();
1076
1077         VoteReset();
1078
1079         DumpStats(TRUE);
1080
1081         if(cvar("sv_eventlog"))
1082                 GameLogEcho(":gameover");
1083
1084         GameLogClose();
1085
1086         FOR_EACH_CLIENT(other)
1087         {
1088                 FixIntermissionClient(other);
1089
1090                 if(other.winning)
1091                         bprint(other.netname, " ^7wins.\n");
1092         }
1093
1094         minTotalFrags = 0;
1095         maxTotalFrags = 0;
1096         FOR_EACH_PLAYER(other)
1097         {
1098                 if(maxTotalFrags < other.totalfrags)
1099                         maxTotalFrags = other.totalfrags;
1100                 if(minTotalFrags > other.totalfrags)
1101                         minTotalFrags = other.totalfrags;
1102         }
1103
1104         if(!currentbots)
1105         {
1106                 FOR_EACH_PLAYER(other)
1107                 {
1108                         score = (other.totalfrags - minTotalFrags) / max(maxTotalFrags - minTotalFrags, 1);
1109                         f = bound(0, other.play_time / max(time, 1), 1);
1110                         // store some statistics?
1111                 }
1112         }
1113
1114         if(cvar("g_campaign"))
1115                 CampaignPreIntermission();
1116
1117         // WriteByte (MSG_ALL, SVC_INTERMISSION);
1118 };
1119
1120 /*
1121 ============
1122 CheckRules_Player
1123
1124 Exit deathmatch games upon conditions
1125 ============
1126 */
1127 void CheckRules_Player()
1128 {
1129         if (gameover)   // someone else quit the game already
1130                 return;
1131
1132         if(self.deadflag == DEAD_NO)
1133                 self.play_time += frametime;
1134
1135         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1136         //   (div0: and that in CheckRules_World please)
1137 };
1138
1139 float checkrules_oneminutewarning;
1140
1141 float checkrules_equality;
1142 float checkrules_overtimewarning;
1143 float checkrules_overtimeend;
1144
1145 void InitiateOvertime()
1146 {
1147         if(!checkrules_overtimeend)
1148                 checkrules_overtimeend = time + 60 * cvar("timelimit_maxovertime");
1149 }
1150
1151 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1152 float WINNING_YES = 1; // winner found
1153 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1154 float WINNING_STARTOVERTIME = 3; // no winner, enter overtime NOW
1155
1156 float GetWinningCode(float fraglimitreached, float equality)
1157 {
1158         if(equality)
1159                 if(fraglimitreached)
1160                         return WINNING_STARTOVERTIME;
1161                 else
1162                         return WINNING_NEVER;
1163         else
1164                 if(fraglimitreached)
1165                         return WINNING_YES;
1166                 else
1167                         return WINNING_NO;
1168 }
1169
1170 // set the .winning flag for exactly those players with a given field value
1171 void SetWinners(.float field, float value)
1172 {
1173         entity head;
1174         FOR_EACH_PLAYER(head)
1175                 head.winning = (head.field == value);
1176 }
1177
1178 // set the .winning flag for those players with a given field value
1179 void AddWinners(.float field, float value)
1180 {
1181         entity head;
1182         FOR_EACH_PLAYER(head)
1183                 if(head.field == value)
1184                         head.winning = 1;
1185 }
1186
1187 // clear the .winning flags
1188 void ClearWinners(void)
1189 {
1190         entity head;
1191         FOR_EACH_PLAYER(head)
1192                 head.winning = 0;
1193 }
1194
1195 // Onslaught winning condition:
1196 // game terminates if only one team has a working generator (or none)
1197 float WinningCondition_Onslaught()
1198 {
1199         entity head;
1200         local float t1, t2, t3, t4;
1201         // first check if the game has ended
1202         t1 = t2 = t3 = t4 = 0;
1203         head = find(world, classname, "onslaught_generator");
1204         while (head)
1205         {
1206                 if (head.health > 0)
1207                 {
1208                         if (head.team == COLOR_TEAM1) t1 = 1;
1209                         if (head.team == COLOR_TEAM2) t2 = 1;
1210                         if (head.team == COLOR_TEAM3) t3 = 1;
1211                         if (head.team == COLOR_TEAM4) t4 = 1;
1212                 }
1213                 head = find(head, classname, "onslaught_generator");
1214         }
1215         if (t1 + t2 + t3 + t4 < 2)
1216         {
1217                 // game over, only one team remains (or none)
1218                 ClearWinners();
1219                 if (t1) SetWinners(team, COLOR_TEAM1);
1220                 if (t2) SetWinners(team, COLOR_TEAM2);
1221                 if (t3) SetWinners(team, COLOR_TEAM3);
1222                 if (t4) SetWinners(team, COLOR_TEAM4);
1223                 dprint("Have a winner, ending game.\n");
1224                 return WINNING_YES;
1225         }
1226
1227         // Two or more teams remain
1228         return WINNING_NO;
1229 }
1230
1231 float LMS_NewPlayerLives()
1232 {
1233         float fl;
1234         fl = cvar("fraglimit");
1235         if(fl == 0)
1236                 fl = 999;
1237
1238         // first player has left the game for dying too much? Nobody else can get in.
1239         if(lms_lowest_lives < 1)
1240                 return 0;
1241
1242         if(!cvar("g_lms_join_anytime"))
1243                 if(lms_lowest_lives < fl - cvar("g_lms_last_join"))
1244                         return 0;
1245
1246         return bound(1, lms_lowest_lives, fl);
1247 }
1248
1249 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1250 // they win. Otherwise the defending team wins once the timelimit passes.
1251 void assault_new_round();
1252 float WinningCondition_Assault()
1253 {
1254         local float status;
1255         status = WINNING_NO;
1256
1257         // as the timelimit has not yet passed just assume the defending team will win
1258         if(assault_attacker_team == COLOR_TEAM1)
1259         {
1260                 SetWinners(team, COLOR_TEAM2);
1261         }
1262         else
1263         {
1264                 SetWinners(team, COLOR_TEAM1);
1265         }
1266
1267         local entity ent;
1268         ent = find(world, classname, "target_assault_roundend");
1269         if(ent)
1270         {
1271                 if(ent.winning) // round end has been triggered by attacking team
1272                 {
1273                         SetWinners(team, assault_attacker_team);
1274                         if(assault_attacker_team == COLOR_TEAM1)
1275                         {
1276                                 team1_score = team1_score + 50;
1277                         }
1278                         else
1279                         {
1280                                 team2_score = team2_score + 50;
1281                         }
1282
1283                         if(ent.cnt == 1) // this was the second round
1284                         {
1285                                 status = WINNING_YES;
1286                         }
1287                         else
1288                         {
1289                                 local entity oldself;
1290                                 oldself = self;
1291                                 self = ent;
1292                                 cvar_set("timelimit", ftos((2*time)/60)); // FIXME use game_starttime here
1293                                 assault_new_round();
1294                                 self = oldself;
1295                         }
1296                 }
1297         }
1298
1299         return status;
1300
1301 }
1302
1303 // LMS winning condition: game terminates if and only if there's at most one
1304 // one player who's living lives. Top two scores being equal cancels the time
1305 // limit.
1306 float WinningCondition_LMS()
1307 {
1308         entity head, head2;
1309         float have_player;
1310         float have_players;
1311         float l;
1312
1313         have_player = FALSE;
1314         have_players = FALSE;
1315         l = LMS_NewPlayerLives();
1316
1317         head = find(world, classname, "player");
1318         if(head)
1319                 have_player = TRUE;
1320         head2 = find(head, classname, "player");
1321         if(head2)
1322                 have_players = TRUE;
1323
1324         if(have_player)
1325         {
1326                 // we have at least one player
1327                 if(have_players)
1328                 {
1329                         // two or more active players - continue with the game
1330                 }
1331                 else
1332                 {
1333                         // exactly one player?
1334
1335                         ClearWinners();
1336                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1337
1338                         if(l)
1339                         {
1340                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1341                                 return WINNING_NO;
1342                         }
1343                         else
1344                         {
1345                                 // a winner!
1346                                 // and assign him his first place
1347                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1348                                 return WINNING_YES;
1349                         }
1350                 }
1351         }
1352         else
1353         {
1354                 // nobody is playing at all...
1355                 if(l)
1356                 {
1357                         // wait for players...
1358                 }
1359                 else
1360                 {
1361                         // SNAFU (maybe a draw game?)
1362                         ClearWinners();
1363                         dprint("No players, ending game.\n");
1364                         return WINNING_YES;
1365                 }
1366         }
1367
1368         // When we get here, we have at least two players who are actually LIVING,
1369         // now check if the top two players have equal score.
1370         WinningConditionHelper();
1371
1372         ClearWinners();
1373         if(WinningConditionHelper_winner)
1374                 WinningConditionHelper_winner.winning = TRUE;
1375         if(WinningConditionHelper_equality)
1376                 return WINNING_NEVER;
1377
1378         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1379         return WINNING_NO;
1380 }
1381
1382 void print_to(entity e, string s)
1383 {
1384         if(e)
1385                 sprint(e, strcat(s, "\n"));
1386         else
1387                 print(s, "\n");
1388 }
1389
1390 void ShuffleMaplist()
1391 {
1392         string result;
1393         float start;
1394         float litems;
1395         float selected;
1396         float i;
1397
1398         result = cvar_string("g_maplist");
1399         litems = tokenizebyseparator(result, " ");
1400
1401         for(start = 0; start < litems - 1; ++start)
1402         {
1403                 result = "";
1404
1405                 // select a random item
1406                 selected = floor(random() * (litems - start) + start);
1407
1408                 // shift this item to the place start
1409                 for(i = 0; i < start; ++i)
1410                         result = strcat(result, " ", argv(i));
1411                 result = strcat(result, " ", argv(selected));
1412                 for(i = start; i < litems; ++i)
1413                         if(i != selected)
1414                                 result = strcat(result, " ", argv(i));
1415                 result = substring(result, 1, strlen(result) - 1);
1416
1417                 litems = tokenizebyseparator(result, " ");
1418
1419                 //dprint(result, "\n");
1420         }
1421
1422         cvar_set("g_maplist", result);
1423 }
1424
1425 float WinningCondition_Scores(float limit)
1426 {
1427         // TODO make everything use THIS winning condition (except LMS)
1428         WinningConditionHelper();
1429
1430         if(teams_matter)
1431         {
1432                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1433                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1434                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1435                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1436         }
1437
1438         ClearWinners();
1439         if(WinningConditionHelper_winner)
1440                 WinningConditionHelper_winner.winning = 1;
1441         if(WinningConditionHelper_winnerteam >= 0)
1442                 SetWinners(team, WinningConditionHelper_winnerteam);
1443
1444         if(WinningConditionHelper_lowerisbetter)
1445         {
1446                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1447                 limit = -limit;
1448         }
1449
1450         return GetWinningCode(limit && WinningConditionHelper_topscore && (WinningConditionHelper_topscore >= limit), WinningConditionHelper_equality);
1451 }
1452
1453 float WinningCondition_Race(float fraglimit)
1454 {
1455         float wc;
1456         entity p;
1457         wc = WinningCondition_Scores(fraglimit);
1458
1459         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1460         if(wc == WINNING_YES || wc == WINNING_STARTOVERTIME)
1461         // do NOT support equality when the laps are all raced!
1462         {
1463                 FOR_EACH_PLAYER(p)
1464                         if not(p.race_completed)
1465                                 return WINNING_STARTOVERTIME;
1466                 return WINNING_YES;
1467         }
1468         return wc;
1469 }
1470
1471 void ReadyRestart();
1472 float WinningCondition_QualifyingThenRace(float limit)
1473 {
1474         float wc;
1475         wc = WinningCondition_Scores(limit);
1476
1477         // NEVER initiate overtime
1478         if(wc == WINNING_YES || wc == WINNING_STARTOVERTIME)
1479         {
1480                 return WINNING_YES;
1481         }
1482
1483         return wc;
1484 }
1485
1486 float WinningCondition_RanOutOfSpawns()
1487 {
1488         entity head;
1489
1490         if(!have_team_spawns)
1491                 return WINNING_NO;
1492
1493         if(!some_spawn_has_been_used)
1494                 return WINNING_NO;
1495
1496         team1_score = team2_score = team3_score = team4_score = 0;
1497
1498         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1499         {
1500                 if(head.team == COLOR_TEAM1)
1501                         team1_score = 1;
1502                 else if(head.team == COLOR_TEAM2)
1503                         team2_score = 1;
1504                 else if(head.team == COLOR_TEAM3)
1505                         team3_score = 1;
1506                 else if(head.team == COLOR_TEAM4)
1507                         team4_score = 1;
1508         }
1509
1510         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1511         {
1512                 if(head.team == COLOR_TEAM1)
1513                         team1_score = 1;
1514                 else if(head.team == COLOR_TEAM2)
1515                         team2_score = 1;
1516                 else if(head.team == COLOR_TEAM3)
1517                         team3_score = 1;
1518                 else if(head.team == COLOR_TEAM4)
1519                         team4_score = 1;
1520         }
1521
1522         ClearWinners();
1523         if(team1_score + team2_score + team3_score + team4_score == 0)
1524         {
1525                 checkrules_equality = TRUE;
1526                 return WINNING_YES;
1527         }
1528         else if(team1_score + team2_score + team3_score + team4_score == 1)
1529         {
1530                 float t, i;
1531                 if(team1_score) t = COLOR_TEAM1;
1532                 if(team2_score) t = COLOR_TEAM2;
1533                 if(team3_score) t = COLOR_TEAM3;
1534                 if(team4_score) t = COLOR_TEAM4;
1535                 CheckAllowedTeams(world);
1536                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1537                 {
1538                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
1539                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
1540                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
1541                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
1542                 }
1543
1544                 AddWinners(team, t);
1545                 return WINNING_YES;
1546         }
1547         else
1548                 return WINNING_NO;
1549 }
1550
1551 /*
1552 ============
1553 CheckRules_World
1554
1555 Exit deathmatch games upon conditions
1556 ============
1557 */
1558 void CheckRules_World()
1559 {
1560         local float status;
1561         local float timelimit;
1562         local float fraglimit;
1563
1564         VoteThink();
1565         MapVote_Think();
1566
1567         SetDefaultAlpha();
1568
1569         /*
1570         MapVote_Think should now do that part
1571         if (intermission_running)
1572                 if (time >= intermission_exittime + 60)
1573                 {
1574                         if(!DoNextMapOverride())
1575                                 GotoNextMap();
1576                         return;
1577                 }
1578         */
1579
1580         if (gameover)   // someone else quit the game already
1581         {
1582                 if(player_count == 0) // Nobody there? Then let's go to the next map
1583                         MapVote_Start();
1584                         // this will actually check the player count in the next frame
1585                         // again, but this shouldn't hurt
1586                 return;
1587         }
1588
1589         timelimit = cvar("timelimit") * 60;
1590         fraglimit = cvar("fraglimit");
1591
1592         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1593         {
1594                 if(timelimit > 0)
1595                         timelimit = 0; // timelimit is not made for warmup
1596                 if(fraglimit > 0)
1597                         fraglimit = 0; // no fraglimit for now
1598         }
1599
1600         if(timelimit > 0)
1601                 timelimit += game_starttime;
1602
1603         if(checkrules_overtimeend)
1604         {
1605                 if(!checkrules_overtimewarning)
1606                 {
1607                         checkrules_overtimewarning = TRUE;
1608                         //announceall("announcer/robotic/1minuteremains.wav");
1609                         if(g_race && !g_race_qualifying)
1610                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
1611                         else
1612                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
1613                 }
1614         }
1615         else
1616         {
1617                 if (timelimit && time >= timelimit)
1618                 {
1619                         if(g_race && g_race_qualifying == 2 && timelimit > 0)
1620                         {
1621                                 float totalplayers;
1622                                 float playerswithlaps;
1623                                 float readyplayers;
1624                                 entity head;
1625                                 totalplayers = playerswithlaps = readyplayers = 0;
1626                                 FOR_EACH_PLAYER(head)
1627                                 {
1628                                         ++totalplayers;
1629                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
1630                                                 ++playerswithlaps;
1631                                         if(head.ready)
1632                                                 ++readyplayers;
1633                                 }
1634
1635                                 // at least 2/3 of the players have completed a lap: start the RACE
1636                                 // otherwise, the players should end the qualifying on their own
1637                                 if(readyplayers || ((totalplayers >= 3) && (playerswithlaps * 3 >= totalplayers * 2)))
1638                                 {
1639                                         checkrules_overtimeend = 0;
1640                                         ReadyRestart(); // go to race
1641                                 }
1642                                 else
1643                                         InitiateOvertime();
1644                         }
1645                         else
1646                                 InitiateOvertime();
1647                 }
1648         }
1649
1650         if (checkrules_overtimeend && time >= checkrules_overtimeend)
1651         {
1652                 NextLevel();
1653                 return;
1654         }
1655
1656         if (!checkrules_oneminutewarning && timelimit > 0 && time > timelimit - 60)
1657         {
1658                 checkrules_oneminutewarning = TRUE;
1659                 play2all("announcer/robotic/1minuteremains.wav");
1660         }
1661
1662         status = WinningCondition_RanOutOfSpawns();
1663         if(status == WINNING_YES)
1664         {
1665                 bprint("Hey! Someone ran out of spawns!\n");
1666         }
1667         else if(g_race && !g_race_qualifying && timelimit >= 0)
1668         {
1669                 status = WinningCondition_Race(fraglimit);
1670         }
1671         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
1672         {
1673                 status = WinningCondition_QualifyingThenRace(fraglimit);
1674         }
1675         else if(g_assault)
1676         {
1677                 status = WinningCondition_Assault(); // TODO remove this?
1678         }
1679         else if(g_lms)
1680         {
1681                 status = WinningCondition_LMS();
1682         }
1683         else if (g_onslaught)
1684         {
1685                 status = WinningCondition_Onslaught(); // TODO remove this?
1686         }
1687         else
1688         {
1689                 status = WinningCondition_Scores(fraglimit);
1690         }
1691
1692         if(status == WINNING_STARTOVERTIME)
1693         {
1694                 status = WINNING_NEVER;
1695                 InitiateOvertime();
1696         }
1697
1698         if(status == WINNING_NEVER)
1699                 // equality cases! Nobody wins if the overtime ends in a draw.
1700                 ClearWinners();
1701
1702         if(checkrules_overtimeend)
1703                 if(status != WINNING_NEVER || time >= checkrules_overtimeend)
1704                         status = WINNING_YES;
1705
1706         if(status == WINNING_YES)
1707                 NextLevel();
1708 };
1709
1710 float mapvote_nextthink;
1711 float mapvote_initialized;
1712 float mapvote_keeptwotime;
1713 float mapvote_timeout;
1714 string mapvote_message;
1715 string mapvote_screenshot_dir;
1716
1717 float mapvote_count;
1718 float mapvote_count_real;
1719 string mapvote_maps[MAPVOTE_COUNT];
1720 float mapvote_maps_suggested[MAPVOTE_COUNT];
1721 string mapvote_suggestions[MAPVOTE_COUNT];
1722 float mapvote_suggestion_ptr;
1723 float mapvote_maxlen;
1724 float mapvote_voters;
1725 float mapvote_votes[MAPVOTE_COUNT];
1726 float mapvote_run;
1727 float mapvote_detail;
1728 float mapvote_abstain;
1729 float mapvote_dirty;
1730 .float mapvote;
1731
1732 void MapVote_ClearAllVotes()
1733 {
1734         FOR_EACH_CLIENT(other)
1735                 other.mapvote = 0;
1736 }
1737
1738 string MapVote_Suggest(string m)
1739 {
1740         float i;
1741         if(m == "")
1742                 return "That's not how to use this command.";
1743         if(!cvar("g_maplist_votable_suggestions"))
1744                 return "Suggestions are not accepted on this server.";
1745         if(mapvote_initialized)
1746                 return "Can't suggest - voting is already in progress!";
1747         m = MapInfo_FixName(m);
1748         if(!m)
1749                 return "The map you suggested is not available on this server.";
1750         if(!cvar("g_maplist_votable_override_mostrecent"))
1751                 if(Map_IsRecent(m))
1752                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
1753
1754         if(!MapInfo_CheckMap(m))
1755                 return "The map you suggested does not support the current game mode.";
1756         for(i = 0; i < mapvote_suggestion_ptr; ++i)
1757                 if(mapvote_suggestions[i] == m)
1758                         return "This map was already suggested.";
1759         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
1760         {
1761                 i = floor(random() * mapvote_suggestion_ptr);
1762         }
1763         else
1764         {
1765                 i = mapvote_suggestion_ptr;
1766                 mapvote_suggestion_ptr += 1;
1767         }
1768         if(mapvote_suggestions[i] != "")
1769                 strunzone(mapvote_suggestions[i]);
1770         mapvote_suggestions[i] = strzone(m);
1771         if(cvar("sv_eventlog"))
1772                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
1773         return strcat("Suggestion of ", m, " accepted.");
1774 }
1775
1776 void MapVote_AddVotable(string nextMap, float isSuggestion)
1777 {
1778         float j;
1779         if(nextMap == "")
1780                 return;
1781         for(j = 0; j < mapvote_count; ++j)
1782                 if(mapvote_maps[j] == nextMap)
1783                         return;
1784         if(strlen(nextMap) > mapvote_maxlen)
1785                 mapvote_maxlen = strlen(nextMap);
1786         mapvote_maps[mapvote_count] = strzone(nextMap);
1787         mapvote_maps_suggested[mapvote_count] = isSuggestion;
1788         mapvote_count += 1;
1789 }
1790
1791 void MapVote_SendData(float target);
1792 void MapVote_Init()
1793 {
1794         float i;
1795         float nmax, smax;
1796
1797         MapVote_ClearAllVotes();
1798
1799         mapvote_count = 0;
1800         mapvote_detail = !cvar("g_maplist_votable_nodetail");
1801         mapvote_abstain = cvar("g_maplist_votable_abstain");
1802
1803         if(mapvote_abstain)
1804                 nmax = min(MAPVOTE_COUNT - 1, cvar("g_maplist_votable"));
1805         else
1806                 nmax = min(MAPVOTE_COUNT, cvar("g_maplist_votable"));
1807         smax = min3(nmax, cvar("g_maplist_votable_suggestions"), mapvote_suggestion_ptr);
1808
1809         if(mapvote_suggestion_ptr)
1810                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
1811                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
1812
1813         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
1814                 MapVote_AddVotable(GetNextMap(), FALSE);
1815
1816         if(mapvote_count == 0)
1817         {
1818                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1819                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(0, MAPINFO_FLAG_HIDDEN));
1820                 localcmd("\nmenu_cmd sync\n");
1821                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
1822                         MapVote_AddVotable(GetNextMap(), FALSE);
1823         }
1824
1825         mapvote_count_real = mapvote_count;
1826         if(mapvote_abstain)
1827                 MapVote_AddVotable("don't care", 0);
1828
1829         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
1830
1831         mapvote_keeptwotime = time + cvar("g_maplist_votable_keeptwotime");
1832         mapvote_timeout = time + cvar("g_maplist_votable_timeout");
1833         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
1834                 mapvote_keeptwotime = 0;
1835         mapvote_message = "Choose a map and press its key!";
1836
1837         mapvote_screenshot_dir = cvar_string("g_maplist_votable_screenshot_dir");
1838         if(mapvote_screenshot_dir == "")
1839                 mapvote_screenshot_dir = "maps";
1840         mapvote_screenshot_dir = strzone(mapvote_screenshot_dir);
1841
1842         if(!cvar("g_maplist_textonly"))
1843                 MapVote_SendData(MSG_ALL);
1844 }
1845
1846 void MapVote_SendPicture(float id)
1847 {
1848         msg_entity = self;
1849         WriteByte(MSG_ONE, SVC_TEMPENTITY);
1850         WriteByte(MSG_ONE, TE_CSQC_MAPVOTE);
1851         WriteByte(MSG_ONE, MAPVOTE_NET_PIC);
1852         WriteByte(MSG_ONE, id);
1853         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dir, "/", mapvote_maps[id]), 3072);
1854 }
1855
1856 float GameCommand_MapVote(string cmd)
1857 {
1858         if(!intermission_running)
1859                 return FALSE;
1860         if(!cvar("g_maplist_textonly"))
1861         {
1862                 if(cmd == "mv_getpic")
1863                 {
1864                         MapVote_SendPicture(stof(argv(1)));
1865                         return TRUE;
1866                 }
1867         }
1868
1869         return FALSE;
1870 }
1871
1872 float MapVote_GetMapMask()
1873 {
1874         float mask, i, power;
1875         mask = 0;
1876         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
1877                 if(mapvote_maps[i] != "")
1878                         mask |= power;
1879         return mask;
1880 }
1881
1882 void MapVote_SendData(float targ)
1883 {
1884         string mapfile, pakfile;
1885         float i, o;
1886         WriteByte(targ, SVC_TEMPENTITY);
1887         WriteByte(targ, TE_CSQC_CONFIG);
1888         WriteString(targ, "mv_screenshot_dir");
1889         WriteString(targ, mapvote_screenshot_dir);
1890
1891         WriteByte(targ, SVC_TEMPENTITY);
1892         WriteByte(targ, TE_CSQC_MAPVOTE);
1893         WriteByte(targ, MAPVOTE_NET_INIT);
1894
1895         WriteByte(targ, mapvote_count);
1896         WriteByte(targ, mapvote_abstain);
1897         WriteByte(targ, mapvote_detail);
1898         WriteCoord(targ, mapvote_timeout);
1899         if(mapvote_count <= 8)
1900                 WriteByte(targ, MapVote_GetMapMask());
1901         else
1902                 WriteShort(targ, MapVote_GetMapMask());
1903         for(i = 0; i < mapvote_count; ++i)
1904                 if(mapvote_maps[i] != "")
1905                 {
1906                         WriteString(targ, mapvote_maps[i]);
1907                         mapfile = strcat(mapvote_screenshot_dir, "/", mapvote_maps[i]);
1908                         pakfile = whichpack(strcat(mapfile, ".tga"));
1909                         if(pakfile == "")
1910                                 pakfile = whichpack(strcat(mapfile, ".jpg"));
1911                         if(pakfile == "")
1912                                 pakfile = whichpack(strcat(mapfile, ".png"));
1913                         print("pakfile is ", pakfile, "\n");
1914                         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
1915                                 pakfile = substring(pakfile, o, 999);
1916                         WriteString(targ, pakfile);
1917                 }
1918 }
1919
1920 void MapVote_UpdateData(float targ)
1921 {
1922         float i;
1923         WriteByte(targ, SVC_TEMPENTITY);
1924         WriteByte(targ, TE_CSQC_MAPVOTE);
1925         WriteByte(targ, MAPVOTE_NET_UPDATE);
1926         if(mapvote_count <= 8)
1927                 WriteByte(targ, MapVote_GetMapMask());
1928         else
1929                 WriteShort(targ, MapVote_GetMapMask());
1930         if(mapvote_detail)
1931                 for(i = 0; i < mapvote_count; ++i)
1932                         if(mapvote_maps[i] != "")
1933                                 WriteByte(targ, mapvote_votes[i]);
1934 }
1935
1936 void MapVote_TellVote(float targ, float vote)
1937 {
1938         WriteByte(targ, SVC_TEMPENTITY);
1939         WriteByte(targ, TE_CSQC_MAPVOTE);
1940         WriteByte(targ, MAPVOTE_NET_OWNVOTE);
1941         WriteByte(targ, vote);
1942 }
1943
1944 float MapVote_Finished(float mappos)
1945 {
1946         string result;
1947         float i;
1948         float didntvote;
1949
1950         if(cvar("sv_eventlog"))
1951         {
1952                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
1953                 result = strcat(result, ":", ftos(mapvote_votes[mappos]), "::");
1954                 didntvote = mapvote_voters;
1955                 for(i = 0; i < mapvote_count; ++i)
1956                         if(mapvote_maps[i] != "")
1957                         {
1958                                 didntvote -= mapvote_votes[i];
1959                                 if(i != mappos)
1960                                 {
1961                                         result = strcat(result, ":", mapvote_maps[i]);
1962                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
1963                                 }
1964                         }
1965                 result = strcat(result, ":didn't vote:", ftos(didntvote));
1966
1967                 GameLogEcho(result);
1968                 if(mapvote_maps_suggested[mappos])
1969                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
1970         }
1971
1972         FOR_EACH_REALCLIENT(other)
1973                 FixClientCvars(other);
1974
1975         Map_Goto_SetStr(mapvote_maps[mappos]);
1976         Map_Goto();
1977         alreadychangedlevel = TRUE;
1978         return TRUE;
1979 }
1980 void MapVote_CheckRules_1()
1981 {
1982         float i;
1983
1984         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
1985         {
1986                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
1987                 mapvote_votes[i] = 0;
1988         }
1989
1990         mapvote_voters = 0;
1991         FOR_EACH_REALCLIENT(other)
1992         {
1993                 ++mapvote_voters;
1994                 if(other.mapvote)
1995                 {
1996                         i = other.mapvote - 1;
1997                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
1998                         mapvote_votes[i] = mapvote_votes[i] + 1;
1999                 }
2000         }
2001 }
2002
2003 float MapVote_CheckRules_2()
2004 {
2005         float i;
2006         float firstPlace, secondPlace;
2007         float firstPlaceVotes, secondPlaceVotes;
2008         float mapvote_voters_real;
2009         string result;
2010
2011         mapvote_voters_real = mapvote_voters;
2012         if(mapvote_abstain)
2013                 mapvote_voters_real -= mapvote_votes[mapvote_count - 1];
2014
2015         RandomSelection_Init();
2016         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2017                 RandomSelection_Add(world, i, 1, mapvote_votes[i]);
2018         firstPlace = RandomSelection_chosen_float;
2019         firstPlaceVotes = RandomSelection_best_priority;
2020         //dprint("First place: ", ftos(firstPlace), "\n");
2021         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2022
2023         RandomSelection_Init();
2024         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2025                 if(i != firstPlace)
2026                         RandomSelection_Add(world, i, 1, mapvote_votes[i]);
2027         secondPlace = RandomSelection_chosen_float;
2028         secondPlaceVotes = RandomSelection_best_priority;
2029         //dprint("Second place: ", ftos(secondPlace), "\n");
2030         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2031
2032         if(firstPlace == -1)
2033                 error("No first place in map vote... WTF?");
2034
2035         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2036                 return MapVote_Finished(firstPlace);
2037
2038         if(mapvote_keeptwotime)
2039                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2040                 {
2041                         float didntvote;
2042                         mapvote_dirty = TRUE;
2043                         mapvote_message = "Now decide between the TOP TWO!";
2044                         mapvote_keeptwotime = 0;
2045                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2046                         result = strcat(result, ":", ftos(firstPlaceVotes));
2047                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2048                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2049                         didntvote = mapvote_voters;
2050                         for(i = 0; i < mapvote_count; ++i)
2051                                 if(mapvote_maps[i] != "")
2052                                 {
2053                                         didntvote -= mapvote_votes[i];
2054                                         if(i != firstPlace)
2055                                                 if(i != secondPlace)
2056                                                 {
2057                                                         result = strcat(result, ":", mapvote_maps[i]);
2058                                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2059                                                         if(i < mapvote_count_real)
2060                                                         {
2061                                                                 strunzone(mapvote_maps[i]);
2062                                                                 mapvote_maps[i] = "";
2063                                                         }
2064                                                 }
2065                                 }
2066                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2067                         if(cvar("sv_eventlog"))
2068                                 GameLogEcho(result);
2069                 }
2070
2071         return FALSE;
2072 }
2073 void MapVote_Tick()
2074 {
2075         string msgstr;
2076         string tmp;
2077         float i;
2078         float keeptwo;
2079         float totalvotes;
2080
2081         keeptwo = mapvote_keeptwotime;
2082         MapVote_CheckRules_1(); // count
2083         if(MapVote_CheckRules_2()) // decide
2084                 return;
2085
2086         totalvotes = 0;
2087         FOR_EACH_REALCLIENT(other)
2088         {
2089                 // hide scoreboard again
2090                 if(other.health != 2342)
2091                 {
2092                         other.health = 2342;
2093                         other.impulse = 0;
2094                         if(clienttype(other) == CLIENTTYPE_REAL)
2095                         {
2096                                 if(cvar("g_maplist_textonly"))
2097                                         stuffcmd(other, "\nin_bind 7 1 \"impulse 1\"; in_bind 7 2 \"impulse 2\"; in_bind 7 3 \"impulse 3\"; in_bind 7 4 \"impulse 4\"; in_bind 7 5 \"impulse 5\"; in_bind 7 6 \"impulse 6\"; in_bind 7 7 \"impulse 7\"; in_bind 7 8 \"impulse 8\"; in_bind 7 9 \"impulse 9\"; in_bind 7 0 \"impulse 10\"; in_bind 7 KP_1 \"impulse 1\"; in_bind 7 KP_2 \"impulse 2\"; in_bind 7 KP_3 \"impulse 3\"; in_bind 7 KP_4 \"impulse 4\"; in_bind 7 KP_5 \"impulse 5\"; in_bind 7 KP_6 \"impulse 6\"; in_bind 7 KP_7 \"impulse 7\"; in_bind 7 KP_8 \"impulse 8\"; in_bind 7 KP_9 \"impulse 9\"; in_bind 7 KP_0 \"impulse 10\"; in_bindmap 7 0\n");
2098
2099                                 msg_entity = other;
2100                                 WriteByte(MSG_ONE, SVC_FINALE);
2101                                 WriteString(MSG_ONE, "");
2102                         }
2103                 }
2104
2105                 // notify about keep-two
2106                 if(keeptwo != 0 && mapvote_keeptwotime == 0)
2107                         play2(other, "misc/invshot.wav");
2108
2109                 // clear possibly invalid votes
2110                 if(mapvote_maps[other.mapvote - 1] == "")
2111                         other.mapvote = 0;
2112                 // use impulses as new vote
2113                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2114                         if(mapvote_maps[other.impulse - 1] != "")
2115                         {
2116                                 other.mapvote = other.impulse;
2117                                 if(mapvote_detail)
2118                                         mapvote_dirty = TRUE;
2119
2120                                 msg_entity = other;
2121                                 MapVote_TellVote(MSG_ONE, other.mapvote);
2122                         }
2123                 other.impulse = 0;
2124
2125                 if(other.mapvote)
2126                         ++totalvotes;
2127         }
2128
2129         MapVote_CheckRules_1(); // just count
2130
2131         if(!cvar("g_maplist_textonly"))
2132         if(mapvote_dirty) // 1 if "keeptwo" or "impulse" happened before
2133         {
2134                 MapVote_UpdateData(MSG_BROADCAST);
2135                 mapvote_dirty = FALSE;
2136         }
2137
2138         if(cvar("g_maplist_textonly"))
2139         {
2140                 FOR_EACH_REALCLIENT(other)
2141                 {
2142                         // display voting screen
2143                         msgstr = "\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n";
2144                         msgstr = substring(msgstr, 0, strlen(msgstr) - mapvote_count);
2145                         if(mapvote_abstain)
2146                                 msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
2147                         msgstr = strcat(msgstr, mapvote_message);
2148                         msgstr = strcat(msgstr, "\n\n");
2149                         for(i = 0; i < mapvote_count; ++i)
2150                                 if(mapvote_maps[i] == "")
2151                                         msgstr = strcat(msgstr, "\n");
2152                                 else
2153                                 {
2154                                         tmp = mapvote_maps[i];
2155                                         tmp = strpad(mapvote_maxlen, tmp);
2156                                         tmp = strcat(ftos(mod(i + 1, 10)), ": ", tmp);
2157                                         if(mapvote_detail)
2158                                         {
2159                                                 tmp = strcat(tmp, " ^2(", ftos(mapvote_votes[i]), " vote");
2160                                                 if(mapvote_votes[i] != 1)
2161                                                         tmp = strcat(tmp, "s");
2162                                                 tmp = strcat(tmp, ")");
2163                                                 tmp = strpad(mapvote_maxlen + 15, tmp);
2164                                         }
2165                                         if(mapvote_abstain)
2166                                                 if(i == mapvote_count - 1)
2167                                                         msgstr = strcat(msgstr, "\n");
2168                                         if(other.mapvote == i + 1)
2169                                                 msgstr = strcat(msgstr, "^3> ", tmp, "\n");
2170                                         else
2171                                                 msgstr = strcat(msgstr, "^7  ", tmp, "\n");
2172                                 }
2173
2174                         msgstr = strcat(msgstr, "\n\n^2", ftos(totalvotes), " vote");
2175                         if(totalvotes != 1)
2176                                 msgstr = strcat(msgstr, "s");
2177                         msgstr = strcat(msgstr, " cast");
2178                         i = ceil(mapvote_timeout - time);
2179                         msgstr = strcat(msgstr, "\n", ftos(i), " second");
2180                         if(i != 1)
2181                                 msgstr = strcat(msgstr, "s");
2182                         msgstr = strcat(msgstr, " left");
2183
2184                         centerprint_atprio(other, CENTERPRIO_MAPVOTE, msgstr);
2185                 }
2186         }
2187 }
2188 void MapVote_Start()
2189 {
2190         if(mapvote_run)
2191                 return;
2192
2193         MapInfo_Enumerate();
2194         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? MAPINFO_FLAG_HIDDEN : 0), 1))
2195                 mapvote_run = TRUE;
2196 }
2197 void MapVote_Think()
2198 {
2199         if(!mapvote_run)
2200                 return;
2201
2202         if(alreadychangedlevel)
2203                 return;
2204
2205         if(time < mapvote_nextthink)
2206                 return;
2207         //dprint("tick\n");
2208
2209         mapvote_nextthink = time + 0.5;
2210
2211         if(!mapvote_initialized)
2212         {
2213                 mapvote_initialized = TRUE;
2214                 if(DoNextMapOverride())
2215                         return;
2216                 if(!cvar("g_maplist_votable") || player_count <= 0)
2217                 {
2218                         GotoNextMap();
2219                         return;
2220                 }
2221                 MapVote_Init();
2222         }
2223
2224         MapVote_Tick();
2225 };
2226
2227 string GotoMap(string m)
2228 {
2229         if(!MapInfo_CheckMap(m))
2230                 return "The map you chose is not available on this server.";
2231         cvar_set("nextmap", m);
2232         cvar_set("timelimit", "-1");
2233         if(mapvote_initialized || alreadychangedlevel)
2234         {
2235                 if(DoNextMapOverride())
2236                         return "Map switch initiated.";
2237                 else
2238                         return "Hm... no. For some reason I like THIS map more.";
2239         }
2240         else
2241                 return "Map switch will happen after scoreboard.";
2242 }
2243
2244
2245 void EndFrame()
2246 {
2247         FOR_EACH_REALCLIENT(self)
2248         {
2249                 if(self.classname == "spectator")
2250                 {
2251                         if(self.enemy.typehitsound)
2252                                 play2(self, "misc/typehit.wav");
2253                         else if(self.enemy.hitsound)
2254                                 play2(self, "misc/hit.wav");
2255                 }
2256                 else
2257                 {
2258                         if(self.typehitsound)
2259                                 play2(self, "misc/typehit.wav");
2260                         else if(self.hitsound)
2261                                 play2(self, "misc/hit.wav");
2262                 }
2263         }
2264         FOR_EACH_CLIENT(self)
2265         {
2266                 self.hitsound = FALSE;
2267                 self.typehitsound = FALSE;
2268         }
2269 }
2270
2271
2272 /*
2273  * RedirectionThink:
2274  * returns TRUE if redirecting
2275  */
2276 float redirection_timeout;
2277 float redirection_nextthink;
2278 float RedirectionThink()
2279 {
2280         float clients_found;
2281
2282         if(redirection_target == "")
2283                 return FALSE;
2284
2285         if(!redirection_timeout)
2286         {
2287                 cvar_set("sv_public", "-2");
2288                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2289                 if(redirection_target == "self")
2290                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2291                 else
2292                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2293         }
2294
2295         if(time < redirection_nextthink)
2296                 return TRUE;
2297
2298         redirection_nextthink = time + 1;
2299
2300         clients_found = 0;
2301         FOR_EACH_REALCLIENT(self)
2302         {
2303                 print("Redirecting: sending connect command to ", self.netname, "\n");
2304                 if(redirection_target == "self")
2305                         stuffcmd(self, "\ndisconnect; reconnect\n");
2306                 else
2307                         stuffcmd(self, strcat("\ndisconnect; connect ", redirection_target, "\n"));
2308                 ++clients_found;
2309         }
2310
2311         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2312
2313         if(time > redirection_timeout || clients_found == 0)
2314                 localcmd("\nwait; wait; wait; quit\n");
2315
2316         return TRUE;
2317 }
2318
2319 void RestoreGame()
2320 {
2321         // Loaded from a save game
2322         // some things then break, so let's work around them...
2323
2324         // Progs DB (capture records)
2325         if(sv_cheats)
2326                 ServerProgsDB = db_create();
2327         else
2328                 ServerProgsDB = db_load("server.db");
2329
2330         // Mapinfo
2331         MapInfo_Shutdown();
2332         MapInfo_Enumerate();
2333         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? MAPINFO_FLAG_HIDDEN : 0), 1);
2334 }
2335
2336 void SV_Shutdown()
2337 {
2338         if(world_initialized > 0)
2339         {
2340                 world_initialized = 0;
2341                 print("Saving persistent data...\n");
2342                 Ban_SaveBans();
2343                 if(!sv_cheats)
2344                         db_save(ServerProgsDB, "server.db");
2345                 if(cvar("developer"))
2346                         db_save(TemporaryDB, "server-temp.db");
2347                 db_close(ServerProgsDB);
2348                 db_close(TemporaryDB);
2349                 print("done!\n");
2350                 // tell the bot system the game is ending now
2351                 bot_endgame();
2352
2353                 MapInfo_Shutdown();
2354         }
2355         else if(world_initialized == 0)
2356         {
2357                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2358         }
2359 }