data/qcsrc/menu/nexuiz/util.qc

   1 void forAllDescendants(entity root, void(entity, entity) funcPre, void(entity, entity) funcPost, entity pass)
   2 {
   3         depthfirst(root, parent, firstChild, nextSibling, funcPre, funcPost, pass);
   4 }
   5
   6 .string cvarName;
   7 void SUB_Null_ee(entity e1, entity e2)
   8 {
   9 }
  10 void saveCvarsOf(entity ignore, entity e)
  11 {
  12         if(e.saveCvars)
  13                 e.saveCvars(e);
  14 }
  15 void loadCvarsOf(entity ignore, entity e)
  16 {
  17         if(e.loadCvars)
  18                 e.loadCvars(e);
  19 }
  20 void saveAllCvars(entity root)
  21 {
  22         forAllDescendants(root, saveCvarsOf, SUB_Null_ee, NULL);
  23 }
  24 void loadAllCvars(entity root)
  25 {
  26         forAllDescendants(root, loadCvarsOf, SUB_Null_ee, NULL);
  27 }
  28
  29 .string cvarNames_Multi;
  30 .void(entity me) saveCvars_Multi;
  31 void saveCvarsMulti(entity me)
  32 {
  33         float n, i;
  34         string s;
  35
  36         me.saveCvars_Multi(me);
  37         s = cvar_string(me.cvarName);
  38
  39         n = tokenize_sane(me.cvarNames_Multi);
  40         for(i = 0; i < n; ++i)
  41                 cvar_set(argv(i), s);
  42 }
  43
  44 void makeMulti(entity e, string otherCvars)
  45 {
  46         e.cvarNames_Multi = otherCvars;
  47         e.saveCvars_Multi = e.saveCvars;
  48         e.saveCvars = saveCvarsMulti;
  49 }
  50
  51 .void(entity) draw_setDependent;
  52 .string cvar_setDependent;
  53 .float cvarMin_setDependent;
  54 .float cvarMax_setDependent;
  55 .string cvar2_setDependent;
  56 .float cvar2Min_setDependent;
  57 .float cvar2Max_setDependent;
  58 .float op_setDependent;
  59 .string cvarString_setDependent;
  60 .string cvarValue_setDependent;
  61 void setDependent_Check(entity e)
  62 {
  63         float f;
  64         string s;
  65         if(e.cvarString_setDependent)
  66         {
  67                 s = cvar_string(e.cvarString_setDependent);
  68                 e.disabled = (cvar_string(e.cvarString_setDependent) == e.cvarValue_setDependent);
  69         }
  70         else
  71         {
  72                 if(e.cvar_setDependent)
  73                 {
  74                         f = cvar(e.cvar_setDependent);
  75                         if(e.cvarMin_setDependent <= e.cvarMax_setDependent)
  76                                 e.disabled = ((f < e.cvarMin_setDependent) || (f > e.cvarMax_setDependent));
  77                         else
  78                                 e.disabled = ((f >= e.cvarMax_setDependent) && (f <= e.cvarMin_setDependent));
  79                 }
  80                 if(e.cvar2_setDependent)
  81                 {
  82                         f = cvar(e.cvar2_setDependent);
  83                         if(e.cvar2Min_setDependent <= e.cvar2Max_setDependent)
  84                                 e.disabled = (e.disabled + ((f < e.cvar2Min_setDependent) || (f > e.cvar2Max_setDependent)) > e.op_setDependent);
  85                         else
  86                                 e.disabled = (e.disabled + ((f >= e.cvar2Max_setDependent) && (f <= e.cvar2Min_setDependent)) > e.op_setDependent);
  87                 }
  88         }
  89 }
  90 void setDependent_Draw(entity e)
  91 {
  92         setDependent_Check(e);
  93         e.draw_setDependent(e);
  94 }
  95 void setDependent(entity e, string theCvarName, float theCvarMin, float theCvarMax)
  96 {
  97         e.draw_setDependent = e.draw;
  98         e.cvar_setDependent = theCvarName;
  99         e.cvarMin_setDependent = theCvarMin;
 100         e.cvarMax_setDependent = theCvarMax;
 101         e.cvar2_setDependent = string_null;
 102         e.draw = setDependent_Draw;
 103         setDependent_Check(e);
 104 }
 105 void setDependentStringNotEqual(entity e, string theCvarName, string theCvarValue)
 106 {
 107         e.draw_setDependent = e.draw;
 108         e.cvarString_setDependent = theCvarName;
 109         e.cvarValue_setDependent = theCvarValue;
 110         e.cvar_setDependent = string_null;
 111         e.cvar2_setDependent = string_null;
 112         e.draw = setDependent_Draw;
 113         setDependent_Check(e);
 114 }
 115 void setDependentAND(entity e, string theCvarName, float theCvarMin, float theCvarMax, string theCvar2Name, float theCvar2Min, float theCvar2Max)
 116 {
 117         e.draw_setDependent = e.draw;
 118         e.cvar_setDependent = theCvarName;
 119         e.cvarMin_setDependent = theCvarMin;
 120         e.cvarMax_setDependent = theCvarMax;
 121         e.cvar2_setDependent = theCvar2Name;
 122         e.cvar2Min_setDependent = theCvar2Min;
 123         e.cvar2Max_setDependent = theCvar2Max;
 124         e.op_setDependent = 0;
 125         e.draw = setDependent_Draw;
 126         setDependent_Check(e);
 127 }
 128 void setDependentOR(entity e, string theCvarName, float theCvarMin, float theCvarMax, string theCvar2Name, float theCvar2Min, float theCvar2Max)
 129 {
 130         e.draw_setDependent = e.draw;
 131         e.cvar_setDependent = theCvarName;
 132         e.cvarMin_setDependent = theCvarMin;
 133         e.cvarMax_setDependent = theCvarMax;
 134         e.cvar2_setDependent = theCvar2Name;
 135         e.cvar2Min_setDependent = theCvar2Min;
 136         e.cvar2Max_setDependent = theCvar2Max;
 137         e.op_setDependent = 1;
 138         e.draw = setDependent_Draw;
 139         setDependent_Check(e);
 140 }
 141
 142 // EXTRESPONSE SYSTEM ////////////////////////////////////////////////////////
 143
 144 float _Nex_ExtResponseSystem_RequestsSent;
 145 float _Nex_ExtResponseSystem_VersionHandled;
 146 string _Nex_ExtResponseSystem_UpdateTo;
 147 float _Nex_ExtResponseSystem_RetryTime;
 148 float _Nex_ExtResponseSystem_RetryTime_LastDelay;
 149
 150 void() Item_Nex_ExtResponseSystem_SendQuery =
 151 {
 152         dprint("Sending extended response requests...\n");
 153         localcmd(strcat("packet update.alientrap.org:27950 \"getExtResponse checkUpdates nexuiz ", cvar_string("g_nexuizversion"), "\"\n"));
 154         _Nex_ExtResponseSystem_RequestsSent = TRUE;
 155         _Nex_ExtResponseSystem_RetryTime_LastDelay = _Nex_ExtResponseSystem_RetryTime_LastDelay * 2 + 1;
 156         _Nex_ExtResponseSystem_RetryTime = time + _Nex_ExtResponseSystem_RetryTime_LastDelay;
 157 }
 158
 159 void(float argc) Item_Nex_ExtResponseSystem_Parse =
 160 {
 161         dprint("Received extended response packet from ", argv(0), "\n");
 162         if(!_Nex_ExtResponseSystem_RequestsSent)
 163         {
 164                 dprint("  But I haven't sent a request yet! Ignoring.\n");
 165                 return;
 166         }
 167         if(argv(1) == "noUpdateAvailable")
 168         {
 169                 if(_Nex_ExtResponseSystem_VersionHandled)
 170                 {
 171                         dprint("  duplicated update notice, ignored\n");
 172                         return;
 173                 }
 174                 _Nex_ExtResponseSystem_VersionHandled = 1;
 175         }
 176         else if(argv(1) == "updateAvailable")
 177         {
 178                 if(_Nex_ExtResponseSystem_VersionHandled)
 179                 {
 180                         dprint("  duplicated update notice, ignored\n");
 181                         return;
 182                 }
 183                 _Nex_ExtResponseSystem_VersionHandled = 1;
 184                 _Nex_ExtResponseSystem_UpdateTo = strzone(argv(2)); // note: only one packet can be handled, so this can't be a leak
 185         }
 186         else
 187                 dprint("  UNKNOWN RESPONSE TYPE: ", argv(1), "\n");
 188 }
 189
 190 void() Item_Nex_ExtResponseSystem_CheckForResponse =
 191 {
 192         local string s;
 193         local float argc;
 194         while(strlen((s = getextresponse())))
 195         {
 196                 argc = tokenize_sane(s);
 197                 Item_Nex_ExtResponseSystem_Parse(argc);
 198         }
 199 }
 200
 201 // END OF EXTRESPONSE SYSTEM /////////////////////////////////////////////////
 202
 203 float preMenuInit()
 204 {
 205         vector sz;
 206         vector boxA, boxB;
 207
 208         MapInfo_Cache_Create();
 209         MapInfo_Enumerate();
 210         if(!MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, 0, 0, 1))
 211         {
 212                 draw_reset();
 213
 214                 sz = eX * 0.025 + eY * 0.025 * (draw_scale_x / draw_scale_y);
 215                 draw_CenterText('0.5 0.5 0' - 1.25 * sz_y * eY, "Autogenerating mapinfo for newly added maps...", sz, '1 1 1', 1, 0);
 216
 217                 boxA = '0.05 0.5 0' + 0.25 * sz_y * eY;
 218                 boxB = '0.95 0.5 0' + 1.25 * sz_y * eY;
 219                 draw_Fill(boxA, boxB - boxA, '1 1 1', 1);
 220
 221                 boxA += sz * 0.1;
 222                 boxB -= sz * 0.1;
 223                 draw_Fill(boxA, boxB - boxA, '0.1 0.1 0.1', 1);
 224
 225                 boxB_x = boxA_x * (1 - MapInfo_progress) + boxB_x * MapInfo_progress;
 226                 draw_Fill(boxA, boxB - boxA, '0 0 1', 1);
 227
 228                 return FALSE;
 229         }
 230         return TRUE;
 231 }
 232
 233 string campaign_name_previous;
 234 float campaign_won_previous;
 235 void postMenuDraw()
 236 {
 237 }
 238 void preMenuDraw()
 239 {
 240         vector fs, sz, line, mid;
 241         Item_Nex_ExtResponseSystem_CheckForResponse();
 242         if(!_Nex_ExtResponseSystem_VersionHandled)
 243                 if(time > _Nex_ExtResponseSystem_RetryTime)
 244                         Item_Nex_ExtResponseSystem_SendQuery();
 245
 246         if(_Nex_ExtResponseSystem_UpdateTo != "")
 247         {
 248                 fs = ((1/draw_scale_x) * eX + (1/draw_scale_y) * eY) * 12;
 249                 line = eY * fs_y;
 250                 sz_x = draw_TextWidth("  http://www.nexuiz.com/  ", 0) * fs_x;
 251                 sz_y = 3 * fs_y;
 252
 253                 draw_alpha = sin(time * 0.112 - 0.3) * 0.7;
 254                 mid = eX * (0.5 + 0.5 * (1 - sz_x) * cos(time * 0.071))
 255                     + eY * (0.5 + 0.5 * (1 - sz_y) * sin(time * 0.071));
 256
 257                 draw_Fill(mid - 0.5 * sz, sz, '1 1 0', 1);
 258                 draw_CenterText(mid - 1 * line, strcat("Update to ", _Nex_ExtResponseSystem_UpdateTo, " now!"), fs, '1 0 0', 1, 0);
 259                 draw_CenterText(mid - 0 * line, "http://www.nexuiz.com/", fs, '0 0 1', 1, 0);
 260         }
 261         if not(campaign_name_previous)
 262                 campaign_name_previous = strzone(strcat(campaign_name, "x")); // force unequal
 263         if(campaign_name == campaign_name_previous)
 264         {
 265                 if(cvar(strcat("g_campaign", campaign_name, "_won")))
 266                 {
 267                         if(!campaign_won_previous)
 268                         {
 269                                 m_display();
 270                                 DialogOpenButton_Click_withCoords(NULL, main.winnerDialog, '0 0 0', eX * conwidth + eY * conheight);
 271                         }
 272                         campaign_won_previous = 1;
 273                 }
 274                 else
 275                         campaign_won_previous = 0;
 276         }
 277         else
 278         {
 279                 strunzone(campaign_name_previous);
 280                 campaign_name_previous = strzone(campaign_name);
 281                 campaign_won_previous = cvar(strcat("g_campaign", campaign_name, "_won"));
 282         }
 283 }