data/qcsrc/server/cl_physics.qc

   1 float sv_accelerate;
   2 float sv_friction;
   3 float sv_maxspeed;
   4 float sv_airaccelerate;
   5 float sv_maxairspeed;
   6 float sv_stopspeed;
   7 float sv_gravity;
   8 float sv_airaccel_sideways_friction;
   9 float sv_airaccel_qw;
  10 .float ladder_time;
  11 .entity ladder_entity;
  12 .float gravity;
  13 .float swamp_slowdown;
  14 .float lastflags;
  15 .float lastground;
  16
  17 /*
  18 =============
  19 PlayerJump
  20
  21 When you press the jump key
  22 =============
  23 */
  24 void PlayerJump (void)
  25 {
  26         float mjumpheight;
  27
  28         mjumpheight = cvar("g_balance_jumpheight");
  29         if (self.waterlevel >= 2)
  30         {
  31                 if (self.watertype == CONTENT_WATER)
  32                         self.velocity_z = 200;
  33                 else if (self.watertype == CONTENT_SLIME)
  34                         self.velocity_z = 80;
  35                 else
  36                         self.velocity_z = 50;
  37
  38                 return;
  39         }
  40
  41
  42         if (!(self.flags & FL_ONGROUND))
  43                 return;
  44
  45         if (!(self.flags & FL_JUMPRELEASED))
  46                 return;
  47
  48         if(cvar("g_runematch"))
  49         {
  50                 if(self.runes & RUNE_SPEED)
  51                 {
  52                         if(self.runes & CURSE_SLOW)
  53                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_combo_jumpheight");
  54                         else
  55                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
  56                 }
  57                 else if(self.runes & CURSE_SLOW)
  58                 {
  59                         mjumpheight = mjumpheight * cvar("g_balance_curse_slow_jumpheight");
  60                 }
  61         }
  62
  63         if(cvar("g_minstagib") && (self.items & IT_INVINCIBLE))
  64         {
  65                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
  66         }
  67
  68         self.velocity_z = self.velocity_z + mjumpheight;
  69         self.oldvelocity_z = self.velocity_z;
  70
  71         self.flags = self.flags - FL_ONGROUND;
  72         self.flags = self.flags - FL_JUMPRELEASED;
  73 }
  74
  75 void() CheckWaterJump =
  76 {
  77         local vector start, end;
  78
  79 // check for a jump-out-of-water
  80         makevectors (self.angles);
  81         start = self.origin;
  82         start_z = start_z + 8;
  83         v_forward_z = 0;
  84         normalize(v_forward);
  85         end = start + v_forward*24;
  86         traceline (start, end, TRUE, self);
  87         if (trace_fraction < 1)
  88         {       // solid at waist
  89                 start_z = start_z + self.maxs_z - 8;
  90                 end = start + v_forward*24;
  91                 self.movedir = trace_plane_normal * -50;
  92                 traceline (start, end, TRUE, self);
  93                 if (trace_fraction == 1)
  94                 {       // open at eye level
  95                         self.flags = self.flags | FL_WATERJUMP;
  96                         self.velocity_z = 225;
  97                         self.flags = self.flags - (self.flags & FL_JUMPRELEASED);
  98                         self.teleport_time = time + 2;  // safety net
  99                         return;
 100                 }
 101         }
 102 };
 103
 104
 105 void Nixnex_GiveCurrentWeapon();
 106 void SV_PlayerPhysics()
 107 {
 108         local vector wishvel, wishdir, v;
 109         local float wishspeed, f, maxspd_mod, spd, maxairspd, airaccel, swampspd_mod;
 110         string temps;
 111
 112         if (clienttype(self) == CLIENTTYPE_BOT)
 113                 bot_think();
 114
 115         if (self.movetype == MOVETYPE_NONE)
 116                 return;
 117
 118         if (self.punchangle != '0 0 0')
 119         {
 120                 f = vlen(self.punchangle) - 10 * frametime;
 121                 if (f > 0)
 122                         self.punchangle = normalize(self.punchangle) * f;
 123                 else
 124                         self.punchangle = '0 0 0';
 125         }
 126
 127         if (self.punchvector != '0 0 0')
 128         {
 129                 f = vlen(self.punchvector) - 30 * frametime;
 130                 if (f > 0)
 131                         self.punchvector = normalize(self.punchvector) * f;
 132                 else
 133                         self.punchvector = '0 0 0';
 134         }
 135
 136         maxspd_mod = 1;
 137
 138         if(cvar("g_runematch"))
 139         {
 140                 if(self.runes & RUNE_SPEED)
 141                 {
 142                         if(self.runes & CURSE_SLOW)
 143                                 maxspd_mod = maxspd_mod * cvar("g_balance_rune_speed_combo_moverate");
 144                         else
 145                                 maxspd_mod = maxspd_mod * cvar("g_balance_rune_speed_moverate");
 146                 }
 147                 else if(self.runes & CURSE_SLOW)
 148                 {
 149                         maxspd_mod = maxspd_mod * cvar("g_balance_curse_slow_moverate");
 150                 }
 151         }
 152
 153         if(cvar("g_minstagib") && (self.items & IT_INVINCIBLE))
 154         {
 155                 maxspd_mod = cvar("g_balance_rune_speed_moverate");
 156         }
 157
 158         swampspd_mod = 1;
 159         if(self.in_swamp) {
 160                 swampspd_mod = self.swamp_slowdown; //cvar("g_balance_swamp_moverate");
 161         }
 162
 163         if(self.flags & FL_NOTARGET)
 164                 maxspd_mod = cvar("sv_spectator_speed_multiplier");
 165
 166         spd = sv_maxspeed * maxspd_mod * swampspd_mod;
 167
 168         if(self.speed != spd)
 169         {
 170                 self.speed = spd;
 171                 temps = ftos(spd);
 172                 stuffcmd(self, strcat("cl_forwardspeed ", temps, "\n"));
 173                 stuffcmd(self, strcat("cl_backspeed ", temps, "\n"));
 174                 stuffcmd(self, strcat("cl_sidespeed ", temps, "\n"));
 175                 stuffcmd(self, strcat("cl_upspeed ", temps, "\n"));
 176
 177                 temps = ftos(sv_accelerate * maxspd_mod);
 178                 stuffcmd(self, strcat("cl_movement_accelerate ", temps, "\n"));
 179         }
 180
 181         // if dead, behave differently
 182         if (self.deadflag)
 183                 return;
 184
 185         UpdateSelectedPlayer();
 186
 187         if (!self.fixangle)
 188         {
 189                 self.angles_x = 0;
 190                 self.angles_y = self.v_angle_y;
 191                 self.angles_z = 0;
 192         }
 193
 194         if(self.classname == "player")
 195         {
 196                 if (self.button2)
 197                         PlayerJump ();
 198                 else
 199                         self.flags = self.flags | FL_JUMPRELEASED;
 200
 201                 if (self.waterlevel == 2)
 202                         CheckWaterJump ();
 203         }
 204
 205         if (self.flags & FL_WATERJUMP )
 206         {
 207                 self.velocity_x = self.movedir_x;
 208                 self.velocity_y = self.movedir_y;
 209                 if (time > self.teleport_time || self.waterlevel == 0)
 210                 {
 211                         self.flags = self.flags - (self.flags & FL_WATERJUMP);
 212                         self.teleport_time = 0;
 213                 }
 214         }
 215         else if (self.movetype == MOVETYPE_NOCLIP || self.movetype == MOVETYPE_FLY)
 216         {
 217                 // noclipping or flying
 218                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 219
 220                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 221                 makevectors(self.v_angle);
 222                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 223                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 224                 // acceleration
 225                 wishdir = normalize(wishvel);
 226                 wishspeed = vlen(wishvel);
 227                 if (wishspeed > sv_maxspeed*maxspd_mod)
 228                         wishspeed = sv_maxspeed*maxspd_mod;
 229                 if (time >= self.teleport_time)
 230                 {
 231                         f = wishspeed - (self.velocity * wishdir);
 232                         if (f > 0)
 233                                 self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 234                 }
 235         }
 236         else if (self.waterlevel >= 2)
 237         {
 238                 // swimming
 239                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 240
 241                 makevectors(self.v_angle);
 242                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 243                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 244                 if (wishvel == '0 0 0')
 245                         wishvel = '0 0 -60'; // drift towards bottom
 246
 247                 wishdir = normalize(wishvel);
 248                 wishspeed = vlen(wishvel);
 249                 if (wishspeed > sv_maxspeed*maxspd_mod)
 250                         wishspeed = sv_maxspeed*maxspd_mod;
 251                 wishspeed = wishspeed * 0.7;
 252
 253                 // water friction
 254                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 255
 256                 // water acceleration
 257                 f = wishspeed - (self.velocity * wishdir);
 258                 if (f > 0)
 259                         self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 260         }
 261         else if (time < self.ladder_time)
 262         {
 263                 // on a func_ladder or swimming in func_water
 264                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 265
 266                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 267                 makevectors(self.v_angle);
 268                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 269                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 270                 if (self.gravity)
 271                         self.velocity_z = self.velocity_z + self.gravity * sv_gravity * frametime;
 272                 else
 273                         self.velocity_z = self.velocity_z + sv_gravity * frametime;
 274                 if (self.ladder_entity.classname == "func_water")
 275                 {
 276                         f = vlen(wishvel);
 277                         if (f > self.ladder_entity.speed)
 278                                 wishvel = wishvel * (self.ladder_entity.speed / f);
 279
 280                         self.watertype = self.ladder_entity.skin;
 281                         f = self.ladder_entity.origin_z + self.ladder_entity.maxs_z;
 282                         if ((self.origin_z + self.view_ofs_z) < f)
 283                                 self.waterlevel = 3;
 284                         else if ((self.origin_z + (self.mins_z + self.maxs_z) * 0.5) < f)
 285                                 self.waterlevel = 2;
 286                         else if ((self.origin_z + self.mins_z + 1) < f)
 287                                 self.waterlevel = 1;
 288                         else
 289                         {
 290                                 self.waterlevel = 0;
 291                                 self.watertype = CONTENT_EMPTY;
 292                         }
 293                 }
 294                 // acceleration
 295                 wishdir = normalize(wishvel);
 296                 wishspeed = vlen(wishvel);
 297                 if (wishspeed > sv_maxspeed)
 298                         wishspeed = sv_maxspeed;
 299                 if (time >= self.teleport_time)
 300                 {
 301                         f = wishspeed - (self.velocity * wishdir);
 302                         if (f > 0)
 303                                 self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 304                 }
 305         }
 306         else if (self.flags & FL_ONGROUND)
 307         {
 308                 // walking
 309                 makevectors(self.v_angle_y * '0 1 0');
 310                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
 311
 312                 if(!(self.lastflags & FL_ONGROUND))
 313                 {
 314                         if(cvar("speedmeter"))
 315                                 dprint(strcat("landing velocity: ", vtos(self.velocity), " (abs: ", ftos(vlen(self.velocity)), ")\n"));
 316                         if(self.lastground < time - 0.3)
 317                                 self.velocity = self.velocity * (1 - cvar("sv_friction_on_land"));
 318                         if(self.jumppadcount > 1)
 319                                 dprint(strcat(ftos(self.jumppadcount), "x jumppad combo\n"));
 320                         self.jumppadcount = 0;
 321                 }
 322
 323                 if (self.velocity_x || self.velocity_y)
 324                 if (!(self.flags & FL_JUMPRELEASED) || !self.button2)
 325                 {
 326                         v = self.velocity;
 327                         v_z = 0;
 328                         f = vlen(v);
 329                         if (f < sv_stopspeed)
 330                                 f = 1 - frametime * (sv_stopspeed / f) * sv_friction;
 331                         else
 332                                 f = 1 - frametime * sv_friction;
 333                         if (f > 0)
 334                                 self.velocity = self.velocity * f;
 335                         else
 336                                 self.velocity = '0 0 0';
 337                 }
 338                 // acceleration
 339                 wishdir = normalize(wishvel);
 340                 wishspeed = vlen(wishvel);
 341                 if (wishspeed > sv_maxspeed*maxspd_mod)
 342                         wishspeed = sv_maxspeed*maxspd_mod;
 343                 if (self.crouch)
 344                         wishspeed = wishspeed * 0.5;
 345                 if (time >= self.teleport_time)
 346                 {
 347                         f = wishspeed - (self.velocity * wishdir);
 348                         if (f > 0)
 349                                 self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 350                 }
 351         }
 352         else
 353         {
 354                 if(maxspd_mod < 1)
 355                 {
 356                         maxairspd = sv_maxairspeed*maxspd_mod;
 357                         airaccel = sv_airaccelerate*maxspd_mod;
 358                 }
 359                 else
 360                 {
 361                         maxairspd = sv_maxairspeed;
 362                         airaccel = sv_airaccelerate;
 363                 }
 364                 // airborn
 365                 makevectors(self.v_angle_y * '0 1 0');
 366                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
 367                 // acceleration
 368                 wishdir = normalize(wishvel);
 369                 wishspeed = vlen(wishvel);
 370                 if (wishspeed > maxairspd)
 371                         wishspeed = maxairspd;
 372                 if (self.crouch)
 373                         wishspeed = wishspeed * 0.5;
 374                 if (time >= self.teleport_time)
 375                 {
 376                         // NOTE: this does the same as the commented out old code if:
 377                         //   sv_airaccel_qw 0
 378                         //   sv_airaccel_sideways_friction 0
 379
 380                         float vel_straight;
 381                         float vel_z;
 382                         vector vel_perpend;
 383                         vel_straight = self.velocity * wishdir;
 384                         vel_z = self.velocity_z;
 385                         vel_perpend = self.velocity - vel_straight * wishdir - vel_z * '0 0 1';
 386
 387                         f = wishspeed - vel_straight;
 388                         if(f > 0)
 389                                 vel_straight = vel_straight + min(f, airaccel * frametime * wishspeed) * sv_airaccel_qw;
 390                         if(wishspeed > 0)
 391                                 vel_straight = vel_straight + min(wishspeed, airaccel * frametime * wishspeed) * (1 - sv_airaccel_qw);
 392
 393                         // anti-sideways friction to fix QW-style bunnyhopping
 394                         vel_perpend = vel_perpend * (1 - frametime * (wishspeed / maxairspd) * sv_airaccel_sideways_friction);
 395
 396                         self.velocity = vel_straight * wishdir + vel_z * '0 0 1' + vel_perpend;
 397
 398                         /*
 399                         f = wishspeed;// - (self.velocity * wishdir);
 400                         if (f > 0)
 401                                 self.velocity = self.velocity + wishdir * min(f, airaccel * frametime * wishspeed);
 402                         */
 403                 }
 404         }
 405
 406         if(self.flags & FL_ONGROUND)
 407                 self.lastground = time;
 408
 409         self.lastflags = self.flags;
 410 };