data/qcsrc/server/cl_player.qc

   1
   2 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
   3 // merged player_run and player_stand to player_anim
   4 // added death animations to player_anim
   5 // can now spawn thrown weapons from anywhere, not just from players
   6 // thrown weapons now fade out after 20 seconds
   7 // created PlayerGib function
   8 // PlayerDie no longer uses hitloc or damage
   9 // PlayerDie now supports dying animations as well as gibbing
  10 // cleaned up PlayerDie a lot
  11 // added CopyBody
  12
  13 .entity pusher;
  14 .float pushltime;
  15
  16 void CopyBody(float keepvelocity)
  17 {
  18         local entity oldself;
  19         if (self.effects & EF_NODRAW)
  20                 return;
  21         oldself = self;
  22         self = spawn();
  23         self.colormap = oldself.colormap;
  24         self.iscreature = oldself.iscreature;
  25         self.angles = oldself.angles;
  26         self.avelocity = oldself.avelocity;
  27         self.classname = "body";
  28         self.damageforcescale = oldself.damageforcescale;
  29         self.effects = oldself.effects;
  30         self.event_damage = oldself.event_damage;
  31         self.animstate_startframe = oldself.animstate_startframe;
  32         self.animstate_numframes = oldself.animstate_numframes;
  33         self.animstate_framerate = oldself.animstate_framerate;
  34         self.animstate_starttime = oldself.animstate_starttime;
  35         self.animstate_endtime = oldself.animstate_endtime;
  36         self.animstate_override = oldself.animstate_override;
  37         self.animstate_looping = oldself.animstate_looping;
  38         self.frame = oldself.frame;
  39         self.dead_frame = oldself.dead_frame;
  40         self.pain_finished = oldself.pain_finished;
  41         self.health = oldself.health;
  42         self.armorvalue = oldself.armorvalue;
  43         self.armortype = oldself.armortype;
  44         self.model = oldself.model;
  45         self.modelindex = oldself.modelindex;
  46         self.movetype = oldself.movetype;
  47         self.nextthink = oldself.nextthink;
  48         self.skin = oldself.skin;
  49         self.solid = oldself.solid;
  50         self.takedamage = oldself.takedamage;
  51         self.think = oldself.think;
  52         self.gibrandom = oldself.gibrandom;
  53         self.customizeentityforclient = oldself.customizeentityforclient;
  54         if (keepvelocity == 1)
  55                 self.velocity = oldself.velocity;
  56         self.oldvelocity = self.velocity;
  57         self.fade_time = oldself.fade_time;
  58         self.fade_rate = oldself.fade_rate;
  59         //self.weapon = oldself.weapon;
  60         setorigin(self, oldself.origin);
  61         setsize(self, oldself.mins, oldself.maxs);
  62         self.oldorigin = oldself.origin;
  63         self = oldself;
  64 }
  65
  66 float animparseerror;
  67 vector(float animfile) animparseline =
  68 {
  69         local string line;
  70         local float c;
  71         local vector anim;
  72         if (animfile < 0)
  73                 return '0 1 2';
  74         line = fgets(animfile);
  75         c = tokenize(line);
  76         if (c != 3)
  77         {
  78                 animparseerror = TRUE;
  79                 return '0 1 2';
  80         }
  81         anim_x = stof(argv(0));
  82         anim_y = stof(argv(1));
  83         anim_z = stof(argv(2));
  84         // don't allow completely bogus values
  85         if (anim_x < 0 || anim_y < 1 || anim_z < 0.001)
  86                 anim = '0 1 2';
  87         return anim;
  88 };
  89
  90 void() player_setupanimsformodel =
  91 {
  92         local string animfilename;
  93         local float animfile;
  94         // defaults for legacy .zym models without animinfo files
  95         self.anim_die1 = '0 1 0.5'; // 2 seconds
  96         self.anim_die2 = '1 1 0.5'; // 2 seconds
  97         self.anim_draw = '2 1 3'; // TODO: analyze models and set framerate
  98         self.anim_duck = '3 1 100'; // this anim seems bogus in most models, so make it play VERY briefly!
  99         self.anim_duckwalk = '4 1 1';
 100         self.anim_duckjump = '5 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 101         self.anim_duckidle = '6 1 1';
 102         self.anim_idle = '7 1 1';
 103         self.anim_jump = '8 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 104         self.anim_pain1 = '9 1 2'; // 0.5 seconds
 105         self.anim_pain2 = '10 1 2'; // 0.5 seconds
 106         self.anim_shoot = '11 1 5'; // TODO: analyze models and set framerate
 107         self.anim_taunt = '12 1 1'; // FIXME?  there is no code using this anim
 108         self.anim_run = '13 1 1';
 109         self.anim_runbackwards = '14 1 1';
 110         self.anim_strafeleft = '15 1 1';
 111         self.anim_straferight = '16 1 1';
 112         self.anim_dead1 = '17 1 1';
 113         self.anim_dead2 = '18 1 1';
 114         self.anim_forwardright = '19 1 1';
 115         self.anim_forwardleft = '20 1 1';
 116         self.anim_backright = '21 1 1';
 117         self.anim_backleft  = '22 1 1';
 118         animparseerror = FALSE;
 119         animfilename = strcat(self.model, ".animinfo");
 120         animfile = fopen(animfilename, FILE_READ);
 121         if (animfile >= 0)
 122         {
 123                 self.anim_die1         = animparseline(animfile);
 124                 self.anim_die2         = animparseline(animfile);
 125                 self.anim_draw         = animparseline(animfile);
 126                 self.anim_duck         = animparseline(animfile);
 127                 self.anim_duckwalk     = animparseline(animfile);
 128                 self.anim_duckjump     = animparseline(animfile);
 129                 self.anim_duckidle     = animparseline(animfile);
 130                 self.anim_idle         = animparseline(animfile);
 131                 self.anim_jump         = animparseline(animfile);
 132                 self.anim_pain1        = animparseline(animfile);
 133                 self.anim_pain2        = animparseline(animfile);
 134                 self.anim_shoot        = animparseline(animfile);
 135                 self.anim_taunt        = animparseline(animfile);
 136                 self.anim_run          = animparseline(animfile);
 137                 self.anim_runbackwards = animparseline(animfile);
 138                 self.anim_strafeleft   = animparseline(animfile);
 139                 self.anim_straferight  = animparseline(animfile);
 140                 self.anim_forwardright = animparseline(animfile);
 141                 self.anim_forwardleft  = animparseline(animfile);
 142                 self.anim_backright    = animparseline(animfile);
 143                 self.anim_backleft     = animparseline(animfile);
 144                 fclose(animfile);
 145
 146                 // derived anims
 147                 self.anim_dead1 = '0 1 1' + '1 0 0' * (self.anim_die1_x + self.anim_die1_y - 1);
 148                 self.anim_dead2 = '0 1 1' + '1 0 0' * (self.anim_die2_x + self.anim_die2_y - 1);
 149
 150                 if (animparseerror)
 151                         print("Parse error in ", animfilename, ", some player animations are broken\n");
 152         }
 153         else
 154                 dprint("File ", animfilename, " not found, assuming legacy .zym model animation timings\n");
 155         // reset animstate now
 156         player_setanim(self.anim_idle, TRUE, FALSE, TRUE);
 157 };
 158
 159 void(vector anim, float looping, float override, float restart) player_setanim =
 160 {
 161         if (!restart)
 162         if (anim_x == self.animstate_startframe)
 163         if (anim_y == self.animstate_numframes)
 164         if (anim_z == self.animstate_framerate)
 165                 return;
 166         self.animstate_startframe = anim_x;
 167         self.animstate_numframes = anim_y;
 168         self.animstate_framerate = anim_z;
 169         self.animstate_starttime = time;
 170         self.animstate_endtime = time + self.animstate_numframes / self.animstate_framerate;
 171         self.animstate_looping = looping;
 172         self.animstate_override = override;
 173         self.frame = self.animstate_startframe;
 174 };
 175
 176 void() player_updateframe =
 177 {
 178         if (time >= self.animstate_endtime)
 179         {
 180                 if (self.animstate_looping)
 181                 {
 182                         self.animstate_starttime = self.animstate_endtime;
 183                         self.animstate_endtime = self.animstate_endtime + self.animstate_numframes / self.animstate_framerate;
 184                 }
 185                 self.animstate_override = FALSE;
 186         }
 187         self.frame = self.animstate_startframe + bound(0, (time - self.animstate_starttime) * self.animstate_framerate, self.animstate_numframes - 1);
 188 };
 189
 190 void player_anim (void)
 191 {
 192         player_updateframe();
 193
 194         if (self.deadflag != DEAD_NO)
 195         {
 196                 if (time > self.animstate_endtime)
 197                 {
 198                         if (self.maxs_z > 5)
 199                         {
 200                                 self.maxs_z = 5;
 201                                 setsize(self, self.mins, self.maxs);
 202                         }
 203                         self.frame = self.dead_frame;
 204                 }
 205                 return;
 206         }
 207
 208         if (!self.animstate_override)
 209         {
 210                 if (!(self.flags & FL_ONGROUND))
 211                 {
 212                         if (self.crouch)
 213                                 player_setanim(self.anim_duckjump, FALSE, TRUE, FALSE);
 214                         else
 215                                 player_setanim(self.anim_jump, FALSE, TRUE, FALSE);
 216                 }
 217                 else if (self.crouch)
 218                 {
 219                         if (self.movement_x * self.movement_x + self.movement_y * self.movement_y > 20)
 220                                 player_setanim(self.anim_duckwalk, TRUE, FALSE, FALSE);
 221                         else
 222                                 player_setanim(self.anim_duckidle, TRUE, FALSE, FALSE);
 223                 }
 224                 else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
 225                 {
 226                         if (self.movement_x > 0 && self.movement_y == 0)
 227                                 player_setanim(self.anim_run, TRUE, FALSE, FALSE);
 228                         else if (self.movement_x < 0 && self.movement_y == 0)
 229                                 player_setanim(self.anim_runbackwards, TRUE, FALSE, FALSE);
 230                         else if (self.movement_x == 0 && self.movement_y > 0)
 231                                 player_setanim(self.anim_straferight, TRUE, FALSE, FALSE);
 232                         else if (self.movement_x == 0 && self.movement_y < 0)
 233                                 player_setanim(self.anim_strafeleft, TRUE, FALSE, FALSE);
 234                         else if (self.movement_x > 0 && self.movement_y > 0)
 235                                 player_setanim(self.anim_forwardright, TRUE, FALSE, FALSE);
 236                         else if (self.movement_x > 0 && self.movement_y < 0)
 237                                 player_setanim(self.anim_forwardleft, TRUE, FALSE, FALSE);
 238                         else if (self.movement_x < 0 && self.movement_y > 0)
 239                                 player_setanim(self.anim_backright, TRUE, FALSE, FALSE);
 240                         else if (self.movement_x < 0 && self.movement_y < 0)
 241                                 player_setanim(self.anim_backleft, TRUE, FALSE, FALSE);
 242                         else
 243                                 player_setanim(self.anim_run, TRUE, FALSE, FALSE);
 244                 }
 245                 else
 246                         player_setanim(self.anim_idle, TRUE, FALSE, FALSE);
 247         }
 248 }
 249 //End change by Supajoe on 11:44 PM EST 11/16/03 (Subject: Player animations)
 250
 251 void SpawnThrownWeapon (vector org, float w)
 252 {
 253         if (!cvar("g_pickup_items"))
 254         if (!g_minstagib)
 255                 return;
 256         if (!w)
 257                 return;
 258         if (w == IT_LASER)
 259                 return;
 260
 261         W_ThrowWeapon(randomvec() * 100 + '0 0 200', org - self.origin, FALSE);
 262 }
 263
 264 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 265 {
 266         local float take, save;
 267         pointparticles(particleeffectnum("blood"), hitloc, force, bound(0, damage, 200));
 268         // damage resistance (ignore most of the damage from a bullet or similar)
 269         damage = max(damage - 5, 1);
 270
 271         save = bound(0, damage * cvar("g_balance_armor_blockpercent"), self.armorvalue);
 272         take = bound(0, damage - save, damage);
 273
 274         if (save > 10)
 275                 sound (self, CHAN_IMPACT, "misc/armorimpact.wav", 1, ATTN_NORM);
 276         else if (take > 30)
 277                 sound (self, CHAN_IMPACT, "misc/bodyimpact2.wav", 1, ATTN_NORM);
 278         else if (take > 10)
 279                 sound (self, CHAN_IMPACT, "misc/bodyimpact1.wav", 1, ATTN_NORM);
 280
 281         if (take > 50)
 282                 TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.1,1);
 283         if (take > 100)
 284                 TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.2,1);
 285
 286         if (!(self.flags & FL_GODMODE))
 287         {
 288                 self.armorvalue = self.armorvalue - save;
 289                 self.health = self.health - take;
 290                 // pause regeneration for 5 seconds
 291                 self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
 292         }
 293         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 294         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 295         self.dmg_inflictor = inflictor;
 296
 297         if (self.health <= -50)
 298         {
 299                 // don't use any animations as a gib
 300                 self.frame = 0;
 301                 self.dead_frame = 0;
 302                 // view just above the floor
 303                 self.view_ofs = '0 0 4';
 304
 305                 // make a juicy mess
 306                 local float multiplier;
 307                 multiplier = 1;
 308                 if (cvar("ekg"))
 309                         multiplier = 5;
 310                 te_bloodshower (self.origin + self.mins, self.origin + self.maxs, 1200 * multiplier, 1000);
 311
 312                 // make a meaty mess
 313                 TossGib (self, "models/gibs/eye.md3", self.origin, self.velocity,0);
 314                 TossGib (world, "models/gibs/bloodyskull.md3", self.origin, '0 0 600',0);
 315
 316                 local float c;
 317                 c = 0;
 318                 while (c < multiplier)
 319                 {
 320                         c = c + 1;
 321                         TossGib (world, "models/gibs/gib1.md3", self.origin, self.velocity,0);
 322                         //TossGib (world, "models/gibs/gib2.md3", self.origin, self.velocity,0);
 323                         TossGib (world, "models/gibs/gib1.mdl", self.origin, self.velocity,0);
 324                         //TossGib (world, "models/gibs/gib3.md3", self.origin, self.velocity,0);
 325                         TossGib (world, "models/gibs/gib2.mdl", self.origin, self.velocity,0);
 326                         //TossGib (world, "models/gibs/gib4.md3", self.origin, self.velocity,0);
 327                         TossGib (world, "models/gibs/gib3.mdl", self.origin, self.velocity,0);
 328
 329                         // these destory on impact
 330                         TossGib (world, "models/gibs/gib5.md3", self.origin, '-500 0 450',1);
 331                         //TossGib (world, "models/gibs/gib6.md3", self.origin, '0 500 450',1);
 332                         TossGib (world, "models/gibs/chunk.mdl", self.origin, '0 -500 450',1);
 333                         TossGib (world, "models/gibs/chunk.mdl", self.origin, '500 0 450',1);
 334                         TossGib (world, "models/gibs/chunk.mdl", self.origin, self.velocity,1);
 335                         TossGib (world, "models/gibs/chunk.mdl", self.origin, '0 0 450',1);
 336                 }
 337
 338                 sound (self, CHAN_VOICE, "misc/gib.wav", 1, ATTN_NORM);
 339         }
 340 }
 341
 342 void ClientKill_Now_TeamChange();
 343
 344 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 345 {
 346         local float take, save, waves, sdelay;
 347
 348         damage = damage * bound(1.0, self.cvar_cl_handicap, 100.0);
 349
 350         pointparticles(particleeffectnum("blood"), hitloc, force, bound(0, damage, 200));
 351         if (self.pain_finished < time)          //Don't switch pain sequences like crazy
 352         {
 353                 if (random() > 0.5)
 354                         player_setanim(self.anim_pain1, FALSE, TRUE, TRUE);
 355                 else
 356                         player_setanim(self.anim_pain2, FALSE, TRUE, TRUE);
 357                 self.pain_finished = time + 0.5;        //Supajoe
 358
 359                 // throw off bot aim temporarily
 360                 local float shake;
 361                 shake = damage * 5 / (bound(0,skill,100) + 1);
 362                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 363                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 364         }
 365
 366         if(g_arena)
 367         if(numspawned < 2)
 368                 return;
 369
 370         if (!g_minstagib)
 371         {
 372                 save = bound(0, damage * cvar("g_balance_armor_blockpercent"), self.armorvalue);
 373                 take = bound(0, damage - save, damage);
 374         }
 375         else
 376         {
 377                 save = 0;
 378                 take = damage;
 379         }
 380
 381         if (save > 10)
 382                 sound (self, CHAN_IMPACT, "misc/armorimpact.wav", 1, ATTN_NORM);
 383         else if (take > 30)
 384                 sound (self, CHAN_IMPACT, "misc/bodyimpact2.wav", 1, ATTN_NORM);
 385         else if (take > 10)
 386                 sound (self, CHAN_IMPACT, "misc/bodyimpact1.wav", 1, ATTN_NORM);
 387
 388         if (take > 50)
 389                 TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.1,1);
 390         if (take > 100)
 391                 TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.2,1);
 392
 393         if (time > self.spawnshieldtime)
 394         {
 395                 if (!(self.flags & FL_GODMODE))
 396                 {
 397                         self.armorvalue = self.armorvalue - save;
 398                         self.health = self.health - take;
 399                         // pause regeneration for 5 seconds
 400                         self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
 401                 }
 402                 else
 403                         self.max_armorvalue += (save + take);
 404         }
 405         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 406         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 407         self.dmg_inflictor = inflictor;
 408
 409         if(attacker == self)
 410         {
 411                 // don't reset pushltime for self damage as it may be an attempt to
 412                 // escape a lava pit or similar
 413                 //self.pushltime = 0;
 414         }
 415         else if(attacker.classname == "player" || attacker.classname == "gib")
 416         {
 417                 self.pusher = attacker;
 418                 self.pushltime = time + cvar("g_maxpushtime");
 419         }
 420         else if(time < self.pushltime)
 421         {
 422                 attacker = self.pusher;
 423                 self.pushltime = max(self.pushltime, time + 0.6);
 424         }
 425         else
 426                 self.pushltime = 0;
 427
 428         if (self.health < 1)
 429         {
 430                 float defer_ClientKill_Now_TeamChange;
 431                 defer_ClientKill_Now_TeamChange = FALSE;
 432
 433                 self.deaths += 1;
 434
 435                 // get rid of kill indicator
 436                 if(self.killindicator)
 437                 {
 438                         remove(self.killindicator);
 439                         self.killindicator = world;
 440                         if(self.killindicator_teamchange)
 441                                 defer_ClientKill_Now_TeamChange = TRUE;
 442                 }
 443
 444                 // become fully visible
 445                 self.alpha = 1;
 446                 // clear selected player display
 447                 ClearSelectedPlayer();
 448                 // throw a weapon
 449                 SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 450                 // print an obituary message
 451                 Obituary (attacker, self, deathtype);
 452                 DropAllRunes(self);
 453                 if(self == attacker)
 454                         kh_Key_DropAll(self, TRUE);
 455                 else if(attacker.classname == "player" || attacker.classname == "gib")
 456                         kh_Key_DropAll(self, FALSE);
 457                 else
 458                         kh_Key_DropAll(self, TRUE);
 459                 if(self.flagcarried)
 460                         DropFlag(self.flagcarried);
 461                 // clear waypoints
 462                 WaypointSprite_PlayerDead();
 463                 // make the corpse upright (not tilted)
 464                 self.angles_x = 0;
 465                 self.angles_z = 0;
 466                 // don't spin
 467                 self.avelocity = '0 0 0';
 468                 // view from the floor
 469                 self.view_ofs = '0 0 -8';
 470                 // toss the corpse
 471                 self.movetype = MOVETYPE_TOSS;
 472                 // shootable corpse
 473                 self.solid = SOLID_CORPSE;
 474                 // don't stick to the floor
 475                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 476                 // dying animation
 477                 self.deadflag = DEAD_DYING;
 478                 // when to allow respawn
 479                 sdelay = 0;
 480                 waves = 0;
 481                 if(cvar("g_respawn_mapsettings"))
 482                 {
 483                         sdelay = cvar("g_respawn_mapsettings_delay");
 484                         waves = cvar("g_respawn_mapsettings_waves");
 485                 }
 486                 if(!sdelay)
 487                         sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 488                 if(!sdelay)
 489                         sdelay = cvar("g_respawn_delay");
 490                 if(!waves)
 491                         waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 492                 if(!waves)
 493                         waves = cvar("g_respawn_waves");
 494                 if(waves)
 495                         self.death_time = ceil((time + sdelay) / waves) * waves;
 496                 else
 497                         self.death_time = time + sdelay;
 498                 if((sdelay + waves >= 5.0) && (self.death_time - time > 1.75))
 499                         self.respawn_countdown = 10; // first number to count down from is 10
 500                 else
 501                         self.respawn_countdown = -1; // do not count down
 502                 if (random() < 0.5)
 503                 {
 504                         player_setanim(self.anim_die1, FALSE, TRUE, TRUE);
 505                         self.dead_frame = self.anim_dead1_x;
 506                 }
 507                 else
 508                 {
 509                         player_setanim(self.anim_die2, FALSE, TRUE, TRUE);
 510                         self.dead_frame = self.anim_dead2_x;
 511                 }
 512                 // set damage function to corpse damage
 513                 self.event_damage = PlayerCorpseDamage;
 514                 // call the corpse damage function just in case it wants to gib
 515                 self.event_damage(inflictor, attacker, 0, deathtype, hitloc, force);
 516                 // set up to fade out later
 517                 SUB_SetFade (self, time + 12 + random () * 4, 1);
 518
 519                 // remove laserdot
 520                 if(self.weaponentity)
 521                         if(self.weaponentity.lasertarget)
 522                                 remove(self.weaponentity.lasertarget);
 523
 524                 if(clienttype(self) == CLIENTTYPE_REAL)
 525                 {
 526                         self.fixangle = TRUE;
 527                         //msg_entity = self;
 528                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 529                         //WriteAngle (MSG_ONE, self.v_angle_x);
 530                         //WriteAngle (MSG_ONE, self.v_angle_y);
 531                         //WriteAngle (MSG_ONE, 80);
 532                 }
 533
 534                 if(g_arena)
 535                         Spawnqueue_Unmark(self);
 536
 537                 if(defer_ClientKill_Now_TeamChange)
 538                         ClientKill_Now_TeamChange();
 539         }
 540 }
 541
 542 float UpdateSelectedPlayer_countvalue(float v)
 543 {
 544         return max(0, (v - 1.0) / 0.5);
 545 }
 546
 547 // returns: -2 if no hit, otherwise cos of the angle
 548 // uses the global v_angle
 549 float UpdateSelectedPlayer_canSee(entity p, float mincosangle, float maxdist)
 550 {
 551         vector so, d;
 552         float c;
 553
 554         if(p == self)
 555                 return -2;
 556
 557         if(p.deadflag)
 558                 return -2;
 559
 560         so = self.origin + self.view_ofs;
 561         d = p.origin - so;
 562
 563         // misaimed?
 564         if(dist_point_line(d, '0 0 0', v_forward) > maxdist)
 565                 return -2;
 566
 567         // now find the cos of the angle...
 568         c = normalize(d) * v_forward;
 569
 570         if(c <= mincosangle)
 571                 return -2;
 572
 573         traceline(so, p.origin, MOVE_NOMONSTERS, self);
 574         if(trace_fraction < 1)
 575                 return -2;
 576
 577         return c;
 578 }
 579
 580 void ClearSelectedPlayer()
 581 {
 582         if(self.selected_player)
 583         {
 584                 centerprint_expire(self, CENTERPRIO_POINT);
 585                 self.selected_player = world;
 586                 self.selected_player_display_needs_update = FALSE;
 587         }
 588 }
 589
 590 void UpdateSelectedPlayer()
 591 {
 592         entity selected;
 593         float selected_score;
 594         selected = world;
 595         selected_score = 0.95; // 18 degrees
 596
 597         if(!cvar("sv_allow_shownames"))
 598                 return;
 599
 600         if(clienttype(self) != CLIENTTYPE_REAL)
 601                 return;
 602
 603         if(self.cvar_cl_shownames == 0)
 604                 return;
 605
 606         if(self.cvar_cl_shownames == 1 && !teams_matter)
 607                 return;
 608
 609         makevectors(self.v_angle); // sets v_forward
 610
 611         // 1. cursor trace is always right
 612         if(self.cursor_trace_ent && self.cursor_trace_ent.classname == "player" && !self.cursor_trace_ent.deadflag)
 613         {
 614                 selected = self.cursor_trace_ent;
 615         }
 616         else
 617         {
 618                 // 2. if we don't have a cursor trace, find the player which is least
 619                 //    mis-aimed at
 620                 entity p;
 621                 FOR_EACH_PLAYER(p)
 622                 {
 623                         float c;
 624                         c = UpdateSelectedPlayer_canSee(p, selected_score, 100); // 100 = 2.5 meters
 625                         if(c >= -1)
 626                         {
 627                                 selected = p;
 628                                 selected_score = c;
 629                         }
 630                 }
 631         }
 632
 633         if(selected)
 634         {
 635                 self.selected_player_display_timeout = time + self.cvar_scr_centertime;
 636         }
 637         else
 638         {
 639                 if(time < self.selected_player_display_timeout)
 640                         if(UpdateSelectedPlayer_canSee(self.selected_player, 0.7, 200) >= -1) // 5 meters, 45 degrees
 641                                 selected = self.selected_player;
 642         }
 643
 644         if(selected)
 645         {
 646                 if(selected == self.selected_player)
 647                 {
 648                         float save;
 649                         save = UpdateSelectedPlayer_countvalue(self.selected_player_count);
 650                         self.selected_player_count = self.selected_player_count + frametime;
 651                         if(save != UpdateSelectedPlayer_countvalue(self.selected_player_count))
 652                         {
 653                                 string namestr, healthstr;
 654                                 namestr = playername(selected);
 655                                 if(teams_matter)
 656                                 {
 657                                         healthstr = ftos(floor(selected.health));
 658                                         if(self.team == selected.team)
 659                                         {
 660                                                 namestr = strcat(namestr, " (", healthstr, "%)");
 661                                                 self.selected_player_display_needs_update = TRUE;
 662                                         }
 663                                 }
 664                                 centerprint_atprio(self, CENTERPRIO_POINT, namestr);
 665                         }
 666                 }
 667                 else
 668                 {
 669                         ClearSelectedPlayer();
 670                         self.selected_player = selected;
 671                         self.selected_player_time = time;
 672                         self.selected_player_count = 0;
 673                         self.selected_player_display_needs_update = FALSE;
 674                 }
 675         }
 676         else
 677         {
 678                 ClearSelectedPlayer();
 679         }
 680
 681         if(self.selected_player)
 682                 self.last_selected_player = self.selected_player;
 683 }
 684
 685 float precache_sound_index (string s) = #19;
 686 void soundto(entity e, entity sounddest, float chan, string samp, float vol, float atten)
 687 {
 688         vector o;
 689         if(clienttype(sounddest) != CLIENTTYPE_REAL)
 690                 return;
 691         o = e.origin + 0.5 * (e.mins + e.maxs);
 692         msg_entity = sounddest;
 693         WriteByte(MSG_ONE, 6);
 694         WriteByte(MSG_ONE, 27); // all bits except SND_LOOPING
 695         WriteByte(MSG_ONE, vol * 255);
 696         WriteByte(MSG_ONE, atten * 64);
 697         WriteEntity(MSG_ONE, e);
 698         WriteByte(MSG_ONE, chan);
 699         WriteShort(MSG_ONE, precache_sound_index(samp));
 700         WriteCoord(MSG_ONE, o_x);
 701         WriteCoord(MSG_ONE, o_y);
 702         WriteCoord(MSG_ONE, o_z);
 703 }
 704
 705 #if 0
 706 .string playersound_attack;
 707 .string playersound_attackinfive;
 708 .string playersound_coverme;
 709 .string playersound_defend;
 710 .string playersound_freelance;
 711 .string playersound_incoming;
 712 .string playersound_meet;
 713 .string playersound_needhelp;
 714 .string playersound_seenflag;
 715 .string playersound_taunt;
 716 .string playersound_teamshoot;
 717 .float modelindex_for_playersound;
 718
 719 float GetVoiceMessageTeamsayType(string type)
 720 {
 721         if(type == "taunt")
 722                 return 0;
 723         if(type == "teamshoot")
 724                 return 2;
 725         return 1;
 726 }
 727
 728 string allvoicesamples = "attack attackinfive coverme defend freelance incoming meet needhelp seenflag taunt teamshoot";
 729 float GetPlayerSoundSampleField_notFound;
 730 .string GetVoiceMessageSampleField(string type)
 731 {
 732         GetPlayerSoundSampleField_notFound = 0;
 733         switch(type)
 734         {
 735                 case "attack":       return playersound_attack;
 736                 case "attackinfive": return playersound_attackinfive;
 737                 case "coverme":      return playersound_coverme;
 738                 case "defend":       return playersound_defend;
 739                 case "freelance":    return playersound_freelance;
 740                 case "incoming":     return playersound_incoming;
 741                 case "meet":         return playersound_meet;
 742                 case "needhelp":     return playersound_needhelp;
 743                 case "seenflag":     return playersound_seenflag;
 744                 case "taunt":        return playersound_taunt;
 745                 case "teamshoot":    return playersound_teamshoot;
 746         }
 747         GetPlayerSoundSampleField_notFound = 1;
 748         return playersound_taunt;
 749 }
 750
 751 .string GetPlayerSoundSampleField(string type)
 752 {
 753         GetPlayerSoundSampleField_notFound = 0;
 754         switch(type)
 755         {
 756                 case "attack":       return playersound_attack;
 757                 default:             return GetVoiceMessageSampleField(type);
 758         }
 759 }
 760
 761 void PrecachePlayerSounds(string f)
 762 {
 763         float fh;
 764         float i, n;
 765         string s;
 766         fh = fopen(f, FILE_READ);
 767         if(fh < 0)
 768                 return;
 769         while((s = fgets(fh)))
 770         {
 771                 if(tokenize(s) != 3)
 772                 {
 773                         dprint("Invalid sound info line: ", s, "\n");
 774                         continue;
 775                 }
 776                 n = stof(argv(2));
 777                 for(i = 1; i <= n; ++i)
 778                         precache_sound(strcat(argv(1), ftos(i), ".wav"));
 779         }
 780         fclose(fh);
 781 }
 782
 783 void LoadPlayerSounds(string f)
 784 {
 785         float fh;
 786         string s;
 787         var .string field;
 788         fh = fopen(f, FILE_READ);
 789         if(fh < 0)
 790                 return;
 791         while((s = fgets(fh)))
 792         {
 793                 if(tokenize(s) != 3)
 794                         continue;
 795                 field = GetPlayerSoundSampleField(argv(0));
 796                 if(GetPlayerSoundSampleField_notFound)
 797                         continue;
 798                 if(self.field)
 799                         strunzone(self.field);
 800                 self.field = strzone(strcat(argv(1), " ", argv(2)));
 801         }
 802         fclose(fh);
 803 }
 804
 805 void UpdatePlayerSounds()
 806 {
 807         if(self.modelindex == self.modelindex_for_playersound)
 808                 return;
 809         self.modelindex_for_playersound = self.modelindex;
 810         LoadPlayerSounds("sound/player/default.sounds");
 811         LoadPlayerSounds(strcat(self.model, ".sounds"));
 812 }
 813
 814 void VoiceMessage(string type)
 815 {
 816         // TODO precache voice messages?
 817         var string sample;
 818         var float teamsay;
 819         sample = self.(GetPlayerSoundSampleField(type));
 820
 821         if(GetPlayerSoundSampleField_notFound)
 822         {
 823                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
 824                 return;
 825         }
 826
 827         if(!sample)
 828                 return;
 829
 830         teamsay = GetVoiceMessageTeamsayType(type);
 831
 832         tokenize(sample);
 833         sample = strcat(argv(0), ftos(ceil(random() * stof(argv(1)))), ".wav"); // randomization
 834
 835         if(teamsay == 2)
 836         {
 837                 if(teams_matter)
 838                         if(self.pusher)
 839                                 if(self.pusher.team == self.team)
 840                                 {
 841                                         soundto(self, self.pusher, CHAN_VOICE, sample, 1, ATTN_NONE);
 842                                         soundto(self, self, CHAN_VOICE, sample, 1, ATTN_NONE);
 843                                 }
 844         }
 845         else if(teamsay == 0 || !teams_matter)
 846         {
 847                 // broadcast the sound, but it's directional
 848                 sound(self, CHAN_VOICE, sample, 1, ATTN_NORM);
 849         }
 850         else if(teamsay == 1)
 851         {
 852                 entity e;
 853                 FOR_EACH_REALCLIENT(e)
 854                         if(e.team == self.team)
 855                                 soundto(self, e, CHAN_VOICE, sample, 1, ATTN_NONE);
 856         }
 857 }
 858 #else
 859 void PrecachePlayerSounds(string f) { }
 860 void UpdatePlayerSounds() { }
 861 void VoiceMessage(string type) { sprint(self, "Sorry, voice command support is not done yet. Maybe later.\n"); }
 862 #endif