data/qcsrc/server/g_world.qc

   1 string GetMapname();
   2 void GotoNextMap();
   3
   4 void SetDefaultAlpha()
   5 {
   6         if(cvar("g_running_guns"))
   7         {
   8                 default_player_alpha = -1;
   9                 default_weapon_alpha = +1;
  10         }
  11         else if(cvar("g_cloaked"))
  12         {
  13                 default_player_alpha = cvar("g_balance_cloaked_alpha");
  14                 default_weapon_alpha = default_player_alpha;
  15         }
  16         else
  17         {
  18                 default_player_alpha = cvar("g_player_alpha");
  19                 if(default_player_alpha <= 0)
  20                         default_player_alpha = 1;
  21                 default_weapon_alpha = default_player_alpha;
  22         }
  23 }
  24
  25 void fteqcc_testbugs()
  26 {
  27         float a, b;
  28
  29         if(!cvar("developer_fteqccbugs"))
  30                 return;
  31
  32         dprint("*** fteqcc test: checking for bugs...\n");
  33
  34         a = 1;
  35         b = 5;
  36         if(sqrt(a) - sqrt(b - a) == 0)
  37                 dprint("*** fteqcc test: found same-function-twice bug\n");
  38         else
  39                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  40
  41         world.frags = -10;
  42         world.enemy = world;
  43         world.enemy.frags += 10;
  44         if(world.frags > 0.2 || world.frags < -0.2) // don't error out if it's just roundoff errors
  45                 dprint("*** fteqcc test: found += bug\n");
  46         else
  47                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  48         world.frags = 0;
  49 }
  50
  51 void GotoFirstMap()
  52 {
  53         if(cvar("_sv_init"))
  54         {
  55                 cvar_set("_sv_init", "0");
  56                 tokenize(cvar_string("g_maplist"));
  57                 if(argv(0) != GetMapname())
  58                 {
  59                         cvar_set("nextmap", argv(0));
  60                         GotoNextMap();
  61                 }
  62         }
  63 }
  64
  65 float world_already_spawned;
  66 void worldspawn (void)
  67 {
  68         if(world_already_spawned)
  69                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
  70         world_already_spawned = TRUE;
  71         // Precache all player models
  72         // Workaround for "invisible players"
  73         precache_model("models/player/carni.zym");
  74         precache_model("models/player/crash.zym");
  75         precache_model("models/player/grunt.zym");
  76         precache_model("models/player/headhunter.zym");
  77         precache_model("models/player/insurrectionist.zym");
  78         precache_model("models/player/jeandarc.zym");
  79         precache_model("models/player/lurk.zym");
  80         precache_model("models/player/lycanthrope.zym");
  81         precache_model("models/player/marine.zym");
  82         precache_model("models/player/nexus.zym");
  83         precache_model("models/player/pyria.zym");
  84         precache_model("models/player/shock.zym");
  85         precache_model("models/player/skadi.zym");
  86         precache_model("models/player/specop.zym");
  87         precache_model("models/player/visitant.zym");
  88
  89         //precache_model ("progs/beam.mdl");
  90         precache_model ("models/bullet.mdl");
  91         precache_model ("models/casing_bronze.mdl");
  92         precache_model ("models/casing_shell.mdl");
  93         precache_model ("models/casing_steel.mdl");
  94         precache_model ("models/ebomb.mdl");
  95         precache_model ("models/elaser.mdl");
  96         precache_model ("models/flash.md3");
  97         precache_model ("models/gibs/bloodyskull.md3");
  98         precache_model ("models/gibs/chunk.mdl");
  99         precache_model ("models/gibs/eye.md3");
 100         precache_model ("models/gibs/gib1.md3");
 101         //precache_model ("models/gibs/gib2.md3");
 102         //precache_model ("models/gibs/gib3.md3");
 103         //precache_model ("models/gibs/gib4.md3");
 104         precache_model ("models/gibs/gib5.md3");
 105         //precache_model ("models/gibs/gib6.md3");
 106         precache_model ("models/gibs/gib1.mdl");
 107         precache_model ("models/gibs/gib2.mdl");
 108         precache_model ("models/gibs/gib3.mdl");
 109         precache_model ("models/grenademodel.md3");
 110         precache_model ("models/hagarmissile.mdl");
 111         precache_model ("models/items/a_bullets.mdl");
 112         precache_model ("models/items/a_cells.md3");
 113         precache_model ("models/items/a_rockets.md3");
 114         precache_model ("models/items/a_shells.md3");
 115         precache_model ("models/items/g_a1.md3");
 116         precache_model ("models/items/g_a25.md3");
 117         precache_model ("models/items/g_h1.md3");
 118         precache_model ("models/items/g_h25.md3");
 119         precache_model ("models/items/g_h100.md3");
 120         precache_model ("models/items/g_invincible.md3");
 121         precache_model ("models/items/g_strength.md3");
 122         precache_model ("models/laser.mdl");
 123         precache_model ("models/misc/chatbubble.spr");
 124         precache_model ("models/misc/teambubble.spr");
 125         precache_model ("models/nexflash.md3");
 126         precache_model ("models/plasma.mdl");
 127         precache_model ("models/plasmatrail.mdl");
 128         precache_model ("models/rocket.md3");
 129         //precache_model ("models/sprites/grenexpl.spr");
 130         precache_model ("models/runematch/rune.mdl");
 131         precache_model ("models/runematch/curse.mdl");
 132         //precache_model ("models/sprites/hagar.spr");
 133         //precache_model ("models/sprites/muzzleflash.spr32");
 134         //precache_model ("models/sprites/electrocombo.spr32");
 135         //precache_model ("models/sprites/plasmahitwall.spr32");
 136         //precache_model ("models/sprites/plasmashot.spr32");
 137         //precache_model ("models/sprites/rockexpl.spr");
 138         precache_model ("models/tracer.mdl");
 139         precache_model ("models/uziflash.md3");
 140         precache_model ("models/weapons/g_crylink.md3");
 141         precache_model ("models/weapons/g_electro.md3");
 142         precache_model ("models/weapons/g_gl.md3");
 143         precache_model ("models/weapons/g_hagar.md3");
 144         precache_model ("models/weapons/g_nex.md3");
 145         precache_model ("models/weapons/g_rl.md3");
 146         precache_model ("models/weapons/g_shotgun.md3");
 147         precache_model ("models/weapons/g_uzi.md3");
 148         precache_model ("models/weapons/v_crylink.md3");
 149         precache_model ("models/weapons/v_electro.md3");
 150         precache_model ("models/weapons/v_gl.md3");
 151         precache_model ("models/weapons/v_hagar.md3");
 152         precache_model ("models/weapons/v_laser.md3");
 153         precache_model ("models/weapons/v_nex.md3");
 154         precache_model ("models/weapons/v_rl.md3");
 155         precache_model ("models/weapons/v_shotgun.md3");
 156         precache_model ("models/weapons/v_uzi.md3");
 157         precache_model ("models/weapons/w_crylink.zym");
 158         precache_model ("models/weapons/w_electro.zym");
 159         precache_model ("models/weapons/w_gl.zym");
 160         precache_model ("models/weapons/w_hagar.zym");
 161         precache_model ("models/weapons/w_laser.zym");
 162         precache_model ("models/weapons/w_nex.zym");
 163         precache_model ("models/weapons/w_rl.zym");
 164         precache_model ("models/weapons/w_shotgun.zym");
 165         precache_model ("models/weapons/w_uzi.zym");
 166
 167         // laser for laser-guided weapons
 168         precache_model ("models/laser_dot.mdl");
 169
 170         precache_sound ("misc/null.wav");
 171         precache_sound ("misc/armor1.wav");
 172         precache_sound ("misc/armor25.wav");
 173         precache_sound ("misc/armorimpact.wav");
 174         precache_sound ("misc/bodyimpact1.wav");
 175         precache_sound ("misc/bodyimpact2.wav");
 176         precache_sound ("misc/gib.wav");
 177         precache_sound ("misc/gib_splat01.wav");
 178         precache_sound ("misc/gib_splat02.wav");
 179         precache_sound ("misc/gib_splat03.wav");
 180         precache_sound ("misc/gib_splat04.wav");
 181         //precache_sound ("misc/h2ohit.wav");
 182         precache_sound ("misc/hit.wav");
 183         precache_sound ("misc/footstep01.wav");
 184         precache_sound ("misc/footstep02.wav");
 185         precache_sound ("misc/footstep03.wav");
 186         precache_sound ("misc/footstep04.wav");
 187         precache_sound ("misc/footstep05.wav");
 188         precache_sound ("misc/footstep06.wav");
 189         precache_sound ("misc/hitground1.ogg");
 190         precache_sound ("misc/hitground2.ogg");
 191         precache_sound ("misc/hitground3.ogg");
 192         precache_sound ("misc/hitground4.ogg");
 193         precache_sound ("misc/itempickup.ogg");
 194         precache_sound ("misc/itemrespawn.ogg");
 195         precache_sound ("misc/jumppad.ogg");
 196         precache_sound ("misc/mediumhealth.ogg");
 197         precache_sound ("misc/megahealth.ogg");
 198         precache_sound ("misc/minihealth.ogg");
 199         precache_sound ("misc/powerup.ogg");
 200         precache_sound ("misc/powerup_shield.ogg");
 201         precache_sound ("misc/talk.wav");
 202         precache_sound ("misc/teleport.ogg");
 203         precache_sound ("plats/medplat1.wav");
 204         precache_sound ("plats/medplat2.wav");
 205         precache_sound ("player/lava.wav");
 206         precache_sound ("player/slime.wav");
 207         precache_sound ("weapons/crylink_fire.ogg");
 208         precache_sound ("weapons/electro_bounce.ogg");
 209         precache_sound ("weapons/electro_fire.ogg");
 210         precache_sound ("weapons/electro_fire2.ogg");
 211         precache_sound ("weapons/electro_fly.wav");
 212         precache_sound ("weapons/electro_impact.ogg");
 213         precache_sound ("weapons/electro_impact_combo.ogg");
 214         //precache_sound ("weapons/grenade_bounce.ogg");
 215         precache_sound ("weapons/grenade_bounce1.ogg");
 216         precache_sound ("weapons/grenade_bounce2.ogg");
 217         precache_sound ("weapons/grenade_bounce3.ogg");
 218         precache_sound ("weapons/grenade_fire.ogg");
 219         precache_sound ("weapons/grenade_impact.ogg");
 220         precache_sound ("weapons/hagar_fire.ogg");
 221         precache_sound ("weapons/hagexp1.ogg");
 222         precache_sound ("weapons/hagexp2.ogg");
 223         precache_sound ("weapons/hagexp3.ogg");
 224         precache_sound ("weapons/hook_fire.ogg");
 225         precache_sound ("weapons/hook_impact.ogg");
 226         precache_sound ("weapons/lasergun_fire.ogg");
 227         precache_sound ("weapons/laserimpact.ogg");
 228         precache_sound ("weapons/nexfire.ogg");
 229         precache_sound ("weapons/neximpact.ogg");
 230         precache_sound ("weapons/ric1.ogg");
 231         precache_sound ("weapons/ric2.ogg");
 232         precache_sound ("weapons/ric3.ogg");
 233         precache_sound ("weapons/rocket_fire.ogg");
 234         precache_sound ("weapons/rocket_fly.wav");
 235         precache_sound ("weapons/rocket_impact.ogg");
 236         precache_sound ("weapons/rocket_det.ogg");
 237         precache_sound ("weapons/shotgun_fire.ogg");
 238         precache_sound ("weapons/tink1.ogg");
 239         precache_sound ("weapons/uzi_fire.ogg");
 240         precache_sound ("weapons/weapon_switch.ogg");
 241         precache_sound ("weapons/weaponpickup.ogg");
 242         precache_sound ("weapons/strength_fire.ogg");
 243
 244         //precache_sound ("announce/male/kill10.ogg");
 245         //precache_sound ("announce/male/kill15.ogg");
 246         //precache_sound ("announce/male/kill20.ogg");
 247         //precache_sound ("announce/male/kill25.ogg");
 248         //precache_sound ("announce/male/kill3.ogg");
 249         //precache_sound ("announce/male/kill30.ogg");
 250         //precache_sound ("announce/male/kill4.ogg");
 251         //precache_sound ("announce/male/kill5.ogg");
 252         //precache_sound ("announce/male/kill6.ogg");
 253         //precache_sound ("announce/male/mapkill1.ogg");
 254         //precache_sound ("announce/robotic/last_second_save.ogg");
 255         //precache_sound ("announce/robotic/narrowly_averted.ogg");
 256         //precache_sound ("minstagib/mockery.ogg");
 257
 258         // announcer sounds - male
 259         precache_sound ("announcer/male/03kills.ogg");
 260         precache_sound ("announcer/male/05kills.ogg");
 261         precache_sound ("announcer/male/10kills.ogg");
 262         precache_sound ("announcer/male/15kills.ogg");
 263         precache_sound ("announcer/male/20kills.ogg");
 264         precache_sound ("announcer/male/25kills.ogg");
 265         precache_sound ("announcer/male/30kills.ogg");
 266         precache_sound ("announcer/male/botlike.ogg");
 267         precache_sound ("announcer/male/electrobitch.ogg");
 268         precache_sound ("announcer/male/welcome.ogg");
 269         precache_sound ("announcer/male/yoda.ogg");
 270
 271         // announcer sounds - robotic
 272         precache_sound ("announcer/robotic/1fragleft.ogg");
 273         precache_sound ("announcer/robotic/1minuteremains.ogg");
 274         precache_sound ("announcer/robotic/2fragsleft.ogg");
 275         precache_sound ("announcer/robotic/3fragsleft.ogg");
 276         precache_sound ("announcer/robotic/lastsecond.ogg");
 277         precache_sound ("announcer/robotic/narrowly.ogg");
 278
 279         // plays music for the level if there is any
 280         if (self.noise)
 281         {
 282                 precache_sound (self.noise);
 283                 ambientsound ('0 0 0', self.noise, 1.00, ATTN_NONE);
 284         }
 285
 286                 // 0 normal
 287         lightstyle(0, "m");
 288
 289         // 1 FLICKER (first variety)
 290         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 291
 292         // 2 SLOW STRONG PULSE
 293         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 294
 295         // 3 CANDLE (first variety)
 296         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 297
 298         // 4 FAST STROBE
 299         lightstyle(4, "mamamamamama");
 300
 301         // 5 GENTLE PULSE 1
 302         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 303
 304         // 6 FLICKER (second variety)
 305         lightstyle(6, "nmonqnmomnmomomno");
 306
 307         // 7 CANDLE (second variety)
 308         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 309
 310         // 8 CANDLE (third variety)
 311         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 312
 313         // 9 SLOW STROBE (fourth variety)
 314         lightstyle(9, "aaaaaaaazzzzzzzz");
 315
 316         // 10 FLUORESCENT FLICKER
 317         lightstyle(10, "mmamammmmammamamaaamammma");
 318
 319         // 11 SLOW PULSE NOT FADE TO BLACK
 320         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 321
 322         // styles 32-62 are assigned by the light program for switchable lights
 323
 324         // 63 testing
 325         lightstyle(63, "a");
 326
 327         player_count = 0;
 328         lms_dead_count = 0;
 329         lms_lowest_lives = 0;
 330         lms_next_place = 0;
 331
 332         GotoFirstMap();
 333
 334         if(cvar("g_campaign"))
 335                 CampaignPreInit();
 336
 337         InitGameplayMode();
 338         //if (cvar("g_domination"))
 339         //      dom_init();
 340
 341         local entity head;
 342         head = nextent(world);
 343         maxclients = 0;
 344         while(head)
 345         {
 346                 maxclients++;
 347                 head = nextent(head);
 348         }
 349
 350         GameLogInit(); // prepare everything
 351         if(cvar("sv_eventlog"))
 352         {
 353                 local string s;
 354                 GameLogEcho(":logversion:2", FALSE);
 355                 s = strcat(cvar_string("sv_eventlog_files_counter"), ".");
 356                 s = strcat(s, ftos(random()));
 357                 GameLogEcho(strcat(":gamestart:", GetMapname(), ":", s), FALSE);
 358                 s = ":gameinfo:mutators:LIST";
 359                 if(cvar("g_grappling_hook"))
 360                         s = strcat(s, ":grappling_hook");
 361                 if(!cvar("g_use_ammunition"))
 362                         s = strcat(s, ":no_use_ammunition");
 363                 if(!cvar("g_pickup_items"))
 364                         s = strcat(s, ":no_pickup_items");
 365                 if(cvar("g_instagib"))
 366                         s = strcat(s, ":instagib");
 367                 if(cvar("g_rocketarena"))
 368                         s = strcat(s, ":rockerarena");
 369                 if(cvar("g_nixnex"))
 370                         s = strcat(s, ":nixnex");
 371                 if(cvar("g_vampire"))
 372                         s = strcat(s, ":vampire");
 373                 if(cvar("g_laserguided_missile"))
 374                         s = strcat(s, ":laserguided_missile");
 375                 if(cvar("g_norecoil"))
 376                         s = strcat(s, ":norecoil");
 377                 if(cvar("g_midair"))
 378                         s = strcat(s, ":midair");
 379                 if(cvar("g_minstagib"))
 380                         s = strcat(s, ":minstagib");
 381                 GameLogEcho(s, FALSE);
 382                 GameLogEcho(":gameinfo:end", FALSE);
 383         }
 384
 385         cvar_set("nextmap", "");
 386
 387         SetDefaultAlpha();
 388
 389         if(cvar("g_campaign"))
 390                 CampaignPostInit();
 391
 392         fteqcc_testbugs();
 393 }
 394
 395 void light (void)
 396 {
 397         makestatic (self);
 398 }
 399
 400 float( string pFilename ) TryFile =
 401 {
 402         local float lHandle;
 403         dprint("TryFile(\"", pFilename, "\")\n");
 404         lHandle = fopen( pFilename, FILE_READ );
 405         if( lHandle != -1 ) {
 406                 fclose( lHandle );
 407                 return TRUE;
 408         } else {
 409                 return FALSE;
 410         }
 411 };
 412
 413 string GetMapname()
 414 {
 415         if (game == GAME_DEATHMATCH)
 416                 return strcat("dm_", mapname);
 417         else if (game == GAME_TEAM_DEATHMATCH)
 418                 return strcat("tdm_", mapname);
 419         else if (game == GAME_DOMINATION)
 420                 return strcat("dom_", mapname);
 421         else if (game == GAME_CTF)
 422                 return strcat("ctf_", mapname);
 423         else if (game == GAME_RUNEMATCH)
 424                 return strcat("rune_", mapname);
 425         else if (game == GAME_LMS)
 426                 return strcat("lms_", mapname);
 427         return strcat("dm_", mapname);
 428 }
 429
 430 float Map_Count, Map_Current;
 431
 432 // NOTE: this now expects the map list to be already tokenize()d and the count in Map_Count
 433 float GetMaplistPosition()
 434 {
 435         float pos;
 436         string map;
 437
 438         map = GetMapname();
 439         for(pos = 0; pos < Map_Count; ++pos)
 440                 if(map == argv(pos))
 441                         return pos;
 442
 443         // resume normal maplist rotation if current map is not in g_maplist
 444         return cvar("g_maplist_index");
 445 }
 446
 447 float MapHasRightSize(string map)
 448 {
 449         // open map size restriction file
 450         float fh;
 451         dprint("opensize "); dprint(map);
 452         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 453         if(fh >= 0)
 454         {
 455                 float mapmin, mapmax;
 456                 dprint(": ok, ");
 457                 mapmin = stof(fgets(fh));
 458                 mapmax = stof(fgets(fh));
 459                 fclose(fh);
 460                 if(player_count < mapmin)
 461                 {
 462                         dprint("not enough\n");
 463                         return FALSE;
 464                 }
 465                 if(player_count > mapmax)
 466                 {
 467                         dprint("too many\n");
 468                         return FALSE;
 469                 }
 470                 dprint("right size\n");
 471                 return TRUE;
 472         }
 473         dprint(": not found\n");
 474         return TRUE;
 475 }
 476
 477 string Map_Filename(float position)
 478 {
 479         return strcat("maps/", argv(position), ".mapcfg");
 480 }
 481
 482 float(float position, float pass) Map_Check =
 483 {
 484         string filename;
 485         filename = Map_Filename(position);
 486         if(TryFile(filename))
 487         {
 488                 if(pass == 2)
 489                         return 1;
 490                 if(MapHasRightSize(argv(position)))
 491                         return 1;
 492                 return 0;
 493         }
 494         else
 495                 dprint( "Couldn't find '", filename, "'..\n" );
 496
 497         return 0;
 498 }
 499
 500 void(float position) Map_Goto =
 501 {
 502         cvar_set("g_maplist_index", ftos(position));
 503         localcmd(strcat("exec \"", Map_Filename(position) ,"\"\n"));
 504 }
 505
 506 // return codes of map selectors:
 507 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
 508 //   -2 = permanent failure
 509 float() MaplistMethod_Iterate = // usual method
 510 {
 511         float pass, i;
 512
 513         for(pass = 1; pass <= 2; ++pass)
 514         {
 515                 for(i = 1; i < Map_Count; ++i)
 516                 {
 517                         float mapindex;
 518                         mapindex = math_mod(i + Map_Current, Map_Count);
 519                         if(Map_Check(mapindex, pass))
 520                                 return mapindex;
 521                 }
 522         }
 523         return -1;
 524 }
 525
 526 float() MaplistMethod_Repeat = // fallback method
 527 {
 528         if(Map_Check(Map_Current, 2))
 529                 return Map_Current;
 530         return -2;
 531 }
 532
 533 float() MaplistMethod_Random = // random map selection
 534 {
 535         float i, imax;
 536
 537         imax = 42;
 538
 539         for(i = 0; i <= imax; ++i)
 540         {
 541                 float mapindex;
 542                 mapindex = math_mod(Map_Current + ceil(random() * (Map_Count - 1)), Map_Count); // any OTHER map
 543                 if(Map_Check(mapindex, 1))
 544                         return mapindex;
 545         }
 546         return -1;
 547 }
 548
 549 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
 550 // the exponent sets a bias on the map selection:
 551 // the higher the exponent, the
 552 {
 553         float i, j, imax, insertpos;
 554
 555         imax = 42;
 556
 557         if(Map_Count <= 1)
 558                 return 0; // only one map, then always play this one
 559
 560         for(i = 0; i <= imax; ++i)
 561         {
 562                 string newlist;
 563
 564                 // now reinsert this at another position
 565                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
 566                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
 567                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
 568                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
 569
 570                 // insert the current map there
 571                 newlist = "";
 572                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
 573                         newlist = strcat(newlist, "'", argv(j), "'");
 574                 newlist = strcat(newlist, "'", argv(0), "'");  // now insert the just selected map
 575                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
 576                         newlist = strcat(newlist, "'", argv(j), "'");
 577                 cvar_set("g_maplist", newlist);
 578                 Map_Count = tokenize(newlist);
 579
 580                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
 581                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
 582                 if(Map_Check(Map_Current, 1))
 583                         return Map_Current;
 584         }
 585         return -1;
 586 }
 587
 588 void() Maplist_Init =
 589 {
 590         string temp;
 591         temp = cvar_string("g_maplist");
 592         Map_Count = tokenize(temp);
 593         if(Map_Count == 0)
 594         {
 595                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
 596                 cvar_set("g_maplist", temp = cvar_string("g_maplist_defaultlist"));
 597                 Map_Count = tokenize(temp);
 598         }
 599         if(Map_Count == 0)
 600                 error("empty maplist, cannot select a new map");
 601         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
 602 }
 603
 604 void() GotoNextMap =
 605 {
 606         //local string nextmap;
 607         //local float n, nummaps;
 608         //local string s;
 609         string exit_cfg;
 610         if (alreadychangedlevel)
 611                 return;
 612         alreadychangedlevel = TRUE;
 613
 614         if(cvar("g_campaign"))
 615         {
 616                 CampaignPostIntermission();
 617                 return;
 618         }
 619
 620         if (cvar("samelevel")) // if samelevel is set, stay on same level
 621         {
 622                 // this does not work because it tries to exec maps/nexdm01.mapcfg (which doesn't exist, it should be trying maps/dm_nexdm01.mapcfg for example)
 623                 //localcmd(strcat("exec \"maps/", mapname, ".mapcfg\"\n"));
 624                 // so instead just restart the current map using the restart command (DOES NOT WORK PROPERLY WITH exit_cfg STUFF)
 625                 localcmd("restart\n");
 626                 //changelevel (mapname);
 627                 return;
 628         }
 629
 630         // if an exit cfg is defined by exiting map, exec it.
 631         exit_cfg = cvar_string("exit_cfg");
 632         if(exit_cfg != "")
 633                 localcmd(strcat("exec \"", exit_cfg, "\"\n"));
 634
 635         localcmd("exec game_reset.cfg\n");
 636
 637
 638         if (cvar("lastlevel"))
 639         {
 640                 localcmd(strcat("set lastlevel 0\n"));
 641                 localcmd(strcat("togglemenu\n"));
 642         }
 643         else
 644         {
 645                 float nextMap;
 646                 float allowReset;
 647
 648                 // cvar "nextmap" always gets priority
 649                 if(TryFile(strcat("maps/", cvar_string("nextmap"), ".mapcfg")))
 650                 {
 651                         localcmd(strcat("exec \"maps/", cvar_string("nextmap"), ".mapcfg\"\n"));
 652                         return;
 653                 }
 654
 655                 for(allowReset = 1; allowReset >= 0; --allowReset)
 656                 {
 657                         Maplist_Init();
 658                         nextMap = -1;
 659
 660                         if(nextMap == -1)
 661                                 if(cvar("g_maplist_shuffle") > 0)
 662                                         nextMap = MaplistMethod_Shuffle(cvar("g_maplist_shuffle") + 1);
 663
 664                         if(nextMap == -1)
 665                                 if(cvar("g_maplist_selectrandom"))
 666                                         nextMap = MaplistMethod_Random();
 667
 668                         if(nextMap == -1)
 669                                 nextMap = MaplistMethod_Iterate();
 670
 671                         if(nextMap == -1)
 672                                 nextMap = MaplistMethod_Repeat();
 673
 674                         if(nextMap >= 0)
 675                         {
 676                                 Map_Goto(nextMap);
 677                                 break;
 678                         }
 679                         else // PERMANENT FAILURE
 680                         {
 681                                 if(allowReset)
 682                                 {
 683                                         bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
 684                                         cvar_set("g_maplist", cvar_string("g_maplist_defaultlist"));
 685                                 }
 686                                 else
 687                                 {
 688                                         error("Everything is broken - not even the default map list works. Please report this to the developers.");
 689                                 }
 690                         }
 691                 }
 692         }
 693 };
 694
 695
 696 /*
 697 ============
 698 IntermissionThink
 699
 700 When the player presses attack or jump, change to the next level
 701 ============
 702 */
 703 void() IntermissionThink =
 704 {
 705         if(cvar("sv_autoscreenshot"))
 706         if(self.cnt > time)
 707         {
 708                 self.cnt = FALSE;
 709                 if(clienttype(self) == CLIENTTYPE_REAL)
 710                         stuffcmd(self, "screenshot\necho \"^5A screenshot has been taken at request of the server.\"\n");
 711                 return;
 712         }
 713
 714         if (time < intermission_exittime)
 715                 return;
 716
 717         if (time < intermission_exittime + 10 && !self.button0 && !self.button1 && !self.button2 && !self.button3)
 718                 return;
 719
 720         GotoNextMap ();
 721 };
 722
 723 /*
 724 ============
 725 FindIntermission
 726
 727 Returns the entity to view from
 728 ============
 729 */
 730 /*
 731 entity() FindIntermission =
 732 {
 733         local   entity spot;
 734         local   float cyc;
 735
 736 // look for info_intermission first
 737         spot = find (world, classname, "info_intermission");
 738         if (spot)
 739         {       // pick a random one
 740                 cyc = random() * 4;
 741                 while (cyc > 1)
 742                 {
 743                         spot = find (spot, classname, "info_intermission");
 744                         if (!spot)
 745                                 spot = find (spot, classname, "info_intermission");
 746                         cyc = cyc - 1;
 747                 }
 748                 return spot;
 749         }
 750
 751 // then look for the start position
 752         spot = find (world, classname, "info_player_start");
 753         if (spot)
 754                 return spot;
 755
 756 // testinfo_player_start is only found in regioned levels
 757         spot = find (world, classname, "testplayerstart");
 758         if (spot)
 759                 return spot;
 760
 761 // then look for the start position
 762         spot = find (world, classname, "info_player_deathmatch");
 763         if (spot)
 764                 return spot;
 765
 766         //objerror ("FindIntermission: no spot");
 767         return world;
 768 };
 769 */
 770
 771 /*
 772 ===============================================================================
 773
 774 RULES
 775
 776 ===============================================================================
 777 */
 778
 779 void() DumpStats =
 780 {
 781         local float file;
 782         local string s;
 783
 784         if(cvar("_printstats"))
 785                 cvar_set("_printstats", "0");
 786         else if(!gameover)
 787                 return;
 788
 789         if(gameover)
 790                 s = ":scores:";
 791         else
 792                 s = ":status:";
 793
 794         s = strcat(s, GetMapname(), ":", ftos(rint(time)));
 795
 796         if(cvar("sv_eventlog") && gameover)
 797                 GameLogEcho(s, FALSE);
 798         else if(cvar("sv_logscores_console"))
 799                 ServerConsoleEcho(s, FALSE);
 800         if(cvar("sv_logscores_file"))
 801         {
 802                 file = fopen(cvar_string("sv_logscores_filename"), FILE_APPEND);
 803                 fputs(file, strcat(s, "\n"));
 804         }
 805
 806         other = findchainflags(flags, FL_CLIENT);
 807         while (other)
 808         {
 809                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && cvar("sv_logscores_bots")))
 810                 {
 811                         s = strcat(":player:", ftos(other.frags), ":");
 812                         s = strcat(s, ftos(other.deaths), ":");
 813                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
 814                         s = strcat(s, ftos(other.team), ":");
 815
 816                         if(cvar("sv_logscores_file"))
 817                                 fputs(file, strcat(s, other.netname, "\n"));
 818                         if(cvar("sv_eventlog") && gameover)
 819                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname), TRUE);
 820                         else if(cvar("sv_logscores_console"))
 821                                 ServerConsoleEcho(strcat(s, other.netname), TRUE);
 822                 }
 823                 other = other.chain;
 824         }
 825
 826         if(cvar("sv_eventlog") && gameover)
 827                 GameLogEcho(":end", FALSE);
 828         else if(cvar("sv_logscores_console"))
 829                 ServerConsoleEcho(":end", FALSE);
 830         if(cvar("sv_logscores_file"))
 831         {
 832                 fputs(file, ":end\n");
 833                 fclose(file);
 834         }
 835 }
 836
 837
 838 /*
 839 go to the next level for deathmatch
 840 only called if a time or frag limit has expired
 841 */
 842 void() NextLevel =
 843 {
 844         gameover = TRUE;
 845
 846         intermission_running = 1;
 847
 848 // enforce a wait time before allowing changelevel
 849         if(player_count > 0)
 850                 intermission_exittime = time + cvar("sv_mapchange_delay");
 851         else
 852                 intermission_exittime = -60;
 853
 854         WriteByte (MSG_ALL, SVC_CDTRACK);
 855         WriteByte (MSG_ALL, 3);
 856         WriteByte (MSG_ALL, 3);
 857
 858         //pos = FindIntermission ();
 859
 860         VoteReset();
 861
 862         DumpStats();
 863
 864         if(cvar("sv_eventlog"))
 865                 GameLogEcho(":gameover", FALSE);
 866
 867         GameLogClose();
 868
 869         other = findchainflags(flags, FL_CLIENT);
 870         while (other != world)
 871         {
 872                 //other.nextthink = time + 0.5;
 873                 other.takedamage = DAMAGE_NO;
 874                 other.solid = SOLID_NOT;
 875                 other.movetype = MOVETYPE_NONE;
 876                 other.angles = other.v_angle;
 877                 other.angles_x = other.angles_x * -1;
 878                 other.cnt = time + 0.5; // used for autoscreenshot
 879
 880                 self = other;
 881
 882                 if(other.winning)
 883                         bprint(strcat(other.netname, " ^7wins.\n"));
 884
 885                 /*
 886                 if (pos != world);
 887                 {
 888                         other.modelindex = 0;
 889                         other.weaponentity = world; // remove weapon model
 890                         other.view_ofs = '0 0 0';
 891                         other.angles = other.v_angle = pos.mangle;
 892                         if (!other.angles)
 893                         {
 894                                 other.angles = other.v_angle = pos.angles;
 895                                 other.v_angle_x = other.v_angle_x * -1;
 896                         }
 897                         other.fixangle = TRUE;          // turn this way immediately
 898                         setorigin (other, pos.origin);
 899                 }
 900                 */
 901                 other = other.chain;
 902         }
 903
 904         if(cvar("g_campaign"))
 905                 CampaignPreIntermission();
 906
 907         WriteByte (MSG_ALL, SVC_INTERMISSION);
 908 };
 909
 910 /*
 911 ============
 912 CheckRules_Player
 913
 914 Exit deathmatch games upon conditions
 915 ============
 916 */
 917 void() CheckRules_Player =
 918 {
 919         if (gameover)   // someone else quit the game already
 920                 return;
 921
 922         // fixme: don't check players; instead check dom_team and ctf_team entities
 923         //   (div0: and that in CheckRules_World please)
 924         centermsg_check();
 925 };
 926
 927 float checkrules_oneminutewarning;
 928 float checkrules_leaderfrags;
 929 float tdm_max_score, tdm_old_score;
 930
 931 float checkrules_equality;
 932 float checkrules_overtimewarning;
 933 float checkrules_overtimeend;
 934
 935 void() InitiateOvertime =
 936 {
 937         if(!checkrules_overtimeend)
 938                 checkrules_overtimeend = time + 60 * cvar("timelimit_maxovertime");
 939 }
 940
 941 float WINNING_NO = 0; // no winner, but time limits may terminate the game
 942 float WINNING_YES = 1; // winner found
 943 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
 944 float WINNING_STARTOVERTIME = 3; // no winner, enter overtime NOW
 945
 946 float(float fraglimitreached, float equality) GetWinningCode =
 947 {
 948         if(equality)
 949                 if(fraglimitreached)
 950                         return WINNING_STARTOVERTIME;
 951                 else
 952                         return WINNING_NEVER;
 953         else
 954                 if(fraglimitreached)
 955                         return WINNING_YES;
 956                 else
 957                         return WINNING_NO;
 958 }
 959
 960 // set the .winning flag for exactly those players with a given field value
 961 void(.float field, float value) SetWinners =
 962 {
 963         entity head;
 964         head = findchain(classname, "player");
 965         while (head)
 966         {
 967                 head.winning = (head.field == value);
 968                 head = head.chain;
 969         }
 970 }
 971
 972 // set the .winning flag for those players with a given field value
 973 void(.float field, float value) AddWinners =
 974 {
 975         entity head;
 976         head = findchain(classname, "player");
 977         while (head)
 978         {
 979                 if(head.field == value)
 980                         head.winning = 1;
 981                 head = head.chain;
 982         }
 983 }
 984
 985 // clear the .winning flags
 986 void(void) ClearWinners =
 987 {
 988         entity head;
 989         head = findchain(classname, "player");
 990         while (head)
 991         {
 992                 head.winning = 0;
 993                 head = head.chain;
 994         }
 995 }
 996
 997 // LMS winning condition: game terminates if and only if there's at most one
 998 // one player who's living lives. Top two scores being equal cancels the time
 999 // limit.
