data/qcsrc/server/cl_physics.qc

   1 float sv_accelerate;
   2 float sv_friction;
   3 float sv_maxspeed;
   4 float sv_airaccelerate;
   5 float sv_maxairspeed;
   6 float sv_stopspeed;
   7 float sv_gravity;
   8 float sv_airaccel_sideways_friction;
   9 float sv_airaccel_qw;
  10 .float ladder_time;
  11 .entity ladder_entity;
  12 .float gravity;
  13 .float swamp_slowdown;
  14 .float lastflags;
  15 .float lastground;
  16 .float wasFlying;
  17 .float spectatorspeed;
  18
  19 #define SHTEST_DELTA 10
  20 #define SHTEST_THRESHOLD 1.1
  21 .float shtest_next;
  22 .float shtest_accumulator;
  23
  24 /*
  25 =============
  26 PlayerJump
  27
  28 When you press the jump key
  29 =============
  30 */
  31 void PlayerJump (void)
  32 {
  33         float mjumpheight;
  34
  35         mjumpheight = cvar("sv_jumpvelocity");
  36         if (self.waterlevel >= 2)
  37         {
  38                 if (self.watertype == CONTENT_WATER)
  39                         self.velocity_z = 200;
  40                 else if (self.watertype == CONTENT_SLIME)
  41                         self.velocity_z = 80;
  42                 else
  43                         self.velocity_z = 50;
  44
  45                 return;
  46         }
  47
  48
  49         if (!(self.flags & FL_ONGROUND))
  50                 return;
  51
  52         if(!sv_pogostick)
  53                 if (!(self.flags & FL_JUMPRELEASED))
  54                         return;
  55
  56         if(g_runematch)
  57         {
  58                 if(self.runes & RUNE_SPEED)
  59                 {
  60                         if(self.runes & CURSE_SLOW)
  61                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_combo_jumpheight");
  62                         else
  63                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
  64                 }
  65                 else if(self.runes & CURSE_SLOW)
  66                 {
  67                         mjumpheight = mjumpheight * cvar("g_balance_curse_slow_jumpheight");
  68                 }
  69         }
  70
  71         if(g_minstagib && (self.items & IT_INVINCIBLE))
  72         {
  73                 mjumpheight = mjumpheight * cvar("g_minstagib_speed_jumpheight");
  74         }
  75
  76         self.velocity_z = self.velocity_z + mjumpheight;
  77         self.oldvelocity_z = self.velocity_z;
  78
  79         self.flags = self.flags - FL_ONGROUND;
  80         self.flags = self.flags - FL_JUMPRELEASED;
  81
  82         if (self.crouch)
  83                 player_setanim(self.anim_duckjump, FALSE, TRUE, TRUE);
  84         else
  85                 player_setanim(self.anim_jump, FALSE, TRUE, TRUE);
  86
  87         if(g_jump_grunt)
  88                 PlayerSound(playersound_jump, CHAN_PLAYER, 0);
  89 }
  90
  91 void CheckWaterJump()
  92 {
  93         local vector start, end;
  94
  95 // check for a jump-out-of-water
  96         makevectors (self.angles);
  97         start = self.origin;
  98         start_z = start_z + 8;
  99         v_forward_z = 0;
 100         normalize(v_forward);
 101         end = start + v_forward*24;
 102         traceline (start, end, TRUE, self);
 103         if (trace_fraction < 1)
 104         {       // solid at waist
 105                 start_z = start_z + self.maxs_z - 8;
 106                 end = start + v_forward*24;
 107                 self.movedir = trace_plane_normal * -50;
 108                 traceline (start, end, TRUE, self);
 109                 if (trace_fraction == 1)
 110                 {       // open at eye level
 111                         self.flags = self.flags | FL_WATERJUMP;
 112                         self.velocity_z = 225;
 113                         self.flags = self.flags - (self.flags & FL_JUMPRELEASED);
 114                         self.teleport_time = time + 2;  // safety net
 115                         return;
 116                 }
 117         }
 118 };
 119
 120 float racecar_angle(float forward, float down)
 121 {
 122         float ret, angle_mult;
 123
 124         if(forward < 0)
 125         {
 126                 forward = -forward;
 127                 down = -down;
 128         }
 129
 130         ret = vectoyaw('0 1 0' * down + '1 0 0' * forward);
 131
 132         angle_mult = forward / (800 + forward);
 133
 134         if(ret > 180)
 135                 return ret * angle_mult + 360 * (1 - angle_mult);
 136         else
 137                 return ret * angle_mult;
 138 }
 139
 140 void RaceCarPhysics()
 141 {
 142         // using this move type for "big rigs"
 143         // the engine does not push the entity!
 144
 145         float accel, steer, f;
 146         vector angles_save, rigvel;
 147
 148         angles_save = self.angles;
 149         accel = bound(-1, self.movement_x / sv_maxspeed, 1);
 150         steer = bound(-1, self.movement_y / sv_maxspeed, 1);
 151
 152         if(g_bugrigs_reverse_speeding)
 153         {
 154                 if(accel < 0)
 155                 {
 156                         // back accel is DIGITAL
 157                         // to prevent speedhack
 158                         if(accel < -0.5)
 159                                 accel = -1;
 160                         else
 161                                 accel = 0;
 162                 }
 163         }
 164
 165         self.angles_x = 0;
 166         self.angles_z = 0;
 167         makevectors(self.angles); // new forward direction!
 168
 169         if(self.flags & FL_ONGROUND || g_bugrigs_air_steering)
 170         {
 171                 float myspeed, upspeed, steerfactor, accelfactor;
 172
 173                 myspeed = self.velocity * v_forward;
 174                 upspeed = self.velocity * v_up;
 175
 176                 // responsiveness factor for steering and acceleration
 177                 f = 1 / (1 + pow(max(-myspeed, myspeed) / g_bugrigs_speed_ref, g_bugrigs_speed_pow));
 178                 //MAXIMA: f(v) := 1 / (1 + (v / g_bugrigs_speed_ref) ^ g_bugrigs_speed_pow);
 179
 180                 if(myspeed < 0 && g_bugrigs_reverse_spinning)
 181                         steerfactor = -myspeed * g_bugrigs_steer;
 182                 else
 183                         steerfactor = -myspeed * f * g_bugrigs_steer;
 184
 185                 if(myspeed < 0 && g_bugrigs_reverse_speeding)
 186                         accelfactor = g_bugrigs_accel;
 187                 else
 188                         accelfactor = f * g_bugrigs_accel;
 189                 //MAXIMA: accel(v) := f(v) * g_bugrigs_accel;
 190
 191                 if(accel < 0)
 192                 {
 193                         if(myspeed > 0)
 194                         {
 195                                 myspeed = max(0, myspeed - frametime * (g_bugrigs_friction_floor - g_bugrigs_friction_brake * accel));
 196                         }
 197                         else
 198                         {
 199                                 if(!g_bugrigs_reverse_speeding)
 200                                         myspeed = min(0, myspeed + frametime * g_bugrigs_friction_floor);
 201                         }
 202                 }
 203                 else
 204                 {
 205                         if(myspeed >= 0)
 206                         {
 207                                 myspeed = max(0, myspeed - frametime * g_bugrigs_friction_floor);
 208                         }
 209                         else
 210                         {
 211                                 if(g_bugrigs_reverse_stopping)
 212                                         myspeed = 0;
 213                                 else
 214                                         myspeed = min(0, myspeed + frametime * (g_bugrigs_friction_floor + g_bugrigs_friction_brake * accel));
 215                         }
 216                 }
 217                 // terminal velocity = velocity at which 50 == accelfactor, that is, 1549 units/sec
 218                 //MAXIMA: friction(v) := g_bugrigs_friction_floor;
 219
 220                 self.angles_y += steer * frametime * steerfactor; // apply steering
 221                 makevectors(self.angles); // new forward direction!
 222
 223                 myspeed += accel * accelfactor * frametime;
 224
 225                 rigvel = myspeed * v_forward + '0 0 1' * upspeed;
 226         }
 227         else
 228         {
 229                 myspeed = vlen(self.velocity);
 230
 231                 // responsiveness factor for steering and acceleration
 232                 f = 1 / (1 + pow(max(0, myspeed / g_bugrigs_speed_ref), g_bugrigs_speed_pow));
 233                 steerfactor = -myspeed * f;
 234                 self.angles_y += steer * frametime * steerfactor; // apply steering
 235
 236                 rigvel = self.velocity;
 237                 makevectors(self.angles); // new forward direction!
 238         }
 239
 240         rigvel = rigvel * max(0, 1 - vlen(rigvel) * g_bugrigs_friction_air * frametime);
 241         //MAXIMA: airfriction(v) := v * v * g_bugrigs_friction_air;
 242         //MAXIMA: total_acceleration(v) := accel(v) - friction(v) - airfriction(v);
 243         //MAXIMA: solve(total_acceleration(v) = 0, v);
 244
 245         if(g_bugrigs_planar_movement)
 246         {
 247                 vector rigvel_xy, neworigin, up;
 248                 float mt;
 249
 250                 rigvel_z -= frametime * sv_gravity; // 4x gravity plays better
 251                 rigvel_xy = rigvel;
 252                 rigvel_xy_z = 0;
 253
 254                 if(g_bugrigs_planar_movement_car_jumping && !g_touchexplode) // touchexplode is a better way to handle collisions
 255                         mt = MOVE_NORMAL;
 256                 else
 257                         mt = MOVE_NOMONSTERS;
 258
 259                 tracebox(self.origin, self.mins, self.maxs, self.origin + '0 0 1024', mt, self);
 260                 up = trace_endpos - self.origin;
 261
 262                 // BUG RIGS: align the move to the surface instead of doing collision testing
 263                 // can we move?
 264                 tracebox(trace_endpos, self.mins, self.maxs, trace_endpos + rigvel_xy * frametime, mt, self);
 265
 266                 // align to surface
 267                 tracebox(trace_endpos, self.mins, self.maxs, trace_endpos - up + '0 0 1' * rigvel_z * frametime, mt, self);
 268
 269                 if(trace_fraction < 0.5)
 270                 {
 271                         trace_fraction = 1;
 272                         neworigin = self.origin;
 273                 }
 274                 else
 275                         neworigin = trace_endpos;
 276
 277                 if(trace_fraction < 1)
 278                 {
 279                         // now set angles_x so that the car points parallel to the surface
 280                         self.angles = vectoangles(
 281                                         '1 0 0' * v_forward_x * trace_plane_normal_z
 282                                         +
 283                                         '0 1 0' * v_forward_y * trace_plane_normal_z
 284                                         +
 285                                         '0 0 1' * -(v_forward_x * trace_plane_normal_x + v_forward_y * trace_plane_normal_y)
 286                                         );
 287                         self.flags |= FL_ONGROUND;
 288                 }
 289                 else
 290                 {
 291                         // now set angles_x so that the car points forward, but is tilted in velocity direction
 292                         self.flags (-) FL_ONGROUND;
 293                 }
 294
 295                 self.velocity = (neworigin - self.origin) * (1.0 / frametime);
 296                 self.movetype = MOVETYPE_NOCLIP;
 297         }
 298         else
 299         {
 300                 rigvel_z -= frametime * sv_gravity; // 4x gravity plays better
 301                 self.velocity = rigvel;
 302                 self.movetype = MOVETYPE_FLY;
 303         }
 304
 305         trace_fraction = 1;
 306         tracebox(self.origin, self.mins, self.maxs, self.origin - '0 0 4', MOVE_NORMAL, self);
 307         if(trace_fraction != 1)
 308         {
 309                 self.angles = vectoangles2(
 310                                 '1 0 0' * v_forward_x * trace_plane_normal_z
 311                                 +
 312                                 '0 1 0' * v_forward_y * trace_plane_normal_z
 313                                 +
 314                                 '0 0 1' * -(v_forward_x * trace_plane_normal_x + v_forward_y * trace_plane_normal_y),
 315                                 trace_plane_normal
 316                                 );
 317         }
 318         else
 319         {
 320                 vector vel_local;
 321
 322                 vel_local_x = v_forward * self.velocity;
 323                 vel_local_y = v_right * self.velocity;
 324                 vel_local_z = v_up * self.velocity;
 325
 326                 self.angles_x = racecar_angle(vel_local_x, vel_local_z);
 327                 self.angles_z = racecar_angle(-vel_local_y, vel_local_z);
 328         }
 329
 330         // smooth the angles
 331         vector vf1, vu1, smoothangles;
 332         makevectors(self.angles);
 333         f = bound(0, frametime * g_bugrigs_angle_smoothing, 1);
 334         if(f == 0)
 335                 f = 1;
 336         vf1 = v_forward * f;
 337         vu1 = v_up * f;
 338         makevectors(angles_save);
 339         vf1 = vf1 + v_forward * (1 - f);
 340         vu1 = vu1 + v_up * (1 - f);
 341         smoothangles = vectoangles2(vf1, vu1);
 342         self.angles_x = -smoothangles_x;
 343         self.angles_z =  smoothangles_z;
 344 }
 345
 346 .vector movement_old;
 347 .float buttons_old;
 348 .vector v_angle_old;
 349
 350 void Nixnex_GiveCurrentWeapon();
 351 void SV_PlayerPhysics()
 352 {
 353         local vector wishvel, wishdir, v;
 354         local float wishspeed, f, maxspd_mod, spd, maxairspd, airaccel, swampspd_mod, shtest_score, buttons;
 355         string temps;
 356
 357         buttons = self.BUTTON_ATCK + 2 * self.BUTTON_JUMP + 4 * self.BUTTON_ATCK2 + 8 * self.BUTTON_ZOOM + 16 * self.BUTTON_CROUCH + 32 * self.BUTTON_HOOK + 64 * self.BUTTON_USE;
 358         if(!sv_maxidle_spectatorsareidle || self.movetype == MOVETYPE_WALK)
 359         {
 360                 if(buttons != self.buttons_old || self.movement != self.movement_old || self.v_angle != self.v_angle_old)
 361                         self.parm_idlesince = time;
 362         }
 363         self.buttons_old = buttons;
 364         self.movement_old = self.movement;
 365         self.v_angle_old = self.v_angle;
 366
 367         if(time > self.shtest_next)
 368         {
 369                 if(self.shtest_next > 0)
 370                 {
 371                         // self.shtest_accumulator:
 372                         //   started at time - SHTEST_DELTA
 373                         //   should be at SHTEST_DELTA
 374                         shtest_score = self.shtest_accumulator / (SHTEST_DELTA + time - self.shtest_next);
 375                         if(shtest_score > SHTEST_THRESHOLD)
 376                                 print("TIME PARADOX: shtest for ", self.netname, " said ", ftos(shtest_score), "\n");
 377                         else if(cvar("developer_shtest"))
 378                                 dprint("okay: shtest for ", self.netname, " said ", ftos(shtest_score), "\n");
 379                 }
 380                 self.shtest_next = time + SHTEST_DELTA;
 381                 self.shtest_accumulator = 0;
 382         }
 383         self.shtest_accumulator += frametime;
 384
 385         if (clienttype(self) == CLIENTTYPE_BOT)
 386                 bot_think();
 387
 388         if (self.movetype == MOVETYPE_NONE && self.disableclientprediction != 2)
 389                 return;
 390
 391         if (self.punchangle != '0 0 0')
 392         {
 393                 f = vlen(self.punchangle) - 10 * frametime;
 394                 if (f > 0)
 395                         self.punchangle = normalize(self.punchangle) * f;
 396                 else
 397                         self.punchangle = '0 0 0';
 398         }
 399
 400         if (self.punchvector != '0 0 0')
 401         {
 402                 f = vlen(self.punchvector) - 30 * frametime;
 403                 if (f > 0)
 404                         self.punchvector = normalize(self.punchvector) * f;
 405                 else
 406                         self.punchvector = '0 0 0';
 407         }
 408
 409         maxspd_mod = 1;
 410
 411         if(g_runematch)
 412         {
 413                 if(self.runes & RUNE_SPEED)
 414                 {
 415                         if(self.runes & CURSE_SLOW)
 416                                 maxspd_mod = maxspd_mod * cvar("g_balance_rune_speed_combo_moverate");
 417                         else
 418                                 maxspd_mod = maxspd_mod * cvar("g_balance_rune_speed_moverate");
 419                 }
 420                 else if(self.runes & CURSE_SLOW)
 421                 {
 422                         maxspd_mod = maxspd_mod * cvar("g_balance_curse_slow_moverate");
 423                 }
 424         }
 425
 426         if(g_minstagib && (self.items & IT_INVINCIBLE))
 427         {
 428                 maxspd_mod = cvar("g_minstagib_speed_moverate");
 429         }
 430
 431         swampspd_mod = 1;
 432         if(self.in_swamp) {
 433                 swampspd_mod = self.swamp_slowdown; //cvar("g_balance_swamp_moverate");
 434         }
 435
 436         if(self.flags & FL_NOTARGET)
 437         {
 438                 maxspd_mod = cvar("sv_spectator_speed_multiplier");
 439                 if(!self.spectatorspeed)
 440                         self.spectatorspeed = maxspd_mod;
 441                 if(self.impulse && self.impulse <= 19)
 442                 {
 443                         if(self.lastflags & FL_NOTARGET)
 444                         {
 445                                 if(self.impulse == 10 || self.impulse == 15 || self.impulse == 18)
 446                                         self.spectatorspeed = bound(1, self.spectatorspeed + 0.5, 5);
 447                                 else if(self.impulse == 11)
 448                                         self.spectatorspeed = maxspd_mod;
 449                                 else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19)
 450                                         self.spectatorspeed = bound(1, self.spectatorspeed - 0.5, 5);
 451                                 else if(self.impulse >= 1 && self.impulse <= 9)
 452                                         self.spectatorspeed = 1 + 0.5 * (self.impulse - 1);
 453                         } // otherwise just clear
 454                         self.impulse = 0;
 455                 }
 456                 maxspd_mod = self.spectatorspeed;
 457         }
 458
 459         spd = sv_maxspeed * maxspd_mod * swampspd_mod;
 460
 461         if(self.speed != spd)
 462         {
 463                 self.speed = spd;
 464                 temps = ftos(spd);
 465                 stuffcmd(self, strcat("cl_forwardspeed ", temps, "\n"));
 466                 stuffcmd(self, strcat("cl_backspeed ", temps, "\n"));
 467                 stuffcmd(self, strcat("cl_sidespeed ", temps, "\n"));
 468                 stuffcmd(self, strcat("cl_upspeed ", temps, "\n"));
 469
 470                 temps = ftos(sv_accelerate * maxspd_mod);
 471                 stuffcmd(self, strcat("cl_movement_accelerate ", temps, "\n"));
 472         }
 473
 474         // if dead, behave differently
 475         if (self.deadflag)
 476                 return;
 477
 478         if (!self.fixangle && !g_bugrigs)
 479         {
 480                 self.angles_x = 0;
 481                 self.angles_y = self.v_angle_y;
 482                 self.angles_z = 0;
 483         }
 484
 485         if(self.flags & FL_ONGROUND)
 486         if(self.wasFlying)
 487         {
 488                 self.wasFlying = 0;
 489
 490                 if(self.waterlevel < 2)
 491                 if(time >= self.ladder_time)
 492                 if not(self.hook)
 493                 {
 494                         self.nextstep = time + 0.3 + random() * 0.1;
 495                         trace_dphitq3surfaceflags = 0;
 496                         tracebox(self.origin, self.mins, self.maxs, self.origin - '0 0 1', MOVE_NOMONSTERS, self);
 497                         if not(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOSTEPS)
 498                         {
 499                                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_METALSTEPS)
 500                                         GlobalSound(globalsound_metalfall, CHAN_PLAYER, 0);
 501                                 else
 502                                         GlobalSound(globalsound_fall, CHAN_PLAYER, 0);
 503                         }
 504                 }
 505         }
 506
 507         if(IsFlying(self))
 508                 self.wasFlying = 1;
 509
 510         if(self.classname == "player")
 511         {
 512                 if(sv_doublejump)
 513                 {
 514                         self.flags = self.flags - (self.flags & FL_ONGROUND);
 515                         tracebox(self.origin + '0 0 1', self.mins, self.maxs, self.origin - '0 0 2', MOVE_NORMAL, self);
 516                         if(trace_fraction < 1 && trace_plane_normal_z > 0.7)
 517                                 self.flags = self.flags | FL_ONGROUND;
 518                 }
 519
 520                 if (self.BUTTON_JUMP)
 521                         PlayerJump ();
 522                 else
 523                         self.flags = self.flags | FL_JUMPRELEASED;
 524
 525                 if (self.waterlevel == 2)
 526                         CheckWaterJump ();
 527         }
 528
 529         if (self.flags & FL_WATERJUMP )
 530         {
 531                 self.velocity_x = self.movedir_x;
 532                 self.velocity_y = self.movedir_y;
 533                 if (time > self.teleport_time || self.waterlevel == 0)
 534                 {
 535                         self.flags = self.flags - (self.flags & FL_WATERJUMP);
 536                         self.teleport_time = 0;
 537                 }
 538         }
 539         else if (g_bugrigs && self.classname == "player")
 540         {
 541                 RaceCarPhysics();
 542         }
 543         else if (self.movetype == MOVETYPE_NOCLIP || self.movetype == MOVETYPE_FLY)
 544         {
 545                 // noclipping or flying
 546                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 547
 548                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 549                 makevectors(self.v_angle);
 550                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 551                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 552                 // acceleration
 553                 wishdir = normalize(wishvel);
 554                 wishspeed = vlen(wishvel);
 555                 if (wishspeed > sv_maxspeed*maxspd_mod)
 556                         wishspeed = sv_maxspeed*maxspd_mod;
 557                 if (time >= self.teleport_time)
 558                 {
 559                         f = wishspeed - (self.velocity * wishdir);
 560                         if (f > 0)
 561                                 self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 562                 }
 563         }
 564         else if (self.waterlevel >= 2)
 565         {
 566                 // swimming
 567                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 568
 569                 makevectors(self.v_angle);
 570                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 571                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 572                 if (wishvel == '0 0 0')
 573                         wishvel = '0 0 -60'; // drift towards bottom
 574
 575                 wishdir = normalize(wishvel);
 576                 wishspeed = vlen(wishvel);
 577                 if (wishspeed > sv_maxspeed*maxspd_mod)
 578                         wishspeed = sv_maxspeed*maxspd_mod;
 579                 wishspeed = wishspeed * 0.7;
 580
 581                 // water friction
 582                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 583
 584                 // water acceleration
 585                 f = wishspeed - (self.velocity * wishdir);
 586                 if (f > 0)
 587                         self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 588         }
 589         else if (time < self.ladder_time)
 590         {
 591                 // on a spawnfunc_func_ladder or swimming in spawnfunc_func_water
 592                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 593
 594                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 595                 makevectors(self.v_angle);
 596                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 597                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 598                 if (self.gravity)
 599                         self.velocity_z = self.velocity_z + self.gravity * sv_gravity * frametime;
 600                 else
 601                         self.velocity_z = self.velocity_z + sv_gravity * frametime;
 602                 if (self.ladder_entity.classname == "func_water")
 603                 {
 604                         f = vlen(wishvel);
 605                         if (f > self.ladder_entity.speed)
 606                                 wishvel = wishvel * (self.ladder_entity.speed / f);
 607
 608                         self.watertype = self.ladder_entity.skin;
 609                         f = self.ladder_entity.origin_z + self.ladder_entity.maxs_z;
 610                         if ((self.origin_z + self.view_ofs_z) < f)
 611                                 self.waterlevel = 3;
 612                         else if ((self.origin_z + (self.mins_z + self.maxs_z) * 0.5) < f)
 613                                 self.waterlevel = 2;
 614                         else if ((self.origin_z + self.mins_z + 1) < f)
 615                                 self.waterlevel = 1;
 616                         else
 617                         {
 618                                 self.waterlevel = 0;
 619                                 self.watertype = CONTENT_EMPTY;
 620                         }
 621                 }
 622                 // acceleration
 623                 wishdir = normalize(wishvel);
 624                 wishspeed = vlen(wishvel);
 625                 if (wishspeed > sv_maxspeed)
 626                         wishspeed = sv_maxspeed;
 627                 if (time >= self.teleport_time)
 628                 {
 629                         f = wishspeed - (self.velocity * wishdir);
 630                         if (f > 0)
 631                                 self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 632                 }
 633         }
 634         else if (self.flags & FL_ONGROUND)
 635         {
 636                 // walking
 637                 makevectors(self.v_angle_y * '0 1 0');
 638                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
 639
 640                 if(!(self.lastflags & FL_ONGROUND))
 641                 {
 642                         if(cvar("speedmeter"))
 643                                 dprint(strcat("landing velocity: ", vtos(self.velocity), " (abs: ", ftos(vlen(self.velocity)), ")\n"));
 644                         if(self.lastground < time - 0.3)
 645                                 self.velocity = self.velocity * (1 - cvar("sv_friction_on_land"));
 646                         if(self.jumppadcount > 1)
 647                                 dprint(strcat(ftos(self.jumppadcount), "x jumppad combo\n"));
 648                         self.jumppadcount = 0;
 649                 }
 650
 651                 if (self.velocity_x || self.velocity_y)
 652                 if (!(self.flags & FL_JUMPRELEASED) || !self.BUTTON_JUMP)
 653                 {
 654                         v = self.velocity;
 655                         v_z = 0;
 656                         f = vlen(v);
 657                         if (f < sv_stopspeed)
 658                                 f = 1 - frametime * (sv_stopspeed / f) * sv_friction;
 659                         else
 660                                 f = 1 - frametime * sv_friction;
 661                         if (f > 0)
 662                                 self.velocity = self.velocity * f;
 663                         else
 664                                 self.velocity = '0 0 0';
 665                 }
 666                 // acceleration
 667                 wishdir = normalize(wishvel);
 668                 wishspeed = vlen(wishvel);
 669                 if (wishspeed > sv_maxspeed*maxspd_mod)
 670                         wishspeed = sv_maxspeed*maxspd_mod;
 671                 if (self.crouch)
 672                         wishspeed = wishspeed * 0.5;
 673                 if (time >= self.teleport_time)
 674                 {
 675                         f = wishspeed - (self.velocity * wishdir);
 676                         if (f > 0)
 677                                 self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 678                 }
 679         }
 680         else
 681         {
 682                 if(maxspd_mod < 1)
 683                 {
 684                         maxairspd = sv_maxairspeed*maxspd_mod;
 685                         airaccel = sv_airaccelerate*maxspd_mod;
 686                 }
 687                 else
 688                 {
 689                         maxairspd = sv_maxairspeed;
 690                         airaccel = sv_airaccelerate;
 691                 }
 692                 // airborn
 693                 makevectors(self.v_angle_y * '0 1 0');
 694                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
 695                 // acceleration
 696                 wishdir = normalize(wishvel);
 697                 wishspeed = vlen(wishvel);
 698                 if (wishspeed > maxairspd)
 699                         wishspeed = maxairspd;
 700                 if (self.crouch)
 701                         wishspeed = wishspeed * 0.5;
 702                 if (time >= self.teleport_time)
 703                 {
 704                         // NOTE: this does the same as the commented out old code if:
 705                         //   sv_airaccel_qw 0
 706                         //   sv_airaccel_sideways_friction 0
 707
 708                         float vel_straight;
 709                         float vel_z;
 710                         vector vel_perpend;
 711                         vel_straight = self.velocity * wishdir;
 712                         vel_z = self.velocity_z;
 713                         vel_perpend = self.velocity - vel_straight * wishdir - vel_z * '0 0 1';
 714
 715                         f = wishspeed - vel_straight;
 716                         if(f > 0)
 717                                 vel_straight = vel_straight + min(f, airaccel * frametime * wishspeed) * sv_airaccel_qw;
 718                         if(wishspeed > 0)
 719                                 vel_straight = vel_straight + min(wishspeed, airaccel * frametime * wishspeed) * (1 - sv_airaccel_qw);
 720
 721                         // anti-sideways friction to fix QW-style bunnyhopping
 722                         vel_perpend = vel_perpend * (1 - frametime * (wishspeed / maxairspd) * sv_airaccel_sideways_friction);
 723
 724                         self.velocity = vel_straight * wishdir + vel_z * '0 0 1' + vel_perpend;
 725
 726                         /*
 727                         f = wishspeed;// - (self.velocity * wishdir);
 728                         if (f > 0)
 729                                 self.velocity = self.velocity + wishdir * min(f, airaccel * frametime * wishspeed);
 730                         */
 731                 }
 732         }
 733
 734         if(self.flags & FL_ONGROUND)
 735                 self.lastground = time;
 736
 737         self.lastflags = self.flags;
 738 };