data/qcsrc/common/gamecommand.qc

   1 #define MAX_RPN_STACK 16
   2 float rpn_db;
   3 float rpn_error;
   4 float rpn_sp;
   5 string rpn_stack[MAX_RPN_STACK];
   6 string rpn_pop() {
   7         if(rpn_sp > 0) {
   8                 --rpn_sp;
   9                 return rpn_stack[rpn_sp];
  10         } else {
  11                 print("rpn: stack underflow\n");
  12                 rpn_error = TRUE;
  13                 return "";
  14         }
  15 }
  16 void rpn_push(string s) {
  17         if(rpn_sp < MAX_RPN_STACK) {
  18                 rpn_stack[rpn_sp] = s;
  19                 ++rpn_sp;
  20         } else {
  21                 print("rpn: stack overflow\n");
  22                 rpn_error = TRUE;
  23         }
  24 }
  25 string rpn_get() {
  26         if(rpn_sp > 0) {
  27                 return rpn_stack[rpn_sp - 1];
  28         } else {
  29                 print("rpn: empty stack\n");
  30                 rpn_error = TRUE;
  31                 return "";
  32         }
  33 }
  34 void rpn_set(string s) {
  35         if(rpn_sp > 0) {
  36                 rpn_stack[rpn_sp - 1] = s;
  37         } else {
  38                 print("rpn: empty stack\n");
  39                 rpn_error = TRUE;
  40         }
  41 }
  42 float rpn_getf() { return stof(rpn_get()); }
  43 float rpn_popf() { return stof(rpn_pop()); }
  44 void rpn_pushf(float f) { return rpn_push(ftos(f)); }
  45 void rpn_setf(float f) { return rpn_set(ftos(f)); }
  46
  47 float GameCommand_Generic(string command)
  48 {
  49         float argc;
  50         float i, j, f, n;
  51         string s, s2;
  52         argc = tokenize_sane(command);
  53         if(argv(0) == "help")
  54         {
  55                 print("  rpn EXPRESSION... - a RPN calculator.\n");
  56                 print("    Operator description (x: string, s: set, f: float):\n");
  57                 print("    x pop ----------------------------->     : removes the top\n");
  58                 print("    x dup -----------------------------> x x : duplicates the top\n");
  59                 print("    x x exch --------------------------> x x : swap the top two\n");
  60                 print("    /cvarname load --------------------> x   : loads a cvar\n");
  61                 print("    /cvarname x def ------------------->     : writes to a cvar\n");
  62                 print("    f f add|sub|mul|div|mod|max|min ---> f   : adds/... two numbers\n");
  63                 print("    f f eq|ne|gt|ge|lt|le -------------> f   : compares two numbers\n");
  64                 print("    f neg|abs|sgn|rand|floor|ceil------> f   : negates/... a number\n");
  65                 print("    f f f bound -----------------------> f   : bounds the middle number\n");
  66                 print("    f1 f2 b when ----------------------> f   : f1 if b, f2 otherwise\n");
  67                 print("    s s union|intersection|difference -> s   : set operations\n");
  68                 print("    s shuffle -------------------------> s   : randomly arrange elements\n");
  69                 print("    x dbpush -------------------------->     : pushes the top onto the database\n");
  70                 print("    dbpop|dbget -----------------------> x   : removes/reads DB's top\n");
  71                 print("    dblen|dbat ------------------------> f   : gets the DB's size/cursor pos\n");
  72                 print("    dbclr ----------------------------->     : clear the DB\n");
  73                 print("    s dbsave|dbload-------------------->     : save/load the DB to/from a file\n");
  74                 print("    x dbins --------------------------->     : moves the top into the DB\n");
  75                 print("    dbext|dbread ----------------------> x   : extract/get from the DB's cursor\n");
  76                 print("    f dbmov|dbgoto -------------------->     : move or set the DB's cursor\n");
  77                 print("    Set operations operate on 'such''strings'.\n");
  78                 print("    Unknown tokens insert their cvar value.\n");
  79                 print("  maplist add map\n");
  80                 print("  maplist remove map\n");
  81                 print("  maplist shuffle\n");
  82                 return TRUE;
  83         }
  84
  85         if(argv(0) == "maplist")
  86         {
  87                 if(argv(1) == "add" && argc == 3)
  88                 {
  89                         f = fopen(strcat("maps/", argv(2), ".bsp"), FILE_READ);
  90                         if(f != -1)
  91                                 fclose(f);
  92                         else {
  93                                 print("maplist: ERROR: ", argv(2), " does not exist!\n");
  94                                 return TRUE;
  95                         }
  96                         if(cvar_string("g_maplist") == "")
  97                                 cvar_set("g_maplist", argv(2));
  98                         else
  99                                 cvar_set("g_maplist", strcat(argv(2), " ", cvar_string("g_maplist")));
 100                         return TRUE;
 101                 }
 102                 else if(argv(1) == "remove" && argc == 3)
 103                 {
 104                         s = argv(2);
 105                         n = tokenizebyseparator(cvar_string("g_maplist"), " ");
 106                         s2 = "";
 107                         for(i = 0; i < n; ++i)
 108                                 if(argv(i) != s)
 109                                 {
 110                                         s2 = strcat(s2, " ", argv(i));
 111                                 }
 112                         s2 = substring(s2, 1, strlen(s2) - 1);
 113                         cvar_set("g_maplist", s2);
 114                         return TRUE;
 115                 }
 116                 else if(argv(1) == "shuffle" && argc == 2)
 117                 {
 118                         s = cvar_string("g_maplist");
 119                         for(i = 1; i < (n = tokenizebyseparator(s, " ")); ++i)
 120                         {
 121                                 // swap i-th item at a random position from 0 to i
 122                                 // proof for even distribution:
 123                                 //   n = 1: obvious
 124                                 //   n -> n+1:
 125                                 //     item n+1 gets at any position with chance 1/(n+1)
 126                                 //     all others will get their 1/n chance reduced by factor n/(n+1)
 127                                 //     to be on place n+1, their chance will be 1/(n+1)
 128                                 //     1/n * n/(n+1) = 1/(n+1)
 129                                 //     q.e.d.
 130                                 f = floor(random() * (i + 1)); // 0 to i
 131                                 if(f == i)
 132                                         continue; // no change
 133
 134                                 s2 = "";
 135                                 for(j = 0; j < n; ++j)
 136                                         s2 = strcat(s2, " ", argv((j == i) ? f : (j == f) ? i : j));
 137                                 s = substring(s2, 1, strlen(s2) - 1);
 138                         }
 139                         cvar_set("g_maplist", s);
 140                         return TRUE;
 141                 }
 142         }
 143         else if(argv(0) == "rpn")
 144         {
 145                 if(!rpn_db)
 146                 {
 147                         rpn_db = db_create();
 148                         db_put(rpn_db, "stack.pointer", "0");
 149                         db_put(rpn_db, "stack.pos", "-1");
 150                 }
 151                 if(argc >= 2)
 152                 {
 153                         float rpnpos;
 154                         string rpncmd;
 155                         float f2, f3;
 156                         rpn_sp = 0;
 157                         rpn_error = FALSE;
 158                         for(rpnpos = 1; rpnpos < argc; ++rpnpos)
 159                         {
 160                                 rpncmd = argv(rpnpos);
 161                                 f = strlen(rpncmd);
 162                                 if(rpncmd == "") {
 163                                 } else if(stof(substring(rpncmd, 0, 1)) > 0) {
 164                                         rpn_push(rpncmd);
 165                                 } else if(substring(rpncmd, 0, 1) == "0") {
 166                                         rpn_push(rpncmd);
 167                                 } else if(f >= 2 && substring(rpncmd, 0, 1) == "+") {
 168                                         rpn_push(rpncmd);
 169                                 } else if(f >= 2 && substring(rpncmd, 0, 1) == "-") {
 170                                         rpn_push(rpncmd);
 171                                 } else if(f >= 2 && substring(rpncmd, 0, 1) == "/") {
 172                                         rpn_push(substring(rpncmd, 1, strlen(rpncmd) - 1));
 173                                 } else if(rpncmd == "clear") {
 174                                         rpn_sp = 0;
 175                                 } else if(rpncmd == "def" || rpncmd == "=") {
 176                                         s = rpn_pop();
 177                                         s2 = rpn_pop();
 178 #ifdef MENUQC
 179                                         registercvar(s2, "", 0);
 180 #else
 181                                         registercvar(s2, "");
 182 #endif
 183                                         if(!rpn_error) // don't change cvars if a stack error had happened!
 184                                                 cvar_set(s2, s);
 185                                 } else if(rpncmd == "defs" || rpncmd == "@") {
 186                                         s = "";
 187                                         i = rpn_popf();
 188                                         j = (i == 0);
 189                                         while(rpn_sp > 1 && (j || i > 0))
 190                                         {
 191                                                 s = strcat("/", rpn_pop(), " ", s);
 192                                                 --i;
 193                                         }
 194                                         s2 = rpn_pop();
 195 #ifdef MENUQC
 196                                         registercvar(s2, "", 0);
 197 #else
 198                                         registercvar(s2, "");
 199 #endif
 200                                         if(!rpn_error) // don't change cvars if a stack error had happened!
 201                                                 cvar_set(s2, s);
 202                                 } else if(rpncmd == "load") {
 203                                         rpn_set(cvar_string(rpn_get()));
 204                                 } else if(rpncmd == "exch") {
 205                                         s = rpn_pop();
 206                                         s2 = rpn_get();
 207                                         rpn_set(s);
 208                                         rpn_push(s2);
 209                                 } else if(rpncmd == "dup") {
 210                                         rpn_push(rpn_get());
 211                                 } else if(rpncmd == "pop") {
 212                                         rpn_pop();
 213                                 } else if(rpncmd == "add" || rpncmd == "+") {
 214                                         f = rpn_popf();
 215                                         rpn_setf(rpn_getf() + f);
 216                                 } else if(rpncmd == "sub" || rpncmd == "-") {
 217                                         f = rpn_popf();
 218                                         rpn_setf(rpn_getf() - f);
 219                                 } else if(rpncmd == "mul" || rpncmd == "*") {
 220                                         f = rpn_popf();
 221                                         rpn_setf(rpn_getf() * f);
 222                                 } else if(rpncmd == "div" || rpncmd == "/") {
 223                                         f = rpn_popf();
 224                                         rpn_setf(rpn_getf() / f);
 225                                 } else if(rpncmd == "mod" || rpncmd == "%") {
 226                                         f = rpn_popf();
 227                                         f2 = rpn_getf();
 228                                         rpn_setf(f2 - f * floor(f2 / f));
 229                                 } else if(rpncmd == "abs") {
 230                                         rpn_setf(fabs(rpn_getf()));
 231                                 } else if(rpncmd == "sgn") {
 232                                         f = rpn_getf();
 233                                         if(f < 0)
 234                                                 rpn_set("-1");
 235                                         else if(f > 0)
 236                                                 rpn_set("1");
 237                                         else
 238                                                 rpn_set("0");
 239                                 } else if(rpncmd == "neg" || rpncmd == "~") {
 240                                         rpn_setf(-rpn_getf());
 241                                 } else if(rpncmd == "floor" || rpncmd == "f") {
 242                                         rpn_setf(floor(rpn_getf()));
 243                                 } else if(rpncmd == "ceil" || rpncmd == "c") {
 244                                         rpn_setf(ceil(rpn_getf()));
 245                                 } else if(rpncmd == "max") {
 246                                         f = rpn_popf();
 247                                         f2 = rpn_getf();
 248                                         rpn_setf(max(f2, f));
 249                                 } else if(rpncmd == "min") {
 250                                         f = rpn_popf();
 251                                         f2 = rpn_getf();
 252                                         rpn_setf(min(f2, f));
 253                                 } else if(rpncmd == "bound") {
 254                                         f = rpn_popf();
 255                                         f2 = rpn_popf();
 256                                         f3 = rpn_getf();
 257                                         rpn_setf(bound(f3, f2, f));
 258                                 } else if(rpncmd == "when") {
 259                                         f = rpn_popf();
 260                                         f2 = rpn_popf();
 261                                         f3 = rpn_getf();
 262                                         if(f)
 263                                                 rpn_setf(f3);
 264                                         else
 265                                                 rpn_setf(f2);
 266                                 } else if(rpncmd == ">" || rpncmd == "gt") {
 267                                         f = rpn_popf();
 268                                         rpn_setf(rpn_getf() > f);
 269                                 } else if(rpncmd == "<" || rpncmd == "lt") {
 270                                         f = rpn_popf();
 271                                         rpn_setf(rpn_getf() < f);
 272                                 } else if(rpncmd == "==" || rpncmd == "eq") {
 273                                         f = rpn_popf();
 274                                         rpn_setf(rpn_getf() == f);
 275                                 } else if(rpncmd == ">=" || rpncmd == "ge") {
 276                                         f = rpn_popf();
 277                                         rpn_setf(rpn_getf() >= f);
 278                                 } else if(rpncmd == "<=" || rpncmd == "le") {
 279                                         f = rpn_popf();
 280                                         rpn_setf(rpn_getf() <= f);
 281                                 } else if(rpncmd == "!=" || rpncmd == "ne") {
 282                                         f = rpn_popf();
 283                                         rpn_setf(rpn_getf() != f);
 284                                 } else if(rpncmd == "rand") {
 285                                         rpn_setf(ceil(random() * rpn_getf()) - 1);
 286                                 } else if(rpncmd == "dbpush") {
 287                                         s = rpn_pop();
 288                                         if(!rpn_error)
 289                                         {
 290                                                 i = stof(db_get(rpn_db, "stack.pointer"));
 291                                                 db_put(rpn_db, "stack.pointer", ftos(i+1));
 292                                                 db_put(rpn_db, strcat("stack.", ftos(i)), s);
 293                                         }
 294                                         if(!i)
 295                                                 db_put(rpn_db, "stack.pos", "0");
 296                                 } else if(rpncmd == "dbpop") {
 297                                         i = stof(db_get(rpn_db, "stack.pointer"));
 298                                         if(i)
 299                                         {
 300                                                 s = ftos(i-1);
 301                                                 db_put(rpn_db, "stack.pointer", s);
 302                                                 rpn_push(db_get(rpn_db, strcat("stack.", s)));
 303                                                 j = stof(db_get(rpn_db, "stack.pos"));
 304                                                 if(j >= i)
 305                                                         db_put(rpn_db, "stack.pos", ftos(i-2));
 306                                         } else {
 307                                                 rpn_error = 1;
 308                                                 print("rpn: database underflow\n");
 309                                         }
 310                                 } else if(rpncmd == "dbget") {
 311
 312                                         i = stof(db_get(rpn_db, "stack.pointer"));
 313                                         if(i)
 314                                         {
 315                                                 rpn_push(db_get(rpn_db, strcat("stack.", ftos(i-1))));
 316                                         } else {
 317                                                 rpn_error = 1;
 318                                                 print("rpn: database empty\n");
 319                                         }
 320                                 } else if(rpncmd == "dblen") {
 321                                         rpn_push(db_get(rpn_db, "stack.pointer"));
 322                                 } else if(rpncmd == "dbclr") {
 323                                         db_close(rpn_db);
 324                                         rpn_db = db_create();
 325                                         db_put(rpn_db, "stack.pointer", "0");
 326                                         db_put(rpn_db, "stack.pos", "-1");
 327                                 } else if(rpncmd == "dbsave") {
 328                                         s = rpn_pop();
 329                                         if(!rpn_error)
 330                                                 db_save(rpn_db, s);
 331                                 } else if(rpncmd == "dbload") {
 332                                         s = rpn_pop();
 333                                         if(!rpn_error)
 334                                         {
 335                                                 db_close(rpn_db);
 336                                                 rpn_db = db_load(s);
 337                                         }
 338                                 } else if(rpncmd == "dbins") {
 339                                         s = rpn_pop();
 340                                         if(!rpn_error)
 341                                                 //if(rpn_sp > 0)
 342                                         {
 343                                                 j = stof(db_get(rpn_db, "stack.pointer"));
 344                                                 i = stof(db_get(rpn_db, "stack.pos"));
 345
 346                                                 if(i < 0)
 347                                                 {
 348                                                         i = 0;
 349                                                         db_put(rpn_db, "stack.pos", "0");
 350                                                 }
 351
 352                                                 db_put(rpn_db, "stack.pointer", ftos(j+1));
 353                                                 for(--j; j >= i; --j)
 354                                                 {
 355                                                         db_put(rpn_db, strcat("stack.", ftos(j+1)),
 356                                                                db_get(rpn_db, (strcat("stack.", ftos(j))))
 357                                                                 );
 358                                                 }
 359                                                 db_put(rpn_db, strcat("stack.", ftos(i)), s);
 360                                         }
 361                                 } else if(rpncmd == "dbext") {
 362                                         j = stof(db_get(rpn_db, "stack.pointer"));
 363                                         i = stof(db_get(rpn_db, "stack.pos"));
 364                                         if(!j)
 365                                         {
 366                                                 rpn_error = TRUE;
 367                                                 print("rpn: empty database\n");
 368                                         } else {
 369                                                 --j;
 370                                                 rpn_push(db_get(rpn_db, strcat("stack.", ftos(i))));
 371                                                 db_put(rpn_db, "stack.pointer", ftos(j));
 372                                                 if(i == j)
 373                                                 {
 374                                                         db_put(rpn_db, "stack.pos", ftos(j-1));
 375                                                 } else {
 376                                                         while(i < j)
 377                                                         {
 378                                                                 db_put(rpn_db, strcat("stack.", ftos(i)),
 379                                                                        db_get(rpn_db, (strcat("stack.", ftos(i+1))))
 380                                                                         );
 381                                                                 ++i;
 382                                                         }
 383                                                 }
 384                                         }
 385                                 } else if(rpncmd == "dbread") {
 386                                         s = db_get(rpn_db, "stack.pos");
 387                                         if(stof(s) >= 0)
 388                                         {
 389                                                 rpn_push(db_get(rpn_db, strcat("stack.", s)));
 390                                         } else {
 391                                                 rpn_error = 1;
 392                                                 print("rpn: empty database\n");
 393                                         }
 394                                 } else if(rpncmd == "dbat") {
 395                                         rpn_push(db_get(rpn_db, "stack.pos"));
 396                                 } else if(rpncmd == "dbmov") {
 397                                         j = stof(db_get(rpn_db, "stack.pointer"));
 398                                         i = stof(db_get(rpn_db, "stack.pos"));
 399                                         i += rpn_popf();
 400                                         if(!rpn_error)
 401                                         {
 402                                                 if(i < 0 || i >= j)
 403                                                 {
 404                                                         print("rpn: database cursor out of bounds\n");
 405                                                         rpn_error = TRUE;
 406                                                 }
 407                                                 if(!rpn_error)
 408                                                 {
 409                                                         db_put(rpn_db, "stack.pos", ftos(i));
 410                                                 }
 411                                         }
 412                                 } else if(rpncmd == "dbgoto") {
 413                                         s = rpn_pop();
 414                                         j = stof(db_get(rpn_db, "stack.pointer"));
 415                                         if(!j)
 416                                         {
 417                                                 rpn_error = TRUE;
 418                                                 print("rpn: empty database, cannot move cursor\n");
 419                                         }
 420                                         if(!rpn_error)
 421                                         {
 422                                                 if(s == "end")
 423                                                         i = stof(db_get(rpn_db, "stack.pointer"))-1;
 424                                                 else if(s == "beg")
 425                                                         i = 0;
 426                                                 else
 427                                                         i = stof(s);
 428
 429                                                 j = stof(db_get(rpn_db, "stack.pointer"));
 430                                                 if(i < 0 || i >= j)
 431                                                 {
 432                                                         print("rpn: database cursor destination out of bounds\n");
 433                                                         rpn_error = TRUE;
 434                                                 }
 435                                                 if(!rpn_error)
 436                                                 {
 437                                                         db_put(rpn_db, "stack.pos", ftos(i));
 438                                                 }
 439                                         }
 440                                 } else if(rpncmd == "union") {
 441                                         // s s2 union
 442                                         s2 = rpn_pop();
 443                                         s = rpn_get();
 444                                         f = tokenize_sane(s);
 445                                         f2 = tokenize_sane(strcat(s, " ", s2));
 446                                         // tokens 0..(f-1) represent s
 447                                         // tokens f..f2 represent s2
 448                                         // UNION: add all tokens to s that are in s2 but not in s
 449                                         s = "";
 450                                         for(i = 0; i < f; ++i)
 451                                                 s = strcat(s, " ", argv(i));
 452                                         for(i = f; i < f2; ++i) {
 453                                                 for(j = 0; j < f; ++j)
 454                                                         if(argv(i) == argv(j))
 455                                                                 goto skip_union;
 456                                                 s = strcat(s, " ", argv(i));
 457 :skip_union
 458                                         }
 459                                         if(substring(s, 0, 1) == " ")
 460                                                 s = substring(s, 1, 99999);
 461                                         rpn_set(s);
 462                                         tokenize_sane(command);
 463                                 } else if(rpncmd == "intersection") {
 464                                         // s s2 intersection
 465                                         s2 = rpn_pop();
 466                                         s = rpn_get();
 467                                         f = tokenize_sane(s);
 468                                         f2 = tokenize_sane(strcat(s, " ", s2));
 469                                         // tokens 0..(f-1) represent s
 470                                         // tokens f..f2 represent s2
 471                                         // INTERSECTION: keep only the tokens from s that are also in s2
 472                                         s = "";
 473                                         for(i = 0; i < f; ++i) {
 474                                                 for(j = f; j < f2; ++j)
 475                                                         if(argv(i) == argv(j))
 476                                                         {
 477                                                                 s = strcat(s, " ", argv(i));
 478                                                                 break;
 479                                                         }
 480                                         }
 481                                         if(substring(s, 0, 1) == " ")
 482                                                 s = substring(s, 1, 99999);
 483                                         rpn_set(s);
 484                                         tokenize_sane(command);
 485                                 } else if(rpncmd == "difference") {
 486                                         // s s2 difference
 487                                         s2 = rpn_pop();
 488                                         s = rpn_get();
 489                                         f = tokenize_sane(s);
 490                                         f2 = tokenize_sane(strcat(s, " ", s2));
 491                                         // tokens 0..(f-1) represent s
 492                                         // tokens f..f2 represent s2
 493                                         // DIFFERENCE: keep only the tokens from s that are not in s2
 494                                         s = "";
 495                                         for(i = 0; i < f; ++i) {
 496                                                 for(j = f; j < f2; ++j)
 497                                                         if(argv(i) == argv(j))
 498                                                                 goto skip_difference;
 499                                                 s = strcat(s, " ", argv(i));
 500 :skip_difference
 501                                         }
 502                                         if(substring(s, 0, 1) == " ")
 503                                                 s = substring(s, 1, 99999);
 504                                         rpn_set(s);
 505                                         tokenize_sane(command);
 506                                 } else if(rpncmd == "shuffle") {
 507                                         // s shuffle
 508                                         s = rpn_get();
 509                                         f = tokenize_sane(s);
 510
 511                                         for(i = 0; i < f - 1; ++i) {
 512                                                 // move a random item from i..f-1 to position i
 513                                                 s = "";
 514                                                 f2 = floor(random() * (f - i) + i);
 515                                                 for(j = 0; j < i; ++j)
 516                                                         s = strcat(s, " ", argv(j));
 517                                                 s = strcat(s, " ", argv(f2));
 518                                                 for(j = i; j < f; ++j)
 519                                                         if(j != f2)
 520                                                                 s = strcat(s, " ", argv(j));
 521                                                 f = tokenize_sane(s);
 522                                         }
 523
 524                                         if(substring(s, 0, 1) == " ")
 525                                                 s = substring(s, 1, 99999);
 526                                         rpn_set(s);
 527                                         tokenize_sane(command);
 528                                         } else if(rpncmd == "fexists_assert") {
 529                                         s = rpn_pop();
 530                                         if(!rpn_error)
 531                                         {
 532                                                 f = fopen(s, FILE_READ);
 533                                                 if(f != -1)
 534                                                         fclose(f);
 535                                                 else {
 536                                                         print("rpn: ERROR: ", s, " does not exist!\n");
 537                                                         rpn_error = TRUE;
 538                                                 }
 539                                         }
 540                                 } else {
 541                                         rpn_push(cvar_string(rpncmd));
 542                                 }
 543                                 if(rpn_error)
 544                                         break;
 545                         }
 546                         while(rpn_sp > 0)
 547                         {
 548                                 s = rpn_pop();
 549                                 print("rpn: still on stack: ", s, "\n");
 550                         }
 551                         return TRUE;
 552                 }
 553 #ifdef MENUQC
 554         } else if(argv(0) == "cp") {
 555                 if(argc >= 2)
 556                 {
 557                         s = argv(1);
 558                         for(i = 2; i < argc; ++i)
 559                                 s = strcat(s, " ", argv(i));
 560                         centerprint(unescape(s));
 561                 }
 562                 return TRUE;
 563 #endif
 564         }
 565
 566         return FALSE;
 567 }