data/qcsrc/server/cl_player.qc

   1
   2 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
   3 // merged player_run and player_stand to player_anim
   4 // added death animations to player_anim
   5 // can now spawn thrown weapons from anywhere, not just from players
   6 // thrown weapons now fade out after 20 seconds
   7 // created PlayerGib function
   8 // PlayerDie no longer uses hitloc or damage
   9 // PlayerDie now supports dying animations as well as gibbing
  10 // cleaned up PlayerDie a lot
  11 // added CopyBody
  12
  13 .entity pusher;
  14 .float pushltime;
  15
  16 void CopyBody(float keepvelocity)
  17 {
  18         local entity oldself;
  19         if (self.effects & EF_NODRAW)
  20                 return;
  21         oldself = self;
  22         self = spawn();
  23         self.enemy = oldself;
  24         self.lip = oldself.lip;
  25         self.colormap = oldself.colormap;
  26         self.iscreature = oldself.iscreature;
  27         self.angles = oldself.angles;
  28         self.avelocity = oldself.avelocity;
  29         self.classname = "body";
  30         self.damageforcescale = oldself.damageforcescale;
  31         self.effects = oldself.effects;
  32         self.event_damage = oldself.event_damage;
  33         self.animstate_startframe = oldself.animstate_startframe;
  34         self.animstate_numframes = oldself.animstate_numframes;
  35         self.animstate_framerate = oldself.animstate_framerate;
  36         self.animstate_starttime = oldself.animstate_starttime;
  37         self.animstate_endtime = oldself.animstate_endtime;
  38         self.animstate_override = oldself.animstate_override;
  39         self.animstate_looping = oldself.animstate_looping;
  40         self.frame = oldself.frame;
  41         self.dead_frame = oldself.dead_frame;
  42         self.pain_finished = oldself.pain_finished;
  43         self.health = oldself.health;
  44         self.armorvalue = oldself.armorvalue;
  45         self.armortype = oldself.armortype;
  46         self.model = oldself.model;
  47         self.modelindex = oldself.modelindex;
  48         self.movetype = oldself.movetype;
  49         self.nextthink = oldself.nextthink;
  50         self.skin = oldself.skin;
  51         self.solid = oldself.solid;
  52         self.takedamage = oldself.takedamage;
  53         self.think = oldself.think;
  54         self.gibrandom = oldself.gibrandom;
  55         self.customizeentityforclient = oldself.customizeentityforclient;
  56         if (keepvelocity == 1)
  57                 self.velocity = oldself.velocity;
  58         self.oldvelocity = self.velocity;
  59         self.fade_time = oldself.fade_time;
  60         self.fade_rate = oldself.fade_rate;
  61         //self.weapon = oldself.weapon;
  62         setorigin(self, oldself.origin);
  63         setsize(self, oldself.mins, oldself.maxs);
  64         self.oldorigin = oldself.origin;
  65         self = oldself;
  66 }
  67
  68 float animparseerror;
  69 vector animparseline(float animfile)
  70 {
  71         local string line;
  72         local float c;
  73         local vector anim;
  74         if (animfile < 0)
  75                 return '0 1 2';
  76         line = fgets(animfile);
  77         c = tokenize(line);
  78         if (c != 3)
  79         {
  80                 animparseerror = TRUE;
  81                 return '0 1 2';
  82         }
  83         anim_x = stof(argv(0));
  84         anim_y = stof(argv(1));
  85         anim_z = stof(argv(2));
  86         // don't allow completely bogus values
  87         if (anim_x < 0 || anim_y < 1 || anim_z < 0.001)
  88                 anim = '0 1 2';
  89         return anim;
  90 };
  91
  92 void player_setupanimsformodel()
  93 {
  94         local string animfilename;
  95         local float animfile;
  96         // defaults for legacy .zym models without animinfo files
  97         self.anim_die1 = '0 1 0.5'; // 2 seconds
  98         self.anim_die2 = '1 1 0.5'; // 2 seconds
  99         self.anim_draw = '2 1 3'; // TODO: analyze models and set framerate
 100         self.anim_duck = '3 1 100'; // this anim seems bogus in most models, so make it play VERY briefly!
 101         self.anim_duckwalk = '4 1 1';
 102         self.anim_duckjump = '5 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 103         self.anim_duckidle = '6 1 1';
 104         self.anim_idle = '7 1 1';
 105         self.anim_jump = '8 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 106         self.anim_pain1 = '9 1 2'; // 0.5 seconds
 107         self.anim_pain2 = '10 1 2'; // 0.5 seconds
 108         self.anim_shoot = '11 1 5'; // TODO: analyze models and set framerate
 109         self.anim_taunt = '12 1 1'; // FIXME?  there is no code using this anim
 110         self.anim_run = '13 1 1';
 111         self.anim_runbackwards = '14 1 1';
 112         self.anim_strafeleft = '15 1 1';
 113         self.anim_straferight = '16 1 1';
 114         self.anim_dead1 = '17 1 1';
 115         self.anim_dead2 = '18 1 1';
 116         self.anim_forwardright = '19 1 1';
 117         self.anim_forwardleft = '20 1 1';
 118         self.anim_backright = '21 1 1';
 119         self.anim_backleft  = '22 1 1';
 120         animparseerror = FALSE;
 121         animfilename = strcat(self.model, ".animinfo");
 122         animfile = fopen(animfilename, FILE_READ);
 123         if (animfile >= 0)
 124         {
 125                 self.anim_die1         = animparseline(animfile);
 126                 self.anim_die2         = animparseline(animfile);
 127                 self.anim_draw         = animparseline(animfile);
 128                 self.anim_duck         = animparseline(animfile);
 129                 self.anim_duckwalk     = animparseline(animfile);
 130                 self.anim_duckjump     = animparseline(animfile);
 131                 self.anim_duckidle     = animparseline(animfile);
 132                 self.anim_idle         = animparseline(animfile);
 133                 self.anim_jump         = animparseline(animfile);
 134                 self.anim_pain1        = animparseline(animfile);
 135                 self.anim_pain2        = animparseline(animfile);
 136                 self.anim_shoot        = animparseline(animfile);
 137                 self.anim_taunt        = animparseline(animfile);
 138                 self.anim_run          = animparseline(animfile);
 139                 self.anim_runbackwards = animparseline(animfile);
 140                 self.anim_strafeleft   = animparseline(animfile);
 141                 self.anim_straferight  = animparseline(animfile);
 142                 self.anim_forwardright = animparseline(animfile);
 143                 self.anim_forwardleft  = animparseline(animfile);
 144                 self.anim_backright    = animparseline(animfile);
 145                 self.anim_backleft     = animparseline(animfile);
 146                 fclose(animfile);
 147
 148                 // derived anims
 149                 self.anim_dead1 = '0 1 1' + '1 0 0' * (self.anim_die1_x + self.anim_die1_y - 1);
 150                 self.anim_dead2 = '0 1 1' + '1 0 0' * (self.anim_die2_x + self.anim_die2_y - 1);
 151
 152                 if (animparseerror)
 153                         print("Parse error in ", animfilename, ", some player animations are broken\n");
 154         }
 155         else
 156                 dprint("File ", animfilename, " not found, assuming legacy .zym model animation timings\n");
 157         // reset animstate now
 158         player_setanim(self.anim_idle, TRUE, FALSE, TRUE);
 159 };
 160
 161 void player_setanim(vector anim, float looping, float override, float restart)
 162 {
 163         if (!restart)
 164         if (anim_x == self.animstate_startframe)
 165         if (anim_y == self.animstate_numframes)
 166         if (anim_z == self.animstate_framerate)
 167                 return;
 168         self.animstate_startframe = anim_x;
 169         self.animstate_numframes = anim_y;
 170         self.animstate_framerate = anim_z;
 171         self.animstate_starttime = time;
 172         self.animstate_endtime = time + self.animstate_numframes / self.animstate_framerate;
 173         self.animstate_looping = looping;
 174         self.animstate_override = override;
 175         self.frame = self.animstate_startframe;
 176 };
 177
 178 void player_updateframe()
 179 {
 180         if (time >= self.animstate_endtime)
 181         {
 182                 if (self.animstate_looping)
 183                 {
 184                         self.animstate_starttime = self.animstate_endtime;
 185                         self.animstate_endtime = self.animstate_endtime + self.animstate_numframes / self.animstate_framerate;
 186                 }
 187                 self.animstate_override = FALSE;
 188         }
 189         self.frame = self.animstate_startframe + bound(0, (time - self.animstate_starttime) * self.animstate_framerate, self.animstate_numframes - 1);
 190 };
 191
 192 void player_anim (void)
 193 {
 194         player_updateframe();
 195
 196         if (self.deadflag != DEAD_NO)
 197         {
 198                 if (time > self.animstate_endtime)
 199                 {
 200                         if (self.maxs_z > 5)
 201                         {
 202                                 self.maxs_z = 5;
 203                                 setsize(self, self.mins, self.maxs);
 204                         }
 205                         self.frame = self.dead_frame;
 206                 }
 207                 return;
 208         }
 209
 210         if (!self.animstate_override)
 211         {
 212                 if (!(self.flags & FL_ONGROUND))
 213                 {
 214                         if (self.crouch)
 215                                 player_setanim(self.anim_duckjump, FALSE, TRUE, FALSE);
 216                         else
 217                                 player_setanim(self.anim_jump, FALSE, TRUE, FALSE);
 218                 }
 219                 else if (self.crouch)
 220                 {
 221                         if (self.movement_x * self.movement_x + self.movement_y * self.movement_y > 20)
 222                                 player_setanim(self.anim_duckwalk, TRUE, FALSE, FALSE);
 223                         else
 224                                 player_setanim(self.anim_duckidle, TRUE, FALSE, FALSE);
 225                 }
 226                 else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
 227                 {
 228                         if (self.movement_x > 0 && self.movement_y == 0)
 229                                 player_setanim(self.anim_run, TRUE, FALSE, FALSE);
 230                         else if (self.movement_x < 0 && self.movement_y == 0)
 231                                 player_setanim(self.anim_runbackwards, TRUE, FALSE, FALSE);
 232                         else if (self.movement_x == 0 && self.movement_y > 0)
 233                                 player_setanim(self.anim_straferight, TRUE, FALSE, FALSE);
 234                         else if (self.movement_x == 0 && self.movement_y < 0)
 235                                 player_setanim(self.anim_strafeleft, TRUE, FALSE, FALSE);
 236                         else if (self.movement_x > 0 && self.movement_y > 0)
 237                                 player_setanim(self.anim_forwardright, TRUE, FALSE, FALSE);
 238                         else if (self.movement_x > 0 && self.movement_y < 0)
 239                                 player_setanim(self.anim_forwardleft, TRUE, FALSE, FALSE);
 240                         else if (self.movement_x < 0 && self.movement_y > 0)
 241                                 player_setanim(self.anim_backright, TRUE, FALSE, FALSE);
 242                         else if (self.movement_x < 0 && self.movement_y < 0)
 243                                 player_setanim(self.anim_backleft, TRUE, FALSE, FALSE);
 244                         else
 245                                 player_setanim(self.anim_run, TRUE, FALSE, FALSE);
 246                 }
 247                 else
 248                         player_setanim(self.anim_idle, TRUE, FALSE, FALSE);
 249         }
 250 }
 251 //End change by Supajoe on 11:44 PM EST 11/16/03 (Subject: Player animations)
 252
 253 void SpawnThrownWeapon (vector org, float w)
 254 {
 255         W_ThrowWeapon(randomvec() * 100 + '0 0 200', org - self.origin, FALSE);
 256 }
 257
 258 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 259 {
 260         local float take, save;
 261         if(sv_gentle < 1)
 262                 pointparticles(particleeffectnum("blood"), hitloc, force, bound(0, damage, 200));
 263         // damage resistance (ignore most of the damage from a bullet or similar)
 264         damage = max(damage - 5, 1);
 265
 266         save = bound(0, damage * cvar("g_balance_armor_blockpercent"), self.armorvalue);
 267         take = bound(0, damage - save, damage);
 268
 269         if (save > 10)
 270                 sound (self, CHAN_PROJECTILE, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 271         else if (take > 30)
 272                 sound (self, CHAN_PROJECTILE, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 273         else if (take > 10)
 274                 sound (self, CHAN_PROJECTILE, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 275
 276         if(sv_gentle < 1) {
 277                 if (take > 50)
 278                         TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.1,1);
 279                 if (take > 100)
 280                         TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.2,1);
 281         }
 282
 283         if (!(self.flags & FL_GODMODE))
 284         {
 285                 self.armorvalue = self.armorvalue - save;
 286                 self.health = self.health - take;
 287                 // pause regeneration for 5 seconds
 288                 self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
 289         }
 290         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 291         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 292         self.dmg_inflictor = inflictor;
 293
 294         if (self.health <= -50)
 295         {
 296                 // don't use any animations as a gib
 297                 self.frame = 0;
 298                 self.dead_frame = 0;
 299                 // view just above the floor
 300                 self.view_ofs = '0 0 4';
 301
 302                 // make a juicy mess
 303                 local float multiplier;
 304                 multiplier = 1;
 305                 if (cvar("ekg"))
 306                         multiplier = 5;
 307
 308
 309                 // make a meaty mess
 310                 TossGib (self, "models/gibs/eye.md3", self.origin + self.view_ofs, self.velocity + randomvec() * 150,0);
 311
 312                 if(sv_gentle < 1) {
 313                         te_bloodshower (self.origin + self.mins, self.origin + self.maxs, 1200 * multiplier, 1000);
 314                         TossGib (world, "models/gibs/bloodyskull.md3", self.origin + self.view_ofs, self.velocity,0);
 315
 316                         local float c;
 317                         c = 0;
 318
 319                         while (c < multiplier)
 320                         {
 321                                 c = c + 1;
 322                                 //TossGib (world, "models/gibs/gib1.md3", self.origin, self.velocity + randomvec() * 450,0);
 323                                 //TossGib (world, "models/gibs/gib2.md3", self.origin, self.velocity + randomvec() * 450,0);
 324                                 //TossGib (world, "models/gibs/gib3.md3", self.origin, self.velocity + randomvec() * 450,0);
 325                                 //TossGib (world, "models/gibs/gib4.md3", self.origin, self.velocity + randomvec() * 450,0);
 326                                 //TossGib (world, "models/gibs/gib5.md3", self.origin, self.velocity + randomvec() * 450,0);
 327                                 //TossGib (world, "models/gibs/gib6.md3", self.origin, self.velocity + randomvec() * 450,0);
 328
 329                                 TossGib (world, "models/gibs/arm.md3", self.origin + self.view_ofs, self.velocity + randomvec() * (random() * 120 + 90),0);
 330                                 TossGib (world, "models/gibs/arm.md3", self.origin + self.view_ofs, self.velocity + randomvec() * (random() * 120 + 90),0);
 331                                 //TossGib (world, "models/gibs/arm.md3", self.origin + self.view_ofs, self.velocity + randomvec() * 150,0);
 332                                 //TossGib (world, "models/gibs/arm.md3", self.origin + self.view_ofs, self.velocity + randomvec() * 150,0);
 333                                 TossGib (world, "models/gibs/chest.md3", self.origin + self.view_ofs * 0.5, self.velocity + randomvec() * (random() * 120 + 80),0);
 334                                 //TossGib (world, "models/gibs/smallchest.md3", self.origin + self.view_ofs, self.velocity + randomvec() * 150,0);
 335                                 TossGib (world, "models/gibs/smallchest.md3", self.origin + self.view_ofs, self.velocity + randomvec() * (random() * 120 + 80),0);
 336                                 TossGib (world, "models/gibs/leg1.md3", self.origin + self.view_ofs * -0.2, self.velocity + randomvec() * (random() * 120 + 85),0);
 337                                 TossGib (world, "models/gibs/leg2.md3", self.origin + self.view_ofs * -0.4, self.velocity + randomvec() * (random() * 120 + 85),0);
 338                                 //TossGib (world, "models/gibs/leg1.md3", self.origin + self.view_ofs * -0.2, self.velocity + randomvec() * 150,0);
 339                                 //TossGib (world, "models/gibs/leg2.md3", self.origin + self.view_ofs * -0.4, self.velocity + randomvec() * 150,0);
 340
 341                                 // these splat on impact
 342                                 TossGib (world, "models/gibs/chunk.mdl", self.origin, self.velocity + randomvec() * 450,1);
 343                                 TossGib (world, "models/gibs/chunk.mdl", self.origin, self.velocity + randomvec() * 450,1);
 344                                 TossGib (world, "models/gibs/chunk.mdl", self.origin, self.velocity + randomvec() * 450,1);
 345                                 TossGib (world, "models/gibs/chunk.mdl", self.origin, self.velocity + randomvec() * 450,1);
 346                         }
 347                         sound (self, CHAN_PLAYER, "misc/gib.wav", VOL_BASE, ATTN_NORM);
 348                 }
 349         }
 350 }
 351
 352 void ClientKill_Now_TeamChange();
 353
 354 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 355 {
 356         local float take, save, waves, sdelay;
 357
 358         if(self.hook)
 359                 if(self.hook.aiment == attacker)
 360                         RemoveGrapplingHook(self); // STOP THAT, you parasite!
 361
 362         damage = damage * bound(1.0, self.cvar_cl_handicap, 100.0);
 363         if(sv_gentle > 0) {
 364                 pointparticles(particleeffectnum("damage_hit"), hitloc, force, bound(0, damage, 200));
 365         } else {
 366                 pointparticles(particleeffectnum("blood"), hitloc, force, bound(0, damage, 200));
 367         }
 368
 369         if(g_arena)
 370         if(numspawned < 2)
 371                 return;
 372
 373         if (!g_minstagib)
 374         {
 375                 save = bound(0, damage * cvar("g_balance_armor_blockpercent"), self.armorvalue);
 376                 take = bound(0, damage - save, damage);
 377         }
 378         else
 379         {
 380                 save = 0;
 381                 take = damage;
 382         }
 383
 384         if (save > 10)
 385                 sound (self, CHAN_PROJECTILE, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 386         else if (take > 30)
 387                 sound (self, CHAN_PROJECTILE, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 388         else if (take > 10)
 389                 sound (self, CHAN_PROJECTILE, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 390
 391         if (take > 50)
 392                 TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.1,1);
 393         if (take > 100)
 394                 TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.2,1);
 395
 396         if (time > self.spawnshieldtime)
 397         {
 398                 if (!(self.flags & FL_GODMODE))
 399                 {
 400                         self.armorvalue = self.armorvalue - save;
 401                         self.health = self.health - take;
 402                         // pause regeneration for 5 seconds
 403                         self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
 404
 405                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 406                         {
 407                                 self.pain_finished = time + 0.5;        //Supajoe
 408
 409                                 if(sv_gentle < 1) {
 410                                         if (random() > 0.5)
 411                                                 player_setanim(self.anim_pain1, FALSE, TRUE, TRUE);
 412                                         else
 413                                                 player_setanim(self.anim_pain2, FALSE, TRUE, TRUE);
 414
 415                                         if(deathtype != IT_LASER || attacker != self || self.health < 2 * cvar("g_balance_laser_primary_damage") * cvar("g_balance_selfdamagepercent") + 1)
 416                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 417                                         {
 418                                                 if(self.health > 75) // TODO make a "gentle" version?
 419                                                         PlayerSound(playersound_pain100, CHAN_PAIN, 0);
 420                                                 else if(self.health > 50)
 421                                                         PlayerSound(playersound_pain75, CHAN_PAIN, 0);
 422                                                 else if(self.health > 25)
 423                                                         PlayerSound(playersound_pain50, CHAN_PAIN, 0);
 424                                                 else if(self.health > 1)
 425                                                         PlayerSound(playersound_pain25, CHAN_PAIN, 0);
 426                                         }
 427                                 }
 428
 429                                 // throw off bot aim temporarily
 430                                 local float shake;
 431                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 432                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 433                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 434                         }
 435                 }
 436                 else
 437                         self.max_armorvalue += (save + take);
 438         }
 439         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 440         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 441         self.dmg_inflictor = inflictor;
 442
 443         if(attacker == self)
 444         {
 445                 // don't reset pushltime for self damage as it may be an attempt to
 446                 // escape a lava pit or similar
 447                 //self.pushltime = 0;
 448         }
 449         else if(attacker.classname == "player" || attacker.classname == "gib")
 450         {
 451                 self.pusher = attacker;
 452                 self.pushltime = time + cvar("g_maxpushtime");
 453         }
 454         else if(time < self.pushltime)
 455         {
 456                 attacker = self.pusher;
 457                 self.pushltime = max(self.pushltime, time + 0.6);
 458         }
 459         else
 460                 self.pushltime = 0;
 461
 462         if (self.health < 1)
 463         {
 464                 float defer_ClientKill_Now_TeamChange;
 465                 defer_ClientKill_Now_TeamChange = FALSE;
 466
 467                 if(sv_gentle < 1) // TODO make a "gentle" version?
 468                 {
 469                         if(deathtype == DEATH_DROWN)
 470                                 PlayerSound(playersound_drown, CHAN_PAIN, 0);
 471                         else
 472                                 PlayerSound(playersound_death, CHAN_PAIN, 0);
 473                 }
 474
 475                 // get rid of kill indicator
 476                 if(self.killindicator)
 477                 {
 478                         remove(self.killindicator);
 479                         self.killindicator = world;
 480                         if(self.killindicator_teamchange)
 481                                 defer_ClientKill_Now_TeamChange = TRUE;
 482
 483                         if(self.classname == "body")
 484                         if(deathtype == DEATH_KILL)
 485                         {
 486                                 // for the lemmings fans, a small harmless explosion
 487                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 488                         }
 489                 }
 490
 491                 // become fully visible
 492                 self.alpha = 1;
 493                 // clear selected player display
 494                 ClearSelectedPlayer();
 495                 // throw a weapon
 496                 SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 497                 // print an obituary message
 498                 Obituary (attacker, self, deathtype);
 499                 DropAllRunes(self);
 500                 if(self == attacker)
 501                         kh_Key_DropAll(self, TRUE);
 502                 else if(attacker.classname == "player" || attacker.classname == "gib")
 503                         kh_Key_DropAll(self, FALSE);
 504                 else
 505                         kh_Key_DropAll(self, TRUE);
 506                 if(self.flagcarried)
 507                         DropFlag(self.flagcarried);
 508                 // clear waypoints
 509                 WaypointSprite_PlayerDead();
 510                 // make the corpse upright (not tilted)
 511                 self.angles_x = 0;
 512                 self.angles_z = 0;
 513                 // don't spin
 514                 self.avelocity = '0 0 0';
 515                 // view from the floor
 516                 self.view_ofs = '0 0 -8';
 517                 // toss the corpse
 518                 self.movetype = MOVETYPE_TOSS;
 519                 // shootable corpse
 520                 self.solid = SOLID_CORPSE;
 521                 // don't stick to the floor
 522                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 523                 // dying animation
 524                 self.deadflag = DEAD_DYING;
 525                 // when to allow respawn
 526                 sdelay = 0;
 527                 waves = 0;
 528                 if(cvar("g_respawn_mapsettings"))
 529                 {
 530                         sdelay = cvar("g_respawn_mapsettings_delay");
 531                         waves = cvar("g_respawn_mapsettings_waves");
 532                 }
 533                 if(!sdelay)
 534                         sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 535                 if(!sdelay)
 536                         sdelay = cvar("g_respawn_delay");
 537                 if(!waves)
 538                         waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 539                 if(!waves)
 540                         waves = cvar("g_respawn_waves");
 541                 if(waves)
 542                         self.death_time = ceil((time + sdelay) / waves) * waves;
 543                 else
 544                         self.death_time = time + sdelay;
 545                 if((sdelay + waves >= 5.0) && (self.death_time - time > 1.75))
 546                         self.respawn_countdown = 10; // first number to count down from is 10
 547                 else
 548                         self.respawn_countdown = -1; // do not count down
 549                 if (random() < 0.5)
 550                 {
 551                         player_setanim(self.anim_die1, FALSE, TRUE, TRUE);
 552                         self.dead_frame = self.anim_dead1_x;
 553                 }
 554                 else
 555                 {
 556                         player_setanim(self.anim_die2, FALSE, TRUE, TRUE);
 557                         self.dead_frame = self.anim_dead2_x;
 558                 }
 559                 // set damage function to corpse damage
 560                 self.event_damage = PlayerCorpseDamage;
 561                 // call the corpse damage function just in case it wants to gib
 562                 self.event_damage(inflictor, attacker, 0, deathtype, hitloc, force);
 563                 // set up to fade out later
 564                 SUB_SetFade (self, time + 12 + random () * 4, 1);
 565
 566                 // remove laserdot
 567                 if(self.weaponentity)
 568                         if(self.weaponentity.lasertarget)
 569                                 remove(self.weaponentity.lasertarget);
 570
 571                 if(clienttype(self) == CLIENTTYPE_REAL)
 572                 {
 573                         self.fixangle = TRUE;
 574                         //msg_entity = self;
 575                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 576                         //WriteAngle (MSG_ONE, self.v_angle_x);
 577                         //WriteAngle (MSG_ONE, self.v_angle_y);
 578                         //WriteAngle (MSG_ONE, 80);
 579                 }
 580
 581                 if(g_arena)
 582                         Spawnqueue_Unmark(self);
 583
 584                 if(defer_ClientKill_Now_TeamChange)
 585                         ClientKill_Now_TeamChange();
 586
 587                 if(sv_gentle > 0) {
 588                         // remove corpse
 589                         PlayerCorpseDamage (inflictor, attacker, 100.0, deathtype, hitloc, force);
 590                         pointparticles(particleeffectnum("damage_dissolve"), self.origin, force, 1);
 591                 }
 592         }
 593 }
 594
 595 float UpdateSelectedPlayer_countvalue(float v)
 596 {
 597         return max(0, (v - 1.0) / 0.5);
 598 }
 599
 600 // returns: -2 if no hit, otherwise cos of the angle
 601 // uses the global v_angle
 602 float UpdateSelectedPlayer_canSee(entity p, float mincosangle, float maxdist)
 603 {
 604         vector so, d;
 605         float c;
 606
 607         if(p == self)
 608                 return -2;
 609
 610         if(p.deadflag)
 611                 return -2;
 612
 613         so = self.origin + self.view_ofs;
 614         d = p.origin - so;
 615
 616         // misaimed?
 617         if(dist_point_line(d, '0 0 0', v_forward) > maxdist)
 618                 return -2;
 619
 620         // now find the cos of the angle...
 621         c = normalize(d) * v_forward;
 622
 623         if(c <= mincosangle)
 624                 return -2;
 625
 626         traceline(so, p.origin, MOVE_NOMONSTERS, self);
 627         if(trace_fraction < 1)
 628                 return -2;
 629
 630         return c;
 631 }
 632
 633 void ClearSelectedPlayer()
 634 {
 635         if(self.selected_player)
 636         {
 637                 centerprint_expire(self, CENTERPRIO_POINT);
 638                 self.selected_player = world;
 639                 self.selected_player_display_needs_update = FALSE;
 640         }
 641 }
 642
 643 void UpdateSelectedPlayer()
 644 {
 645         entity selected;
 646         float selected_score;
 647         selected = world;
 648         selected_score = 0.95; // 18 degrees
 649
 650         if(!cvar("sv_allow_shownames"))
 651                 return;
 652
 653         if(clienttype(self) != CLIENTTYPE_REAL)
 654                 return;
 655
 656         if(self.cvar_cl_shownames == 0)
 657                 return;
 658
 659         if(self.cvar_cl_shownames == 1 && !teams_matter)
 660                 return;
 661
 662         makevectors(self.v_angle); // sets v_forward
 663
 664         // 1. cursor trace is always right
 665         if(self.cursor_trace_ent && self.cursor_trace_ent.classname == "player" && !self.cursor_trace_ent.deadflag)
 666         {
 667                 selected = self.cursor_trace_ent;
 668         }
 669         else
 670         {
 671                 // 2. if we don't have a cursor trace, find the player which is least
 672                 //    mis-aimed at
 673                 entity p;
 674                 FOR_EACH_PLAYER(p)
 675                 {
 676                         float c;
 677                         c = UpdateSelectedPlayer_canSee(p, selected_score, 100); // 100 = 2.5 meters
 678                         if(c >= -1)
 679                         {
 680                                 selected = p;
 681                                 selected_score = c;
 682                         }
 683                 }
 684         }
 685
 686         if(selected)
 687         {
 688                 self.selected_player_display_timeout = time + self.cvar_scr_centertime;
 689         }
 690         else
 691         {
 692                 if(time < self.selected_player_display_timeout)
 693                         if(UpdateSelectedPlayer_canSee(self.selected_player, 0.7, 200) >= -1) // 5 meters, 45 degrees
 694                                 selected = self.selected_player;
 695         }
 696
 697         if(selected)
 698         {
 699                 if(selected == self.selected_player)
 700                 {
 701                         float save;
 702                         save = UpdateSelectedPlayer_countvalue(self.selected_player_count);
 703                         self.selected_player_count = self.selected_player_count + frametime;
 704                         if(save != UpdateSelectedPlayer_countvalue(self.selected_player_count))
 705                         {
 706                                 string namestr, healthstr;
 707                                 namestr = playername(selected);
 708                                 if(teams_matter)
 709                                 {
 710                                         healthstr = ftos(floor(selected.health));
 711                                         if(self.team == selected.team)
 712                                         {
 713                                                 namestr = strcat(namestr, " (", healthstr, "%)");
 714                                                 self.selected_player_display_needs_update = TRUE;
 715                                         }
 716                                 }
 717                                 centerprint_atprio(self, CENTERPRIO_POINT, namestr);
 718                         }
 719                 }
 720                 else
 721                 {
 722                         ClearSelectedPlayer();
 723                         self.selected_player = selected;
 724                         self.selected_player_time = time;
 725                         self.selected_player_count = 0;
 726                         self.selected_player_display_needs_update = FALSE;
 727                 }
 728         }
 729         else
 730         {
 731                 ClearSelectedPlayer();
 732         }
 733
 734         if(self.selected_player)
 735                 self.last_selected_player = self.selected_player;
 736 }
 737
 738 float GetVoiceMessageTeamsayType(string type)
 739 {
 740         if(type == "taunt")
 741                 return 0;
 742         if(type == "teamshoot")
 743                 return 2;
 744         return 1;
 745 }
 746
 747 string allvoicesamples = "attack attackinfive coverme defend freelance incoming meet needhelp seenflag taunt teamshoot";
 748 float GetPlayerSoundSampleField_notFound;
 749 float GetPlayerSoundSampleField_fixed;
 750 .string GetVoiceMessageSampleField(string type)
 751 {
 752         GetPlayerSoundSampleField_notFound = 0;
 753         GetPlayerSoundSampleField_fixed = 0;
 754         switch(type)
 755         {
 756                 case "attack":       return playersound_attack;
 757                 case "attackinfive": return playersound_attackinfive;
 758                 case "coverme":      return playersound_coverme;
 759                 case "defend":       return playersound_defend;
 760                 case "freelance":    return playersound_freelance;
 761                 case "incoming":     return playersound_incoming;
 762                 case "meet":         return playersound_meet;
 763                 case "needhelp":     return playersound_needhelp;
 764                 case "seenflag":     return playersound_seenflag;
 765                 case "taunt":        return playersound_taunt;
 766                 case "teamshoot":    return playersound_teamshoot;
 767         }
 768         GetPlayerSoundSampleField_notFound = 1;
 769         return playersound_taunt;
 770 }
 771
 772 .string GetPlayerSoundSampleField(string type)
 773 {
 774         GetPlayerSoundSampleField_notFound = 0;
 775         GetPlayerSoundSampleField_fixed = 0;
 776         switch(type)
 777         {
 778                 case "death":        return playersound_death;
 779                 case "drown":        return playersound_drown;
 780                 case "falling":      return playersound_falling;
 781                 case "gasp":         return playersound_gasp;
 782                 case "jump":         return playersound_jump;
 783                 case "pain25":       return playersound_pain25;
 784                 case "pain50":       return playersound_pain50;
 785                 case "pain75":       return playersound_pain75;
 786                 case "pain100":      return playersound_pain100;
 787         }
 788         GetPlayerSoundSampleField_notFound = 1;
 789         return playersound_taunt;
 790 }
 791
 792 void PrecacheGlobalSound(string samplestring)
 793 {
 794         float n, i;
 795         tokenize(samplestring);
 796         n = stof(argv(1));
 797         if(n > 0)
 798         {
 799                 for(i = 1; i <= n; ++i)
 800                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
 801         }
 802         else
 803         {
 804                 precache_sound(strcat(argv(0), ".wav"));
 805         }
 806 }
 807
 808 void PrecachePlayerSounds(string f)
 809 {
 810         float fh;
 811         string s;
 812         fh = fopen(f, FILE_READ);
 813         if(fh < 0)
 814                 return;
 815         while((s = fgets(fh)))
 816         {
 817                 if(tokenize(s) != 3)
 818                 {
 819                         dprint("Invalid sound info line: ", s, "\n");
 820                         continue;
 821                 }
 822                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
 823         }
 824         fclose(fh);
 825 }
 826
 827 void ClearPlayerSounds()
 828 {
 829         if(self.playersound_attack      ) { strunzone(self.playersound_attack      ); self.playersound_attack = string_null; }
 830         if(self.playersound_attackinfive) { strunzone(self.playersound_attackinfive); self.playersound_attackinfive = string_null; }
 831         if(self.playersound_coverme     ) { strunzone(self.playersound_coverme     ); self.playersound_coverme = string_null; }
 832         if(self.playersound_defend      ) { strunzone(self.playersound_defend      ); self.playersound_defend = string_null; }
 833         if(self.playersound_freelance   ) { strunzone(self.playersound_freelance   ); self.playersound_freelance = string_null; }
 834         if(self.playersound_incoming    ) { strunzone(self.playersound_incoming    ); self.playersound_incoming = string_null; }
 835         if(self.playersound_meet        ) { strunzone(self.playersound_meet        ); self.playersound_meet = string_null; }
 836         if(self.playersound_needhelp    ) { strunzone(self.playersound_needhelp    ); self.playersound_needhelp = string_null; }
 837         if(self.playersound_seenflag    ) { strunzone(self.playersound_seenflag    ); self.playersound_seenflag = string_null; }
 838         if(self.playersound_taunt       ) { strunzone(self.playersound_taunt       ); self.playersound_taunt = string_null; }
 839         if(self.playersound_teamshoot   ) { strunzone(self.playersound_teamshoot   ); self.playersound_teamshoot = string_null; }
 840         if(self.playersound_death       ) { strunzone(self.playersound_death       ); self.playersound_death = string_null; }
 841         if(self.playersound_drown       ) { strunzone(self.playersound_drown       ); self.playersound_drown = string_null; }
 842         if(self.playersound_falling     ) { strunzone(self.playersound_falling     ); self.playersound_falling = string_null; }
 843         if(self.playersound_gasp        ) { strunzone(self.playersound_gasp        ); self.playersound_gasp = string_null; }
 844         if(self.playersound_jump        ) { strunzone(self.playersound_jump        ); self.playersound_jump = string_null; }
 845         if(self.playersound_pain25      ) { strunzone(self.playersound_pain25      ); self.playersound_pain25 = string_null; }
 846         if(self.playersound_pain50      ) { strunzone(self.playersound_pain50      ); self.playersound_pain50 = string_null; }
 847         if(self.playersound_pain75      ) { strunzone(self.playersound_pain75      ); self.playersound_pain75 = string_null; }
 848         if(self.playersound_pain100     ) { strunzone(self.playersound_pain100     ); self.playersound_pain100 = string_null; }
 849 }
 850
 851 void LoadPlayerSounds(string f, float first)
 852 {
 853         float fh;
 854         string s;
 855         var .string field;
 856         fh = fopen(f, FILE_READ);
 857         if(fh < 0)
 858                 return;
 859         while((s = fgets(fh)))
 860         {
 861                 if(tokenize(s) != 3)
 862                         continue;
 863                 field = GetPlayerSoundSampleField(argv(0));
 864                 if(GetPlayerSoundSampleField_notFound)
 865                         field = GetVoiceMessageSampleField(argv(0));
 866                 if(GetPlayerSoundSampleField_notFound)
 867                         continue;
 868                 if(GetPlayerSoundSampleField_fixed)
 869                         if not(first)
 870                                 continue;
 871                 if(self.field)
 872                         strunzone(self.field);
 873                 self.field = strzone(strcat(argv(1), " ", argv(2)));
 874         }
 875         fclose(fh);
 876 }
 877
 878 .float modelindex_for_playersound;
 879 void UpdatePlayerSounds()
 880 {
 881         if(self.modelindex == self.modelindex_for_playersound)
 882                 return;
 883         self.modelindex_for_playersound = self.modelindex;
 884         ClearPlayerSounds();
 885         LoadPlayerSounds("sound/player/default.sounds", 1);
 886         LoadPlayerSounds(strcat(self.model, ".sounds"), 0);
 887 }
 888
 889 void GlobalSound(string sample, float chan, float teamsay)
 890 {
 891         float n;
 892
 893         if(sample == "")
 894                 return;
 895
 896         tokenize(sample);
 897         n = stof(argv(1));
 898         if(n > 0)
 899                 sample = strcat(argv(0), ftos(ceil(random() * n)), ".wav"); // randomization
 900         else
 901                 sample = strcat(argv(0), ".wav"); // randomization
 902
 903         if(teamsay == 2) // only to last attacker
 904         {
 905                 if(teams_matter)
 906                         if(self.pusher)
 907                                 if(self.pusher.team == self.team)
 908                                 {
 909                                         msg_entity = self.pusher;
 910                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
 911                                         msg_entity = self;
 912                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
 913                                 }
 914         }
 915         else if(teamsay == 0) // to everyone
 916         {
 917                 // broadcast the sound, but it's directional
 918                 sound(self, chan, sample, VOL_BASE, ATTN_NORM);
 919         }
 920         else if(teamsay == 1) // to the same team
 921         {
 922                 if(teams_matter)
 923                 {
 924                         entity e;
 925                         FOR_EACH_REALCLIENT(e)
 926                                 if(!teams_matter || e.team == self.team)
 927                                 {
 928                                         msg_entity = e;
 929                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
 930                                 }
 931                 }
 932                 else
 933                 {
 934                         sound(self, chan, sample, VOL_BASE, ATTN_NONE);
 935                 }
 936         }
 937 }
 938
 939 void PlayerSound(.string samplefield, float chan, float teamsay)
 940 {
 941         string sample;
 942         sample = self.samplefield;
 943         GlobalSound(sample, chan, teamsay);
 944 }
 945
 946 void VoiceMessage(string type)
 947 {
 948         var .string sample;
 949         var float teamsay;
 950         sample = GetVoiceMessageSampleField(type);
 951
 952         if(GetPlayerSoundSampleField_notFound)
 953         {
 954                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
 955                 return;
 956         }
 957
 958         teamsay = GetVoiceMessageTeamsayType(type);
 959
 960         PlayerSound(sample, CHAN_VOICE, teamsay);
 961 }