data/qcsrc/server/cl_player.qc

   1
   2 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
   3 // merged player_run and player_stand to player_anim
   4 // added death animations to player_anim
   5 // can now spawn thrown weapons from anywhere, not just from players
   6 // thrown weapons now fade out after 20 seconds
   7 // created PlayerGib function
   8 // PlayerDie no longer uses hitloc or damage
   9 // PlayerDie now supports dying animations as well as gibbing
  10 // cleaned up PlayerDie a lot
  11 // added CopyBody
  12
  13 .entity pusher;
  14 .float pushltime;
  15
  16 void CopyBody(float keepvelocity)
  17 {
  18         local entity oldself;
  19         if (self.effects & EF_NODRAW)
  20                 return;
  21         oldself = self;
  22         self = spawn();
  23         self.enemy = oldself;
  24         self.lip = oldself.lip;
  25         self.colormap = oldself.colormap;
  26         self.iscreature = oldself.iscreature;
  27         self.angles = oldself.angles;
  28         self.avelocity = oldself.avelocity;
  29         self.classname = "body";
  30         self.damageforcescale = oldself.damageforcescale;
  31         self.effects = oldself.effects;
  32         self.event_damage = oldself.event_damage;
  33         self.animstate_startframe = oldself.animstate_startframe;
  34         self.animstate_numframes = oldself.animstate_numframes;
  35         self.animstate_framerate = oldself.animstate_framerate;
  36         self.animstate_starttime = oldself.animstate_starttime;
  37         self.animstate_endtime = oldself.animstate_endtime;
  38         self.animstate_override = oldself.animstate_override;
  39         self.animstate_looping = oldself.animstate_looping;
  40         self.frame = oldself.frame;
  41         self.dead_frame = oldself.dead_frame;
  42         self.pain_finished = oldself.pain_finished;
  43         self.health = oldself.health;
  44         self.armorvalue = oldself.armorvalue;
  45         self.armortype = oldself.armortype;
  46         self.model = oldself.model;
  47         self.modelindex = oldself.modelindex;
  48         self.movetype = oldself.movetype;
  49         self.nextthink = oldself.nextthink;
  50         self.skin = oldself.skin;
  51         self.solid = oldself.solid;
  52         self.takedamage = oldself.takedamage;
  53         self.think = oldself.think;
  54         self.gibrandom = oldself.gibrandom;
  55         self.customizeentityforclient = oldself.customizeentityforclient;
  56         if (keepvelocity == 1)
  57                 self.velocity = oldself.velocity;
  58         self.oldvelocity = self.velocity;
  59         self.fade_time = oldself.fade_time;
  60         self.fade_rate = oldself.fade_rate;
  61         //self.weapon = oldself.weapon;
  62         setorigin(self, oldself.origin);
  63         setsize(self, oldself.mins, oldself.maxs);
  64         self.oldorigin = oldself.origin;
  65         self = oldself;
  66 }
  67
  68 float animparseerror;
  69 vector(float animfile) animparseline =
  70 {
  71         local string line;
  72         local float c;
  73         local vector anim;
  74         if (animfile < 0)
  75                 return '0 1 2';
  76         line = fgets(animfile);
  77         c = tokenize(line);
  78         if (c != 3)
  79         {
  80                 animparseerror = TRUE;
  81                 return '0 1 2';
  82         }
  83         anim_x = stof(argv(0));
  84         anim_y = stof(argv(1));
  85         anim_z = stof(argv(2));
  86         // don't allow completely bogus values
  87         if (anim_x < 0 || anim_y < 1 || anim_z < 0.001)
  88                 anim = '0 1 2';
  89         return anim;
  90 };
  91
  92 void() player_setupanimsformodel =
  93 {
  94         local string animfilename;
  95         local float animfile;
  96         // defaults for legacy .zym models without animinfo files
  97         self.anim_die1 = '0 1 0.5'; // 2 seconds
  98         self.anim_die2 = '1 1 0.5'; // 2 seconds
  99         self.anim_draw = '2 1 3'; // TODO: analyze models and set framerate
 100         self.anim_duck = '3 1 100'; // this anim seems bogus in most models, so make it play VERY briefly!
 101         self.anim_duckwalk = '4 1 1';
 102         self.anim_duckjump = '5 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 103         self.anim_duckidle = '6 1 1';
 104         self.anim_idle = '7 1 1';
 105         self.anim_jump = '8 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 106         self.anim_pain1 = '9 1 2'; // 0.5 seconds
 107         self.anim_pain2 = '10 1 2'; // 0.5 seconds
 108         self.anim_shoot = '11 1 5'; // TODO: analyze models and set framerate
 109         self.anim_taunt = '12 1 1'; // FIXME?  there is no code using this anim
 110         self.anim_run = '13 1 1';
 111         self.anim_runbackwards = '14 1 1';
 112         self.anim_strafeleft = '15 1 1';
 113         self.anim_straferight = '16 1 1';
 114         self.anim_dead1 = '17 1 1';
 115         self.anim_dead2 = '18 1 1';
 116         self.anim_forwardright = '19 1 1';
 117         self.anim_forwardleft = '20 1 1';
 118         self.anim_backright = '21 1 1';
 119         self.anim_backleft  = '22 1 1';
 120         animparseerror = FALSE;
 121         animfilename = strcat(self.model, ".animinfo");
 122         animfile = fopen(animfilename, FILE_READ);
 123         if (animfile >= 0)
 124         {
 125                 self.anim_die1         = animparseline(animfile);
 126                 self.anim_die2         = animparseline(animfile);
 127                 self.anim_draw         = animparseline(animfile);
 128                 self.anim_duck         = animparseline(animfile);
 129                 self.anim_duckwalk     = animparseline(animfile);
 130                 self.anim_duckjump     = animparseline(animfile);
 131                 self.anim_duckidle     = animparseline(animfile);
 132                 self.anim_idle         = animparseline(animfile);
 133                 self.anim_jump         = animparseline(animfile);
 134                 self.anim_pain1        = animparseline(animfile);
 135                 self.anim_pain2        = animparseline(animfile);
 136                 self.anim_shoot        = animparseline(animfile);
 137                 self.anim_taunt        = animparseline(animfile);
 138                 self.anim_run          = animparseline(animfile);
 139                 self.anim_runbackwards = animparseline(animfile);
 140                 self.anim_strafeleft   = animparseline(animfile);
 141                 self.anim_straferight  = animparseline(animfile);
 142                 self.anim_forwardright = animparseline(animfile);
 143                 self.anim_forwardleft  = animparseline(animfile);
 144                 self.anim_backright    = animparseline(animfile);
 145                 self.anim_backleft     = animparseline(animfile);
 146                 fclose(animfile);
 147
 148                 // derived anims
 149                 self.anim_dead1 = '0 1 1' + '1 0 0' * (self.anim_die1_x + self.anim_die1_y - 1);
 150                 self.anim_dead2 = '0 1 1' + '1 0 0' * (self.anim_die2_x + self.anim_die2_y - 1);
 151
 152                 if (animparseerror)
 153                         print("Parse error in ", animfilename, ", some player animations are broken\n");
 154         }
 155         else
 156                 dprint("File ", animfilename, " not found, assuming legacy .zym model animation timings\n");
 157         // reset animstate now
 158         player_setanim(self.anim_idle, TRUE, FALSE, TRUE);
 159 };
 160
 161 void(vector anim, float looping, float override, float restart) player_setanim =
 162 {
 163         if (!restart)
 164         if (anim_x == self.animstate_startframe)
 165         if (anim_y == self.animstate_numframes)
 166         if (anim_z == self.animstate_framerate)
 167                 return;
 168         self.animstate_startframe = anim_x;
 169         self.animstate_numframes = anim_y;
 170         self.animstate_framerate = anim_z;
 171         self.animstate_starttime = time;
 172         self.animstate_endtime = time + self.animstate_numframes / self.animstate_framerate;
 173         self.animstate_looping = looping;
 174         self.animstate_override = override;
 175         self.frame = self.animstate_startframe;
 176 };
 177
 178 void() player_updateframe =
 179 {
 180         if (time >= self.animstate_endtime)
 181         {
 182                 if (self.animstate_looping)
 183                 {
 184                         self.animstate_starttime = self.animstate_endtime;
 185                         self.animstate_endtime = self.animstate_endtime + self.animstate_numframes / self.animstate_framerate;
 186                 }
 187                 self.animstate_override = FALSE;
 188         }
 189         self.frame = self.animstate_startframe + bound(0, (time - self.animstate_starttime) * self.animstate_framerate, self.animstate_numframes - 1);
 190 };
 191
 192 void player_anim (void)
 193 {
 194         player_updateframe();
 195
 196         if (self.deadflag != DEAD_NO)
 197         {
 198                 if (time > self.animstate_endtime)
 199                 {
 200                         if (self.maxs_z > 5)
 201                         {
 202                                 self.maxs_z = 5;
 203                                 setsize(self, self.mins, self.maxs);
 204                         }
 205                         self.frame = self.dead_frame;
 206                 }
 207                 return;
 208         }
 209
 210         if (!self.animstate_override)
 211         {
 212                 if (!(self.flags & FL_ONGROUND))
 213                 {
 214                         if (self.crouch)
 215                                 player_setanim(self.anim_duckjump, FALSE, TRUE, FALSE);
 216                         else
 217                                 player_setanim(self.anim_jump, FALSE, TRUE, FALSE);
 218                 }
 219                 else if (self.crouch)
 220                 {
 221                         if (self.movement_x * self.movement_x + self.movement_y * self.movement_y > 20)
 222                                 player_setanim(self.anim_duckwalk, TRUE, FALSE, FALSE);
 223                         else
 224                                 player_setanim(self.anim_duckidle, TRUE, FALSE, FALSE);
 225                 }
 226                 else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
 227                 {
 228                         if (self.movement_x > 0 && self.movement_y == 0)
 229                                 player_setanim(self.anim_run, TRUE, FALSE, FALSE);
 230                         else if (self.movement_x < 0 && self.movement_y == 0)
 231                                 player_setanim(self.anim_runbackwards, TRUE, FALSE, FALSE);
 232                         else if (self.movement_x == 0 && self.movement_y > 0)
 233                                 player_setanim(self.anim_straferight, TRUE, FALSE, FALSE);
 234                         else if (self.movement_x == 0 && self.movement_y < 0)
 235                                 player_setanim(self.anim_strafeleft, TRUE, FALSE, FALSE);
 236                         else if (self.movement_x > 0 && self.movement_y > 0)
 237                                 player_setanim(self.anim_forwardright, TRUE, FALSE, FALSE);
 238                         else if (self.movement_x > 0 && self.movement_y < 0)
 239                                 player_setanim(self.anim_forwardleft, TRUE, FALSE, FALSE);
 240                         else if (self.movement_x < 0 && self.movement_y > 0)
 241                                 player_setanim(self.anim_backright, TRUE, FALSE, FALSE);
 242                         else if (self.movement_x < 0 && self.movement_y < 0)
 243                                 player_setanim(self.anim_backleft, TRUE, FALSE, FALSE);
 244                         else
 245                                 player_setanim(self.anim_run, TRUE, FALSE, FALSE);
 246                 }
 247                 else
 248                         player_setanim(self.anim_idle, TRUE, FALSE, FALSE);
 249         }
 250 }
 251 //End change by Supajoe on 11:44 PM EST 11/16/03 (Subject: Player animations)
 252
 253 void SpawnThrownWeapon (vector org, float w)
 254 {
 255         W_ThrowWeapon(randomvec() * 100 + '0 0 200', org - self.origin, FALSE);
 256 }
 257
 258 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 259 {
 260         local float take, save;
 261         pointparticles(particleeffectnum("blood"), hitloc, force, bound(0, damage, 200));
 262         // damage resistance (ignore most of the damage from a bullet or similar)
 263         damage = max(damage - 5, 1);
 264
 265         save = bound(0, damage * cvar("g_balance_armor_blockpercent"), self.armorvalue);
 266         take = bound(0, damage - save, damage);
 267
 268         if (save > 10)
 269                 sound (self, CHAN_IMPACT, "misc/armorimpact.wav", 1, ATTN_NORM);
 270         else if (take > 30)
 271                 sound (self, CHAN_IMPACT, "misc/bodyimpact2.wav", 1, ATTN_NORM);
 272         else if (take > 10)
 273                 sound (self, CHAN_IMPACT, "misc/bodyimpact1.wav", 1, ATTN_NORM);
 274
 275         if (take > 50)
 276                 TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.1,1);
 277         if (take > 100)
 278                 TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.2,1);
 279
 280         if (!(self.flags & FL_GODMODE))
 281         {
 282                 self.armorvalue = self.armorvalue - save;
 283                 self.health = self.health - take;
 284                 // pause regeneration for 5 seconds
 285                 self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
 286         }
 287         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 288         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 289         self.dmg_inflictor = inflictor;
 290
 291         if (self.health <= -50)
 292         {
 293                 // don't use any animations as a gib
 294                 self.frame = 0;
 295                 self.dead_frame = 0;
 296                 // view just above the floor
 297                 self.view_ofs = '0 0 4';
 298
 299                 // make a juicy mess
 300                 local float multiplier;
 301                 multiplier = 1;
 302                 if (cvar("ekg"))
 303                         multiplier = 5;
 304                 te_bloodshower (self.origin + self.mins, self.origin + self.maxs, 1200 * multiplier, 1000);
 305
 306                 // make a meaty mess
 307                 TossGib (self, "models/gibs/eye.md3", self.origin + self.view_ofs, self.velocity + randomvec() * 150,0);
 308                 TossGib (world, "models/gibs/bloodyskull.md3", self.origin + self.view_ofs, self.velocity,0);
 309
 310                 local float c;
 311                 c = 0;
 312                 while (c < multiplier)
 313                 {
 314                         c = c + 1;
 315                         //TossGib (world, "models/gibs/gib1.md3", self.origin, self.velocity + randomvec() * 450,0);
 316                         //TossGib (world, "models/gibs/gib2.md3", self.origin, self.velocity + randomvec() * 450,0);
 317                         //TossGib (world, "models/gibs/gib3.md3", self.origin, self.velocity + randomvec() * 450,0);
 318                         //TossGib (world, "models/gibs/gib4.md3", self.origin, self.velocity + randomvec() * 450,0);
 319                         //TossGib (world, "models/gibs/gib5.md3", self.origin, self.velocity + randomvec() * 450,0);
 320                         //TossGib (world, "models/gibs/gib6.md3", self.origin, self.velocity + randomvec() * 450,0);
 321
 322                         TossGib (world, "models/gibs/arm.md3", self.origin + self.view_ofs, self.velocity + randomvec() * (random() * 120 + 90),0);
 323                         TossGib (world, "models/gibs/arm.md3", self.origin + self.view_ofs, self.velocity + randomvec() * (random() * 120 + 90),0);
 324                         //TossGib (world, "models/gibs/arm.md3", self.origin + self.view_ofs, self.velocity + randomvec() * 150,0);
 325                         //TossGib (world, "models/gibs/arm.md3", self.origin + self.view_ofs, self.velocity + randomvec() * 150,0);
 326                         TossGib (world, "models/gibs/chest.md3", self.origin + self.view_ofs * 0.5, self.velocity + randomvec() * (random() * 120 + 80),0);
 327                         //TossGib (world, "models/gibs/smallchest.md3", self.origin + self.view_ofs, self.velocity + randomvec() * 150,0);
 328                         TossGib (world, "models/gibs/smallchest.md3", self.origin + self.view_ofs, self.velocity + randomvec() * (random() * 120 + 80),0);
 329                         TossGib (world, "models/gibs/leg1.md3", self.origin + self.view_ofs * -0.2, self.velocity + randomvec() * (random() * 120 + 85),0);
 330                         TossGib (world, "models/gibs/leg2.md3", self.origin + self.view_ofs * -0.4, self.velocity + randomvec() * (random() * 120 + 85),0);
 331                         //TossGib (world, "models/gibs/leg1.md3", self.origin + self.view_ofs * -0.2, self.velocity + randomvec() * 150,0);
 332                         //TossGib (world, "models/gibs/leg2.md3", self.origin + self.view_ofs * -0.4, self.velocity + randomvec() * 150,0);
 333
 334                         // these splat on impact
 335                         TossGib (world, "models/gibs/chunk.mdl", self.origin, self.velocity + randomvec() * 450,1);
 336                         TossGib (world, "models/gibs/chunk.mdl", self.origin, self.velocity + randomvec() * 450,1);
 337                         TossGib (world, "models/gibs/chunk.mdl", self.origin, self.velocity + randomvec() * 450,1);
 338                         TossGib (world, "models/gibs/chunk.mdl", self.origin, self.velocity + randomvec() * 450,1);
 339                 }
 340
 341                 sound (self, CHAN_VOICE, "misc/gib.wav", 1, ATTN_NORM);
 342         }
 343 }
 344
 345 void ClientKill_Now_TeamChange();
 346
 347 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 348 {
 349         local float take, save, waves, sdelay;
 350
 351         damage = damage * bound(1.0, self.cvar_cl_handicap, 100.0);
 352
 353         pointparticles(particleeffectnum("blood"), hitloc, force, bound(0, damage, 200));
 354         if (self.pain_finished < time)          //Don't switch pain sequences like crazy
 355         {
 356                 if (random() > 0.5)
 357                         player_setanim(self.anim_pain1, FALSE, TRUE, TRUE);
 358                 else
 359                         player_setanim(self.anim_pain2, FALSE, TRUE, TRUE);
 360                 self.pain_finished = time + 0.5;        //Supajoe
 361
 362                 // throw off bot aim temporarily
 363                 local float shake;
 364                 shake = damage * 5 / (bound(0,skill,100) + 1);
 365                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 366                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 367         }
 368
 369         if(g_arena)
 370         if(numspawned < 2)
 371                 return;
 372
 373         if (!g_minstagib)
 374         {
 375                 save = bound(0, damage * cvar("g_balance_armor_blockpercent"), self.armorvalue);
 376                 take = bound(0, damage - save, damage);
 377         }
 378         else
 379         {
 380                 save = 0;
 381                 take = damage;
 382         }
 383
 384         if (save > 10)
 385                 sound (self, CHAN_IMPACT, "misc/armorimpact.wav", 1, ATTN_NORM);
 386         else if (take > 30)
 387                 sound (self, CHAN_IMPACT, "misc/bodyimpact2.wav", 1, ATTN_NORM);
 388         else if (take > 10)
 389                 sound (self, CHAN_IMPACT, "misc/bodyimpact1.wav", 1, ATTN_NORM);
 390
 391         if (take > 50)
 392                 TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.1,1);
 393         if (take > 100)
 394                 TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.2,1);
 395
 396         if (time > self.spawnshieldtime)
 397         {
 398                 if (!(self.flags & FL_GODMODE))
 399                 {
 400                         self.armorvalue = self.armorvalue - save;
 401                         self.health = self.health - take;
 402                         // pause regeneration for 5 seconds
 403                         self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
 404                 }
 405                 else
 406                         self.max_armorvalue += (save + take);
 407         }
 408         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 409         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 410         self.dmg_inflictor = inflictor;
 411
 412         if(attacker == self)
 413         {
 414                 // don't reset pushltime for self damage as it may be an attempt to
 415                 // escape a lava pit or similar
 416                 //self.pushltime = 0;
 417         }
 418         else if(attacker.classname == "player" || attacker.classname == "gib")
 419         {
 420                 self.pusher = attacker;
 421                 self.pushltime = time + cvar("g_maxpushtime");
 422         }
 423         else if(time < self.pushltime)
 424         {
 425                 attacker = self.pusher;
 426                 self.pushltime = max(self.pushltime, time + 0.6);
 427         }
 428         else
 429                 self.pushltime = 0;
 430
 431         if (self.health < 1)
 432         {
 433                 float defer_ClientKill_Now_TeamChange;
 434                 defer_ClientKill_Now_TeamChange = FALSE;
 435
 436                 self.deaths += 1;
 437
 438                 // get rid of kill indicator
 439                 if(self.killindicator)
 440                 {
 441                         remove(self.killindicator);
 442                         self.killindicator = world;
 443                         if(self.killindicator_teamchange)
 444                                 defer_ClientKill_Now_TeamChange = TRUE;
 445
 446                         if(self.classname == "body")
 447                         if(deathtype == DEATH_KILL)
 448                         {
 449                                 // for the lemmings fans, a small harmless explosion
 450                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 451                         }
 452                 }
 453
 454                 // become fully visible
 455                 self.alpha = 1;
 456                 // clear selected player display
 457                 ClearSelectedPlayer();
 458                 // throw a weapon
 459                 SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 460                 // print an obituary message
 461                 Obituary (attacker, self, deathtype);
 462                 DropAllRunes(self);
 463                 if(self == attacker)
 464                         kh_Key_DropAll(self, TRUE);
 465                 else if(attacker.classname == "player" || attacker.classname == "gib")
 466                         kh_Key_DropAll(self, FALSE);
 467                 else
 468                         kh_Key_DropAll(self, TRUE);
 469                 if(self.flagcarried)
 470                         DropFlag(self.flagcarried);
 471                 // clear waypoints
 472                 WaypointSprite_PlayerDead();
 473                 // make the corpse upright (not tilted)
 474                 self.angles_x = 0;
 475                 self.angles_z = 0;
 476                 // don't spin
 477                 self.avelocity = '0 0 0';
 478                 // view from the floor
 479                 self.view_ofs = '0 0 -8';
 480                 // toss the corpse
 481                 self.movetype = MOVETYPE_TOSS;
 482                 // shootable corpse
 483                 self.solid = SOLID_CORPSE;
 484                 // don't stick to the floor
 485                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 486                 // dying animation
 487                 self.deadflag = DEAD_DYING;
 488                 // when to allow respawn
 489                 sdelay = 0;
 490                 waves = 0;
 491                 if(cvar("g_respawn_mapsettings"))
 492                 {
 493                         sdelay = cvar("g_respawn_mapsettings_delay");
 494                         waves = cvar("g_respawn_mapsettings_waves");
 495                 }
 496                 if(!sdelay)
 497                         sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 498                 if(!sdelay)
 499                         sdelay = cvar("g_respawn_delay");
 500                 if(!waves)
 501                         waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 502                 if(!waves)
 503                         waves = cvar("g_respawn_waves");
 504                 if(waves)
 505                         self.death_time = ceil((time + sdelay) / waves) * waves;
 506                 else
 507                         self.death_time = time + sdelay;
 508                 if((sdelay + waves >= 5.0) && (self.death_time - time > 1.75))
 509                         self.respawn_countdown = 10; // first number to count down from is 10
 510                 else
 511                         self.respawn_countdown = -1; // do not count down
 512                 if (random() < 0.5)
 513                 {
 514                         player_setanim(self.anim_die1, FALSE, TRUE, TRUE);
 515                         self.dead_frame = self.anim_dead1_x;
 516                 }
 517                 else
 518                 {
 519                         player_setanim(self.anim_die2, FALSE, TRUE, TRUE);
 520                         self.dead_frame = self.anim_dead2_x;
 521                 }
 522                 // set damage function to corpse damage
 523                 self.event_damage = PlayerCorpseDamage;
 524                 // call the corpse damage function just in case it wants to gib
 525                 self.event_damage(inflictor, attacker, 0, deathtype, hitloc, force);
 526                 // set up to fade out later
 527                 SUB_SetFade (self, time + 12 + random () * 4, 1);
 528
 529                 // remove laserdot
 530                 if(self.weaponentity)
 531                         if(self.weaponentity.lasertarget)
 532                                 remove(self.weaponentity.lasertarget);
 533
 534                 if(clienttype(self) == CLIENTTYPE_REAL)
 535                 {
 536                         self.fixangle = TRUE;
 537                         //msg_entity = self;
 538                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 539                         //WriteAngle (MSG_ONE, self.v_angle_x);
 540                         //WriteAngle (MSG_ONE, self.v_angle_y);
 541                         //WriteAngle (MSG_ONE, 80);
 542                 }
 543
 544                 if(g_arena)
 545                         Spawnqueue_Unmark(self);
 546
 547                 if(defer_ClientKill_Now_TeamChange)
 548                         ClientKill_Now_TeamChange();
 549         }
 550 }
 551
 552 float UpdateSelectedPlayer_countvalue(float v)
 553 {
 554         return max(0, (v - 1.0) / 0.5);
 555 }
 556
 557 // returns: -2 if no hit, otherwise cos of the angle
 558 // uses the global v_angle
 559 float UpdateSelectedPlayer_canSee(entity p, float mincosangle, float maxdist)
 560 {
 561         vector so, d;
 562         float c;
 563
 564         if(p == self)
 565                 return -2;
 566
 567         if(p.deadflag)
 568                 return -2;
 569
 570         so = self.origin + self.view_ofs;
 571         d = p.origin - so;
 572
 573         // misaimed?
 574         if(dist_point_line(d, '0 0 0', v_forward) > maxdist)
 575                 return -2;
 576
 577         // now find the cos of the angle...
 578         c = normalize(d) * v_forward;
 579
 580         if(c <= mincosangle)
 581                 return -2;
 582
 583         traceline(so, p.origin, MOVE_NOMONSTERS, self);
 584         if(trace_fraction < 1)
 585                 return -2;
 586
 587         return c;
 588 }
 589
 590 void ClearSelectedPlayer()
 591 {
 592         if(self.selected_player)
 593         {
 594                 centerprint_expire(self, CENTERPRIO_POINT);
 595                 self.selected_player = world;
 596                 self.selected_player_display_needs_update = FALSE;
 597         }
 598 }
 599
 600 void UpdateSelectedPlayer()
 601 {
 602         entity selected;
 603         float selected_score;
 604         selected = world;
 605         selected_score = 0.95; // 18 degrees
 606
 607         if(!cvar("sv_allow_shownames"))
 608                 return;
 609
 610         if(clienttype(self) != CLIENTTYPE_REAL)
 611                 return;
 612
 613         if(self.cvar_cl_shownames == 0)
 614                 return;
 615
 616         if(self.cvar_cl_shownames == 1 && !teams_matter)
 617                 return;
 618
 619         makevectors(self.v_angle); // sets v_forward
 620
 621         // 1. cursor trace is always right
 622         if(self.cursor_trace_ent && self.cursor_trace_ent.classname == "player" && !self.cursor_trace_ent.deadflag)
 623         {
 624                 selected = self.cursor_trace_ent;
 625         }
 626         else
 627         {
 628                 // 2. if we don't have a cursor trace, find the player which is least
 629                 //    mis-aimed at
 630                 entity p;
 631                 FOR_EACH_PLAYER(p)
 632                 {
 633                         float c;
 634                         c = UpdateSelectedPlayer_canSee(p, selected_score, 100); // 100 = 2.5 meters
 635                         if(c >= -1)
 636                         {
 637                                 selected = p;
 638                                 selected_score = c;
 639                         }
 640                 }
 641         }
 642
 643         if(selected)
 644         {
 645                 self.selected_player_display_timeout = time + self.cvar_scr_centertime;
 646         }
 647         else
 648         {
 649                 if(time < self.selected_player_display_timeout)
 650                         if(UpdateSelectedPlayer_canSee(self.selected_player, 0.7, 200) >= -1) // 5 meters, 45 degrees
 651                                 selected = self.selected_player;
 652         }
 653
 654         if(selected)
 655         {
 656                 if(selected == self.selected_player)
 657                 {
 658                         float save;
 659                         save = UpdateSelectedPlayer_countvalue(self.selected_player_count);
 660                         self.selected_player_count = self.selected_player_count + frametime;
 661                         if(save != UpdateSelectedPlayer_countvalue(self.selected_player_count))
 662                         {
 663                                 string namestr, healthstr;
 664                                 namestr = playername(selected);
 665                                 if(teams_matter)
 666                                 {
 667                                         healthstr = ftos(floor(selected.health));
 668                                         if(self.team == selected.team)
 669                                         {
 670                                                 namestr = strcat(namestr, " (", healthstr, "%)");
 671                                                 self.selected_player_display_needs_update = TRUE;
 672                                         }
 673                                 }
 674                                 centerprint_atprio(self, CENTERPRIO_POINT, namestr);
 675                         }
 676                 }
 677                 else
 678                 {
 679                         ClearSelectedPlayer();
 680                         self.selected_player = selected;
 681                         self.selected_player_time = time;
 682                         self.selected_player_count = 0;
 683                         self.selected_player_display_needs_update = FALSE;
 684                 }
 685         }
 686         else
 687         {
 688                 ClearSelectedPlayer();
 689         }
 690
 691         if(self.selected_player)
 692                 self.last_selected_player = self.selected_player;
 693 }
 694
 695 float precache_sound_index (string s) = #19;
 696 void soundto(entity e, entity sounddest, float chan, string samp, float vol, float atten)
 697 {
 698         vector o;
 699         if(clienttype(sounddest) != CLIENTTYPE_REAL)
 700                 return;
 701         o = e.origin + 0.5 * (e.mins + e.maxs);
 702         msg_entity = sounddest;
 703         WriteByte(MSG_ONE, 6);
 704         WriteByte(MSG_ONE, 27); // all bits except SND_LOOPING
 705         WriteByte(MSG_ONE, vol * 255);
 706         WriteByte(MSG_ONE, atten * 64);
 707         WriteEntity(MSG_ONE, e);
 708         WriteByte(MSG_ONE, chan);
 709         WriteShort(MSG_ONE, precache_sound_index(samp));
 710         WriteCoord(MSG_ONE, o_x);
 711         WriteCoord(MSG_ONE, o_y);
 712         WriteCoord(MSG_ONE, o_z);
 713 }
 714
 715 #if 0
 716 .string playersound_attack;
 717 .string playersound_attackinfive;
 718 .string playersound_coverme;
 719 .string playersound_defend;
 720 .string playersound_freelance;
 721 .string playersound_incoming;
 722 .string playersound_meet;
 723 .string playersound_needhelp;
 724 .string playersound_seenflag;
 725 .string playersound_taunt;
 726 .string playersound_teamshoot;
 727 .float modelindex_for_playersound;
 728
 729 float GetVoiceMessageTeamsayType(string type)
 730 {
 731         if(type == "taunt")
 732                 return 0;
 733         if(type == "teamshoot")
 734                 return 2;
 735         return 1;
 736 }
 737
 738 string allvoicesamples = "attack attackinfive coverme defend freelance incoming meet needhelp seenflag taunt teamshoot";
 739 float GetPlayerSoundSampleField_notFound;
 740 .string GetVoiceMessageSampleField(string type)
 741 {
 742         GetPlayerSoundSampleField_notFound = 0;
 743         switch(type)
 744         {
 745                 case "attack":       return playersound_attack;
 746                 case "attackinfive": return playersound_attackinfive;
 747                 case "coverme":      return playersound_coverme;
 748                 case "defend":       return playersound_defend;
 749                 case "freelance":    return playersound_freelance;
 750                 case "incoming":     return playersound_incoming;
 751                 case "meet":         return playersound_meet;
 752                 case "needhelp":     return playersound_needhelp;
 753                 case "seenflag":     return playersound_seenflag;
 754                 case "taunt":        return playersound_taunt;
 755                 case "teamshoot":    return playersound_teamshoot;
 756         }
 757         GetPlayerSoundSampleField_notFound = 1;
 758         return playersound_taunt;
 759 }
 760
 761 .string GetPlayerSoundSampleField(string type)
 762 {
 763         GetPlayerSoundSampleField_notFound = 0;
 764         switch(type)
 765         {
 766                 case "attack":       return playersound_attack;
 767                 default:             return GetVoiceMessageSampleField(type);
 768         }
 769 }
 770
 771 void PrecachePlayerSounds(string f)
 772 {
 773         float fh;
 774         float i, n;
 775         string s;
 776         fh = fopen(f, FILE_READ);
 777         if(fh < 0)
 778                 return;
 779         while((s = fgets(fh)))
 780         {
 781                 if(tokenize(s) != 3)
 782                 {
 783                         dprint("Invalid sound info line: ", s, "\n");
 784                         continue;
 785                 }
 786                 n = stof(argv(2));
 787                 for(i = 1; i <= n; ++i)
 788                         precache_sound(strcat(argv(1), ftos(i), ".wav"));
 789         }
 790         fclose(fh);
 791 }
 792
 793 void LoadPlayerSounds(string f)
 794 {
 795         float fh;
 796         string s;
 797         var .string field;
 798         fh = fopen(f, FILE_READ);
 799         if(fh < 0)
 800                 return;
 801         while((s = fgets(fh)))
 802         {
 803                 if(tokenize(s) != 3)
 804                         continue;
 805                 field = GetPlayerSoundSampleField(argv(0));
 806                 if(GetPlayerSoundSampleField_notFound)
 807                         continue;
 808                 if(self.field)
 809                         strunzone(self.field);
 810                 self.field = strzone(strcat(argv(1), " ", argv(2)));
 811         }
 812         fclose(fh);
 813 }
 814
 815 void UpdatePlayerSounds()
 816 {
 817         if(self.modelindex == self.modelindex_for_playersound)
 818                 return;
 819         self.modelindex_for_playersound = self.modelindex;
 820         LoadPlayerSounds("sound/player/default.sounds");
 821         LoadPlayerSounds(strcat(self.model, ".sounds"));
 822 }
 823
 824 void VoiceMessage(string type)
 825 {
 826         // TODO precache voice messages?
 827         var string sample;
 828         var float teamsay;
 829         sample = self.(GetPlayerSoundSampleField(type));
 830
 831         if(GetPlayerSoundSampleField_notFound)
 832         {
 833                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
 834                 return;
 835         }
 836
 837         if(!sample)
 838                 return;
 839
 840         teamsay = GetVoiceMessageTeamsayType(type);
 841
 842         tokenize(sample);
 843         sample = strcat(argv(0), ftos(ceil(random() * stof(argv(1)))), ".wav"); // randomization
 844
 845         if(teamsay == 2)
 846         {
 847                 if(teams_matter)
 848                         if(self.pusher)
 849                                 if(self.pusher.team == self.team)
 850                                 {
 851                                         soundto(self, self.pusher, CHAN_VOICE, sample, 1, ATTN_NONE);
 852                                         soundto(self, self, CHAN_VOICE, sample, 1, ATTN_NONE);
 853                                 }
 854         }
 855         else if(teamsay == 0 || !teams_matter)
 856         {
 857                 // broadcast the sound, but it's directional
 858                 sound(self, CHAN_VOICE, sample, 1, ATTN_NORM);
 859         }
 860         else if(teamsay == 1)
 861         {
 862                 entity e;
 863                 FOR_EACH_REALCLIENT(e)
 864                         if(e.team == self.team)
 865                                 soundto(self, e, CHAN_VOICE, sample, 1, ATTN_NONE);
 866         }
 867 }
 868 #else
 869 void PrecachePlayerSounds(string f) { }
 870 void UpdatePlayerSounds() { }
 871 void VoiceMessage(string type) { sprint(self, "Sorry, voice command support is not done yet. Maybe later.\n"); }
 872 #endif