data/qcsrc/server/cl_weaponsystem.qc

   1 /*
   2 ===========================================================================
   3
   4   CLIENT WEAPONSYSTEM CODE
   5   Bring back W_Weaponframe
   6
   7 ===========================================================================
   8 */
   9
  10 void W_SwitchWeapon_Force(entity e, float w)
  11 {
  12         e.cnt = e.switchweapon;
  13         e.switchweapon = w;
  14 }
  15
  16 .float antilag_debug;
  17
  18 // VorteX: static frame globals
  19 float WFRAME_DONTCHANGE = -1;
  20 float WFRAME_FIRE1 = 0;
  21 float WFRAME_FIRE2 = 1;
  22 float WFRAME_IDLE = 2;
  23 float WFRAME_RELOAD = 3;
  24 .float wframe;
  25
  26 void(float fr, float t, void() func) weapon_thinkf;
  27
  28 vector w_shotorg;
  29 vector w_shotdir;
  30
  31 // this function calculates w_shotorg and w_shotdir based on the weapon model
  32 // offset, trueaim and antilag, and won't put w_shotorg inside a wall.
  33 // make sure you call makevectors first (FIXME?)
  34 void W_SetupShot(entity ent, float antilag, float recoil, string snd)
  35 {
  36         float nudge = 1; // added to traceline target and subtracted from result
  37         local vector trueaimpoint;
  38         local float oldsolid;
  39         vector vecs;
  40         oldsolid = self.dphitcontentsmask;
  41         self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
  42         traceline(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * MAX_SHOT_DISTANCE, MOVE_NOMONSTERS, self);
  43         trueaimpoint = trace_endpos;
  44
  45         if(ent.weaponentity.movedir_x > 0)
  46         {
  47                 vecs = ent.weaponentity.movedir;
  48                 vecs_y = -vecs_y;
  49         }
  50         else
  51                 vecs = '0 0 0';
  52
  53         if(debug_shotorg != '0 0 0')
  54                 vecs = debug_shotorg;
  55
  56         w_shotorg = ent.origin + ent.view_ofs + v_right * vecs_y + v_up * vecs_z;
  57
  58         // now move the shotorg forward as much as requested if possible
  59         traceline(w_shotorg, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, self);
  60         w_shotorg = trace_endpos - v_forward * nudge;
  61         // calculate the shotdir from the chosen shotorg
  62         w_shotdir = normalize(trueaimpoint - w_shotorg);
  63
  64 #if 0
  65         // explanation of g_antilag:
  66         // if client reports it was aiming at a player, and the serverside trace
  67         // says it would miss, change the aim point to the player's new origin,
  68         // but only if the shot at the player's new origin would hit of course
  69         //
  70         // FIXME: a much better method for bullet weapons would be to leave a
  71         // trail of lagged 'ghosts' behind players, and see if the bullet hits the
  72         // ghost corresponding to this player's ping time, and if so it would do
  73         // damage to the real player
  74         if (antilag)
  75         if (self.cursor_trace_ent)                 // client was aiming at someone
  76         if (self.cursor_trace_ent != self)         // just to make sure
  77         if (self.cursor_trace_ent.takedamage)      // and that person is killable
  78         if (self.cursor_trace_ent.classname == "player") // and actually a player
  79         if (cvar("g_antilag") == 1)
  80         {
  81                 // verify that the shot would miss without antilag
  82                 // (avoids an issue where guns would always shoot at their origin)
  83                 traceline(w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, MOVE_NORMAL, self);
  84                 if (!trace_ent.takedamage)
  85                 {
  86                         // verify that the shot would hit if altered
  87                         traceline(w_shotorg, self.cursor_trace_ent.origin, MOVE_NORMAL, self);
  88                         if (trace_ent == self.cursor_trace_ent)
  89                         {
  90                                 // verify that the shot would hit in the past
  91                                 if(self.antilag_debug)
  92                                         antilag_takeback(self.cursor_trace_ent, time - self.antilag_debug);
  93                                 else
  94                                         antilag_takeback(self.cursor_trace_ent, time - ANTILAG_LATENCY(self));
  95
  96                                 traceline(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, self);
  97                                 antilag_restore(self.cursor_trace_ent);
  98
  99                                 if(trace_ent == self.cursor_trace_ent)
 100                                 {
 101                                         // HIT!
 102                                         w_shotdir = normalize(self.cursor_trace_ent.origin - w_shotorg);
 103                                         dprint("ANTILAG HIT for ", self.netname, "\n");
 104                                 }
 105                                 else
 106                                 {
 107                                         // prydon cursor aimbot or odd network conditions
 108                                         dprint("WARNING: antilag ghost trace for ", self.netname, " failed!\n");
 109                                 }
 110
 111                                 if(cvar("developer") >= 2)
 112                                 {
 113                                         vector v, vplus, vel;
 114                                         float X;
 115                                         v     = antilag_takebackorigin(self.cursor_trace_ent, time - (ANTILAG_LATENCY(self)       ));
 116                                         vplus = antilag_takebackorigin(self.cursor_trace_ent, time - (ANTILAG_LATENCY(self) + 0.01));
 117                                         vel = (vplus - v) * (1 / 0.01);
 118                                         // solve: v + X * vel = closest to self.origin + self.view_ofs, v_forward axis
 119                                         v     -= (self.origin + self.view_ofs);
 120                                         // solve: v + X * vel = closest to v_forward axis
 121                                         // project into 2D by subtracting v_forward components:
 122                                         v   -= (v   * v_forward) * v_forward;
 123                                         vel -= (vel * v_forward) * v_forward;
 124                                         // solve: v + X * vel = closest to origin
 125                                         // (v + X * vel)^2 closest to 0
 126                                         // v^2 + 2 * X * (v * vel) + X^2 * vel^2 closest to 0
 127                                         X = -(v * vel) / (vel * vel);
 128                                         dprint("dead center needs adjustment of ", ftos(X), " (that is, ", ftos(ANTILAG_LATENCY(self) + X), " instead of ", ftos(ANTILAG_LATENCY(self)), "\n");
 129                                 }
 130                         }
 131                 }
 132         }
 133 #else
 134         if (antilag)
 135         {
 136                 if (cvar("g_antilag") == 1) // switch to "ghost" if not hitting original
 137                 {
 138                         traceline(w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, MOVE_NORMAL, self);
 139                         if (!trace_ent.takedamage)
 140                         {
 141                                 traceline_antilag_force (self, w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, MOVE_NORMAL, self, ANTILAG_LATENCY(self));
 142                                 if (trace_ent.takedamage && trace_ent.classname == "player")
 143                                 {
 144                                         entity e;
 145                                         e = trace_ent;
 146                                         traceline(w_shotorg, e.origin, MOVE_NORMAL, self);
 147                                         if(trace_ent == e)
 148                                                 w_shotdir = normalize(trace_ent.origin - w_shotorg);
 149                                 }
 150                         }
 151                 }
 152                 else if(cvar("g_antilag") == 3) // client side hitscan
 153                 {
 154                         if (self.cursor_trace_ent)                 // client was aiming at someone
 155                         if (self.cursor_trace_ent != self)         // just to make sure
 156                         if (self.cursor_trace_ent.takedamage)      // and that person is killable
 157                         if (self.cursor_trace_ent.classname == "player") // and actually a player
 158                         {
 159                                 // verify that the shot would miss without antilag
 160                                 // (avoids an issue where guns would always shoot at their origin)
 161                                 traceline(w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, MOVE_NORMAL, self);
 162                                 if (!trace_ent.takedamage)
 163                                 {
 164                                         // verify that the shot would hit if altered
 165                                         traceline(w_shotorg, self.cursor_trace_ent.origin, MOVE_NORMAL, self);
 166                                         if (trace_ent == self.cursor_trace_ent)
 167                                                 w_shotdir = normalize(self.cursor_trace_ent.origin - w_shotorg);
 168                                         else
 169                                                 print("antilag fail\n");
 170                                 }
 171                         }
 172                 }
 173         }
 174 #endif
 175
 176         self.dphitcontentsmask = oldsolid; // restore solid type (generally SOLID_SLIDEBOX)
 177
 178         if (!g_norecoil)
 179                 self.punchangle_x = recoil * -1;
 180
 181         if (snd != "")
 182         {
 183                 sound (self, CHAN_WEAPON, snd, VOL_BASE, ATTN_NORM);
 184         }
 185
 186         if (self.items & IT_STRENGTH)
 187         if (!g_minstagib)
 188                 sound (self, CHAN_AUTO, "weapons/strength_fire.wav", VOL_BASE, ATTN_NORM);
 189 };
 190
 191 void LaserTarget_Think()
 192 {
 193         entity e;
 194         vector offset;
 195         float uselaser;
 196         uselaser = 0;
 197
 198         // list of weapons that will use the laser, and the options that enable it
 199         if(self.owner.laser_on && self.owner.weapon == WEP_ROCKET_LAUNCHER && g_laserguided_missile)
 200                 uselaser = 1;
 201         // example
 202         //if(self.owner.weapon == WEP_ELECTRO && cvar("g_laserguided_electro"))
 203         //      uselaser = 1;
 204
 205
 206
 207         // if a laser-enabled weapon isn't selected, delete any existing laser and quit
 208         if(!uselaser)
 209         {
 210                 // rocket launcher isn't selected, so no laser target.
 211                 if(self.lasertarget != world)
 212                 {
 213                         remove(self.lasertarget);
 214                         self.lasertarget = world;
 215                 }
 216                 return;
 217         }
 218
 219         if(!self.lasertarget)
 220         {
 221                 // we don't have a lasertarget entity, so spawn one
 222                 //bprint("create laser target\n");
 223                 e = self.lasertarget = spawn();
 224                 e.owner = self.owner;                   // Its owner is my owner
 225                 e.classname = "laser_target";
 226                 e.movetype = MOVETYPE_NOCLIP;   // don't touch things
 227                 setmodel(e, "models/laser_dot.mdl");    // what it looks like, precision set below
 228                 e.scale = 1.25;                         // make it larger
 229                 e.alpha = 0.25;                         // transparency
 230                 e.colormod = '255 0 0' * (1/255) * 8;   // change colors
 231                 e.effects = EF_FULLBRIGHT | EF_LOWPRECISION;
 232                 // make it dynamically glow
 233                 // you should avoid over-using this, as it can slow down the player's computer.
 234                 e.glow_color = 251; // red color
 235                 e.glow_size = 12;
 236         }
 237         else
 238                 e = self.lasertarget;
 239
 240         // move the laser dot to where the player is looking
 241
 242         makevectors(self.owner.v_angle); // set v_forward etc to the direction the player is looking
 243         offset = '0 0 26' + v_right*3;
 244         traceline(self.owner.origin + offset, self.owner.origin + offset + v_forward * MAX_SHOT_DISTANCE, FALSE, self); // trace forward until you hit something, like a player or wall
 245         setorigin(e, trace_endpos + v_forward*8); // move me to where the traceline ended
 246         if(trace_plane_normal != '0 0 0')
 247                 e.angles = vectoangles(trace_plane_normal);
 248         else
 249                 e.angles = vectoangles(v_forward);
 250 }
 251
 252 float CL_Weaponentity_CustomizeEntityForClient()
 253 {
 254         self.viewmodelforclient = self.owner;
 255         if(other.classname == "spectator")
 256                 if(other.enemy == self.owner)
 257                         self.viewmodelforclient = other;
 258         return TRUE;
 259 }
 260
 261 float qcweaponanimation;
 262 vector weapon_offset = '0 -10 0';
 263 vector weapon_adjust = '10 0 -15';
 264 .vector weapon_morph0origin;
 265 .vector weapon_morph0angles;
 266 .float  weapon_morph0time;
 267 .vector weapon_morph1origin;
 268 .vector weapon_morph1angles;
 269 .float  weapon_morph1time;
 270 .vector weapon_morph2origin;
 271 .vector weapon_morph2angles;
 272 .float  weapon_morph2time;
 273 .vector weapon_morph3origin;
 274 .vector weapon_morph3angles;
 275 .float  weapon_morph3time;
 276 .vector weapon_morph4origin;
 277 .vector weapon_morph4angles;
 278 .float  weapon_morph4time;
 279 .string weaponname;
 280 #define QCWEAPONANIMATION_ORIGIN(e) ((weapon_offset_x + e.view_ofs_x) * v_forward - (weapon_offset_y + e.view_ofs_y) * v_right + (weapon_offset_z + e.view_ofs_z) * v_up + weapon_adjust)
 281
 282 /*
 283  * supported formats:
 284  *
 285  * 1. simple animated model, muzzlr flash handling on h_ model:
 286  *    h_tuba.dpm, h_tuba.dpm.animinfo - invisible model controlling the animation
 287  *      tags:
 288  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 289  *        shell = casings ejection point (must be on the right hand side of the gun)
 290  *        weapon = attachment for v_tuba.md3
 291  *    v_tuba.md3 - first and third person model
 292  *    g_tuba.md3 - pickup model
 293  *
 294  * 2. fully animated model, muzzle flash handling on h_ model:
 295  *    h_tuba.dpm, h_tuba.dpm.animinfo - animated first person model
 296  *      tags:
 297  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 298  *        shell = casings ejection point (must be on the right hand side of the gun)
 299  *        handle = corresponding to the origin of v_tuba.md3 (used for muzzle flashes)
 300  *    v_tuba.md3 - third person model
 301  *    g_tuba.md3 - pickup model
 302  *
 303  * 3. fully animated model, muzzle flash handling on v_ model:
 304  *    h_tuba.dpm, h_tuba.dpm.animinfo - animated first person model
 305  *      tags:
 306  *        shot = muzzle end (shot origin)
 307  *        shell = casings ejection point (must be on the right hand side of the gun)
 308  *    v_tuba.md3 - third person model
 309  *      tags:
 310  *        shot = muzzle end (for muzzle flashes)
 311  *    g_tuba.md3 - pickup model
 312  */
 313
 314 void CL_Weaponentity_Think()
 315 {
 316         float tb, v_shot_idx;
 317         self.nextthink = time;
 318         if (intermission_running)
 319                 self.frame = self.anim_idle_x;
 320         if (self.owner.weaponentity != self)
 321         {
 322                 if (self.weaponentity)
 323                         remove(self.weaponentity);
 324                 remove(self);
 325                 return;
 326         }
 327         if (self.owner.deadflag != DEAD_NO)
 328         {
 329                 self.model = "";
 330                 if (self.weaponentity)
 331                         self.weaponentity.model = "";
 332                 return;
 333         }
 334         if (self.cnt != self.owner.weapon || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
 335         {
 336                 self.cnt = self.owner.weapon;
 337                 self.dmg = self.owner.modelindex;
 338                 self.deadflag = self.owner.deadflag;
 339
 340                 string animfilename;
 341                 float animfile;
 342                 if (self.owner.weaponname != "")
 343                 {
 344                         // if there is a child entity, hide it until we're sure we use it
 345                         if (self.weaponentity)
 346                                 self.weaponentity.model = "";
 347                         setmodel(self, strcat("models/weapons/v_", self.owner.weaponname, ".md3")); // precision set below
 348                         v_shot_idx = gettagindex(self, "shot"); // used later
 349
 350                         if(qcweaponanimation)
 351                         {
 352                                 self.angles = '0 0 0';
 353                                 makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 354                                 self.movedir = weapon_offset_x * v_forward - weapon_offset_y * v_right + weapon_offset_z * v_up + weapon_adjust;
 355                                 self.movedir_x += 32;
 356                                 self.spawnorigin = self.movedir;
 357                                 // oldorigin - not calculated here
 358                         }
 359                         else
 360                         {
 361                                 setmodel(self, strcat("models/weapons/h_", self.owner.weaponname, ".dpm")); // precision set below
 362                                 animfilename = strcat("models/weapons/h_", self.owner.weaponname, ".dpm.animinfo");
 363                                 animfile = fopen(animfilename, FILE_READ);
 364                                 // preset some defaults that work great for renamed zym files (which don't need an animinfo)
 365                                 self.anim_fire1  = '0 1 0.01';
 366                                 self.anim_fire2  = '1 1 0.01';
 367                                 self.anim_idle   = '2 1 0.01';
 368                                 self.anim_reload = '3 1 0.01';
 369                                 if (animfile >= 0)
 370                                 {
 371                                         animparseerror = FALSE;
 372                                         self.anim_fire1  = animparseline(animfile);
 373                                         self.anim_fire2  = animparseline(animfile);
 374                                         self.anim_idle   = animparseline(animfile);
 375                                         self.anim_reload = animparseline(animfile);
 376                                         fclose(animfile);
 377                                         if (animparseerror)
 378                                                 print("Parse error in ", animfilename, ", some player animations are broken\n");
 379                                 }
 380
 381                                 // if we have a "weapon" tag, let's attach the v_ model to it ("invisible hand" style model)
 382                                 // if we don't, this is a "real" animated model
 383                                 if(gettagindex(self, "weapon"))
 384                                 {
 385                                         if (!self.weaponentity)
 386                                                 self.weaponentity = spawn();
 387                                         setmodel(self.weaponentity, strcat("models/weapons/v_", self.owner.weaponname, ".md3")); // precision does not matter
 388                                         setattachment(self.weaponentity, self, "weapon");
 389                                 }
 390                                 else
 391                                 {
 392                                         if(self.weaponentity)
 393                                                 remove(self.weaponentity);
 394                                         self.weaponentity = world;
 395                                 }
 396
 397                                 self.origin = '0 0 0';
 398                                 self.angles = '0 0 0';
 399                                 self.frame = 0;
 400                                 self.viewmodelforclient = world;
 401
 402                                 float idx;
 403                                 idx = gettagindex(self, "shot");
 404                                 if(idx)
 405                                 {
 406                                         self.movedir = gettaginfo(self, idx);
 407                                 }
 408                                 else
 409                                 {
 410                                         print("WARNING: weapon model ", self.model, " does not support the 'shot' tag, will display shots TOTALLY wrong\n");
 411                                         self.movedir = '0 0 0';
 412                                 }
 413
 414                                 idx = gettagindex(self, "shell");
 415                                 if(idx)
 416                                 {
 417                                         self.spawnorigin = gettaginfo(self, idx);
 418                                 }
 419                                 else
 420                                 {
 421                                         print("WARNING: weapon model ", self.model, " does not support the 'shell' tag, will display casings wrong\n");
 422                                         self.spawnorigin = self.movedir;
 423                                 }
 424
 425                                 if(v_shot_idx)
 426                                 {
 427                                         self.oldorigin = '0 0 0';
 428                                 }
 429                                 else
 430                                 {
 431                                         if(self.weaponentity)
 432                                                 idx = gettagindex(self, "weapon");
 433                                         else
 434                                                 idx = gettagindex(self, "handle");
 435                                         if(idx)
 436                                         {
 437                                                 self.oldorigin = self.movedir - gettaginfo(self, idx);
 438                                         }
 439                                         else
 440                                         {
 441                                                 print("WARNING: weapon model ", self.model, " does not support the 'handle' tag and neither does the v_ model support the 'shot' tag, will display muzzle flashes TOTALLY wrong\n");
 442                                                 self.oldorigin = '0 0 0'; // there is no way to recover from this
 443                                         }
 444                                 }
 445
 446                                 self.viewmodelforclient = self.owner;
 447                         }
 448                 }
 449                 else
 450                 {
 451                         self.model = "";
 452                         if(self.weaponentity)
 453                                 remove(self.weaponentity);
 454                         self.weaponentity = world;
 455                         self.movedir = '0 0 0';
 456                         self.spawnorigin = '0 0 0';
 457                         self.oldorigin = '0 0 0';
 458                         self.anim_fire1  = '0 1 0.01';
 459                         self.anim_fire2  = '0 1 0.01';
 460                         self.anim_idle   = '0 1 0.01';
 461                         self.anim_reload = '0 1 0.01';
 462                 }
 463
 464                 self.view_ofs = '0 0 0';
 465
 466                 if(self.movedir_x >= 0)
 467                 {
 468                         vector v0;
 469                         v0 = self.movedir;
 470                         self.movedir = shotorg_adjust(v0, FALSE, FALSE);
 471                         self.view_ofs = shotorg_adjust(v0, FALSE, TRUE) - v0;
 472                 }
 473
 474                 self.spawnorigin += self.view_ofs; // offset the casings origin by the same amount
 475
 476                 // check if an instant weapon switch occurred
 477                 if (qcweaponanimation)
 478                 {
 479                         if (self.state == WS_READY)
 480                         {
 481                                 self.angles = '0 0 0';
 482                                 makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 483                                 setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
 484                         }
 485                 }
 486                 else
 487                         setorigin(self, self.view_ofs);
 488                 // reset animstate now
 489                 self.wframe = WFRAME_IDLE;
 490                 self.weapon_morph0time = 0;
 491                 self.weapon_morph1time = 0;
 492                 self.weapon_morph2time = 0;
 493                 self.weapon_morph3time = 0;
 494                 self.weapon_morph4time = 0;
 495                 setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 496         }
 497
 498         tb = (self.effects & EF_TELEPORT_BIT);
 499         self.effects = self.owner.effects & EFMASK_CHEAP;
 500         self.effects &~= EF_LOWPRECISION;
 501         self.effects &~= EF_FULLBRIGHT; // can mask team color, so get rid of it
 502         self.effects &~= EF_TELEPORT_BIT;
 503         self.effects |= tb;
 504
 505         if(self.owner.alpha != 0)
 506                 self.alpha = self.owner.alpha;
 507         else
 508                 self.alpha = 1;
 509
 510         self.colormap = self.owner.colormap;
 511         if (self.weaponentity)
 512         {
 513                 self.weaponentity.effects = self.effects;
 514                 self.weaponentity.alpha = self.alpha;
 515                 self.weaponentity.colormap = self.colormap;
 516         }
 517
 518         self.angles = '0 0 0';
 519         local float f;
 520         f = 0;
 521         if (self.state == WS_RAISE)
 522         {
 523                 f = (self.owner.weapon_nextthink - time) / cvar("g_balance_weaponswitchdelay");
 524                 self.angles_x = -90 * f * f;
 525                 if (qcweaponanimation)
 526                 {
 527                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 528                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
 529                 }
 530         }
 531         else if (self.state == WS_DROP)
 532         {
 533                 f = 1 - (self.owner.weapon_nextthink - time) / cvar("g_balance_weaponswitchdelay");
 534                 self.angles_x = -90 * f * f;
 535                 if (qcweaponanimation)
 536                 {
 537                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 538                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
 539                 }
 540         }
 541         else if (self.state == WS_CLEAR)
 542         {
 543                 f = 1;
 544                 self.angles_x = -90 * f * f;
 545                 if (qcweaponanimation)
 546                 {
 547                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 548                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
 549                 }
 550         }
 551         else if (qcweaponanimation && time < self.owner.weapon_morph1time)
 552         {
 553                 f = (time - self.owner.weapon_morph0time) / (self.owner.weapon_morph1time - self.owner.weapon_morph0time);
 554                 f = 1 - pow(1 - f, 3);
 555                 self.angles = self.owner.weapon_morph0angles * (1 - f) + self.owner.weapon_morph1angles * f;
 556                 setorigin(self, self.owner.weapon_morph0origin * (1 - f) + self.owner.weapon_morph1origin * f);
 557         }
 558         else if (qcweaponanimation && time < self.owner.weapon_morph2time)
 559         {
 560                 f = (time - self.owner.weapon_morph1time) / (self.owner.weapon_morph2time - self.owner.weapon_morph1time);
 561                 f = 1 - pow(1 - f, 3);
 562                 self.angles = self.owner.weapon_morph1angles * (1 - f) + self.owner.weapon_morph2angles * f;
 563                 setorigin(self, self.owner.weapon_morph1origin * (1 - f) + self.owner.weapon_morph2origin * f);
 564         }
 565         else if (qcweaponanimation && time < self.owner.weapon_morph3time)
 566         {
 567                 f = (time - self.owner.weapon_morph2time) / (self.owner.weapon_morph3time - self.owner.weapon_morph2time);
 568                 f = 1 - pow(1 - f, 3);
 569                 self.angles = self.owner.weapon_morph2angles * (1 - f) + self.owner.weapon_morph3angles * f;
 570                 setorigin(self, self.owner.weapon_morph2origin * (1 - f) + self.owner.weapon_morph3origin * f);
 571         }
 572         else if (qcweaponanimation && time < self.owner.weapon_morph4time)
 573         {
 574                 f = (time - self.owner.weapon_morph3time) / (self.owner.weapon_morph4time - self.owner.weapon_morph3time);
 575                 f = 1 - pow(1 - f, 3);
 576                 self.angles = self.owner.weapon_morph3angles * (1 - f) + self.owner.weapon_morph4angles * f;
 577                 setorigin(self, self.owner.weapon_morph3origin * (1 - f) + self.owner.weapon_morph4origin * f);
 578         }
 579         else if (qcweaponanimation)
 580         {
 581                 // begin a new idle morph
 582                 self.owner.weapon_morph0time   = time;
 583                 self.owner.weapon_morph0angles = self.angles;
 584                 self.owner.weapon_morph0origin = self.origin;
 585
 586                 float r;
 587                 float t;
 588
 589                 r = random();
 590                 if (r < 0.1)
 591                 {
 592                         // turn gun to the left to look at it
 593                         t = 2;
 594                         self.owner.weapon_morph1time   = time + t * 0.2;
 595                         self.owner.weapon_morph1angles = randomvec() * 3 + '-5 30 0';
 596                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
 597                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
 598
 599                         self.owner.weapon_morph2time   = time + t * 0.6;
 600                         self.owner.weapon_morph2angles = randomvec() * 3 + '-5 30 0';
 601                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
 602                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
 603
 604                         self.owner.weapon_morph3time   = time + t;
 605                         self.owner.weapon_morph3angles = '0 0 0';
 606                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
 607                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
 608                 }
 609                 else if (r < 0.2)
 610                 {
 611                         // raise the gun a bit
 612                         t = 2;
 613                         self.owner.weapon_morph1time   = time + t * 0.2;
 614                         self.owner.weapon_morph1angles = randomvec() * 3 + '30 -10 0';
 615                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
 616                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
 617
 618                         self.owner.weapon_morph2time   = time + t * 0.5;
 619                         self.owner.weapon_morph2angles = randomvec() * 3 + '30 -10 5';
 620                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
 621                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
 622
 623                         self.owner.weapon_morph3time   = time + t;
 624                         self.owner.weapon_morph3angles = '0 0 0';
 625                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
 626                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
 627                 }
 628                 else if (r < 0.3)
 629                 {
 630                         // tweak it a bit
 631                         t = 5;
 632                         self.owner.weapon_morph1time   = time + t * 0.3;
 633                         self.owner.weapon_morph1angles = randomvec() * 6;
 634                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
 635                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
 636
 637                         self.owner.weapon_morph2time   = time + t * 0.7;
 638                         self.owner.weapon_morph2angles = randomvec() * 6;
 639                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
 640                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
 641
 642                         self.owner.weapon_morph3time   = time + t;
 643                         self.owner.weapon_morph3angles = '0 0 0';
 644                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
 645                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
 646                 }
 647                 else
 648                 {
 649                         // hold it mostly steady
 650                         t = random() * 6 + 4;
 651                         self.owner.weapon_morph1time   = time + t * 0.2;
 652                         self.owner.weapon_morph1angles = randomvec() * 1;
 653                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
 654                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
 655
 656                         self.owner.weapon_morph2time   = time + t * 0.5;
 657                         self.owner.weapon_morph2angles = randomvec() * 1;
 658                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
 659                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
 660
 661                         self.owner.weapon_morph3time   = time + t * 0.7;
 662                         self.owner.weapon_morph3angles = randomvec() * 1;
 663                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
 664                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
 665                 }
 666
 667                 self.owner.weapon_morph4time   = time + t;
 668                 self.owner.weapon_morph4angles = '0 0 0';
 669                 makevectors(self.owner.weapon_morph4angles_x * '-1 0 0' + self.owner.weapon_morph4angles_y * '0 1 0' + self.owner.weapon_morph4angles_z * '0 0 1');
 670                 self.owner.weapon_morph4origin = QCWEAPONANIMATION_ORIGIN(self);
 671
 672         }
 673
 674         // create or update the lasertarget entity
 675         LaserTarget_Think();
 676 };
 677
 678 void CL_ExteriorWeaponentity_Think()
 679 {
 680         float tag_found;
 681         self.nextthink = time;
 682         if (self.owner.exteriorweaponentity != self)
 683         {
 684                 remove(self);
 685                 return;
 686         }
 687         if (self.owner.deadflag != DEAD_NO)
 688         {
 689                 self.model = "";
 690                 return;
 691         }
 692         if (self.cnt != self.owner.weapon || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
 693         {
 694                 self.cnt = self.owner.weapon;
 695                 self.dmg = self.owner.modelindex;
 696                 self.deadflag = self.owner.deadflag;
 697                 if (self.owner.weaponname != "")
 698                         setmodel(self, strcat("models/weapons/v_", self.owner.weaponname, ".md3")); // precision set below
 699                 else
 700                         self.model = "";
 701
 702                 if((tag_found = gettagindex(self.owner, "tag_weapon")))
 703                 {
 704                         self.tag_index = tag_found;
 705                         self.tag_entity = self.owner;
 706                 }
 707                 else
 708                         setattachment(self, self.owner, "bip01 r hand");
 709
 710                 // if that didn't find a tag, hide the exterior weapon model
 711                 if (!self.tag_index)
 712                         self.model = "";
 713         }
 714         self.effects = self.owner.effects | EF_LOWPRECISION;
 715         self.effects = self.effects & EFMASK_CHEAP; // eat performance
 716         if(self.owner.alpha != 0)
 717                 self.alpha = self.owner.alpha;
 718         else
 719                 self.alpha = 1;
 720
 721         self.colormap = self.owner.colormap;
 722 };
 723
 724 // spawning weaponentity for client
 725 void CL_SpawnWeaponentity()
 726 {
 727         self.weaponentity = spawn();
 728         self.weaponentity.classname = "weaponentity";
 729         self.weaponentity.solid = SOLID_NOT;
 730         self.weaponentity.owner = self;
 731         setmodel(self.weaponentity, ""); // precision set when changed
 732         self.weaponentity.origin = '0 0 0';
 733         self.weaponentity.angles = '0 0 0';
 734         self.weaponentity.viewmodelforclient = self;
 735         self.weaponentity.flags = 0;
 736         self.weaponentity.think = CL_Weaponentity_Think;
 737         self.weaponentity.customizeentityforclient = CL_Weaponentity_CustomizeEntityForClient;
 738         self.weaponentity.nextthink = time;
 739
 740         self.exteriorweaponentity = spawn();
 741         self.exteriorweaponentity.classname = "exteriorweaponentity";
 742         self.exteriorweaponentity.solid = SOLID_NOT;
 743         self.exteriorweaponentity.exteriorweaponentity = self.exteriorweaponentity;
 744         self.exteriorweaponentity.owner = self;
 745         self.exteriorweaponentity.origin = '0 0 0';
 746         self.exteriorweaponentity.angles = '0 0 0';
 747         self.exteriorweaponentity.think = CL_ExteriorWeaponentity_Think;
 748         self.exteriorweaponentity.nextthink = time;
 749 };
 750
 751 .float hasweapon_complain_spam;
 752
 753 float client_hasweapon(entity cl, float wpn, float andammo, float complain)
 754 {
 755         local float weaponbit, f;
 756         local entity oldself;
 757
 758         if(time < self.hasweapon_complain_spam)
 759                 complain = 0;
 760         if(complain)
 761                 self.hasweapon_complain_spam = time + 0.2;
 762
 763         if (wpn < WEP_FIRST || wpn > WEP_LAST)
 764         {
 765                 if (complain)
 766                         sprint(self, "Invalid weapon\n");
 767                 return FALSE;
 768         }
 769         weaponbit = W_WeaponBit(wpn);
 770         if (cl.weapons & weaponbit)
 771         {
 772                 if (andammo)
 773                 {
 774                         if(cl.items & IT_UNLIMITED_WEAPON_AMMO)
 775                         {
 776                                 f = 1;
 777                         }
 778                         else
 779                         {
 780                                 oldself = self;
 781                                 self = cl;
 782                                 f = weapon_action(wpn, WR_CHECKAMMO1);
 783                                 f = f + weapon_action(wpn, WR_CHECKAMMO2);
 784                                 self = oldself;
 785                         }
 786                         if (!f)
 787                         {
 788                                 if (complain)
 789                                         sprint(cl, strcat("You don't have any ammo for the ^2", W_Name(wpn), "\n"));
 790                                 return FALSE;
 791                         }
 792                 }
 793                 return TRUE;
 794         }
 795         if (complain)
 796         {
 797                 // DRESK - 3/16/07
 798                 // Report Proper Weapon Status / Modified Weapon Ownership Message
 799                 if(weaponsInMap & weaponbit)
 800                 {
 801                         sprint(cl, strcat("You do not have the ^2", W_Name(wpn), "\n") );
 802
 803                         if(cvar("g_showweaponspawns"))
 804                         {
 805                                 entity e;
 806                                 string s;
 807
 808                                 e = get_weaponinfo(wpn);
 809                                 s = e.model2;
 810
 811                                 for(e = world; (e = findfloat(e, weapons, weaponbit)); )
 812                                 {
 813                                         if(e.classname == "droppedweapon")
 814                                                 continue;
 815                                         if not(e.flags & FL_ITEM)
 816                                                 continue;
 817                                         WaypointSprite_Spawn(
 818                                                 s,
 819                                                 1, 0,
 820                                                 world, e.origin,
 821                                                 self, 0,
 822                                                 world, enemy,
 823                                                 0
 824                                         );
 825                                 }
 826                         }
 827                 }
 828                 else
 829                         sprint(cl, strcat("The ^2", W_Name(wpn), "^7 is ^1NOT AVAILABLE^7 in this map\n") );
 830         }
 831         return FALSE;
 832 };
 833
 834 // Weapon subs
 835 void w_clear()
 836 {
 837         if (self.weapon != -1)
 838                 self.weapon = 0;
 839         if (self.weaponentity)
 840         {
 841                 self.weaponentity.state = WS_CLEAR;
 842                 self.weaponentity.effects = 0;
 843         }
 844 };
 845
 846 void w_ready()
 847 {
 848         if (self.weaponentity)
 849                 self.weaponentity.state = WS_READY;
 850         weapon_thinkf(WFRAME_IDLE, 1000000, w_ready);
 851 };
 852
 853 // Setup weapon for client (after this raise frame will be launched)
 854 void weapon_setup(float windex)
 855 {
 856         entity e;
 857         qcweaponanimation = cvar("sv_qcweaponanimation");
 858         e = get_weaponinfo(windex);
 859         self.items &~= IT_AMMO;
 860         self.items = self.items | e.items;
 861
 862         // the two weapon entities will notice this has changed and update their models
 863         self.weapon = windex;
 864         self.weaponname = e.mdl;
 865         self.bulletcounter = 0;
 866 };
 867
 868 // perform weapon to attack (weaponstate and attack_finished check is here)
 869 .float race_penalty;
 870 float weapon_prepareattack(float secondary, float attacktime)
 871 {
 872         //if sv_ready_restart_after_countdown is set, don't allow the player to shoot
 873         //if all players readied up and the countdown is running
 874         if (cvar("sv_ready_restart_after_countdown"))
 875                 if(time < game_starttime || time < self.race_penalty) {
 876                         return FALSE;
 877                 }
 878
 879         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 880         if (!weapon_action(self.weapon, WR_CHECKAMMO1 + secondary))
 881         {
 882                 W_SwitchWeapon_Force(self, w_getbestweapon(self));
 883                 return FALSE;
 884         }
 885
 886         if (timeoutStatus == 2) //don't allow the player to shoot while game is paused
 887                 return FALSE;
 888
 889         // do not even think about shooting if switching
 890         if(self.switchweapon != self.weapon)
 891                 return FALSE;
 892
 893         // don't fire if previous attack is not finished
 894         if(attacktime >= 0)
 895                 if (ATTACK_FINISHED(self) > time + frametime * 0.5)
 896                         return FALSE;
 897         // don't fire while changing weapon
 898         if (self.weaponentity.state != WS_READY)
 899                 return FALSE;
 900         self.weaponentity.state = WS_INUSE;
 901
 902         self.spawnshieldtime = min(self.spawnshieldtime, time); // kill spawn shield when you fire
 903
 904         // if the weapon hasn't been firing continuously, reset the timer
 905         if(attacktime >= 0)
 906         {
 907                 if (ATTACK_FINISHED(self) < time - frametime * 1.5)
 908                 {
 909                         ATTACK_FINISHED(self) = time;
 910                         //dprint("resetting attack finished to ", ftos(time), "\n");
 911                 }
 912                 ATTACK_FINISHED(self) = ATTACK_FINISHED(self) + attacktime;
 913         }
 914         self.bulletcounter += 1;
 915         //dprint("attack finished ", ftos(ATTACK_FINISHED(self)), "\n");
 916         return TRUE;
 917 };
 918
 919 void weapon_thinkf(float fr, float t, void() func)
 920 {
 921         vector a;
 922         vector of, or, ou;
 923         float restartanim;
 924
 925         if(fr == WFRAME_DONTCHANGE)
 926         {
 927                 fr = self.weaponentity.wframe;
 928                 restartanim = FALSE;
 929         }
 930         else if (fr == WFRAME_IDLE)
 931                 restartanim = FALSE;
 932         else
 933                 restartanim = TRUE;
 934
 935         of = v_forward;
 936         or = v_right;
 937         ou = v_up;
 938
 939         if (self.weaponentity)
 940         {
 941                 self.weaponentity.wframe = fr;
 942                 if (qcweaponanimation)
 943                 {
 944                         if (fr != WFRAME_IDLE)
 945                         {
 946                                 self.weapon_morph0time = time;
 947                                 self.weapon_morph0angles = self.weaponentity.angles;
 948                                 self.weapon_morph0origin = self.weaponentity.origin;
 949
 950                                 self.weapon_morph1angles = '0 0 0';
 951                                 self.weapon_morph1time = time + t;
 952                                 makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
 953                                 self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
 954
 955                                 self.weapon_morph2angles = '0 0 0';
 956                                 self.weapon_morph2time = time + t;
 957                                 makevectors(self.weapon_morph2angles_x * '-1 0 0' + self.weapon_morph2angles_y * '0 1 0' + self.weapon_morph2angles_z * '0 0 1');
 958                                 self.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
 959
 960                                 self.weapon_morph3angles = '0 0 0';
 961                                 self.weapon_morph3time = time + t;
 962                                 makevectors(self.weapon_morph3angles_x * '-1 0 0' + self.weapon_morph3angles_y * '0 1 0' + self.weapon_morph3angles_z * '0 0 1');
 963                                 self.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
 964
 965                                 self.weapon_morph4angles = '0 0 0';
 966                                 self.weapon_morph4time = time + t;
 967                                 makevectors(self.weapon_morph4angles_x * '-1 0 0' + self.weapon_morph4angles_y * '0 1 0' + self.weapon_morph4angles_z * '0 0 1');
 968                                 self.weapon_morph4origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
 969
 970                                 if (fr == WFRAME_FIRE1)
 971                                 {
 972                                         self.weapon_morph1angles = '5 0 0';
 973                                         self.weapon_morph1time = time + t * 0.1;
 974                                         makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
 975                                         self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
 976                                         self.weapon_morph4time = time + t + 1; // delay idle effect
 977                                 }
 978                                 else if (fr == WFRAME_FIRE2)
 979                                 {
 980                                         self.weapon_morph1angles = '10 0 0';
 981                                         self.weapon_morph1time = time + t * 0.1;
 982                                         makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
 983                                         self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
 984                                         self.weapon_morph4time = time + t + 1; // delay idle effect
 985                                 }
 986                                 else if (fr == WFRAME_RELOAD)
 987                                 {
 988                                         self.weapon_morph1time = time + t * 0.05;
 989                                         self.weapon_morph1angles = '-10 40 0';
 990                                         makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
 991                                         self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
 992
 993                                         self.weapon_morph2time = time + t * 0.15;
 994                                         self.weapon_morph2angles = '-10 40 5';
 995                                         makevectors(self.weapon_morph2angles_x * '-1 0 0' + self.weapon_morph2angles_y * '0 1 0' + self.weapon_morph2angles_z * '0 0 1');
 996                                         self.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
 997
 998                                         self.weapon_morph3time = time + t * 0.25;
 999                                         self.weapon_morph3angles = '-10 40 0';
1000                                         makevectors(self.weapon_morph3angles_x * '-1 0 0' + self.weapon_morph3angles_y * '0 1 0' + self.weapon_morph3angles_z * '0 0 1');
1001                                         self.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1002                                 }
1003                         }
1004                 }
1005                 else
1006                 {
1007                         if (fr == WFRAME_IDLE)
1008                                 a = self.weaponentity.anim_idle;
1009                         else if (fr == WFRAME_FIRE1)
1010                                 a = self.weaponentity.anim_fire1;
1011                         else if (fr == WFRAME_FIRE2)
1012                                 a = self.weaponentity.anim_fire2;
1013                         else if (fr == WFRAME_RELOAD)
1014                                 a = self.weaponentity.anim_reload;
1015                         setanim(self.weaponentity, a, restartanim == FALSE, restartanim, restartanim);
1016                 }
1017
1018                 if(restartanim)
1019                 {
1020                         BITXOR_ASSIGN(self.weaponentity.effects, EF_TELEPORT_BIT);
1021                 }
1022         }
1023
1024         v_forward = of;
1025         v_right = or;
1026         v_up = ou;
1027
1028         if(self.weapon_think == w_ready && func != w_ready && self.weaponentity.state == WS_RAISE)
1029         {
1030                 backtrace("Tried to override initial weapon think function - should this really happen?");
1031         }
1032
1033         if(g_runematch)
1034         {
1035                 if(self.runes & RUNE_SPEED)
1036                 {
1037                         if(self.runes & CURSE_SLOW)
1038                                 t = t * cvar("g_balance_rune_speed_combo_atkrate");
1039                         else
1040                                 t = t * cvar("g_balance_rune_speed_atkrate");
1041                 }
1042                 else if(self.runes & CURSE_SLOW)
1043                 {
1044                         t = t * cvar("g_balance_curse_slow_atkrate");
1045                 }
1046         }
1047
1048         // VorteX: haste can be added here
1049         if (self.weapon_think == w_ready)
1050         {
1051                 self.weapon_nextthink = time;
1052                 //dprint("started firing at ", ftos(time), "\n");
1053         }
1054         if (self.weapon_nextthink < time - frametime * 1.5 || self.weapon_nextthink > time + frametime * 1.5)
1055         {
1056                 self.weapon_nextthink = time;
1057                 //dprint("reset weapon animation timer at ", ftos(time), "\n");
1058         }
1059         self.weapon_nextthink = self.weapon_nextthink + t;
1060         self.weapon_think = func;
1061         //dprint("next ", ftos(self.weapon_nextthink), "\n");
1062
1063         if (restartanim)
1064         if (t)
1065         if (!self.crouch) // shoot anim stands up, this looks bad
1066         {
1067                 local vector anim;
1068                 anim = self.anim_shoot;
1069                 anim_z = anim_y / t;
1070                 setanim(self, anim, FALSE, TRUE, TRUE);
1071         }
1072 };
1073
1074 void weapon_boblayer1(float spd, vector org)
1075 {
1076         // VorteX: haste can be added here
1077 };
1078
1079 vector W_CalculateProjectileVelocity(vector pvelocity, vector mvelocity)
1080 {
1081         vector mdirection;
1082         float mspeed;
1083         float outspeed;
1084         float nstyle;
1085         vector outvelocity;
1086
1087         mdirection = normalize(mvelocity);
1088         mspeed = vlen(mvelocity);
1089
1090         nstyle = cvar("g_projectiles_newton_style");
1091         if(nstyle == 0)
1092         {
1093                 // absolute velocity
1094                 outvelocity = mvelocity;
1095         }
1096         else if(nstyle == 1)
1097         {
1098                 // true Newtonian projectiles
1099                 outvelocity = pvelocity + mvelocity;
1100         }
1101         else if(nstyle == 2)
1102         {
1103                 // true Newtonian projectiles with automatic aim adjustment
1104                 //
1105                 // solve: |outspeed * mdirection - pvelocity| = mspeed
1106                 // outspeed^2 - 2 * outspeed * (mdirection * pvelocity) + pvelocity^2 - mspeed^2 = 0
1107                 // outspeed = (mdirection * pvelocity) +- sqrt((mdirection * pvelocity)^2 - pvelocity^2 + mspeed^2)
1108                 // PLUS SIGN!
1109                 // not defined?
1110                 // then...
1111                 // pvelocity^2 - (mdirection * pvelocity)^2 > mspeed^2
1112                 // velocity without mdirection component > mspeed
1113                 // fire at smallest possible mspeed that works?
1114                 // |(mdirection * pvelocity) * pvelocity - pvelocity| = mspeed
1115
1116                 vector solution;
1117                 solution = solve_quadratic(1, -2 * (mdirection * pvelocity), pvelocity * pvelocity - mspeed * mspeed);
1118                 if(solution_z)
1119                         outspeed = solution_y; // the larger one
1120                 else
1121                 {
1122                         //outspeed = 0; // slowest possible shot
1123                         outspeed = solution_x; // the real part (that is, the average!)
1124                         //dprint("impossible shot, adjusting\n");
1125                 }
1126
1127                 outspeed = bound(mspeed * 0.7, outspeed, mspeed * 5.0);
1128                 outvelocity = mdirection * outspeed;
1129         }
1130         else if(nstyle == 3)
1131         {
1132                 // pseudo-Newtonian:
1133                 outspeed = mspeed + mdirection * pvelocity;
1134                 outspeed = bound(mspeed * 0.7, outspeed, mspeed * 5.0);
1135                 outvelocity = mdirection * outspeed;
1136         }
1137         else if(nstyle == 4)
1138         {
1139                 // tZorkian:
1140                 outspeed = mspeed + vlen(pvelocity);
1141                 outvelocity = mdirection * outspeed;
1142         }
1143         else
1144                 error("g_projectiles_newton_style must be 0 (absolute), 1 (Newtonian), 2 (Newtonian + aimfix), 3 (pseudo Newtonian) or 4 (tZorkian)!");
1145
1146         return outvelocity;
1147 }
1148
1149 void W_SetupProjectileVelocity(entity missile)
1150 {
1151         if(missile.owner == world)
1152                 error("Unowned missile");
1153
1154         missile.velocity = W_CalculateProjectileVelocity(missile.owner.velocity, missile.velocity);
1155 }
1156
1157 void W_AttachToShotorg(entity flash, vector offset)
1158 {
1159         entity xflash;
1160         flash.owner = self;
1161         flash.angles_z = random() * 360;
1162         if(qcweaponanimation)
1163         {
1164                 setorigin(flash, w_shotorg + w_shotdir * 50);
1165                 flash.angles = vectoangles(w_shotdir);
1166                 flash.angles_z = random() * 360;
1167         }
1168         else
1169         {
1170                 setattachment(flash, self.weaponentity, "shot");
1171                 setorigin(flash, offset);
1172
1173                 xflash = spawn();
1174                 copyentity(flash, xflash);
1175
1176                 flash.viewmodelforclient = self;
1177
1178                 if(self.weaponentity.oldorigin_x > 0)
1179                 {
1180                         setattachment(xflash, self.exteriorweaponentity, "");
1181                         setorigin(xflash, self.weaponentity.oldorigin + offset);
1182                 }
1183                 else
1184                 {
1185                         setattachment(xflash, self.exteriorweaponentity, "shot");
1186                 }
1187         }
1188 }