data/qcsrc/server/func_breakable.qc

   1 .entity sprite;
   2
   3 .float dmg;
   4 .float dmg_edge;
   5 .float dmg_radius;
   6 .float dmg_force;
   7
   8 .string mdl_dead; // or "" to hide when broken
   9 .string debris; // space separated list of debris models
  10 // other fields:
  11 //   mdl = particle effect name
  12 //   count = particle effect multiplier
  13 //   targetname = target to trigger to unbreak the model
  14 //   target = targets to trigger when broken
  15 //   health = amount of damage it can take
  16 //   spawnflags:
  17 //     1 = start disabled (needs to be triggered to activate)
  18 //     2 = indicate damage
  19 // notes:
  20 //   for mdl_dead to work, origin must be set (using a common/origin brush).
  21 //   Otherwise mdl_dead will be displayed at the map origin, and nobody would
  22 //   want that!
  23
  24 .vector mins_save, maxs_save;
  25
  26 void func_breakable_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force);
  27
  28 //
  29 // func_breakable
  30 // - basically func_assault_destructible for general gameplay use
  31 //
  32 void LaunchDebris (string debrisname) =
  33 {
  34         local   entity dbr;
  35
  36         dbr = spawn();
  37         dbr.origin = self.origin + self.absmin
  38                    + '1 0 0' * random() * (self.absmax_x - self.absmin_x)
  39                    + '0 1 0' * random() * (self.absmax_y - self.absmin_y)
  40                    + '0 0 1' * random() * (self.absmax_z - self.absmin_z);
  41         setmodel (dbr, debrisname );
  42         dbr.movetype = MOVETYPE_BOUNCE;
  43         dbr.solid = SOLID_NOT;
  44         // TODO parametrize this
  45         dbr.velocity_x = 70 * crandom();
  46         dbr.velocity_y = 70 * crandom();
  47         dbr.velocity_z = 140 + 70 * random();
  48         dbr.avelocity_x = random()*600;
  49         dbr.avelocity_y = random()*600;
  50         dbr.avelocity_z = random()*600;
  51         SUB_SetFade(dbr, time + 1 + random() * 5, 1);
  52 };
  53
  54 void func_breakable_colormod()
  55 {
  56         float h;
  57         if not(self.spawnflags & 2)
  58                 return;
  59         h = self.health / self.max_health;
  60         if(h < 0.25)
  61                 self.colormod = '1 0 0';
  62         else if(h <= 0.75)
  63                 self.colormod = '1 0 0' + '0 1 0' * (2 * h - 0.5);
  64         else
  65                 self.colormod = '1 1 1';
  66 }
  67
  68 void func_breakable_look_destroyed()
  69 {
  70         if(self.mdl_dead == "")
  71                 self.model = "";
  72         else
  73                 setmodel(self, self.mdl_dead);
  74
  75         self.solid = SOLID_NOT;
  76 }
  77
  78 void func_breakable_look_restore()
  79 {
  80         setmodel(self, self.mdl);
  81         self.solid = SOLID_BSP;
  82 }
  83
  84 void func_breakable_behave_destroyed()
  85 {
  86         self.health = self.max_health;
  87         self.takedamage = DAMAGE_NO;
  88         self.event_damage = SUB_Null;
  89         self.state = 1;
  90         setsize(self, '0 0 0', '0 0 0');
  91         func_breakable_colormod();
  92 }
  93
  94 void func_breakable_behave_restore()
  95 {
  96         self.health = self.max_health;
  97         self.takedamage = DAMAGE_AIM;
  98         self.event_damage = func_breakable_damage;
  99         self.state = 0;
 100         setsize(self, self.mins_save, self.maxs_save);
 101         func_breakable_colormod();
 102 }
 103
 104 void func_breakable_destroyed()
 105 {
 106         func_breakable_look_destroyed();
 107         func_breakable_behave_destroyed();
 108 }
 109
 110 void func_breakable_restore()
 111 {
 112         func_breakable_look_restore();
 113         func_breakable_behave_restore();
 114 }
 115
 116 void func_breakable_destroy() {
 117         float n, i;
 118
 119         activator = self.owner;
 120
 121         func_breakable_destroyed();
 122
 123         if(self.noise)
 124                 sound (self, CHAN_AUTO, self.noise, VOL_BASE, ATTN_NORM);
 125
 126         if(self.dmg)
 127                 RadiusDamage(self, activator, self.dmg, self.dmg_edge, self.dmg_radius, self, self.dmg_force, DEATH_HURTTRIGGER, world);
 128
 129         // now throw around the debris
 130         n = tokenize_sane(self.debris);
 131         for(i = 0; i < n; ++i)
 132                 LaunchDebris(argv(i));
 133
 134         if(self.cnt)
 135                 pointparticles(self.cnt, self.absmin * 0.5 + self.absmax * 0.5, '0 0 0', self.count);
 136
 137         SUB_UseTargets();
 138 }
 139
 140 void func_breakable_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 141 {
 142         if(self.state == 1)
 143                 return;
 144         if(self.team)
 145                 if(attacker.team == self.team)
 146                         return;
 147         if(self.sprite)
 148                 WaypointSprite_Ping(self.sprite);
 149         self.health = self.health - damage;
 150         func_breakable_colormod();
 151
 152         if(self.health <= 0)
 153                 W_PrepareExplosionByDamage(attacker, func_breakable_destroy);
 154 }
 155
 156 void func_breakable_reset()
 157 {
 158         self.team = self.team_saved;
 159         func_breakable_look_restore();
 160         if(self.spawnflags & 1)
 161                 func_breakable_behave_destroyed();
 162         else
 163                 func_breakable_behave_restore();
 164 }
 165
 166 // destructible walls that can be used to trigger target_objective_decrease
 167 void spawnfunc_func_breakable() {
 168         float n, i;
 169         if(!self.health)
 170                 self.health = 100;
 171         self.max_health = self.health;
 172
 173         if(self.mdl != "")
 174                 self.cnt = particleeffectnum(self.mdl);
 175         if(self.count == 0)
 176                 self.count = 1;
 177
 178         if(!self.message)
 179                 self.message = "got too close to an explosion";
 180         if(!self.message2)
 181                 self.message2 = "was pushed into an explosion by";
 182         if(!self.dmg_radius)
 183                 self.dmg_radius = 150;
 184         if(!self.dmg_force)
 185                 self.dmg_force = 200;
 186
 187         self.mdl = self.model;
 188         SetBrushEntityModel();
 189         self.mins_save = self.mins;
 190         self.maxs_save = self.maxs;
 191
 192         self.use = func_breakable_restore;
 193
 194         // precache all the models
 195         if (self.mdl_dead)
 196                 precache_model(self.mdl_dead);
 197         n = tokenize_sane(self.debris);
 198         for(i = 0; i < n; ++i)
 199                 precache_model(argv(i));
 200         if(self.noise)
 201                 precache_sound(self.noise);
 202
 203         self.team_saved = self.team;
 204
 205         self.reset = func_breakable_reset;
 206         func_breakable_reset();
 207 }