data/qcsrc/server/cl_weapons.qc

   1
   2 // generic weapons table
   3 // add new weapons here
   4 float(float wpn, float wrequest) weapon_action =
   5 {
   6         if (wpn == WEP_LASER)
   7                 return w_laser(wrequest);
   8         else if (wpn == WEP_SHOTGUN)
   9                 return w_shotgun(wrequest);
  10         else if (wpn == WEP_UZI)
  11                 return w_uzi(wrequest);
  12         else if (wpn == WEP_GRENADE_LAUNCHER)
  13                 return w_glauncher(wrequest);
  14         else if (wpn == WEP_ELECTRO)
  15                 return w_electro(wrequest);
  16         else if (wpn == WEP_CRYLINK)
  17                 return w_crylink(wrequest);
  18         else if (wpn == WEP_NEX)
  19                 return w_nex(wrequest);
  20         else if (wpn == WEP_HAGAR)
  21                 return w_hagar(wrequest);
  22         else if (wpn == WEP_ROCKET_LAUNCHER)
  23                 return w_rlauncher(wrequest);
  24         return FALSE;
  25 };
  26
  27 // think function for tossed weapons
  28 void() thrown_wep_think
  29 {
  30         self.solid = SOLID_TRIGGER;
  31         self.owner = world;
  32         SUB_SetFade(self, time + 20, 1);
  33         setorigin(self, self.origin);
  34 };
  35
  36 // toss current weapon
  37 void() W_ThrowWeapon
  38 {
  39         local float w, ammo;
  40         local entity wep, e;
  41
  42         e = self;
  43         wep = spawn();
  44         self = wep;
  45         w = e.weapon;
  46         setorigin(wep, e.origin);
  47         makevectors(e.angles);
  48         wep.classname = "droppedweapon";
  49         wep.velocity = e.velocity * 0.5 + v_forward * 750;
  50         SUB_SetFade(wep, time + 20, 1);
  51
  52         if(w == WEP_SHOTGUN)
  53         {
  54                 w = IT_SHOTGUN;
  55                 if(!(e.items & w))
  56                 {
  57                         remove(wep);
  58                         return;
  59                 }
  60                 weapon_shotgun();
  61                 ammo = min(e.ammo_shells, wep.ammo_shells);
  62                 wep.ammo_shells = ammo;
  63                 e.ammo_shells -= ammo;
  64         }
  65         else if(w == WEP_UZI)
  66         {
  67                 w = IT_UZI;
  68                 if(!(e.items & w))
  69                 {
  70                         remove(wep);
  71                         return;
  72                 }
  73                 weapon_uzi();
  74                 ammo = min(e.ammo_nails, wep.ammo_nails);
  75                 wep.ammo_nails = ammo;
  76                 e.ammo_nails -= ammo;
  77         }
  78         else if(w == WEP_GRENADE_LAUNCHER)
  79         {
  80                 w = IT_GRENADE_LAUNCHER;
  81                 if(!(e.items & w))
  82                 {
  83                         remove(wep);
  84                         return;
  85                 }
  86                 weapon_grenadelauncher();
  87                 ammo = min(e.ammo_rockets, wep.ammo_rockets);
  88                 wep.ammo_rockets = ammo;
  89                 e.ammo_rockets -= ammo;
  90         }
  91         else if(w == WEP_ELECTRO)
  92         {
  93                 w = IT_ELECTRO;
  94                 if(!(e.items & w))
  95                 {
  96                         remove(wep);
  97                         return;
  98                 }
  99                 weapon_electro();
 100                 ammo = min(e.ammo_cells, wep.ammo_cells);
 101                 wep.ammo_cells = ammo;
 102                 e.ammo_cells -= ammo;
 103         }
 104         else if(w == WEP_CRYLINK)
 105         {
 106                 w = IT_CRYLINK;
 107                 if(!(e.items & w))
 108                 {
 109                         remove(wep);
 110                         return;
 111                 }
 112                 weapon_crylink();
 113                 ammo = min(e.ammo_cells, wep.ammo_cells);
 114                 wep.ammo_cells = ammo;
 115                 e.ammo_cells -= ammo;
 116         }
 117         else if(w == WEP_NEX)
 118         {
 119                 w = IT_NEX;
 120                 if(!(e.items & w))
 121                 {
 122                         remove(wep);
 123                         return;
 124                 }
 125                 weapon_nex();
 126                 ammo = min(e.ammo_cells, wep.ammo_cells);
 127                 wep.ammo_cells = ammo;
 128                 e.ammo_cells -= ammo;
 129         }
 130         else if(w == WEP_HAGAR)
 131         {
 132                 w = IT_HAGAR;
 133                 if(!(e.items & w))
 134                 {
 135                         remove(wep);
 136                         return;
 137                 }
 138                 weapon_hagar();
 139                 ammo = min(e.ammo_rockets, wep.ammo_rockets);
 140                 wep.ammo_rockets = ammo;
 141                 e.ammo_rockets -= ammo;
 142         }
 143         else if(w == WEP_ROCKET_LAUNCHER)
 144         {
 145                 w = IT_ROCKET_LAUNCHER;
 146                 if(!(e.items & w))
 147                 {
 148                         remove(wep);
 149                         return;
 150                 }
 151                 weapon_rocketlauncher();
 152                 ammo = min(e.ammo_rockets, wep.ammo_rockets);
 153                 wep.ammo_rockets = ammo;
 154                 e.ammo_rockets -= ammo;
 155         }
 156
 157         if(e.items & w)
 158                 sprint(e, strcat("You dropped the ^2", wep.netname, "\n"));
 159         wep.owner = e;
 160         setorigin(wep, wep.origin);
 161         wep.nextthink = time + 0.5;
 162         wep.think = thrown_wep_think;
 163         wep.classname = "droppedweapon";
 164         e.items = e.items - (e.items & w);
 165         e.switchweapon = w_getbestweapon(e);
 166         wep.colormap = e.colormap;
 167         if (e.switchweapon != e.weapon)
 168                 e.cnt = e.weapon;
 169         self = e;
 170 };
 171
 172 // switch between weapons
 173 void(float imp) W_SwitchWeapon
 174 {
 175         if (client_hasweapon(self, imp, TRUE, TRUE))
 176         {
 177                 self.cnt = self.weapon;
 178                 self.switchweapon = imp;
 179         }
 180 };
 181
 182 // next weapon
 183 void() W_NextWeapon =
 184 {
 185         local float weaponwant, maxtries;
 186
 187         maxtries = WEP_LAST;
 188
 189         weaponwant = self.switchweapon + 1;
 190         if (weaponwant < WEP_FIRST)
 191                 weaponwant = WEP_LAST;
 192         if (weaponwant > WEP_LAST)
 193                 weaponwant = WEP_FIRST;
 194         while(!client_hasweapon(self, weaponwant, TRUE, FALSE))
 195         {
 196                 if(!maxtries)
 197                         return;
 198
 199                 maxtries -= 1;
 200                 weaponwant = weaponwant + 1;
 201                 if (weaponwant < WEP_FIRST)
 202                         weaponwant = WEP_LAST;
 203                 if (weaponwant > WEP_LAST)
 204                         weaponwant = WEP_FIRST;
 205         }
 206         self.cnt = self.weapon;
 207         self.switchweapon = weaponwant;
 208 };
 209
 210 // prev weapon
 211 void() W_PreviousWeapon =
 212 {
 213         local float weaponwant, maxtries;
 214
 215         maxtries = WEP_LAST;
 216
 217         weaponwant = self.switchweapon - 1;
 218         if (weaponwant < WEP_FIRST)
 219                 weaponwant = WEP_LAST;
 220         if (weaponwant > WEP_LAST)
 221                 weaponwant = WEP_FIRST;
 222         while(!client_hasweapon(self, weaponwant, TRUE, FALSE))
 223         {
 224                 if(!maxtries)
 225                         return;
 226
 227                 maxtries -= 1;
 228                 weaponwant = weaponwant - 1;
 229                 if (weaponwant < WEP_FIRST)
 230                         weaponwant = WEP_LAST;
 231                 if (weaponwant > WEP_LAST)
 232                         weaponwant = WEP_FIRST;
 233         }
 234         self.cnt = self.weapon;
 235         self.switchweapon = weaponwant;
 236 };
 237
 238 // Bringed back weapon frame
 239 void() W_WeaponFrame =
 240 {
 241         if(arena_roundbased)
 242         if(time < self.arena_warmup_end)
 243                 return;
 244
 245         if (!self.weaponentity || self.health < 1)
 246                 return; // Dead player can't use weapons and injure impulse commands
 247
 248         if(!self.switchweapon)
 249         {
 250                 self.weapon = 0;
 251                 self.weaponentity.state = WS_CLEAR;
 252                 return;
 253         }
 254
 255         makevectors(self.v_angle);
 256
 257         // Change weapon
 258         if (self.weapon != self.switchweapon)
 259         {
 260                 if (self.weaponentity.state == WS_CLEAR)
 261                 {
 262                         self.weaponentity.state = WS_RAISE;
 263                         weapon_action(self.switchweapon, WR_SETUP);
 264                         // VorteX: add player model weapon select frame here
 265                         // setcustomframe(PlayerWeaponRaise);
 266                         weapon_thinkf(WFRAME_IDLE, cvar("g_balance_weaponswitchdelay"), w_ready);
 267                         weapon_boblayer1(PLAYER_WEAPONSELECTION_SPEED, '0 0 0');
 268                 }
 269                 else if (self.weaponentity.state == WS_READY)
 270                 {
 271                         sound (self, CHAN_WEAPON, "weapons/weapon_switch.ogg", 1, ATTN_NORM);
 272                         self.weaponentity.state = WS_DROP;
 273                         // set up weapon switch think in the future, and start drop anim
 274                         weapon_thinkf(WFRAME_IDLE, cvar("g_balance_weaponswitchdelay"), w_clear);
 275                         weapon_boblayer1(PLAYER_WEAPONSELECTION_SPEED, PLAYER_WEAPONSELECTION_RANGE);
 276                 }
 277         }
 278
 279         // call the think code which may fire the weapon
 280         weapon_action(self.weapon, WR_THINK);
 281
 282         // update currentammo incase it has changed
 283         if (self.items & IT_CELLS)
 284                 self.currentammo = self.ammo_cells;
 285         else if (self.items & IT_ROCKETS)
 286                 self.currentammo = self.ammo_rockets;
 287         else if (self.items & IT_NAILS)
 288                 self.currentammo = self.ammo_nails;
 289         else if (self.items & IT_SHELLS)
 290                 self.currentammo = self.ammo_shells;
 291         else
 292                 self.currentammo = 1;
 293
 294         // do weapon think
 295         if (time >= self.weapon_nextthink)
 296                 if (self.weapon_nextthink > 0)
 297                         self.weapon_think();
 298 };
 299
 300 float nixnex_weapon;
 301 float nixnex_nextchange;
 302 float nixnex_nextweapon;
 303 .float nixnex_lastchange_id;
 304 .float nixnex_lastinfotime;
 305 .float nixnex_nextincr;
 306
 307 void Nixnex_ChooseNextWeapon()
 308 {
 309         float numberof, id;
 310         numberof = WEP_LAST - WEP_FIRST; // all but the current one
 311         if(cvar("g_nixnex_with_laser"))
 312                 numberof = numberof - 1;
 313         id = WEP_FIRST + ceil(random() * numberof) - 1;
 314
 315         if(cvar("g_nixnex_with_laser")) // skip the laser if needed
 316                 id = id + 1;
 317
 318         if(id >= nixnex_weapon) // skip the current weapon
 319                 id = id + 1;
 320
 321         if(id < WEP_FIRST) // can't happen, but to be sure...
 322         {
 323                 dprint("Won't happen (id < WEP_FIRST)\n");
 324                 id = WEP_FIRST;
 325         }
 326         if(id > WEP_LAST) // either
 327         {
 328                 dprint("Won't happen (id > WEP_LAST)\n");
 329                 id = WEP_LAST;
 330         }
 331
 332         nixnex_nextweapon = id;
 333 }
 334
 335 string W_Name(float weaponid)
 336 {
 337         if(weaponid == WEP_LASER)             return "Laser";
 338         if(weaponid == WEP_UZI)               return "Machine Gun";
 339         if(weaponid == WEP_SHOTGUN)           return "Shotgun";
 340         if(weaponid == WEP_GRENADE_LAUNCHER)  return "Mortar";
 341         if(weaponid == WEP_ELECTRO)           return "Electro";
 342         if(weaponid == WEP_NEX)               return "Nex";
 343         if(weaponid == WEP_HAGAR)             return "Hagar";
 344         if(weaponid == WEP_ROCKET_LAUNCHER)   return "Rocket Launcher";
 345         if(weaponid == WEP_CRYLINK)           return "Crylink";
 346         return "@!#%'n Tuba";
 347 }
 348
 349 void Nixnex_GiveCurrentWeapon()
 350 {
 351         float dt;
 352         if(cvar("g_nixnex"))
 353         {
 354                 if(!nixnex_nextweapon)
 355                         Nixnex_ChooseNextWeapon();
 356
 357                 dt = ceil(nixnex_nextchange - time);
 358
 359                 if(dt <= 0)
 360                 {
 361                         nixnex_weapon = nixnex_nextweapon;
 362                         nixnex_nextweapon = 0;
 363                         nixnex_nextchange = time + cvar("g_balance_nixnex_roundtime");
 364                 }
 365
 366                 if(nixnex_nextchange != self.nixnex_lastchange_id) // this shall only be called once per round!
 367                 {
 368                         self.nixnex_lastchange_id = nixnex_nextchange;
 369                         if (cvar("g_use_ammunition"))
 370                         {
 371                                 self.ammo_shells = cvar("g_balance_nixnex_ammo_shells");
 372                                 self.ammo_nails = cvar("g_balance_nixnex_ammo_nails");
 373                                 self.ammo_rockets = cvar("g_balance_nixnex_ammo_rockets");
 374                                 self.ammo_cells = cvar("g_balance_nixnex_ammo_cells");
 375                         }
 376                         else
 377                         {
 378                                 self.ammo_shells = 999;
 379                                 self.ammo_nails = 999;
 380                                 self.ammo_rockets = 999;
 381                                 self.ammo_cells = 999;
 382                         }
 383                         self.nixnex_nextincr = time + cvar("g_balance_nixnex_incrtime");
 384                         if(dt >= 1 && dt <= 5)
 385                                 self.nixnex_lastinfotime = -42;
 386                         else
 387                                 centerprint(self, strcat("\n\n^2Active weapon: ^3", W_Name(nixnex_weapon), "\n"));
 388                 }
 389                 if(self.nixnex_lastinfotime != dt)
 390                 {
 391                         self.nixnex_lastinfotime = dt; // initial value 0 should count as "not seen"
 392                         if(dt >= 1 && dt <= 5)
 393                                 centerprint(self, strcat("^3", ftos(dt), "^2 seconds until weapon change...\n\nNext weapon: ^3", W_Name(nixnex_nextweapon), "\n"));
 394                 }
 395
 396                 if(cvar("g_use_ammunition") && time > self.nixnex_nextincr)
 397                 {
 398                         self.ammo_shells = self.ammo_shells + cvar("g_balance_nixnex_ammoincr_shells");
 399                         self.ammo_nails = self.ammo_nails + cvar("g_balance_nixnex_ammoincr_nails");
 400                         self.ammo_rockets = self.ammo_rockets + cvar("g_balance_nixnex_ammoincr_rockets");
 401                         self.ammo_cells = self.ammo_cells + cvar("g_balance_nixnex_ammoincr_cells");
 402                         self.nixnex_nextincr = time + cvar("g_balance_nixnex_incrtime");
 403                 }
 404
 405                 self.items = self.items - (self.items & (IT_LASER | IT_SHOTGUN | IT_UZI | IT_GRENADE_LAUNCHER | IT_ELECTRO | IT_CRYLINK | IT_NEX | IT_HAGAR | IT_ROCKET_LAUNCHER));
 406                 if(cvar("g_nixnex_with_laser"))
 407                         self.items = self.items + IT_LASER;
 408                 self.items = self.items - (self.items & weapon_translateindextoflag(nixnex_weapon)) + weapon_translateindextoflag(nixnex_weapon);
 409
 410                 if(self.switchweapon != nixnex_weapon)
 411                         if(!client_hasweapon(self, self.switchweapon, TRUE, FALSE))
 412                                 if(client_hasweapon(self, nixnex_weapon, TRUE, FALSE))
 413                                         W_SwitchWeapon(nixnex_weapon);
 414         }
 415 }
 416