1000 float() WinningCondition_LMS =
1001 {
1002         entity head;
1003
1004         if(lms_dead_count < 0)
1005                 lms_dead_count = 0;
1006
1007         if(player_count > 1 && lms_dead_count >= player_count - 1)
1008                 return WINNING_YES; // He's the last man standing!
1009
1010         if((player_count == 1 && lms_dead_count == 1))
1011                 return WINNING_YES; // All dead... (n:n is handled by the test above)
1012
1013         // dprint("player count = "); dprint(ftos(player_count));
1014         // dprint(", dead count = "); dprint(ftos(lms_dead_count));
1015         // dprint("\n");
1016
1017         // When we get here, we have at least two players who are actually LIVING,
1018         // or one player who is still waiting for a victim to join the server. Now
1019         // check if the top two players have equal score.
1020
1021         checkrules_leaderfrags = 0;
1022         head = findchain(classname, "player");
1023         checkrules_equality = FALSE;
1024         while (head)
1025         {
1026                 if(head.frags > checkrules_leaderfrags)
1027                 {
1028                         checkrules_leaderfrags = head.frags;
1029                         checkrules_equality = FALSE;
1030                 }
1031                 else if(head.frags > 0 && head.frags == checkrules_leaderfrags)
1032                         checkrules_equality = TRUE;
1033                 head = head.chain;
1034         }
1035
1036         SetWinners(frags, checkrules_leaderfrags);
1037
1038         // The top two players have the same amount of lives? No timelimit then,
1039         // enter overtime...
1040
1041         if(checkrules_equality)
1042                 return WINNING_NEVER;
1043
1044         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1045         return WINNING_NO;
1046 }
1047
1048 // DM winning condition: game terminates if a player reached the fraglimit,
1049 // unless the first two players have the same score. The latter case also
1050 // breaks the time limit.
1051 float(float fraglimit) WinningCondition_MaxIndividualScore =
1052 {
1053         float checkrules_oldleaderfrags;
1054         entity head;
1055
1056         checkrules_oldleaderfrags = checkrules_leaderfrags;
1057         checkrules_leaderfrags = 0;
1058         head = findchain(classname, "player");
1059         checkrules_equality = FALSE;
1060         while (head)
1061         {
1062                 if(head.frags > checkrules_leaderfrags)
1063                 {
1064                         checkrules_leaderfrags = head.frags;
1065                         checkrules_equality = FALSE;
1066                 }
1067                 else if(head.frags > 0 && head.frags == checkrules_leaderfrags)
1068                         checkrules_equality = TRUE;
1069                 head = head.chain;
1070         }
1071
1072         if(checkrules_leaderfrags > 0)
1073                 SetWinners(frags, checkrules_leaderfrags);
1074         else
1075                 ClearWinners();
1076
1077         if (!cvar("g_runematch"))
1078                 if (checkrules_leaderfrags != checkrules_oldleaderfrags)
1079                 {
1080                         if (checkrules_leaderfrags == fraglimit - 1)
1081                                 sound(world, CHAN_AUTO, "announcer/robotic/1fragleft.ogg", 1, ATTN_NONE);
1082                         else if (checkrules_leaderfrags == fraglimit - 2)
1083                                 sound(world, CHAN_AUTO, "announcer/robotic/2fragsleft.ogg", 1, ATTN_NONE);
1084                         else if (checkrules_leaderfrags == fraglimit - 3)
1085                                 sound(world, CHAN_AUTO, "announcer/robotic/3fragsleft.ogg", 1, ATTN_NONE);
1086                 }
1087
1088         return GetWinningCode(fraglimit && checkrules_leaderfrags >= fraglimit, checkrules_equality);
1089 }
1090
1091 float(float fraglimit) WinningConditionBase_Teamplay =
1092 {
1093         tdm_old_score = tdm_max_score;
1094         tdm_max_score = max(team1_score, team2_score, team3_score, team4_score);
1095
1096         checkrules_equality =
1097         (
1098                 (tdm_max_score > 0)
1099                 &&
1100                 (
1101                           (team1_score == tdm_max_score)
1102                         + (team2_score == tdm_max_score)
1103                         + (team3_score == tdm_max_score)
1104                         + (team4_score == tdm_max_score)
1105                         >= 2));
1106
1107         ClearWinners();
1108         if(tdm_max_score > 0)
1109         {
1110                 if(team1_score == tdm_max_score)
1111                         AddWinners(team, COLOR_TEAM1);
1112                 if(team2_score == tdm_max_score)
1113                         AddWinners(team, COLOR_TEAM2);
1114                 if(team3_score == tdm_max_score)
1115                         AddWinners(team, COLOR_TEAM3);
1116                 if(team4_score == tdm_max_score)
1117                         AddWinners(team, COLOR_TEAM4);
1118         }
1119
1120         if(!cvar("g_runematch") && !cvar("g_domination"))
1121                 if(tdm_max_score != tdm_old_score)
1122                 {
1123                         if(tdm_max_score == fraglimit - 1)
1124                                 sound(world, CHAN_AUTO, "announcer/robotic/1fragleft.ogg", 1, ATTN_NONE);
1125                         else if(tdm_max_score == fraglimit - 2)
1126                                 sound(world, CHAN_AUTO, "announcer/robotic/2fragsleft.ogg", 1, ATTN_NONE);
1127                         else if(tdm_max_score == fraglimit - 3)
1128                                 sound(world, CHAN_AUTO, "announcer/robotic/3fragsleft.ogg", 1, ATTN_NONE);
1129                 }
1130
1131         return GetWinningCode(fraglimit && tdm_max_score >= fraglimit, checkrules_equality);
1132 }
1133
1134 // TDM winning condition: game terminates if a team's score sum reached the
1135 // fraglimit, unless the first two teams have the same total score. The latter
1136 // case also breaks the time limit.
1137 float(float fraglimit) WinningCondition_MaxTeamSum =
1138 {
1139         entity head;
1140
1141         team1_score = team2_score = team3_score = team4_score = 0;
1142
1143         head = findchain(classname, "player");
1144         while (head)
1145         {
1146                 if(head.team == COLOR_TEAM1)
1147                         team1_score += head.frags;
1148                 else if(head.team == COLOR_TEAM2)
1149                         team2_score += head.frags;
1150                 else if(head.team == COLOR_TEAM3)
1151                         team3_score += head.frags;
1152                 else if(head.team == COLOR_TEAM4)
1153                         team4_score += head.frags;
1154                 head = head.chain;
1155         }
1156
1157         return WinningConditionBase_Teamplay(fraglimit);
1158 }
1159
1160 // DOM/CTF winning condition: game terminates if the max of a team's players'
1161 // score reached the fraglimit, unless the first two teams have the same
1162 // maximum score. The latter case also breaks the time limit.
1163 float(float fraglimit) WinningCondition_MaxTeamMax =
1164 {
1165         entity head;
1166
1167         team1_score = team2_score = team3_score = team4_score = 0;
1168
1169         head = findchain(classname, "player");
1170         while (head)
1171         {
1172                 if(head.team == COLOR_TEAM1)
1173                 {
1174                         if(head.frags > team1_score)
1175                                 team1_score = head.frags;
1176                 }
1177                 else if(head.team == COLOR_TEAM2)
1178                 {
1179                         if(head.frags > team2_score)
1180                                 team2_score = head.frags;
1181                 }
1182                 else if(head.team == COLOR_TEAM3)
1183                 {
1184                         if(head.frags > team3_score)
1185                                 team3_score = head.frags;
1186                 }
1187                 else if(head.team == COLOR_TEAM4)
1188                 {
1189                         if(head.frags > team4_score)
1190                                 team4_score = head.frags;
1191                 }
1192                 head = head.chain;
1193         }
1194
1195         return WinningConditionBase_Teamplay(fraglimit);
1196 }
1197
1198 void PrintScoreboardFor(string name, string colorcode, float whichteam)
1199 {
1200         entity head;
1201         float fragtotal;
1202         string s;
1203         float found;
1204         found = FALSE;
1205         head = find(world, classname, "player");
1206         while(head)
1207         {
1208                 if(!whichteam || head.team == whichteam)
1209                 {
1210                         if(name != "")
1211                                 if(!found)
1212                                         ServerConsoleEcho(strcat(" ", colorcode, name, ":"), FALSE);
1213                         found = TRUE;
1214                         fragtotal = fragtotal + head.frags;
1215                         s = ftos(head.frags);
1216                         s = strcat(s, "/", ftos(head.deaths));
1217                         s = strcat(s, " @ ", ftos(head.ping));
1218                         if(clienttype(head) == CLIENTTYPE_BOT)
1219                                 s = strcat(s, "botms");
1220                         else
1221                                 s = strcat(s, "ms");
1222                         ServerConsoleEcho(strcat("  ", colorcode, head.netname, colorcode, " (", s, ")"), TRUE);
1223                 }
1224                 head = find(head, classname, "player");
1225         }
1226         if(whichteam && found)
1227                 ServerConsoleEcho(strcat(colorcode, "  (total: ", ftos(fragtotal), ")"), FALSE);
1228 }
1229
1230 void PrintScoreboard()
1231 {
1232         ServerConsoleEcho("Scoreboard:", FALSE);
1233         if(teams_matter)
1234         {
1235                 PrintScoreboardFor("Red", "^1", COLOR_TEAM1);
1236                 PrintScoreboardFor("Blue", "^4", COLOR_TEAM2);
1237                 PrintScoreboardFor("Pink", "^6", COLOR_TEAM3);
1238                 PrintScoreboardFor("Yellow", "^3", COLOR_TEAM4);
1239         }
1240         else
1241         {
1242                 PrintScoreboardFor("", "^7", 0);
1243         }
1244         ServerConsoleEcho(".", FALSE);
1245 }
1246
1247 void RemoveFromMaplist(string m)
1248 {
1249         string result;
1250         float litems;
1251         float i;
1252         float found;
1253
1254         litems = tokenize(cvar_string("g_maplist"));
1255         found = 0;
1256         result = "";
1257         for(i = 0; i < litems; ++i)
1258         {
1259                 m = strcat(m);
1260                 result = strcat(result);
1261                 if(argv(i) == m)
1262                         found += 1;
1263                 else
1264                         result = strcat(result, "'", argv(i), "'");
1265         }
1266         if(found)
1267         {
1268                 cvar_set("g_maplist", result);
1269                 localcmd("set _g_maplist_have_shuffled 0\n");
1270         }
1271         ServerConsoleEcho(strcat("Removed ", ftos(found), " items."), FALSE);
1272 }
1273
1274 void AddToMaplist(string m)
1275 {
1276         float found;
1277         float litems;
1278         float i;
1279
1280         if(!TryFile(strcat("maps/", m, ".mapcfg")))
1281         {
1282                 ServerConsoleEcho("Map not found.", FALSE);
1283                 return;
1284         }
1285
1286         litems = tokenize(cvar_string("g_maplist"));
1287         found = 0;
1288         for(i = 0; i < litems; ++i)
1289                 if(argv(i) == m)
1290                         found += 1;
1291         if(!found)
1292         {
1293                 cvar_set("g_maplist", strcat(cvar_string("g_maplist"), "'", m, "'"));
1294                 localcmd("set _g_maplist_have_shuffled 0\n");
1295                 ServerConsoleEcho("Map added.", FALSE);
1296         }
1297         else
1298                 ServerConsoleEcho("Map already in list.", FALSE);
1299 }
1300
1301 void ShuffleMaplist()
1302 {
1303         string result;
1304         float start;
1305         float litems;
1306         float selected;
1307         float i;
1308
1309         result = cvar_string("g_maplist");
1310         litems = tokenize(result);
1311
1312         for(start = 0; start < litems - 1; ++start)
1313         {
1314                 result = "";
1315
1316                 // select a random item
1317                 selected = ceil(random() * (litems - start) + start) - 1;
1318
1319                 // shift this item to the place start
1320                 for(i = 0; i < start; ++i)
1321                         result = strcat(result, "'", argv(i), "'");
1322                 result = strcat(result, "'", argv(selected), "'");
1323                 for(i = start; i < litems; ++i)
1324                         if(i != selected)
1325                                 result = strcat(result, "'", argv(i), "'");
1326
1327                 litems = tokenize(result);
1328
1329                 //dprint(result, "\n");
1330         }
1331
1332         cvar_set("g_maplist", result);
1333 }
1334
1335 /*
1336 ============
1337 CheckRules_World
1338
1339 Exit deathmatch games upon conditions
1340 ============
1341 */
1342 void() CheckRules_World =
1343 {
1344         local float status;
1345         local float timelimit;
1346         local float fraglimit;
1347
1348         VoteThink();
1349
1350         SetDefaultAlpha();
1351
1352         if (intermission_running)
1353                 if (time >= intermission_exittime + 60)
1354                 {
1355                         GotoNextMap();
1356                         return;
1357                 }
1358
1359         if (gameover)   // someone else quit the game already
1360                 return;
1361
1362         DumpStats();
1363
1364         if(cvar("_scoreboard"))
1365         {
1366                 cvar_set("_scoreboard", "0");
1367                 PrintScoreboard();
1368         }
1369
1370         // automatically shuffle when setting g_maplist_shuffle
1371         if(cvar_string("_g_maplist_add") != "")
1372         {
1373                 AddToMaplist(cvar_string("_g_maplist_add"));
1374                 cvar_set("_g_maplist_add", "");
1375         }
1376         if(cvar_string("_g_maplist_remove") != "")
1377         {
1378                 RemoveFromMaplist(cvar_string("_g_maplist_remove"));
1379                 cvar_set("_g_maplist_remove", "");
1380         }
1381         if(cvar("_g_maplist_shufflenow") || (cvar("g_maplist_shuffle") && !cvar("_g_maplist_have_shuffled")))
1382         {
1383                 ShuffleMaplist();
1384                 localcmd("set _g_maplist_shufflenow 0\nset _g_maplist_have_shuffled 1\necho Shuffled map list.\n");
1385         }
1386         if(cvar("_g_maplist_have_shuffled"))
1387                 if(!cvar("g_maplist_shuffle"))
1388                         localcmd("set _g_maplist_have_shuffled 0\n");
1389
1390         timelimit = cvar("timelimit") * 60;
1391         fraglimit = cvar("fraglimit");
1392
1393         if (timelimit && time >= timelimit)
1394                 InitiateOvertime();
1395
1396         if (checkrules_overtimeend && time >= checkrules_overtimeend)
1397         {
1398                 NextLevel();
1399                 return;
1400         }
1401
1402         if(!checkrules_overtimewarning && checkrules_overtimeend)
1403         {
1404                 checkrules_overtimewarning = TRUE;
1405                 //sound(world, CHAN_AUTO, "announcer/robotic/1minuteremains.ogg", 1, ATTN_NONE);
1406                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
1407         }
1408
1409         if (!checkrules_oneminutewarning && timelimit > 0 && time > timelimit - 60)
1410         {
1411                 checkrules_oneminutewarning = TRUE;
1412                 sound(world, CHAN_AUTO, "announcer/robotic/1minuteremains.ogg", 1, ATTN_NONE);
1413         }
1414
1415         status = WINNING_NO;
1416         if(cvar("g_lms"))
1417         {
1418                 status = WinningCondition_LMS();
1419         }
1420         else
1421         {
1422                 if(teams_matter)
1423                 {
1424                         if(cvar("g_tdm") || cvar("g_runematch") || cvar("g_ctf") || cvar("g_domination"))
1425                                 status = WinningCondition_MaxTeamSum(fraglimit);
1426                         //else if()
1427                         //      status = WinningCondition_MaxTeamMax(fraglimit);
1428                         else
1429                         {
1430                                 dprint("div0: How can this happen?\n");
1431                                 status = WinningCondition_MaxTeamMax(fraglimit);
1432                         }
1433                 }
1434                 else
1435                         status = WinningCondition_MaxIndividualScore(fraglimit);
1436         }
1437
1438         if(status == WINNING_STARTOVERTIME)
1439         {
1440                 status = WINNING_NEVER;
1441                 InitiateOvertime();
1442         }
1443
1444         if(status == WINNING_NEVER)
1445                 // equality cases! Nobody wins if the overtime ends in a draw.
1446                 ClearWinners();
1447
1448         if(checkrules_overtimeend)
1449                 if(status != WINNING_NEVER)
1450                         status = WINNING_YES;
1451
1452         if(status == WINNING_YES)
1453                 NextLevel();
1454 };