data/qcsrc/menu/nexuiz/maplist.c

   1 #ifdef INTERFACE
   2 CLASS(NexuizMapList) EXTENDS(NexuizListBox)
   3         METHOD(NexuizMapList, configureNexuizMapList, void(entity))
   4         ATTRIB(NexuizMapList, rowsPerItem, float, 4)
   5         METHOD(NexuizMapList, draw, void(entity))
   6         METHOD(NexuizMapList, drawListBoxItem, void(entity, float, vector, float))
   7         METHOD(NexuizMapList, clickListBoxItem, void(entity, float, vector))
   8         METHOD(NexuizMapList, resizeNotify, void(entity, vector, vector, vector, vector))
   9         METHOD(NexuizMapList, refilter, void(entity))
  10         METHOD(NexuizMapList, keyDown, float(entity, float, float, float))
  11
  12         ATTRIB(NexuizMapList, realFontSize, vector, '0 0 0')
  13         ATTRIB(NexuizMapList, columnPreviewOrigin, float, 0)
  14         ATTRIB(NexuizMapList, columnPreviewSize, float, 0)
  15         ATTRIB(NexuizMapList, columnNameOrigin, float, 0)
  16         ATTRIB(NexuizMapList, columnNameSize, float, 0)
  17         ATTRIB(NexuizMapList, checkMarkOrigin, vector, '0 0 0')
  18         ATTRIB(NexuizMapList, checkMarkSize, vector, '0 0 0')
  19         ATTRIB(NexuizMapList, realUpperMargin1, float, 0)
  20         ATTRIB(NexuizMapList, realUpperMargin2, float, 0)
  21
  22         ATTRIB(NexuizMapList, lastClickedMap, float, -1)
  23         ATTRIB(NexuizMapList, lastClickedTime, float, 0)
  24
  25         ATTRIB(NexuizMapList, lastGametype, float, 0)
  26         ATTRIB(NexuizMapList, lastFeatures, float, 0)
  27
  28         ATTRIB(NexuizMapList, origin, vector, '0 0 0')
  29         ATTRIB(NexuizMapList, itemAbsSize, vector, '0 0 0')
  30
  31         ATTRIB(NexuizMapList, g_maplistCache, string, string_null)
  32         METHOD(NexuizMapList, g_maplistCacheToggle, void(entity, float))
  33         METHOD(NexuizMapList, g_maplistCacheQuery, float(entity, float))
  34
  35         ATTRIB(NexuizMapList, startButton, entity, NULL)
  36
  37         METHOD(NexuizMapList, loadCvars, void(entity))
  38
  39         ATTRIB(NexuizMapList, typeToSearchString, string, string_null)
  40         ATTRIB(NexuizMapList, typeToSearchTime, float, 0)
  41
  42         METHOD(NexuizMapList, destroy, void(entity))
  43 ENDCLASS(NexuizMapList)
  44 entity makeNexuizMapList();
  45 void MapList_All(entity btn, entity me);
  46 void MapList_None(entity btn, entity me);
  47 void MapList_LoadMap(entity btn, entity me);
  48 #endif
  49
  50 #ifdef IMPLEMENTATION
  51 void destroyNexuizMapList(entity me)
  52 {
  53         MapInfo_Shutdown();
  54 }
  55
  56 entity makeNexuizMapList()
  57 {
  58         entity me;
  59         me = spawnNexuizMapList();
  60         me.configureNexuizMapList(me);
  61         return me;
  62 }
  63
  64 void configureNexuizMapListNexuizMapList(entity me)
  65 {
  66         me.configureNexuizListBox(me);
  67         me.refilter(me);
  68 }
  69
  70 void loadCvarsNexuizMapList(entity me)
  71 {
  72         me.refilter(me);
  73 }
  74
  75 float g_maplistCacheQueryNexuizMapList(entity me, float i)
  76 {
  77         return stof(substring(me.g_maplistCache, i, 1));
  78 }
  79 void g_maplistCacheToggleNexuizMapList(entity me, float i)
  80 {
  81         string a, b, c, s, bspname;
  82         float n;
  83         s = me.g_maplistCache;
  84         if not(s)
  85                 return;
  86         b = substring(s, i, 1);
  87         if(b == "0")
  88                 b = "1";
  89         else if(b == "1")
  90                 b = "0";
  91         else
  92                 return; // nothing happens
  93         a = substring(s, 0, i);
  94         c = substring(s, i+1, strlen(s) - (i+1));
  95         strunzone(s);
  96         me.g_maplistCache = strzone(strcat(a, b, c));
  97         // TODO also update the actual cvar
  98         if not((bspname = MapInfo_BSPName_ByID(i)))
  99                 return;
 100         if(b == "1")
 101                 cvar_set("g_maplist", strcat(bspname, " ", cvar_string("g_maplist")));
 102         else
 103         {
 104                 s = "";
 105                 n = tokenize_sane(cvar_string("g_maplist"));
 106                 for(i = 0; i < n; ++i)
 107                         if(argv(i) != bspname)
 108                                 s = strcat(s, " ", argv(i));
 109                 cvar_set("g_maplist", substring(s, 1, strlen(s) - 1));
 110         }
 111 }
 112
 113 void drawNexuizMapList(entity me)
 114 {
 115         if(me.startButton)
 116                 me.startButton.disabled = ((me.selectedItem < 0) || (me.selectedItem >= me.nItems));
 117         drawListBox(me);
 118 }
 119
 120 void resizeNotifyNexuizMapList(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
 121 {
 122         me.origin = absOrigin;
 123         me.itemAbsSize = '0 0 0';
 124         resizeNotifyNexuizListBox(me, relOrigin, relSize, absOrigin, absSize);
 125
 126         me.realFontSize_y = me.fontSize / (me.itemAbsSize_y = (absSize_y * me.itemHeight));
 127         me.realFontSize_x = me.fontSize / (me.itemAbsSize_x = (absSize_x * (1 - me.controlWidth)));
 128         me.realUpperMargin1 = 0.5 * (1 - 2.5 * me.realFontSize_y);
 129         me.realUpperMargin2 = me.realUpperMargin1 + 1.5 * me.realFontSize_y;
 130
 131         me.columnPreviewOrigin = 0;
 132         me.columnPreviewSize = me.itemAbsSize_y / me.itemAbsSize_x * 4 / 3;
 133         me.columnNameOrigin = me.columnPreviewOrigin + me.columnPreviewSize + me.realFontSize_x;
 134         me.columnNameSize = 1 - me.columnPreviewSize - 2 * me.realFontSize_x;
 135
 136         me.checkMarkSize = (eX * (me.itemAbsSize_y / me.itemAbsSize_x) + eY) * 0.5;
 137         me.checkMarkOrigin = eY + eX * (me.columnPreviewOrigin + me.columnPreviewSize) - me.checkMarkSize;
 138 }
 139
 140 void clickListBoxItemNexuizMapList(entity me, float i, vector where)
 141 {
 142         if(where_x <= me.columnPreviewOrigin + me.columnPreviewSize)
 143         {
 144                 if(where_x >= 0)
 145                         me.g_maplistCacheToggle(me, i);
 146         }
 147         if(where_x >= me.columnNameOrigin)
 148                 if(where_x <= 1)
 149                         {
 150                                 if(i == me.lastClickedMap)
 151                                         if(time < me.lastClickedTime + 0.3)
 152                                         {
 153                                                 // DOUBLE CLICK!
 154                                                 // pop up map info screen
 155                                                 main.mapInfoDialog.loadMapInfo(main.mapInfoDialog, i, me);
 156                                                 DialogOpenButton_Click_withCoords(NULL, main.mapInfoDialog, me.origin + eX * (me.columnNameOrigin * me.size_x) + eY * ((me.itemHeight * i - me.scrollPos) * me.size_y), eY * me.itemAbsSize_y + eX * (me.itemAbsSize_x * me.columnNameSize));
 157                                                 return;
 158                                         }
 159                                 me.lastClickedMap = i;
 160                                 me.lastClickedTime = time;
 161                         }
 162 }
 163
 164 void drawListBoxItemNexuizMapList(entity me, float i, vector absSize, float isSelected)
 165 {
 166         // layout: Ping, Map name, Map name, NP, TP, MP
 167         string s;
 168         float p;
 169         float theAlpha;
 170         float included;
 171
 172         if(!MapInfo_Get_ByID(i))
 173                 return;
 174
 175         included = me.g_maplistCacheQuery(me, i);
 176         if(included || isSelected)
 177                 theAlpha = SKINALPHA_MAPLIST_INCLUDEDFG;
 178         else
 179                 theAlpha = SKINALPHA_MAPLIST_NOTINCLUDEDFG;
 180
 181         if(isSelected)
 182                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
 183         else if(included)
 184                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_MAPLIST_INCLUDEDBG, SKINALPHA_MAPLIST_INCLUDEDBG);
 185
 186         s = ftos(p);
 187         draw_Picture(me.columnPreviewOrigin * eX, strcat("/maps/", MapInfo_Map_bspname), me.columnPreviewSize * eX + eY, '1 1 1', theAlpha);
 188         if(included)
 189                 draw_Picture(me.checkMarkOrigin, "checkmark", me.checkMarkSize, '1 1 1', 1);
 190         s = draw_TextShortenToWidth(strcat(MapInfo_Map_bspname, ": ", MapInfo_Map_title), me.columnNameSize / me.realFontSize_x, 0);
 191         draw_Text(me.realUpperMargin1 * eY + (me.columnNameOrigin + 0.00 * (me.columnNameSize - draw_TextWidth(s, 0) * me.realFontSize_x)) * eX, s, me.realFontSize, SKINCOLOR_MAPLIST_TITLE, theAlpha, 0);
 192         s = draw_TextShortenToWidth(MapInfo_Map_author, me.columnNameSize / me.realFontSize_x, 0);
 193         draw_Text(me.realUpperMargin2 * eY + (me.columnNameOrigin + 1.00 * (me.columnNameSize - draw_TextWidth(s, 0) * me.realFontSize_x)) * eX, s, me.realFontSize, SKINCOLOR_MAPLIST_AUTHOR, theAlpha, 0);
 194
 195         MapInfo_ClearTemps();
 196 }
 197
 198 void refilterNexuizMapList(entity me)
 199 {
 200         float i, j, n;
 201         string s;
 202         float gt, f;
 203         gt = MapInfo_CurrentGametype();
 204         f = MapInfo_CurrentFeatures();
 205         MapInfo_FilterGametype(gt, f, 0, MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN, 0);
 206         me.nItems = MapInfo_count;
 207         for(i = 0; i < MapInfo_count; ++i)
 208                 draw_PreloadPicture(strcat("/maps/", MapInfo_BSPName_ByID(i)));
 209         if(me.g_maplistCache)
 210                 strunzone(me.g_maplistCache);
 211         s = "0";
 212         for(i = 1; i < MapInfo_count; i *= 2)
 213                 s = strcat(s, s);
 214         n = tokenize_sane(cvar_string("g_maplist"));
 215         for(i = 0; i < n; ++i)
 216         {
 217                 j = MapInfo_FindName(argv(i));
 218                 if(j >= 0)
 219                         s = strcat(
 220                                 substring(s, 0, j),
 221                                 "1",
 222                                 substring(s, j+1, MapInfo_count - (j+1))
 223                         );
 224         }
 225         me.g_maplistCache = strzone(s);
 226         if(gt != me.lastGametype || f != me.lastFeatures)
 227         {
 228                 me.lastGametype = gt;
 229                 me.lastFeatures = f;
 230                 me.setSelected(me, 0);
 231         }
 232 }
 233
 234 void MapList_All(entity btn, entity me)
 235 {
 236         float i;
 237         string s;
 238         MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, 0, MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN, 0); // all
 239         s = "";
 240         for(i = 0; i < MapInfo_count; ++i)
 241                 s = strcat(s, " ", MapInfo_BSPName_ByID(i));
 242         cvar_set("g_maplist", substring(s, 1, strlen(s) - 1));
 243         me.refilter(me);
 244 }
 245
 246 void MapList_None(entity btn, entity me)
 247 {
 248         cvar_set("g_maplist", "");
 249         me.refilter(me);
 250 }
 251
 252 void MapList_LoadMap(entity btn, entity me)
 253 {
 254         string m;
 255         float i;
 256
 257         i = me.selectedItem;
 258
 259         if(btn.parent.instanceOfNexuizMapInfoDialog)
 260         {
 261                 i = btn.parent.currentMapIndex;
 262                 Dialog_Close(btn, btn.parent);
 263         }
 264
 265         if(i >= me.nItems || i < 0)
 266                 return;
 267
 268         m = MapInfo_BSPName_ByID(i);
 269         if not(m)
 270         {
 271                 print("Huh? Can't play this (m is NULL). Refiltering so this won't happen again.\n");
 272                 return;
 273         }
 274         if(MapInfo_CheckMap(m))
 275         {
 276                 localcmd("\ndisconnect\nwait\ng_campaign 0\nmaxplayers $menu_maxplayers\ng_maplist_shufflenow\n");
 277                 if(cvar("menu_use_default_hostname"))
 278                         localcmd("hostname \"", strdecolorize(cvar_string("_cl_name")), "'s Nexuiz server\"\n");
 279                 MapInfo_LoadMap(m);
 280         }
 281         else
 282         {
 283                 print("Huh? Can't play this (invalid game type). Refiltering so this won't happen again.\n");
 284                 me.refilter(me);
 285         }
 286 }
 287
 288 float keyDownNexuizMapList(entity me, float scan, float ascii, float shift)
 289 {
 290         string ch, save;
 291         if(scan == K_ENTER)
 292         {
 293                 // pop up map info screen
 294                 main.mapInfoDialog.loadMapInfo(main.mapInfoDialog, me.selectedItem, me);
 295                 DialogOpenButton_Click_withCoords(NULL, main.mapInfoDialog, me.origin + eX * (me.columnNameOrigin * me.size_x) + eY * ((me.itemHeight * me.selectedItem - me.scrollPos) * me.size_y), eY * me.itemAbsSize_y + eX * (me.itemAbsSize_x * me.columnNameSize));
 296         }
 297         else if(scan == K_SPACE)
 298         {
 299                 me.g_maplistCacheToggle(me, me.selectedItem);
 300         }
 301         else if(ascii == 43) // +
 302         {
 303                 if not(me.g_maplistCacheQuery(me, me.selectedItem))
 304                         me.g_maplistCacheToggle(me, me.selectedItem);
 305         }
 306         else if(ascii == 45) // -
 307         {
 308                 if(me.g_maplistCacheQuery(me, me.selectedItem))
 309                         me.g_maplistCacheToggle(me, me.selectedItem);
 310         }
 311         else if(scan == K_BACKSPACE)
 312         {
 313                 if(time < me.typeToSearchTime)
 314                 {
 315                         save = substring(me.typeToSearchString, 0, strlen(me.typeToSearchString) - 1);
 316                         if(me.typeToSearchString)
 317                                 strunzone(me.typeToSearchString);
 318                         me.typeToSearchString = strzone(save);
 319                         me.typeToSearchTime = time + 0.5;
 320                         if(strlen(me.typeToSearchString))
 321                         {
 322                                 MapInfo_FindName(me.typeToSearchString);
 323                                 if(MapInfo_FindName_firstResult >= 0)
 324                                         me.setSelected(me, MapInfo_FindName_firstResult);
 325                         }
 326                 }
 327         }
 328         else if(ascii >= 32 && ascii != 127)
 329         {
 330                 ch = chr(ascii);
 331                 if(time > me.typeToSearchTime)
 332                         save = ch;
 333                 else
 334                         save = strcat(me.typeToSearchString, ch);
 335                 if(me.typeToSearchString)
 336                         strunzone(me.typeToSearchString);
 337                 me.typeToSearchString = strzone(save);
 338                 me.typeToSearchTime = time + 0.5;
 339                 MapInfo_FindName(me.typeToSearchString);
 340                 if(MapInfo_FindName_firstResult >= 0)
 341                         me.setSelected(me, MapInfo_FindName_firstResult);
 342         }
 343         else
 344                 return keyDownListBox(me, scan, ascii, shift);
 345         return 1;
 346 }
 347
 348 #endif