data/qcsrc/menu/nexuiz/credits.c

   1 #ifdef INTERFACE
   2 CLASS(NexuizCreditsList) EXTENDS(NexuizListBox)
   3         METHOD(NexuizCreditsList, configureNexuizCreditsList, void(entity))
   4         ATTRIB(NexuizCreditsList, rowsPerItem, float, 1)
   5         METHOD(NexuizCreditsList, draw, void(entity))
   6         METHOD(NexuizCreditsList, drawListBoxItem, void(entity, float, vector, float))
   7         METHOD(NexuizCreditsList, resizeNotify, void(entity, vector, vector, vector, vector))
   8         METHOD(NexuizCreditsList, keyDown, float(entity, float, float, float))
   9         METHOD(NexuizCreditsList, destroy, void(entity))
  10
  11         ATTRIB(NexuizCreditsList, realFontSize, vector, '0 0 0')
  12         ATTRIB(NexuizCreditsList, realUpperMargin, float, 0)
  13         ATTRIB(NexuizCreditsList, bufferIndex, float, 0)
  14         ATTRIB(NexuizCreditsList, scrolling, float, 0)
  15 ENDCLASS(NexuizCreditsList)
  16 entity makeNexuizCreditsList();
  17 #endif
  18
  19 #ifdef IMPLEMENTATION
  20 entity makeNexuizCreditsList()
  21 {
  22         entity me;
  23         me = spawnNexuizCreditsList();
  24         me.configureNexuizCreditsList(me);
  25         return me;
  26 }
  27 void configureNexuizCreditsListNexuizCreditsList(entity me)
  28 {
  29         me.configureNexuizListBox(me);
  30         // load the file
  31         me.bufferIndex = buf_load("nexuiz-credits.txt");
  32         me.nItems = buf_getsize(me.bufferIndex);
  33 }
  34 void destroyNexuizCreditsList(entity me)
  35 {
  36         buf_del(me.bufferIndex);
  37 }
  38 void drawNexuizCreditsList(entity me)
  39 {
  40         float i;
  41         if(me.scrolling)
  42         {
  43                 me.scrollPos = bound(0, (time - me.scrolling) * me.itemHeight, me.nItems * me.itemHeight - 1);
  44                 i = min(me.selectedItem, floor((me.scrollPos + 1) / me.itemHeight - 1));
  45                 i = max(i, ceil(me.scrollPos / me.itemHeight));
  46                 me.setSelected(me, i);
  47         }
  48         drawListBox(me);
  49 }
  50 void resizeNotifyNexuizCreditsList(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
  51 {
  52         resizeNotifyNexuizListBox(me, relOrigin, relSize, absOrigin, absSize);
  53
  54         me.realFontSize_y = me.fontSize / (absSize_y * me.itemHeight);
  55         me.realFontSize_x = me.fontSize / (absSize_x * (1 - me.controlWidth));
  56         me.realUpperMargin = 0.5 * (1 - me.realFontSize_y);
  57 }
  58 void drawListBoxItemNexuizCreditsList(entity me, float i, vector absSize, float isSelected)
  59 {
  60         // layout: Ping, Credits name, Map name, NP, TP, MP
  61         string s;
  62         float theAlpha;
  63         vector theColor;
  64
  65         s = bufstr_get(me.bufferIndex, i);
  66
  67         if(substring(s, 0, 2) == "**")
  68         {
  69                 s = substring(s, 2, strlen(s) - 2);
  70                 theColor = SKINCOLOR_CREDITS_TITLE;
  71                 theAlpha = SKINALPHA_CREDITS_TITLE;
  72         }
  73         else if(substring(s, 0, 1) == "*")
  74         {
  75                 s = substring(s, 1, strlen(s) - 1);
  76                 theColor = SKINCOLOR_CREDITS_FUNCTION;
  77                 theAlpha = SKINALPHA_CREDITS_FUNCTION;
  78         }
  79         else
  80         {
  81                 theColor = SKINCOLOR_CREDITS_PERSON;
  82                 theAlpha = SKINALPHA_CREDITS_PERSON;
  83         }
  84
  85         draw_CenterText(me.realUpperMargin * eY + 0.5 * eX, s, me.realFontSize, theColor, theAlpha, 0);
  86 }
  87
  88 float keyDownNexuizCreditsList(entity me, float scan, float ascii, float shift)
  89 {
  90         float i;
  91         me.dragScrollTimer = time;
  92         me.scrolling = 0;
  93
  94         if(scan == K_PGUP)
  95                 me.scrollPos = max(me.scrollPos - 0.5, 0);
  96         else if(scan == K_PGDN)
  97                 me.scrollPos = min(me.scrollPos + 0.5, me.nItems * me.itemHeight - 1);
  98         else if(scan == K_UPARROW)
  99                 me.scrollPos = max(me.scrollPos - me.itemHeight, 0);
 100         else if(scan == K_DOWNARROW)
 101                 me.scrollPos = min(me.scrollPos + me.itemHeight, me.nItems * me.itemHeight - 1);
 102         else
 103                 return keyDownListBox(me, scan, ascii, shift);
 104
 105         i = min(me.selectedItem, floor((me.scrollPos + 1) / me.itemHeight - 1));
 106         i = max(i, ceil(me.scrollPos / me.itemHeight));
 107         me.setSelected(me, i);
 108
 109         return 1;
 110 }
 111 #endif