data/qcsrc/server/cl_physics.qc

   1 float sv_accelerate;
   2 float sv_friction;
   3 float sv_maxspeed;
   4 float sv_airaccelerate;
   5 float sv_maxairspeed;
   6 float sv_stopspeed;
   7 float sv_gravity;
   8 float sv_airaccel_sideways_friction;
   9 float sv_airaccel_qw;
  10 .float ladder_time;
  11 .entity ladder_entity;
  12 .float gravity;
  13 .float swamp_slowdown;
  14 .float lastflags;
  15 .float lastground;
  16
  17 #define SHTEST_DELTA 15
  18 .float shtest_next;
  19 .float shtest_accumulator;
  20
  21 /*
  22 =============
  23 PlayerJump
  24
  25 When you press the jump key
  26 =============
  27 */
  28 void PlayerJump (void)
  29 {
  30         float mjumpheight;
  31
  32         mjumpheight = cvar("sv_jumpvelocity");
  33         if (self.waterlevel >= 2)
  34         {
  35                 if (self.watertype == CONTENT_WATER)
  36                         self.velocity_z = 200;
  37                 else if (self.watertype == CONTENT_SLIME)
  38                         self.velocity_z = 80;
  39                 else
  40                         self.velocity_z = 50;
  41
  42                 return;
  43         }
  44
  45
  46         if (!(self.flags & FL_ONGROUND))
  47                 return;
  48
  49         if (!(self.flags & FL_JUMPRELEASED))
  50                 return;
  51
  52         if(cvar("g_runematch"))
  53         {
  54                 if(self.runes & RUNE_SPEED)
  55                 {
  56                         if(self.runes & CURSE_SLOW)
  57                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_combo_jumpheight");
  58                         else
  59                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
  60                 }
  61                 else if(self.runes & CURSE_SLOW)
  62                 {
  63                         mjumpheight = mjumpheight * cvar("g_balance_curse_slow_jumpheight");
  64                 }
  65         }
  66
  67         if(g_minstagib && (self.items & IT_INVINCIBLE))
  68         {
  69                 mjumpheight = mjumpheight * cvar("g_minstagib_speed_jumpheight");
  70         }
  71
  72         self.velocity_z = self.velocity_z + mjumpheight;
  73         self.oldvelocity_z = self.velocity_z;
  74
  75         self.flags = self.flags - FL_ONGROUND;
  76         self.flags = self.flags - FL_JUMPRELEASED;
  77 }
  78
  79 void() CheckWaterJump =
  80 {
  81         local vector start, end;
  82
  83 // check for a jump-out-of-water
  84         makevectors (self.angles);
  85         start = self.origin;
  86         start_z = start_z + 8;
  87         v_forward_z = 0;
  88         normalize(v_forward);
  89         end = start + v_forward*24;
  90         traceline (start, end, TRUE, self);
  91         if (trace_fraction < 1)
  92         {       // solid at waist
  93                 start_z = start_z + self.maxs_z - 8;
  94                 end = start + v_forward*24;
  95                 self.movedir = trace_plane_normal * -50;
  96                 traceline (start, end, TRUE, self);
  97                 if (trace_fraction == 1)
  98                 {       // open at eye level
  99                         self.flags = self.flags | FL_WATERJUMP;
 100                         self.velocity_z = 225;
 101                         self.flags = self.flags - (self.flags & FL_JUMPRELEASED);
 102                         self.teleport_time = time + 2;  // safety net
 103                         return;
 104                 }
 105         }
 106 };
 107
 108
 109 void Nixnex_GiveCurrentWeapon();
 110 void SV_PlayerPhysics()
 111 {
 112         local vector wishvel, wishdir, v;
 113         local float wishspeed, f, maxspd_mod, spd, maxairspd, airaccel, swampspd_mod, shtest_score;
 114         string temps;
 115
 116         if(time > self.shtest_next)
 117         {
 118                 if(self.shtest_next > 0)
 119                 {
 120                         // self.shtest_accumulator:
 121                         //   started at time - SHTEST_DELTA
 122                         //   should be at SHTEST_DELTA
 123                         shtest_score = self.shtest_accumulator / SHTEST_DELTA;
 124                         if(shtest_score > 1.2)
 125                                 dprint("TIME PARADOX: shtest for ", self.netname, " said ", ftos(shtest_score), "\n");
 126                         else if(cvar("developer_shtest"))
 127                                 dprint("okay: shtest for ", self.netname, " said ", ftos(shtest_score), "\n");
 128                 }
 129                 self.shtest_next = time + SHTEST_DELTA;
 130                 self.shtest_accumulator = 0;
 131         }
 132         self.shtest_accumulator += frametime;
 133
 134         if (clienttype(self) == CLIENTTYPE_BOT)
 135                 bot_think();
 136
 137         if (self.movetype == MOVETYPE_NONE)
 138                 return;
 139
 140         if (self.punchangle != '0 0 0')
 141         {
 142                 f = vlen(self.punchangle) - 10 * frametime;
 143                 if (f > 0)
 144                         self.punchangle = normalize(self.punchangle) * f;
 145                 else
 146                         self.punchangle = '0 0 0';
 147         }
 148
 149         if (self.punchvector != '0 0 0')
 150         {
 151                 f = vlen(self.punchvector) - 30 * frametime;
 152                 if (f > 0)
 153                         self.punchvector = normalize(self.punchvector) * f;
 154                 else
 155                         self.punchvector = '0 0 0';
 156         }
 157
 158         maxspd_mod = 1;
 159
 160         if(cvar("g_runematch"))
 161         {
 162                 if(self.runes & RUNE_SPEED)
 163                 {
 164                         if(self.runes & CURSE_SLOW)
 165                                 maxspd_mod = maxspd_mod * cvar("g_balance_rune_speed_combo_moverate");
 166                         else
 167                                 maxspd_mod = maxspd_mod * cvar("g_balance_rune_speed_moverate");
 168                 }
 169                 else if(self.runes & CURSE_SLOW)
 170                 {
 171                         maxspd_mod = maxspd_mod * cvar("g_balance_curse_slow_moverate");
 172                 }
 173         }
 174
 175         if(g_minstagib && (self.items & IT_INVINCIBLE))
 176         {
 177                 maxspd_mod = cvar("g_minstagib_speed_moverate");
 178         }
 179
 180         swampspd_mod = 1;
 181         if(self.in_swamp) {
 182                 swampspd_mod = self.swamp_slowdown; //cvar("g_balance_swamp_moverate");
 183         }
 184
 185         if(self.flags & FL_NOTARGET)
 186                 maxspd_mod = cvar("sv_spectator_speed_multiplier");
 187
 188         spd = sv_maxspeed * maxspd_mod * swampspd_mod;
 189
 190         if(self.speed != spd)
 191         {
 192                 self.speed = spd;
 193                 temps = ftos(spd);
 194                 stuffcmd(self, strcat("cl_forwardspeed ", temps, "\n"));
 195                 stuffcmd(self, strcat("cl_backspeed ", temps, "\n"));
 196                 stuffcmd(self, strcat("cl_sidespeed ", temps, "\n"));
 197                 stuffcmd(self, strcat("cl_upspeed ", temps, "\n"));
 198
 199                 temps = ftos(sv_accelerate * maxspd_mod);
 200                 stuffcmd(self, strcat("cl_movement_accelerate ", temps, "\n"));
 201         }
 202
 203         // if dead, behave differently
 204         if (self.deadflag)
 205                 return;
 206
 207         if (!self.fixangle)
 208         {
 209                 self.angles_x = 0;
 210                 self.angles_y = self.v_angle_y;
 211                 self.angles_z = 0;
 212         }
 213
 214         if(self.classname == "player")
 215         {
 216                 if (self.button2)
 217                         PlayerJump ();
 218                 else
 219                         self.flags = self.flags | FL_JUMPRELEASED;
 220
 221                 if (self.waterlevel == 2)
 222                         CheckWaterJump ();
 223         }
 224
 225         if (self.flags & FL_WATERJUMP )
 226         {
 227                 self.velocity_x = self.movedir_x;
 228                 self.velocity_y = self.movedir_y;
 229                 if (time > self.teleport_time || self.waterlevel == 0)
 230                 {
 231                         self.flags = self.flags - (self.flags & FL_WATERJUMP);
 232                         self.teleport_time = 0;
 233                 }
 234         }
 235         else if (self.movetype == MOVETYPE_NOCLIP || self.movetype == MOVETYPE_FLY)
 236         {
 237                 // noclipping or flying
 238                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 239
 240                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 241                 makevectors(self.v_angle);
 242                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 243                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 244                 // acceleration
 245                 wishdir = normalize(wishvel);
 246                 wishspeed = vlen(wishvel);
 247                 if (wishspeed > sv_maxspeed*maxspd_mod)
 248                         wishspeed = sv_maxspeed*maxspd_mod;
 249                 if (time >= self.teleport_time)
 250                 {
 251                         f = wishspeed - (self.velocity * wishdir);
 252                         if (f > 0)
 253                                 self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 254                 }
 255         }
 256         else if (self.waterlevel >= 2)
 257         {
 258                 // swimming
 259                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 260
 261                 makevectors(self.v_angle);
 262                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 263                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 264                 if (wishvel == '0 0 0')
 265                         wishvel = '0 0 -60'; // drift towards bottom
 266
 267                 wishdir = normalize(wishvel);
 268                 wishspeed = vlen(wishvel);
 269                 if (wishspeed > sv_maxspeed*maxspd_mod)
 270                         wishspeed = sv_maxspeed*maxspd_mod;
 271                 wishspeed = wishspeed * 0.7;
 272
 273                 // water friction
 274                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 275
 276                 // water acceleration
 277                 f = wishspeed - (self.velocity * wishdir);
 278                 if (f > 0)
 279                         self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 280         }
 281         else if (time < self.ladder_time)
 282         {
 283                 // on a func_ladder or swimming in func_water
 284                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 285
 286                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 287                 makevectors(self.v_angle);
 288                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 289                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 290                 if (self.gravity)
 291                         self.velocity_z = self.velocity_z + self.gravity * sv_gravity * frametime;
 292                 else
 293                         self.velocity_z = self.velocity_z + sv_gravity * frametime;
 294                 if (self.ladder_entity.classname == "func_water")
 295                 {
 296                         f = vlen(wishvel);
 297                         if (f > self.ladder_entity.speed)
 298                                 wishvel = wishvel * (self.ladder_entity.speed / f);
 299
 300                         self.watertype = self.ladder_entity.skin;
 301                         f = self.ladder_entity.origin_z + self.ladder_entity.maxs_z;
 302                         if ((self.origin_z + self.view_ofs_z) < f)
 303                                 self.waterlevel = 3;
 304                         else if ((self.origin_z + (self.mins_z + self.maxs_z) * 0.5) < f)
 305                                 self.waterlevel = 2;
 306                         else if ((self.origin_z + self.mins_z + 1) < f)
 307                                 self.waterlevel = 1;
 308                         else
 309                         {
 310                                 self.waterlevel = 0;
 311                                 self.watertype = CONTENT_EMPTY;
 312                         }
 313                 }
 314                 // acceleration
 315                 wishdir = normalize(wishvel);
 316                 wishspeed = vlen(wishvel);
 317                 if (wishspeed > sv_maxspeed)
 318                         wishspeed = sv_maxspeed;
 319                 if (time >= self.teleport_time)
 320                 {
 321                         f = wishspeed - (self.velocity * wishdir);
 322                         if (f > 0)
 323                                 self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 324                 }
 325         }
 326         else if (self.flags & FL_ONGROUND)
 327         {
 328                 // walking
 329                 makevectors(self.v_angle_y * '0 1 0');
 330                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
 331
 332                 if(!(self.lastflags & FL_ONGROUND))
 333                 {
 334                         if(cvar("speedmeter"))
 335                                 dprint(strcat("landing velocity: ", vtos(self.velocity), " (abs: ", ftos(vlen(self.velocity)), ")\n"));
 336                         if(self.lastground < time - 0.3)
 337                                 self.velocity = self.velocity * (1 - cvar("sv_friction_on_land"));
 338                         if(self.jumppadcount > 1)
 339                                 dprint(strcat(ftos(self.jumppadcount), "x jumppad combo\n"));
 340                         self.jumppadcount = 0;
 341                 }
 342
 343                 if (self.velocity_x || self.velocity_y)
 344                 if (!(self.flags & FL_JUMPRELEASED) || !self.button2)
 345                 {
 346                         v = self.velocity;
 347                         v_z = 0;
 348                         f = vlen(v);
 349                         if (f < sv_stopspeed)
 350                                 f = 1 - frametime * (sv_stopspeed / f) * sv_friction;
 351                         else
 352                                 f = 1 - frametime * sv_friction;
 353                         if (f > 0)
 354                                 self.velocity = self.velocity * f;
 355                         else
 356                                 self.velocity = '0 0 0';
 357                 }
 358                 // acceleration
 359                 wishdir = normalize(wishvel);
 360                 wishspeed = vlen(wishvel);
 361                 if (wishspeed > sv_maxspeed*maxspd_mod)
 362                         wishspeed = sv_maxspeed*maxspd_mod;
 363                 if (self.crouch)
 364                         wishspeed = wishspeed * 0.5;
 365                 if (time >= self.teleport_time)
 366                 {
 367                         f = wishspeed - (self.velocity * wishdir);
 368                         if (f > 0)
 369                                 self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 370                 }
 371         }
 372         else
 373         {
 374                 if(maxspd_mod < 1)
 375                 {
 376                         maxairspd = sv_maxairspeed*maxspd_mod;
 377                         airaccel = sv_airaccelerate*maxspd_mod;
 378                 }
 379                 else
 380                 {
 381                         maxairspd = sv_maxairspeed;
 382                         airaccel = sv_airaccelerate;
 383                 }
 384                 // airborn
 385                 makevectors(self.v_angle_y * '0 1 0');
 386                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
 387                 // acceleration
 388                 wishdir = normalize(wishvel);
 389                 wishspeed = vlen(wishvel);
 390                 if (wishspeed > maxairspd)
 391                         wishspeed = maxairspd;
 392                 if (self.crouch)
 393                         wishspeed = wishspeed * 0.5;
 394                 if (time >= self.teleport_time)
 395                 {
 396                         // NOTE: this does the same as the commented out old code if:
 397                         //   sv_airaccel_qw 0
 398                         //   sv_airaccel_sideways_friction 0
 399
 400                         float vel_straight;
 401                         float vel_z;
 402                         vector vel_perpend;
 403                         vel_straight = self.velocity * wishdir;
 404                         vel_z = self.velocity_z;
 405                         vel_perpend = self.velocity - vel_straight * wishdir - vel_z * '0 0 1';
 406
 407                         f = wishspeed - vel_straight;
 408                         if(f > 0)
 409                                 vel_straight = vel_straight + min(f, airaccel * frametime * wishspeed) * sv_airaccel_qw;
 410                         if(wishspeed > 0)
 411                                 vel_straight = vel_straight + min(wishspeed, airaccel * frametime * wishspeed) * (1 - sv_airaccel_qw);
 412
 413                         // anti-sideways friction to fix QW-style bunnyhopping
 414                         vel_perpend = vel_perpend * (1 - frametime * (wishspeed / maxairspd) * sv_airaccel_sideways_friction);
 415
 416                         self.velocity = vel_straight * wishdir + vel_z * '0 0 1' + vel_perpend;
 417
 418                         /*
 419                         f = wishspeed;// - (self.velocity * wishdir);
 420                         if (f > 0)
 421                                 self.velocity = self.velocity + wishdir * min(f, airaccel * frametime * wishspeed);
 422                         */
 423                 }
 424         }
 425
 426         if(self.flags & FL_ONGROUND)
 427                 self.lastground = time;
 428
 429         self.lastflags = self.flags;
 430 };