data/qcsrc/menu/menu.qc

   1 ///////////////////////////////////////////////
   2 // Menu Source File
   3 ///////////////////////
   4 // This file belongs to dpmod/darkplaces
   5 // AK contains all menu functions (especially the required ones)
   6 ///////////////////////////////////////////////
   7
   8 float mouseButtonsPressed;
   9 vector menuMousePos;
  10 float menuShiftState;
  11 float menuPrevTime;
  12 float menuAlpha;
  13 float menuLogoAlpha;
  14 float prevMenuAlpha;
  15 float menuInitialized;
  16 float menuNotTheFirstFrame;
  17 float menuMouseMode;
  18
  19 void SUB_Null() { };
  20
  21 void() m_init =
  22 {
  23         dprint_load();
  24 }
  25
  26 void UpdateConWidthHeight()
  27 {
  28         float conwidth_s, conheight_s;
  29         conwidth_s = conwidth;
  30         conheight_s = conheight;
  31         conwidth = cvar("vid_conwidth");
  32         conheight = cvar("vid_conheight");
  33         if(conwidth < 800)
  34         {
  35                 conheight *= 800 / conwidth;
  36                 conwidth = 800;
  37         }
  38         if(conheight < 600)
  39         {
  40                 conwidth *= 600 / conheight;
  41                 conheight = 600;
  42         }
  43         if(main)
  44         {
  45                 if(conwidth_s != conwidth || conheight_s != conheight)
  46                 {
  47                         draw_reset();
  48                         main.resizeNotify(main, '0 0 0', eX * conwidth + eY * conheight, '0 0 0', eX * conwidth + eY * conheight);
  49                 }
  50         }
  51 }
  52
  53 void() m_init_delayed =
  54 {
  55         float fh, glob, n, i;
  56         string s;
  57
  58         dprint_load();
  59
  60         menuInitialized = 0;
  61         if(!preMenuInit())
  62                 return;
  63         menuInitialized = 1;
  64         GameCommand_Init();
  65
  66         fh = -1;
  67         if(cvar_string("menu_skin") != "")
  68         {
  69                 draw_currentSkin = strcat("gfx/menu/", cvar_string("menu_skin"));
  70                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  71         }
  72         if(fh < 0)
  73         if(cvar_defstring("menu_skin") != "")
  74         {
  75                 draw_currentSkin = strcat("gfx/menu/", cvar_defstring("menu_skin"));
  76                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  77         }
  78         if(fh < 0)
  79         {
  80                 draw_currentSkin = "gfx/menu/default";
  81                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  82         }
  83         draw_currentSkin = strzone(draw_currentSkin);
  84         while((s = fgets(fh)))
  85         {
  86                 n = tokenize_sane(s);
  87                 if(n >= 2)
  88                         Skin_ApplySetting(argv(0), substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
  89         }
  90         fclose(fh);
  91
  92         glob = search_begin(strcat(draw_currentSkin, "/*.tga"), TRUE, TRUE);
  93         if(glob >= 0)
  94         {
  95                 n = search_getsize(glob);
  96                 for(i = 0; i < n; ++i)
  97                         precache_pic(search_getfilename(glob, i));
  98                 search_end(glob);
  99         }
 100
 101         draw_setMousePointer(SKINGFX_CURSOR, SKINSIZE_CURSOR, SKINOFFSET_CURSOR);
 102
 103         conwidth = conheight = -1;
 104         draw_reset();
 105         UpdateConWidthHeight();
 106         main = spawnMainWindow(); main.configureMainWindow(main);
 107         main.resizeNotify(main, '0 0 0', eX * conwidth + eY * conheight, '0 0 0', eX * conwidth + eY * conheight);
 108         main.focused = 1;
 109         menuShiftState = 0;
 110         menuMousePos = '0.5 0.5 0';
 111
 112         if(Menu_Active)
 113                 m_display(); // delayed menu display
 114 };
 115
 116 void(float key, float ascii) m_keyup =
 117 {
 118         if(!menuInitialized)
 119                 return;
 120         if(!Menu_Active)
 121                 return;
 122         draw_reset();
 123         main.keyUp(main, key, ascii, menuShiftState);
 124         if(key >= K_MOUSE1 && key <= K_MOUSE3)
 125         {
 126                 --mouseButtonsPressed;
 127                 if(!mouseButtonsPressed)
 128                         main.mouseRelease(main, menuMousePos);
 129                 if(mouseButtonsPressed < 0)
 130                 {
 131                         mouseButtonsPressed = 0;
 132                         print("Warning: released an already released button\n");
 133                 }
 134         }
 135         if(key == K_ALT) menuShiftState -= (menuShiftState & S_ALT);
 136         if(key == K_CTRL) menuShiftState -= (menuShiftState & S_CTRL);
 137         if(key == K_SHIFT) menuShiftState -= (menuShiftState & S_SHIFT);
 138 };
 139
 140 void(float key, float ascii) m_keydown =
 141 {
 142         if(!menuInitialized)
 143                 return;
 144         if(!Menu_Active)
 145                 return;
 146         if(keyGrabber)
 147         {
 148                 entity e;
 149                 e = keyGrabber;
 150                 keyGrabber = NULL;
 151                 e.keyGrabbed(e, key, ascii);
 152         }
 153         else
 154         {
 155                 draw_reset();
 156                 if(key >= K_MOUSE1 && key <= K_MOUSE3)
 157                         if(!mouseButtonsPressed)
 158                                 main.mousePress(main, menuMousePos);
 159                 if(!main.keyDown(main, key, ascii, menuShiftState))
 160                         if(key == K_ESCAPE)
 161                                 if(gamestatus & (GAME_ISSERVER | GAME_CONNECTED)) // don't back out to console only
 162                                         m_hide(); // disable menu on unhandled ESC
 163         }
 164         if(key >= K_MOUSE1 && key <= K_MOUSE3)
 165         {
 166                 ++mouseButtonsPressed;
 167                 if(mouseButtonsPressed > 10)
 168                 {
 169                         mouseButtonsPressed = 10;
 170                         print("Warning: pressed an already pressed button\n");
 171                 }
 172         }
 173         if(key == K_ALT) menuShiftState |= S_ALT;
 174         if(key == K_CTRL) menuShiftState |= S_CTRL;
 175         if(key == K_SHIFT) menuShiftState |= S_SHIFT;
 176 };
 177
 178 void(string img, float a) drawBackground =
 179 {
 180         vector sz;
 181         vector isz;
 182         sz = draw_PictureSize(img);
 183         // keep aspect of image
 184         if(sz_x * draw_scale_y >= sz_y * draw_scale_x)
 185         {
 186                 // that is, sz_x/sz_y >= draw_scale_x/draw_scale_y
 187                 // match up the height
 188                 isz_y = 1;
 189                 isz_x = isz_y * (sz_x / sz_y) * (draw_scale_y / draw_scale_x);
 190         }
 191         else
 192         {
 193                 // that is, sz_x/sz_y <= draw_scale_x/draw_scale_y
 194                 // match up the width
 195                 isz_x = 1;
 196                 isz_y = isz_x * (sz_y / sz_x) * (draw_scale_x / draw_scale_y);
 197         }
 198         draw_Picture('0.5 0.5 0' - 0.5 * isz, img, isz, '1 1 1', a);
 199 }
 200
 201 void() m_draw =
 202 {
 203         float t;
 204         float realFrametime;
 205
 206         menuMouseMode = cvar("menu_mouse_absolute");
 207
 208         if(main)
 209                 UpdateConWidthHeight();
 210
 211         if(!menuInitialized)
 212         {
 213                 // TODO draw an info image about this situation
 214                 m_init_delayed();
 215                 return;
 216         }
 217         if(!menuNotTheFirstFrame)
 218         {
 219                 menuNotTheFirstFrame = 1;
 220                 if(Menu_Active)
 221                 if(!cvar("menu_video_played"))
 222                 {
 223                         localcmd("set menu_video_played 1; cd loop $menu_cdtrack; play sound/announcer/male/welcome.ogg\n");
 224                         menuLogoAlpha = -0.8; // no idea why, but when I start this at zero, it jumps instead of fading
 225                 }
 226         }
 227
 228         t = gettime();
 229         realFrametime = frametime = min(0.2, t - menuPrevTime);
 230         menuPrevTime = t;
 231         time += frametime;
 232
 233         t = cvar("menu_slowmo");
 234         if(t)
 235         {
 236                 frametime *= t;
 237                 realFrametime *= t;
 238         }
 239         else
 240                 t = 1;
 241
 242         if(Menu_Active)
 243         {
 244                 if(getmousetarget() == (menuMouseMode ? MT_CLIENT : MT_MENU) && (getkeydest() == KEY_MENU || getkeydest() == KEY_MENU_GRABBED))
 245                         setkeydest(keyGrabber ? KEY_MENU_GRABBED : KEY_MENU);
 246                 else
 247                         m_hide();
 248         }
 249
 250         if(cvar("cl_capturevideo"))
 251                 frametime = t / cvar("cl_capturevideo_fps"); // make capturevideo work smoothly
 252
 253         dprint_load();
 254         gamestatus = 0;
 255         if(isserver())
 256                 gamestatus = gamestatus | GAME_ISSERVER;
 257         if(clientstate() == CS_CONNECTED)
 258                 gamestatus = gamestatus | GAME_CONNECTED;
 259         if(cvar("developer"))
 260                 gamestatus = gamestatus | GAME_DEVELOPER;
 261
 262         prevMenuAlpha = menuAlpha;
 263         if(Menu_Active)
 264         {
 265                 if(menuAlpha == 0 && menuLogoAlpha < 2)
 266                 {
 267                         menuLogoAlpha = menuLogoAlpha + frametime * 2;
 268                 }
 269                 else
 270                 {
 271                         menuAlpha = min(1, menuAlpha + frametime * 5);
 272                         menuLogoAlpha = 2;
 273                 }
 274         }
 275         else
 276         {
 277                 menuAlpha = max(0, menuAlpha - frametime * 5);
 278                 menuLogoAlpha = 2;
 279         }
 280
 281         draw_reset();
 282
 283         if(!(gamestatus & (GAME_CONNECTED | GAME_ISSERVER)))
 284         {
 285                 if(menuLogoAlpha > 0)
 286                 {
 287                         drawBackground(SKINGFX_BACKGROUND, bound(0, menuLogoAlpha, 1));
 288                         if(menuAlpha <= 0 && SKINALPHA_CURSOR_INTRO > 0)
 289                         {
 290                                 draw_alpha = SKINALPHA_CURSOR_INTRO * bound(0, menuLogoAlpha, 1);
 291                                 draw_drawMousePointer(menuMousePos);
 292                                 draw_alpha = 1;
 293                         }
 294                 }
 295         }
 296         else if(SKINALPHA_BACKGROUND_INGAME)
 297         {
 298                 if(menuAlpha > 0)
 299                         drawBackground(SKINGFX_BACKGROUND_INGAME, menuAlpha * SKINALPHA_BACKGROUND_INGAME);
 300         }
 301
 302         draw_reset();
 303         preMenuDraw();
 304         draw_reset();
 305
 306         if(menuAlpha <= 0)
 307         {
 308                 if(prevMenuAlpha > 0)
 309                         main.initializeDialog(main, main.firstChild);
 310                 draw_reset();
 311                 postMenuDraw();
 312                 return;
 313         }
 314
 315         draw_alpha *= menuAlpha;
 316
 317         if(menuMouseMode)
 318         {
 319                 vector newMouse;
 320                 newMouse = globalToBoxSize(getmousepos(), draw_scale);
 321                 if(newMouse != '0 0 0')
 322                         if(newMouse != menuMousePos)
 323                         {
 324                                 menuMousePos = newMouse;
 325                                 if(mouseButtonsPressed)
 326                                         main.mouseDrag(main, menuMousePos);
 327                                 else
 328                                         main.mouseMove(main, menuMousePos);
 329                         }
 330         }
 331         else
 332         {
 333                 if(frametime > 0)
 334                 {
 335                         vector dMouse;
 336                         dMouse = getmousepos() * (frametime / realFrametime); // for capturevideo
 337                         if(dMouse != '0 0 0')
 338                         {
 339                                 dMouse = globalToBoxSize(dMouse, draw_scale);
 340                                 menuMousePos += dMouse * cvar("menu_mouse_speed");
 341                                 menuMousePos_x = bound(0, menuMousePos_x, 1);
 342                                 menuMousePos_y = bound(0, menuMousePos_y, 1);
 343                                 if(mouseButtonsPressed)
 344                                         main.mouseDrag(main, menuMousePos);
 345                                 else
 346                                         main.mouseMove(main, menuMousePos);
 347                         }
 348                 }
 349         }
 350         main.draw(main);
 351         draw_alpha = max(draw_alpha, SKINALPHA_CURSOR_INTRO * bound(0, menuLogoAlpha, 1));
 352
 353         draw_drawMousePointer(menuMousePos);
 354
 355         draw_reset();
 356         postMenuDraw();
 357
 358         frametime = 0;
 359 };
 360
 361 void() m_display =
 362 {
 363         Menu_Active = true;
 364         setkeydest(KEY_MENU);
 365         setmousetarget((menuMouseMode ? MT_CLIENT : MT_MENU));
 366
 367         if(!menuInitialized)
 368                 return;
 369
 370         if(mouseButtonsPressed)
 371                 main.mouseRelease(main, menuMousePos);
 372         mouseButtonsPressed = 0;
 373
 374         main.focusEnter(main);
 375         main.showNotify(main);
 376 };
 377
 378 void() m_hide =
 379 {
 380         Menu_Active = false;
 381         setkeydest(KEY_GAME);
 382         setmousetarget(MT_CLIENT);
 383
 384         if(!menuInitialized)
 385                 return;
 386
 387         main.focusLeave(main);
 388         main.hideNotify(main);
 389 };
 390
 391 void() m_toggle =
 392 {
 393         if(Menu_Active)
 394                 m_hide();
 395         else
 396                 m_display();
 397 };
 398
 399 void() m_shutdown =
 400 {
 401         entity e;
 402
 403         m_hide();
 404         for(e = NULL; (e = nextent(e)) != NULL; )
 405         {
 406                 if(e.destroy)
 407                         e.destroy(e);
 408         }
 409 };
 410
 411 void(string itemname) m_goto =
 412 {
 413         entity e;
 414         if(!menuInitialized)
 415                 return;
 416         if(itemname == "") // this can be called by GameCommand
 417         {
 418                 if(gamestatus & (GAME_ISSERVER | GAME_CONNECTED))
 419                         m_hide();
 420                 else
 421                 {
 422                         main.initializeDialog(main, main.firstChild);
 423                         m_display();
 424                 }
 425         }
 426         else
 427         {
 428                 e = findstring(NULL, name, itemname);
 429                 if(e && e.parent == main)
 430                 {
 431                         m_hide();
 432                         main.initializeDialog(main, e);
 433                         m_display();
 434                 }
 435         }
 436 }
 437
 438 void() m_goto_skin_selector =
 439 {
 440         if(!menuInitialized)
 441                 return;
 442         // TODO add code to switch back to the skin selector (no idea how to do it now)
 443         m_hide();
 444         //main.initializeDialog(main, main.firstChild);
 445         //main.firstChild.setFocus(main.firstChild, findstring(NULL, name, "__skinselect_window"));
 446         m_display();
 447 }