data/qcsrc/server/cl_weapons.qc

   1 void W_Reload()
   2 {
   3         if(self.switchweapon == self.weapon)
   4         if(self.weaponentity.state == WS_READY)
   5                 weapon_action(self.weapon, WR_RELOAD);
   6 }
   7
   8 // switch between weapons
   9 void W_SwitchWeapon(float imp)
  10 {
  11         if (self.switchweapon != imp)
  12         {
  13                 if (client_hasweapon(self, imp, TRUE, TRUE))
  14                         W_SwitchWeapon_Force(self, imp);
  15         }
  16         else
  17         {
  18                 W_Reload();
  19         }
  20 };
  21
  22 .float weaponcomplainindex;
  23 float W_GetCycleWeapon(entity pl, string weaponorder, float dir, float imp, float complain)
  24 {
  25         float n, i, weaponwant, first_valid, prev_valid, switchtonext, switchtolast, c;
  26         n = tokenize_console(weaponorder);
  27         switchtonext = switchtolast = 0;
  28         first_valid = prev_valid = 0;
  29
  30         if(dir == 0)
  31                 switchtonext = 1;
  32
  33         c = 0;
  34
  35         for(i = 0; i < n; ++i)
  36         {
  37                 weaponwant = stof(argv(i));
  38                 if(imp >= 0)
  39                         if((get_weaponinfo(weaponwant)).impulse != imp)
  40                                 continue;
  41
  42                 ++c;
  43
  44                 if(client_hasweapon(pl, weaponwant, TRUE, FALSE))
  45                 {
  46                         if(switchtonext)
  47                                 return weaponwant;
  48                         if(!first_valid)
  49                                 first_valid = weaponwant;
  50                         if(weaponwant == pl.switchweapon)
  51                         {
  52                                 if(dir >= 0)
  53                                         switchtonext = 1;
  54                                 else if(prev_valid)
  55                                         return prev_valid;
  56                                 else
  57                                         switchtolast = 1;
  58                         }
  59                         prev_valid = weaponwant;
  60                 }
  61         }
  62         if(first_valid)
  63         {
  64                 if(switchtolast)
  65                         return prev_valid;
  66                 else
  67                         return first_valid;
  68         }
  69         // complain (but only for one weapon on the button that has been pressed)
  70         if(complain)
  71         {
  72                 self.weaponcomplainindex += 1;
  73                 c = mod(self.weaponcomplainindex, c) + 1;
  74                 for(i = 0; i < n; ++i)
  75                 {
  76                         weaponwant = stof(argv(i));
  77                         if(imp >= 0)
  78                                 if((get_weaponinfo(weaponwant)).impulse != imp)
  79                                         continue;
  80
  81                         --c;
  82                         if(c == 0)
  83                         {
  84                                 client_hasweapon(pl, weaponwant, TRUE, TRUE);
  85                                 break;
  86                         }
  87                 }
  88         }
  89         return 0;
  90 }
  91
  92 void W_CycleWeapon(string weaponorder, float dir)
  93 {
  94         float w;
  95         w = W_GetCycleWeapon(self, weaponorder, dir, -1, 1);
  96         if(w > 0)
  97                 W_SwitchWeapon(w);
  98 }
  99
 100 void W_NextWeaponOnImpulse(float imp)
 101 {
 102         float w;
 103         w = W_GetCycleWeapon(self, self.cvar_cl_weaponpriority, +1, imp, 1);
 104         if(w > 0)
 105                 W_SwitchWeapon(w);
 106 }
 107
 108 // next weapon
 109 void W_NextWeapon(float list)
 110 {
 111         if(list == 0)
 112                 W_CycleWeapon(weaponpriority_hudselector_0, -1);
 113         else if(list == 1)
 114                 W_CycleWeapon(weaponpriority_hudselector_1, -1);
 115         else if(list == 2)
 116                 W_CycleWeapon(self.cvar_cl_weaponpriority, -1);
 117 }
 118
 119 // prev weapon
 120 void W_PreviousWeapon(float list)
 121 {
 122         if(list == 0)
 123                 W_CycleWeapon(weaponpriority_hudselector_0, +1);
 124         else if(list == 1)
 125                 W_CycleWeapon(weaponpriority_hudselector_1, +1);
 126         else if(list == 2)
 127                 W_CycleWeapon(self.cvar_cl_weaponpriority, +1);
 128 }
 129
 130 string W_FixWeaponOrder_AllowIncomplete(string order)
 131 {
 132         return W_FixWeaponOrder(order, 0);
 133 }
 134
 135 string W_FixWeaponOrder_ForceComplete(string order)
 136 {
 137         if(order == "")
 138                 order = cvar_string("cl_weaponpriority");
 139         return W_FixWeaponOrder(order, 1);
 140 }
 141
 142 float w_getbestweapon(entity e)
 143 {
 144         return W_GetCycleWeapon(e, e.cvar_cl_weaponpriority, 0, -1, 0);
 145 };
 146
 147 // generic weapons table
 148 // TODO should they be macros instead?
 149 float weapon_action(float wpn, float wrequest)
 150 {
 151         return (get_weaponinfo(wpn)).weapon_func(wrequest);
 152 };
 153
 154 string W_Name(float weaponid)
 155 {
 156         return (get_weaponinfo(weaponid)).message;
 157 }
 158
 159 float W_WeaponBit(float wpn)
 160 {
 161         return (get_weaponinfo(wpn)).weapons;
 162 }
 163
 164 float W_AmmoItemCode(float wpn)
 165 {
 166         return (get_weaponinfo(wpn)).items;
 167 }
 168
 169 void thrown_wep_think()
 170 {
 171         self.solid = SOLID_TRIGGER;
 172         self.owner = world;
 173         SUB_SetFade(self, time + 20, 1);
 174 }
 175
 176 // returns amount of ammo used as string, or -1 for failure, or 0 for no ammo count
 177 string W_ThrowNewWeapon(entity own, float wpn, float doreduce, vector org, vector velo)
 178 {
 179         entity oldself, wep;
 180         float wa, thisammo, i, j;
 181         string s;
 182         var .float ammofield;
 183
 184         wep = spawn();
 185
 186         setorigin(wep, org);
 187         wep.classname = "droppedweapon";
 188         wep.velocity = velo;
 189         wep.owner = wep.enemy = own;
 190         wep.classname = "droppedweapon";
 191         wep.flags |= FL_TOSSED;
 192         wep.colormap = own.colormap;
 193
 194         wa = W_AmmoItemCode(wpn);
 195         if(wa == IT_SUPERWEAPON || wa == 0)
 196         {
 197                 oldself = self;
 198                 self = wep;
 199                 weapon_defaultspawnfunc(wpn);
 200                 self = oldself;
 201                 if(startitem_failed)
 202                         return string_null;
 203                 wep.think = thrown_wep_think;
 204                 wep.nextthink = time + 0.5;
 205                 return "";
 206         }
 207         else
 208         {
 209                 s = "";
 210                 oldself = self;
 211                 self = wep;
 212                 weapon_defaultspawnfunc(wpn);
 213                 self = oldself;
 214                 if(startitem_failed)
 215                         return string_null;
 216                 if(doreduce)
 217                 {
 218                         for(i = 0, j = 1; i < 24; ++i, j *= 2)
 219                         {
 220                                 if(wa & j)
 221                                 {
 222                                         ammofield = Item_CounterField(j);
 223                                         thisammo = min(own.ammofield, wep.ammofield);
 224                                         wep.ammofield = thisammo;
 225                                         own.ammofield -= thisammo;
 226                                         s = strcat(s, " and ", ftos(thisammo), " ", Item_CounterFieldName(j));
 227                                 }
 228                         }
 229                         s = substring(s, 5, -1);
 230                 }
 231                 wep.think = thrown_wep_think;
 232                 wep.nextthink = time + 0.5;
 233                 return s;
 234         }
 235 }
 236
 237 float W_IsWeaponThrowable(float w)
 238 {
 239         float wb, wa;
 240         wb = W_WeaponBit(w);
 241         if(!wb)
 242                 return 0;
 243         wa = W_AmmoItemCode(w);
 244         if(start_weapons & wb)
 245         {
 246                 if(wa == IT_SUPERWEAPON && start_items & IT_UNLIMITED_SUPERWEAPONS)
 247                         return 0;
 248                 if(wa != IT_SUPERWEAPON && start_items & IT_UNLIMITED_WEAPON_AMMO)
 249                         return 0;
 250                 // start weapons that take no ammo can't be dropped (this prevents dropping the laser, as long as it continues to use no ammo)
 251                 if(wa == 0)
 252                         return 0;
 253         }
 254
 255         return 1;
 256 }
 257
 258 // toss current weapon
 259 void W_ThrowWeapon(vector velo, vector delta, float doreduce)
 260 {
 261         local float w, wb;
 262         string a;
 263
 264         w = self.weapon;
 265         if (w == 0)
 266                 return; // just in case
 267         if (g_weaponarena)
 268                 return;
 269         if (g_lms)
 270                 return;
 271         if (g_nixnex)
 272                 return;
 273         if (g_nexball && w == WEP_GRENADE_LAUNCHER)
 274                 return;
 275         if (!cvar("g_pickup_items"))
 276                 return;
 277         if(!W_IsWeaponThrowable(w))
 278                 return;
 279
 280         wb = W_WeaponBit(w);
 281         if(self.weapons & wb != wb)
 282                 return;
 283
 284         self.weapons &~= wb;
 285         W_SwitchWeapon_Force(self, w_getbestweapon(self));
 286         a = W_ThrowNewWeapon(self, w, doreduce, self.origin + delta, velo);
 287         if not(a)
 288                 return;
 289         if(self.health >= 1)
 290         {
 291                 if(a == "")
 292                         sprint(self, strcat("You dropped the ^2", W_Name(w), "\n"));
 293                 else
 294                         sprint(self, strcat("You dropped the ^2", W_Name(w), " with ", a, "\n"));
 295         }
 296 };
 297
 298 // Bringed back weapon frame
 299 void W_WeaponFrame()
 300 {
 301         if((arena_roundbased && time < warmup) || ((time < game_starttime) && !cvar("sv_ready_restart_after_countdown")))
 302                 return;
 303
 304         if (!self.weaponentity || self.health < 1)
 305                 return; // Dead player can't use weapons and injure impulse commands
 306
 307         if(!self.switchweapon)
 308         {
 309                 self.weapon = 0;
 310                 self.weaponentity.state = WS_CLEAR;
 311                 self.weaponname = "";
 312                 self.items &~= IT_AMMO;
 313                 return;
 314         }
 315
 316         makevectors(self.v_angle);
 317
 318         // Change weapon
 319         if (self.weapon != self.switchweapon)
 320         {
 321                 if (self.weaponentity.state == WS_CLEAR)
 322                 {
 323                         setanim(self, self.anim_draw, FALSE, TRUE, TRUE);
 324                         self.weaponentity.state = WS_RAISE;
 325                         weapon_action(self.switchweapon, WR_SETUP);
 326                         // VorteX: add player model weapon select frame here
 327                         // setcustomframe(PlayerWeaponRaise);
 328                         weapon_thinkf(WFRAME_IDLE, cvar("g_balance_weaponswitchdelay"), w_ready);
 329                         weapon_boblayer1(PLAYER_WEAPONSELECTION_SPEED, '0 0 0');
 330                 }
 331                 else if (self.weaponentity.state == WS_READY)
 332                 {
 333 #ifndef INDEPENDENT_ATTACK_FINISHED
 334                         if(ATTACK_FINISHED(self) <= time + frametime * 0.5)
 335                         {
 336 #endif
 337                         // UGLY WORKAROUND: play this on CHAN_WEAPON2 so it can't cut off fire sounds
 338                         sound (self, CHAN_WEAPON2, "weapons/weapon_switch.wav", VOL_BASE, ATTN_NORM);
 339                         self.weaponentity.state = WS_DROP;
 340                         // set up weapon switch think in the future, and start drop anim
 341                         weapon_thinkf(WFRAME_DONTCHANGE, cvar("g_balance_weaponswitchdelay"), w_clear);
 342                         weapon_boblayer1(PLAYER_WEAPONSELECTION_SPEED, PLAYER_WEAPONSELECTION_RANGE);
 343 #ifndef INDEPENDENT_ATTACK_FINISHED
 344                         }
 345 #endif
 346                 }
 347         }
 348
 349         float wb;
 350         wb = W_WeaponBit(self.weapon);
 351
 352         // call the think code which may fire the weapon
 353         // and do so multiple times to resolve framerate dependency issues if the
 354         // server framerate is very low and the weapon fire rate very high
 355         local float c;
 356         c = 0;
 357         while (c < 5)
 358         {
 359                 c = c + 1;
 360                 if(wb && ((self.weapons & wb) == 0))
 361                 {
 362                         W_SwitchWeapon_Force(self, w_getbestweapon(self));
 363                         wb = 0;
 364                 }
 365                 if(wb)
 366                         weapon_action(self.weapon, WR_THINK);
 367                 if (time + frametime * 0.5 >= self.weapon_nextthink)
 368                 {
 369                         if(self.weapon_think)
 370                                 self.weapon_think();
 371                         else
 372                                 bprint("\{1}^1ERROR: undefined weapon think function for ", self.netname, "\n");
 373                 }
 374         }
 375
 376         // don't let attack_finished fall behind when not firing (must be after weapon_setup calls!)
 377         //if (ATTACK_FINISHED(self) < time)
 378         //      ATTACK_FINISHED(self) = time;
 379
 380         //if (self.weapon_nextthink < time)
 381         //      self.weapon_nextthink = time;
 382
 383         // update currentammo incase it has changed
 384 #if 0
 385         if (self.items & IT_CELLS)
 386                 self.currentammo = self.ammo_cells;
 387         else if (self.items & IT_ROCKETS)
 388                 self.currentammo = self.ammo_rockets;
 389         else if (self.items & IT_NAILS)
 390                 self.currentammo = self.ammo_nails;
 391         else if (self.items & IT_SHELLS)
 392                 self.currentammo = self.ammo_shells;
 393         else
 394                 self.currentammo = 1;
 395 #endif
 396 };
 397
 398 float nixnex_weapon;
 399 float nixnex_nextchange;
 400 float nixnex_nextweapon;
 401 .float nixnex_lastchange_id;
 402 .float nixnex_lastinfotime;
 403 .float nixnex_nextincr;
 404
 405 float NixNex_CanChooseWeapon(float wpn)
 406 {
 407         entity e;
 408         e = get_weaponinfo(wpn);
 409         if(!e.weapons) // skip dummies
 410                 return FALSE;
 411         if(g_weaponarena)
 412         {
 413                 if not(g_weaponarena & e.weapons)
 414                         return FALSE;
 415         }
 416         else
 417         {
 418                 if(wpn == WEP_LASER && g_nixnex_with_laser)
 419                         return FALSE;
 420                 if not(e.spawnflags & WEPSPAWNFLAG_NORMAL)
 421                         return FALSE;
 422         }
 423         return TRUE;
 424 }
 425 void Nixnex_ChooseNextWeapon()
 426 {
 427         float j;
 428         RandomSelection_Init();
 429         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 430                 if(NixNex_CanChooseWeapon(j))
 431                         RandomSelection_Add(world, j, string_null, 1, (j != nixnex_weapon));
 432         nixnex_nextweapon = RandomSelection_chosen_float;
 433 }
 434
 435 void Nixnex_GiveCurrentWeapon()
 436 {
 437         float dt;
 438         if(g_nixnex)
 439         {
 440                 if(!nixnex_nextweapon)
 441                         Nixnex_ChooseNextWeapon();
 442
 443                 dt = ceil(nixnex_nextchange - time);
 444
 445                 if(dt <= 0)
 446                 {
 447                         nixnex_weapon = nixnex_nextweapon;
 448                         nixnex_nextweapon = 0;
 449                         nixnex_nextchange = time + cvar("g_balance_nixnex_roundtime");
 450                         //weapon_action(nixnex_weapon, WR_PRECACHE); // forget it, too slow
 451                 }
 452
 453                 if(nixnex_nextchange != self.nixnex_lastchange_id) // this shall only be called once per round!
 454                 {
 455                         self.nixnex_lastchange_id = nixnex_nextchange;
 456                         if (self.items & IT_UNLIMITED_WEAPON_AMMO)
 457                         {
 458                                 self.ammo_shells = cvar("g_pickup_shells_max");
 459                                 self.ammo_nails = cvar("g_pickup_nails_max");
 460                                 self.ammo_rockets = cvar("g_pickup_rockets_max");
 461                                 self.ammo_cells = cvar("g_pickup_cells_max");
 462                                 self.ammo_fuel = cvar("g_pickup_fuel_max");
 463                         }
 464                         else
 465                         {
 466                                 self.ammo_shells = cvar("g_balance_nixnex_ammo_shells");
 467                                 self.ammo_nails = cvar("g_balance_nixnex_ammo_nails");
 468                                 self.ammo_rockets = cvar("g_balance_nixnex_ammo_rockets");
 469                                 self.ammo_cells = cvar("g_balance_nixnex_ammo_cells");
 470                                 self.ammo_fuel = cvar("g_balance_nixnex_ammo_fuel");
 471                         }
 472                         self.nixnex_nextincr = time + cvar("g_balance_nixnex_incrtime");
 473                         if(dt >= 1 && dt <= 5)
 474                                 self.nixnex_lastinfotime = -42;
 475                         else
 476                                 centerprint(self, strcat("\n\n^2Active weapon: ^3", W_Name(nixnex_weapon)));
 477                 }
 478                 if(self.nixnex_lastinfotime != dt)
 479                 {
 480                         self.nixnex_lastinfotime = dt; // initial value 0 should count as "not seen"
 481                         if(dt >= 1 && dt <= 5)
 482                                 centerprint(self, strcat("^3", ftos(dt), "^2 seconds until weapon change...\n\nNext weapon: ^3", W_Name(nixnex_nextweapon), "\n"));
 483                 }
 484
 485                 if(!(self.items & IT_UNLIMITED_WEAPON_AMMO) && time > self.nixnex_nextincr)
 486                 {
 487                         self.ammo_shells = self.ammo_shells + cvar("g_balance_nixnex_ammoincr_shells");
 488                         self.ammo_nails = self.ammo_nails + cvar("g_balance_nixnex_ammoincr_nails");
 489                         self.ammo_rockets = self.ammo_rockets + cvar("g_balance_nixnex_ammoincr_rockets");
 490                         self.ammo_cells = self.ammo_cells + cvar("g_balance_nixnex_ammoincr_cells");
 491                         self.ammo_fuel = self.ammo_fuel + cvar("g_balance_nixnex_ammoincr_fuel");
 492                         self.nixnex_nextincr = time + cvar("g_balance_nixnex_incrtime");
 493                 }
 494
 495                 self.weapons = 0;
 496                 if(g_nixnex_with_laser)
 497                         self.weapons = self.weapons | WEPBIT_LASER;
 498                 self.weapons = self.weapons | W_WeaponBit(nixnex_weapon);
 499
 500                 if(self.switchweapon != nixnex_weapon)
 501                         if(!client_hasweapon(self, self.switchweapon, TRUE, FALSE))
 502                                 if(client_hasweapon(self, nixnex_weapon, TRUE, FALSE))
 503                                         W_SwitchWeapon(nixnex_weapon);
 504         }
 505 }