data/qcsrc/server/campaign.qc

   1 // campaign cvars:
   2 //   _campaign_index: index of CURRENT map
   3 //   _campaign_name: name of the current campaign
   4 //   g_campaign(name)_index: index of current LAST map (saved)
   5 //   g_campaign_skill: bot skill offset
   6
   7 float campaign_level;
   8 float campaign_won;
   9 string campaign_index_var;
  10 float checkrules_equality;
  11
  12 float CampaignBailout(string s)
  13 {
  14         cvar = cvar_builtin;
  15         cvar_string = cvar_string_builtin;
  16         cvar_set = cvar_set_builtin;
  17         cvar_set("g_campaign", "0");
  18         print("campaign initialization failed: ", s, "\n");
  19         return 1;
  20 }
  21
  22 string cvar_campaignwrapper_list; // string of format ; var value; var value; var value;
  23 string cvar_string_campaignwrapper(string theCvar)
  24 {
  25         float p, q;
  26         p = strstrofs(cvar_campaignwrapper_list, strcat("; ", theCvar, " "), 0);
  27         if(p < 0)
  28                 return cvar_defstring(theCvar);
  29         p += strlen(theCvar) + 3;
  30         q = strstrofs(cvar_campaignwrapper_list, ";", p);
  31         if(q < 0)
  32                 return cvar_defstring(theCvar);
  33         return substring(cvar_campaignwrapper_list, p, q - p);
  34 }
  35 float cvar_campaignwrapper(string theCvar)
  36 {
  37         return stof(cvar_string_campaignwrapper(theCvar));
  38 }
  39 void cvar_set_campaignwrapper(string theCvar, string theValue)
  40 {
  41         if(cvar_string_campaignwrapper(theCvar) == theValue)
  42                 return;
  43         string s;
  44         s = cvar_campaignwrapper_list;
  45         cvar_campaignwrapper_list = strzone(strcat("; ", theCvar, " ", theValue, s));
  46         strunzone(s);
  47         //print(cvar_campaignwrapper_list, "\n");
  48 }
  49
  50 float Campaign_Invalid()
  51 {
  52         string thismapname, wantedmapname;
  53         thismapname = GetMapname();
  54         wantedmapname = campaign_gametype[0];
  55         if(MapInfo_CurrentGametype() != MapInfo_Type_FromString(wantedmapname))
  56                 return CampaignBailout("wrong game type!");
  57         wantedmapname = campaign_mapname[0];
  58         if(wantedmapname != thismapname)
  59                 return CampaignBailout(strcat("wrong map: ", wantedmapname, " != ", thismapname));
  60         return 0;
  61 }
  62
  63 void CampaignPreInit()
  64 {
  65         float baseskill;
  66         string title;
  67         campaign_level = cvar("_campaign_index");
  68         campaign_name = strzone(cvar_string("_campaign_name"));
  69         campaign_index_var = strzone(strcat("g_campaign", campaign_name, "_index"));
  70         CampaignFile_Load(campaign_level, 2);
  71         if(campaign_entries < 1)
  72         {
  73                 CampaignBailout("unknown map");
  74                 return;
  75         }
  76
  77         baseskill = cvar("g_campaign_skill");
  78         baseskill = baseskill + campaign_botskill[0];
  79         if(baseskill < 0)
  80                 baseskill = 0;
  81
  82         cvar_set("sv_public", "0");
  83         cvar_set("pausable", "1");
  84
  85         cvar_campaignwrapper_list = strzone(strcat("; ", campaign_mutators[0], "; "));
  86
  87         cvar = cvar_campaignwrapper;
  88         cvar_string = cvar_string_campaignwrapper;
  89         cvar_set = cvar_set_campaignwrapper;
  90
  91         cvar_set("g_campaign", "1");
  92         cvar_set("g_dm", "0");
  93         cvar_set("skill", ftos(baseskill));
  94         cvar_set("bot_number", ftos(campaign_bots[0]));
  95         MapInfo_SwitchGameType(MapInfo_Type_FromString(campaign_gametype[0]));
  96
  97         // copy sv_gravity cvar, as the engine needs it too (sorry, this will mess
  98         // with the menu a little still...)
  99         cvar_set_builtin("sv_gravity", cvar_string("sv_gravity"));
 100
 101         if(Campaign_Invalid())
 102                 return;
 103
 104         title = campaign_shortdesc[0];
 105         title = strzone(strcat("Level ", ftos(campaign_level + 1), ": ", title));
 106         campaign_message = strzone(strcat("\n\n\n\n\n\n\n\n\n\n^1\n", title, "\n^3\n", campaign_longdesc[0], "\n\n^1press jump to enter the game"));
 107         strunzone(title);
 108 }
 109
 110 string GetMapname();
 111 void CampaignPostInit()
 112 {
 113         // now some sanity checks
 114         if(Campaign_Invalid())
 115                 return;
 116         cvar_set("fraglimit", ftos(campaign_fraglimit[0]));
 117         cvar_set("timelimit", "0");
 118         cvar_set_builtin("fraglimit", ftos(campaign_fraglimit[0]));
 119         cvar_set_builtin("timelimit", "0");
 120 }
 121
 122 void CampaignSaveCvar(string cvarname, float value)
 123 {
 124         float fh;
 125         float len;
 126         string contents;
 127         string l;
 128
 129         registercvar(cvarname, ftos(value));
 130         cvar_set_builtin(cvarname, ftos(value));
 131         // note: cvarname must be remembered
 132
 133         fh = fopen("campaign.cfg", FILE_READ);
 134         contents = "";
 135         if(fh >= 0)
 136         {
 137                 while((l = fgets(fh)))
 138                 {
 139                         len = tokenize_console(l);
 140                         if(len != 3)
 141                                 continue;
 142                         if(argv(0) != "set")
 143                                 continue;
 144                         if(argv(1) == cvarname)
 145                                 continue;
 146                         contents = strcat(contents, "set ", argv(1), " ", argv(2), "\n");
 147                 }
 148                 fclose(fh);
 149         }
 150         contents = strcat(contents, "set ", cvarname,  " ", ftos(value), "\n");
 151         fh = fopen("campaign.cfg", FILE_WRITE);
 152         if(fh >= 0)
 153         {
 154                 fputs(fh, contents);
 155         }
 156         else
 157         {
 158                 error("Cannot write to campaign file");
 159         }
 160 }
 161
 162 void CampaignPreIntermission()
 163 {
 164         entity head;
 165         float won;
 166         float lost;
 167         local string savevar;
 168
 169         won = 0;
 170
 171         head = findchain(classname, "player");
 172         while(head)
 173         {
 174                 if(clienttype(head) == CLIENTTYPE_REAL)
 175                 {
 176                         if(head.winning)
 177                                 won = won + 1;
 178                         else
 179                                 lost = lost + 1;
 180                 }
 181                 head = head.chain;
 182         }
 183
 184         if(won == 1 && lost == 0 && checkrules_equality == 0)
 185         {
 186                 campaign_won = 1;
 187                 bprint("The current level has been WON.\n");
 188                 // sound!
 189         }
 190         else
 191         {
 192                 campaign_won = 0;
 193                 bprint("The current level has been LOST.\n");
 194                 // sound!
 195         }
 196
 197         if(campaign_won)
 198         {
 199                 if(campaign_entries < 2)
 200                 {
 201                         // I have won
 202                         savevar = strcat("g_campaign", campaign_name, "_won");
 203                         CampaignSaveCvar(savevar, 1);
 204                         // advance level (for menu to show it right)
 205                         CampaignSaveCvar(campaign_index_var, campaign_level + 1);
 206                 }
 207                 else if(campaign_level == cvar_builtin(campaign_index_var))
 208                 {
 209                         // advance level
 210                         CampaignSaveCvar(campaign_index_var, campaign_level + 1);
 211                 }
 212         }
 213 }
 214
 215 void CampaignPostIntermission()
 216 {
 217         // NOTE: campaign_won is 0 or 1, that is, points to the next level
 218
 219         if(campaign_won && campaign_entries < 2)
 220         {
 221                 // last map won!
 222                 localcmd("togglemenu 1\n");
 223                 CampaignFile_Unload();
 224                 return;
 225         }
 226
 227         CampaignSetup(campaign_won);
 228         CampaignFile_Unload();
 229         strunzone(campaign_message);
 230         strunzone(campaign_index_var);
 231         strunzone(campaign_name);
 232         campaign_name = "";
 233 }
 234
 235
 236
 237 void CampaignLevelWarp(float n)
 238 {
 239         if(!sv_cheats)
 240                 return;
 241         CampaignFile_Unload();
 242         CampaignFile_Load(n, 1);
 243         if(campaign_entries)
 244                 CampaignSetup(0);
 245         else
 246                 error("Sorry, cheater. You are NOT WELCOME.");
 247         CampaignFile_Unload();
 248 }