some missing files; g_race_qualifying is still broken (ignores fraglimit, no idea...
[divverent/nexuiz.git] / data / qcsrc / server / campaign.qc
1 // campaign cvars:
2 //   _campaign_index: index of CURRENT map
3 //   _campaign_name: name of the current campaign
4 //   g_campaign(name)_index: index of current LAST map (saved)
5 //   g_campaign_skill: bot skill offset
6
7 float campaign_level;
8 float campaign_won;
9 string campaign_index_var;
10 float checkrules_equality;
11
12 void CampaignBailout(string s)
13 {
14         cvar_set("g_campaign", "0");
15         ServerConsoleEcho(strcat("campaign initialization failed: ", s), TRUE);
16         return;
17 }
18
19 void CampaignPreInit()
20 {
21         float baseskill;
22         string title;
23         campaign_level = cvar("_campaign_index");
24         campaign_name = strzone(cvar_string("_campaign_name"));
25         campaign_index_var = strzone(strcat("g_campaign", campaign_name, "_index"));
26         CampaignFile_Load(campaign_level, 2);
27         if(campaign_entries < 1)
28                 return CampaignBailout("unknown map");
29         cvar_set("bot_number", ftos(campaign_bots[0]));
30
31         baseskill = cvar("g_campaign_skill");
32         baseskill = baseskill + campaign_botskill[0];
33         if(baseskill < 0)
34                 baseskill = 0;
35         cvar_set("skill", ftos(baseskill));
36
37         cvar_set("sv_public", "0");
38         cvar_set("pausable", "1");
39
40         title = campaign_shortdesc[0];
41         title = strzone(strcat("Level ", ftos(campaign_level + 1), ": ", title));
42         campaign_message = strzone(strcat("\n\n\n\n\n\n\n\n\n\n^1\n", title, "\n^3\n", wordwrap(campaign_longdesc[0], 50), "\n\n^1press jump to enter the game"));
43         strunzone(title);
44 }
45
46 string GetMapname();
47 void CampaignPostInit()
48 {
49         // now some sanity checks
50         string thismapname, wantedmapname;
51         thismapname = GetMapname();
52         wantedmapname = campaign_gametype[0];
53 #ifdef MAPINFO
54         // TODO check game type
55         if(MapInfo_CurrentGametype() != MapInfo_Type_FromString(wantedmapname))
56                 return CampaignBailout("wrong game type!");
57         wantedmapname = campaign_mapname[0];
58 #else
59         wantedmapname = strcat(wantedmapname, "_", campaign_mapname[0]);
60 #endif
61         if(wantedmapname != thismapname)
62                 return CampaignBailout(strcat("wrong map: ", wantedmapname, " != ", thismapname));
63         cvar_set("fraglimit", ftos(campaign_fraglimit[0]));
64         cvar_set("timelimit", "0");
65 }
66
67 void CampaignSaveCvar(string cvarname, float value)
68 {
69         float fh;
70         float len;
71         string contents;
72         string l;
73
74         registercvar(cvarname, ftos(value));
75         cvar_set(cvarname, ftos(value));
76         // note: cvarname must be remembered
77
78         fh = fopen("campaign.cfg", FILE_READ);
79         contents = "";
80         if(fh >= 0)
81         {
82                 while((l = fgets(fh)))
83                 {
84                         len = tokenize(l);
85                         if(len != 3)
86                                 continue;
87                         if(argv(0) != "set")
88                                 continue;
89                         if(argv(1) == cvarname)
90                                 continue;
91                         contents = strcat(contents, "set ", argv(1), " ", argv(2), "\n");
92                 }
93                 fclose(fh);
94         }
95         contents = strcat(contents, "set ", cvarname,  " ", ftos(value), "\n");
96         fh = fopen("campaign.cfg", FILE_WRITE);
97         if(fh >= 0)
98         {
99                 fputs(fh, contents);
100         }
101         else
102         {
103                 error("Cannot write to campaign file");
104         }
105 }
106
107 void CampaignPreIntermission()
108 {
109         entity head;
110         float won;
111         float lost;
112         local string savevar;
113
114         won = 0;
115
116         head = findchain(classname, "player");
117         while(head)
118         {
119                 if(clienttype(head) == CLIENTTYPE_REAL)
120                 {
121                         if(head.winning)
122                                 won = won + 1;
123                         else
124                                 lost = lost + 1;
125                 }
126                 head = head.chain;
127         }
128
129         if(won == 1 && lost == 0 && checkrules_equality == 0)
130         {
131                 campaign_won = 1;
132                 bprint("The current level has been WON.\n");
133                 // sound!
134         }
135         else
136         {
137                 campaign_won = 0;
138                 bprint("The current level has been LOST.\n");
139                 // sound!
140         }
141
142         if(campaign_won)
143         {
144                 if(campaign_entries < 2)
145                 {
146                         // I have won
147                         savevar = strcat("g_campaign", campaign_name, "_won");
148                         CampaignSaveCvar(savevar, 1);
149                         // advance level (for menu to show it right)
150                         CampaignSaveCvar(campaign_index_var, campaign_level + 1);
151                 }
152                 else if(campaign_level == cvar(campaign_index_var))
153                 {
154                         // advance level
155                         CampaignSaveCvar(campaign_index_var, campaign_level + 1);
156                 }
157         }
158 }
159
160 void CampaignPostIntermission()
161 {
162         // NOTE: campaign_won is 0 or 1, that is, points to the next level
163
164         if(campaign_won && campaign_entries < 2)
165         {
166                 // last map won!
167                 localcmd("togglemenu 1\n");
168                 CampaignFile_Unload();
169                 return;
170         }
171
172         CampaignSetup(campaign_won);
173         CampaignFile_Unload();
174         strunzone(campaign_message);
175         strunzone(campaign_index_var);
176         strunzone(campaign_name);
177         campaign_name = "";
178 }
179
180
181
182 void CampaignLevelWarp(float n)
183 {
184         if(!sv_cheats)
185                 return;
186         CampaignFile_Unload();
187         CampaignFile_Load(n, 1);
188         if(campaign_entries)
189                 CampaignSetup(0);
190         else
191                 error("Sorry, cheater. You are NOT WELCOME.");
192         CampaignFile_Unload();
193 }