data/qcsrc/client/sbar.qc

   1
   2 float last_weapon;
   3 float weapontime;
   4
   5 float sb_lines; // still don't know what to do with that NOTE: check dp's sbar.c to see what that should be
   6
   7 vector sbar;
   8 float sbar_alpha_fg;
   9 float sbar_hudselector;
  10
  11 float ps_primary, ps_secondary;
  12 float ts_primary, ts_secondary;
  13
  14 void CSQC_kh_hud();
  15 void CSQC_ctf_hud();
  16 void MapVote_Draw();
  17 void Sbar_FinaleOverlay()
  18 {
  19         /*vector pos;
  20         pos_x = (vid_conwidth - 1)/2;
  21         pos_y = 16;
  22         pos_z = 0;*/
  23
  24         //drawpic(pos, "gfx/finale", '0 0 0', '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
  25
  26         //drawstring(pos, "END", sbar_fontsize, '1 1 1', 1, DRAWFLAG_NORMAL);
  27         MapVote_Draw();
  28 }
  29
  30 float weaponspace[10];
  31 float weapon_first, weapon_last;
  32 void Sbar_DrawWeapon_Clear()
  33 {
  34         float idx;
  35         weapon_first = -2;
  36         weapon_last = -1;
  37         for(idx = 0; idx < 10; ++idx)
  38                 weaponspace[idx] = 0;
  39         for(idx = 0; idx <= 23; ++idx)
  40         {
  41                 if(weaponimpulse[idx] >= 0)
  42                 {
  43                         if(weapon_first < 0)
  44                                 weapon_first = idx;
  45                         weapon_last = idx;
  46                 }
  47         }
  48 }
  49 void Sbar_DrawWeapon(float nr, float fade, float active)
  50 {
  51         vector pos, vsize, color;
  52         float value, idx, imp, sp;
  53
  54         imp = weaponimpulse[nr];
  55         if(imp == 0)
  56                 idx = 9;
  57         else
  58                 idx = imp - 1;
  59
  60         value = (active) ? 1 : 0.6;
  61         color_x = color_y = color_z = value;
  62
  63         if(sbar_hudselector == 1)
  64         {
  65                 // width = 300, height = 100
  66                 const float w_width = 32, w_height = 12, w_space = 2, font_size = 8;
  67
  68                 sp = weaponspace[idx] + 1;
  69                 weaponspace[idx] = sp;
  70
  71                 pos_x = (vid_conwidth - w_width * 9) * 0.5 + w_width * idx;
  72                 pos_y = (vid_conheight - w_height * sp);
  73                 pos_z = 0;
  74                 vsize_x = w_width;
  75                 vsize_y = w_height;
  76                 vsize_z = 0;
  77                 drawpic(pos, strcat("gfx/inv_weapon", ftos(nr)), vsize, color, value * fade * sbar_alpha_fg, 0);
  78                 pos_x += w_space;
  79                 pos_y += w_space;
  80                 vsize_x = font_size;
  81                 vsize_y = font_size;
  82                 vsize_z = 0;
  83                 drawstring(pos, ftos(imp), vsize, '1 1 0', sbar_alpha_fg, 0);
  84         }
  85         else
  86         {
  87                 // width = 300, height = 100
  88                 const float w2_width = 300, w2_height = 100, w2_space = 10;
  89                 const float w2_scale = 0.4;
  90
  91                 float f;
  92                 f = 9 / (weapon_last + 1 - weapon_first);
  93
  94                 pos_x = vid_conwidth - (w2_width + w2_space) * w2_scale * f;
  95                 pos_y = (w2_height + w2_space) * w2_scale * nr * f + w2_space;
  96                 pos_z = 0;
  97                 vsize_x = w2_width * w2_scale * f;
  98                 vsize_y = w2_height * w2_scale * f;
  99                 vsize_z = 0;
 100
 101                 drawpic(pos, strcat("gfx/inv_weapon", ftos(nr)), vsize, color, value * fade * sbar_alpha_fg, 0);
 102         }
 103 }
 104 void Sbar_DrawXNum (vector pos, float num, float digits, float lettersize, vector rgb, float a, float dflags)
 105 {
 106         float l, i;
 107         string str, tmp;
 108         float minus;
 109         vector vsize;
 110
 111         vsize_x = vsize_y = lettersize;
 112         vsize_z = 0;
 113
 114         if(num < 0)
 115         {
 116                 minus = true;
 117                 num = -num;
 118                 pos_x -= lettersize;
 119         } else
 120                 minus = false;
 121
 122         if(digits < 0)
 123         {
 124                 tmp = ftos(num);
 125                 digits = -digits;
 126                 str = strcat(substring("0000000000", 0, digits - strlen(tmp)), tmp);
 127         } else
 128                 str = ftos(num);
 129
 130         l = strlen(str);
 131
 132         if(l > digits)
 133         {
 134                 str = substring(str, l-digits, 999);
 135                 l = strlen(str);
 136         } else if(l < digits)
 137                 pos_x += (digits-l) * lettersize;
 138
 139         if(minus)
 140         {
 141                 drawpic(sbar + pos, "gfx/num_minus", vsize, rgb, a * sbar_alpha_fg, dflags);
 142                 pos_x += lettersize;
 143         }
 144
 145         for(i = 0; i < l; ++i)
 146         {
 147                 drawpic(sbar + pos, strcat("gfx/num_", substring(str, i, 1)), vsize, rgb, a * sbar_alpha_fg, dflags);
 148                 pos_x += lettersize;
 149         }
 150 }
 151
 152 void Cmd_Sbar_SetFields(float argc);
 153 void Sbar_InitScores()
 154 {
 155         float i, f;
 156
 157         ps_primary = ps_secondary = ts_primary = ts_secondary = -1;
 158         for(i = 0; i < MAX_SCORE; ++i)
 159         {
 160                 f = (scores_flags[i] & SFL_SORT_PRIO_MASK);
 161                 if(f == SFL_SORT_PRIO_PRIMARY)
 162                         ps_primary = i;
 163                 if(f == SFL_SORT_PRIO_SECONDARY)
 164                         ps_secondary = i;
 165         }
 166         if(ps_secondary == -1)
 167                 ps_secondary = ps_primary;
 168
 169         for(i = 0; i < MAX_TEAMSCORE; ++i)
 170         {
 171                 f = (teamscores_flags[i] & SFL_SORT_PRIO_MASK);
 172                 if(f == SFL_SORT_PRIO_PRIMARY)
 173                         ts_primary = i;
 174                 if(f == SFL_SORT_PRIO_SECONDARY)
 175                         ts_secondary = i;
 176         }
 177         if(ts_secondary == -1)
 178                 ts_secondary = ts_primary;
 179
 180         Cmd_Sbar_SetFields(0);
 181 }
 182
 183 void Sbar_UpdatePlayerPos(entity pl);
 184 float SetTeam(entity pl, float Team);
 185 //float lastpnum;
 186 void Sbar_UpdatePlayerTeams()
 187 {
 188         float Team;
 189         entity pl, tmp;
 190         float num;
 191
 192         num = 0;
 193         for(pl = players.sort_next; pl; pl = pl.sort_next)
 194         {
 195                 num += 1;
 196                 Team = GetPlayerColor(pl.sv_entnum);
 197                 if(SetTeam(pl, Team))
 198                 {
 199                         tmp = pl.sort_prev;
 200                         Sbar_UpdatePlayerPos(pl);
 201                         if(tmp)
 202                                 pl = tmp;
 203                         else
 204                                 pl = players.sort_next;
 205                 }
 206         }
 207         /*
 208         if(num != lastpnum)
 209                 print(strcat("PNUM: ", ftos(num), "\n"));
 210         lastpnum = num;
 211         */
 212 }
 213
 214 float Sbar_ComparePlayerScores(entity left, entity right)
 215 {
 216         float vl, vr;
 217         vl = GetPlayerColor(left.sv_entnum);
 218         vr = GetPlayerColor(right.sv_entnum);
 219
 220         if(!left.gotscores)
 221                 vl = COLOR_SPECTATOR;
 222         if(!right.gotscores)
 223                 vr = COLOR_SPECTATOR;
 224
 225         if(vl > vr)
 226                 return true;
 227         if(vl < vr)
 228                 return false;
 229
 230         if(vl == COLOR_SPECTATOR)
 231         {
 232                 // FIRST the one with scores (spectators), THEN the ones without (downloaders)
 233                 // no other sorting
 234                 if(!left.gotscores && right.gotscores)
 235                         return true;
 236                 return false;
 237         }
 238
 239         vl = left.scores[ps_primary];
 240         vr = right.scores[ps_primary];
 241         if(scores_flags[ps_primary] & SFL_ZERO_IS_WORST)
 242         {
 243                 if(vl == 0 && vr != 0)
 244                         return 1;
 245                 if(vl != 0 && vr == 0)
 246                         return 0;
 247         }
 248         if(vl > vr)
 249                 return IS_INCREASING(scores_flags[ps_primary]);
 250         if(vl < vr)
 251                 return IS_DECREASING(scores_flags[ps_primary]);
 252
 253         vl = left.scores[ps_secondary];
 254         vr = right.scores[ps_secondary];
 255         if(scores_flags[ps_secondary] & SFL_ZERO_IS_WORST)
 256         {
 257                 if(vl == 0 && vr != 0)
 258                         return 1;
 259                 if(vl != 0 && vr == 0)
 260                         return 0;
 261         }
 262         if(vl > vr)
 263                 return IS_INCREASING(scores_flags[ps_secondary]);
 264         if(vl < vr)
 265                 return IS_DECREASING(scores_flags[ps_secondary]);
 266
 267         return false;
 268 }
 269
 270 void Sbar_UpdatePlayerPos(entity player)
 271 {
 272         for(other = player.sort_next; other && Sbar_ComparePlayerScores(player, other); other = player.sort_next)
 273         {
 274                 SORT_SWAP(player, other);
 275         }
 276         for(other = player.sort_prev; other != players && Sbar_ComparePlayerScores(other, player); other = player.sort_prev)
 277         {
 278                 SORT_SWAP(other, player);
 279         }
 280 }
 281
 282 float Sbar_CompareTeamScores(entity left, entity right)
 283 {
 284         float vl, vr;
 285
 286         if(left.team == COLOR_SPECTATOR)
 287                 return 1;
 288         if(right.team == COLOR_SPECTATOR)
 289                 return 0;
 290
 291         vl = left.teamscores[ts_primary];
 292         vr = right.teamscores[ts_primary];
 293         if(vl > vr)
 294                 return IS_INCREASING(teamscores_flags[ts_primary]);
 295         if(vl < vr)
 296                 return IS_DECREASING(teamscores_flags[ts_primary]);
 297
 298         vl = left.teamscores[ts_secondary];
 299         vr = right.teamscores[ts_secondary];
 300         if(vl > vr)
 301                 return IS_INCREASING(teamscores_flags[ts_secondary]);
 302         if(vl < vr)
 303                 return IS_DECREASING(teamscores_flags[ts_secondary]);
 304
 305         return false;
 306 }
 307
 308 void Sbar_UpdateTeamPos(entity Team)
 309 {
 310         for(other = Team.sort_next; other && Sbar_CompareTeamScores(Team, other); other = Team.sort_next)
 311         {
 312                 SORT_SWAP(Team, other);
 313         }
 314         for(other = Team.sort_prev; other != teams && Sbar_CompareTeamScores(other, Team); other = Team.sort_prev)
 315         {
 316                 SORT_SWAP(other, Team);
 317         }
 318 }
 319
 320 void Cmd_Sbar_Help(float argc)
 321 {
 322         print("You can modify the scoreboard using the\n");
 323         print("^3|---------------------------------------------------------------|\n");
 324         print("^1 TO BE DONE\n");
 325         print("Usage:\n");
 326         print("^2sbar_columns_set default\n");
 327         print("^2sbar_columns_set ^7filed1 field2 ...\n");
 328         print("The following field names are recognized (case INsensitive):\n");
 329         print("You can use a ^3|^7 to start the right-aligned fields.\n");
 330
 331         print("^3name^7 or ^3nick^7             Name of a player\n");
 332         print("^3ping^7                     Ping time\n\n");
 333         print("^3kd^7 or ^3kdr^7 or ^3kdratio^7 or ^3k/d\n");
 334         print("                         The kill-death ratio\n");
 335
 336         print("Before a field you can put a + or - sign, then a comma separated list\n");
 337         print("of game types, then a slash, to make the field show up only in these\n");
 338         print("or in all but these game types.\n");
 339
 340         print("The special game type names 'teams' and 'noteams' can be used to\n");
 341         print("include/exclude ALL teams/noteams game modes.\n");
 342
 343         local float i;
 344         print("Additional columns:\n");
 345         for(i = 0; i < MAX_SCORE; ++i)
 346         {
 347                 if(scores_label[i] != "")
 348                         print(strcat(scores_label[i], "\n"));
 349         }
 350 }
 351
 352 #define MIN_NAMELEN 24
 353 #define MAX_NAMELEN 24
 354
 355 string Sbar_DefaultColumnLayout()
 356 {
 357         return strcat( // fteqcc sucks
 358                 "ping pl name | ",
 359                 "+noteams/kills +noteams/deaths +noteams/suicides -noteams,tdm/frags ", // tdm already has this in "score"
 360                 "+kh/caps +kh/pushes +kh/destroyed ",
 361                 "+ctf/caps +ctf/pickups +ctf/fckills +ctf/returns ",
 362                 "-lms/score");
 363 }
 364
 365 void Cmd_Sbar_SetFields(float argc)
 366 {
 367         float i, j, slash;
 368         string str, pattern, subpattern, subpattern2;
 369         float digit;
 370         float have_name, have_primary, have_secondary, have_separator;
 371         float missing;
 372
 373         // TODO: re enable with gametype dependant cvars?
 374         if(argc < 2) // no arguments provided
 375                 argc = tokenizebyseparator(strcat("x ", cvar_string("sbar_columns")), " ");
 376
 377         if(argc < 2)
 378                 argc = tokenizebyseparator(strcat("x ", Sbar_DefaultColumnLayout()), " ");
 379
 380         if(argc == 2)
 381         {
 382                 if(argv(1) == "default")
 383                         argc = tokenizebyseparator(strcat("x ", Sbar_DefaultColumnLayout()), " ");
 384                 else if(argv(1) == "all")
 385                 {
 386                         string s;
 387                         s = "ping pl color name |";
 388                         for(i = 0; i < MAX_SCORE; ++i)
 389                         {
 390                                 if(i != ps_primary)
 391                                 if(i != ps_secondary)
 392                                 if(scores_label[i] != "")
 393                                         s = strcat(s, " ", scores_label[i]);
 394                         }
 395                         if(ps_secondary != ps_primary)
 396                                 s = strcat(s, " ", scores_label[ps_secondary]);
 397                         s = strcat(s, " ", scores_label[ps_primary]);
 398                         argc = tokenizebyseparator(strcat("x ", s), " ");
 399                 }
 400         }
 401
 402
 403         sbar_num_fields = 0;
 404
 405         drawfont = sbar_font;
 406         digit = stringwidth("0123456789", FALSE) / 10;
 407
 408         subpattern = strcat(",", GametypeNameFromType(gametype), ",");
 409         if(teamplay)
 410                 subpattern2 = ",teams,";
 411         else
 412                 subpattern2 = ",noteams,";
 413
 414         for(i = 0; i < argc - 1; ++i)
 415         {
 416                 str = argv(i+1);
 417
 418                 slash = strstrofs(str, "/", 0);
 419                 if(slash >= 0)
 420                 {
 421                         pattern = substring(str, 0, slash);
 422                         str = substring(str, slash + 1, strlen(str) - (slash + 1));
 423
 424                         if(substring(pattern, 0, 1) == "-")
 425                         {
 426                                 pattern = substring(pattern, 1, strlen(pattern) - 1);
 427                                 if(strstrofs(strcat(",", pattern, ","), subpattern, 0) >= 0)
 428                                         continue;
 429                                 if(strstrofs(strcat(",", pattern, ","), subpattern2, 0) >= 0)
 430                                         continue;
 431                         }
 432                         else
 433                         {
 434                                 if(substring(pattern, 0, 1) == "+")
 435                                         pattern = substring(pattern, 1, strlen(pattern) - 1);
 436                                 if(strstrofs(strcat(",", pattern, ","), subpattern, 0) < 0)
 437                                 if(strstrofs(strcat(",", pattern, ","), subpattern2, 0) < 0)
 438                                         continue;
 439                         }
 440                 }
 441
 442                 strunzone(sbar_title[sbar_num_fields]);
 443                 sbar_title[sbar_num_fields] = strzone(str);
 444                 sbar_size[sbar_num_fields] = stringwidth(str, FALSE);
 445                 str = strtolower(str);
 446
 447                 if(str == "ping") {
 448                         sbar_field[sbar_num_fields] = SP_PING;
 449                 } else if(str == "pl") {
 450                         sbar_field[sbar_num_fields] = SP_PL;
 451                 } else if(str == "kd" || str == "kdr" || str == "kdratio" || str == "k/d") {
 452                         sbar_field[sbar_num_fields] = SP_KDRATIO;
 453                 } else if(str == "name" || str == "nick") {
 454                         sbar_field[sbar_num_fields] = SP_NAME;
 455                         sbar_size[sbar_num_fields] = MIN_NAMELEN; // minimum size? any use?
 456                         have_name = 1;
 457                 } else if(str == "|") {
 458                         sbar_field[sbar_num_fields] = SP_SEPARATOR;
 459                         have_separator = 1;
 460                 } else {
 461                         for(j = 0; j < MAX_SCORE; ++j)
 462                                 if(str == strtolower(scores_label[j]))
 463                                         goto found; // sorry, but otherwise fteqcc -O3 miscompiles this and warns about "unreachable code"
 464 :notfound
 465                         if(str == "frags")
 466                         {
 467                                 j = SP_FRAGS;
 468                         }
 469                         else
 470                         {
 471                                 print(strcat("^1Error:^7 Unknown score field: '", str, "'\n"));
 472                                 continue;
 473                         }
 474 :found
 475                         sbar_field[sbar_num_fields] = j;
 476                         if(j == ps_primary)
 477                                 have_primary = 1;
 478                         if(j == ps_secondary)
 479                                 have_secondary = 1;
 480                 }
 481                 ++sbar_num_fields;
 482                 if(sbar_num_fields >= MAX_SBAR_FIELDS)
 483                         break;
 484         }
 485
 486         if(scores_flags[ps_primary] & SFL_ALLOW_HIDE)
 487                 have_primary = 1;
 488         if(scores_flags[ps_secondary] & SFL_ALLOW_HIDE)
 489                 have_secondary = 1;
 490         if(ps_primary == ps_secondary)
 491                 have_secondary = 1;
 492         missing = !have_primary + !have_secondary + !have_separator + !have_name;
 493
 494         if(sbar_num_fields+missing < MAX_SBAR_FIELDS)
 495         {
 496                 if(!have_name)
 497                 {
 498                         strunzone(sbar_title[sbar_num_fields]);
 499                         for(i = sbar_num_fields; i > 0; --i)
 500                         {
 501                                 sbar_title[i] = sbar_title[i-1];
 502                                 sbar_size[i] = sbar_size[i-1];
 503                                 sbar_field[i] = sbar_field[i-1];
 504                         }
 505                         sbar_title[0] = strzone("name");
 506                         sbar_field[0] = SP_NAME;
 507                         sbar_size[0] = MIN_NAMELEN; // minimum size? any use?
 508                         ++sbar_num_fields;
 509                         print("fixed missing field 'name'\n");
 510
 511                         if(!have_separator)
 512                         {
 513                                 strunzone(sbar_title[sbar_num_fields]);
 514                                 for(i = sbar_num_fields; i > 1; --i)
 515                                 {
 516                                         sbar_title[i] = sbar_title[i-1];
 517                                         sbar_size[i] = sbar_size[i-1];
 518                                         sbar_field[i] = sbar_field[i-1];
 519                                 }
 520                                 sbar_title[1] = strzone("|");
 521                                 sbar_field[1] = SP_SEPARATOR;
 522                                 sbar_size[1] = stringwidth("|", FALSE);
 523                                 ++sbar_num_fields;
 524                                 print("fixed missing field '|'\n");
 525                         }
 526                 }
 527                 else if(!have_separator)
 528                 {
 529                         strunzone(sbar_title[sbar_num_fields]);
 530                         sbar_title[sbar_num_fields] = strzone("|");
 531                         sbar_size[sbar_num_fields] = stringwidth("|", FALSE);
 532                         sbar_field[sbar_num_fields] = SP_SEPARATOR;
 533                         ++sbar_num_fields;
 534                         print("fixed missing field '|'\n");
 535                 }
 536
 537                 if(!have_secondary)
 538                 {
 539                         strunzone(sbar_title[sbar_num_fields]);
 540                         sbar_title[sbar_num_fields] = strzone(scores_label[ps_secondary]);
 541                         sbar_size[sbar_num_fields] = stringwidth(sbar_title[sbar_num_fields], FALSE);
 542                         sbar_field[sbar_num_fields] = ps_secondary;
 543                         ++sbar_num_fields;
 544                         print("fixed missing field '", scores_label[ps_secondary], "'\n");
 545                 }
 546
 547                 if(!have_primary)
 548                 {
 549                         strunzone(sbar_title[sbar_num_fields]);
 550                         sbar_title[sbar_num_fields] = strzone(scores_label[ps_primary]);
 551                         sbar_size[sbar_num_fields] = stringwidth(sbar_title[sbar_num_fields], FALSE);
 552                         sbar_field[sbar_num_fields] = ps_primary;
 553                         ++sbar_num_fields;
 554                         print("fixed missing field '", scores_label[ps_primary], "'\n");
 555                 }
 556         }
 557
 558         sbar_field[sbar_num_fields] = SP_END;
 559 }
 560
 561 // MOVEUP::
 562 vector sbar_field_rgb;
 563 string sbar_field_icon0;
 564 string sbar_field_icon1;
 565 string sbar_field_icon2;
 566 vector sbar_field_icon0_rgb;
 567 vector sbar_field_icon1_rgb;
 568 vector sbar_field_icon2_rgb;
 569 float sbar_field_icon0_alpha;
 570 float sbar_field_icon1_alpha;
 571 float sbar_field_icon2_alpha;
 572 string Sbar_GetField(entity pl, float field)
 573 {
 574         float tmp, num, denom, f;
 575         string str;
 576         sbar_field_rgb = '1 1 1';
 577         sbar_field_icon0 = "";
 578         sbar_field_icon1 = "";
 579         sbar_field_icon2 = "";
 580         sbar_field_icon0_rgb = '1 1 1';
 581         sbar_field_icon1_rgb = '1 1 1';
 582         sbar_field_icon2_rgb = '1 1 1';
 583         sbar_field_icon0_alpha = 1;
 584         sbar_field_icon1_alpha = 1;
 585         sbar_field_icon2_alpha = 1;
 586         switch(field)
 587         {
 588                 case SP_PING:
 589                         if not(pl.gotscores)
 590                                 return "\x8D\x8D\x8D"; // >>> sign
 591                         str = getplayerkey(pl.sv_entnum, "ping");
 592                         if(str == "0")
 593                                 return "N/A";
 594                         tmp = max(0, min(220, stof(str)-80)) / 220;
 595                         sbar_field_rgb = '1 1 1' - '0 1 1'*tmp;
 596                         return str;
 597
 598                 case SP_PL:
 599                         if not(pl.gotscores)
 600                                 return "N/A";
 601                         str = getplayerkey(pl.sv_entnum, "pl");
 602                         if(str == "0")
 603                                 return "";
 604                         tmp = bound(0, stof(str), 20) / 20; // 20% is REALLY BAD pl
 605                         sbar_field_rgb = '1 0.5 0.5' - '0 0.5 0.5'*tmp;
 606                         return str;
 607
 608                 case SP_NAME:
 609                         if(ready_waiting && pl.ready)
 610                         {
 611                                 sbar_field_icon0 = "gfx/sb_player_ready";
 612                         }
 613                         else if(!teamplay)
 614                         {
 615                                 f = stof(getplayerkey(pl.sv_entnum, "colors"));
 616                                 {
 617                                         sbar_field_icon0 = "gfx/sb_playercolor_base";
 618                                         sbar_field_icon1 = "gfx/sb_playercolor_shirt";
 619                                         sbar_field_icon1_rgb = colormapPaletteColor(floor(f / 16), 0);
 620                                         sbar_field_icon2 = "gfx/sb_playercolor_pants";
 621                                         sbar_field_icon2_rgb = colormapPaletteColor(mod(f, 16), 1);
 622                                 }
 623                         }
 624                         return GetPlayerName(pl.sv_entnum);
 625
 626                 case SP_FRAGS:
 627                         f = pl.(scores[SP_KILLS]);
 628                         f -= pl.(scores[SP_SUICIDES]);
 629                         return ftos(f);
 630
 631                 case SP_KDRATIO:
 632                         num = pl.(scores[SP_KILLS]);
 633                         denom = pl.(scores[SP_DEATHS]);
 634
 635                         if(denom == 0) {
 636                                 sbar_field_rgb = '0 1 0';
 637                                 str = ftos(num);
 638                         } else if(num <= 0) {
 639                                 sbar_field_rgb = '1 0 0';
 640                                 str = ftos(num/denom);
 641                         } else
 642                                 str = ftos(num/denom);
 643
 644                         tmp = strstrofs(str, ".", 0);
 645                         if(tmp > 0)
 646                                 str = substring(str, 0, tmp+2);
 647                         return str;
 648
 649                 default:
 650                         tmp = pl.(scores[field]);
 651                         f = scores_flags[field];
 652                         if(field == ps_primary)
 653                                 sbar_field_rgb = '1 1 0';
 654                         else if(field == ps_secondary)
 655                                 sbar_field_rgb = '0 1 1';
 656                         else
 657                                 sbar_field_rgb = '1 1 1';
 658                         return ScoreString(f, tmp);
 659         }
 660         //return "error";
 661 }
 662
 663 float xmin, xmax, ymin, ymax, sbwidth;
 664 float sbar_fixscoreboardcolumnwidth_len;
 665 float sbar_fixscoreboardcolumnwidth_iconlen;
 666 float sbar_fixscoreboardcolumnwidth_marginlen;
 667
 668 float stringwidth_colors(string s)
 669 {
 670         return stringwidth(s, TRUE);
 671 }
 672
 673 float stringwidth_nocolors(string s)
 674 {
 675         return stringwidth(s, FALSE);
 676 }
 677
 678 string Sbar_FixScoreboardColumnWidth(float i, string str)
 679 {
 680         float field, maxsize, j, f;
 681         vector sz;
 682         field = sbar_field[i];
 683
 684         if(field == SP_NAME) // name gets all remaining space
 685         {
 686                 maxsize = (xmax - xmin) / sbar_fontsize_x;
 687                 for(j = 0; j < sbar_num_fields; ++j) if(j != i) if(sbar_field[j] != SP_SEPARATOR)
 688                         maxsize -= sbar_size[j] + 1;
 689                 maxsize += 1;
 690                 str = textShortenToWidth(str, maxsize, stringwidth_colors);
 691                 sbar_fixscoreboardcolumnwidth_len = stringwidth(str, TRUE);
 692         }
 693         else
 694                 sbar_fixscoreboardcolumnwidth_len = stringwidth(str, FALSE);
 695
 696         sbar_fixscoreboardcolumnwidth_iconlen = 0;
 697
 698         if(sbar_field_icon0 != "")
 699         {
 700                 sz = drawgetimagesize(sbar_field_icon0);
 701                 f = sz_x / sz_y;
 702                 if(sbar_fixscoreboardcolumnwidth_iconlen < f)
 703                         sbar_fixscoreboardcolumnwidth_iconlen = f;
 704         }
 705
 706         if(sbar_field_icon1 != "")
 707         {
 708                 sz = drawgetimagesize(sbar_field_icon1);
 709                 f = sz_x / sz_y;
 710                 if(sbar_fixscoreboardcolumnwidth_iconlen < f)
 711                         sbar_fixscoreboardcolumnwidth_iconlen = f;
 712         }
 713
 714         if(sbar_field_icon2 != "")
 715         {
 716                 sz = drawgetimagesize(sbar_field_icon2);
 717                 f = sz_x / sz_y;
 718                 if(sbar_fixscoreboardcolumnwidth_iconlen < f)
 719                         sbar_fixscoreboardcolumnwidth_iconlen = f;
 720         }
 721
 722         sbar_fixscoreboardcolumnwidth_iconlen *= sbar_fontsize_y / sbar_fontsize_x; // fix icon aspect
 723
 724         if(sbar_fixscoreboardcolumnwidth_iconlen != 0 && sbar_fixscoreboardcolumnwidth_len != 0)
 725                 sbar_fixscoreboardcolumnwidth_marginlen = stringwidth(" ", FALSE);
 726         else
 727                 sbar_fixscoreboardcolumnwidth_marginlen = 0;
 728
 729         f = sbar_fixscoreboardcolumnwidth_len + sbar_fixscoreboardcolumnwidth_marginlen + sbar_fixscoreboardcolumnwidth_iconlen;
 730         if(sbar_size[i] < f)
 731                 sbar_size[i] = f;
 732
 733         return str;
 734 }
 735
 736 void Sbar_PrintScoreboardItem(vector pos, entity pl, float is_self)
 737 {
 738         vector tmp;
 739         string str;
 740         float i, field;
 741         float is_spec;
 742         is_spec = (GetPlayerColor(pl.sv_entnum) == COLOR_SPECTATOR);
 743
 744         // Layout:
 745         tmp_z = 0;
 746         if(is_self)
 747         {
 748                 tmp_x = sbwidth;
 749                 tmp_y = sbar_fontsize_y;
 750                 drawfill(pos - '1 1 0', tmp + '2 2 0', '1 1 1', 0.3, DRAWFLAG_NORMAL);
 751         }
 752         tmp_y = 0;
 753
 754         for(i = 0; i < sbar_num_fields; ++i)
 755         {
 756                 field = sbar_field[i];
 757                 if(field == SP_SEPARATOR)
 758                         break;
 759
 760                 if(is_spec && field != SP_NAME && field != SP_PING) {
 761                         pos_x += sbar_fontsize_x*sbar_size[i] + sbar_fontsize_x;
 762                         continue;
 763                 }
 764                 str = Sbar_GetField(pl, field);
 765                 str = Sbar_FixScoreboardColumnWidth(i, str);
 766
 767                 pos_x += sbar_fontsize_x*sbar_size[i] + sbar_fontsize_x;
 768
 769                 if(field == SP_NAME) {
 770                         tmp_x = sbar_fontsize_x*(sbar_size[i] - sbar_fixscoreboardcolumnwidth_iconlen - sbar_fixscoreboardcolumnwidth_marginlen) + sbar_fontsize_x;
 771                         drawcolorcodedstring(pos - tmp, str, sbar_fontsize, 1, DRAWFLAG_NORMAL);
 772                 } else {
 773                         tmp_x = sbar_fixscoreboardcolumnwidth_len*sbar_fontsize_x + sbar_fontsize_x;
 774                         drawstring(pos - tmp, str, sbar_fontsize, sbar_field_rgb, 1, DRAWFLAG_NORMAL);
 775                 }
 776
 777                 tmp_x = sbar_fontsize_x*sbar_size[i] + sbar_fontsize_x;
 778                 if(sbar_field_icon0 != "")
 779                         drawpic(pos - tmp, sbar_field_icon0, '0 1 0' * sbar_fontsize_y + '1 0 0' * sbar_fontsize_x * sbar_fixscoreboardcolumnwidth_iconlen, sbar_field_icon1_rgb, sbar_field_icon0_alpha, 0);
 780                 if(sbar_field_icon1 != "")
 781                         drawpic(pos - tmp, sbar_field_icon1, '0 1 0' * sbar_fontsize_y + '1 0 0' * sbar_fontsize_x * sbar_fixscoreboardcolumnwidth_iconlen, sbar_field_icon1_rgb, sbar_field_icon1_alpha, 0);
 782                 if(sbar_field_icon2 != "")
 783                         drawpic(pos - tmp, sbar_field_icon2, '0 1 0' * sbar_fontsize_y + '1 0 0' * sbar_fontsize_x * sbar_fixscoreboardcolumnwidth_iconlen, sbar_field_icon2_rgb, sbar_field_icon2_alpha, 0);
 784         }
 785
 786         if(sbar_field[i] == SP_SEPARATOR)
 787         {
 788                 pos_x = xmax;
 789                 for(i = sbar_num_fields-1; i > 0; --i)
 790                 {
 791                         field = sbar_field[i];
 792                         if(field == SP_SEPARATOR)
 793                                 break;
 794
 795                         if(is_spec && field != SP_NAME && field != SP_PING) {
 796                                 pos_x -= sbar_fontsize_x*sbar_size[i] + sbar_fontsize_x;
 797                                 continue;
 798                         }
 799
 800                         str = Sbar_GetField(pl, field);
 801                         str = Sbar_FixScoreboardColumnWidth(i, str);
 802
 803                         if(field == SP_NAME) {
 804                                 tmp_x = sbar_fontsize_x*sbar_fixscoreboardcolumnwidth_len; // left or right aligned? let's put it right...
 805                                 drawcolorcodedstring(pos - tmp, str, sbar_fontsize, 1, DRAWFLAG_NORMAL);
 806                         } else {
 807                                 tmp_x = sbar_fontsize_x*sbar_fixscoreboardcolumnwidth_len; //strlen(str);
 808                                 drawstring(pos - tmp, str, sbar_fontsize, sbar_field_rgb, 1, DRAWFLAG_NORMAL);
 809                         }
 810
 811                         tmp_x = sbar_fontsize_x*sbar_size[i];
 812                         if(sbar_field_icon0 != "")
 813                                 drawpic(pos - tmp, sbar_field_icon0, '0 1 0' * sbar_fontsize_y + '1 0 0' * sbar_fontsize_x * sbar_fixscoreboardcolumnwidth_iconlen, sbar_field_icon1_rgb, sbar_field_icon0_alpha, 0);
 814                         if(sbar_field_icon1 != "")
 815                                 drawpic(pos - tmp, sbar_field_icon1, '0 1 0' * sbar_fontsize_y + '1 0 0' * sbar_fontsize_x * sbar_fixscoreboardcolumnwidth_iconlen, sbar_field_icon1_rgb, sbar_field_icon1_alpha, 0);
 816                         if(sbar_field_icon2 != "")
 817                                 drawpic(pos - tmp, sbar_field_icon2, '0 1 0' * sbar_fontsize_y + '1 0 0' * sbar_fontsize_x * sbar_fixscoreboardcolumnwidth_iconlen, sbar_field_icon2_rgb, sbar_field_icon2_alpha, 0);
 818
 819                         pos_x -= sbar_fontsize_x*sbar_size[i] + sbar_fontsize_x;
 820                 }
 821         }
 822 }
 823
 824 float lastpingstime;
 825 float scoreboard_bottom;
 826 void Sbar_DrawScoreboard()
 827 {
 828         //float xmin, ymin, xmax, ymax;
 829         vector rgb, pos, tmp, sbar_save;
 830         entity pl, tm;
 831         float specs, i;
 832         float center_x;
 833
 834         if(time > lastpingstime + 10)
 835         {
 836                 localcmd("pings\n");
 837                 lastpingstime = time;
 838         }
 839
 840         sbwidth = Sbar_GetWidth(6.5 * sbar_fontsize_y);
 841
 842         xmin = 0.5 * (vid_conwidth - sbwidth);
 843         ymin = 45;
 844
 845         xmax = vid_conwidth - xmin;
 846     ymax = vid_conheight - 0.2*vid_conheight;
 847
 848         center_x = xmin + 0.5*sbwidth;
 849
 850         //Sbar_UpdateFields();
 851
 852         // Initializes position
 853         //pos_x = xmin;
 854         pos_y = ymin;
 855         pos_z = 0;
 856
 857         // Heading
 858         drawfont = sbar_bigfont;
 859         pos_x = center_x - stringwidth("Scoreboard", TRUE)*0.5*24;
 860         drawstring(pos, "Scoreboard", '24 24 0', '1 1 1', 1, DRAWFLAG_NORMAL);
 861         pos_x = xmin;
 862         pos_y += 24 + 4;
 863
 864         // Titlebar background:
 865         tmp_x = sbwidth;
 866         tmp_y = sbar_fontsize_y;
 867         drawfill(pos - '1 1 0', tmp + '2 2 0', '0.5 0.5 0.5', 0.5, DRAWFLAG_NORMAL);
 868
 869         drawfont = sbar_font;
 870
 871         for(i = 0; i < sbar_num_fields; ++i)
 872         {
 873                 if(sbar_field[i] == SP_SEPARATOR)
 874                         break;
 875                 drawstring(pos, sbar_title[i], sbar_fontsize, '1 1 1', 1, DRAWFLAG_NORMAL);
 876                 pos_x += sbar_fontsize_x*sbar_size[i] + sbar_fontsize_x;
 877         }
 878
 879         if(sbar_field[i] == SP_SEPARATOR)
 880         {
 881                 pos_x = xmax + sbar_fontsize_x;
 882                 tmp_y = tmp_z = 0;
 883                 for(i = sbar_num_fields-1; i > 0; --i)
 884                 {
 885                         if(sbar_field[i] == SP_SEPARATOR)
 886                                 break;
 887
 888                         pos_x -= sbar_fontsize_x*sbar_size[i] + sbar_fontsize_x;
 889                         /**
 890                          * FTEQCC BUG!
 891                          * Using the following line will mess it all up:
 892                          **
 893                          * tmp_x = sbar_size[i] - strlen(sbar_title[i])*8;
 894                          */
 895                         tmp_x = sbar_fontsize_x*sbar_size[i];
 896                         tmp_x -= stringwidth(sbar_title[i], FALSE)*sbar_fontsize_x;
 897                         drawstring(pos + tmp, sbar_title[i], sbar_fontsize, '1 1 1', 1, DRAWFLAG_NORMAL);
 898                 }
 899         }
 900
 901         pos_x = xmin;
 902         pos_y += 1.5 * sbar_fontsize_y;
 903
 904         sbar_save = sbar;
 905         sbar = '0 0 0';
 906
 907         if(teamplay)
 908         {
 909                 //for(tm = sortedTeams.sort_next; tm; tm = tm.sort_next)
 910                 for(tm = teams.sort_next; tm; tm = tm.sort_next)
 911                 {
 912                         if(!tm.team_size || tm.team == COLOR_SPECTATOR)
 913                                 continue;
 914
 915                         rgb = GetTeamRGB(tm.team);
 916
 917                         pos_x = xmin;
 918
 919                         Sbar_DrawXNum(
 920                                 pos - '6.5 0 0' * sbar_fontsize_y,
 921                                 tm.(teamscores[ts_primary]),
 922                                 4, sbar_fontsize_y * 1.5, rgb, 1, DRAWFLAG_NORMAL);
 923
 924                         if(ts_primary != ts_secondary)
 925                         Sbar_DrawXNum(
 926                                 pos - '4.5 0 0' * sbar_fontsize_y + '0 1.5 0' * sbar_fontsize_y,
 927                                 tm.(teamscores[ts_secondary]),
 928                                 4, sbar_fontsize_y * 1, rgb, 1, DRAWFLAG_NORMAL);
 929
 930                         specs = tm.team_size;
 931
 932                         if(specs < 2)
 933                                 specs = 2;
 934
 935                         tmp_x = sbwidth;
 936                         tmp_y = 1.25 * sbar_fontsize_y * specs;
 937                         drawfill(pos - '1 1 0', tmp + '2 0 0', rgb, 0.2, DRAWFLAG_NORMAL);
 938
 939                         for(pl = players.sort_next; pl; pl = pl.sort_next)
 940                         {
 941                                 if(pl.team != tm.team)
 942                                         continue;
 943                                 Sbar_PrintScoreboardItem(pos, pl, (pl.sv_entnum == player_localentnum - 1));
 944                                 pos_y += 1.25 * sbar_fontsize_y;
 945                                 tmp_y -= 1.25 * sbar_fontsize_y;
 946                         }
 947                         pos_y += tmp_y + 1.5 * sbar_fontsize_y;
 948                 }
 949                 // rgb := tempvector :)
 950                 rgb = pos + '0 1.5 0' * sbar_fontsize_y;
 951                 pos_y += 3 * sbar_fontsize_y;
 952                 specs = 0;
 953                 for(pl = players.sort_next; pl; pl = pl.sort_next)
 954                 {
 955                         if(pl.team != COLOR_SPECTATOR)
 956                                 continue;
 957                         Sbar_PrintScoreboardItem(pos, pl, (pl.sv_entnum == player_localentnum - 1));
 958                         pos += '0 1.25 0' * sbar_fontsize_y;
 959                         ++specs;
 960                 }
 961
 962                 if(specs)
 963                         drawstring(rgb, "Spectators", sbar_fontsize, '1 1 1', 1, 0);
 964         } else {
 965                 pos_x = xmin;
 966                 for(pl = players.sort_next; pl; pl = pl.sort_next)
 967                 {
 968                         if(pl.team == COLOR_SPECTATOR)
 969                                 continue;
 970                         Sbar_PrintScoreboardItem(pos, pl, (pl.sv_entnum == player_localentnum - 1));
 971                         pos_y += 1.25 * sbar_fontsize_y;
 972                         tmp_y -= 1.25 * sbar_fontsize_y;
 973                 }
 974
 975                 // rgb := tempvector :)
 976                 rgb = pos + '0 1.5 0' * sbar_fontsize_y;
 977                 pos_y += 3 * sbar_fontsize_y;
 978                 specs = 0;
 979                 for(pl = players.sort_next; pl; pl = pl.sort_next)
 980                 {
 981                         if(pl.team != COLOR_SPECTATOR)
 982                                 continue;
 983                         Sbar_PrintScoreboardItem(pos, pl, (pl.sv_entnum == player_localentnum - 1));
 984                         pos += '0 1.25 0' * sbar_fontsize_y;
 985                         ++specs;
 986                 }
 987
 988                 if(specs)
 989                         drawstring(rgb, "Spectators", sbar_fontsize, '1 1 1', 1, 0);
 990         }
 991
 992         string str;
 993         float tl, fl;
 994         str = strcat("playing on ^2", shortmapname, "^7");
 995         tl = getstatf(STAT_TIMELIMIT);
 996         fl = getstatf(STAT_FRAGLIMIT);
 997         if(gametype == GAME_LMS)
 998         {
 999                 if(tl > 0)
1000                         str = strcat(str, " for up to ^1", ftos(tl), " minutes^7");
1001         }
1002         else
1003         {
1004                 if(tl > 0)
1005                         str = strcat(str, " for ^1", ftos(tl), " minutes^7");
1006                 if(fl > 0)
1007                 {
1008                         if(tl > 0)
1009                                 str = strcat(str, " or");
1010                         if(teamplay)
1011                         {
1012                                 str = strcat(str, " until ^3", ScoreString(teamscores_flags[ts_primary], fl));
1013                                 if(teamscores_label[ts_primary] == "score")
1014                                         str = strcat(str, " points^7");
1015                                 else if(teamscores_label[ts_primary] == "fastest")
1016                                         str = strcat(str, " is beaten^7");
1017                                 else
1018                                         str = strcat(str, " ", teamscores_label[ts_primary]);
1019                         }
1020                         else
1021                         {
1022                                 str = strcat(str, " until ^3", ScoreString(scores_flags[ps_primary], fl));
1023                                 if(scores_label[ps_primary] == "score")
1024                                         str = strcat(str, " points^7");
1025                                 else if(scores_label[ps_primary] == "fastest")
1026                                         str = strcat(str, " is beaten^7");
1027                                 else
1028                                         str = strcat(str, " ", scores_label[ps_primary]);
1029                         }
1030                 }
1031         }
1032
1033
1034         pos_y += 1.2 * sbar_fontsize_y;
1035         drawcolorcodedstring(pos + '0.5 0 0' * (sbwidth - sbar_fontsize_x * stringwidth(str, TRUE)), str, sbar_fontsize, 0.8, 0);
1036
1037         sbar = sbar_save;
1038         scoreboard_bottom = pos_y + 2 * sbar_fontsize_y;
1039 }
1040
1041 string MakeRaceString(float cp, float mytime, float histime, float lapdelta, string hisname)
1042 {
1043         string col;
1044         string timestr;
1045         string cpname;
1046         string lapstr;
1047         lapstr = "";
1048
1049         if(histime == 0) // goal hit
1050         {
1051                 if(mytime > 0)
1052                 {
1053                         timestr = strcat("+", ftos_decimals(+mytime, 1));
1054                         col = "^1";
1055                 }
1056                 else if(mytime == 0)
1057                 {
1058                         timestr = "+0.0";
1059                         col = "^3";
1060                 }
1061                 else
1062                 {
1063                         timestr = strcat("-", ftos_decimals(-mytime, 1));
1064                         col = "^2";
1065                 }
1066
1067                 if(lapdelta > 0)
1068                 {
1069                         lapstr = strcat(" (-", ftos(lapdelta), "L)");
1070                         col = "^2";
1071                 }
1072                 else if(lapdelta < 0)
1073                 {
1074                         lapstr = strcat(" (+", ftos(-lapdelta), "L)");
1075                         col = "^1";
1076                 }
1077         }
1078         else if(histime > 0) // anticipation
1079         {
1080                 if(mytime >= histime)
1081                         timestr = strcat("+", ftos_decimals(mytime - histime, 1));
1082                 else
1083                         timestr = mmsss(histime * 10);
1084                 col = "^3";
1085         }
1086         else
1087                 col = "^7";
1088
1089         if(cp)
1090                 cpname = strcat("Intermediate ", ftos(cp));
1091         else
1092                 cpname = "Finish line";
1093
1094         if(histime < 0)
1095                 return strcat(col, cpname);
1096         else if(hisname == "")
1097                 return strcat(col, cpname, " (", timestr, ")");
1098         else
1099                 return strcat(col, cpname, " (", timestr, " ", strcat(hisname, col, lapstr), ")");
1100 }
1101
1102 void dummyfunction(float a1, float a2, float a3, float a4, float a5, float a6, float a7, float a8)
1103 {
1104 }
1105
1106 void Sbar_Score(float margin)
1107 {
1108         float timelimit, minutes, seconds, timeleft, minutesLeft, secondsLeft, distribution, myplace, score;
1109         vector sbar_save, place, timer_color;
1110         entity tm, pl, me;
1111         sbar_save = sbar;
1112
1113         myteam = GetPlayerColor(player_localentnum - 1);
1114
1115         sbar_y = vid_conheight - (32+12);
1116         sbar_x -= margin;
1117
1118         place = '-48 -12 0';
1119         if(teamplay)
1120         {
1121                 // Layout:
1122                 //
1123                 //   team1 team3 team4
1124                 //
1125                 //         TEAM2
1126                 //for(i = 0; i < 4; ++i)
1127                 for(tm = teams.sort_next; tm; tm = tm.sort_next)
1128                 {
1129                         if(tm.team == COLOR_SPECTATOR || !tm.team_size) // no players? don't display
1130                                 continue;
1131                         // -32*4 = -128
1132                         score = tm.(teamscores[ts_primary]);
1133                         if(tm.team == myteam)
1134                                 Sbar_DrawXNum('-128 0 0', score, 4, 32, GetTeamRGB(tm.team), 1, DRAWFLAG_NORMAL);
1135                         else
1136                         {
1137                                 Sbar_DrawXNum(place, score, 4, 12, GetTeamRGB(tm.team), 1, DRAWFLAG_NORMAL);
1138                                 place_x -= 4*12;
1139                         }
1140                 }
1141         } else {
1142                 // me vector := [team/connected frags id]
1143                 myplace = 0;
1144                 for(me = players.sort_next; me; me = me.sort_next)
1145                 {
1146                         if(me.team != COLOR_SPECTATOR)
1147                                 ++myplace;
1148                         if(me.sv_entnum == player_localentnum - 1)
1149                                 break;
1150                 }
1151                 pl = players;
1152                 if(pl == me)
1153                         pl = pl.sort_next;
1154
1155                 if(pl) {
1156                         distribution = me.(scores[ps_primary]) - pl.(scores[ps_primary]);
1157                 } else
1158                         distribution = 0;
1159
1160                 if(myplace == 1)
1161                         Sbar_DrawXNum('-36 -12 0', myplace, 3, 12, '1 1 1', 1, DRAWFLAG_NORMAL);
1162                 else if(myplace == 2)
1163                         Sbar_DrawXNum('-36 -12 0', myplace, 3, 12, '1 1 0', 1, DRAWFLAG_NORMAL);
1164                 else
1165                         Sbar_DrawXNum('-36 -12 0', myplace, 3, 12, '1 0 0', 1, DRAWFLAG_NORMAL);
1166
1167                 score = me.(scores[ps_primary]);
1168                 if(distribution >= 0)
1169                 {
1170                         Sbar_DrawXNum('-84 -12 0', distribution, 4, 12, ' 1 1 1', 1, DRAWFLAG_NORMAL);
1171                         Sbar_DrawXNum('-128 0 0', score, 4, 32, '1 1 1', 1, DRAWFLAG_NORMAL);
1172                 } else if(distribution >= -5)
1173                 {
1174                         Sbar_DrawXNum('-84 -12 0', distribution, 4, 12, ' 1 1 0', 1, DRAWFLAG_NORMAL);
1175                         Sbar_DrawXNum('-128 0 0', score, 4, 32, '1 1 0', 1, DRAWFLAG_NORMAL);
1176                 } else {
1177                         Sbar_DrawXNum('-84 -12 0', distribution, 4, 12, ' 1 0 0', 1, DRAWFLAG_NORMAL);
1178                         Sbar_DrawXNum('-128 0 0', score, 4, 32, '1 0 0', 1, DRAWFLAG_NORMAL);
1179                 }
1180         }
1181
1182         //draw the remaining or elapsed time
1183         timelimit = getstatf(STAT_TIMELIMIT);
1184         if(timelimit > 0)
1185         {
1186                 timeleft = max(0, timelimit * 60 + getstatf(STAT_GAMESTARTTIME) - time);
1187                 timeleft = ceil(timeleft);
1188                 minutesLeft = floor(timeleft / 60);
1189                 secondsLeft = timeleft - minutesLeft*60;
1190
1191                 if(minutesLeft >= 5) {
1192                         timer_color = '1 1 1'; //white
1193                 } else if(minutesLeft >= 1) {
1194                         timer_color = '1 1 0'; //yellow
1195                 } else {
1196                         timer_color = '1 0 0'; //red
1197                 }
1198
1199                 if (warmup_stage) {
1200                         timer_color = '1 1 1'; //don't use red or yellow for timer during warmup
1201                 }
1202
1203                 if (cvar("sbar_increment_maptime")) {
1204                         if (time < getstatf(STAT_GAMESTARTTIME)) {
1205                                 //while restart is still active, show negative counter
1206                                 minutes = 0;
1207                                 seconds = ceil(getstatf(STAT_GAMESTARTTIME) - time);
1208                         } else {
1209                                 float elapsedTime;
1210                                 elapsedTime = floor(time - getstatf(STAT_GAMESTARTTIME)); //127
1211                                 minutes = floor(elapsedTime / 60);
1212                                 seconds = elapsedTime - minutes*60;
1213                         }
1214                 } else {
1215                         minutes = minutesLeft;
1216                         seconds = secondsLeft;
1217                 }
1218
1219                 if(minutesLeft >= 1 || (cvar("sbar_increment_maptime") && minutes >= 1) ) {
1220                         Sbar_DrawXNum('-72 32 0', minutes, 3, 12, timer_color, 1, DRAWFLAG_NORMAL);
1221                         drawpic(sbar + '-36 32 0', "gfx/num_colon", '12 12 0', timer_color, sbar_alpha_fg, 0);
1222                 }
1223                 Sbar_DrawXNum('-24 32 0', seconds, -2, 12, timer_color, 1, DRAWFLAG_NORMAL);
1224         } else {
1225                 timer_color = '1 1 1'; //white
1226                 minutes = floor(time / 60);
1227                 seconds = floor(time - minutes*60);
1228                 Sbar_DrawXNum('-72 32 0', minutes, 3, 12, timer_color, 1, DRAWFLAG_NORMAL);
1229                 drawpic(sbar + '-36 32 0', "gfx/num_colon", '12 12 0', timer_color, sbar_alpha_fg, 0);
1230                 Sbar_DrawXNum('-24 32 0', seconds, -2, 12, timer_color, 1, DRAWFLAG_NORMAL);
1231         }
1232
1233         if(gametype == GAME_RACE)
1234         {
1235                 drawfont = sbar_bigfont;
1236                 float a;
1237                 vector m;
1238                 string s, forcetime;
1239
1240                 m = '0.5 0 0' * vid_conwidth + '0 0.25 0' * vid_conheight;
1241
1242                 if(race_checkpointtime)
1243                 {
1244                         a = bound(0, 2 - (time - race_checkpointtime), 1);
1245                         s = "";
1246                         forcetime = "";
1247                         if(a > 0) // just hit a checkpoint?
1248                         {
1249                                 if(race_time && race_previousbesttime)
1250                                         s = MakeRaceString(race_checkpoint, race_time / 10 - race_previousbesttime / 10, 0, 0, race_previousbestname);
1251                                 else
1252                                         s = MakeRaceString(race_checkpoint, 0, -1, 0, race_previousbestname);
1253                                 if(race_time)
1254                                         forcetime = mmsss(race_time);
1255                         }
1256                         else
1257                         {
1258                                 if(race_laptime && race_nextbesttime)
1259                                 {
1260                                         a = bound(0, 2 - ((race_laptime + race_nextbesttime/10) - time), 1);
1261                                         if(a > 0) // next one?
1262                                         {
1263                                                 s = MakeRaceString(race_nextcheckpoint, time - race_laptime, race_nextbesttime / 10, 0, race_nextbestname);
1264                                         }
1265                                 }
1266                         }
1267
1268                         if(s != "" && a > 0)
1269                         {
1270                                 dummyfunction(0, 0, 0, 0, 0, 0, 0, 0); // work around DP bug (set OFS_PARAM5 to 0)
1271                                 drawcolorcodedstring(m - '0 16 0' - '8 0 0' * stringwidth(s, TRUE), s, '16 16 0', sbar_alpha_fg * a, 0);
1272                         }
1273
1274                         if(forcetime != "")
1275                         {
1276                                 float sz;
1277                                 a = bound(0, 1 - 2 * (time - race_checkpointtime), 1);
1278                                 sz = 1.2 / (a + 0.2);
1279                                 drawstring(m - '0 0 0' - '0 16 0' * (sz - 1) - '16 0 0' * sz * stringwidth(forcetime, FALSE), forcetime, '32 32 0' * sz, '1 1 1', sbar_alpha_fg * a, 0);
1280                                 a = 1 - a;
1281                         }
1282                         else
1283                                 a = 1;
1284
1285                         if(race_laptime)
1286                         {
1287                                 s = mmsss(10*(time - race_laptime));
1288                                 drawstring(m - '0 0 0' - '16 0 0' * stringwidth(s, FALSE), s, '32 32 0', '1 1 1', sbar_alpha_fg * a, 0);
1289                         }
1290                 }
1291                 else
1292                 {
1293                         if(race_mycheckpointtime)
1294                         {
1295                                 a = bound(0, 2 - (time - race_mycheckpointtime), 1);
1296                                 s = MakeRaceString(race_mycheckpoint, race_mycheckpointdelta / 10, -!race_mycheckpointenemy, race_mycheckpointlapsdelta, race_mycheckpointenemy);
1297                                 dummyfunction(0, 0, 0, 0, 0, 0, 0, 0); // work around DP bug (set OFS_PARAM5 to 0)
1298                                 drawcolorcodedstring(m - '0 16 0' - '8 0 0' * stringwidth(s, TRUE), s, '16 16 0', sbar_alpha_fg * a, 0);
1299                         }
1300                         if(race_othercheckpointtime && race_othercheckpointenemy != "")
1301                         {
1302                                 a = bound(0, 2 - (time - race_othercheckpointtime), 1);
1303                                 s = MakeRaceString(race_othercheckpoint, -race_othercheckpointdelta / 10, -!race_othercheckpointenemy, race_othercheckpointlapsdelta, race_othercheckpointenemy);
1304                                 dummyfunction(0, 0, 0, 0, 0, 0, 0, 0); // work around DP bug (set OFS_PARAM5 to 0)
1305                                 drawcolorcodedstring(m - '0 0 0' - '8 0 0' * stringwidth(s, TRUE), s, '16 16 0', sbar_alpha_fg * a, 0);
1306                         }
1307                 }
1308
1309                 drawfont = sbar_font;
1310         }
1311
1312         sbar = sbar_save;
1313 }
1314
1315 void Sbar_MiniscoreItem(vector pos, entity pl, float is_self)
1316 {
1317         float x, score;
1318         pos_x += 72;
1319
1320         if(teamplay)
1321                 drawfill(pos + '0 1 0', '40 6 0', GetTeamRGB(pl.team)*0.5, 1, DRAWFLAG_NORMAL);
1322         else
1323                 drawfill(pos + '0 1 0', '40 6 0', '0.5 0.5 0.5', 0.5, DRAWFLAG_NORMAL);
1324         x = pos_x;
1325         pos_x += 5*8;
1326         score = pl.(scores[ps_primary]);
1327         pos_x -= stringwidth(ftos(score), FALSE)*8;
1328         drawstring(pos, ftos(score), '8 8 0', '1 1 1', 1, DRAWFLAG_NORMAL);
1329         pos_x = x;
1330         if(is_self)
1331         {
1332                 pos_x += 48;
1333                 drawstring(pos, "\x0D", '8 8 0', '1 1 1', 1, DRAWFLAG_NORMAL);
1334                 pos_x += 8;
1335         } else
1336                 pos_x += 56;
1337         drawcolorcodedstring(pos, GetPlayerName(pl.sv_entnum), '8 8 0', 1, 0);
1338 }
1339
1340 void Sbar_MiniscoreTeamItem(vector pos, float color, float frags, float is_self)
1341 {
1342         float x;
1343         pos_x += 72;
1344
1345         if(teamplay)
1346                 drawfill(pos + '0 1 0', '40 6 0', GetTeamRGB(color)*0.5, 1, DRAWFLAG_NORMAL);
1347         else
1348                 drawfill(pos + '0 1 0', '40 6 0', '0.5 0.5 0.5', 0.5, DRAWFLAG_NORMAL);
1349         x = pos_x;
1350         pos_x += 5*8;
1351         pos_x -= stringwidth(ftos(frags), FALSE)*8;
1352         drawstring(pos, ftos(frags), '8 8 0', '1 1 1', 1, DRAWFLAG_NORMAL);
1353         pos_x = x;
1354         if(is_self)
1355         {
1356                 pos_x += 48;
1357                 drawstring(pos, "\x0D", '8 8 0', '1 1 1', 1, DRAWFLAG_NORMAL);
1358                 pos_x += 8;
1359         } else
1360                 pos_x += 56;
1361         drawstring(pos, GetTeamName(color), '8 8 0', '1 1 1', 1, DRAWFLAG_NORMAL);
1362 }
1363
1364 void Sbar_MiniDeathmatchOverlay(vector pos)
1365 {
1366         float numlines, up, down, score;
1367         entity me, tm, pl;
1368         float miniscoreboard_size;
1369         miniscoreboard_size = cvar("sbar_miniscoreboard_size");
1370
1371         if(miniscoreboard_size == 0)
1372                 return;
1373         pos_y = vid_conheight - 8;
1374
1375         if(miniscoreboard_size < 0)
1376                 numlines = (vid_conheight - sbar_y + 7) / 8;
1377         else
1378                 numlines = miniscoreboard_size;
1379
1380         // give up if there isn't enough room
1381         if(pos_x >= vid_conwidth || pos_y >= vid_conheight || numlines < 1)
1382                 return;
1383
1384         // me vector := [team/connected frags id]
1385         for(me = players.sort_next; me; me = me.sort_next)
1386         {
1387                 if(me.sv_entnum == player_localentnum - 1)
1388                         break;
1389         }
1390
1391         if(teamplay)
1392                 numlines -= numteams;
1393
1394         // figure out how many players above and below we can show
1395         up = floor(numlines/2);
1396         down = up;
1397         if((up + down) > numlines)
1398                 down = numlines - up;
1399
1400         // render bottom-up
1401         for(pl = me.sort_next; pl && down > 0; pl = pl.sort_next)
1402         {
1403                 if(pl.team == COLOR_SPECTATOR)
1404                         continue;
1405                 Sbar_MiniscoreItem(pos, pl, false);
1406                 pos_y -= 9;
1407                 --down;
1408         }
1409         Sbar_MiniscoreItem(pos, me, true);
1410         pos_y -= 9;
1411         up += down; // if there weren't enough lines below... add them
1412         for(pl = me.sort_prev; pl && up > 0; pl = pl.sort_prev)
1413         {
1414                 if(pl.team == COLOR_SPECTATOR)
1415                         continue;
1416                 Sbar_MiniscoreItem(pos, pl, false);
1417                 pos_y -= 9;
1418                 --up;
1419         }
1420
1421         if(teamplay)
1422         {
1423                 for(tm = teams.sort_next; tm.sort_next; tm = tm.sort_next);
1424                 for(; tm; tm = tm.sort_prev)
1425                 {
1426                         if(!tm.team_size || tm.team == COLOR_SPECTATOR)
1427                                 continue;
1428                         score = tm.(teamscores[ts_primary]);
1429                         Sbar_MiniscoreTeamItem(pos, tm.team, score, (tm.team == me.team));
1430                         pos_y -= 9;
1431                 }
1432         }
1433 }
1434
1435 float Sbar_WouldDrawScoreboard ()
1436 {
1437         if (sb_showscores)
1438                 return 1;
1439         else if (intermission == 1)
1440                 return 1;
1441         else if (intermission == 2)
1442                 return 1;
1443         else if (getstati(STAT_HEALTH) <= 0 && cvar("cl_deathscoreboard"))
1444                 return 1;
1445         else if(sb_showscores_force)
1446                 return 1;
1447         return 0;
1448 }
1449
1450 void CSQC_Strength_Timer() {
1451         float stat_items;
1452         stat_items = getstati(STAT_ITEMS);
1453         if not(stat_items & IT_STRENGTH)
1454                 if not(stat_items & IT_INVINCIBLE)
1455                         return;
1456
1457         if (getstati(STAT_HEALTH) <= 0)
1458                 return;
1459
1460         vector pos, picsize, number_position;
1461         float strength_time, invincibility_time, countdown_fontsize;
1462
1463         picsize = '40 40 0';
1464         countdown_fontsize = 22;
1465
1466         //element will be positioned on the right side of the screen:
1467         pos_x = vid_conwidth - picsize_x - 10; //margin 10 from right border
1468         number_position_x = pos_x - 5/*margin to the left from image*/ - countdown_fontsize*2/*width of text*/;
1469
1470         pos_y = 180;
1471         number_position_y = pos_y;
1472
1473         //now calculate the values Sbar_DrawXNum() will be called with:
1474         number_position_x = number_position_x - sbar_x; //relative to sbar coordinates
1475         number_position_y = number_position_y - sbar_y; //relative to sbar coordinates
1476         number_position_y += 10; //center number vertically to the icon
1477
1478         pos_z = number_position_z = 0;
1479
1480         //strength
1481         if (stat_items & IT_STRENGTH) {
1482                 drawpic(pos, "gfx/sb_str", picsize, '0 0.086 0.953'/*strength color*/, 1, DRAWFLAG_NORMAL);
1483                 strength_time = getstatf(STAT_STRENGTH_FINISHED) - time;
1484                 if (strength_time > 0) { //show countdown once we received the valid stats-value
1485                         Sbar_DrawXNum(number_position, ceil(strength_time), 2, countdown_fontsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1486                 }
1487
1488                 //add some margin to the invincibility icon
1489                 pos_y             += picsize_y + 10;
1490                 number_position_y += picsize_y + 10;
1491         }
1492
1493         //invincibility
1494         if (stat_items & IT_INVINCIBLE) {
1495                 drawpic(pos, "gfx/sb_invinc", picsize, '0.976 0 0.165'/*invincibility color*/, 1, DRAWFLAG_NORMAL);
1496                 invincibility_time = getstatf(STAT_INVINCIBLE_FINISHED) - time;
1497                 if (invincibility_time > 0) { //show countdown once we received the valid stats-value
1498                         Sbar_DrawXNum(number_position, ceil(invincibility_time), 2, countdown_fontsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1499                 }
1500         }
1501 }
1502
1503 #define CENTERPRINT_MAX_LINES 30
1504 string centerprint_messages[CENTERPRINT_MAX_LINES];
1505 float centerprint_width[CENTERPRINT_MAX_LINES];
1506 vector centerprint_start;
1507 float centerprint_expire;
1508 float centerprint_num;
1509 float centerprint_offset_hint;
1510 vector centerprint_fontsize;
1511
1512 void centerprint(string strMessage)
1513 {
1514         float i, j, n, hcount;
1515         string s;
1516
1517         centerprint_fontsize = Sbar_GetFontsize("scr_centersize");
1518
1519         // delete old centerprint messages
1520         for (i=0; i<centerprint_num; ++i)
1521         {
1522                 if(centerprint_messages[i])
1523                 {
1524                         strunzone(centerprint_messages[i]);
1525                         centerprint_messages[i] = string_null;
1526                         centerprint_width[i] = 0;
1527                 }
1528         }
1529
1530         if(strMessage == "")
1531                 return;
1532
1533         // strip trailing newlines
1534         j = strlen(strMessage) - 1;
1535         while(substring(strMessage, j, 1) == "\n" && j >= 0)
1536                 j = j - 1;
1537         strMessage = substring(strMessage, 0, j + 1);
1538
1539         if(strMessage == "")
1540                 return;
1541
1542         // strip leading newlines and remember them, they are a hint that the message should be lower on the screen
1543         j = 0;
1544         while(substring(strMessage, j, 1) == "\n" && j < strlen(strMessage))
1545                 j = j + 1;
1546         strMessage = substring(strMessage, j, strlen(strMessage) - j);
1547         centerprint_offset_hint = j;
1548
1549         // TODO if we're parsing centerprints now anyway, why not word wrap them?
1550         n = tokenizebyseparator(strMessage, "\n");
1551         i = hcount = 0;
1552         for(j = 0; j < n; ++j)
1553         {
1554                 getWrappedLine_remaining = argv(j);
1555                 while(getWrappedLine_remaining)
1556                 {
1557                         s = getWrappedLine(vid_conwidth * 0.75 / centerprint_fontsize_x, stringwidth_colors);
1558                         centerprint_messages[i] = strzone(s);
1559                         centerprint_width[i] = stringwidth(s, TRUE);
1560                         ++i;
1561
1562                         // half height for empty lines looks better
1563                         if(s == "")
1564                                 hcount += 0.5;
1565                         else
1566                                 hcount += 1;
1567
1568                         if(i >= CENTERPRINT_MAX_LINES)
1569                                 break;
1570                 }
1571         }
1572
1573         float h, havail;
1574         h = centerprint_fontsize_y*hcount;
1575
1576         havail = vid_conheight;
1577         if(cvar("con_chatpos") < 0)
1578                 havail -= (-cvar("con_chatpos") + cvar("con_chat")) * cvar("con_chatsize"); // avoid overlapping chat
1579
1580         centerprint_start_x = 0;
1581
1582 #if 0
1583         float forbiddenmin, forbiddenmax, allowedmin, allowedmax, preferred;
1584
1585         // here, the centerprint would cover the crosshair. REALLY BAD.
1586         forbiddenmin = vid_conheight * 0.5 - h - 16;
1587         forbiddenmax = vid_conheight * 0.5 + 16;
1588
1589         allowedmin = scoreboard_bottom;
1590         allowedmax = havail - h;
1591         preferred = (havail - h)/2;
1592
1593
1594         // possible orderings (total: 4! / 4 = 6)
1595         //  allowedmin allowedmax forbiddenmin forbiddenmax
1596         //  forbiddenmin forbiddenmax allowedmin allowedmax
1597         if(allowedmax < forbiddenmin || allowedmin > forbiddenmax)
1598         {
1599                 // forbidden doesn't matter in this case
1600                 centerprint_start_y = bound(allowedmin, preferred, allowedmax);
1601         }
1602         //  allowedmin forbiddenmin allowedmax forbiddenmax
1603         else if(allowedmin < forbiddenmin && allowedmax < forbiddenmax)
1604         {
1605                 centerprint_start_y = bound(allowedmin, preferred, forbiddenmin);
1606         }
1607         //  allowedmin forbiddenmin forbiddenmax allowedmax
1608         else if(allowedmin < forbiddenmin)
1609         {
1610                 // make sure the forbidden zone is not covered
1611                 if(preferred > (forbiddenmin + forbiddenmax) * 0.5)
1612                         centerprint_start_y = bound(allowedmin, preferred, forbiddenmin);
1613                 else
1614                         centerprint_start_y = bound(forbiddenmax, preferred, allowedmin);
1615         }
1616         //  forbiddenmin allowedmin allowedmax forbiddenmax
1617         else if(allowedmax < forbiddenmax)
1618         {
1619                 // it's better to leave the allowed zone (overlap with scoreboard) than
1620                 // to cover the forbidden zone (crosshair)
1621                 if(preferred > (forbiddenmin + forbiddenmax) * 0.5)
1622                         centerprint_start_y = forbiddenmax;
1623                 else
1624                         centerprint_start_y = forbiddenmin;
1625         }
1626         //  forbiddenmin allowedmin forbiddenmax allowedmax
1627         else
1628         {
1629                 centerprint_start_y = bound(forbiddenmax, preferred, allowedmax);
1630         }
1631 #else
1632         centerprint_start_y =
1633                 min(
1634                         max(
1635                                 max(scoreboard_bottom, vid_conheight * 0.5 + 16),
1636                                 (havail - h)/2
1637                         ),
1638                         havail - h
1639                 );
1640 #endif
1641
1642         centerprint_num = i;
1643         centerprint_expire = time + cvar("scr_centertime");
1644 }
1645
1646 void Sbar_DrawCenterPrint (void)
1647 {
1648         float i;
1649         vector pos;
1650         string ts;
1651         float a;
1652
1653         //if(time > centerprint_expire)
1654         //      return;
1655
1656         //a = bound(0, 1 - 2 * (time - centerprint_expire), 1);
1657         a = bound(0, 1 - 4 * (time - centerprint_expire), 1);
1658         //sz = 1.2 / (a + 0.2);
1659
1660         if(a <= 0)
1661                 return;
1662
1663         pos = centerprint_start;
1664         for (i=0; i<centerprint_num; i = i + 1)
1665         {
1666                 pos_x = (vid_conwidth - centerprint_fontsize_x * centerprint_width[i]) * 0.5;
1667                 ts = centerprint_messages[i];
1668                 if (ts != "")
1669                 {
1670                         dummyfunction(0, 0, 0, 0, 0, 0, 0, 0); // work around DP bug (set OFS_PARAM5 to 0)
1671                         drawcolorcodedstring(pos, ts, centerprint_fontsize, a, DRAWFLAG_NORMAL);
1672                         //  - '0 0.5 0' * (sz - 1) * centerprint_fontsize_x - '0.5 0 0' * (sz - 1) * centerprint_width[i] * centerprint_fontsize_y, centerprint_fontsize * sz
1673                         pos_y = pos_y + centerprint_fontsize_y;
1674                 }
1675                 else
1676                         // half height for empty lines looks better
1677                         pos_y = pos_y + centerprint_fontsize_y * 0.5;
1678         }
1679 }
1680
1681 vector Sbar_DrawNoteLine(vector offset, string s)
1682 {
1683         dummyfunction(0, 0, 0, 0, 0, 0, 0, 0); // work around DP bug (set OFS_PARAM5 to 0)
1684         drawcolorcodedstring(
1685                 offset - sbar_fontsize_x * '1 0 0' * stringwidth(s, TRUE),
1686                 s,
1687                 sbar_fontsize,
1688                 sbar_alpha_fg,
1689                 0
1690         );
1691         return offset + sbar_fontsize_y * '0 1 0';
1692 }
1693
1694 void Sbar_Draw (void)
1695 {
1696         float i;
1697         float x, fade;
1698         float stat_items, stat_weapons;
1699         vector o; o = '1 0 0' * vid_conwidth;
1700         string s;
1701
1702         sbar_fontsize = Sbar_GetFontsize("sbar_fontsize");
1703
1704         if(spectatee_status)
1705         {
1706                 if(spectatee_status == -1)
1707                         s = "^1Observing";
1708                 else
1709                         s = strcat("^1Spectating ^7", GetPlayerName(spectatee_status - 1));
1710                 o = Sbar_DrawNoteLine(o, s);
1711
1712                 if(spectatee_status == -1)
1713                         s = strcat("^1Press ^3", getcommandkey("primary fire", "+attack"), "^1 to spectate");
1714                 else
1715                         s = strcat("^1Press ^3", getcommandkey("primary fire", "+attack"), "^1 for another player");
1716                 o = Sbar_DrawNoteLine(o, s);
1717
1718                 if(spectatee_status == -1)
1719                         s = strcat("^1Use ^3", getcommandkey("next weapon", "weapnext"), "^1 or ^3", getcommandkey("previous weapon", "weapprev"), "^1 to change the speed");
1720                 else
1721                         s = strcat("^1Press ^3", getcommandkey("secondary fire", "+attack2"), "^1 to observe");
1722                 o = Sbar_DrawNoteLine(o, s);
1723
1724                 if(gametype == GAME_ARENA)
1725                         s = "^1Wait for your turn to join";
1726                 else if(gametype == GAME_LMS)
1727                 {
1728                         entity sk;
1729                         sk = playerslots[player_localentnum - 1];
1730                         if(sk.(scores[ps_primary]) >= 666)
1731                                 s = "^1Match has already begun";
1732                         else if(sk.(scores[ps_primary]) > 0)
1733                                 s = "^1You have no more lives left";
1734                         else
1735                                 s = strcat("^1Press ^3", getcommandkey("jump", "+jump"), "^1 to join");
1736                 }
1737                 else
1738                         s = strcat("^1Press ^3", getcommandkey("jump", "+jump"), "^1 to join");
1739                 o = Sbar_DrawNoteLine(o, s);
1740
1741                 //show restart countdown:
1742                 if (time < getstatf(STAT_GAMESTARTTIME)) {
1743                         float countdown;
1744                         //we need to ceil, otherwise the countdown would be off by .5 when using round()
1745                         countdown = ceil(getstatf(STAT_GAMESTARTTIME) - time);
1746                         s = strcat("^1Game starts in ^3", ftos(countdown), "^1 seconds");
1747                         o = Sbar_DrawNoteLine(o, s);
1748                 }
1749         }
1750         if(warmup_stage)
1751         {
1752                 s = "^2Currently in ^1warmup^2 stage!";
1753                 o = Sbar_DrawNoteLine(o, s);
1754         }
1755
1756         // move more important stuff more to the middle so its more visible
1757         o_y = vid_conheight * 0.66;
1758
1759         string blinkcolor;
1760         if(mod(time, 1) >= 0.5)
1761                 blinkcolor = "^1";
1762         else
1763                 blinkcolor = "^3";
1764
1765         if(ready_waiting)
1766         {
1767                 if(ready_waiting_for_me)
1768                 {
1769                         if(warmup_stage)
1770                                 s = strcat(blinkcolor, "Press ^3", getcommandkey("ready", "ready"), blinkcolor, " to end warmup");
1771                         else
1772                                 s = strcat(blinkcolor, "Press ^3", getcommandkey("ready", "ready"), blinkcolor, " once you are ready");
1773                 }
1774                 else
1775                 {
1776                         if(warmup_stage)
1777                                 s = strcat("^2Waiting for others to ready up to end warmup...");
1778                         else
1779                                 s = strcat("^2Waiting for others to ready up...");
1780                 }
1781                 o = Sbar_DrawNoteLine(o, s);
1782         }
1783         else if(warmup_stage)
1784         {
1785                 s = strcat("^2Press ^3", getcommandkey("ready", "ready"), "^2 to end warmup");
1786                 o = Sbar_DrawNoteLine(o, s);
1787         }
1788         if(vote_waiting)
1789         {
1790                 s = strcat("^2A vote has been called for ^1", vote_called_vote);
1791                 o = Sbar_DrawNoteLine(o, s);
1792
1793                 if(vote_waiting_for_me)
1794                 {
1795                         s = strcat(blinkcolor, "Press ^3", getcommandkey("vote yes", "vyes"), blinkcolor, " to accept");
1796                         o = Sbar_DrawNoteLine(o, s);
1797
1798                         s = strcat(blinkcolor, "Press ^3", getcommandkey("vote no", "vno"), blinkcolor, " to reject");
1799                         o = Sbar_DrawNoteLine(o, s);
1800
1801                         s = strcat(blinkcolor, "Press ^3", getcommandkey("vote abstain", "vabstain"), blinkcolor, " to abstain");
1802                         o = Sbar_DrawNoteLine(o, s);
1803                 }
1804                 else
1805                 {
1806                         s = strcat("^2Waiting for others to vote...");
1807                         o = Sbar_DrawNoteLine(o, s);
1808                 }
1809         }
1810         if(teamplay)
1811         {
1812                 entity tm;
1813                 float ts_min, ts_max;
1814                 tm = teams.sort_next;
1815                 if (tm)
1816                 {
1817                         for(; tm.sort_next; tm = tm.sort_next)
1818                         {
1819                                 if(!tm.team_size || tm.team == COLOR_SPECTATOR)
1820                                         continue;
1821                                 if(!ts_min) ts_min = tm.team_size;
1822                                 else ts_min = min(ts_min, tm.team_size);
1823                                 if(!ts_max) ts_max = tm.team_size;
1824                                 else ts_max = max(ts_max, tm.team_size);
1825                         }
1826                         if ((ts_max - ts_min) > 1)
1827                         {
1828                                 s = strcat(blinkcolor, "Teamnumbers are unbalanced!");
1829                                 tm = GetTeam(myteam, false);
1830                                 if (tm)
1831                                 if (tm.team != COLOR_SPECTATOR)
1832                                 if (tm.team_size == ts_max)
1833                                         s = strcat(s, " Press ^3", getcommandkey("team menu", "menu_showteamselect"), blinkcolor, " to adjust");
1834
1835                                 o = Sbar_DrawNoteLine(o, s);
1836                         }
1837                 }
1838         }
1839
1840         //Sbar_SortFrags();
1841         Sbar_UpdatePlayerTeams();
1842
1843         sb_lines = 24;
1844
1845         if (sb_showscores)
1846         {
1847                 Sbar_DrawScoreboard();
1848                 Sbar_DrawCenterPrint();
1849         }
1850         else if (intermission == 1)
1851         {
1852                 Sbar_DrawScoreboard();
1853                 Sbar_DrawCenterPrint();
1854                 return;
1855         }
1856         else if (intermission == 2)
1857         {
1858                 Sbar_FinaleOverlay();
1859                 Sbar_DrawCenterPrint();
1860         }
1861         else
1862         {
1863                 if (sb_showscores || sb_showscores_force || (getstati(STAT_HEALTH) <= 0 && cvar("cl_deathscoreboard")))
1864                 {
1865                         sbar_x = (vid_conwidth - 640.0)*0.5;
1866                         sbar_y = vid_conheight - 47;
1867                         //Sbar_DrawAlphaPic (sbar_x, sbar_y, sb_scorebar, sbar_alpha_bg.value);
1868                         //drawpic('0 0 0', "gfx/scorebar", '0 0 0', '1 1 1', cvar("sbar_alpha_bg"), 0);
1869                         Sbar_DrawScoreboard ();
1870                 }
1871                 else
1872                 {
1873                         if (sb_lines && sbar_hudselector == 1)
1874                         {
1875                                 stat_items = getstati(STAT_ITEMS);
1876                                 stat_weapons = getstati(STAT_WEAPONS);
1877
1878                                 sbar_x = (vid_conwidth - 320.0)*0.5;
1879                                 sbar_y = vid_conheight - 24.0 - 16.0;
1880                                 sbar_z = 0;
1881
1882                                 fade = 3.2 - 2 * (time - weapontime);
1883                                 fade = bound(0.7, fade, 1);
1884
1885                                 x = 1.0;
1886                                 Sbar_DrawWeapon_Clear();
1887                                 for(i = 1; i <= 24; ++i)
1888                                 {
1889                                         if(weaponimpulse[i-1] >= 0)
1890                                         if(stat_weapons & x)
1891                                         {
1892                                                 Sbar_DrawWeapon(i-1, fade, (i == activeweapon));
1893                                         }
1894                                         x *= 2;
1895                                 }
1896
1897                                 // armor
1898                                 x = getstati(STAT_ARMOR);
1899                                 if (x > 0)
1900                                 {
1901                                         // "gfx/sb_armor"
1902                                         //Sbar_DrawStretchPic (72, 0, sb_armor[0], sbar_alpha_fg.value, 24, 24);
1903                                         drawpic(sbar + '72 0 0', "gfx/sb_armor", '24 24 0', '1 1 1', sbar_alpha_fg, 0);
1904                                         if(x > 200)
1905                                                 Sbar_DrawXNum('0 0 0', x, 3, 24, '0 1 0', 1, 0);
1906                                         else if(x > 100)
1907                                                 Sbar_DrawXNum('0 0 0', x, 3, 24, '0.2 1 0', 1, 0);
1908                                         else if(x > 50)
1909                                                 Sbar_DrawXNum('0 0 0', x, 3, 24, '0.6 0.7 0.8', 1, 0);
1910                                         else if(x > 25)
1911                                                 Sbar_DrawXNum('0 0 0', x, 3, 24, '1 1 0.2', 1, 0);
1912                                         else
1913                                                 Sbar_DrawXNum('0 0 0', x, 3, 24, '0.7 0 0', 1, 0);
1914                                 }
1915
1916                                 // health
1917                                 x = getstati(STAT_HEALTH);
1918                                 if (x != 0)
1919                                 {
1920                                         // "gfx/sb_health"
1921                                         //Sbar_DrawStretchPic (184, 0, sb_health, sbar_alpha_fg.value, 24, 24);
1922                                         drawpic(sbar + '184 0 0', "gfx/sb_health", '24 24 0', '1 1 1', sbar_alpha_fg, 0);
1923                                         if(x > 200)
1924                                                 Sbar_DrawXNum('112 0 0', x, 3, 24, '0 1 0', 1, 0);
1925                                         else if(x > 100)
1926                                                 Sbar_DrawXNum('112 0 0', x, 3, 24, '0.2 1 0', 1, 0);
1927                                         else if(x > 50)
1928                                                 Sbar_DrawXNum('112 0 0', x, 3, 24, '0.6 0.7 0.8', 1, 0);
1929                                         else if(x > 25)
1930                                                 Sbar_DrawXNum('112 0 0', x, 3, 24, '1 1 0.2', 1, 0);
1931                                         else
1932                                                 Sbar_DrawXNum('112 0 0', x, 3, 24, '0.7 0 0', 1, 0);
1933                                 }
1934
1935                                 // ammo
1936                                 x = getstati(STAT_AMMO);
1937                                 if ((stat_items & IT_AMMO) || x != 0)
1938                                 {
1939                                         if (stat_items & IT_SHELLS)
1940                                                 drawpic(sbar + '296 0 0', "gfx/sb_shells", '24 24 0', '1 1 1', sbar_alpha_fg, 0);
1941                                         else if (stat_items & IT_NAILS)
1942                                                 drawpic(sbar + '296 0 0', "gfx/sb_bullets", '24 24 0', '1 1 1', sbar_alpha_fg, 0);
1943                                         else if (stat_items & IT_ROCKETS)
1944                                                 drawpic(sbar + '296 0 0', "gfx/sb_rocket", '24 24 0', '1 1 1', sbar_alpha_fg, 0);
1945                                         else if (stat_items & IT_CELLS)
1946                                                 drawpic(sbar + '296 0 0', "gfx/sb_cells", '24 24 0', '1 1 1', sbar_alpha_fg, 0);
1947                                         if(x > 10)
1948                                                 Sbar_DrawXNum('224 0 0', x, 3, 24, '0.6 0.7 0.8', 1, 0);
1949                                         else
1950                                                 Sbar_DrawXNum('224 0 0', x, 3, 24, '0.7 0 0', 1, 0);
1951                                 }
1952
1953                                 if (sbar_x + 320 + 160 <= vid_conwidth)
1954                                         Sbar_MiniDeathmatchOverlay(sbar + '320 0 0');
1955                                 if (sbar_x > 0)
1956                                         Sbar_Score(16);
1957                                 // The margin can be at most 8 to support 640x480 console size:
1958                                 //   320 + 2 * (144 + 16) = 640
1959                         }
1960                         else if (sb_lines)
1961                         {
1962
1963                                 stat_items = getstati(STAT_ITEMS);
1964                                 stat_weapons = getstati(STAT_WEAPONS);
1965
1966                                 sbar_x = (vid_conwidth - 640.0)*0.5;
1967                                 sbar_y = vid_conheight - 47;
1968                                 sbar_z = 0;
1969
1970                                 fade = 3 - 2 * (time - weapontime);
1971
1972                                 x = 1.0;
1973                                 Sbar_DrawWeapon_Clear();
1974                                 for(i = 1; i <= 24; ++i)
1975                                 {
1976                                         if(weaponimpulse[i-1] >= 0)
1977                                         if(stat_weapons & x)
1978                                         {
1979                                                 Sbar_DrawWeapon(i-1, fade, (i == activeweapon));
1980                                         }
1981                                         x *= 2;
1982                                 }
1983
1984                                 if (sb_lines > 24)
1985                                         drawpic(sbar, "gfx/sbar", '0 0 0', '1 1 1', sbar_alpha_fg, 0);
1986                                 else
1987                                         drawpic(sbar, "gfx/sbar_minimal", '0 0 0', '1 1 1', sbar_alpha_fg, 0);
1988
1989                                 // armor
1990                                 // (340-3*24) = 268
1991                                 Sbar_DrawXNum('268 12 0', getstati(STAT_ARMOR), 3, 24, '0.6 0.7 0.8', 1, 0);
1992
1993                                 // health
1994                                 // (154-3*24) = 82
1995                                 x = getstati(STAT_HEALTH);
1996                                 if(x > 100)
1997                                         Sbar_DrawXNum('82 12 0', x, 3, 24, '1 1 1', 1, 0);
1998                                 else if(x <= 25 && time - floor(time) > 0.5)
1999                                         Sbar_DrawXNum('82 12 0', x, 3, 24, '0.7 0 0', 1, 0);
2000                                 else
2001                                         Sbar_DrawXNum('81 12 0', x, 3, 24, '0.6 0.7 0.8', 1, 0);
2002
2003                                 x = getstati(STAT_AMMO);
2004                                 if ((stat_items & IT_AMMO) || x != 0)
2005                                 {
2006                                         // (519-3*24) = 447
2007                                         if (stat_items & IT_SHELLS)
2008                                                 drawpic(sbar + '519 0 0', "gfx/sb_shells", '0 0 0', '1 1 1', sbar_alpha_fg, 0);
2009                                         else if (stat_items & IT_NAILS)
2010                                                 drawpic(sbar + '519 0 0', "gfx/sb_bullets", '0 0 0', '1 1 1', sbar_alpha_fg, 0);
2011                                         else if (stat_items & IT_ROCKETS)
2012                                                 drawpic(sbar + '519 0 0', "gfx/sb_rocket", '0 0 0', '1 1 1', sbar_alpha_fg, 0);
2013                                         else if (stat_items & IT_CELLS)
2014                                                 drawpic(sbar + '519 0 0', "gfx/sb_cells", '0 0 0', '1 1 1', sbar_alpha_fg, 0);
2015                                         if(x > 10)
2016                                                 Sbar_DrawXNum('447 12 0', x, 3, 24, '0.6 0.7 0.8', 1, 0);
2017                                         else
2018                                                 Sbar_DrawXNum('447 12 0', x, 3, 24, '0.7 0 0', 1, 0);
2019                                 }
2020
2021                                 if (sb_lines > 24)
2022                                         drawpic(sbar, "gfx/sbar_overlay", '0 0 0', '1 1 1', 1, DRAWFLAG_MODULATE);
2023
2024                                 if (sbar_x + 600 + 160 <= vid_conwidth)
2025                                         Sbar_MiniDeathmatchOverlay (sbar + '600 0 0');
2026
2027                                 if (sbar_x > 0)
2028                                         Sbar_Score(-16);
2029                                 // Because:
2030                                 //   Mini scoreboard uses 12*4 per other team, that is, 144
2031                                 //   pixels when there are four teams...
2032                                 //   Nexuiz by default sets vid_conwidth to 800... makes
2033                                 //   sbar_x == 80...
2034                                 //   so we need to shift it by 64 pixels to the right to fit
2035                                 //   BUT: then it overlaps with the image that gets drawn
2036                                 //   for viewsize 100! Therefore, just account for 3 teams,
2037                                 //   that is, 96 pixels mini scoreboard size, needing 16 pixels
2038                                 //   to the right!
2039                         }
2040
2041                         //show strength/invincibility ICON and timer:
2042                         CSQC_Strength_Timer();
2043
2044                         if(gametype == GAME_KEYHUNT)
2045                         {
2046                                 CSQC_kh_hud();
2047                         } else if(gametype == GAME_CTF)
2048                         {
2049                                 CSQC_ctf_hud();
2050                         }
2051                 }
2052                 Sbar_DrawCenterPrint();
2053         }
2054 }
2055
2056 void CSQC_ctf_hud(void)
2057 {
2058         // cvar("sbar_flagstatus_right") move the flag icons right
2059         // cvar("sbar_flagstatus_pos") pixel position of the nexuiz flagstatus icons
2060         float redflag, blueflag;
2061         float stat_items;
2062         vector pos;
2063
2064         stat_items = getstati(STAT_ITEMS);
2065         redflag = (stat_items/IT_RED_FLAG_TAKEN) & 3;
2066         blueflag = (stat_items/IT_BLUE_FLAG_TAKEN) & 3;
2067
2068         /**
2069          * FTEQCC BUG!
2070          * For some reason now not even THAT works there...
2071          * Maybe the minus' precedence screws it up? The last one there, maybe I should use brackets
2072          **
2073          * pos_x = (cvar("sbar_flagstatus_right")) ? vid_conwidth - 10 - sbar_x - 64 : 10 - sbar_x;
2074          ** Should try those later:
2075          * pos_x = (cvar("sbar_flagstatus_right")) ? (vid_conwidth - 10 - sbar_x - 64) : (10 - sbar_x);
2076          * pos_x = ( (cvar("sbar_flagstatus_right")) ? vid_conwidth - 10 - 64 : 10 ) - sbar_x;
2077          */
2078
2079         if(cvar("sbar_flagstatus_right"))
2080                 pos_x = vid_conwidth - 10 - sbar_x - 64;
2081         else
2082                 pos_x = 10 - sbar_x;
2083
2084         pos_z = 0;
2085
2086         if(sbar_hudselector == 1)
2087                 pos_y = (vid_conheight - sbar_y) - cvar("sbar_flagstatus_pos") - 64;
2088         else
2089                 pos_y = -117;
2090
2091         pos += sbar;
2092
2093         switch(redflag)
2094         {
2095         case 1: drawpic(pos, "gfx/sb_flag_red_taken", '128 64 0', '1 1 1', 1, DRAWFLAG_NORMAL); break;
2096         case 2: drawpic(pos, "gfx/sb_flag_red_lost", '128 64 0', '1 1 1', 1, DRAWFLAG_NORMAL); break;
2097         case 3: drawpic(pos, "gfx/sb_flag_red_carrying", '128 64 0', '1 1 1', 1, DRAWFLAG_NORMAL); break;
2098         default:
2099                 if(stat_items & IT_CTF_SHIELDED)
2100                         if(myteam == COLOR_TEAM2)
2101                                 drawpic(pos, "gfx/sb_flag_red_shielded", '128 64 0', '1 1 1', 1, DRAWFLAG_NORMAL); break;
2102         }
2103
2104         pos_y -= 64;
2105
2106         switch(blueflag)
2107         {
2108         case 1: drawpic(pos, "gfx/sb_flag_blue_taken", '128 64 0', '1 1 1', 1, 0); break;
2109         case 2: drawpic(pos, "gfx/sb_flag_blue_lost", '128 64 0', '1 1 1', 1, 0); break;
2110         case 3: drawpic(pos, "gfx/sb_flag_blue_carrying", '128 64 0', '1 1 1', 1, 0); break;
2111         default:
2112                 if(stat_items & IT_CTF_SHIELDED)
2113                         if(myteam == COLOR_TEAM1)
2114                                 drawpic(pos, "gfx/sb_flag_blue_shielded", '128 64 0', '1 1 1', 1, DRAWFLAG_NORMAL); break;
2115         }
2116 }