data/qcsrc/menu/nexuiz/skinlist.c

   1 #ifdef INTERFACE
   2 CLASS(NexuizSkinList) EXTENDS(NexuizListBox)
   3         METHOD(NexuizSkinList, configureNexuizSkinList, void(entity))
   4         ATTRIB(NexuizSkinList, rowsPerItem, float, 4)
   5         METHOD(NexuizSkinList, resizeNotify, void(entity, vector, vector, vector, vector))
   6         METHOD(NexuizSkinList, drawListBoxItem, void(entity, float, vector, float))
   7         METHOD(NexuizSkinList, getSkins, void(entity))
   8         METHOD(NexuizSkinList, setSkin, void(entity))
   9         METHOD(NexuizSkinList, loadCvars, void(entity))
  10         METHOD(NexuizSkinList, saveCvars, void(entity))
  11         METHOD(NexuizSkinList, skinParameter, string(entity, float, float))
  12         METHOD(NexuizSkinList, clickListBoxItem, void(entity, float, vector))
  13         METHOD(NexuizSkinList, keyDown, float(entity, float, float, float))
  14         METHOD(NexuizSkinList, destroy, void(entity))
  15
  16         ATTRIB(NexuizSkinList, skinlist, float, -1)
  17         ATTRIB(NexuizSkinList, realFontSize, vector, '0 0 0')
  18         ATTRIB(NexuizSkinList, columnPreviewOrigin, float, 0)
  19         ATTRIB(NexuizSkinList, columnPreviewSize, float, 0)
  20         ATTRIB(NexuizSkinList, columnNameOrigin, float, 0)
  21         ATTRIB(NexuizSkinList, columnNameSize, float, 0)
  22         ATTRIB(NexuizSkinList, realUpperMargin1, float, 0)
  23         ATTRIB(NexuizSkinList, realUpperMargin2, float, 0)
  24         ATTRIB(NexuizSkinList, origin, vector, '0 0 0')
  25         ATTRIB(NexuizSkinList, itemAbsSize, vector, '0 0 0')
  26
  27         ATTRIB(NexuizSkinList, lastClickedSkin, float, -1)
  28         ATTRIB(NexuizSkinList, lastClickedTime, float, 0)
  29
  30         ATTRIB(NexuizSkinList, name, string, "skinselector")
  31 ENDCLASS(NexuizSkinList)
  32
  33 entity makeNexuizSkinList();
  34 void SetSkin_Click(entity btn, entity me);
  35 #endif
  36
  37 #ifdef IMPLEMENTATION
  38
  39 #define SKINPARM_NAME 0
  40 #define SKINPARM_TITLE 1
  41 #define SKINPARM_AUTHOR 2
  42 #define SKINPARM_PREVIEW 3
  43 #define SKINPARM_COUNT 4
  44
  45 entity makeNexuizSkinList()
  46 {
  47         entity me;
  48         me = spawnNexuizSkinList();
  49         me.configureNexuizSkinList(me);
  50         return me;
  51 }
  52
  53 void configureNexuizSkinListNexuizSkinList(entity me)
  54 {
  55         me.configureNexuizListBox(me);
  56         me.getSkins(me);
  57         me.loadCvars(me);
  58 }
  59
  60 void loadCvarsNexuizSkinList(entity me)
  61 {
  62         string s;
  63         float i, n;
  64         s = cvar_string("menu_skin");
  65         n = me.nItems;
  66         for(i = 0; i < n; ++i)
  67         {
  68                 if(me.skinParameter(me, i, SKINPARM_NAME) == s)
  69                 {
  70                         me.selectedItem = i;
  71                         break;
  72                 }
  73         }
  74 }
  75
  76 void saveCvarsNexuizSkinList(entity me)
  77 {
  78         cvar_set("menu_skin", me.skinParameter(me, me.selectedItem, SKINPARM_NAME));
  79 }
  80
  81 string skinParameterNexuizSkinList(entity me, float i, float key)
  82 {
  83         return bufstr_get(me.skinlist, i * SKINPARM_COUNT + key);
  84 }
  85
  86 void getSkinsNexuizSkinList(entity me)
  87 {
  88         float glob, buf, i, n, fh;
  89         string s;
  90
  91         buf = buf_create();
  92         glob = search_begin("gfx/menu/*/skinvalues.txt", TRUE, TRUE);
  93         if(glob < 0)
  94         {
  95                 me.skinlist = buf;
  96                 me.nItems = 0;
  97                 return;
  98         }
  99
 100         n = search_getsize(glob);
 101         for(i = 0; i < n; ++i)
 102         {
 103                 s = search_getfilename(glob, i);
 104                 bufstr_set(buf, i * SKINPARM_COUNT + SKINPARM_NAME, substring(s, 9, strlen(s) - 24)); // the * part
 105                 bufstr_set(buf, i * SKINPARM_COUNT + SKINPARM_TITLE, "<TITLE>");
 106                 bufstr_set(buf, i * SKINPARM_COUNT + SKINPARM_AUTHOR, "<AUTHOR>");
 107                 bufstr_set(buf, i * SKINPARM_COUNT + SKINPARM_PREVIEW, strcat("/gfx/menu/", substring(s, 9, strlen(s) - 24), "/skinpreview"));
 108                 fh = fopen(s, FILE_READ);
 109                 if(fh < 0)
 110                 {
 111                         print("Warning: can't open skinvalues.txt file\n");
 112                         continue;
 113                 }
 114                 while((s = fgets(fh)))
 115                 {
 116                         // these two are handled by skinlist.qc
 117                         if(substring(s, 0, 6) == "title ")
 118                                 bufstr_set(buf, i * SKINPARM_COUNT + SKINPARM_TITLE, substring(s, 6, strlen(s) - 6));
 119                         else if(substring(s, 0, 7) == "author ")
 120                                 bufstr_set(buf, i * SKINPARM_COUNT + SKINPARM_AUTHOR, substring(s, 7, strlen(s) - 7));
 121                 }
 122         }
 123
 124         search_end(glob);
 125
 126         me.skinlist = buf;
 127         me.nItems = n;
 128 }
 129
 130 void destroyNexuizSkinList(entity me)
 131 {
 132         buf_del(me.skinlist);
 133 }
 134
 135 void resizeNotifyNexuizSkinList(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
 136 {
 137         me.itemAbsSize = '0 0 0';
 138         resizeNotifyNexuizListBox(me, relOrigin, relSize, absOrigin, absSize);
 139
 140         me.realFontSize_y = me.fontSize / (me.itemAbsSize_y = (absSize_y * me.itemHeight));
 141         me.realFontSize_x = me.fontSize / (me.itemAbsSize_x = (absSize_x * (1 - me.controlWidth)));
 142         me.realUpperMargin1 = 0.5 * (1 - 2.5 * me.realFontSize_y);
 143         me.realUpperMargin2 = me.realUpperMargin1 + 1.5 * me.realFontSize_y;
 144
 145         me.columnPreviewOrigin = 0;
 146         me.columnPreviewSize = me.itemAbsSize_y / me.itemAbsSize_x * 4 / 3;
 147         me.columnNameOrigin = me.columnPreviewOrigin + me.columnPreviewSize + me.realFontSize_x;
 148         me.columnNameSize = 1 - me.columnPreviewSize - 2 * me.realFontSize_x;
 149 }
 150
 151 void drawListBoxItemNexuizSkinList(entity me, float i, vector absSize, float isSelected)
 152 {
 153         string s;
 154
 155         if(isSelected)
 156                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
 157
 158         s = me.skinParameter(me, i, SKINPARM_PREVIEW);
 159         draw_Picture(me.columnPreviewOrigin * eX, s, me.columnPreviewSize * eX + eY, '1 1 1', 1);
 160
 161         s = me.skinParameter(me, i, SKINPARM_NAME);
 162         s = strcat(s, ": ", me.skinParameter(me, i, SKINPARM_TITLE));
 163         s = draw_TextShortenToWidth(s, me.columnNameSize / me.realFontSize_x, 0);
 164         draw_Text(me.realUpperMargin1 * eY + (me.columnNameOrigin + 0.00 * (me.columnNameSize - draw_TextWidth(s, 0) * me.realFontSize_x)) * eX, s, me.realFontSize, SKINCOLOR_SKINLIST_TITLE, SKINALPHA_TEXT, 0);
 165
 166         s = me.skinParameter(me, i, SKINPARM_AUTHOR);
 167         s = draw_TextShortenToWidth(s, me.columnNameSize / me.realFontSize_x, 0);
 168         draw_Text(me.realUpperMargin2 * eY + (me.columnNameOrigin + 1.00 * (me.columnNameSize - draw_TextWidth(s, 0) * me.realFontSize_x)) * eX, s, me.realFontSize, SKINCOLOR_SKINLIST_AUTHOR, SKINALPHA_TEXT, 0);
 169 }
 170
 171 void setSkinNexuizSkinList(entity me)
 172 {
 173         me.saveCvars(me);
 174         localcmd("\nmenu_restart\ntogglemenu\ndefer 0.1 \"menu_cmd skinselect\"\n");
 175 }
 176
 177 void SetSkin_Click(entity btn, entity me)
 178 {
 179         me.setSkin(me);
 180 }
 181
 182 void clickListBoxItemNexuizSkinList(entity me, float i, vector where)
 183 {
 184         if(i == me.lastClickedSkin)
 185                 if(time < me.lastClickedTime + 0.3)
 186                 {
 187                         // DOUBLE CLICK!
 188                         me.setSelected(me, i);
 189                         me.setSkin(me);
 190                 }
 191         me.lastClickedSkin = i;
 192         me.lastClickedTime = time;
 193 }
 194
 195 float keyDownNexuizSkinList(entity me, float scan, float ascii, float shift)
 196 {
 197         if(scan == K_ENTER) {
 198                 me.setSkin(me);
 199                 return 1;
 200         }
 201         else
 202                 return keyDownListBox(me, scan, ascii, shift);
 203 }
 204 #endif