data/qcsrc/server/cl_player.qc

   1
   2 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
   3 // merged player_run and player_stand to player_anim
   4 // added death animations to player_anim
   5 // can now spawn thrown weapons from anywhere, not just from players
   6 // thrown weapons now fade out after 20 seconds
   7 // created PlayerGib function
   8 // PlayerDie no longer uses hitloc or damage
   9 // PlayerDie now supports dying animations as well as gibbing
  10 // cleaned up PlayerDie a lot
  11 // added CopyBody
  12
  13 .entity pusher;
  14 .float pushltime;
  15
  16 void CopyBody(float keepvelocity)
  17 {
  18         local entity oldself;
  19         if (self.effects & EF_NODRAW)
  20                 return;
  21         oldself = self;
  22         self = spawn();
  23         self.enemy = oldself;
  24         self.lip = oldself.lip;
  25         self.colormap = oldself.colormap;
  26         self.iscreature = oldself.iscreature;
  27         self.angles = oldself.angles;
  28         self.avelocity = oldself.avelocity;
  29         self.classname = "body";
  30         self.damageforcescale = oldself.damageforcescale;
  31         self.effects = oldself.effects;
  32         self.event_damage = oldself.event_damage;
  33         self.animstate_startframe = oldself.animstate_startframe;
  34         self.animstate_numframes = oldself.animstate_numframes;
  35         self.animstate_framerate = oldself.animstate_framerate;
  36         self.animstate_starttime = oldself.animstate_starttime;
  37         self.animstate_endtime = oldself.animstate_endtime;
  38         self.animstate_override = oldself.animstate_override;
  39         self.animstate_looping = oldself.animstate_looping;
  40         self.frame = oldself.frame;
  41         self.dead_frame = oldself.dead_frame;
  42         self.pain_finished = oldself.pain_finished;
  43         self.health = oldself.health;
  44         self.armorvalue = oldself.armorvalue;
  45         self.armortype = oldself.armortype;
  46         self.model = oldself.model;
  47         self.modelindex = oldself.modelindex;
  48         self.movetype = oldself.movetype;
  49         self.nextthink = oldself.nextthink;
  50         self.skin = oldself.skin;
  51         self.solid = oldself.solid;
  52         self.takedamage = oldself.takedamage;
  53         self.think = oldself.think;
  54         self.gibrandom = oldself.gibrandom;
  55         self.customizeentityforclient = oldself.customizeentityforclient;
  56         if (keepvelocity == 1)
  57                 self.velocity = oldself.velocity;
  58         self.oldvelocity = self.velocity;
  59         self.fade_time = oldself.fade_time;
  60         self.fade_rate = oldself.fade_rate;
  61         //self.weapon = oldself.weapon;
  62         setorigin(self, oldself.origin);
  63         setsize(self, oldself.mins, oldself.maxs);
  64         self.oldorigin = oldself.origin;
  65         self = oldself;
  66 }
  67
  68 float animparseerror;
  69 vector animparseline(float animfile)
  70 {
  71         local string line;
  72         local float c;
  73         local vector anim;
  74         if (animfile < 0)
  75                 return '0 1 2';
  76         line = fgets(animfile);
  77         c = tokenize(line);
  78         if (c != 3)
  79         {
  80                 animparseerror = TRUE;
  81                 return '0 1 2';
  82         }
  83         anim_x = stof(argv(0));
  84         anim_y = stof(argv(1));
  85         anim_z = stof(argv(2));
  86         // don't allow completely bogus values
  87         if (anim_x < 0 || anim_y < 1 || anim_z < 0.001)
  88                 anim = '0 1 2';
  89         return anim;
  90 };
  91
  92 void player_setupanimsformodel()
  93 {
  94         local string animfilename;
  95         local float animfile;
  96         // defaults for legacy .zym models without animinfo files
  97         self.anim_die1 = '0 1 0.5'; // 2 seconds
  98         self.anim_die2 = '1 1 0.5'; // 2 seconds
  99         self.anim_draw = '2 1 3'; // TODO: analyze models and set framerate
 100         self.anim_duck = '3 1 100'; // this anim seems bogus in most models, so make it play VERY briefly!
 101         self.anim_duckwalk = '4 1 1';
 102         self.anim_duckjump = '5 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 103         self.anim_duckidle = '6 1 1';
 104         self.anim_idle = '7 1 1';
 105         self.anim_jump = '8 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 106         self.anim_pain1 = '9 1 2'; // 0.5 seconds
 107         self.anim_pain2 = '10 1 2'; // 0.5 seconds
 108         self.anim_shoot = '11 1 5'; // TODO: analyze models and set framerate
 109         self.anim_taunt = '12 1 1'; // FIXME?  there is no code using this anim
 110         self.anim_run = '13 1 1';
 111         self.anim_runbackwards = '14 1 1';
 112         self.anim_strafeleft = '15 1 1';
 113         self.anim_straferight = '16 1 1';
 114         self.anim_dead1 = '17 1 1';
 115         self.anim_dead2 = '18 1 1';
 116         self.anim_forwardright = '19 1 1';
 117         self.anim_forwardleft = '20 1 1';
 118         self.anim_backright = '21 1 1';
 119         self.anim_backleft  = '22 1 1';
 120         animparseerror = FALSE;
 121         animfilename = strcat(self.model, ".animinfo");
 122         animfile = fopen(animfilename, FILE_READ);
 123         if (animfile >= 0)
 124         {
 125                 self.anim_die1         = animparseline(animfile);
 126                 self.anim_die2         = animparseline(animfile);
 127                 self.anim_draw         = animparseline(animfile);
 128                 self.anim_duck         = animparseline(animfile);
 129                 self.anim_duckwalk     = animparseline(animfile);
 130                 self.anim_duckjump     = animparseline(animfile);
 131                 self.anim_duckidle     = animparseline(animfile);
 132                 self.anim_idle         = animparseline(animfile);
 133                 self.anim_jump         = animparseline(animfile);
 134                 self.anim_pain1        = animparseline(animfile);
 135                 self.anim_pain2        = animparseline(animfile);
 136                 self.anim_shoot        = animparseline(animfile);
 137                 self.anim_taunt        = animparseline(animfile);
 138                 self.anim_run          = animparseline(animfile);
 139                 self.anim_runbackwards = animparseline(animfile);
 140                 self.anim_strafeleft   = animparseline(animfile);
 141                 self.anim_straferight  = animparseline(animfile);
 142                 self.anim_forwardright = animparseline(animfile);
 143                 self.anim_forwardleft  = animparseline(animfile);
 144                 self.anim_backright    = animparseline(animfile);
 145                 self.anim_backleft     = animparseline(animfile);
 146                 fclose(animfile);
 147
 148                 // derived anims
 149                 self.anim_dead1 = '0 1 1' + '1 0 0' * (self.anim_die1_x + self.anim_die1_y - 1);
 150                 self.anim_dead2 = '0 1 1' + '1 0 0' * (self.anim_die2_x + self.anim_die2_y - 1);
 151
 152                 if (animparseerror)
 153                         print("Parse error in ", animfilename, ", some player animations are broken\n");
 154         }
 155         else
 156                 dprint("File ", animfilename, " not found, assuming legacy .zym model animation timings\n");
 157         // reset animstate now
 158         player_setanim(self.anim_idle, TRUE, FALSE, TRUE);
 159 };
 160
 161 void player_setanim(vector anim, float looping, float override, float restart)
 162 {
 163         if (!restart)
 164         if (anim_x == self.animstate_startframe)
 165         if (anim_y == self.animstate_numframes)
 166         if (anim_z == self.animstate_framerate)
 167                 return;
 168         self.animstate_startframe = anim_x;
 169         self.animstate_numframes = anim_y;
 170         self.animstate_framerate = anim_z;
 171         self.animstate_starttime = time;
 172         self.animstate_endtime = time + self.animstate_numframes / self.animstate_framerate;
 173         self.animstate_looping = looping;
 174         self.animstate_override = override;
 175         self.frame = self.animstate_startframe;
 176 };
 177
 178 void player_updateframe()
 179 {
 180         if (time >= self.animstate_endtime)
 181         {
 182                 if (self.animstate_looping)
 183                 {
 184                         self.animstate_starttime = self.animstate_endtime;
 185                         self.animstate_endtime = self.animstate_endtime + self.animstate_numframes / self.animstate_framerate;
 186                 }
 187                 self.animstate_override = FALSE;
 188         }
 189         self.frame = self.animstate_startframe + bound(0, (time - self.animstate_starttime) * self.animstate_framerate, self.animstate_numframes - 1);
 190 };
 191
 192 void player_anim (void)
 193 {
 194         player_updateframe();
 195
 196         if (self.deadflag != DEAD_NO)
 197         {
 198                 if (time > self.animstate_endtime)
 199                 {
 200                         if (self.maxs_z > 5)
 201                         {
 202                                 self.maxs_z = 5;
 203                                 setsize(self, self.mins, self.maxs);
 204                         }
 205                         self.frame = self.dead_frame;
 206                 }
 207                 return;
 208         }
 209
 210         if (!self.animstate_override)
 211         {
 212                 if (!(self.flags & FL_ONGROUND))
 213                 {
 214                         if (self.crouch)
 215                                 player_setanim(self.anim_duckjump, FALSE, TRUE, FALSE);
 216                         else
 217                                 player_setanim(self.anim_jump, FALSE, TRUE, FALSE);
 218                 }
 219                 else if (self.crouch)
 220                 {
 221                         if (self.movement_x * self.movement_x + self.movement_y * self.movement_y > 20)
 222                                 player_setanim(self.anim_duckwalk, TRUE, FALSE, FALSE);
 223                         else
 224                                 player_setanim(self.anim_duckidle, TRUE, FALSE, FALSE);
 225                 }
 226                 else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
 227                 {
 228                         if (self.movement_x > 0 && self.movement_y == 0)
 229                                 player_setanim(self.anim_run, TRUE, FALSE, FALSE);
 230                         else if (self.movement_x < 0 && self.movement_y == 0)
 231                                 player_setanim(self.anim_runbackwards, TRUE, FALSE, FALSE);
 232                         else if (self.movement_x == 0 && self.movement_y > 0)
 233                                 player_setanim(self.anim_straferight, TRUE, FALSE, FALSE);
 234                         else if (self.movement_x == 0 && self.movement_y < 0)
 235                                 player_setanim(self.anim_strafeleft, TRUE, FALSE, FALSE);
 236                         else if (self.movement_x > 0 && self.movement_y > 0)
 237                                 player_setanim(self.anim_forwardright, TRUE, FALSE, FALSE);
 238                         else if (self.movement_x > 0 && self.movement_y < 0)
 239                                 player_setanim(self.anim_forwardleft, TRUE, FALSE, FALSE);
 240                         else if (self.movement_x < 0 && self.movement_y > 0)
 241                                 player_setanim(self.anim_backright, TRUE, FALSE, FALSE);
 242                         else if (self.movement_x < 0 && self.movement_y < 0)
 243                                 player_setanim(self.anim_backleft, TRUE, FALSE, FALSE);
 244                         else
 245                                 player_setanim(self.anim_run, TRUE, FALSE, FALSE);
 246                 }
 247                 else
 248                         player_setanim(self.anim_idle, TRUE, FALSE, FALSE);
 249         }
 250 }
 251 //End change by Supajoe on 11:44 PM EST 11/16/03 (Subject: Player animations)
 252
 253 void SpawnThrownWeapon (vector org, float w)
 254 {
 255         W_ThrowWeapon(randomvec() * 100 + '0 0 200', org - self.origin, FALSE);
 256 }
 257
 258 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 259 {
 260         local float take, save;
 261         if(sv_gentle < 1)
 262                 pointparticles(particleeffectnum("blood"), hitloc, force, bound(0, damage, 200));
 263         // damage resistance (ignore most of the damage from a bullet or similar)
 264         damage = max(damage - 5, 1);
 265
 266         save = bound(0, damage * cvar("g_balance_armor_blockpercent"), self.armorvalue);
 267         take = bound(0, damage - save, damage);
 268
 269         if (save > 10)
 270                 sound (self, CHAN_IMPACT, "misc/armorimpact.wav", 1, ATTN_NORM);
 271         else if (take > 30)
 272                 sound (self, CHAN_IMPACT, "misc/bodyimpact2.wav", 1, ATTN_NORM);
 273         else if (take > 10)
 274                 sound (self, CHAN_IMPACT, "misc/bodyimpact1.wav", 1, ATTN_NORM);
 275
 276         if(sv_gentle < 1) {
 277                 if (take > 50)
 278                         TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.1,1);
 279                 if (take > 100)
 280                         TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.2,1);
 281         }
 282
 283         if (!(self.flags & FL_GODMODE))
 284         {
 285                 self.armorvalue = self.armorvalue - save;
 286                 self.health = self.health - take;
 287                 // pause regeneration for 5 seconds
 288                 self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
 289         }
 290         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 291         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 292         self.dmg_inflictor = inflictor;
 293
 294         if (self.health <= -50)
 295         {
 296                 // don't use any animations as a gib
 297                 self.frame = 0;
 298                 self.dead_frame = 0;
 299                 // view just above the floor
 300                 self.view_ofs = '0 0 4';
 301
 302                 // make a juicy mess
 303                 local float multiplier;
 304                 multiplier = 1;
 305                 if (cvar("ekg"))
 306                         multiplier = 5;
 307
 308
 309                 // make a meaty mess
 310                 TossGib (self, "models/gibs/eye.md3", self.origin + self.view_ofs, self.velocity + randomvec() * 150,0);
 311
 312                 if(sv_gentle < 1) {
 313                         te_bloodshower (self.origin + self.mins, self.origin + self.maxs, 1200 * multiplier, 1000);
 314                         TossGib (world, "models/gibs/bloodyskull.md3", self.origin + self.view_ofs, self.velocity,0);
 315
 316                         local float c;
 317                         c = 0;
 318
 319                         while (c < multiplier)
 320                         {
 321                                 c = c + 1;
 322                                 //TossGib (world, "models/gibs/gib1.md3", self.origin, self.velocity + randomvec() * 450,0);
 323                                 //TossGib (world, "models/gibs/gib2.md3", self.origin, self.velocity + randomvec() * 450,0);
 324                                 //TossGib (world, "models/gibs/gib3.md3", self.origin, self.velocity + randomvec() * 450,0);
 325                                 //TossGib (world, "models/gibs/gib4.md3", self.origin, self.velocity + randomvec() * 450,0);
 326                                 //TossGib (world, "models/gibs/gib5.md3", self.origin, self.velocity + randomvec() * 450,0);
 327                                 //TossGib (world, "models/gibs/gib6.md3", self.origin, self.velocity + randomvec() * 450,0);
 328
 329                                 TossGib (world, "models/gibs/arm.md3", self.origin + self.view_ofs, self.velocity + randomvec() * (random() * 120 + 90),0);
 330                                 TossGib (world, "models/gibs/arm.md3", self.origin + self.view_ofs, self.velocity + randomvec() * (random() * 120 + 90),0);
 331                                 //TossGib (world, "models/gibs/arm.md3", self.origin + self.view_ofs, self.velocity + randomvec() * 150,0);
 332                                 //TossGib (world, "models/gibs/arm.md3", self.origin + self.view_ofs, self.velocity + randomvec() * 150,0);
 333                                 TossGib (world, "models/gibs/chest.md3", self.origin + self.view_ofs * 0.5, self.velocity + randomvec() * (random() * 120 + 80),0);
 334                                 //TossGib (world, "models/gibs/smallchest.md3", self.origin + self.view_ofs, self.velocity + randomvec() * 150,0);
 335                                 TossGib (world, "models/gibs/smallchest.md3", self.origin + self.view_ofs, self.velocity + randomvec() * (random() * 120 + 80),0);
 336                                 TossGib (world, "models/gibs/leg1.md3", self.origin + self.view_ofs * -0.2, self.velocity + randomvec() * (random() * 120 + 85),0);
 337                                 TossGib (world, "models/gibs/leg2.md3", self.origin + self.view_ofs * -0.4, self.velocity + randomvec() * (random() * 120 + 85),0);
 338                                 //TossGib (world, "models/gibs/leg1.md3", self.origin + self.view_ofs * -0.2, self.velocity + randomvec() * 150,0);
 339                                 //TossGib (world, "models/gibs/leg2.md3", self.origin + self.view_ofs * -0.4, self.velocity + randomvec() * 150,0);
 340
 341                                 // these splat on impact
 342                                 TossGib (world, "models/gibs/chunk.mdl", self.origin, self.velocity + randomvec() * 450,1);
 343                                 TossGib (world, "models/gibs/chunk.mdl", self.origin, self.velocity + randomvec() * 450,1);
 344                                 TossGib (world, "models/gibs/chunk.mdl", self.origin, self.velocity + randomvec() * 450,1);
 345                                 TossGib (world, "models/gibs/chunk.mdl", self.origin, self.velocity + randomvec() * 450,1);
 346                         }
 347                         sound (self, CHAN_VOICE, "misc/gib.wav", 1, ATTN_NORM);
 348                 }
 349         }
 350 }
 351
 352 void ClientKill_Now_TeamChange();
 353
 354 void net_UpdateDeaths(float msg_target)
 355 {
 356         entity p;
 357         WriteByte(msg_target, SVC_TEMPENTITY);
 358         WriteByte(msg_target, TE_CSQC_DEATHS);
 359         FOR_EACH_PLAYER(p)
 360         {
 361                 WriteByte(msg_target, num_for_edict(p));
 362                 WriteByte(msg_target, p.deaths);
 363         }
 364         WriteByte(msg_target, 0);
 365 }
 366
 367 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 368 {
 369         local float take, save, waves, sdelay;
 370
 371         damage = damage * bound(1.0, self.cvar_cl_handicap, 100.0);
 372         if(sv_gentle > 0) {
 373                 pointparticles(particleeffectnum("damage_hit"), hitloc, force, bound(0, damage, 200));
 374         } else {
 375                 pointparticles(particleeffectnum("blood"), hitloc, force, bound(0, damage, 200));
 376         }
 377
 378         if (self.pain_finished < time)          //Don't switch pain sequences like crazy
 379         {
 380                 if(sv_gentle < 1) {
 381                         if (random() > 0.5)
 382                                 player_setanim(self.anim_pain1, FALSE, TRUE, TRUE);
 383                         else
 384                                 player_setanim(self.anim_pain2, FALSE, TRUE, TRUE);
 385                 }
 386                 self.pain_finished = time + 0.5;        //Supajoe
 387
 388                 // throw off bot aim temporarily
 389                 local float shake;
 390                 shake = damage * 5 / (bound(0,skill,100) + 1);
 391                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 392                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 393         }
 394
 395         if(g_arena)
 396         if(numspawned < 2)
 397                 return;
 398
 399         if (!g_minstagib)
 400         {
 401                 save = bound(0, damage * cvar("g_balance_armor_blockpercent"), self.armorvalue);
 402                 take = bound(0, damage - save, damage);
 403         }
 404         else
 405         {
 406                 save = 0;
 407                 take = damage;
 408         }
 409
 410         if (save > 10)
 411                 sound (self, CHAN_IMPACT, "misc/armorimpact.wav", 1, ATTN_NORM);
 412         else if (take > 30)
 413                 sound (self, CHAN_IMPACT, "misc/bodyimpact2.wav", 1, ATTN_NORM);
 414         else if (take > 10)
 415                 sound (self, CHAN_IMPACT, "misc/bodyimpact1.wav", 1, ATTN_NORM);
 416
 417         if (take > 50)
 418                 TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.1,1);
 419         if (take > 100)
 420                 TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.2,1);
 421
 422         if (time > self.spawnshieldtime)
 423         {
 424                 if (!(self.flags & FL_GODMODE))
 425                 {
 426                         self.armorvalue = self.armorvalue - save;
 427                         self.health = self.health - take;
 428                         // pause regeneration for 5 seconds
 429                         self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
 430                 }
 431                 else
 432                         self.max_armorvalue += (save + take);
 433         }
 434         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 435         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 436         self.dmg_inflictor = inflictor;
 437
 438         if(attacker == self)
 439         {
 440                 // don't reset pushltime for self damage as it may be an attempt to
 441                 // escape a lava pit or similar
 442                 //self.pushltime = 0;
 443         }
 444         else if(attacker.classname == "player" || attacker.classname == "gib")
 445         {
 446                 self.pusher = attacker;
 447                 self.pushltime = time + cvar("g_maxpushtime");
 448         }
 449         else if(time < self.pushltime)
 450         {
 451                 attacker = self.pusher;
 452                 self.pushltime = max(self.pushltime, time + 0.6);
 453         }
 454         else
 455                 self.pushltime = 0;
 456
 457         if (self.health < 1)
 458         {
 459                 float defer_ClientKill_Now_TeamChange;
 460                 defer_ClientKill_Now_TeamChange = FALSE;
 461
 462                 self.deaths += 1;
 463                 net_UpdateDeaths(MSG_BROADCAST);
 464
 465                 // get rid of kill indicator
 466                 if(self.killindicator)
 467                 {
 468                         remove(self.killindicator);
 469                         self.killindicator = world;
 470                         if(self.killindicator_teamchange)
 471                                 defer_ClientKill_Now_TeamChange = TRUE;
 472
 473                         if(self.classname == "body")
 474                         if(deathtype == DEATH_KILL)
 475                         {
 476                                 // for the lemmings fans, a small harmless explosion
 477                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 478                         }
 479                 }
 480
 481                 // become fully visible
 482                 self.alpha = 1;
 483                 // clear selected player display
 484                 ClearSelectedPlayer();
 485                 // throw a weapon
 486                 SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 487                 // print an obituary message
 488                 Obituary (attacker, self, deathtype);
 489                 DropAllRunes(self);
 490                 if(self == attacker)
 491                         kh_Key_DropAll(self, TRUE);
 492                 else if(attacker.classname == "player" || attacker.classname == "gib")
 493                         kh_Key_DropAll(self, FALSE);
 494                 else
 495                         kh_Key_DropAll(self, TRUE);
 496                 if(self.flagcarried)
 497                         DropFlag(self.flagcarried);
 498                 // clear waypoints
 499                 WaypointSprite_PlayerDead();
 500                 // make the corpse upright (not tilted)
 501                 self.angles_x = 0;
 502                 self.angles_z = 0;
 503                 // don't spin
 504                 self.avelocity = '0 0 0';
 505                 // view from the floor
 506                 self.view_ofs = '0 0 -8';
 507                 // toss the corpse
 508                 self.movetype = MOVETYPE_TOSS;
 509                 // shootable corpse
 510                 self.solid = SOLID_CORPSE;
 511                 // don't stick to the floor
 512                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 513                 // dying animation
 514                 self.deadflag = DEAD_DYING;
 515                 // when to allow respawn
 516                 sdelay = 0;
 517                 waves = 0;
 518                 if(cvar("g_respawn_mapsettings"))
 519                 {
 520                         sdelay = cvar("g_respawn_mapsettings_delay");
 521                         waves = cvar("g_respawn_mapsettings_waves");
 522                 }
 523                 if(!sdelay)
 524                         sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 525                 if(!sdelay)
 526                         sdelay = cvar("g_respawn_delay");
 527                 if(!waves)
 528                         waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 529                 if(!waves)
 530                         waves = cvar("g_respawn_waves");
 531                 if(waves)
 532                         self.death_time = ceil((time + sdelay) / waves) * waves;
 533                 else
 534                         self.death_time = time + sdelay;
 535                 if((sdelay + waves >= 5.0) && (self.death_time - time > 1.75))
 536                         self.respawn_countdown = 10; // first number to count down from is 10
 537                 else
 538                         self.respawn_countdown = -1; // do not count down
 539                 if (random() < 0.5)
 540                 {
 541                         player_setanim(self.anim_die1, FALSE, TRUE, TRUE);
 542                         self.dead_frame = self.anim_dead1_x;
 543                 }
 544                 else
 545                 {
 546                         player_setanim(self.anim_die2, FALSE, TRUE, TRUE);
 547                         self.dead_frame = self.anim_dead2_x;
 548                 }
 549                 // set damage function to corpse damage
 550                 self.event_damage = PlayerCorpseDamage;
 551                 // call the corpse damage function just in case it wants to gib
 552                 self.event_damage(inflictor, attacker, 0, deathtype, hitloc, force);
 553                 // set up to fade out later
 554                 SUB_SetFade (self, time + 12 + random () * 4, 1);
 555
 556                 // remove laserdot
 557                 if(self.weaponentity)
 558                         if(self.weaponentity.lasertarget)
 559                                 remove(self.weaponentity.lasertarget);
 560
 561                 if(clienttype(self) == CLIENTTYPE_REAL)
 562                 {
 563                         self.fixangle = TRUE;
 564                         //msg_entity = self;
 565                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 566                         //WriteAngle (MSG_ONE, self.v_angle_x);
 567                         //WriteAngle (MSG_ONE, self.v_angle_y);
 568                         //WriteAngle (MSG_ONE, 80);
 569                 }
 570
 571                 if(g_arena)
 572                         Spawnqueue_Unmark(self);
 573
 574                 if(defer_ClientKill_Now_TeamChange)
 575                         ClientKill_Now_TeamChange();
 576
 577                 if(sv_gentle > 0) {
 578                         // remove corpse
 579                         PlayerCorpseDamage (inflictor, attacker, 100.0, deathtype, hitloc, force);
 580                         pointparticles(particleeffectnum("damage_dissolve"), self.origin, force, 1);
 581                 }
 582         }
 583 }
 584
 585 float UpdateSelectedPlayer_countvalue(float v)
 586 {
 587         return max(0, (v - 1.0) / 0.5);
 588 }
 589
 590 // returns: -2 if no hit, otherwise cos of the angle
 591 // uses the global v_angle
 592 float UpdateSelectedPlayer_canSee(entity p, float mincosangle, float maxdist)
 593 {
 594         vector so, d;
 595         float c;
 596
 597         if(p == self)
 598                 return -2;
 599
 600         if(p.deadflag)
 601                 return -2;
 602
 603         so = self.origin + self.view_ofs;
 604         d = p.origin - so;
 605
 606         // misaimed?
 607         if(dist_point_line(d, '0 0 0', v_forward) > maxdist)
 608                 return -2;
 609
 610         // now find the cos of the angle...
 611         c = normalize(d) * v_forward;
 612
 613         if(c <= mincosangle)
 614                 return -2;
 615
 616         traceline(so, p.origin, MOVE_NOMONSTERS, self);
 617         if(trace_fraction < 1)
 618                 return -2;
 619
 620         return c;
 621 }
 622
 623 void ClearSelectedPlayer()
 624 {
 625         if(self.selected_player)
 626         {
 627                 centerprint_expire(self, CENTERPRIO_POINT);
 628                 self.selected_player = world;
 629                 self.selected_player_display_needs_update = FALSE;
 630         }
 631 }
 632
 633 void UpdateSelectedPlayer()
 634 {
 635         entity selected;
 636         float selected_score;
 637         selected = world;
 638         selected_score = 0.95; // 18 degrees
 639
 640         if(!cvar("sv_allow_shownames"))
 641                 return;
 642
 643         if(clienttype(self) != CLIENTTYPE_REAL)
 644                 return;
 645
 646         if(self.cvar_cl_shownames == 0)
 647                 return;
 648
 649         if(self.cvar_cl_shownames == 1 && !teams_matter)
 650                 return;
 651
 652         makevectors(self.v_angle); // sets v_forward
 653
 654         // 1. cursor trace is always right
 655         if(self.cursor_trace_ent && self.cursor_trace_ent.classname == "player" && !self.cursor_trace_ent.deadflag)
 656         {
 657                 selected = self.cursor_trace_ent;
 658         }
 659         else
 660         {
 661                 // 2. if we don't have a cursor trace, find the player which is least
 662                 //    mis-aimed at
 663                 entity p;
 664                 FOR_EACH_PLAYER(p)
 665                 {
 666                         float c;
 667                         c = UpdateSelectedPlayer_canSee(p, selected_score, 100); // 100 = 2.5 meters
 668                         if(c >= -1)
 669                         {
 670                                 selected = p;
 671                                 selected_score = c;
 672                         }
 673                 }
 674         }
 675
 676         if(selected)
 677         {
 678                 self.selected_player_display_timeout = time + self.cvar_scr_centertime;
 679         }
 680         else
 681         {
 682                 if(time < self.selected_player_display_timeout)
 683                         if(UpdateSelectedPlayer_canSee(self.selected_player, 0.7, 200) >= -1) // 5 meters, 45 degrees
 684                                 selected = self.selected_player;
 685         }
 686
 687         if(selected)
 688         {
 689                 if(selected == self.selected_player)
 690                 {
 691                         float save;
 692                         save = UpdateSelectedPlayer_countvalue(self.selected_player_count);
 693                         self.selected_player_count = self.selected_player_count + frametime;
 694                         if(save != UpdateSelectedPlayer_countvalue(self.selected_player_count))
 695                         {
 696                                 string namestr, healthstr;
 697                                 namestr = playername(selected);
 698                                 if(teams_matter)
 699                                 {
 700                                         healthstr = ftos(floor(selected.health));
 701                                         if(self.team == selected.team)
 702                                         {
 703                                                 namestr = strcat(namestr, " (", healthstr, "%)");
 704                                                 self.selected_player_display_needs_update = TRUE;
 705                                         }
 706                                 }
 707                                 centerprint_atprio(self, CENTERPRIO_POINT, namestr);
 708                         }
 709                 }
 710                 else
 711                 {
 712                         ClearSelectedPlayer();
 713                         self.selected_player = selected;
 714                         self.selected_player_time = time;
 715                         self.selected_player_count = 0;
 716                         self.selected_player_display_needs_update = FALSE;
 717                 }
 718         }
 719         else
 720         {
 721                 ClearSelectedPlayer();
 722         }
 723
 724         if(self.selected_player)
 725                 self.last_selected_player = self.selected_player;
 726 }
 727
 728 float precache_sound_index (string s) = #19;
 729 void soundto(entity e, entity sounddest, float chan, string samp, float vol, float atten)
 730 {
 731         vector o;
 732         if(clienttype(sounddest) != CLIENTTYPE_REAL)
 733                 return;
 734         o = e.origin + 0.5 * (e.mins + e.maxs);
 735         msg_entity = sounddest;
 736         WriteByte(MSG_ONE, 6);
 737         WriteByte(MSG_ONE, 27); // all bits except SND_LOOPING
 738         WriteByte(MSG_ONE, vol * 255);
 739         WriteByte(MSG_ONE, atten * 64);
 740         WriteEntity(MSG_ONE, e);
 741         WriteByte(MSG_ONE, chan);
 742         WriteShort(MSG_ONE, precache_sound_index(samp));
 743         WriteCoord(MSG_ONE, o_x);
 744         WriteCoord(MSG_ONE, o_y);
 745         WriteCoord(MSG_ONE, o_z);
 746 }
 747
 748 #if 0
 749 .string playersound_attack;
 750 .string playersound_attackinfive;
 751 .string playersound_coverme;
 752 .string playersound_defend;
 753 .string playersound_freelance;
 754 .string playersound_incoming;
 755 .string playersound_meet;
 756 .string playersound_needhelp;
 757 .string playersound_seenflag;
 758 .string playersound_taunt;
 759 .string playersound_teamshoot;
 760 .float modelindex_for_playersound;
 761
 762 float GetVoiceMessageTeamsayType(string type)
 763 {
 764         if(type == "taunt")
 765                 return 0;
 766         if(type == "teamshoot")
 767                 return 2;
 768         return 1;
 769 }
 770
 771 string allvoicesamples = "attack attackinfive coverme defend freelance incoming meet needhelp seenflag taunt teamshoot";
 772 float GetPlayerSoundSampleField_notFound;
 773 .string GetVoiceMessageSampleField(string type)
 774 {
 775         GetPlayerSoundSampleField_notFound = 0;
 776         switch(type)
 777         {
 778                 case "attack":       return playersound_attack;
 779                 case "attackinfive": return playersound_attackinfive;
 780                 case "coverme":      return playersound_coverme;
 781                 case "defend":       return playersound_defend;
 782                 case "freelance":    return playersound_freelance;
 783                 case "incoming":     return playersound_incoming;
 784                 case "meet":         return playersound_meet;
 785                 case "needhelp":     return playersound_needhelp;
 786                 case "seenflag":     return playersound_seenflag;
 787                 case "taunt":        return playersound_taunt;
 788                 case "teamshoot":    return playersound_teamshoot;
 789         }
 790         GetPlayerSoundSampleField_notFound = 1;
 791         return playersound_taunt;
 792 }
 793
 794 .string GetPlayerSoundSampleField(string type)
 795 {
 796         GetPlayerSoundSampleField_notFound = 0;
 797         switch(type)
 798         {
 799                 case "attack":       return playersound_attack;
 800                 default:             return GetVoiceMessageSampleField(type);
 801         }
 802 }
 803
 804 void PrecachePlayerSounds(string f)
 805 {
 806         float fh;
 807         float i, n;
 808         string s;
 809         fh = fopen(f, FILE_READ);
 810         if(fh < 0)
 811                 return;
 812         while((s = fgets(fh)))
 813         {
 814                 if(tokenize(s) != 3)
 815                 {
 816                         dprint("Invalid sound info line: ", s, "\n");
 817                         continue;
 818                 }
 819                 n = stof(argv(2));
 820                 for(i = 1; i <= n; ++i)
 821                         precache_sound(strcat(argv(1), ftos(i), ".wav"));
 822         }
 823         fclose(fh);
 824 }
 825
 826 void LoadPlayerSounds(string f)
 827 {
 828         float fh;
 829         string s;
 830         var .string field;
 831         fh = fopen(f, FILE_READ);
 832         if(fh < 0)
 833                 return;
 834         while((s = fgets(fh)))
 835         {
 836                 if(tokenize(s) != 3)
 837                         continue;
 838                 field = GetPlayerSoundSampleField(argv(0));
 839                 if(GetPlayerSoundSampleField_notFound)
 840                         continue;
 841                 if(self.field)
 842                         strunzone(self.field);
 843                 self.field = strzone(strcat(argv(1), " ", argv(2)));
 844         }
 845         fclose(fh);
 846 }
 847
 848 void UpdatePlayerSounds()
 849 {
 850         if(self.modelindex == self.modelindex_for_playersound)
 851                 return;
 852         self.modelindex_for_playersound = self.modelindex;
 853         LoadPlayerSounds("sound/player/default.sounds");
 854         LoadPlayerSounds(strcat(self.model, ".sounds"));
 855 }
 856
 857 void VoiceMessage(string type)
 858 {
 859         // TODO precache voice messages?
 860         var string sample;
 861         var float teamsay;
 862         sample = self.(GetPlayerSoundSampleField(type));
 863
 864         if(GetPlayerSoundSampleField_notFound)
 865         {
 866                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
 867                 return;
 868         }
 869
 870         if(!sample)
 871                 return;
 872
 873         teamsay = GetVoiceMessageTeamsayType(type);
 874
 875         tokenize(sample);
 876         sample = strcat(argv(0), ftos(ceil(random() * stof(argv(1)))), ".wav"); // randomization
 877
 878         if(teamsay == 2)
 879         {
 880                 if(teams_matter)
 881                         if(self.pusher)
 882                                 if(self.pusher.team == self.team)
 883                                 {
 884                                         soundto(self, self.pusher, CHAN_VOICE, sample, 1, ATTN_NONE);
 885                                         soundto(self, self, CHAN_VOICE, sample, 1, ATTN_NONE);
 886                                 }
 887         }
 888         else if(teamsay == 0 || !teams_matter)
 889         {
 890                 // broadcast the sound, but it's directional
 891                 sound(self, CHAN_VOICE, sample, 1, ATTN_NORM);
 892         }
 893         else if(teamsay == 1)
 894         {
 895                 entity e;
 896                 FOR_EACH_REALCLIENT(e)
 897                         if(e.team == self.team)
 898                                 soundto(self, e, CHAN_VOICE, sample, 1, ATTN_NONE);
 899         }
 900 }
 901 #else
 902 void PrecachePlayerSounds(string f) { }
 903 void UpdatePlayerSounds() { }
 904 void VoiceMessage(string type) { sprint(self, "Sorry, voice command support is not done yet. Maybe later.\n"); }
 905 #endif