data/qcsrc/server/cl_impulse.qc

   1 .vector personal_v_angle; // view angles to restore on impulse 77
   2 .vector personal_velocity; // velocity to restore on impulse 77
   3
   4 void CopyBody(float keepvelocity);
   5
   6 // changes by LordHavoc on 03/30/04
   7 // cleaned up dummy code
   8 // dummies are now removed eventually after being gibbed (norespawn = TRUE)
   9 // dummy impulse now checks sv_cheats to prevent players from overwhelming server with dummies
  10 // dummies now use player code where possible
  11
  12 void player_anim (void);
  13 void DummyThink(void)
  14 {
  15         self.think = DummyThink;
  16         self.nextthink = time;
  17         SV_PlayerPhysics();
  18         PlayerPreThink();
  19         //player_anim();
  20         PlayerPostThink();
  21 }
  22
  23 // from dpmod
  24 void printsurfaceinfo(entity e, vector v)
  25 {
  26         local float surfnum, numpoints, vnum;
  27         local string s;
  28         local vector n;
  29         surfnum = getsurfacenearpoint(e, v);
  30         if (surfnum >= 0)
  31         {
  32                 sprint(self, "texture: ");
  33                 s = getsurfacetexture(e, surfnum);
  34                 sprint(self, s);
  35                 sprint(self, " normal: ");
  36                 n = getsurfacenormal(e, surfnum);
  37                 sprint(self, vtos(n));
  38                 sprint(self, " ");
  39                 numpoints = getsurfacenumpoints(e, surfnum);
  40                 sprint(self, ftos(numpoints));
  41                 sprint(self, " verts:");
  42                 vnum = 0;
  43                 while (vnum < numpoints)
  44                 {
  45                         sprint(self, " ");
  46                         n = getsurfacepoint(e, surfnum, vnum);
  47                         sprint(self, vtos(n));
  48                         vnum = vnum + 1;
  49                 }
  50                 sprint(self, " point tested: ");
  51                 sprint(self, vtos(v));
  52                 sprint(self, " nearest point on surface: ");
  53                 n = getsurfaceclippedpoint(e, surfnum, v);
  54                 sprint(self, vtos(n));
  55                 sprint(self, "\n");
  56         }
  57 };
  58
  59 /*
  60  * Impulse map:
  61  *
  62  * 0 reserved (no input)
  63  * 1 to 9, 14: weapon shortcuts
  64  * 10: next weapon according to linear list
  65  * 11: most recently used weapon
  66  * 12: previous weapon according to linear list
  67  * 13: best weapon according to priority list
  68  * 15: next weapon according to priority list
  69  * 16: previous weapon according to priority list
  70  * 17: throw weapon
  71  * 18: next weapon according to sbar_hudselector 1 list
  72  * 19: previous weapon according to sbar_hudselector 1 list
  73  *
  74  * 30 to 39: create waypoints
  75  * 47: clear personal waypoints
  76  * 48: clear team waypoints
  77  * 49: turn base waypoints on/off
  78  *
  79  * 99: loaded
  80  *
  81  * 140: moving clone
  82  * 141: ctf speedrun
  83  * 142: fixed clone
  84  * 143: emergency teleport
  85  * 144: printsurfaceinfo
  86  * 145: distance
  87  *
  88  * TODO:
  89  * 200 to 209: prev weapon shortcuts
  90  * 210 to 219: best weapon shortcuts
  91  * 220 to 229: next weapon shortcuts
  92  * 230 to 253: individual weapons (up to 24)
  93  */
  94
  95 void ImpulseCommands (void)
  96 {
  97         local float imp;
  98         vector start, end, enddown;
  99         float i;
 100         float m;
 101         float good, evil, evilsurf;
 102         float maxattempts;
 103         vector org, delta;
 104         float wep;
 105         entity e;
 106
 107         imp = self.impulse;
 108         if (!imp || gameover)
 109                 return;
 110         self.impulse = 0;
 111
 112         if (timeoutStatus == 2) //don't allow any impulses while the game is paused
 113                 return;
 114
 115         if (imp >= 1 && imp <= 9)
 116         {
 117                 // weapon switching impulses
 118                 if(self.deadflag == DEAD_NO)
 119                         W_NextWeaponOnImpulse(imp);
 120                 else
 121                         self.impulse = imp; // retry in next frame
 122         }
 123         else if(imp >= 10 && imp <= 19)
 124         {
 125                 if(self.deadflag == DEAD_NO)
 126                 {
 127                         switch(imp)
 128                         {
 129                                 case 10:
 130                                         W_NextWeapon (0);
 131                                         break;
 132                                 case 11:
 133                                         W_SwitchWeapon (self.cnt); // previously used
 134                                         break;
 135                                 case 12:
 136                                         W_PreviousWeapon (0);
 137                                         break;
 138                                 case 13:
 139                                         W_SwitchWeapon (w_getbestweapon(self));
 140                                         break;
 141                                 case 14:
 142                                         W_NextWeaponOnImpulse(0);
 143                                         break;
 144                                 case 15:
 145                                         W_NextWeapon (2);
 146                                         break;
 147                                 case 16:
 148                                         W_PreviousWeapon (2);
 149                                         break;
 150                                 case 17:
 151                                         if (!g_minstagib)
 152                                                 W_ThrowWeapon(W_CalculateProjectileVelocity(self.velocity, v_forward * 750), '0 0 0', TRUE);
 153                                         break;
 154                                 case 18:
 155                                         W_NextWeapon (1);
 156                                         break;
 157                                 case 19:
 158                                         W_PreviousWeapon (1);
 159                                         break;
 160                                 }
 161                 }
 162                 else
 163                         self.impulse = imp; // retry in next frame
 164         }
 165         else if(imp >= 200 && imp <= 229)
 166         {
 167                 if(self.deadflag == DEAD_NO)
 168                 {
 169                         // custom order weapon cycling
 170                         i = mod(imp, 10);
 171                         m = (imp - (210 + i)); // <0 for prev, =0 for best, >0 for next
 172                         W_CycleWeapon(self.(cvar_cl_weaponpriorities[i]), m);
 173                 }
 174                 else
 175                         self.impulse = imp; // retry in next frame
 176         }
 177         else if(imp >= 230 && imp <= 253)
 178         {
 179                 if(self.deadflag == DEAD_NO)
 180                         W_SwitchWeapon (imp - 230 + WEP_FIRST);
 181                 else
 182                         self.impulse = imp; // retry in next frame
 183         }
 184         // deploy waypoints
 185         else if (imp >= 30 && imp <= 49)
 186         {
 187                 switch(imp)
 188                 {
 189                         case 30:
 190                                 WaypointSprite_DeployPersonal("waypoint", self.origin);
 191                                 self.personal_v_angle = self.v_angle;
 192                                 self.personal_velocity = self.velocity;
 193                                 sprint(self, "personal waypoint spawned at location\n");
 194                                 break;
 195                         case 31:
 196                                 WaypointSprite_DeployPersonal("waypoint", self.cursor_trace_endpos);
 197                                 self.personal_v_angle = self.v_angle;
 198                                 self.personal_velocity = '0 0 0';
 199                                 sprint(self, "personal waypoint spawned at crosshair\n");
 200                                 break;
 201                         case 32:
 202                                 if(vlen(self.death_origin))
 203                                 {
 204                                         WaypointSprite_DeployPersonal("waypoint", self.death_origin);
 205                                         self.personal_v_angle = self.v_angle;
 206                                         self.personal_velocity = '0 0 0';
 207                                         sprint(self, "personal waypoint spawned at death location\n");
 208                                 }
 209                                 break;
 210                         case 33:
 211                                 if(self.deadflag == DEAD_NO && teams_matter)
 212                                 {
 213                                         WaypointSprite_Attach("helpme", TRUE);
 214                                         sprint(self, "HELP ME attached\n");
 215                                 }
 216                                 break;
 217                         case 34:
 218                                 WaypointSprite_DeployFixed("here", FALSE, self.origin);
 219                                 sprint(self, "HERE spawned at location\n");
 220                                 break;
 221                         case 35:
 222                                 WaypointSprite_DeployFixed("here", FALSE, self.cursor_trace_endpos);
 223                                 sprint(self, "HERE spawned at crosshair\n");
 224                                 break;
 225                         case 36:
 226                                 if(vlen(self.death_origin))
 227                                 {
 228                                         WaypointSprite_DeployFixed("here", FALSE, self.death_origin);
 229                                         sprint(self, "HERE spawned at death location\n");
 230                                 }
 231                                 break;
 232                         case 37:
 233                                 WaypointSprite_DeployFixed("danger", FALSE, self.origin);
 234                                 sprint(self, "DANGER spawned at location\n");
 235                                 break;
 236                         case 38:
 237                                 WaypointSprite_DeployFixed("danger", FALSE, self.cursor_trace_endpos);
 238                                 sprint(self, "DANGER spawned at crosshair\n");
 239                                 break;
 240                         case 39:
 241                                 if(vlen(self.death_origin))
 242                                 {
 243                                         WaypointSprite_DeployFixed("danger", FALSE, self.death_origin);
 244                                         sprint(self, "DANGER spawned at death location\n");
 245                                 }
 246                                 break;
 247                         case 47:
 248                                 WaypointSprite_ClearPersonal();
 249                                 sprint(self, "personal waypoint cleared\n");
 250                                 break;
 251                         case 48:
 252                                 WaypointSprite_ClearOwned();
 253                                 sprint(self, "all waypoints cleared\n");
 254                                 break;
 255                         case 49:
 256                                 self.cvar_cl_hidewaypoints = !(self.cvar_cl_hidewaypoints);
 257                                 sprint(self, "fixed waypoints now ");
 258                                 if(self.cvar_cl_hidewaypoints)
 259                                         sprint(self, "OFF\n");
 260                                 else
 261                                         sprint(self, "ON\n");
 262                                 break;
 263                 }
 264         }
 265         else if(imp >= 140 && imp <= 149 || imp == 99) // 10 cheats ought to be enough for anyone
 266         {
 267                 if(sv_cheats)
 268                 if(self.deadflag == DEAD_NO)
 269                 {
 270                         switch(imp)
 271                         {
 272                                 case 99:
 273                                         self.weapons |= WEPBIT_ALL;
 274                                         self.items |= IT_UNLIMITED_AMMO;
 275                                         self.ammo_shells = g_pickup_shells_max;
 276                                         self.ammo_nails = g_pickup_nails_max;
 277                                         self.ammo_rockets = g_pickup_rockets_max;
 278                                         self.ammo_cells = g_pickup_cells_max;
 279                                         self.health = g_pickup_healthsmall_max;
 280                                         self.armorvalue = g_pickup_armorsmall_max;
 281                                         self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 282                                         self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 283                                         self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 284                                         // precache weapon models/sounds
 285                                         wep = WEP_FIRST;
 286                                         while (wep <= WEP_LAST)
 287                                         {
 288                                                 weapon_action(wep, WR_PRECACHE);
 289                                                 wep = wep + 1;
 290                                         }
 291                                         break;
 292                                 case 140:
 293                                         makevectors (self.v_angle);
 294                                         self.velocity = self.velocity + v_forward * 300;
 295                                         CopyBody(1);
 296                                         self.lip += 1;
 297                                         self.velocity = self.velocity - v_forward * 300;
 298                                         break;
 299                                 case 141:
 300                                         if(self.waypointsprite_deployed_personal)
 301                                         {
 302                                                 self.speedrunning = TRUE;
 303                                                 tracebox(self.waypointsprite_deployed_personal.origin, self.mins, self.maxs, self.waypointsprite_deployed_personal.origin, MOVE_WORLDONLY, self);
 304                                                 if(trace_startsolid)
 305                                                 {
 306                                                         sprint(self, "Cannot move there, cheater - only waypoints set using g_waypointsprite_personal work\n");
 307                                                 }
 308                                                 else
 309                                                 {
 310                                                         // Abort speedrun, teleport back
 311                                                         setorigin(self, self.waypointsprite_deployed_personal.origin);
 312                                                         self.oldvelocity = self.velocity = self.personal_velocity;
 313                                                         self.angles = self.personal_v_angle;
 314                                                         self.fixangle = TRUE;
 315                                                         if(self.flagcarried)
 316                                                         {
 317                                                                 bprint("The ", self.flagcarried.netname, " was returned to base by its carrier\n");
 318                                                                 ReturnFlag(self.flagcarried);
 319                                                         }
 320                                                 }
 321                                                 self.ammo_rockets = 999;
 322                                                 self.ammo_nails = 999;
 323                                                 self.ammo_cells = 999;
 324                                                 self.ammo_shells = 999;
 325                                                 self.health = start_health;
 326                                                 self.armorvalue = start_armorvalue;
 327                                                 self.weapons |= weaponsInMap;
 328                                                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 329                                                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 330                                                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 331                                         }
 332                                         else if(self.deadflag != DEAD_NO)
 333                                                 sprint(self, "UR DEAD AHAHAH))\n");
 334                                         else
 335                                                 sprint(self, "No waypoint set, cheater (use g_waypointsprite_personal to set one)\n");
 336                                         break;
 337                                 case 142:
 338                                         CopyBody(0);
 339                                         self.lip += 1;
 340                                         break;
 341                                 case 143:
 342                                         good = DPCONTENTS_SOLID | DPCONTENTS_CORPSE | DPCONTENTS_PLAYERCLIP;
 343                                         evil = DPCONTENTS_SLIME | DPCONTENTS_LAVA | DPCONTENTS_SKY | DPCONTENTS_BODY | DPCONTENTS_DONOTENTER;
 344                                         evilsurf = Q3SURFACEFLAG_SKY;
 345
 346                                         m = self.dphitcontentsmask;
 347                                         self.dphitcontentsmask = good | evil;
 348
 349                                         org = world.mins;
 350                                         delta = world.maxs - world.mins;
 351
 352                                         maxattempts = ((sv_cheats >= 2) ? 100000 : 100);
 353
 354                                         for(i = 0; i < maxattempts; ++i)
 355                                         {
 356                                                 start_x = org_x + random() * delta_x;
 357                                                 start_y = org_y + random() * delta_y;
 358                                                 start_z = org_z + random() * delta_z;
 359
 360                                                 // rule 1: start inside world bounds, and outside
 361                                                 // solid, and don't start from somewhere where you can
 362                                                 // fall down to evil
 363                                                 tracebox(start, self.mins, self.maxs, start - '0 0 1' * delta_z, MOVE_NORMAL, self);
 364                                                 if(trace_fraction >= 1)
 365                                                         continue;
 366                                                 if(trace_startsolid)
 367                                                         continue;
 368                                                 dprint("hit contents ", ftos(trace_dphitcontents), "\n");
 369                                                 if(trace_dphitcontents & evil)
 370                                                         continue;
 371                                                 if(trace_dphitq3surfaceflags & evilsurf)
 372                                                         continue;
 373
 374                                                 // rule 2: if we are too high, lower the point
 375                                                 if(trace_fraction * delta_z > 1024)
 376                                                         start = trace_endpos + '0 0 1024';
 377                                                 enddown = trace_endpos;
 378
 379                                                 // these can be traceLINES as we already verified the starting box
 380                                                 traceline(start, start + '1 0 0' * delta_x, MOVE_NORMAL, self);
 381                                                 if(trace_fraction >= 1)
 382                                                         continue;
 383                                                 traceline(start, start - '1 0 0' * delta_x, MOVE_NORMAL, self);
 384                                                 if(trace_fraction >= 1)
 385                                                         continue;
 386                                                 traceline(start, start + '0 1 0' * delta_y, MOVE_NORMAL, self);
 387                                                 if(trace_fraction >= 1)
 388                                                         continue;
 389                                                 traceline(start, start - '0 1 0' * delta_y, MOVE_NORMAL, self);
 390                                                 if(trace_fraction >= 1)
 391                                                         continue;
 392                                                 traceline(start, start + '0 0 1' * delta_z, MOVE_NORMAL, self);
 393                                                 if(trace_fraction >= 1)
 394                                                         continue;
 395
 396                                                 end_x = org_x + random() * delta_x;
 397                                                 end_y = org_y + random() * delta_y;
 398                                                 end_z = org_z + random() * delta_z;
 399                                                 end = start + normalize(end - start) * vlen(delta);
 400
 401                                                 // rule 3: start TO end must not be too short
 402                                                 tracebox(start, self.mins, self.maxs, end, MOVE_NORMAL, self);
 403                                                 if(trace_startsolid)
 404                                                         continue;
 405                                                 if(trace_fraction < 256 / vlen(delta))
 406                                                         continue;
 407
 408                                                 // rule 4: don't want to look at sky
 409                                                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
 410                                                         continue;
 411
 412                                                 // rule 5: we must not end up in trigger_hurt
 413                                                 if(tracebox_hits_trigger_hurt(start, self.mins, self.maxs, enddown))
 414                                                 {
 415                                                         dprint("trigger_hurt! ouch! and nothing else could find it!\n");
 416                                                         continue;
 417                                                 }
 418
 419                                                 break;
 420                                         }
 421
 422                                         if(i < maxattempts)
 423                                         {
 424                                                 self.origin = start;
 425                                                 self.angles = vectoangles(end - start);
 426                                                 self.angles_x = -self.angles_x;
 427                                                 self.fixangle = TRUE;
 428                                                 self.velocity = '0 0 0';
 429                                                 dprint("Needed ", ftos(i + 1), " attempts\n");
 430                                         }
 431                                         else
 432                                                 sprint(self, "Emergency teleport could not find a good location, forget it!\n");
 433
 434                                         self.dphitcontentsmask = m;
 435                                         break;
 436                                 case 144:
 437                                         makevectors(self.v_angle);
 438                                         traceline(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * MAX_SHOT_DISTANCE, FALSE, self);
 439                                         if (trace_fraction < 1)
 440                                                 printsurfaceinfo(trace_ent, trace_endpos);
 441                                         break;
 442                                 case 145:
 443                                         makevectors(self.v_angle);
 444                                         traceline(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * 65536, FALSE, self);
 445                                         sprint(self, strcat("distance: ", ftos(fabs(vlen(trace_endpos - (self.origin + self.view_ofs)))), "\n"));
 446                                         break;
 447                         }
 448                 }
 449         }
 450         else if(imp >= 103 && imp <= 106)
 451         {
 452                 if(cvar("g_waypointeditor"))
 453                 {
 454                         switch(imp)
 455                         {
 456                                 case 103:
 457                                         waypoint_schedulerelink(waypoint_spawn(self.origin, self.origin, 0));
 458                                         break;
 459                                 case 104:
 460                                         e = navigation_findnearestwaypoint(self, FALSE);
 461                                         if (e)
 462                                                 waypoint_remove(e);
 463                                         break;
 464                                 case 105:
 465                                         waypoint_schedulerelinkall();
 466                                         break;
 467                                 case 106:
 468                                         waypoint_saveall();
 469                                         break;
 470                         }
 471                 }
 472         }
 473
 474         //TetrisImpulses(imp);
 475 }