data/qcsrc/server/func_breakable.qc

   1 .entity sprite;
   2
   3 .float dmg;
   4 .float dmg_edge;
   5 .float dmg_radius;
   6 .float dmg_force;
   7 .float debrismovetype;
   8 .float debrissolid;
   9 .vector debrisvelocity;
  10 .vector debrisvelocityjitter;
  11 .vector debrisavelocityjitter;
  12 .float debristime;
  13 .float debristimejitter;
  14 .float debrisfadetime;
  15 .float debrisdamageforcescale;
  16
  17 .string mdl_dead; // or "" to hide when broken
  18 .string debris; // space separated list of debris models
  19 // other fields:
  20 //   mdl = particle effect name
  21 //   count = particle effect multiplier
  22 //   targetname = target to trigger to unbreak the model
  23 //   target = targets to trigger when broken
  24 //   health = amount of damage it can take
  25 //   spawnflags:
  26 //     1 = start disabled (needs to be triggered to activate)
  27 //     2 = indicate damage
  28 // notes:
  29 //   for mdl_dead to work, origin must be set (using a common/origin brush).
  30 //   Otherwise mdl_dead will be displayed at the map origin, and nobody would
  31 //   want that!
  32
  33 .vector mins_save, maxs_save;
  34
  35 void func_breakable_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force);
  36
  37 //
  38 // func_breakable
  39 // - basically func_assault_destructible for general gameplay use
  40 //
  41 void LaunchDebris (string debrisname, vector force) =
  42 {
  43         local   entity dbr;
  44
  45         dbr = spawn();
  46         setorigin(dbr, self.absmin
  47                    + '1 0 0' * random() * (self.absmax_x - self.absmin_x)
  48                    + '0 1 0' * random() * (self.absmax_y - self.absmin_y)
  49                    + '0 0 1' * random() * (self.absmax_z - self.absmin_z));
  50         setmodel (dbr, debrisname );
  51         dbr.owner = self; // do not be affected by our own explosion
  52         dbr.movetype = self.debrismovetype;
  53         dbr.solid = self.debrissolid;
  54         if(dbr.solid != SOLID_BSP) // SOLID_BSP has exact collision, MAYBE this works? TODO check this out
  55                 setsize(dbr, '0 0 0', '0 0 0'); // needed for performance, until engine can deal better with it
  56         dbr.velocity_x = self.debrisvelocity_x + self.debrisvelocityjitter_x * crandom();
  57         dbr.velocity_y = self.debrisvelocity_y + self.debrisvelocityjitter_y * crandom();
  58         dbr.velocity_z = self.debrisvelocity_z + self.debrisvelocityjitter_z * crandom();
  59         self.velocity = self.velocity + force * self.debrisdamageforcescale;
  60         dbr.avelocity_x = random()*self.debrisavelocityjitter_x;
  61         dbr.avelocity_y = random()*self.debrisavelocityjitter_y;
  62         dbr.avelocity_z = random()*self.debrisavelocityjitter_z;
  63         dbr.damageforcescale = self.debrisdamageforcescale;
  64         if(dbr.damageforcescale)
  65                 dbr.takedamage = DAMAGE_YES;
  66         SUB_SetFade(dbr, time + self.debristime + crandom() * self.debristimejitter, self.debrisfadetime);
  67 };
  68
  69 void func_breakable_colormod()
  70 {
  71         float h;
  72         if not(self.spawnflags & 2)
  73                 return;
  74         h = self.health / self.max_health;
  75         if(h < 0.25)
  76                 self.colormod = '1 0 0';
  77         else if(h <= 0.75)
  78                 self.colormod = '1 0 0' + '0 1 0' * (2 * h - 0.5);
  79         else
  80                 self.colormod = '1 1 1';
  81 }
  82
  83 void func_breakable_look_destroyed()
  84 {
  85         local float floor_z;
  86
  87         if(self.mdl_dead == "")
  88                 self.model = "";
  89         else {
  90                 setmodel(self, self.mdl_dead);
  91                 if (self.origin == '0 0 0')     {       // probably no origin brush, so don't spawn in the middle of the map..
  92                         floor_z = self.absmin_z;
  93                         self.origin = ((self.absmax+self.absmin)*.5);
  94                         self.origin_z = floor_z;
  95                 }
  96         }
  97
  98         self.solid = SOLID_NOT;
  99 }
 100
 101 void func_breakable_look_restore()
 102 {
 103         setmodel(self, self.mdl);
 104         self.solid = SOLID_BSP;
 105 }
 106
 107 void func_breakable_behave_destroyed()
 108 {
 109         self.health = self.max_health;
 110         self.takedamage = DAMAGE_NO;
 111         self.event_damage = SUB_Null;
 112         self.state = 1;
 113         setsize(self, '0 0 0', '0 0 0');
 114         func_breakable_colormod();
 115 }
 116
 117 void func_breakable_behave_restore()
 118 {
 119         self.health = self.max_health;
 120         self.takedamage = DAMAGE_AIM;
 121         self.event_damage = func_breakable_damage;
 122         self.state = 0;
 123         setsize(self, self.mins_save, self.maxs_save);
 124         func_breakable_colormod();
 125 }
 126
 127 void func_breakable_destroyed()
 128 {
 129         func_breakable_look_destroyed();
 130         func_breakable_behave_destroyed();
 131 }
 132
 133 void func_breakable_restore()
 134 {
 135         func_breakable_look_restore();
 136         func_breakable_behave_restore();
 137 }
 138
 139 vector debrisforce; // global, set before calling this
 140 void func_breakable_destroy() {
 141         float n, i;
 142         string oldmsg;
 143
 144         activator = self.owner;
 145
 146         // now throw around the debris
 147         n = tokenize_console(self.debris);
 148         for(i = 0; i < n; ++i)
 149                 LaunchDebris(argv(i), debrisforce);
 150
 151         func_breakable_destroyed();
 152
 153         if(self.noise)
 154                 sound (self, CHAN_AUTO, self.noise, VOL_BASE, ATTN_NORM);
 155
 156         if(self.dmg)
 157                 RadiusDamage(self, activator, self.dmg, self.dmg_edge, self.dmg_radius, self, self.dmg_force, DEATH_HURTTRIGGER, world);
 158
 159         if(self.cnt)
 160                 pointparticles(self.cnt, self.absmin * 0.5 + self.absmax * 0.5, '0 0 0', self.count);
 161
 162         oldmsg = self.message;
 163         self.message = "";
 164         SUB_UseTargets();
 165         self.message = oldmsg;
 166 }
 167
 168 void func_breakable_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 169 {
 170         if(self.state == 1)
 171                 return;
 172         if(self.team)
 173                 if(attacker.team == self.team)
 174                         return;
 175         if(self.sprite)
 176                 WaypointSprite_Ping(self.sprite);
 177         self.health = self.health - damage;
 178         func_breakable_colormod();
 179
 180         if(self.health <= 0)
 181         {
 182                 debrisforce = force;
 183                 W_PrepareExplosionByDamage(attacker, func_breakable_destroy);
 184         }
 185 }
 186
 187 void func_breakable_reset()
 188 {
 189         self.team = self.team_saved;
 190         func_breakable_look_restore();
 191         if(self.spawnflags & 1)
 192                 func_breakable_behave_destroyed();
 193         else
 194                 func_breakable_behave_restore();
 195 }
 196
 197 // destructible walls that can be used to trigger target_objective_decrease
 198 void spawnfunc_func_breakable() {
 199         float n, i;
 200         if(!self.health)
 201                 self.health = 100;
 202         self.max_health = self.health;
 203
 204         // yes, I know, MOVETYPE_NONE is not available here, not that one would want it here anyway
 205         if(!self.debrismovetype) self.debrismovetype = MOVETYPE_BOUNCE;
 206         if(!self.debrissolid) self.debrissolid = SOLID_NOT;
 207         if(self.debrisvelocity == '0 0 0') self.debrisvelocity = '0 0 140';
 208         if(self.debrisvelocityjitter == '0 0 0') self.debrisvelocityjitter = '70 70 70';
 209         if(self.debrisavelocityjitter == '0 0 0') self.debrisavelocityjitter = '600 600 600';
 210         if(!self.debristime) self.debristime = 3.5;
 211         if(!self.debristimejitter) self.debristime = 2.5;
 212
 213         if(self.mdl != "")
 214                 self.cnt = particleeffectnum(self.mdl);
 215         if(self.count == 0)
 216                 self.count = 1;
 217
 218         if(!self.message)
 219                 self.message = "got too close to an explosion";
 220         if(!self.message2)
 221                 self.message2 = "was pushed into an explosion by";
 222         if(!self.dmg_radius)
 223                 self.dmg_radius = 150;
 224         if(!self.dmg_force)
 225                 self.dmg_force = 200;
 226
 227         self.mdl = self.model;
 228         SetBrushEntityModel();
 229         self.mins_save = self.mins;
 230         self.maxs_save = self.maxs;
 231
 232         self.use = func_breakable_restore;
 233
 234         // precache all the models
 235         if (self.mdl_dead)
 236                 precache_model(self.mdl_dead);
 237         n = tokenize_console(self.debris);
 238         for(i = 0; i < n; ++i)
 239                 precache_model(argv(i));
 240         if(self.noise)
 241                 precache_sound(self.noise);
 242
 243         self.team_saved = self.team;
 244
 245         self.reset = func_breakable_reset;
 246         func_breakable_reset();
 247 }