data/qcsrc/menu/nexuiz/demolist.c

   1 #ifdef INTERFACE
   2 CLASS(NexuizDemoList) EXTENDS(NexuizListBox)
   3     METHOD(NexuizDemoList, configureNexuizDemoList, void(entity))
   4     ATTRIB(NexuizDemoList, rowsPerItem, float, 1)
   5     METHOD(NexuizDemoList, resizeNotify, void(entity, vector, vector, vector, vector))
   6     METHOD(NexuizDemoList, drawListBoxItem, void(entity, float, vector, float))
   7     METHOD(NexuizDemoList, getDemos, void(entity))
   8     METHOD(NexuizDemoList, startDemo, void(entity))
   9     METHOD(NexuizDemoList, demoName, string(entity, float))
  10     METHOD(NexuizDemoList, clickListBoxItem, void(entity, float, vector))
  11     METHOD(NexuizDemoList, keyDown, float(entity, float, float, float))
  12     METHOD(NexuizDemoList, destroy, void(entity))
  13     METHOD(NexuizDemoList, showNotify, void(entity))
  14     ATTRIB(NexuizDemoList, listDemo, float, -1)
  15     ATTRIB(NexuizDemoList, realFontSize, vector, '0 0 0')
  16     ATTRIB(NexuizDemoList, columnNameOrigin, float, 0)
  17     ATTRIB(NexuizDemoList, columnNameSize, float, 0)
  18     ATTRIB(NexuizDemoList, realUpperMargin, float, 0)
  19     ATTRIB(NexuizDemoList, origin, vector, '0 0 0')
  20     ATTRIB(NexuizDemoList, itemAbsSize, vector, '0 0 0')
  21     ATTRIB(NexuizDemoList, lastClickedDemo, float, -1)
  22     ATTRIB(NexuizDemoList, lastClickedTime, float, 0)
  23     ATTRIB(NexuizDemoList, filterString, string, string_null)
  24 ENDCLASS(NexuizDemoList)
  25
  26 entity makeNexuizDemoList();
  27 void StartDemo_Click(entity btn, entity me);
  28 void TimeDemo_Click(entity btn, entity me);
  29 void DemoList_Filter_Change(entity box, entity me);
  30 #endif
  31
  32 #ifdef IMPLEMENTATION
  33
  34 entity makeNexuizDemoList()
  35 {
  36     entity me;
  37     me = spawnNexuizDemoList();
  38     me.configureNexuizDemoList(me);
  39     return me;
  40 }
  41
  42 void configureNexuizDemoListNexuizDemoList(entity me)
  43 {
  44     me.configureNexuizListBox(me);
  45     me.getDemos(me);
  46 }
  47
  48 string demoNameNexuizDemoList(entity me, float i )
  49 {
  50     string s;
  51     s = search_getfilename(me.listDemo, i);
  52     s = substring(s, 6, strlen(s) - 6 - 4);  // demos/, .dem
  53     return s;
  54 }
  55
  56
  57 void getDemosNexuizDemoList(entity me)
  58 {
  59     string s;
  60
  61     if(me.filterString)
  62         //subdirectory in filterString allowed
  63         s=strcat("demos/*", me.filterString, "*.dem");
  64     else
  65         s="demos/*.dem";
  66
  67     //dprint("Search demos with the pattern ", s, "\n");
  68         if(me.listDemo >= 0)
  69                 search_end(me.listDemo);
  70     me.listDemo = search_begin(s, FALSE, TRUE);
  71     if(me.listDemo < 0)
  72         me.nItems=0;
  73     else
  74         me.nItems=search_getsize(me.listDemo);
  75 }
  76
  77 void destroyNexuizDemoList(entity me)
  78 {
  79     search_end(me.listDemo);
  80 }
  81
  82 void resizeNotifyNexuizDemoList(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
  83 {
  84     me.origin = absOrigin;
  85     me.itemAbsSize = '0 0 0';
  86     resizeNotifyNexuizListBox(me, relOrigin, relSize, absOrigin, absSize);
  87
  88     me.realFontSize_y = me.fontSize / (me.itemAbsSize_y = (absSize_y * me.itemHeight));
  89     me.realFontSize_x = me.fontSize / (me.itemAbsSize_x = (absSize_x * (1 - me.controlWidth)));
  90     me.realUpperMargin = 0.5 * (1 - me.realFontSize_y);
  91
  92     me.columnNameOrigin = me.realFontSize_x;
  93     me.columnNameSize = 1 - 2 * me.realFontSize_x;
  94 }
  95
  96 void drawListBoxItemNexuizDemoList(entity me, float i, vector absSize, float isSelected)
  97 {
  98     string s;
  99     if(isSelected)
 100         draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
 101
 102     s = me.demoName(me,i);
 103     s = draw_TextShortenToWidth(s, me.columnNameSize / me.realFontSize_x, 0);
 104     draw_Text(me.realUpperMargin * eY + (me.columnNameOrigin + 0.00 * (me.columnNameSize - draw_TextWidth(s, 0) * me.realFontSize_x)) * eX, s, me.realFontSize, '1 1 1', SKINALPHA_TEXT, 0);
 105 }
 106
 107 void showNotifyNexuizDemoList(entity me)
 108 {
 109     me.getDemos(me);
 110 }
 111
 112 void DemoList_Filter_Change(entity box, entity me)
 113 {
 114     if(me.filterString)
 115         strunzone(me.filterString);
 116
 117     if(box.text != "")
 118         me.filterString = strzone(box.text);
 119     else
 120         me.filterString = string_null;
 121
 122     me.getDemos(me);
 123 }
 124
 125 void startDemoNexuizDemoList(entity me)
 126 {
 127     string s;
 128     s = me.demoName(me,me.selectedItem);
 129     localcmd("playdemo demos/", s, ".dem\nwait\ntogglemenu\n");
 130 }
 131
 132 void StartDemo_Click(entity btn, entity me)
 133 {
 134     me.startDemo(me);
 135 }
 136
 137 void TimeDemo_Click(entity btn, entity me)
 138 {
 139     string s;
 140     s = me.demoName(me,me.selectedItem);
 141     localcmd("timedemo demos/", s, ".dem\nwait\ntogglemenu\n");
 142 }
 143
 144 void clickListBoxItemNexuizDemoList(entity me, float i, vector where)
 145 {
 146     if(i == me.lastClickedDemo)
 147         if(time < me.lastClickedTime + 0.3)
 148         {
 149             // DOUBLE CLICK!
 150             me.setSelected(me, i);
 151             me.startDemo(me);
 152         }
 153     me.lastClickedDemo = i;
 154     me.lastClickedTime = time;
 155 }
 156
 157 float keyDownNexuizDemoList(entity me, float scan, float ascii, float shift)
 158 {
 159     if(scan == K_ENTER) {
 160         me.startDemo(me);
 161         return 1;
 162     }
 163     else
 164         return keyDownListBox(me, scan, ascii, shift);
 165 }
 166 #endif
 167