data/qcsrc/server/g_triggers.qc

   1
   2 void() SUB_UseTargets;
   3
   4 void DelayThink()
   5 {
   6         activator = self.enemy;
   7         SUB_UseTargets ();
   8         remove(self);
   9 };
  10
  11 /*
  12 ==============================
  13 SUB_UseTargets
  14
  15 the global "activator" should be set to the entity that initiated the firing.
  16
  17 If self.delay is set, a DelayedUse entity will be created that will actually
  18 do the SUB_UseTargets after that many seconds have passed.
  19
  20 Centerprints any self.message to the activator.
  21
  22 Removes all entities with a targetname that match self.killtarget,
  23 and removes them, so some events can remove other triggers.
  24
  25 Search for (string)targetname in all entities that
  26 match (string)self.target and call their .use function
  27
  28 ==============================
  29 */
  30 void SUB_UseTargets()
  31 {
  32         local entity t, stemp, otemp, act;
  33
  34 //
  35 // check for a delay
  36 //
  37         if (self.delay)
  38         {
  39         // create a temp object to fire at a later time
  40                 t = spawn();
  41                 t.classname = "DelayedUse";
  42                 t.nextthink = time + self.delay;
  43                 t.think = DelayThink;
  44                 t.enemy = activator;
  45                 t.message = self.message;
  46                 t.killtarget = self.killtarget;
  47                 t.target = self.target;
  48                 return;
  49         }
  50
  51
  52 //
  53 // print the message
  54 //
  55         if (activator.classname == "player" && self.message != "")
  56         {
  57                 centerprint (activator, self.message);
  58                 if (!self.noise)
  59                         play2(activator, "misc/talk.wav");
  60         }
  61
  62 //
  63 // kill the killtagets
  64 //
  65         if (self.killtarget)
  66         {
  67                 t = world;
  68                 do
  69                 {
  70                         t = find (t, targetname, self.killtarget);
  71                         if (!t)
  72                                 return;
  73                         remove (t);
  74                 } while ( 1 );
  75         }
  76
  77 //
  78 // fire targets
  79 //
  80         if (self.target)
  81         {
  82                 act = activator;
  83                 t = world;
  84                 do
  85                 {
  86                         t = find (t, targetname, self.target);
  87                         if (!t)
  88                         {
  89                                 return;
  90                         }
  91                         stemp = self;
  92                         otemp = other;
  93                         self = t;
  94                         other = stemp;
  95                         if (self.use)
  96                                 self.use ();
  97                         self = stemp;
  98                         other = otemp;
  99                         activator = act;
 100                 } while ( 1 );
 101         }
 102
 103
 104 };
 105
 106
 107 //=============================================================================
 108
 109 float   SPAWNFLAG_NOMESSAGE = 1;
 110 float   SPAWNFLAG_NOTOUCH = 1;
 111
 112 // the wait time has passed, so set back up for another activation
 113 void multi_wait()
 114 {
 115         if (self.max_health)
 116         {
 117                 self.health = self.max_health;
 118                 self.takedamage = DAMAGE_YES;
 119                 self.solid = SOLID_BBOX;
 120         }
 121 };
 122
 123
 124 // the trigger was just touched/killed/used
 125 // self.enemy should be set to the activator so it can be held through a delay
 126 // so wait for the delay time before firing
 127 void multi_trigger()
 128 {
 129         if (self.nextthink > time)
 130         {
 131                 return;         // allready been triggered
 132         }
 133
 134         if (self.classname == "trigger_secret")
 135         {
 136                 if (self.enemy.classname != "player")
 137                         return;
 138                 found_secrets = found_secrets + 1;
 139                 WriteByte (MSG_ALL, SVC_FOUNDSECRET);
 140         }
 141
 142         if (self.noise)
 143                 sound (self.enemy, CHAN_AUTO, self.noise, VOL_BASE, ATTN_NORM);
 144
 145 // don't trigger again until reset
 146         self.takedamage = DAMAGE_NO;
 147
 148         activator = self.enemy;
 149
 150         SUB_UseTargets();
 151
 152         if (self.wait > 0)
 153         {
 154                 self.think = multi_wait;
 155                 self.nextthink = time + self.wait;
 156         }
 157         else
 158         {       // we can't just remove (self) here, because this is a touch function
 159                 // called wheil C code is looping through area links...
 160                 self.touch = SUB_Null;
 161
 162                 self.nextthink = time + 0.1;
 163                 self.think = SUB_Remove;
 164         }
 165 };
 166
 167 void multi_use()
 168 {
 169         self.enemy = activator;
 170         multi_trigger();
 171 };
 172
 173 void multi_touch()
 174 {
 175         if (other.classname != "player")
 176                 return;
 177
 178     if(self.team)
 179     if(self.team == other.team)
 180         return;
 181
 182 // if the trigger has an angles field, check player's facing direction
 183         if (self.movedir != '0 0 0')
 184         {
 185                 makevectors (other.angles);
 186                 if (v_forward * self.movedir < 0)
 187                         return;         // not facing the right way
 188         }
 189
 190         EXACTTRIGGER_TOUCH;
 191
 192         self.enemy = other;
 193         multi_trigger ();
 194 };
 195
 196 void multi_eventdamage (vector hitloc, float damage, entity inflictor, entity attacker, float deathtype)
 197 {
 198         if (!self.takedamage)
 199                 return;
 200         self.health = self.health - damage;
 201         if (self.health <= 0)
 202         {
 203                 self.enemy = attacker;
 204                 multi_trigger();
 205         }
 206 }
 207
 208 /*QUAKED spawnfunc_trigger_multiple (.5 .5 .5) ? notouch
 209 Variable sized repeatable trigger.  Must be targeted at one or more entities.  If "health" is set, the trigger must be killed to activate each time.
 210 If "delay" is set, the trigger waits some time after activating before firing.
 211 "wait" : Seconds between triggerings. (.2 default)
 212 If notouch is set, the trigger is only fired by other entities, not by touching.
 213 NOTOUCH has been obsoleted by spawnfunc_trigger_relay!
 214 sounds
 215 1)      secret
 216 2)      beep beep
 217 3)      large switch
 218 4)
 219 set "message" to text string
 220 */
 221 void spawnfunc_trigger_multiple()
 222 {
 223         if (self.sounds == 1)
 224         {
 225                 precache_sound ("misc/secret.wav");
 226                 self.noise = "misc/secret.wav";
 227         }
 228         else if (self.sounds == 2)
 229         {
 230                 precache_sound ("misc/talk.wav");
 231                 self.noise = "misc/talk.wav";
 232         }
 233         else if (self.sounds == 3)
 234         {
 235                 precache_sound ("misc/trigger1.wav");
 236                 self.noise = "misc/trigger1.wav";
 237         }
 238
 239         if (!self.wait)
 240                 self.wait = 0.2;
 241         self.use = multi_use;
 242
 243         EXACTTRIGGER_INIT;
 244
 245         if (self.health)
 246         {
 247                 if (self.spawnflags & SPAWNFLAG_NOTOUCH)
 248                         objerror ("health and notouch don't make sense\n");
 249                 self.max_health = self.health;
 250                 self.event_damage = multi_eventdamage;
 251                 self.takedamage = DAMAGE_YES;
 252                 self.solid = SOLID_BBOX;
 253                 setorigin (self, self.origin);  // make sure it links into the world
 254         }
 255         else
 256         {
 257                 if ( !(self.spawnflags & SPAWNFLAG_NOTOUCH) )
 258                 {
 259                         self.touch = multi_touch;
 260                 }
 261         }
 262 };
 263
 264
 265 /*QUAKED spawnfunc_trigger_once (.5 .5 .5) ? notouch
 266 Variable sized trigger. Triggers once, then removes itself.  You must set the key "target" to the name of another object in the level that has a matching
 267 "targetname".  If "health" is set, the trigger must be killed to activate.
 268 If notouch is set, the trigger is only fired by other entities, not by touching.
 269 if "killtarget" is set, any objects that have a matching "target" will be removed when the trigger is fired.
 270 if "angle" is set, the trigger will only fire when someone is facing the direction of the angle.  Use "360" for an angle of 0.
 271 sounds
 272 1)      secret
 273 2)      beep beep
 274 3)      large switch
 275 4)
 276 set "message" to text string
 277 */
 278 void spawnfunc_trigger_once()
 279 {
 280         self.wait = -1;
 281         spawnfunc_trigger_multiple();
 282 };
 283
 284 //=============================================================================
 285
 286 /*QUAKED spawnfunc_trigger_relay (.5 .5 .5) (-8 -8 -8) (8 8 8)
 287 This fixed size trigger cannot be touched, it can only be fired by other events.  It can contain killtargets, targets, delays, and messages.
 288 */
 289 void spawnfunc_trigger_relay()
 290 {
 291         self.use = SUB_UseTargets;
 292 };
 293
 294 void delay_use()
 295 {
 296     self.think = SUB_UseTargets;
 297     self.nextthink = self.wait;
 298 }
 299
 300 void spawnfunc_trigger_delay()
 301 {
 302     if(!self.wait)
 303         self.wait = 1;
 304
 305     self.use = delay_use;
 306 }
 307
 308 //=============================================================================
 309
 310
 311 void counter_use()
 312 {
 313         self.count = self.count - 1;
 314         if (self.count < 0)
 315                 return;
 316
 317         if (self.count != 0)
 318         {
 319                 if (activator.classname == "player"
 320                 && (self.spawnflags & SPAWNFLAG_NOMESSAGE) == 0)
 321                 {
 322                         if (self.count >= 4)
 323                                 centerprint (activator, "There are more to go...");
 324                         else if (self.count == 3)
 325                                 centerprint (activator, "Only 3 more to go...");
 326                         else if (self.count == 2)
 327                                 centerprint (activator, "Only 2 more to go...");
 328                         else
 329                                 centerprint (activator, "Only 1 more to go...");
 330                 }
 331                 return;
 332         }
 333
 334         if (activator.classname == "player"
 335         && (self.spawnflags & SPAWNFLAG_NOMESSAGE) == 0)
 336                 centerprint(activator, "Sequence completed!");
 337         self.enemy = activator;
 338         multi_trigger ();
 339 };
 340
 341 /*QUAKED spawnfunc_trigger_counter (.5 .5 .5) ? nomessage
 342 Acts as an intermediary for an action that takes multiple inputs.
 343
 344 If nomessage is not set, t will print "1 more.. " etc when triggered and "sequence complete" when finished.
 345
 346 After the counter has been triggered "count" times (default 2), it will fire all of it's targets and remove itself.
 347 */
 348 void spawnfunc_trigger_counter()
 349 {
 350         self.wait = -1;
 351         if (!self.count)
 352                 self.count = 2;
 353
 354         self.use = counter_use;
 355 };
 356
 357 .float triggerhurttime;
 358 void trigger_hurt_touch()
 359 {
 360         // only do the EXACTTRIGGER_TOUCH checks when really needed (saves some cpu)
 361         if (!other.owner)
 362         {
 363                 if (other.items & IT_KEY1 || other.items & IT_KEY2)     // reset flag
 364                 {
 365                         EXACTTRIGGER_TOUCH;
 366                         other.pain_finished = min(other.pain_finished, time + 2);
 367                 }
 368                 else if (other.classname == "rune")                     // reset runes
 369                 {
 370                         EXACTTRIGGER_TOUCH;
 371                         other.nextthink = min(other.nextthink, time + 1);
 372                 }
 373         }
 374
 375         if (other.takedamage)
 376         if (other.triggerhurttime < time)
 377         {
 378                 EXACTTRIGGER_TOUCH;
 379                 other.triggerhurttime = time + 1;
 380                 Damage (other, self, self, self.dmg, DEATH_HURTTRIGGER, other.origin, '0 0 0');
 381         }
 382
 383         return;
 384 };
 385
 386 /*QUAKED spawnfunc_trigger_hurt (.5 .5 .5) ?
 387 Any object touching this will be hurt
 388 set dmg to damage amount
 389 defalt dmg = 5
 390 */
 391 .entity trigger_hurt_next;
 392 entity trigger_hurt_last;
 393 entity trigger_hurt_first;
 394 void spawnfunc_trigger_hurt()
 395 {
 396         EXACTTRIGGER_INIT;
 397         self.touch = trigger_hurt_touch;
 398         if (!self.dmg)
 399                 self.dmg = 1000;
 400         if (!self.message)
 401                 self.message = "was in the wrong place.";
 402
 403         if(!trigger_hurt_first)
 404                 trigger_hurt_first = self;
 405         if(trigger_hurt_last)
 406                 trigger_hurt_last.trigger_hurt_next = self;
 407         trigger_hurt_last = self;
 408 };
 409
 410 float trace_hits_box_a0, trace_hits_box_a1;
 411
 412 float trace_hits_box_1d(float end, float thmi, float thma)
 413 {
 414         if(end == 0)
 415         {
 416                 // just check if x is in range
 417                 if(0 < thmi)
 418                         return FALSE;
 419                 if(0 > thma)
 420                         return FALSE;
 421         }
 422         else
 423         {
 424                 // do the trace with respect to x
 425                 // 0 -> end has to stay in thmi -> thma
 426                 trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
 427                 trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
 428                 if(trace_hits_box_a0 > trace_hits_box_a1)
 429                         return FALSE;
 430         }
 431         return TRUE;
 432 }
 433
 434 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
 435 {
 436         end -= start;
 437         thmi -= start;
 438         thma -= start;
 439         // now it is a trace from 0 to end
 440
 441         trace_hits_box_a0 = 0;
 442         trace_hits_box_a1 = 1;
 443
 444         if(!trace_hits_box_1d(end_x, thmi_x, thma_x))
 445                 return FALSE;
 446         if(!trace_hits_box_1d(end_y, thmi_y, thma_y))
 447                 return FALSE;
 448         if(!trace_hits_box_1d(end_z, thmi_z, thma_z))
 449                 return FALSE;
 450
 451         return TRUE;
 452 }
 453
 454 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
 455 {
 456         return trace_hits_box(start, end, thmi - ma, thma - mi);
 457 }
 458
 459 float tracebox_hits_trigger_hurt(vector start, vector mi, vector ma, vector end)
 460 {
 461         entity th;
 462
 463         for(th = trigger_hurt_first; th; th = th.trigger_hurt_next)
 464                 if(tracebox_hits_box(start, mi, ma, end, th.absmin, th.absmax))
 465                         return TRUE;
 466
 467         return FALSE;
 468 }
 469
 470
 471 void target_speaker_use() {sound(self, CHAN_TRIGGER, self.noise, VOL_BASE, ATTN_NORM);}
 472
 473 void spawnfunc_target_speaker()
 474 {
 475         if(self.noise)
 476                 precache_sound (self.noise);
 477         if(self.targetname)
 478                 self.use = target_speaker_use;
 479         else
 480                 ambientsound (self.origin, self.noise, VOL_BASE, ATTN_STATIC);
 481 };
 482
 483
 484 void spawnfunc_func_stardust() {
 485         self.effects = EF_STARDUST;
 486 }
 487
 488 float pointparticles_SendEntity(entity to, float fl)
 489 {
 490         WriteByte(MSG_ENTITY, ENT_CLIENT_POINTPARTICLES);
 491         WriteByte(MSG_ENTITY, fl);
 492         if(fl & 2)
 493         {
 494                 if(self.state)
 495                         WriteCoord(MSG_ENTITY, self.impulse);
 496                 else
 497                         WriteCoord(MSG_ENTITY, 0); // off
 498         }
 499         if(fl & 1)
 500         {
 501                 if(self.modelindex != 4.2)
 502                         WriteShort(MSG_ENTITY, self.modelindex);
 503                 else
 504                         WriteShort(MSG_ENTITY, 0);
 505                 WriteCoord(MSG_ENTITY, self.origin_x + self.mins_x);
 506                 WriteCoord(MSG_ENTITY, self.origin_y + self.mins_y);
 507                 WriteCoord(MSG_ENTITY, self.origin_z + self.mins_z);
 508                 WriteCoord(MSG_ENTITY, self.maxs_x - self.mins_x);
 509                 WriteCoord(MSG_ENTITY, self.maxs_y - self.mins_y);
 510                 WriteCoord(MSG_ENTITY, self.maxs_z - self.mins_z);
 511                 WriteShort(MSG_ENTITY, self.cnt);
 512                 WriteShort(MSG_ENTITY, compressShortVector(self.velocity));
 513                 WriteShort(MSG_ENTITY, compressShortVector(self.movedir));
 514                 WriteCoord(MSG_ENTITY, self.waterlevel);
 515                 WriteCoord(MSG_ENTITY, self.count);
 516                 WriteByte(MSG_ENTITY, self.glow_color);
 517                 WriteString(MSG_ENTITY, self.noise);
 518         }
 519         return 1;
 520 }
 521
 522 void pointparticles_use()
 523 {
 524         if(self.wait && time < self.nextthink)
 525         {
 526                 self.nextthink = time + self.wait; // extend the time
 527                 return;
 528         }
 529
 530         if(self.wait)
 531                 self.nextthink = time + self.wait; // toggle back after a delay
 532         self.state = !self.state;
 533         self.SendFlags |= 2;
 534 }
 535
 536 void pointparticles_think()
 537 {
 538         self.state = !self.state;
 539         self.SendFlags |= 2;
 540 }
 541
 542 void spawnfunc_func_pointparticles()
 543 {
 544         if(self.model != "")
 545                 setmodel(self, self.model);
 546         if(self.noise != "")
 547                 precache_sound (self.noise);
 548
 549         self.effects = EF_NODEPTHTEST;
 550         self.SendEntity = pointparticles_SendEntity;
 551         self.SendFlags = 3;
 552         if(!self.modelindex)
 553                 self.modelindex = 4.2;
 554         self.model = "net_entity";
 555         if(!self.cnt)
 556                 self.cnt = particleeffectnum(self.mdl);
 557         if(self.targetname != "")
 558         {
 559                 self.use = pointparticles_use;
 560                 if(self.spawnflags & 1)
 561                         self.state = 1;
 562                 else
 563                         self.state = 0;
 564                 self.think = pointparticles_think;
 565         }
 566         else
 567                 self.state = 1;
 568 }
 569
 570 void spawnfunc_func_sparks()
 571 {
 572         // self.cnt is the amount of sparks that one burst will spawn
 573         if(self.cnt < 1) {
 574                 self.cnt = 25.0; // nice default value
 575         }
 576
 577         // self.wait is the probability that a sparkthink will spawn a spark shower
 578         // range: 0 - 1, but 0 makes little sense, so...
 579         if(self.wait < 0.05) {
 580                 self.wait = 0.25; // nice default value
 581         }
 582
 583         self.count = self.cnt;
 584         self.mins = '0 0 0';
 585         self.maxs = '0 0 0';
 586         self.velocity = '0 0 -1';
 587         self.mdl = "func_sparks";
 588         self.impulse = 0.1 / self.wait;
 589         self.wait = 0;
 590
 591         spawnfunc_func_pointparticles();
 592 }
 593
 594 float rainsnow_SendEntity(float to)
 595 {
 596         WriteByte(MSG_ENTITY, ENT_CLIENT_RAINSNOW);
 597         WriteByte(MSG_ENTITY, self.state);
 598         WriteCoord(MSG_ENTITY, self.origin_x + self.mins_x);
 599         WriteCoord(MSG_ENTITY, self.origin_y + self.mins_y);
 600         WriteCoord(MSG_ENTITY, self.origin_z + self.mins_z);
 601         WriteCoord(MSG_ENTITY, self.maxs_x - self.mins_x);
 602         WriteCoord(MSG_ENTITY, self.maxs_y - self.mins_y);
 603         WriteCoord(MSG_ENTITY, self.maxs_z - self.mins_z);
 604         WriteShort(MSG_ENTITY, compressShortVector(self.dest));
 605         WriteShort(MSG_ENTITY, self.count);
 606         WriteByte(MSG_ENTITY, self.cnt);
 607         return 1;
 608 };
 609
 610 /*QUAKED spawnfunc_func_rain (0 .5 .8) ?
 611 This is an invisible area like a trigger, which rain falls inside of.
 612
 613 Keys:
 614 "velocity"
 615  falling direction (should be something like '0 0 -700', use the X and Y velocity for wind)
 616 "cnt"
 617  sets color of rain (default 12 - white)
 618 "count"
 619  adjusts density, this many particles fall every second for a 1024x1024 area, default is 2000
 620 */
 621 void spawnfunc_func_rain()
 622 {
 623         self.dest = self.velocity;
 624         self.velocity = '0 0 0';
 625         if (!self.dest)
 626                 self.dest = '0 0 -700';
 627         self.angles = '0 0 0';
 628         self.movetype = MOVETYPE_NONE;
 629         self.solid = SOLID_NOT;
 630         SetBrushEntityModel();
 631         self.model = "";
 632         if (!self.cnt)
 633                 self.cnt = 12;
 634         if (!self.count)
 635                 self.count = 2000;
 636         self.count = 0.1 * self.count * (self.size_x / 1024) * (self.size_y / 1024);
 637         if (self.count < 1)
 638         {
 639                 remove(self);
 640                 return;
 641         }
 642         if(self.count > 65535)
 643                 self.count = 65535;
 644
 645         self.state = 1; // 1 is rain, 0 is snow
 646         self.effects = EF_NODEPTHTEST;
 647         self.SendEntity = rainsnow_SendEntity;
 648         self.Version = 1;
 649         self.modelindex = 1;
 650         self.model = "net_entity";
 651 };
 652
 653
 654 /*QUAKED spawnfunc_func_snow (0 .5 .8) ?
 655 This is an invisible area like a trigger, which snow falls inside of.
 656
 657 Keys:
 658 "velocity"
 659  falling direction (should be something like '0 0 -300', use the X and Y velocity for wind)
 660 "cnt"
 661  sets color of rain (default 12 - white)
 662 "count"
 663  adjusts density, this many particles fall every second for a 1024x1024 area, default is 2000
 664 */
 665 void spawnfunc_func_snow()
 666 {
 667         self.dest = self.velocity;
 668         self.velocity = '0 0 0';
 669         if (!self.dest)
 670                 self.dest = '0 0 -300';
 671         self.angles = '0 0 0';
 672         self.movetype = MOVETYPE_NONE;
 673         self.solid = SOLID_NOT;
 674         SetBrushEntityModel();
 675         self.model = "";
 676         if (!self.cnt)
 677                 self.cnt = 12;
 678         if (!self.count)
 679                 self.count = 2000;
 680         self.count = 0.01 * self.count * (self.size_x / 1024) * (self.size_y / 1024);
 681         if (self.count < 1)
 682         {
 683                 remove(self);
 684                 return;
 685         }
 686         if(self.count > 65535)
 687                 self.count = 65535;
 688
 689         self.state = 0; // 1 is rain, 0 is snow
 690         self.effects = EF_NODEPTHTEST;
 691         self.SendEntity = rainsnow_SendEntity;
 692         self.Version = 1;
 693         self.modelindex = 1;
 694         self.model = "net_entity";
 695 };
 696
 697
 698 void FireRailgunBullet (vector start, vector end, float bdamage, float bforce, float deathtype);
 699 void misc_laser_think()
 700 {
 701         vector o, a;
 702         if(!self.state)
 703         {
 704                 self.enemy = find(world, targetname, self.target);
 705                 self.state = 1;
 706         }
 707         if(self.enemy)
 708         {
 709                 o = self.enemy.origin;
 710                 a = vectoangles(o - self.origin);
 711                 if(a != self.angles)
 712                 {
 713                         self.angles = a;
 714                         self.Version += 1;
 715                 }
 716         }
 717         else
 718         {
 719                 makevectors(self.angles);
 720                 o = self.origin + v_forward * MAX_SHOT_DISTANCE;
 721         }
 722
 723         if(self.dmg)
 724         {
 725                 if(self.dmg < 0)
 726                         FireRailgunBullet(self.origin, o, 100000, 0, DEATH_HURTTRIGGER);
 727                 else
 728                         FireRailgunBullet(self.origin, o, self.dmg * frametime, 0, DEATH_HURTTRIGGER);
 729         }
 730 }
 731 float laser_SendEntity(entity to, float fl)
 732 {
 733         WriteByte(MSG_ENTITY, ENT_CLIENT_LASER);
 734         WriteByte(MSG_ENTITY, fl);
 735         if(fl & 1)
 736         {
 737                 WriteCoord(MSG_ENTITY, self.origin_x);
 738                 WriteCoord(MSG_ENTITY, self.origin_y);
 739                 WriteCoord(MSG_ENTITY, self.origin_z);
 740                 WriteByte(MSG_ENTITY, self.colormod_x * 255.0);
 741                 WriteByte(MSG_ENTITY, self.colormod_y * 255.0);
 742                 WriteByte(MSG_ENTITY, self.colormod_z * 255.0);
 743                 WriteShort(MSG_ENTITY, self.cnt);
 744         }
 745         if(fl & 2)
 746         {
 747                 WriteCoord(MSG_ENTITY, self.velocity_x);
 748                 WriteCoord(MSG_ENTITY, self.velocity_y);
 749                 WriteCoord(MSG_ENTITY, self.velocity_z);
 750         }
 751         return 1;
 752 }
 753
 754 /*QUAKED spawnfunc_misc_laser (.5 .5 .5) ?
 755 Any object touching the beam will be hurt
 756 Keys:
 757 "target"
 758  spawnfunc_target_position where the laser ends
 759 "mdl"
 760  name of beam end effect to use
 761 "colormod"
 762  color of the beam (default: red)
 763 "dmg"
 764  damage per second (-1 for a laser that kills immediately)
 765 */
 766 void spawnfunc_misc_laser()
 767 {
 768         if(self.mdl)
 769         {
 770                 self.cnt = particleeffectnum(strcat(self.mdl, "_end"));
 771                 if(self.cnt < 0)
 772                         self.cnt = particleeffectnum(self.mdl);
 773         }
 774         else
 775         {
 776                 self.cnt = particleeffectnum("misc_laser_beam_end");
 777         }
 778         if(self.colormod == '0 0 0')
 779                 self.colormod = '1 0 0';
 780         if(!self.message)
 781                 self.message = "saw the light";
 782         self.think = misc_laser_think;
 783         self.nextthink = time;
 784
 785         self.effects = EF_NODEPTHTEST;
 786         self.SendEntity = laser_SendEntity;
 787         self.SendFlags = 3;
 788         self.modelindex = 1;
 789         self.model = "net_entity";
 790 }
 791
 792 // tZorks trigger impulse / gravity
 793 .float radius;
 794 .float falloff;
 795 .float strength;
 796 .float lastpushtime;
 797
 798 // targeted (directional) mode
 799 void trigger_impulse_touch1()
 800 {
 801         entity targ;
 802     float pushdeltatime;
 803     float str;
 804
 805         // FIXME: Better checking for what to push and not.
 806         if (other.classname != "player")
 807         if (other.classname != "corpse")
 808         if (other.classname != "body")
 809         if (other.classname != "gib")
 810         if (other.classname != "missile")
 811         if (other.classname != "casing")
 812         if (other.classname != "grenade")
 813         if (other.classname != "plasma")
 814         if (other.classname != "plasma_prim")
 815         if (other.classname != "plasma_chain")
 816         if (other.classname != "droppedweapon")
 817                 return;
 818
 819         if (other.deadflag && other.classname == "player")
 820                 return;
 821
 822         EXACTTRIGGER_TOUCH;
 823
 824     targ = find(world, targetname, self.target);
 825     if(!targ)
 826     {
 827         objerror("trigger_force without a (valid) .target!\n");
 828         remove(self);
 829         return;
 830     }
 831
 832     if(self.falloff == 1)
 833         str = (str / self.radius) * self.strength;
 834     else if(self.falloff == 2)
 835         str = (1 - (str / self.radius)) * self.strength;
 836     else
 837         str = self.strength;
 838
 839     pushdeltatime = time - other.lastpushtime;
 840     if (pushdeltatime > 0.15) pushdeltatime = 0;
 841     other.lastpushtime = time;
 842     if(!pushdeltatime) return;
 843
 844     other.velocity = other.velocity + normalize(targ.origin - self.origin) * self.strength * pushdeltatime;
 845 }
 846
 847 // Directionless (accelerator/decelerator) mode
 848 void trigger_impulse_touch2()
 849 {
 850     float pushdeltatime;
 851
 852         // FIXME: Better checking for what to push and not.
 853         if (other.classname != "player")
 854         if (other.classname != "corpse")
 855         if (other.classname != "body")
 856         if (other.classname != "gib")
 857         if (other.classname != "missile")
 858         if (other.classname != "casing")
 859         if (other.classname != "grenade")
 860         if (other.classname != "plasma")
 861         if (other.classname != "plasma_prim")
 862         if (other.classname != "plasma_chain")
 863         if (other.classname != "droppedweapon")
 864                 return;
 865
 866         if (other.deadflag && other.classname == "player")
 867                 return;
 868
 869         EXACTTRIGGER_TOUCH;
 870
 871     pushdeltatime = time - other.lastpushtime;
 872     if (pushdeltatime > 0.15) pushdeltatime = 0;
 873     other.lastpushtime = time;
 874     if(!pushdeltatime) return;
 875
 876     //if(self.strength > 1)
 877         other.velocity = other.velocity * (self.strength * pushdeltatime);
 878     //else
 879     //    other.velocity = other.velocity - (other.velocity * self.strength * pushdeltatime);
 880 }
 881
 882 // Spherical (gravity/repulsor) mode
 883 void trigger_impulse_touch3()
 884 {
 885     float pushdeltatime;
 886     float str;
 887
 888         // FIXME: Better checking for what to push and not.
 889         if (other.classname != "player")
 890         if (other.classname != "corpse")
 891         if (other.classname != "body")
 892         if (other.classname != "gib")
 893         if (other.classname != "missile")
 894         if (other.classname != "casing")
 895         if (other.classname != "grenade")
 896         if (other.classname != "plasma")
 897         if (other.classname != "plasma_prim")
 898         if (other.classname != "plasma_chain")
 899         if (other.classname != "droppedweapon")
 900                 return;
 901
 902         if (other.deadflag && other.classname == "player")
 903                 return;
 904
 905         EXACTTRIGGER_TOUCH;
 906
 907     pushdeltatime = time - other.lastpushtime;
 908     if (pushdeltatime > 0.15) pushdeltatime = 0;
 909     other.lastpushtime = time;
 910     if(!pushdeltatime) return;
 911
 912     setsize(self, '-1 -1 -1' * self.radius,'1 1 1' * self.radius);
 913
 914         str = min(self.radius, vlen(self.origin - other.origin));
 915
 916     if(self.falloff == 1)
 917         str = (1 - str / self.radius) * self.strength; // 1 in the inside
 918     else if(self.falloff == 2)
 919         str = (str / self.radius) * self.strength; // 0 in the inside
 920     else
 921         str = self.strength;
 922
 923     other.velocity = other.velocity + normalize(other.origin - self.origin) * str * pushdeltatime;
 924 }
 925
 926 /*QUAKED spawnfunc_trigger_impulse (.5 .5 .5) ?
 927 -------- KEYS --------
 928 target : If this is set, this points to the spawnfunc_target_position to which the player will get pushed.
 929          If not, this trigger acts like a damper/accelerator field.
 930
 931 strength : This is how mutch force to add in the direction of .target each second
 932            when .target is set. If not, this is hoe mutch to slow down/accelerate
 933            someting cought inside this trigger. (1=no change, 0,5 half speed rougthly each tic, 2 = doubble)
 934
 935 radius   : If set, act as a spherical device rather then a liniar one.
 936
 937 falloff : 0 = none, 1 = liniar, 2 = inverted liniar
 938
 939 -------- NOTES --------
 940 Use a brush textured with common/origin in the trigger entity to determine the origin of the force
 941 in directional and sperical mode. For damper/accelerator mode this is not nessesary (and has no effect).
 942 */
 943
 944 void spawnfunc_trigger_impulse()
 945 {
 946         EXACTTRIGGER_INIT;
 947     if(self.radius)
 948     {
 949         if(!self.strength) self.strength = 2000;
 950         setorigin(self, self.origin);
 951         setsize(self, '-1 -1 -1' * self.radius,'1 1 1' * self.radius);
 952         self.touch = trigger_impulse_touch3;
 953     }
 954     else
 955     {
 956         if(self.target)
 957         {
 958             if(!self.strength) self.strength = 950;
 959             self.touch = trigger_impulse_touch1;
 960         }
 961         else
 962         {
 963             if(!self.strength) self.strength = 0.9;
 964             self.touch = trigger_impulse_touch2;
 965         }
 966     }
 967 }
 968