data/qcsrc/client/sbar.qc

   1 void drawstringright(vector, string, vector, vector, float, float);
   2 void drawstringcenter(vector, string, vector, vector, float, float);
   3
   4 float teamnagger;
   5
   6 float weapon_hits[WEP_COUNT];
   7 float weapon_fired[WEP_COUNT];
   8 float weapon_number;
   9
  10 float last_weapon;
  11 float weapontime;
  12
  13 float sbar_alpha_fg;
  14 float sbar_alpha_bg;
  15 float sbar_color_bg_team;
  16 float sbar_border_thickness;
  17 float sbar_accuracy_border_thickness;
  18 float sbar_scoreboard_alpha_bg;
  19 float sbar_scoreboard_alpha_fg;
  20 float sbar_scoreboard_highlight;
  21 float sbar_scoreboard_highlight_alpha;
  22 float sbar_scoreboard_highlight_alpha_self;
  23 float sbar_hudselector;
  24 float sbar_accuracy_hud;
  25 float sbar_scoreboard_alpha_name;
  26 float sbar_scoreboard_alpha_name_self;
  27
  28 float ps_primary, ps_secondary;
  29 float ts_primary, ts_secondary;
  30
  31 vector color;
  32 float SCOREBOARD_OFFSET = 50;
  33
  34 void CSQC_kh_hudreset();
  35 void CSQC_kh_hud();
  36 void CSQC_ctf_hudreset();
  37 void CSQC_ctf_hud();
  38 void CSQC_nb_hud();
  39 void CSQC_race_hud();
  40 void MapVote_Draw();
  41 void Sbar_FinaleOverlay()
  42 {
  43         /*vector pos;
  44         pos_x = (vid_conwidth - 1)/2;
  45         pos_y = 16;
  46         pos_z = 0;*/
  47
  48         //drawpic(pos, "gfx/finale", '0 0 0', '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
  49
  50         //drawstring(pos, "END", sbar_fontsize, '1 1 1', 1, DRAWFLAG_NORMAL);
  51         MapVote_Draw();
  52 }
  53
  54 vector Sbar_AccuracyColor(float accuracy)
  55 {
  56         vector color;
  57         float yellow_accuracy = cvar("sbar_accuracy_yellow"); // value at which this function returns yellow
  58         if(accuracy >= 100) {
  59                 color_x = 0;
  60                 color_y = 1;
  61         }
  62         else if(accuracy > yellow_accuracy) {
  63                 color_x = 1 - (accuracy-yellow_accuracy)/(100-yellow_accuracy); // red value between 1 -> 0
  64                 color_y = 1;
  65         }
  66         else {
  67                 color_x = 1;
  68                 color_y = accuracy/yellow_accuracy; // green value between 0 -> 1
  69         }
  70         color_z = 0;
  71         return color;
  72 }
  73
  74 float weaponspace[10];
  75 float weapon_first, weapon_last;
  76 void Sbar_DrawWeapon_Clear()
  77 {
  78         float idx;
  79         weapon_first = -2;
  80         weapon_last = -1;
  81         for(idx = 0; idx < 10; ++idx)
  82                 weaponspace[idx] = 0;
  83         for(idx = 0; idx <= 23; ++idx)
  84         {
  85                 if(weaponimpulse[idx] >= 0)
  86                 {
  87                         if(weapon_first < 0)
  88                                 weapon_first = idx;
  89                         weapon_last = idx;
  90                 }
  91         }
  92 }
  93 void Sbar_DrawWeapon(float nr, float fade, float active, float wc)
  94 {
  95         vector pos, vsize, fill_colour;
  96         float value, idx, imp, sp, weapon_hit, weapon_damage, weapon_stats;
  97
  98         imp = weaponimpulse[nr];
  99         weapon_hit = weapon_hits[wc];
 100         weapon_damage = weapon_fired[wc];
 101         if(imp == 0)
 102                 idx = 9;
 103         else
 104                 idx = imp - 1;
 105
 106         value = (active) ? 1 : 0.6;
 107         color_x = color_y = color_z = value;
 108
 109         // width = 300, height = 100
 110         const float w_width = 24, w_height = 12, w_space = 2, font_size = 8, accuracybar_height = 3;
 111
 112         sp = weaponspace[idx] + 1;
 113         weaponspace[idx] = sp;
 114
 115         pos_x = (vid_conwidth + 6 - w_width * 9) * 0.5 + w_width * idx;
 116         pos_y = (vid_conheight - w_height * sp) - 38; // move 38 pixels up
 117         pos_z = 0;
 118         vsize_x = w_width;
 119         vsize_y = w_height;
 120         vsize_z = 0;
 121         if (active)
 122                 drawpic(pos, "gfx/hud/sb_ammobg", vsize, color, value * fade * sbar_alpha_fg, DRAWFLAG_NORMAL);
 123         drawpic(pos, strcat("gfx/hud/inv_weapon", ftos(nr)), vsize, color, value * fade * sbar_alpha_fg, DRAWFLAG_NORMAL);
 124         pos_x += w_space;
 125         pos_y += w_space;
 126         vsize_x = font_size;
 127         vsize_y = font_size;
 128         vsize_z = 0;
 129         drawstring(pos, ftos(imp), vsize, '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
 130
 131         // draw the weapon accuracy on the HUD
 132         if(sbar_accuracy_hud)
 133         {
 134                 if(weapon_damage)
 135                         weapon_stats = rint(100*weapon_hit/weapon_damage);
 136                 fill_colour = Sbar_AccuracyColor(weapon_stats);
 137                 if(weapon_damage)
 138                         drawpic(pos - '2 0 0' + '0 1 0' * (w_height - accuracybar_height), "gfx/hud/sb_accuracy_bar.tga", '1 0 0' * w_width + '0 1 0' * accuracybar_height, fill_colour, sbar_alpha_fg, DRAWFLAG_NORMAL);
 139         }
 140 }
 141
 142 void Sbar_DrawXNum (vector pos, float num, float digits, float showminusplus, float lettersize, vector rgb, float highlighted, float stroke, float alpha, float dflags)
 143 {
 144         float l, i;
 145         string str, tmp, l_length;
 146         float minus, plus;
 147         vector vsize, num_color;
 148
 149         vsize_x = vsize_y = lettersize;
 150         vsize_z = 0;
 151
 152         // showminusplus 1: always prefix with minus sign (useful in race distribution display)
 153         // showminusplus 2: always prefix with plus sign (useful in race distribution display)
 154         // showminusplus 3: prefix with minus sign if negative, plus sign if positive (useful in score distribution display)
 155
 156         if((showminusplus == 2 && num >= 0) || (num > 0 && showminusplus == 3))
 157         {
 158                 plus = true;
 159                 pos_x -= lettersize;
 160         } else
 161                 plus = false;
 162
 163         if(num < 0 || (num < 0 && showminusplus == 3) || (showminusplus == 1 && num <= 0))
 164         {
 165                 minus = true;
 166                 num = -num;
 167                 pos_x -= lettersize;
 168         } else
 169                 minus = false;
 170
 171         if(digits < 0)
 172         {
 173                 tmp = ftos(num);
 174                 digits = -digits;
 175                 str = strcat(substring("0000000000", 0, digits - strlen(tmp)), tmp);
 176         } else
 177                 str = ftos(num);
 178
 179         l = strlen(str);
 180         l_length = ftos(l);
 181
 182         if(l > digits)
 183         {
 184                 str = substring(str, l-digits, 999);
 185                 l = strlen(str);
 186         } else if(l < digits)
 187                 pos_x += (digits-l) * lettersize;
 188
 189         if (highlighted == 1) {
 190                 vector hl_size;
 191                 hl_size_x = vsize_x * l + vsize_x * 0.2;
 192                 hl_size_y = vsize_y * 1.1;
 193                 hl_size_z = 0;
 194                 if(minus)
 195                         hl_size_x = hl_size_x + vsize_x;
 196
 197                 vector hl_pos;
 198                 hl_pos_x = pos_x - lettersize/10;
 199                 hl_pos_y = pos_y - lettersize/20;
 200                 hl_pos_z = 0;
 201
 202                 drawpic(hl_pos, strcat("gfx/hud/sb_highlight_", l_length), hl_size, '1 1 1', alpha, dflags);
 203         }
 204
 205         if (stroke == 1)
 206                 num_color = '1 1 1';
 207         else
 208                 num_color = rgb;
 209
 210         if(minus)
 211         {
 212                 if (stroke == 1)
 213                         drawpic(pos, "gfx/hud/num_minus_stroke", vsize, rgb, alpha, dflags);
 214                 drawpic(pos, "gfx/hud/num_minus", vsize, num_color, alpha, dflags);
 215                 pos_x += lettersize;
 216         } else if(plus)
 217         {
 218                 if (stroke == 1)
 219                         drawpic(pos, "gfx/hud/num_plus_stroke", vsize, rgb, alpha, dflags);
 220                 drawpic(pos, "gfx/hud/num_plus", vsize, num_color, alpha, dflags);
 221                 pos_x += lettersize;
 222         }
 223
 224         for(i = 0; i < l; ++i)
 225         {
 226                 tmp = substring(str, i, 1);
 227                 if (stroke == 1)
 228                         drawpic(pos, strcat("gfx/hud/num_", tmp, "_stroke"), vsize, rgb, alpha, dflags);
 229                 drawpic(pos, strcat("gfx/hud/num_", tmp), vsize, num_color, alpha, dflags);
 230                 pos_x += lettersize;
 231         }
 232 }
 233
 234 void Sbar_DrawXNum_Colored (vector pos, float x, float lettersize, float alpha)
 235 {
 236         if(x > 200) {
 237                 color_x = 0;
 238                 color_y = 1;
 239                 color_z = 0;
 240         }
 241         else if(x > 150) {
 242                 color_x = 0.4 - (x-150)*0.02 * 0.4; //red value between 0.4 -> 0
 243                 color_y = 0.9 + (x-150)*0.02 * 0.1; // green value between 0.9 -> 1
 244                 color_z = 0;
 245         }
 246         else if(x > 100) {
 247                 color_x = 1 - (x-100)*0.02 * 0.6; //red value between 1 -> 0.4
 248                 color_y = 1 - (x-100)*0.02 * 0.1; // green value between 1 -> 0.9
 249                 color_z = 1 - (x-100)*0.02; // blue value between 1 -> 0
 250         }
 251         else if(x > 50) {
 252                 color_x = 1;
 253                 color_y = 1;
 254                 color_z = 0.2 + (x-50)*0.02 * 0.8; // blue value between 0.2 -> 1
 255         }
 256         else if(x > 20) {
 257                 color_x = 1;
 258                 color_y = (x-20)*90/27/100; // green value between 0 -> 1
 259                 color_z = (x-20)*90/27/100 * 0.2; // blue value between 0 -> 0.2
 260         }
 261         else {
 262                 color_x = 1;
 263                 color_y = 0;
 264                 color_z = 0;
 265         }
 266         Sbar_DrawXNum(pos, x, 3, 0, lettersize, color, 0, 0, alpha, DRAWFLAG_NORMAL);
 267 }
 268
 269 void Cmd_Sbar_SetFields(float argc);
 270 void Sbar_InitScores()
 271 {
 272         float i, f;
 273
 274         ps_primary = ps_secondary = ts_primary = ts_secondary = -1;
 275         for(i = 0; i < MAX_SCORE; ++i)
 276         {
 277                 f = (scores_flags[i] & SFL_SORT_PRIO_MASK);
 278                 if(f == SFL_SORT_PRIO_PRIMARY)
 279                         ps_primary = i;
 280                 if(f == SFL_SORT_PRIO_SECONDARY)
 281                         ps_secondary = i;
 282         }
 283         if(ps_secondary == -1)
 284                 ps_secondary = ps_primary;
 285
 286         for(i = 0; i < MAX_TEAMSCORE; ++i)
 287         {
 288                 f = (teamscores_flags[i] & SFL_SORT_PRIO_MASK);
 289                 if(f == SFL_SORT_PRIO_PRIMARY)
 290                         ts_primary = i;
 291                 if(f == SFL_SORT_PRIO_SECONDARY)
 292                         ts_secondary = i;
 293         }
 294         if(ts_secondary == -1)
 295                 ts_secondary = ts_primary;
 296
 297         Cmd_Sbar_SetFields(0);
 298 }
 299
 300 void Sbar_UpdatePlayerPos(entity pl);
 301 float SetTeam(entity pl, float Team);
 302 //float lastpnum;
 303 void Sbar_UpdatePlayerTeams()
 304 {
 305         float Team;
 306         entity pl, tmp;
 307         float num;
 308
 309         num = 0;
 310         for(pl = players.sort_next; pl; pl = pl.sort_next)
 311         {
 312                 num += 1;
 313                 Team = GetPlayerColor(pl.sv_entnum);
 314                 if(SetTeam(pl, Team))
 315                 {
 316                         tmp = pl.sort_prev;
 317                         Sbar_UpdatePlayerPos(pl);
 318                         if(tmp)
 319                                 pl = tmp;
 320                         else
 321                                 pl = players.sort_next;
 322                 }
 323         }
 324         /*
 325         if(num != lastpnum)
 326                 print(strcat("PNUM: ", ftos(num), "\n"));
 327         lastpnum = num;
 328         */
 329 }
 330
 331 float Sbar_ComparePlayerScores(entity left, entity right)
 332 {
 333         float vl, vr;
 334         vl = GetPlayerColor(left.sv_entnum);
 335         vr = GetPlayerColor(right.sv_entnum);
 336
 337         if(!left.gotscores)
 338                 vl = COLOR_SPECTATOR;
 339         if(!right.gotscores)
 340                 vr = COLOR_SPECTATOR;
 341
 342         if(vl > vr)
 343                 return true;
 344         if(vl < vr)
 345                 return false;
 346
 347         if(vl == COLOR_SPECTATOR)
 348         {
 349                 // FIRST the one with scores (spectators), THEN the ones without (downloaders)
 350                 // no other sorting
 351                 if(!left.gotscores && right.gotscores)
 352                         return true;
 353                 return false;
 354         }
 355
 356         vl = left.scores[ps_primary];
 357         vr = right.scores[ps_primary];
 358         if(scores_flags[ps_primary] & SFL_ZERO_IS_WORST)
 359         {
 360                 if(vl == 0 && vr != 0)
 361                         return 1;
 362                 if(vl != 0 && vr == 0)
 363                         return 0;
 364         }
 365         if(vl > vr)
 366                 return IS_INCREASING(scores_flags[ps_primary]);
 367         if(vl < vr)
 368                 return IS_DECREASING(scores_flags[ps_primary]);
 369
 370         vl = left.scores[ps_secondary];
 371         vr = right.scores[ps_secondary];
 372         if(scores_flags[ps_secondary] & SFL_ZERO_IS_WORST)
 373         {
 374                 if(vl == 0 && vr != 0)
 375                         return 1;
 376                 if(vl != 0 && vr == 0)
 377                         return 0;
 378         }
 379         if(vl > vr)
 380                 return IS_INCREASING(scores_flags[ps_secondary]);
 381         if(vl < vr)
 382                 return IS_DECREASING(scores_flags[ps_secondary]);
 383
 384         return false;
 385 }
 386
 387 void Sbar_UpdatePlayerPos(entity player)
 388 {
 389         for(other = player.sort_next; other && Sbar_ComparePlayerScores(player, other); other = player.sort_next)
 390         {
 391                 SORT_SWAP(player, other);
 392         }
 393         for(other = player.sort_prev; other != players && Sbar_ComparePlayerScores(other, player); other = player.sort_prev)
 394         {
 395                 SORT_SWAP(other, player);
 396         }
 397 }
 398
 399 float Sbar_CompareTeamScores(entity left, entity right)
 400 {
 401         float vl, vr;
 402
 403         if(left.team == COLOR_SPECTATOR)
 404                 return 1;
 405         if(right.team == COLOR_SPECTATOR)
 406                 return 0;
 407
 408         vl = left.teamscores[ts_primary];
 409         vr = right.teamscores[ts_primary];
 410         if(vl > vr)
 411                 return IS_INCREASING(teamscores_flags[ts_primary]);
 412         if(vl < vr)
 413                 return IS_DECREASING(teamscores_flags[ts_primary]);
 414
 415         vl = left.teamscores[ts_secondary];
 416         vr = right.teamscores[ts_secondary];
 417         if(vl > vr)
 418                 return IS_INCREASING(teamscores_flags[ts_secondary]);
 419         if(vl < vr)
 420                 return IS_DECREASING(teamscores_flags[ts_secondary]);
 421
 422         return false;
 423 }
 424
 425 void Sbar_UpdateTeamPos(entity Team)
 426 {
 427         for(other = Team.sort_next; other && Sbar_CompareTeamScores(Team, other); other = Team.sort_next)
 428         {
 429                 SORT_SWAP(Team, other);
 430         }
 431         for(other = Team.sort_prev; other != teams && Sbar_CompareTeamScores(other, Team); other = Team.sort_prev)
 432         {
 433                 SORT_SWAP(other, Team);
 434         }
 435 }
 436
 437 void Cmd_Sbar_Help(float argc)
 438 {
 439         print("You can modify the scoreboard using the ^2sbar_columns_set command.\n");
 440         print("^3|---------------------------------------------------------------|\n");
 441         print("Usage:\n");
 442         print("^2sbar_columns_set default\n");
 443         print("^2sbar_columns_set ^7filed1 field2 ...\n");
 444         print("The following field names are recognized (case insensitive):\n");
 445         print("You can use a ^3|^7 to start the right-aligned fields.\n\n");
 446
 447         print("^3name^7 or ^3nick^7         Name of a player\n");
 448         print("^3ping^7                     Ping time\n");
 449         print("^3pl^7                       Packet loss\n");
 450         print("^3kills^7                    Number of kills\n");
 451         print("^3deaths^7                   Number of deaths\n");
 452         print("^3suicides^7                 Number of suicides\n");
 453         print("^3frags^7                    kills - suicides\n");
 454         print("^3kd^7                       The kill-death ratio\n");
 455         print("^3caps^7                     How often a flag (CTF) or a key (KeyHunt) was captured\n");
 456         print("^3pickups^7                  How often a flag (CTF) or a key (KeyHunt) was picked up\n");
 457         print("^3fckills^7                  Number of flag carrier kills\n");
 458         print("^3returns^7                  Number of flag returns\n");
 459         print("^3drops^7                    Number of flag drops\n");
 460         print("^3lives^7                    Number of lives (LMS)\n");
 461         print("^3rank^7                     Player rank\n");
 462         print("^3pushes^7                   Number of players pushed into void\n");
 463         print("^3destroyed^7                Number of keys destroyed by pushing them into void\n");
 464         print("^3kckills^7                  Number of keys carrier kills\n");
 465         print("^3losses^7                   Number of times a key was lost\n");
 466         print("^3laps^7                     Number of laps finished (race/cts)\n");
 467         print("^3time^7                     Total time raced (race/cts)\n");
 468         print("^3fastest^7                  Time of fastest lap (race/cts)\n");
 469         print("^3ticks^7                    Number of ticks (DOM)\n");
 470         print("^3takes^7                    Number of domination points taken (DOM)\n");
 471         print("^3score^7                    Total score\n\n");
 472
 473         print("Before a field you can put a + or - sign, then a comma separated list\n");
 474         print("of game types, then a slash, to make the field show up only in these\n");
 475         print("or in all but these game types. You can also specify 'all' as a\n");
 476         print("field to show all fields available for the current game mode.\n\n");
 477
 478         print("The special game type names 'teams' and 'noteams' can be used to\n");
 479         print("include/exclude ALL teams/noteams game modes.\n\n");
 480
 481         print("Example: sbar_columns_set name ping pl | +ctf/field3 -dm/field4\n");
 482         print("will display name, ping and pl aligned to the left, and the fields\n");
 483         print("right of the vertical bar aligned to the right.\n");
 484         print("'field3' will only be shown in CTF, and 'field4' will be shown in all\n");
 485         print("other gamemodes except DM.\n");
 486 }
 487
 488 string Sbar_DefaultColumnLayout()
 489 {
 490         return strcat( // fteqcc sucks
 491                 "ping pl name | ",
 492                 "-teams,race,lms/kills -teams,lms/deaths -teams,lms,race/suicides -race,dm,tdm/frags ", // tdm already has this in "score"
 493                 "+ctf/caps +ctf/pickups +ctf/fckills +ctf/returns ",
 494                 "+lms/lives +lms/rank ",
 495                 "+kh/caps +kh/pushes +kh/destroyed ",
 496                 "?+race/laps ?+race/time ?+race/fastest ",
 497                 "+as/objectives +nexball/faults +nexball/goals ",
 498                 "-lms,race,nexball/score");
 499 }
 500
 501 void Cmd_Sbar_SetFields(float argc)
 502 {
 503         float i, j, slash;
 504         string str, pattern;
 505         float digit;
 506         float have_name, have_primary, have_secondary, have_separator;
 507         float missing;
 508
 509         // TODO: re enable with gametype dependant cvars?
 510         if(argc < 2) // no arguments provided
 511                 argc = tokenizebyseparator(strcat("x ", cvar_string("sbar_columns")), " ");
 512
 513         if(argc < 2)
 514                 argc = tokenizebyseparator(strcat("x ", Sbar_DefaultColumnLayout()), " ");
 515
 516         if(argc == 2)
 517         {
 518                 if(argv(1) == "default")
 519                         argc = tokenizebyseparator(strcat("x ", Sbar_DefaultColumnLayout()), " ");
 520                 else if(argv(1) == "all")
 521                 {
 522                         string s;
 523                         s = "ping pl color name |";
 524                         for(i = 0; i < MAX_SCORE; ++i)
 525                         {
 526                                 if(i != ps_primary)
 527                                 if(i != ps_secondary)
 528                                 if(scores_label[i] != "")
 529                                         s = strcat(s, " ", scores_label[i]);
 530                         }
 531                         if(ps_secondary != ps_primary)
 532                                 s = strcat(s, " ", scores_label[ps_secondary]);
 533                         s = strcat(s, " ", scores_label[ps_primary]);
 534                         argc = tokenizebyseparator(strcat("x ", s), " ");
 535                 }
 536         }
 537
 538
 539         sbar_num_fields = 0;
 540
 541         drawfont = sbar_font;
 542         digit = stringwidth("0123456789", FALSE) / 10;
 543
 544         for(i = 0; i < argc - 1; ++i)
 545         {
 546                 float nocomplain;
 547                 str = argv(i+1);
 548
 549                 nocomplain = FALSE;
 550                 if(substring(str, 0, 1) == "?")
 551                 {
 552                         nocomplain = TRUE;
 553                         str = substring(str, 1, strlen(str) - 1);
 554                 }
 555
 556                 slash = strstrofs(str, "/", 0);
 557                 if(slash >= 0)
 558                 {
 559                         pattern = substring(str, 0, slash);
 560                         str = substring(str, slash + 1, strlen(str) - (slash + 1));
 561
 562                         if not(isGametypeInFilter(gametype, teamplay, pattern))
 563                                 continue;
 564                 }
 565
 566                 strunzone(sbar_title[sbar_num_fields]);
 567                 sbar_title[sbar_num_fields] = strzone(str);
 568                 sbar_size[sbar_num_fields] = stringwidth(str, FALSE);
 569                 str = strtolower(str);
 570
 571                 if(str == "ping") {
 572                         sbar_field[sbar_num_fields] = SP_PING;
 573                 } else if(str == "pl") {
 574                         sbar_field[sbar_num_fields] = SP_PL;
 575                 } else if(str == "kd" || str == "kdr" || str == "kdratio" || str == "k/d") {
 576                         sbar_field[sbar_num_fields] = SP_KDRATIO;
 577                 } else if(str == "name" || str == "nick") {
 578                         sbar_field[sbar_num_fields] = SP_NAME;
 579                         have_name = 1;
 580                 } else if(str == "|") {
 581                         sbar_field[sbar_num_fields] = SP_SEPARATOR;
 582                         have_separator = 1;
 583                 } else {
 584                         for(j = 0; j < MAX_SCORE; ++j)
 585                                 if(str == strtolower(scores_label[j]))
 586                                         goto found; // sorry, but otherwise fteqcc -O3 miscompiles this and warns about "unreachable code"
 587 :notfound
 588                         if(str == "frags")
 589                         {
 590                                 j = SP_FRAGS;
 591                         }
 592                         else
 593                         {
 594                                 if not(nocomplain)
 595                                         print(strcat("^1Error:^7 Unknown score field: '", str, "'\n"));
 596                                 continue;
 597                         }
 598 :found
 599                         sbar_field[sbar_num_fields] = j;
 600                         if(j == ps_primary)
 601                                 have_primary = 1;
 602                         if(j == ps_secondary)
 603                                 have_secondary = 1;
 604                 }
 605                 ++sbar_num_fields;
 606                 if(sbar_num_fields >= MAX_SBAR_FIELDS)
 607                         break;
 608         }
 609
 610         if(scores_flags[ps_primary] & SFL_ALLOW_HIDE)
 611                 have_primary = 1;
 612         if(scores_flags[ps_secondary] & SFL_ALLOW_HIDE)
 613                 have_secondary = 1;
 614         if(ps_primary == ps_secondary)
 615                 have_secondary = 1;
 616         missing = (!have_primary) + (!have_secondary) + (!have_separator) + (!have_name);
 617
 618         if(sbar_num_fields+missing < MAX_SBAR_FIELDS)
 619         {
 620                 if(!have_name)
 621                 {
 622                         strunzone(sbar_title[sbar_num_fields]);
 623                         for(i = sbar_num_fields; i > 0; --i)
 624                         {
 625                                 sbar_title[i] = sbar_title[i-1];
 626                                 sbar_size[i] = sbar_size[i-1];
 627                                 sbar_field[i] = sbar_field[i-1];
 628                         }
 629                         sbar_title[0] = strzone("name");
 630                         sbar_field[0] = SP_NAME;
 631                         ++sbar_num_fields;
 632                         print("fixed missing field 'name'\n");
 633
 634                         if(!have_separator)
 635                         {
 636                                 strunzone(sbar_title[sbar_num_fields]);
 637                                 for(i = sbar_num_fields; i > 1; --i)
 638                                 {
 639                                         sbar_title[i] = sbar_title[i-1];
 640                                         sbar_size[i] = sbar_size[i-1];
 641                                         sbar_field[i] = sbar_field[i-1];
 642                                 }
 643                                 sbar_title[1] = strzone("|");
 644                                 sbar_field[1] = SP_SEPARATOR;
 645                                 sbar_size[1] = stringwidth("|", FALSE);
 646                                 ++sbar_num_fields;
 647                                 print("fixed missing field '|'\n");
 648                         }
 649                 }
 650                 else if(!have_separator)
 651                 {
 652                         strunzone(sbar_title[sbar_num_fields]);
 653                         sbar_title[sbar_num_fields] = strzone("|");
 654                         sbar_size[sbar_num_fields] = stringwidth("|", FALSE);
 655                         sbar_field[sbar_num_fields] = SP_SEPARATOR;
 656                         ++sbar_num_fields;
 657                         print("fixed missing field '|'\n");
 658                 }
 659                 if(!have_secondary)
 660                 {
 661                         strunzone(sbar_title[sbar_num_fields]);
 662                         sbar_title[sbar_num_fields] = strzone(scores_label[ps_secondary]);
 663                         sbar_size[sbar_num_fields] = stringwidth(sbar_title[sbar_num_fields], FALSE);
 664                         sbar_field[sbar_num_fields] = ps_secondary;
 665                         ++sbar_num_fields;
 666                         print("fixed missing field '", scores_label[ps_secondary], "'\n");
 667                 }
 668                 if(!have_primary)
 669                 {
 670                         strunzone(sbar_title[sbar_num_fields]);
 671                         sbar_title[sbar_num_fields] = strzone(scores_label[ps_primary]);
 672                         sbar_size[sbar_num_fields] = stringwidth(sbar_title[sbar_num_fields], FALSE);
 673                         sbar_field[sbar_num_fields] = ps_primary;
 674                         ++sbar_num_fields;
 675                         print("fixed missing field '", scores_label[ps_primary], "'\n");
 676                 }
 677         }
 678
 679         sbar_field[sbar_num_fields] = SP_END;
 680 }
 681
 682 // MOVEUP::
 683 vector sbar_field_rgb;
 684 string sbar_field_icon0;
 685 string sbar_field_icon1;
 686 string sbar_field_icon2;
 687 vector sbar_field_icon0_rgb;
 688 vector sbar_field_icon1_rgb;
 689 vector sbar_field_icon2_rgb;
 690 float sbar_field_icon0_alpha;
 691 float sbar_field_icon1_alpha;
 692 float sbar_field_icon2_alpha;
 693 string Sbar_GetField(entity pl, float field)
 694 {
 695         float tmp, num, denom, f;
 696         string str;
 697         sbar_field_rgb = '1 1 1';
 698         sbar_field_icon0 = "";
 699         sbar_field_icon1 = "";
 700         sbar_field_icon2 = "";
 701         sbar_field_icon0_rgb = '1 1 1';
 702         sbar_field_icon1_rgb = '1 1 1';
 703         sbar_field_icon2_rgb = '1 1 1';
 704         sbar_field_icon0_alpha = 1;
 705         sbar_field_icon1_alpha = 1;
 706         sbar_field_icon2_alpha = 1;
 707         switch(field)
 708         {
 709                 case SP_PING:
 710                         if not(pl.gotscores)
 711                                 return "\x8D\x8D\x8D"; // >>> sign
 712                         str = getplayerkey(pl.sv_entnum, "ping");
 713                         if(str == "0")
 714                                 return "N/A";
 715                         tmp = max(0, min(220, stof(str)-80)) / 220;
 716                         sbar_field_rgb = '1 1 1' - '0 1 1'*tmp;
 717                         return str;
 718
 719                 case SP_PL:
 720                         if not(pl.gotscores)
 721                                 return "N/A";
 722                         str = getplayerkey(pl.sv_entnum, "pl");
 723                         if(str == "0")
 724                                 return "";
 725                         tmp = bound(0, stof(str), 20) / 20; // 20% is REALLY BAD pl
 726                         sbar_field_rgb = '1 0.5 0.5' - '0 0.5 0.5'*tmp;
 727                         return str;
 728
 729                 case SP_NAME:
 730                         if(ready_waiting && pl.ready)
 731                         {
 732                                 sbar_field_icon0 = "gfx/sb_player_ready";
 733                         }
 734                         else if(!teamplay)
 735                         {
 736                                 f = stof(getplayerkey(pl.sv_entnum, "colors"));
 737                                 {
 738                                         sbar_field_icon0 = "gfx/sb_playercolor_base";
 739                                         sbar_field_icon1 = "gfx/sb_playercolor_shirt";
 740                                         sbar_field_icon1_rgb = colormapPaletteColor(floor(f / 16), 0);
 741                                         sbar_field_icon2 = "gfx/sb_playercolor_pants";
 742                                         sbar_field_icon2_rgb = colormapPaletteColor(mod(f, 16), 1);
 743                                 }
 744                         }
 745                         return GetPlayerName(pl.sv_entnum);
 746
 747                 case SP_FRAGS:
 748                         f = pl.(scores[SP_KILLS]);
 749                         f -= pl.(scores[SP_SUICIDES]);
 750                         return ftos(f);
 751
 752                 case SP_KDRATIO:
 753                         num = pl.(scores[SP_KILLS]);
 754                         denom = pl.(scores[SP_DEATHS]);
 755
 756                         if(denom == 0) {
 757                                 sbar_field_rgb = '0 1 0';
 758                                 str = ftos(num);
 759                         } else if(num <= 0) {
 760                                 sbar_field_rgb = '1 0 0';
 761                                 str = ftos(num/denom);
 762                         } else
 763                                 str = ftos(num/denom);
 764
 765                         tmp = strstrofs(str, ".", 0);
 766                         if(tmp > 0)
 767                                 str = substring(str, 0, tmp+2);
 768                         return str;
 769
 770                 default:
 771                         tmp = pl.(scores[field]);
 772                         f = scores_flags[field];
 773                         if(field == ps_primary)
 774                                 sbar_field_rgb = '1 1 0';
 775                         else if(field == ps_secondary)
 776                                 sbar_field_rgb = '0 1 1';
 777                         else
 778                                 sbar_field_rgb = '1 1 1';
 779                         return ScoreString(f, tmp);
 780         }
 781         //return "error";
 782 }
 783
 784 float xmin, xmax, ymin, ymax, sbwidth;
 785 float sbar_fixscoreboardcolumnwidth_len;
 786 float sbar_fixscoreboardcolumnwidth_iconlen;
 787 float sbar_fixscoreboardcolumnwidth_marginlen;
 788
 789 float stringwidth_colors(string s)
 790 {
 791         return stringwidth(s, TRUE);
 792 }
 793
 794 float stringwidth_nocolors(string s)
 795 {
 796         return stringwidth(s, FALSE);
 797 }
 798
 799 string Sbar_FixScoreboardColumnWidth(float i, string str)
 800 {
 801         float field, f;
 802         vector sz;
 803         field = sbar_field[i];
 804
 805         sbar_fixscoreboardcolumnwidth_iconlen = 0;
 806
 807         if(sbar_field_icon0 != "")
 808         {
 809                 sz = drawgetimagesize(sbar_field_icon0);
 810                 f = sz_x / sz_y;
 811                 if(sbar_fixscoreboardcolumnwidth_iconlen < f)
 812                         sbar_fixscoreboardcolumnwidth_iconlen = f;
 813         }
 814
 815         if(sbar_field_icon1 != "")
 816         {
 817                 sz = drawgetimagesize(sbar_field_icon1);
 818                 f = sz_x / sz_y;
 819                 if(sbar_fixscoreboardcolumnwidth_iconlen < f)
 820                         sbar_fixscoreboardcolumnwidth_iconlen = f;
 821         }
 822
 823         if(sbar_field_icon2 != "")
 824         {
 825                 sz = drawgetimagesize(sbar_field_icon2);
 826                 f = sz_x / sz_y;
 827                 if(sbar_fixscoreboardcolumnwidth_iconlen < f)
 828                         sbar_fixscoreboardcolumnwidth_iconlen = f;
 829         }
 830
 831         sbar_fixscoreboardcolumnwidth_iconlen *= sbar_fontsize_y / sbar_fontsize_x; // fix icon aspect
 832
 833         if(sbar_fixscoreboardcolumnwidth_iconlen != 0)
 834                 sbar_fixscoreboardcolumnwidth_marginlen = stringwidth(" ", FALSE);
 835         else
 836                 sbar_fixscoreboardcolumnwidth_marginlen = 0;
 837
 838         if(field == SP_NAME) // name gets all remaining space
 839         {
 840                 float namesize, j;
 841                 namesize = sbwidth / sbar_fontsize_x;
 842                 for(j = 0; j < sbar_num_fields; ++j)
 843                         if(j != i)
 844                                 if (sbar_field[i] != SP_SEPARATOR)
 845                                         namesize -= sbar_size[j] + 1;
 846                 namesize += 1;
 847                 sbar_size[i] = namesize;
 848
 849                 if (sbar_fixscoreboardcolumnwidth_iconlen != 0)
 850                         namesize -= sbar_fixscoreboardcolumnwidth_marginlen + sbar_fixscoreboardcolumnwidth_iconlen;
 851                 str = textShortenToWidth(str, namesize, stringwidth_colors);
 852                 sbar_fixscoreboardcolumnwidth_len = stringwidth(str, TRUE);
 853         }
 854         else
 855                 sbar_fixscoreboardcolumnwidth_len = stringwidth(str, FALSE);
 856
 857         f = sbar_fixscoreboardcolumnwidth_len + sbar_fixscoreboardcolumnwidth_marginlen + sbar_fixscoreboardcolumnwidth_iconlen;
 858         if(sbar_size[i] < f)
 859                 sbar_size[i] = f;
 860
 861         return str;
 862 }
 863
 864 void Sbar_PrintScoreboardItem(vector pos, entity pl, float is_self, float pl_number)
 865 {
 866         vector tmp, rgb;
 867         rgb = GetTeamRGB(pl.team);
 868         string str;
 869         float i, field;
 870         float is_spec;
 871         is_spec = (GetPlayerColor(pl.sv_entnum) == COLOR_SPECTATOR);
 872
 873         if((rgb == '1 1 1') && (!is_spec)) {
 874                 rgb_x = cvar("sbar_color_bg_r") + 0.5;
 875                 rgb_y = cvar("sbar_color_bg_g") + 0.5;
 876                 rgb_z = cvar("sbar_color_bg_b") + 0.5; }
 877
 878         // Layout:
 879         tmp_x = sbwidth;
 880         tmp_y = sbar_fontsize_y * 1.25;
 881         tmp_z = 0;
 882
 883         // alternated rows highlighting
 884         if(is_self)
 885                 drawfill(pos - '1 1 0', tmp + '2 0 0', rgb, sbar_scoreboard_highlight_alpha_self, DRAWFLAG_NORMAL);
 886         else if((sbar_scoreboard_highlight) && (!mod(pl_number,2)))
 887                 drawfill(pos - '1 1 0', tmp + '2 0 0', rgb, sbar_scoreboard_highlight_alpha, DRAWFLAG_NORMAL);
 888
 889         tmp_y = 0;
 890
 891         for(i = 0; i < sbar_num_fields; ++i)
 892         {
 893                 field = sbar_field[i];
 894                 if(field == SP_SEPARATOR)
 895                         break;
 896
 897                 if(is_spec && field != SP_NAME && field != SP_PING) {
 898                         pos_x += sbar_fontsize_x*sbar_size[i] + sbar_fontsize_x;
 899                         continue;
 900                 }
 901                 str = Sbar_GetField(pl, field);
 902                 str = Sbar_FixScoreboardColumnWidth(i, str);
 903
 904                 pos_x += sbar_fontsize_x*sbar_size[i] + sbar_fontsize_x;
 905
 906                 if(field == SP_NAME) {
 907                         tmp_x = sbar_fontsize_x*(sbar_size[i] - sbar_fixscoreboardcolumnwidth_iconlen - sbar_fixscoreboardcolumnwidth_marginlen) + sbar_fontsize_x;
 908                         if (is_self)
 909                                 drawcolorcodedstring(pos - tmp, str, sbar_fontsize, sbar_scoreboard_alpha_name_self, DRAWFLAG_NORMAL);
 910                         else
 911                                 drawcolorcodedstring(pos - tmp, str, sbar_fontsize, sbar_scoreboard_alpha_name, DRAWFLAG_NORMAL);
 912                 } else {
 913                         tmp_x = sbar_fixscoreboardcolumnwidth_len*sbar_fontsize_x + sbar_fontsize_x;
 914                         if (is_self)
 915                                 drawstring(pos - tmp, str, sbar_fontsize, sbar_field_rgb, sbar_scoreboard_alpha_name_self, DRAWFLAG_NORMAL);
 916                         else
 917                                 drawstring(pos - tmp, str, sbar_fontsize, sbar_field_rgb, sbar_scoreboard_alpha_name, DRAWFLAG_NORMAL);
 918                 }
 919
 920                 tmp_x = sbar_fontsize_x*sbar_size[i] + sbar_fontsize_x;
 921                 if(sbar_field_icon0 != "")
 922                         if (is_self)
 923                                 drawpic(pos - tmp, sbar_field_icon0, '0 1 0' * sbar_fontsize_y + '1 0 0' * sbar_fontsize_x * sbar_fixscoreboardcolumnwidth_iconlen, sbar_field_icon1_rgb, sbar_field_icon0_alpha * sbar_scoreboard_alpha_name_self, DRAWFLAG_NORMAL);
 924                         else
 925                                 drawpic(pos - tmp, sbar_field_icon0, '0 1 0' * sbar_fontsize_y + '1 0 0' * sbar_fontsize_x * sbar_fixscoreboardcolumnwidth_iconlen, sbar_field_icon1_rgb, sbar_field_icon0_alpha * sbar_scoreboard_alpha_name, DRAWFLAG_NORMAL);
 926                 if(sbar_field_icon1 != "")
 927                         if (is_self)
 928                                 drawpic(pos - tmp, sbar_field_icon1, '0 1 0' * sbar_fontsize_y + '1 0 0' * sbar_fontsize_x * sbar_fixscoreboardcolumnwidth_iconlen, sbar_field_icon1_rgb, sbar_field_icon1_alpha * sbar_scoreboard_alpha_name_self, DRAWFLAG_NORMAL);
 929                         else
 930                                 drawpic(pos - tmp, sbar_field_icon1, '0 1 0' * sbar_fontsize_y + '1 0 0' * sbar_fontsize_x * sbar_fixscoreboardcolumnwidth_iconlen, sbar_field_icon1_rgb, sbar_field_icon1_alpha * sbar_scoreboard_alpha_name, DRAWFLAG_NORMAL);
 931                 if(sbar_field_icon2 != "")
 932                         if (is_self)
 933                                 drawpic(pos - tmp, sbar_field_icon2, '0 1 0' * sbar_fontsize_y + '1 0 0' * sbar_fontsize_x * sbar_fixscoreboardcolumnwidth_iconlen, sbar_field_icon2_rgb, sbar_field_icon2_alpha * sbar_scoreboard_alpha_name_self, DRAWFLAG_NORMAL);
 934                         else
 935                                 drawpic(pos - tmp, sbar_field_icon2, '0 1 0' * sbar_fontsize_y + '1 0 0' * sbar_fontsize_x * sbar_fixscoreboardcolumnwidth_iconlen, sbar_field_icon2_rgb, sbar_field_icon2_alpha * sbar_scoreboard_alpha_name, DRAWFLAG_NORMAL);
 936         }
 937
 938         if(sbar_field[i] == SP_SEPARATOR)
 939         {
 940                 pos_x = xmax;
 941                 for(i = sbar_num_fields-1; i > 0; --i)
 942                 {
 943                         field = sbar_field[i];
 944                         if(field == SP_SEPARATOR)
 945                                 break;
 946
 947                         if(is_spec && field != SP_NAME && field != SP_PING) {
 948                                 pos_x -= sbar_fontsize_x*sbar_size[i] + sbar_fontsize_x;
 949                                 continue;
 950                         }
 951
 952                         str = Sbar_GetField(pl, field);
 953                         str = Sbar_FixScoreboardColumnWidth(i, str);
 954
 955                         if(field == SP_NAME) {
 956                                 tmp_x = sbar_fontsize_x*sbar_fixscoreboardcolumnwidth_len; // left or right aligned? let's put it right...
 957                                 if(is_self)
 958                                         drawcolorcodedstring(pos - tmp, str, sbar_fontsize, sbar_scoreboard_alpha_name_self, DRAWFLAG_NORMAL);
 959                                 else
 960                                         drawcolorcodedstring(pos - tmp, str, sbar_fontsize, sbar_scoreboard_alpha_name, DRAWFLAG_NORMAL);
 961                         } else {
 962                                 tmp_x = sbar_fontsize_x*sbar_fixscoreboardcolumnwidth_len;
 963                                 if(is_self)
 964                                         drawstring(pos - tmp, str, sbar_fontsize, sbar_field_rgb, sbar_scoreboard_alpha_name_self, DRAWFLAG_NORMAL);
 965                                 else
 966                                         drawstring(pos - tmp, str, sbar_fontsize, sbar_field_rgb, sbar_scoreboard_alpha_name, DRAWFLAG_NORMAL);
 967                         }
 968
 969                         tmp_x = sbar_fontsize_x*sbar_size[i];
 970                         if(sbar_field_icon0 != "")
 971                                 if (is_self)
 972                                         drawpic(pos - tmp, sbar_field_icon0, '0 1 0' * sbar_fontsize_y + '1 0 0' * sbar_fontsize_x * sbar_fixscoreboardcolumnwidth_iconlen, sbar_field_icon1_rgb, sbar_field_icon0_alpha * sbar_scoreboard_alpha_name_self, DRAWFLAG_NORMAL);
 973                                 else
 974                                         drawpic(pos - tmp, sbar_field_icon0, '0 1 0' * sbar_fontsize_y + '1 0 0' * sbar_fontsize_x * sbar_fixscoreboardcolumnwidth_iconlen, sbar_field_icon1_rgb, sbar_field_icon0_alpha * sbar_scoreboard_alpha_name, DRAWFLAG_NORMAL);
 975                         if(sbar_field_icon1 != "")
 976                                 if (is_self)
 977                                         drawpic(pos - tmp, sbar_field_icon1, '0 1 0' * sbar_fontsize_y + '1 0 0' * sbar_fontsize_x * sbar_fixscoreboardcolumnwidth_iconlen, sbar_field_icon1_rgb, sbar_field_icon1_alpha * sbar_scoreboard_alpha_name_self, DRAWFLAG_NORMAL);
 978                                 else
 979                                         drawpic(pos - tmp, sbar_field_icon1, '0 1 0' * sbar_fontsize_y + '1 0 0' * sbar_fontsize_x * sbar_fixscoreboardcolumnwidth_iconlen, sbar_field_icon1_rgb, sbar_field_icon1_alpha * sbar_scoreboard_alpha_name, DRAWFLAG_NORMAL);
 980                         if(sbar_field_icon2 != "")
 981                                 if (is_self)
 982                                         drawpic(pos - tmp, sbar_field_icon2, '0 1 0' * sbar_fontsize_y + '1 0 0' * sbar_fontsize_x * sbar_fixscoreboardcolumnwidth_iconlen, sbar_field_icon2_rgb, sbar_field_icon2_alpha * sbar_scoreboard_alpha_name_self, DRAWFLAG_NORMAL);
 983                                 else
 984                                         drawpic(pos - tmp, sbar_field_icon2, '0 1 0' * sbar_fontsize_y + '1 0 0' * sbar_fontsize_x * sbar_fixscoreboardcolumnwidth_iconlen, sbar_field_icon2_rgb, sbar_field_icon2_alpha * sbar_scoreboard_alpha_name, DRAWFLAG_NORMAL);
 985                         pos_x -= sbar_fontsize_x*sbar_size[i] + sbar_fontsize_x;
 986                 }
 987         }
 988 }
 989
 990 /*
 991  * Sbar_Scoreboard_MakeTable
 992  *
 993  * Makes a table for a team (for all playing players in DM) and fills it
 994  */
 995
 996 vector Sbar_Scoreboard_MakeTable(vector pos, entity tm, vector rgb, vector bg_size)
 997 {
 998         float body_table_height, i;
 999         vector tmp, column_dim;
1000         entity pl;
1001
1002         body_table_height = 1.25 * sbar_fontsize_y * max(1, tm.team_size); // no player? show 1 empty line
1003
1004         pos -= '1 1 0';
1005
1006         tmp_x = sbwidth + 2;
1007         tmp_y = 1.25 * sbar_fontsize_y;
1008
1009         // rounded header
1010         drawpic(pos, "gfx/hud/sb_scoreboard_tableheader", tmp, (rgb * sbar_color_bg_team) + '0.5 0.5 0.5', sbar_scoreboard_alpha_bg, DRAWFLAG_NORMAL);
1011
1012         // table border
1013         tmp_y += sbar_border_thickness;
1014         tmp_y += body_table_height;
1015         drawborderlines(sbar_border_thickness, pos, tmp, '0 0 0', sbar_scoreboard_alpha_bg, DRAWFLAG_NORMAL); // more transparency for the scoreboard
1016
1017         // separator header/table
1018         pos_y += 1.25 * sbar_fontsize_y;
1019         tmp_y = sbar_border_thickness;
1020         drawfill(pos, tmp, '0 0 0', sbar_scoreboard_alpha_bg, DRAWFLAG_NORMAL);
1021
1022         pos_y += sbar_border_thickness;
1023
1024         // table background
1025         tmp_y = body_table_height;
1026         drawpic_tiled(pos, "gfx/hud/sb_scoreboard_bg", bg_size, tmp, rgb * sbar_color_bg_team, sbar_scoreboard_alpha_bg, DRAWFLAG_NORMAL);
1027
1028         // anyway, apply some color
1029         //drawfill(pos, tmp + '2 0 0', rgb, 0.1, DRAWFLAG_NORMAL);
1030
1031         // go back to the top to make alternated columns highlighting and to print the strings
1032         pos_y -= 1.25 * sbar_fontsize_y;
1033         pos_y -= sbar_border_thickness;
1034
1035         pos += '1 1 0';
1036
1037         if (sbar_scoreboard_highlight)
1038         {
1039                 column_dim_y = 1.25 * sbar_fontsize_y; // header
1040                 column_dim_y += sbar_border_thickness;
1041                 column_dim_y += body_table_height;
1042         }
1043
1044         // print the strings of the columns headers and draw the columns
1045         for(i = 0; i < sbar_num_fields; ++i)
1046         {
1047                 if(sbar_field[i] == SP_SEPARATOR)
1048                         break;
1049                 column_dim_x = sbar_fontsize_x*sbar_size[i] + sbar_fontsize_x;
1050                 if (sbar_scoreboard_highlight)
1051                 {
1052                         if (mod(i,2))
1053                                 drawfill(pos - '0 1 0' - sbar_fontsize_x / 2 * '1 0 0', column_dim, '0 0 0', sbar_scoreboard_alpha_bg * 0.2, DRAWFLAG_NORMAL);
1054                 }
1055                 drawstring(pos, sbar_title[i], sbar_fontsize, rgb * 1.5, sbar_scoreboard_alpha_fg, DRAWFLAG_NORMAL);
1056                 pos_x += column_dim_x;
1057         }
1058         if(sbar_field[i] == SP_SEPARATOR)
1059         {
1060                 pos_x = xmax;
1061                 tmp_y = 0;
1062                 for(i = sbar_num_fields-1; i > 0; --i)
1063                 {
1064                         if(sbar_field[i] == SP_SEPARATOR)
1065                                 break;
1066
1067                         pos_x -= sbar_size[i]*sbar_fontsize_x;
1068
1069                         if (sbar_scoreboard_highlight)
1070                         {
1071                                 if (!mod(i,2))
1072                                 {
1073                                         if (i == sbar_num_fields-1)
1074                                                 column_dim_x = sbar_fontsize_x*sbar_size[i] + sbar_fontsize_x / 2 + 1;
1075                                         else
1076                                                 column_dim_x = sbar_fontsize_x*sbar_size[i] + sbar_fontsize_x;
1077                                         drawfill(pos - '0 1 0' - sbar_fontsize_x / 2 * '1 0 0', column_dim, '0 0 0', sbar_scoreboard_alpha_bg * 0.2, DRAWFLAG_NORMAL);
1078                                 }
1079                         }
1080
1081                         tmp_x = stringwidth(sbar_title[i], FALSE);
1082                         tmp_x = (sbar_size[i] - tmp_x) * sbar_fontsize_x;
1083                         drawstring(pos + tmp, sbar_title[i], sbar_fontsize, rgb * 1.5, sbar_scoreboard_alpha_fg, DRAWFLAG_NORMAL);
1084                         pos_x -= sbar_fontsize_x;
1085                 }
1086         }
1087
1088         pos_x = xmin;
1089         pos_y += 1.25 * sbar_fontsize_y; // skip the header
1090         pos_y += sbar_border_thickness;
1091
1092         // fill the table and draw the rows
1093         i = 0;
1094         if (teamplay)
1095                 for(pl = players.sort_next; pl; pl = pl.sort_next)
1096                 {
1097                         if(pl.team != tm.team)
1098                                 continue;
1099                         Sbar_PrintScoreboardItem(pos, pl, (pl.sv_entnum == player_localentnum - 1), i);
1100                         pos_y += 1.25 * sbar_fontsize_y;
1101                         ++i;
1102                 }
1103         else
1104                 for(pl = players.sort_next; pl; pl = pl.sort_next)
1105                 {
1106                         if(pl.team == COLOR_SPECTATOR)
1107                                 continue;
1108                         Sbar_PrintScoreboardItem(pos, pl, (pl.sv_entnum == player_localentnum - 1), i);
1109                         pos_y += 1.25 * sbar_fontsize_y;
1110                         ++i;
1111                 }
1112
1113         if (i == 0)
1114                 pos_y += 1.25 * sbar_fontsize_y; // move to the end of the table
1115         pos_y += 1.25 * sbar_fontsize_y; // move empty row (out of the table)
1116
1117         return pos;
1118 }
1119
1120 float Sbar_WouldDrawScoreboard() {
1121         if (sb_showscores)
1122                 return 1;
1123         else if (intermission == 1)
1124                 return 1;
1125         else if (intermission == 2)
1126                 return 1;
1127         else if (getstati(STAT_HEALTH) <= 0 && cvar("cl_deathscoreboard"))
1128                 return 1;
1129         else if(sb_showscores_force)
1130                 return 1;
1131         return 0;
1132 }
1133
1134 float g_minstagib;
1135 float average_accuracy;
1136 vector Sbar_DrawScoreboardAccuracyStats(vector pos, vector rgb, vector bg_size)
1137 {
1138         float i;
1139         float weapon_hit, weapon_damage, weapon_stats;
1140         float fontsize = 40 * 1/3;
1141         float weapon_cnt = 12;
1142         float rows;
1143         if(cvar("sbar_accuracy_doublerows"))
1144                 rows = 2;
1145         else
1146                 rows = 1;
1147         float height = 40;
1148
1149         if(warmup_stage)
1150         {
1151                 return pos;
1152         }
1153
1154         drawstring(pos, strcat("Accuracy stats (average ", ftos(average_accuracy), "%)"), sbar_fontsize, '1 1 1', sbar_scoreboard_alpha_fg, DRAWFLAG_NORMAL);
1155         pos_y += 18;
1156         vector tmp;
1157         tmp_x = sbwidth;
1158         tmp_y = height * rows;
1159
1160         drawpic_tiled(pos, "gfx/hud/sb_scoreboard_bg", bg_size, tmp, rgb * sbar_color_bg_team, sbar_scoreboard_alpha_bg, DRAWFLAG_NORMAL);
1161         drawborderlines(sbar_accuracy_border_thickness, pos, tmp, '0 0 0', sbar_scoreboard_alpha_bg * 0.75, DRAWFLAG_NORMAL);
1162
1163         // column highlighting
1164         for(i = 0; i < weapon_cnt/rows; ++i)
1165         {
1166                 if(!mod(i, 2))
1167                         drawfill(pos + '1 0 0' * (sbwidth/weapon_cnt) * rows * i, '0 1 0' * height * rows + '1 0 0' * (sbwidth/weapon_cnt) * rows, '0 0 0', sbar_scoreboard_alpha_bg * 0.2, DRAWFLAG_NORMAL);
1168         }
1169
1170         // row highlighting
1171         for(i = 0; i < rows; ++i)
1172         {
1173                 drawfill(pos + '0 1 0' * height * (2/3) + '0 1 0' * height * i, '1 0 0' * sbwidth + '0 1 0' * fontsize, '1 1 1', sbar_scoreboard_highlight_alpha, DRAWFLAG_NORMAL);
1174         }
1175
1176         drawfont = sbar_bigfont;
1177         average_accuracy = 0;
1178         float weapons_with_stats;
1179         weapons_with_stats = 0;
1180         if(rows == 2)
1181                 pos_x += sbwidth/weapon_cnt / 2;
1182
1183         if(getstati(STAT_SWITCHWEAPON) == WEP_MINSTANEX)
1184                 g_minstagib = 1; // TODO: real detection for minstagib?
1185
1186         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
1187         {
1188                 if ((i == WEP_NEX && g_minstagib) || i == WEP_PORTO || (i == WEP_MINSTANEX && !g_minstagib) || i == WEP_TUBA || i == WEP_FIREBALL) // skip port-o-launch, nex || minstanex, tuba and fireball
1189                         continue;
1190                 weapon_hit = weapon_hits[i];
1191                 weapon_damage = weapon_fired[i];
1192                 if(weapon_damage)
1193                         weapon_stats = bound(0, rint(100 * weapon_hit / weapon_damage), 100);
1194                 self = get_weaponinfo(i);
1195                 float weapon_alpha;
1196
1197                 if(weapon_damage)
1198                         weapon_alpha = sbar_scoreboard_alpha_fg;
1199                 else
1200                         weapon_alpha = 0.2 * sbar_scoreboard_alpha_fg;
1201
1202                 // weapon icon
1203                 drawpic(pos, strcat("gfx/hud/inv_weapon", ftos(i-1)), '1 0 0' * sbwidth * (1/weapon_cnt) + '0 1 0' * height * (2/3), '1 1 1', weapon_alpha, DRAWFLAG_NORMAL);
1204                 // the accuracy
1205                 if(weapon_damage) {
1206                         weapons_with_stats += 1;
1207                         average_accuracy += weapon_stats; // store sum of all accuracies in average_accuracy
1208
1209                         string s;
1210                         s = strcat(ftos(weapon_stats),"%");
1211
1212                         float padding;
1213                         padding = ((sbwidth/weapon_cnt) - stringwidth(s, FALSE) * fontsize) / 2; // center the accuracy value
1214
1215                         vector color;
1216                         color = Sbar_AccuracyColor(weapon_stats);
1217                         drawstring(pos + '1 0 0' * padding + '0 1 0' * height * (2/3), s, '1 1 0' * fontsize, color, sbar_scoreboard_alpha_fg, DRAWFLAG_NORMAL);
1218                 }
1219                 pos_x += sbwidth/weapon_cnt * rows;
1220                 if(rows == 2 && i == 6) {
1221                         pos_x -= sbwidth;
1222                         pos_y += height;
1223                 }
1224         }
1225         drawfont = sbar_font;
1226
1227         if(weapons_with_stats)
1228                 average_accuracy = floor(average_accuracy / weapons_with_stats);
1229
1230         if(rows == 2)
1231                 pos_x -= sbwidth/weapon_cnt / 2;
1232         pos_x -= sbwidth;
1233         pos_y += height;
1234         return pos;
1235 }
1236
1237 float lastpingstime;
1238 float scoreboard_bottom;
1239 float sbar_scoreboard_fade_alpha;
1240 float sbar_woulddrawscoreboard_prev;
1241 float sbar_woulddrawscoreboard_change; // "time" at which Sbar_WouldDrawScoreboard() changed
1242 void Sbar_DrawScoreboard()
1243 {
1244         float sbar_woulddrawscoreboard;
1245         sbar_woulddrawscoreboard = Sbar_WouldDrawScoreboard();
1246         if(sbar_woulddrawscoreboard != sbar_woulddrawscoreboard_prev) {
1247                 sbar_woulddrawscoreboard_change = time;
1248                 sbar_woulddrawscoreboard_prev = sbar_woulddrawscoreboard;
1249         }
1250
1251         float scoreboard_fadeinspeed = cvar_or("sbar_scoreboard_fadeinspeed", 10);
1252         float scoreboard_fadeoutspeed = cvar_or("sbar_scoreboard_fadeoutspeed", 5);
1253         if(sbar_woulddrawscoreboard) {
1254                 if (scoreboard_fadeinspeed)
1255                         sbar_scoreboard_fade_alpha = bound (0, (time - sbar_woulddrawscoreboard_change) * scoreboard_fadeinspeed, 1);
1256                 else
1257                         sbar_scoreboard_fade_alpha = 1;
1258         }
1259         else
1260                 if (scoreboard_fadeoutspeed)
1261                         sbar_scoreboard_fade_alpha = bound (0, (1/scoreboard_fadeoutspeed - (time - sbar_woulddrawscoreboard_change)) * scoreboard_fadeoutspeed, 1);
1262                 else
1263                         sbar_scoreboard_fade_alpha = 0;
1264
1265         if not(sbar_scoreboard_fade_alpha)
1266                 return;
1267
1268         sbar_scoreboard_alpha_bg = cvar("sbar_scoreboard_alpha_bg") * sbar_scoreboard_fade_alpha;
1269         sbar_scoreboard_alpha_fg = cvar_or("sbar_scoreboard_alpha_fg", 1.0) * sbar_scoreboard_fade_alpha;
1270         sbar_scoreboard_highlight = cvar("sbar_scoreboard_highlight");
1271         sbar_scoreboard_highlight_alpha = cvar_or("sbar_scoreboard_highlight_alpha", 0.10) * sbar_scoreboard_alpha_fg;
1272         sbar_scoreboard_highlight_alpha_self = cvar_or("sbar_scoreboard_highlight_alpha_self", 0.25) * sbar_scoreboard_alpha_fg;
1273         sbar_scoreboard_alpha_name = cvar_or("sbar_scoreboard_alpha_name", 0.9) * sbar_scoreboard_alpha_fg;
1274         sbar_scoreboard_alpha_name_self = cvar_or("sbar_scoreboard_alpha_name_self", 1) * sbar_scoreboard_alpha_fg;
1275
1276         vector rgb, pos, tmp;
1277         entity pl, tm;
1278
1279         if(time > lastpingstime + bound(1, cvar_or("sbar_pingrefreshinterval", 10), 60)) {
1280                 localcmd("pings\n");
1281                 lastpingstime = time;
1282         }
1283
1284         sbwidth = Sbar_GetWidth(6.5 * sbar_fontsize_y);
1285
1286         xmin = 0.5 * (vid_conwidth - sbwidth);
1287         ymin = SCOREBOARD_OFFSET;
1288
1289         xmax = vid_conwidth - xmin;
1290         ymax = vid_conheight - 0.2*vid_conheight;
1291
1292         // Initializes position
1293         pos_x = xmin;
1294         pos_y = ymin;
1295         pos_z = 0;
1296
1297         // Heading
1298         drawfont = sbar_bigfont;
1299         drawstringcenter('0 1 0' * ymin, "Scoreboard", '24 24 0', '1 1 1', sbar_scoreboard_alpha_fg, DRAWFLAG_NORMAL);
1300
1301         pos_y += 24 + 4;
1302         pos_y += sbar_fontsize_y;
1303
1304         drawfont = sbar_font;
1305
1306         // Draw the scoreboard
1307         vector bg_size;
1308         bg_size = drawgetimagesize("gfx/hud/sb_scoreboard_bg");
1309
1310         if(teamplay)
1311         {
1312                 for(tm = teams.sort_next; tm; tm = tm.sort_next)
1313                 {
1314                         if(tm.team == COLOR_SPECTATOR)
1315                                 continue;
1316
1317                         rgb = GetTeamRGB(tm.team);
1318                         Sbar_DrawXNum(pos - '6.5 0 0' * sbar_fontsize_y + '0 1 0' * sbar_fontsize_y, tm.(teamscores[ts_primary]), 4, 0, sbar_fontsize_y * 1.5, rgb, 0, 1, sbar_scoreboard_alpha_fg, DRAWFLAG_NORMAL);
1319
1320                         if(ts_primary != ts_secondary)
1321                                 Sbar_DrawXNum(pos - '4.5 0 0' * sbar_fontsize_y + '0 2.5 0' * sbar_fontsize_y, tm.(teamscores[ts_secondary]), 4, 0, sbar_fontsize_y * 1, rgb, 0, 1, sbar_scoreboard_alpha_fg, DRAWFLAG_NORMAL);
1322
1323                         pos = Sbar_Scoreboard_MakeTable(pos, tm, rgb, bg_size);
1324                 }
1325         }
1326         else
1327         {
1328                 rgb_x = cvar("sbar_color_bg_r");
1329                 rgb_y = cvar("sbar_color_bg_g");
1330                 rgb_z = cvar("sbar_color_bg_b");
1331
1332                 for(tm = teams.sort_next; tm; tm = tm.sort_next)
1333                 {
1334                         if(tm.team == COLOR_SPECTATOR)
1335                                 continue;
1336
1337                         pos = Sbar_Scoreboard_MakeTable(pos, tm, rgb, bg_size);
1338                 }
1339         }
1340
1341         if(gametype == GAME_CTS || gametype == GAME_RACE) {
1342                 if(race_speedaward) {
1343                         drawcolorcodedstring(pos, strcat("Speed award: ", ftos(race_speedaward), " (", race_speedaward_holder, ")"), sbar_fontsize, sbar_scoreboard_alpha_fg, DRAWFLAG_NORMAL);
1344                         pos_y += 1.25 * sbar_fontsize_y;
1345                 }
1346                 if(race_speedaward_alltimebest) {
1347                         drawcolorcodedstring(pos, strcat("All-time fastest: ", ftos(race_speedaward_alltimebest), " (", race_speedaward_alltimebest_holder, ")"), sbar_fontsize, sbar_scoreboard_alpha_fg, DRAWFLAG_NORMAL);
1348                         pos_y += 1.25 * sbar_fontsize_y;
1349                 }
1350         }
1351         else if(cvar("sbar_accuracy")) {
1352                 if(teamplay)
1353                         pos = Sbar_DrawScoreboardAccuracyStats(pos, GetTeamRGB(myteam), bg_size);
1354                 else
1355                         pos = Sbar_DrawScoreboardAccuracyStats(pos, rgb, bg_size);
1356         }
1357
1358         tmp = pos + '0 1.5 0' * sbar_fontsize_y;
1359         pos_y += 3 * sbar_fontsize_y;
1360
1361         // List spectators
1362         float specs;
1363         specs = 0;
1364         for(pl = players.sort_next; pl; pl = pl.sort_next)
1365         {
1366                 if(pl.team != COLOR_SPECTATOR)
1367                         continue;
1368                 Sbar_PrintScoreboardItem(pos, pl, (pl.sv_entnum == player_localentnum - 1), specs);
1369                 pos_y += 1.25 * sbar_fontsize_y;
1370                 ++specs;
1371         }
1372
1373         if(specs)
1374                 drawstring(tmp, "Spectators", sbar_fontsize, '1 1 1', sbar_scoreboard_alpha_fg, DRAWFLAG_NORMAL);
1375
1376         // Print info string
1377         string str;
1378         float tl, fl, ll;
1379         str = strcat("playing on ^2", shortmapname, "^7");
1380         tl = getstatf(STAT_TIMELIMIT);
1381         fl = getstatf(STAT_FRAGLIMIT);
1382         ll = getstatf(STAT_LEADLIMIT);
1383         if(gametype == GAME_LMS)
1384         {
1385                 if(tl > 0)
1386                         str = strcat(str, " for up to ^1", ftos(tl), " minutes^7");
1387         }
1388         else
1389         {
1390                 if(tl > 0)
1391                         str = strcat(str, " for ^1", ftos(tl), " minutes^7");
1392                 if(fl > 0)
1393                 {
1394                         if(tl > 0)
1395                                 str = strcat(str, " or");
1396                         if(teamplay)
1397                         {
1398                                 str = strcat(str, " until ^3", ScoreString(teamscores_flags[ts_primary], fl));
1399                                 if(teamscores_label[ts_primary] == "score")
1400                                         str = strcat(str, " points^7");
1401                                 else if(teamscores_label[ts_primary] == "fastest")
1402                                         str = strcat(str, " is beaten^7");
1403                                 else
1404                                         str = strcat(str, " ", teamscores_label[ts_primary]);
1405                         }
1406                         else
1407                         {
1408                                 str = strcat(str, " until ^3", ScoreString(scores_flags[ps_primary], fl));
1409                                 if(scores_label[ps_primary] == "score")
1410                                         str = strcat(str, " points^7");
1411                                 else if(scores_label[ps_primary] == "fastest")
1412                                         str = strcat(str, " is beaten^7");
1413                                 else
1414                                         str = strcat(str, " ", scores_label[ps_primary]);
1415                         }
1416                 }
1417                 if(ll > 0)
1418                 {
1419                         if(tl > 0 || fl > 0)
1420                                 str = strcat(str, " or");
1421                         if(teamplay)
1422                         {
1423                                 str = strcat(str, " until a lead of ^3", ScoreString(teamscores_flags[ts_primary], ll));
1424                                 if(teamscores_label[ts_primary] == "score")
1425                                         str = strcat(str, " points^7");
1426                                 else if(teamscores_label[ts_primary] == "fastest")
1427                                         str = strcat(str, " is beaten^7");
1428                                 else
1429                                         str = strcat(str, " ", teamscores_label[ts_primary]);
1430                         }
1431                         else
1432                         {
1433                                 str = strcat(str, " until a lead of ^3", ScoreString(scores_flags[ps_primary], ll));
1434                                 if(scores_label[ps_primary] == "score")
1435                                         str = strcat(str, " points^7");
1436                                 else if(scores_label[ps_primary] == "fastest")
1437                                         str = strcat(str, " is beaten^7");
1438                                 else
1439                                         str = strcat(str, " ", scores_label[ps_primary]);
1440                         }
1441                 }
1442         }
1443
1444
1445         pos_y += 1.2 * sbar_fontsize_y;
1446         drawcolorcodedstring(pos + '0.5 0 0' * (sbwidth - sbar_fontsize_x * stringwidth(str, TRUE)), str, sbar_fontsize, sbar_scoreboard_alpha_fg, DRAWFLAG_NORMAL);
1447
1448         scoreboard_bottom = pos_y + 2 * sbar_fontsize_y;
1449 }
1450
1451 string MakeRaceString(float cp, float mytime, float histime, float lapdelta, string hisname)
1452 {
1453         string col;
1454         string timestr;
1455         string cpname;
1456         string lapstr;
1457         lapstr = "";
1458
1459         if(histime == 0) // goal hit
1460         {
1461                 if(mytime > 0)
1462                 {
1463                         timestr = strcat("+", ftos_decimals(+mytime, TIME_DECIMALS));
1464                         col = "^1";
1465                 }
1466                 else if(mytime == 0)
1467                 {
1468                         timestr = "+0.0";
1469                         col = "^3";
1470                 }
1471                 else
1472                 {
1473                         timestr = strcat("-", ftos_decimals(-mytime, TIME_DECIMALS));
1474                         col = "^2";
1475                 }
1476
1477                 if(lapdelta > 0)
1478                 {
1479                         lapstr = strcat(" (-", ftos(lapdelta), "L)");
1480                         col = "^2";
1481                 }
1482                 else if(lapdelta < 0)
1483                 {
1484                         lapstr = strcat(" (+", ftos(-lapdelta), "L)");
1485                         col = "^1";
1486                 }
1487         }
1488         else if(histime > 0) // anticipation
1489         {
1490                 if(mytime >= histime)
1491                         timestr = strcat("+", ftos_decimals(mytime - histime, TIME_DECIMALS));
1492                 else
1493                         timestr = TIME_ENCODED_TOSTRING(TIME_ENCODE(histime));
1494                 col = "^3";
1495         }
1496         else
1497                 col = "^7";
1498
1499         if(cp == 254)
1500                 cpname = "Start line";
1501         else if(cp == 255)
1502                 cpname = "Finish line";
1503         else if(cp)
1504                 cpname = strcat("Intermediate ", ftos(cp));
1505         else
1506                 cpname = "Finish line";
1507
1508         if(histime < 0)
1509                 return strcat(col, cpname);
1510         else if(hisname == "")
1511                 return strcat(col, cpname, " (", timestr, ")");
1512         else
1513                 return strcat(col, cpname, " (", timestr, " ", strcat(hisname, col, lapstr), ")");
1514 }
1515
1516 void Sbar_Score()
1517 {
1518         float score, distribution, leader;
1519         vector score_pos, secondary_score_pos, distribution_color;
1520         entity tm, pl, me;
1521         me = (spectatee_status > 0) ? playerslots[spectatee_status - 1] : playerslots[player_localentnum - 1];
1522
1523         vector bottomright;
1524         bottomright_x = vid_conwidth;
1525         bottomright_y = vid_conheight;
1526         bottomright_z = 0;
1527
1528         score_pos = bottomright - '196 42 0';
1529         secondary_score_pos = score_pos + '132 -6 0';
1530
1531         if((scores_flags[ps_primary] & SFL_TIME) && !teamplay) { // race/cts record display on HUD
1532                 pl = players.sort_next;
1533                 if(pl == me)
1534                         pl = pl.sort_next;
1535                 if(scores_flags[ps_primary] & SFL_ZERO_IS_WORST)
1536                         if(pl.scores[ps_primary] == 0)
1537                                 pl = world;
1538
1539                 score = me.(scores[ps_primary]);
1540
1541                 float racemin, racesec, racemsec;
1542                 float distsec, distmsec, minusplus;
1543
1544                 racemin = floor(score/(60 * TIME_FACTOR));
1545                 racesec = floor((score - racemin*(60 * TIME_FACTOR))/TIME_FACTOR);
1546                 racemsec = score - racemin*60*TIME_FACTOR - racesec*TIME_FACTOR;
1547
1548                 if (pl && ((!(scores_flags[ps_primary] & SFL_ZERO_IS_WORST)) || score)) {
1549                         // distribution display
1550                         distribution = me.(scores[ps_primary]) - pl.(scores[ps_primary]);
1551
1552                         if (distribution < TIME_FACTOR && distribution > -TIME_FACTOR)
1553                                 distmsec = fabs(distribution);
1554                         else {
1555                                 distsec = floor(fabs(distribution)/TIME_FACTOR);
1556                                 distmsec = fabs(distribution) - distsec*TIME_FACTOR;
1557                                 if (distribution < 0)
1558                                         distsec = -distsec;
1559                         }
1560
1561                         if (distribution <= 0) {
1562                                 distribution_color = '0 1 0';
1563                                 minusplus = 1; // minusplus 1: always prefix with minus sign
1564                         }
1565                         else {
1566                                 distribution_color = '1 0 0';
1567                                 minusplus = 2; // minusplus 1: always prefix with plus sign
1568                         }
1569                         Sbar_DrawXNum(bottomright - '0 48 0' - '16 0 0' * TIME_DECIMALS, distmsec, -TIME_DECIMALS, 0, 16, distribution_color, 0, 0, sbar_alpha_fg, DRAWFLAG_NORMAL);
1570                         Sbar_DrawXNum(bottomright - '68 48 0' - '16 0 0' * TIME_DECIMALS, distsec, 4, minusplus, 16, distribution_color, 0, 0, sbar_alpha_fg, DRAWFLAG_NORMAL);
1571                         drawpic(bottomright - '10 48 0' - '16 0 0' * TIME_DECIMALS, "gfx/hud/num_dot", '16 16 0', distribution_color, sbar_alpha_fg, DRAWFLAG_ADDITIVE);
1572                 }
1573                 // race record display
1574                 if (distribution <= 0 || distribution == score) // draw the highlight background behind the timer if we have the lead
1575                         drawpic(bottomright - '0 32 0' - '32 0 0' * (4 + TIME_DECIMALS), "gfx/hud/sb_highlight_4", '0 28 0' + '32 0 0' * (4 + TIME_DECIMALS), '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
1576
1577                 Sbar_DrawXNum(bottomright - '0 32 0' - TIME_DECIMALS * '30 0 0', racemsec, -TIME_DECIMALS, 0, 30, '1 1 1', 0, 0, sbar_alpha_fg, DRAWFLAG_NORMAL);
1578                 Sbar_DrawXNum(bottomright - '0 32 0' - TIME_DECIMALS * '30 0 0'  - '66 0 0', racesec, -2, 0, 30, '1 1 1', 0, 0, sbar_alpha_fg, DRAWFLAG_NORMAL);
1579                 drawpic(bottomright - '0 32 0' - TIME_DECIMALS * '30 0 0' - '18 0 0', "gfx/hud/num_dot", '30 30 0', '1 1 1', sbar_alpha_fg, DRAWFLAG_ADDITIVE);
1580
1581                 Sbar_DrawXNum(bottomright - '0 32 0' - TIME_DECIMALS * '30 0 0' - '132 0 0', racemin, -2, 0, 30, '1 1 1', 0, 0, sbar_alpha_fg, DRAWFLAG_NORMAL);
1582                 drawpic(bottomright - '0 32 0' - TIME_DECIMALS * '30 0 0' - '84 0 0', "gfx/hud/num_colon", '30 30 0', '1 1 1', sbar_alpha_fg, DRAWFLAG_ADDITIVE);
1583
1584         } else if (!teamplay) { // non-teamgames, except race/cts
1585                 // me vector := [team/connected frags id]
1586                 pl = players.sort_next;
1587                 if(pl == me)
1588                         pl = pl.sort_next;
1589
1590                 if(pl)
1591                         distribution = me.(scores[ps_primary]) - pl.(scores[ps_primary]);
1592                 else
1593                         distribution = 0;
1594
1595                 score = me.(scores[ps_primary]);
1596
1597                 if(distribution >= 5) {
1598                         distribution_color = '0 1 0';
1599                         leader = 1;
1600                 } else if(distribution >= 0) {
1601                         distribution_color = '1 1 1';
1602                         leader = 1;
1603                 } else if(distribution >= -5)
1604                         distribution_color = '1 1 0';
1605                 else
1606                         distribution_color = '1 0 0';
1607
1608                 Sbar_DrawXNum(secondary_score_pos, distribution, 4, 3, 16, distribution_color, 0, 0, sbar_alpha_fg, DRAWFLAG_NORMAL);
1609                 Sbar_DrawXNum(score_pos, score, 4, 0, 34, distribution_color, leader, 0, sbar_alpha_fg, DRAWFLAG_NORMAL);
1610         } else { // teamgames
1611                 float max_fragcount;
1612                 max_fragcount = -999;
1613
1614                 for(tm = teams.sort_next; tm; tm = tm.sort_next) {
1615                         if(tm.team == COLOR_SPECTATOR || !tm.team_size) // no players? don't display
1616                                 continue;
1617                         score = tm.(teamscores[ts_primary]);
1618                         leader = 0;
1619
1620                         if (score > max_fragcount)
1621                                 max_fragcount = score;
1622
1623                         if(tm.team == myteam) {
1624                                 if (max_fragcount == score)
1625                                         leader = 1;
1626                                 Sbar_DrawXNum(score_pos, score, 4, 0, 34, GetTeamRGB(tm.team) * 0.8, leader, 1, sbar_alpha_fg, DRAWFLAG_NORMAL);
1627                         } else {
1628                                 if (max_fragcount == score)
1629                                         leader = 1;
1630                                 Sbar_DrawXNum(secondary_score_pos, score, 4, 0, 16, GetTeamRGB(tm.team) * 0.8, leader, 1, sbar_alpha_fg, DRAWFLAG_NORMAL);
1631                                 secondary_score_pos = secondary_score_pos + '0 16 0';
1632                         }
1633                 }
1634         }
1635
1636         if(gametype == GAME_RACE || gametype == GAME_CTS)
1637         {
1638                 drawfont = sbar_bigfont;
1639                 float a, t;
1640                 vector m;
1641                 string s, forcetime;
1642
1643                 m = '0.5 0 0' * vid_conwidth + '0 0.25 0' * vid_conheight;
1644
1645                 if(race_checkpointtime)
1646                 {
1647                         a = bound(0, 2 - (time - race_checkpointtime), 1);
1648                         s = "";
1649                         forcetime = "";
1650                         if(a > 0) // just hit a checkpoint?
1651                         {
1652                                 if(race_checkpoint != 254)
1653                                 {
1654                                         if(race_time && race_previousbesttime)
1655                                                 s = MakeRaceString(race_checkpoint, TIME_DECODE(race_time) - TIME_DECODE(race_previousbesttime), 0, 0, race_previousbestname);
1656                                         else
1657                                                 s = MakeRaceString(race_checkpoint, 0, -1, 0, race_previousbestname);
1658                                         if(race_time)
1659                                                 forcetime = TIME_ENCODED_TOSTRING(race_time);
1660                                 }
1661                         }
1662                         else
1663                         {
1664                                 if(race_laptime && race_nextbesttime && race_nextcheckpoint != 254)
1665                                 {
1666                                         a = bound(0, 2 - ((race_laptime + TIME_DECODE(race_nextbesttime)) - (time + TIME_DECODE(race_penaltyaccumulator))), 1);
1667                                         if(a > 0) // next one?
1668                                         {
1669                                                 s = MakeRaceString(race_nextcheckpoint, (time + TIME_DECODE(race_penaltyaccumulator)) - race_laptime, TIME_DECODE(race_nextbesttime), 0, race_nextbestname);
1670                                         }
1671                                 }
1672                         }
1673
1674                         if(s != "" && a > 0)
1675                         {
1676                                 dummyfunction(0, 0, 0, 0, 0, 0, 0, 0); // work around DP bug (set OFS_PARAM5 to 0)
1677                                 drawcolorcodedstring(m - '0 16 0' - '8 0 0' * stringwidth(s, TRUE), s, '16 16 0', sbar_alpha_fg * a, DRAWFLAG_NORMAL);
1678                         }
1679
1680                         if(race_penaltytime)
1681                         {
1682                                 a = bound(0, 2 - (time - race_penaltyeventtime), 1);
1683                                 if(a > 0)
1684                                 {
1685                                         s = strcat("^1PENALTY: ", ftos_decimals(race_penaltytime * 0.1, 1), " (", race_penaltyreason, ")");
1686                                         dummyfunction(0, 0, 0, 0, 0, 0, 0, 0); // work around DP bug (set OFS_PARAM5 to 0)
1687                                         drawcolorcodedstring(m - '0 32 0' - '8 0 0' * stringwidth(s, TRUE), s, '16 16 0', sbar_alpha_fg * a, DRAWFLAG_NORMAL);
1688                                 }
1689                         }
1690
1691                         if(forcetime != "")
1692                         {
1693                                 a = bound(0, (time - race_checkpointtime) / 0.5, 1);
1694                                 drawstring_expanding(m - '16 0 0' * stringwidth(forcetime, FALSE), forcetime, '32 32 0', '1 1 1', sbar_alpha_fg, 0, a);
1695                         }
1696                         else
1697                                 a = 1;
1698
1699                         if(race_laptime && race_checkpoint != 255)
1700                         {
1701                                 s = TIME_ENCODED_TOSTRING(TIME_ENCODE(time + TIME_DECODE(race_penaltyaccumulator) - race_laptime));
1702                                 drawstring(m - '16 0 0' * stringwidth(s, FALSE), s, '32 32 0', '1 1 1', sbar_alpha_fg * a, DRAWFLAG_NORMAL);
1703                         }
1704                 }
1705                 else
1706                 {
1707                         if(race_mycheckpointtime)
1708                         {
1709                                 a = bound(0, 2 - (time - race_mycheckpointtime), 1);
1710                                 s = MakeRaceString(race_mycheckpoint, TIME_DECODE(race_mycheckpointdelta), -!race_mycheckpointenemy, race_mycheckpointlapsdelta, race_mycheckpointenemy);
1711                                 dummyfunction(0, 0, 0, 0, 0, 0, 0, 0); // work around DP bug (set OFS_PARAM5 to 0)
1712                                 drawcolorcodedstring(m - '0 16 0' - '8 0 0' * stringwidth(s, TRUE), s, '16 16 0', sbar_alpha_fg * a, DRAWFLAG_NORMAL);
1713                         }
1714                         if(race_othercheckpointtime && race_othercheckpointenemy != "")
1715                         {
1716                                 a = bound(0, 2 - (time - race_othercheckpointtime), 1);
1717                                 s = MakeRaceString(race_othercheckpoint, -TIME_DECODE(race_othercheckpointdelta), -!race_othercheckpointenemy, race_othercheckpointlapsdelta, race_othercheckpointenemy);
1718                                 dummyfunction(0, 0, 0, 0, 0, 0, 0, 0); // work around DP bug (set OFS_PARAM5 to 0)
1719                                 drawcolorcodedstring(m - '0 0 0' - '8 0 0' * stringwidth(s, TRUE), s, '16 16 0', sbar_alpha_fg * a, DRAWFLAG_NORMAL);
1720                         }
1721
1722                         if(race_penaltytime && !race_penaltyaccumulator)
1723                         {
1724                                 t = race_penaltytime * 0.1 + race_penaltyeventtime;
1725                                 a = bound(0, (1 + t - time), 1);
1726                                 if(a > 0)
1727                                 {
1728                                         if(time < t)
1729                                                 s = strcat("^1PENALTY: ", ftos_decimals(t - time, 1), " (", race_penaltyreason, ")");
1730                                         else
1731                                                 s = strcat("^2PENALTY: 0.0 (", race_penaltyreason, ")");
1732                                         dummyfunction(0, 0, 0, 0, 0, 0, 0, 0); // work around DP bug (set OFS_PARAM5 to 0)
1733                                         drawcolorcodedstring(m - '0 32 0' - '8 0 0' * stringwidth(s, TRUE), s, '16 16 0', sbar_alpha_fg * a, DRAWFLAG_NORMAL);
1734                                 }
1735                         }
1736                 }
1737
1738                 drawfont = sbar_font;
1739         }
1740 }
1741
1742 void Sbar_Timer()
1743 {
1744         float timelimit, elapsedTime, minutes, seconds, timeleft, minutesLeft, secondsLeft;
1745         vector bgpos, timer_color;
1746         bgpos = '0 0 0';
1747
1748         vector topright;
1749         topright = '0 0 0';
1750         topright_x = vid_conwidth;
1751
1752         timelimit = getstatf(STAT_TIMELIMIT);
1753
1754         timeleft = max(0, timelimit * 60 + getstatf(STAT_GAMESTARTTIME) - time);
1755         timeleft = ceil(timeleft);
1756         minutesLeft = floor(timeleft / 60);
1757         secondsLeft = timeleft - minutesLeft*60;
1758
1759         if(minutesLeft >= 5 || warmup_stage || timelimit == 0) //don't use red or yellow in warmup or when there is no timelimit
1760                 timer_color = '1 1 1'; //white
1761         else if(minutesLeft >= 1)
1762                 timer_color = '1 1 0'; //yellow
1763         else
1764                 timer_color = '1 0 0'; //red
1765
1766         if (cvar("sbar_increment_maptime") || timelimit == 0 || warmup_stage) {
1767                 if (time < getstatf(STAT_GAMESTARTTIME)) {
1768                         //while restart is still active, show 00:00
1769                         minutes = seconds = 0;
1770                 } else {
1771                         elapsedTime = floor(time - getstatf(STAT_GAMESTARTTIME)); //127
1772                         minutes = floor(elapsedTime / 60);
1773                         seconds = elapsedTime - minutes*60;
1774                 }
1775                 if (minutes < 10)
1776                         bgpos_x = topright_x - 54 - 17 - 12;
1777                 else if (minutes < 100) // nudge the timer background left if more digits are drawn
1778                         bgpos_x = topright_x - 72 - 17 - 12;
1779                 else
1780                         bgpos_x = topright_x - 90 - 17 - 12;
1781                 bgpos_y = 0;
1782                 bgpos_z = 0;
1783         } else {
1784                 minutes = minutesLeft;
1785                 seconds = secondsLeft;
1786                 if (minutes == 0)
1787                 bgpos_x = topright_x - 36 - 7 - 12;
1788                 else if (minutes < 10) // nudge the timer background left if more digits are drawn
1789                         bgpos_x = topright_x - 54 - 17 - 12;
1790                 else if (minutes < 100)
1791                         bgpos_x = topright_x - 72 - 17 - 12;
1792                 else
1793                         bgpos_x = topright_x - 90 - 17 - 12;
1794                 bgpos_y = 0;
1795                 bgpos_z = 0;
1796         }
1797
1798         if (cvar("viewsize") <= 100) { // draw timer background when viewsize <= 100
1799                 if (teamplay)
1800                         drawpic(bgpos, "gfx/hud/sb_timerbg", '120 30 0', GetTeamRGB(myteam) * sbar_color_bg_team, sbar_alpha_bg, DRAWFLAG_NORMAL); // timer bg color = myteam color
1801                 else {
1802                         color_x = cvar("sbar_color_bg_r");
1803                         color_y = cvar("sbar_color_bg_g");
1804                         color_z = cvar("sbar_color_bg_b");
1805
1806                         drawpic(bgpos, "gfx/hud/sb_timerbg", '120 30 0', color, sbar_alpha_bg, DRAWFLAG_NORMAL);
1807                 }
1808         }
1809
1810         if(minutesLeft >= 1 || cvar("sbar_increment_maptime") || timelimit == 0 || warmup_stage) {
1811                 Sbar_DrawXNum(topright - '103 0 0' + '0 2 0', minutes, 3, 0, 18, timer_color, 0, 0, sbar_alpha_fg, DRAWFLAG_NORMAL);
1812                 drawpic(topright - '53 0 0' + '0 1 0', "gfx/hud/num_colon", '18 18 0', timer_color, sbar_alpha_fg, DRAWFLAG_NORMAL);
1813         }
1814         Sbar_DrawXNum(topright - '36 0 0' - '3 0 0' + '0 2 0', seconds, -2, 0, 18, timer_color, 0, 0, sbar_alpha_fg, DRAWFLAG_NORMAL);
1815 }
1816
1817 void CSQC_Strength_Timer() {
1818         vector pos;
1819         vector bottom;
1820
1821         bottom_x = vid_conwidth/2;
1822         bottom_y = vid_conheight;
1823         bottom_z = 0;
1824
1825         float stat_items, dt;
1826         stat_items = getstati(STAT_ITEMS);
1827         /*
1828         if not(stat_items & IT_STRENGTH)
1829                 if not(stat_items & IT_INVINCIBLE)
1830                         return;
1831         */
1832
1833         if (getstati(STAT_HEALTH) <= 0)
1834                 return;
1835
1836         vector picsize;
1837         float strength_time, invincibility_time, countdown_fontsize;
1838
1839         picsize = '22 22 0';
1840         countdown_fontsize = 18;
1841
1842         if (vid_conwidth >= 800)
1843                 pos = bottom + '192 -46 0';
1844         else
1845                 pos = bottom + '192 -94 0';
1846
1847         //strength
1848         strength_time = getstatf(STAT_STRENGTH_FINISHED);
1849         invincibility_time = getstatf(STAT_INVINCIBLE_FINISHED);
1850
1851         if (strength_time) {
1852                 dt = strength_time - time;
1853                 if(dt > 0)
1854                 {
1855                         if(dt < 5)
1856                         {
1857                                 drawpic_expanding_two(pos, "gfx/hud/sb_str", picsize, '1 1 1', sbar_alpha_fg, DRAWFLAG_ADDITIVE,
1858                                         bound(0, (ceil(dt) - dt) / 0.5, 1));
1859                         }
1860                         else
1861                         {
1862                                 drawpic(pos, "gfx/hud/sb_str", picsize, '1 1 1', sbar_alpha_fg, DRAWFLAG_ADDITIVE);
1863                         }
1864                         Sbar_DrawXNum(pos - '40 -2 0', ceil(dt), 2, 0, countdown_fontsize, '1 1 1', 0, 0, sbar_alpha_fg, DRAWFLAG_NORMAL);
1865                 }
1866                 else if(dt > -1)
1867                 {
1868                         drawpic_expanding(pos, "gfx/hud/sb_str", picsize, '1 1 1', sbar_alpha_fg, DRAWFLAG_ADDITIVE,
1869                                 bound(0, -dt / 0.5, 1));
1870                 }
1871         }
1872
1873         //invincibility
1874         if (invincibility_time) {
1875                 dt = invincibility_time - time;
1876                 if(dt > 0)
1877                 {
1878                         if(dt < 5)
1879                         {
1880                                 drawpic_expanding_two(pos - '0 -22 0', "gfx/hud/sb_invinc", picsize, '1 1 1', sbar_alpha_fg, DRAWFLAG_ADDITIVE,
1881                                         bound(0, (ceil(dt) - dt) / 0.5, 1));
1882                         }
1883                         else
1884                         {
1885                                 drawpic(pos - '0 -22 0', "gfx/hud/sb_invinc", picsize, '1 1 1', sbar_alpha_fg, DRAWFLAG_ADDITIVE);
1886                         }
1887                         Sbar_DrawXNum(pos - '40 -24 0', ceil(dt), 2, 0, countdown_fontsize, '1 1 1', 0, 0, sbar_alpha_fg, DRAWFLAG_NORMAL);
1888                 }
1889                 else if(dt > -1)
1890                 {
1891                         drawpic_expanding(pos - '0 -22 0', "gfx/hud/sb_invinc", picsize, '1 1 1', sbar_alpha_fg, DRAWFLAG_ADDITIVE,
1892                                 bound(0, -dt / 0.5, 1));
1893                 }
1894         }
1895 }
1896
1897 #define CENTERPRINT_MAX_LINES 30
1898 string centerprint_messages[CENTERPRINT_MAX_LINES];
1899 float centerprint_width[CENTERPRINT_MAX_LINES];
1900 vector centerprint_start;
1901 float centerprint_expire;
1902 float centerprint_num;
1903 float centerprint_offset_hint;
1904 vector centerprint_fontsize;
1905
1906 void centerprint(string strMessage)
1907 {
1908         float i, j, n, hcount;
1909         string s;
1910
1911         centerprint_fontsize = Sbar_GetFontsize("scr_centersize");
1912
1913         centerprint_expire = min(centerprint_expire, time); // if any of the returns happens, this message will fade out
1914
1915         if(cvar("scr_centertime") <= 0)
1916                 return;
1917
1918         if(strMessage == "")
1919                 return;
1920
1921         // strip trailing newlines
1922         j = strlen(strMessage) - 1;
1923         while(substring(strMessage, j, 1) == "\n" && j >= 0)
1924                 j = j - 1;
1925         strMessage = substring(strMessage, 0, j + 1);
1926
1927         if(strMessage == "")
1928                 return;
1929
1930         // strip leading newlines and remember them, they are a hint that the message should be lower on the screen
1931         j = 0;
1932         while(substring(strMessage, j, 1) == "\n" && j < strlen(strMessage))
1933                 j = j + 1;
1934         strMessage = substring(strMessage, j, strlen(strMessage) - j);
1935         centerprint_offset_hint = j;
1936
1937         if(strMessage == "")
1938                 return;
1939
1940         // if we get here, we have a message. Initialize its height.
1941         centerprint_num = 0;
1942
1943         n = tokenizebyseparator(strMessage, "\n");
1944         i = hcount = 0;
1945         for(j = 0; j < n; ++j)
1946         {
1947                 getWrappedLine_remaining = argv(j);
1948                 while(getWrappedLine_remaining)
1949                 {
1950                         s = getWrappedLine(vid_conwidth * 0.75 / centerprint_fontsize_x, stringwidth_colors);
1951                         if(centerprint_messages[i])
1952                                 strunzone(centerprint_messages[i]);
1953                         centerprint_messages[i] = strzone(s);
1954                         centerprint_width[i] = stringwidth(s, TRUE);
1955                         ++i;
1956
1957                         // half height for empty lines looks better
1958                         if(s == "")
1959                                 hcount += 0.5;
1960                         else
1961                                 hcount += 1;
1962
1963                         if(i >= CENTERPRINT_MAX_LINES)
1964                                 break;
1965                 }
1966         }
1967
1968         float h, havail;
1969         h = centerprint_fontsize_y*hcount;
1970
1971         havail = vid_conheight;
1972         if(cvar("con_chatpos") < 0)
1973                 havail -= (-cvar("con_chatpos") + cvar("con_chat")) * cvar("con_chatsize"); // avoid overlapping chat
1974         if(havail > vid_conheight - 70)
1975                 havail = vid_conheight - 70; // avoid overlapping HUD
1976
1977         centerprint_start_x = 0;
1978
1979 #if 0
1980         float forbiddenmin, forbiddenmax, allowedmin, allowedmax, preferred;
1981
1982         // here, the centerprint would cover the crosshair. REALLY BAD.
1983         forbiddenmin = vid_conheight * 0.5 - h - 16;
1984         forbiddenmax = vid_conheight * 0.5 + 16;
1985
1986         allowedmin = scoreboard_bottom;
1987         allowedmax = havail - h;
1988         preferred = (havail - h)/2;
1989
1990
1991         // possible orderings (total: 4! / 4 = 6)
1992         //  allowedmin allowedmax forbiddenmin forbiddenmax
1993         //  forbiddenmin forbiddenmax allowedmin allowedmax
1994         if(allowedmax < forbiddenmin || allowedmin > forbiddenmax)
1995         {
1996                 // forbidden doesn't matter in this case
1997                 centerprint_start_y = bound(allowedmin, preferred, allowedmax);
1998         }
1999         //  allowedmin forbiddenmin allowedmax forbiddenmax
2000         else if(allowedmin < forbiddenmin && allowedmax < forbiddenmax)
2001         {
2002                 centerprint_start_y = bound(allowedmin, preferred, forbiddenmin);
2003         }
2004         //  allowedmin forbiddenmin forbiddenmax allowedmax
2005         else if(allowedmin < forbiddenmin)
2006         {
2007                 // make sure the forbidden zone is not covered
2008                 if(preferred > (forbiddenmin + forbiddenmax) * 0.5)
2009                         centerprint_start_y = bound(allowedmin, preferred, forbiddenmin);
2010                 else
2011                         centerprint_start_y = bound(forbiddenmax, preferred, allowedmin);
2012         }
2013         //  forbiddenmin allowedmin allowedmax forbiddenmax
2014         else if(allowedmax < forbiddenmax)
2015         {
2016                 // it's better to leave the allowed zone (overlap with scoreboard) than
2017                 // to cover the forbidden zone (crosshair)
2018                 if(preferred > (forbiddenmin + forbiddenmax) * 0.5)
2019                         centerprint_start_y = forbiddenmax;
2020                 else
2021                         centerprint_start_y = forbiddenmin;
2022         }
2023         //  forbiddenmin allowedmin forbiddenmax allowedmax
2024         else
2025         {
2026                 centerprint_start_y = bound(forbiddenmax, preferred, allowedmax);
2027         }
2028 #else
2029         centerprint_start_y =
2030                 min(
2031                         max(
2032                                 max(scoreboard_bottom, vid_conheight * 0.5 + 16),
2033                                 (havail - h)/2
2034                         ),
2035                         havail - h
2036                 );
2037 #endif
2038
2039         centerprint_num = i;
2040         centerprint_expire = time + cvar("scr_centertime");
2041 }
2042
2043 void Sbar_DrawCenterPrint (void)
2044 {
2045         float i;
2046         vector pos;
2047         string ts;
2048         float a;
2049
2050         //if(time > centerprint_expire)
2051         //      return;
2052
2053         //a = bound(0, 1 - 2 * (time - centerprint_expire), 1);
2054         a = bound(0, 1 - 4 * (time - centerprint_expire), 1);
2055         //sz = 1.2 / (a + 0.2);
2056
2057         if(a <= 0)
2058                 return;
2059
2060         pos = centerprint_start;
2061         for (i=0; i<centerprint_num; i = i + 1)
2062         {
2063                 pos_x = (vid_conwidth - centerprint_fontsize_x * centerprint_width[i]) * 0.5;
2064                 ts = centerprint_messages[i];
2065                 if (ts != "")
2066                 {
2067                         dummyfunction(0, 0, 0, 0, 0, 0, 0, 0); // work around DP bug (set OFS_PARAM5 to 0)
2068                         drawcolorcodedstring(pos, ts, centerprint_fontsize, a, DRAWFLAG_NORMAL);
2069                         //  - '0 0.5 0' * (sz - 1) * centerprint_fontsize_x - '0.5 0 0' * (sz - 1) * centerprint_width[i] * centerprint_fontsize_y, centerprint_fontsize * sz
2070                         pos_y = pos_y + centerprint_fontsize_y;
2071                 }
2072                 else
2073                         // half height for empty lines looks better
2074                         pos_y = pos_y + centerprint_fontsize_y * 0.5;
2075         }
2076 }
2077
2078 vector Sbar_DrawNoteLine(vector offset, string s)
2079 {
2080         dummyfunction(0, 0, 0, 0, 0, 0, 0, 0); // work around DP bug (set OFS_PARAM5 to 0)
2081         drawcolorcodedstring(
2082                 offset - sbar_fontsize_x * '1 0 0' * stringwidth(s, TRUE),
2083                 s,
2084                 sbar_fontsize,
2085                 sbar_alpha_fg,
2086                 0
2087         );
2088         return offset + sbar_fontsize_y * '0 1 0';
2089 }
2090
2091 void Sbar_DrawPressedKeys(void)
2092 {
2093         vector pos, bgsize;
2094         float pressedkeys;
2095
2096         pos = stov(cvar_string("cl_showpressedkeys_position"));
2097
2098         bgsize = '126 75 0';
2099
2100         pos = '1 0 0' * (vid_conwidth - bgsize_x) * pos_x
2101             + '0 1 0' * (vid_conheight - bgsize_y) * pos_y;
2102         pos -= '-15 -6 0'; // adjust to the origin of these numbers
2103
2104         pressedkeys = getstatf(STAT_PRESSED_KEYS);
2105         drawpic(pos + '-15   -6   0', "gfx/hud/keys/key_bg.tga",           bgsize, '1 1 1', 0.1 * sbar_alpha_fg, DRAWFLAG_NORMAL);
2106         drawpic(pos + ' 83.5  9   0', ((pressedkeys & KEY_CROUCH) ? "gfx/hud/keys/key_crouch_inv.tga" : "gfx/hud/keys/key_crouch.tga"), ' 24 24 0', '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2107         drawpic(pos + ' 32   -1.5 0', ((pressedkeys & KEY_FORWARD) ? "gfx/hud/keys/key_forward_inv.tga" : "gfx/hud/keys/key_forward.tga"),  ' 32 32 0', '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2108         drawpic(pos + '-11.5  9   0', ((pressedkeys & KEY_JUMP) ? "gfx/hud/keys/key_jump_inv.tga" : "gfx/hud/keys/key_jump.tga"),     ' 24 24 0', '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2109         drawpic(pos + ' -1   32   0', ((pressedkeys & KEY_LEFT) ? "gfx/hud/keys/key_left_inv.tga" : "gfx/hud/keys/key_left.tga"),     ' 32 32 0', '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2110         drawpic(pos + ' 32   32   0', ((pressedkeys & KEY_BACKWARD) ? "gfx/hud/keys/key_backward_inv.tga" : "gfx/hud/keys/key_backward.tga"), ' 32 32 0', '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2111         drawpic(pos + ' 65   32   0', ((pressedkeys & KEY_RIGHT) ? "gfx/hud/keys/key_right_inv.tga" : "gfx/hud/keys/key_right.tga"),    ' 32 32 0', '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2112 }
2113
2114 void Sbar_ShowSpeed(void)
2115 {
2116         vector numsize;
2117         float pos, conversion_factor;
2118         string speed, unit;
2119
2120         switch(cvar("cl_showspeed_unit"))
2121         {
2122                 default:
2123                 case 0:
2124                         unit = "";
2125                         conversion_factor = 1.0;
2126                         break;
2127                 case 1:
2128                         unit = " qu/s";
2129                         conversion_factor = 1.0;
2130                         break;
2131                 case 2:
2132                         unit = " m/s";
2133                         conversion_factor = 0.0254;
2134                         break;
2135                 case 3:
2136                         unit = " km/h";
2137                         conversion_factor = 0.0254 * 3.6;
2138                         break;
2139                 case 4:
2140                         unit = " mph";
2141                         conversion_factor = 0.0254 * 3.6 * 0.6213711922;
2142                         break;
2143                 case 5:
2144                         unit = " knots";
2145                         conversion_factor = 0.0254 * 1.943844492; // 1 m/s = 1.943844492 knots, because 1 knot = 1.852 km/h
2146                         break;
2147         }
2148
2149         if (cvar("cl_showspeed_z") == 1)
2150                 speed = strcat(ftos(floor( vlen(pmove_vel) * conversion_factor + 0.5 )), unit);
2151         else
2152                 speed = strcat(ftos(floor( vlen(pmove_vel - pmove_vel_z * '0 0 1') * conversion_factor + 0.5 )), unit);
2153
2154         numsize_x = numsize_y = cvar("cl_showspeed_size");
2155         pos = (vid_conheight - numsize_y) * cvar("cl_showspeed_position");
2156
2157         drawfont = sbar_bigfont;
2158         drawstringcenter('1 0 0' + pos * '0 1 0', speed, numsize, '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2159         drawfont = sbar_font;
2160 }
2161
2162 vector acc_prevspeed;
2163 float acc_prevtime;
2164 float acc_avg;
2165
2166 void Sbar_ShowAcceleration(void)
2167 {
2168         float acceleration, sz, scale, alpha, f;
2169         vector pos, top, rgb;
2170         top_x = vid_conwidth/2;
2171         top_y = 0;
2172
2173         f = time - acc_prevtime;
2174         if(cvar("cl_showacceleration_z"))
2175                 acceleration = (vlen(pmove_vel) - vlen(acc_prevspeed)) * (1 / f);
2176         else
2177                 acceleration = (vlen(pmove_vel - '0 0 1' * pmove_vel_z) - vlen(acc_prevspeed - '0 0 1' * acc_prevspeed_z)) * (1 / f);
2178         acc_prevspeed = pmove_vel;
2179         acc_prevtime = time;
2180
2181         f = bound(0, f * 10, 1);
2182         acc_avg = acc_avg * (1 - f) + acceleration * f;
2183         acceleration = acc_avg / getstatf(STAT_MOVEVARS_MAXSPEED);
2184
2185         pos = top - sz/2 * '0 1 0' + (cvar("cl_showacceleration_position") * vid_conheight) * '0 1 0';
2186
2187         sz = cvar("cl_showacceleration_size");
2188         scale = cvar("cl_showacceleration_scale");
2189         alpha = cvar("cl_showacceleration_alpha");
2190         if (cvar("cl_showacceleration_color_custom"))
2191                 rgb = stov(cvar_string("cl_showacceleration_color"));
2192         else {
2193                 rgb = '1 1 1';
2194                 if (acceleration < 0) {
2195                         rgb = '1 .5 .5' - '0 .5 .5' * bound(0, -acceleration * 0.2, 1);
2196                 } else if (acceleration > 0) {
2197                         rgb = '.5 1 .5' - '.5 0 .5' * bound(0, +acceleration * 0.2, 1);
2198                 }
2199         }
2200
2201         if (acceleration > 0)
2202                 drawpic(pos, "gfx/hud/accelerometer_gradient", acceleration * scale * '40 0 0' + sz * '0 1 0', rgb, alpha * sbar_alpha_fg, DRAWFLAG_NORMAL);
2203         else if (acceleration < 0)
2204                 drawpic(pos + acceleration * scale * '40 0 0', "gfx/hud/accelerometer_gradient", -acceleration * scale * '40 0 0' + sz * '0 1 0', rgb, alpha * sbar_alpha_fg, DRAWFLAG_NORMAL);
2205 }
2206
2207 void Sbar_DrawAccuracyStats_Description_Hitscan(vector position)
2208 {
2209         drawstring(position + '0 3 0' * sbar_fontsize_y, "Shots fired:", sbar_fontsize, '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2210         drawstring(position + '0 5 0' * sbar_fontsize_y, "Shots hit:", sbar_fontsize, '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2211         drawstring(position + '0 7 0' * sbar_fontsize_y, "Accuracy:", sbar_fontsize, '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2212         drawstring(position + '0 9 0' * sbar_fontsize_y, "Shots missed:", sbar_fontsize, '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2213 }
2214
2215 void Sbar_DrawAccuracyStats_Description_Splash(vector position)
2216 {
2217         drawstring(position + '0 3 0' * sbar_fontsize_y, "Maximum damage:", sbar_fontsize, '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2218         drawstring(position + '0 5 0' * sbar_fontsize_y, "Actual damage:", sbar_fontsize, '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2219         drawstring(position + '0 7 0' * sbar_fontsize_y, "Accuracy:", sbar_fontsize, '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2220         drawstring(position + '0 9 0' * sbar_fontsize_y, "Damage wasted:", sbar_fontsize, '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2221 }
2222
2223 void Sbar_DrawAccuracyStats()
2224 {
2225         float i, count_hitscan, count_splash, row;  // count is the number of 'colums'
2226         float weapon_hit, weapon_damage, weapon_stats;
2227         float left_border;  // position where the weapons start, the description is in the border
2228         vector fill_colour, fill_size;
2229         vector pos;
2230
2231         float col_margin = 20;  // pixels between the columns
2232         float row_margin = 20;  // pixels between the rows
2233
2234         fill_size_x = 5 * sbar_fontsize_x;  // width of the background
2235         fill_size_y = 10 * sbar_fontsize_y;  // height of the background
2236
2237         drawfont = sbar_bigfont;
2238         pos_x = 0;
2239         pos_y = SCOREBOARD_OFFSET;
2240         pos_z = 0;
2241         drawstringcenter(pos, "Weapon Accuracy", 2 * sbar_fontsize, '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2242
2243         left_border = col_margin + 11 * sbar_fontsize_x;
2244
2245         drawfont = sbar_font;
2246
2247         if(warmup_stage)
2248         {
2249                 pos_y += 40;
2250                 if(mod(time, 1) >= 0.4)
2251                         drawstringcenter(pos, "Stats are not tracked during warmup stage", sbar_fontsize, '1 1 0', sbar_alpha_fg, DRAWFLAG_NORMAL);
2252
2253                 return;
2254         }
2255
2256         float top_border_hitscan = SCOREBOARD_OFFSET + 55;  // position where the hitscan row starts: pixels down the screen
2257         Sbar_DrawAccuracyStats_Description_Hitscan('1 0 0' * col_margin + '0 1 0' * top_border_hitscan);
2258
2259         float top_border_splash = SCOREBOARD_OFFSET + 175;  // position where the splash row starts: pixels down the screen
2260         Sbar_DrawAccuracyStats_Description_Splash('1 0 0' * col_margin + '0 1 0' * top_border_splash);
2261
2262         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
2263         {
2264                 weapon_hit = weapon_hits[i];
2265                 weapon_damage = weapon_fired[i];
2266                 self = get_weaponinfo(i);
2267
2268                 //if ((weapon_number != 42))  // print them all :)
2269                 if (weapon_damage) {
2270                         if (self.weapon_type == WEP_TYPE_SPLASH) {
2271                                 weapon_stats = bound(0, rint(100 * weapon_hit / weapon_damage), 100);
2272
2273                                 fill_colour_x = 1 - 0.015 * weapon_stats;
2274                                 fill_colour_y = 1 - 0.015 * (100 - weapon_stats);
2275
2276                                 // how the background colour is calculated
2277                                 // %    red             green   red_2                   green_2
2278                                 // 0    1               0               1 - % * 0.015   1 - (100 - %) * 0.015
2279                                 // 10   0.85    0               1 - % * 0.015   1 - (100 - %) * 0.015
2280                                 // 20   0.70    0               1 - % * 0.015   1 - (100 - %) * 0.015
2281                                 // 30   0.55    0               1 - % * 0.015   1 - (100 - %) * 0.015
2282                                 // 40   0.40    0.10    1 - % * 0.015   1 - (100 - %) * 0.015
2283                                 // 50   0.25    0.25    1 - % * 0.015   1 - (100 - %) * 0.015
2284                                 // 60   0.10    0.40    1 - % * 0.015   1 - (100 - %) * 0.015
2285                                 // 70   0               0.55    1 - % * 0.015   1 - (100 - %) * 0.015
2286                                 // 80   0               0.70    1 - % * 0.015   1 - (100 - %) * 0.015
2287                                 // 90   0               0.85    1 - % * 0.015   1 - (100 - %) * 0.015
2288                                 // 100  0               1               1 - % * 0.015   1 - (100 - %) * 0.015
2289
2290                                 if ((left_border + count_splash * (fill_size_x + col_margin) + fill_size_x) >= vid_conwidth)
2291                                 {
2292                                         count_splash = 0;
2293                                         ++row;
2294                                         Sbar_DrawAccuracyStats_Description_Splash('1 0 0' * col_margin + '0 1 0' * (top_border_splash + row * (fill_size_y + row_margin)));
2295                                 }
2296
2297                                 pos_x = left_border + count_splash * (fill_size_x + col_margin);
2298                                 pos_y = top_border_splash + row * (fill_size_y + row_margin);
2299
2300                                 // background
2301                                 drawpic(pos, "gfx/hud/sb_accuracy", fill_size , fill_colour, sbar_alpha_bg, DRAWFLAG_NORMAL);
2302                                 drawborderlines(sbar_border_thickness, pos, fill_size, '0 0 0', sbar_alpha_bg, DRAWFLAG_NORMAL);
2303
2304                                 // the weapon
2305                                 drawpic(pos, strcat("gfx/hud/inv_weapon", ftos(i-1)), '1 0.5 0' * fill_size_x , '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2306
2307                                 // the amount of shots fired or max damage
2308                                 drawstringright(pos + '4.5 0 0' * sbar_fontsize_x + '0 3 0' * sbar_fontsize_y, ftos(weapon_damage), sbar_fontsize, '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2309
2310                                 // the amount of hits or actual damage
2311                                 drawstringright(pos + '4.5 0 0' * sbar_fontsize_x + '0 5 0' * sbar_fontsize_y, ftos(weapon_hit), sbar_fontsize, '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2312
2313                                 // the accuracy
2314                                 drawstringright(pos + '4.5 0 0' * sbar_fontsize_x + '0 7 0' * sbar_fontsize_y, strcat(ftos(weapon_stats),"%"), sbar_fontsize, '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2315
2316                                 // the amount of shots missed or damage wasted
2317                                 drawstringright(pos + '4.5 0 0' * sbar_fontsize_x + '0 9 0' * sbar_fontsize_y, ftos(max(0, weapon_damage - weapon_hit)), sbar_fontsize, '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2318
2319                                 ++count_splash;
2320                         } else if ((self.weapon_type == WEP_TYPE_HITSCAN) && (weapon_damage)) {
2321                                 weapon_stats = bound(0, rint(100 * weapon_hit / weapon_damage), 100);
2322
2323                                 fill_colour_x = 1 - 0.015 * weapon_stats;
2324                                 fill_colour_y = 1 - 0.015 * (100 - weapon_stats);
2325
2326                                 // how the background colour is calculated
2327                                 // %    red             green   red_2                   green_2
2328                                 // 0    1               0               1 - % * 0.015   1 - (100 - %) * 0.015
2329                                 // 10   0.850   0               1 - % * 0.015   1 - (100 - %) * 0.015
2330                                 // 20   0.70    0               1 - % * 0.015   1 - (100 - %) * 0.015
2331                                 // 30   0.55    0               1 - % * 0.015   1 - (100 - %) * 0.015
2332                                 // 40   0.40    0.10    1 - % * 0.015   1 - (100 - %) * 0.015
2333                                 // 50   0.25    0.25    1 - % * 0.015   1 - (100 - %) * 0.015
2334                                 // 60   0.10    0.40    1 - % * 0.015   1 - (100 - %) * 0.015
2335                                 // 70   0               0.55    1 - % * 0.015   1 - (100 - %) * 0.015
2336                                 // 80   0               0.70    1 - % * 0.015   1 - (100 - %) * 0.015
2337                                 // 90   0               0.85    1 - % * 0.015   1 - (100 - %) * 0.015
2338                                 // 100  0               1               1 - % * 0.015   1 - (100 - %) * 0.015
2339
2340                                 if ((left_border + count_hitscan * (fill_size_x + col_margin) + fill_size_x + cvar("stats_right_margin")) >= vid_conwidth)
2341                                 {
2342                                         count_hitscan = 0;
2343                                         ++row;
2344                                         Sbar_DrawAccuracyStats_Description_Hitscan('1 0 0' * col_margin + '0 1 0' * (top_border_hitscan + row * (fill_size_y + row_margin)));
2345                                 }
2346
2347                                 pos_x = left_border + count_hitscan * (fill_size_x + col_margin);
2348                                 pos_y = top_border_hitscan + row * (fill_size_y + row_margin);
2349
2350                                 // background
2351                                 drawpic(pos, "gfx/hud/sb_accuracy", fill_size , fill_colour, sbar_alpha_bg, DRAWFLAG_NORMAL);
2352                                 drawborderlines(sbar_border_thickness, pos, fill_size, '0 0 0', sbar_alpha_bg, DRAWFLAG_NORMAL);
2353
2354                                 // the weapon
2355                                 drawpic(pos, strcat("gfx/hud/inv_weapon", ftos(i-1)), '1 0.5 0' * fill_size_x , '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2356
2357                                 // the amount of shots fired or max damage
2358                                 drawstringright(pos + '4.5 0 0' * sbar_fontsize_x + '0 3 0' * sbar_fontsize_y, ftos(weapon_damage), sbar_fontsize, '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2359
2360                                 // the amount of hits or actual damage
2361                                 drawstringright(pos + '4.5 0 0' * sbar_fontsize_x + '0 5 0' * sbar_fontsize_y, ftos(weapon_hit), sbar_fontsize, '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2362
2363                                 // the accuracy
2364                                 drawstringright(pos + '4.5 0 0' * sbar_fontsize_x + '0 7 0' * sbar_fontsize_y, strcat(ftos(weapon_stats),"%"), sbar_fontsize, '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2365
2366                                 // the amount of shots missed or damage wasted
2367                                 drawstringright(pos + '4.5 0 0' * sbar_fontsize_x + '0 9 0' * sbar_fontsize_y, ftos(max(0, weapon_damage - weapon_hit)), sbar_fontsize, '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2368
2369                                 ++count_hitscan;
2370                         }
2371                 }
2372         }
2373 }
2374
2375 void drawstringright(vector position, string text, vector scale, vector rgb, float alpha, float flag)
2376 {
2377         position_x -= 2 / 3 * strlen(text) * scale_x;
2378         drawstring(position, text, scale, rgb, alpha, flag);
2379 }
2380
2381 void drawstringcenter(vector position, string text, vector scale, vector rgb, float alpha, float flag)
2382 {
2383         position_x = 0.5 * (vid_conwidth - 0.6025 * strlen(text) * scale_x);
2384         drawstring(position, text, scale, rgb, alpha, flag);
2385 }
2386
2387 float GetAmmoStat(float i)
2388 {
2389         switch(i)
2390         {
2391                 case 0: return STAT_SHELLS;
2392                 case 1: return STAT_NAILS;
2393                 case 2: return STAT_ROCKETS;
2394                 case 3: return STAT_CELLS;
2395                 case 4: return STAT_FUEL;
2396                 default: return -1;
2397         }
2398 }
2399
2400 float GetAmmoItemCode(float i)
2401 {
2402         switch(i)
2403         {
2404                 case 0: return IT_SHELLS;
2405                 case 1: return IT_NAILS;
2406                 case 2: return IT_ROCKETS;
2407                 case 3: return IT_CELLS;
2408                 case 4: return IT_FUEL;
2409                 default: return -1;
2410         }
2411 }
2412
2413 string GetAmmoPicture(float i)
2414 {
2415         switch(i)
2416         {
2417                 case 0: return "gfx/hud/sb_shells";
2418                 case 1: return "gfx/hud/sb_bullets";
2419                 case 2: return "gfx/hud/sb_rocket";
2420                 case 3: return "gfx/hud/sb_cells";
2421                 case 4: return "gfx/hud/sb_fuel";
2422                 default: return "";
2423         }
2424 }
2425
2426 void Sbar_Reset (void)
2427 {
2428         // reset gametype specific icons
2429         if(gametype == GAME_KEYHUNT)
2430                 CSQC_kh_hudreset();
2431         else if(gametype == GAME_CTF)
2432                 CSQC_ctf_hudreset();
2433 }
2434
2435 void Sbar_Draw (void)
2436 {
2437         // vectors for top right, bottom right, bottom and bottom left corners
2438         vector topright;
2439         vector bottom;
2440         vector bottomright;
2441         vector bottomleft;
2442
2443         topright_x = vid_conwidth;
2444         topright_y = 0;
2445         topright_z = 0;
2446
2447         bottom_x = vid_conwidth/2;
2448         bottom_y = vid_conheight;
2449         bottom_z = 0;
2450
2451         bottomright_x = vid_conwidth;
2452         bottomright_y = vid_conheight;
2453         bottomright_z = 0;
2454
2455         bottomleft_x = 0;
2456         bottomleft_y = vid_conheight;
2457         bottomleft_z = 0;
2458
2459         sbar_alpha_bg = cvar("sbar_alpha_bg") * (1 - cvar("_menu_alpha"));
2460         sbar_border_thickness = bound(0, cvar("sbar_border_thickness"), 5);
2461         sbar_accuracy_border_thickness = bound(0, cvar_or("sbar_accuracy_border_thickness", 1), 5);
2462         sbar_color_bg_team = cvar("sbar_color_bg_team");
2463
2464         float i;
2465         float weapon_stats;
2466         float x, fade;
2467         float stat_items, stat_weapons;
2468
2469         weapon_stats = getstati(STAT_DAMAGE_HITS);
2470         weapon_number = weapon_stats & 63;
2471         weapon_hits[weapon_number] = rint(weapon_stats / 64);
2472
2473         weapon_stats = getstati(STAT_DAMAGE_FIRED);
2474         weapon_number = weapon_stats & 63;
2475         weapon_fired[weapon_number] = rint(weapon_stats / 64);
2476
2477         vector o; o = '1 0 0' * vid_conwidth;
2478         o_y = 28; // move spectator text slightly down to prevent overlapping the timer
2479
2480         string s;
2481         vector pos;
2482         pos = '0 0 0';
2483
2484         sbar_fontsize = Sbar_GetFontsize("sbar_fontsize");
2485         sbar_fontsize_spec = Sbar_GetFontsize("sbar_fontsize_spec");
2486
2487         if(spectatee_status && !intermission)
2488         {
2489                 drawfont = sbar_bigfont;
2490                 if(spectatee_status == -1)
2491                         s = "^1Observing";
2492                 else
2493                         s = GetPlayerName(spectatee_status - 1);
2494                 // spectated player name between HUD and chat area, aligned to the left
2495                 pos_x = bottomleft_x;
2496                 pos_y = bottom_y - 50 - sbar_fontsize_spec_y;
2497                 s = textShortenToWidth(s, vid_conwidth/2.5/sbar_fontsize_spec_x, stringwidth_colors);
2498                 drawcolorcodedstring(pos, s, sbar_fontsize_spec, sbar_alpha_fg, DRAWFLAG_NORMAL);
2499                 drawfont = sbar_font;
2500
2501                 // spectator text in the upper right corner
2502                 if(spectatee_status == -1)
2503                         s = strcat("^1Press ^3", getcommandkey("primary fire", "+attack"), "^1 to spectate");
2504                 else
2505                         s = strcat("^1Press ^3", getcommandkey("primary fire", "+attack"), "^1 for another player");
2506                 o = Sbar_DrawNoteLine(o, s);
2507
2508                 if(spectatee_status == -1)
2509                         s = strcat("^1Use ^3", getcommandkey("next weapon", "weapnext"), "^1 or ^3", getcommandkey("previous weapon", "weapprev"), "^1 to change the speed");
2510                 else
2511                         s = strcat("^1Press ^3", getcommandkey("secondary fire", "+attack2"), "^1 to observe");
2512                 o = Sbar_DrawNoteLine(o, s);
2513
2514                 s = strcat("^1Press ^3", getcommandkey("server info", "+show_info"), "^1 for gamemode info");
2515                 o = Sbar_DrawNoteLine(o, s);
2516
2517                 if(gametype == GAME_ARENA)
2518                         s = "^1Wait for your turn to join";
2519                 else if(gametype == GAME_LMS)
2520                 {
2521                         entity sk;
2522                         sk = playerslots[player_localentnum - 1];
2523                         if(sk.(scores[ps_primary]) >= 666)
2524                                 s = "^1Match has already begun";
2525                         else if(sk.(scores[ps_primary]) > 0)
2526                                 s = "^1You have no more lives left";
2527                         else
2528                                 s = strcat("^1Press ^3", getcommandkey("jump", "+jump"), "^1 to join");
2529                 }
2530                 else
2531                         s = strcat("^1Press ^3", getcommandkey("jump", "+jump"), "^1 to join");
2532                 o = Sbar_DrawNoteLine(o, s);
2533
2534                 //show restart countdown:
2535                 if (time < getstatf(STAT_GAMESTARTTIME)) {
2536                         float countdown;
2537                         //we need to ceil, otherwise the countdown would be off by .5 when using round()
2538                         countdown = ceil(getstatf(STAT_GAMESTARTTIME) - time);
2539                         s = strcat("^1Game starts in ^3", ftos(countdown), "^1 seconds");
2540                         o = Sbar_DrawNoteLine(o, s);
2541                 }
2542         }
2543         if(warmup_stage && !intermission)
2544         {
2545                 s = "^2Currently in ^1warmup^2 stage!";
2546                 o = Sbar_DrawNoteLine(o, s);
2547         }
2548
2549         // move more important stuff more to the middle so its more visible
2550         o_y = vid_conheight * 0.66;
2551
2552         string blinkcolor;
2553         if(mod(time, 1) >= 0.5)
2554                 blinkcolor = "^1";
2555         else
2556                 blinkcolor = "^3";
2557
2558         if(ready_waiting && !intermission && !spectatee_status)
2559         {
2560                 if(ready_waiting_for_me)
2561                 {
2562                         if(warmup_stage)
2563                                 s = strcat(blinkcolor, "Press ^3", getcommandkey("ready", "ready"), blinkcolor, " to end warmup");
2564                         else
2565                                 s = strcat(blinkcolor, "Press ^3", getcommandkey("ready", "ready"), blinkcolor, " once you are ready");
2566                 }
2567                 else
2568                 {
2569                         if(warmup_stage)
2570                                 s = strcat("^2Waiting for others to ready up to end warmup...");
2571                         else
2572                                 s = strcat("^2Waiting for others to ready up...");
2573                 }
2574                 o = Sbar_DrawNoteLine(o, s);
2575         }
2576         else if(warmup_stage && !intermission && !spectatee_status)
2577         {
2578                 s = strcat("^2Press ^3", getcommandkey("ready", "ready"), "^2 to end warmup");
2579                 o = Sbar_DrawNoteLine(o, s);
2580         }
2581         if(vote_waiting)
2582         {
2583                 s = strcat("^2A vote has been called for ^1",  textShortenToWidth(vote_called_vote, vid_conwidth/2/sbar_fontsize_x, stringwidth_colors));
2584                 o = Sbar_DrawNoteLine(o, s);
2585
2586                 if(vote_waiting_for_me)
2587                 {
2588                         s = strcat(blinkcolor, "Press ^3", getcommandkey("vote yes", "vyes"), blinkcolor, " to accept");
2589                         o = Sbar_DrawNoteLine(o, s);
2590
2591                         s = strcat(blinkcolor, "Press ^3", getcommandkey("vote no", "vno"), blinkcolor, " to reject");
2592                         o = Sbar_DrawNoteLine(o, s);
2593
2594                         s = strcat(blinkcolor, "Press ^3", getcommandkey("vote abstain", "vabstain"), blinkcolor, " to abstain");
2595                         o = Sbar_DrawNoteLine(o, s);
2596                 }
2597                 else
2598                 {
2599                         s = strcat("^2Waiting for others to vote...");
2600                         o = Sbar_DrawNoteLine(o, s);
2601                 }
2602         }
2603         if(teamplay && !intermission && !spectatee_status && gametype != GAME_CA && teamnagger)
2604         {
2605                 entity tm;
2606                 float ts_min, ts_max;
2607                 tm = teams.sort_next;
2608                 if (tm)
2609                 {
2610                         for(; tm.sort_next; tm = tm.sort_next)
2611                         {
2612                                 if(!tm.team_size || tm.team == COLOR_SPECTATOR)
2613                                         continue;
2614                                 if(!ts_min) ts_min = tm.team_size;
2615                                 else ts_min = min(ts_min, tm.team_size);
2616                                 if(!ts_max) ts_max = tm.team_size;
2617                                 else ts_max = max(ts_max, tm.team_size);
2618                         }
2619                         if ((ts_max - ts_min) > 1)
2620                         {
2621                                 s = strcat(blinkcolor, "Teamnumbers are unbalanced!");
2622                                 tm = GetTeam(myteam, false);
2623                                 if (tm)
2624                                 if (tm.team != COLOR_SPECTATOR)
2625                                 if (tm.team_size == ts_max)
2626                                         s = strcat(s, " Press ^3", getcommandkey("team menu", "menu_showteamselect"), blinkcolor, " to adjust");
2627
2628                                 o = Sbar_DrawNoteLine(o, s);
2629                         }
2630                 }
2631         }
2632
2633         Sbar_UpdatePlayerTeams();
2634         if (intermission == 2) // map voting screen
2635         {
2636                 if(sb_showaccuracy) {
2637                         Sbar_DrawAccuracyStats();
2638                         Sbar_Score();
2639                         Sbar_Timer();
2640                 }
2641                 else if(sb_showscores) {
2642                         Sbar_DrawScoreboard();
2643                         Sbar_Score();
2644                         Sbar_Timer();
2645                 }
2646                 else
2647                         Sbar_FinaleOverlay();
2648
2649                 Sbar_Reset();
2650         }
2651         else if (sb_showscores_force || getstati(STAT_HEALTH) <= 0 || intermission == 1)
2652         {
2653                 if(sb_showaccuracy)
2654                         Sbar_DrawAccuracyStats();
2655                 else
2656                         Sbar_DrawScoreboard();
2657                 Sbar_Score();
2658                 Sbar_Timer();
2659
2660                 Sbar_Reset();
2661         }
2662         else
2663         {
2664                 if(sb_showaccuracy)
2665                         Sbar_DrawAccuracyStats();
2666                 else
2667                         Sbar_DrawScoreboard();
2668                 float armor, health;
2669                 armor = getstati(STAT_ARMOR);
2670                 health = getstati(STAT_HEALTH);
2671
2672                 stat_items = getstati(STAT_ITEMS);
2673                 stat_weapons = getstati(STAT_WEAPONS);
2674
2675                 fade = 3.2 - 2 * (time - weapontime);
2676                 fade = bound(0.7, fade, 1);
2677
2678                 vector bg_size; // hud background size
2679                 bg_size = '1600 58 0';
2680
2681                 if (cvar("viewsize") <= 100 && vid_conwidth <= 1600) {
2682                         if (teamplay)
2683                                 drawpic(bottom - '800 58 0', "gfx/hud/sbar", bg_size, GetTeamRGB(myteam) * sbar_color_bg_team, sbar_alpha_bg, DRAWFLAG_NORMAL); // hud color = myteam color
2684                         else {
2685                                 // allow for custom HUD colors in non-teamgames
2686                                 color_x = cvar("sbar_color_bg_r");
2687                                 color_y = cvar("sbar_color_bg_g");
2688                                 color_z = cvar("sbar_color_bg_b");
2689
2690                                 drawpic(bottom - '800 58 0', "gfx/hud/sbar", bg_size, color, sbar_alpha_bg, DRAWFLAG_NORMAL);
2691                         }
2692                 }
2693
2694                 if(sbar_hudselector == 2) // combined health and armor display
2695                 {
2696                         vector v;
2697                         v = healtharmor_maxdamage(health, armor, armorblockpercent);
2698
2699                         vector num_pos;
2700                         num_pos = bottom - '96 28 0';
2701
2702                         x = floor(v_x + 1);
2703
2704                         if(v_z) // fully armored
2705                         {
2706                                 // here, armorideal > armor
2707                                 drawpic(num_pos + '78 -4.5 0', "gfx/hud/sb_health", '32 32 0', '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2708                                 drawpic(num_pos + '108 -4.5 0', "gfx/hud/sb_armor", '20 20 0', '1 1 1', sbar_alpha_fg * armor / v_y, DRAWFLAG_NORMAL);
2709                         }
2710                         else
2711                         {
2712                                 drawpic(num_pos + '108 -4.5 0', "gfx/hud/sb_health", '20 20 0', '1 1 1', sbar_alpha_fg * v_y / armor, DRAWFLAG_NORMAL);
2713                                 drawpic(num_pos + '78 -4.5 0', "gfx/hud/sb_armor", '32 32 0', '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2714                         }
2715                         Sbar_DrawXNum_Colored(num_pos, x, 24, sbar_alpha_fg); // draw the combined health and armor
2716                 }
2717
2718                 else
2719                 {
2720                         vector health_pos, armor_pos;
2721
2722                         if (sbar_hudselector == 0) { // old style layout with armor left of health
2723                                 armor_pos = bottom - '96 28 0';
2724                                 health_pos = bottom - '-14 28 0';
2725                         }
2726                         else {
2727                                 health_pos = bottom - '96 28 0';
2728                                 armor_pos = bottom - '-14 28 0';
2729                         }
2730
2731                         // armor
2732                         x = armor;
2733                         if (x > 0)
2734                         {
2735                                 if (x > 45) {
2736                                         drawpic(armor_pos + '78 -4.5 0', "gfx/hud/sb_armor", '32 32 0', '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2737                                         Sbar_DrawXNum_Colored(armor_pos, x, 24, sbar_alpha_fg);
2738                                 }
2739                                 else {
2740                                         drawpic(armor_pos + '78 -4.5 0', "gfx/hud/sb_armor", '32 32 0', '1 1 1', (x+10)/55 * sbar_alpha_fg, DRAWFLAG_NORMAL);
2741                                         Sbar_DrawXNum_Colored(armor_pos, x, 24, sbar_alpha_fg);
2742                                 }
2743                         }
2744
2745                         // health
2746                         x = health;
2747                         drawpic(health_pos + '78 -4.5 0', "gfx/hud/sb_health", '32 32 0', '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2748                         Sbar_DrawXNum_Colored(health_pos, x, 24, sbar_alpha_fg);
2749                 }
2750
2751                 // ammo
2752                 float a; // i will be the ammo type (already declared), a will contain how much ammo there is of type i
2753
2754                 for (i = 0; i < 4; ++i) {
2755                         a = getstati(GetAmmoStat(i)); // how much ammo do we have of type i?
2756
2757                         if(sbar_currentammo || vid_conwidth < 800) { // force showing current ammo only with conwidths < 800
2758                                 if (stat_items & GetAmmoItemCode(i)) {
2759                                         if (vid_conwidth >= 800) {
2760                                                 pos_x = 230;
2761                                                 pos_y = 40;
2762                                         } else {
2763                                                 pos_x = 206;
2764                                                 pos_y = 33;
2765                                         }
2766
2767                                         pos = bottom - pos;
2768                                         if(vid_conwidth >= 800)
2769                                                 drawpic(pos + '0 1.5 0', "gfx/hud/sb_ammobg", '107 29 0', '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2770                                         drawpic(pos + '76 3 0', GetAmmoPicture(i), '24 24 0', '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2771                                         if(a < 10)
2772                                                 Sbar_DrawXNum(pos + '5 5 0', a, 3, 0, 24, '0.7 0 0', 0, 0, sbar_alpha_fg, DRAWFLAG_NORMAL);
2773                                         else
2774                                                 Sbar_DrawXNum(pos + '5 5 0', a, 3, 0, 24, '1 1 1', 0, 0, sbar_alpha_fg, DRAWFLAG_NORMAL);
2775                                 }
2776                         } else {
2777                                 if (a > 0) {
2778                                         switch (i) {
2779                                                 case 0: pos_x = 286; pos_y = 48; break; // shells
2780                                                 case 1: pos_x = 286; pos_y = 26; break; // bullets
2781                                                 case 2: pos_x = 200; pos_y = 48; break; // rockets
2782                                                 case 3: pos_x = 200; pos_y = 26; break; // cells
2783                                         }
2784
2785                                         pos = bottom - pos;
2786                                         if (stat_items & GetAmmoItemCode(i))
2787                                                 drawpic(pos + '0 1.5 0', "gfx/hud/sb_ammobg", '80 22 0', '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2788                                         drawpic(pos + '56 3 0', GetAmmoPicture(i), '18 18 0', '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2789                                         if (a < 10) {
2790                                                 if(stat_items & GetAmmoItemCode(i))
2791                                                         Sbar_DrawXNum(pos + '6 4.5 0', a, 3, 0, 16, '0.7 0 0', 0, 0, sbar_alpha_fg, DRAWFLAG_NORMAL);
2792                                                 else
2793                                                         Sbar_DrawXNum(pos + '6 4.5 0', a, 3, 0, 16, '0.7 0 0', 0, 0, sbar_alpha_fg * 0.7, DRAWFLAG_NORMAL);
2794                                         } else {
2795                                                 if(stat_items & GetAmmoItemCode(i))
2796                                                         Sbar_DrawXNum(pos + '6 4.5 0', a, 3, 0, 16, '1 1 1', 0, 0, sbar_alpha_fg, DRAWFLAG_NORMAL);
2797                                                 else
2798                                                         Sbar_DrawXNum(pos + '6 4.5 0', a, 3, 0, 16, '0.7 0.7 0.7', 0, 0, sbar_alpha_fg * 0.7, DRAWFLAG_NORMAL);
2799                                         }
2800                                 }
2801                         }
2802                 }
2803
2804                 // fuel ammo
2805                 a = getstati(GetAmmoStat(4)); // how much fuel do we have?
2806
2807                 if (a > 0) { // if we have fuel, draw the amount
2808                         float invincibility_time, dt;
2809                         invincibility_time = getstatf(STAT_INVINCIBLE_FINISHED);
2810                         dt = invincibility_time - time;
2811                         if (vid_conwidth >= 800) {
2812                                 if (dt > 0) { // if the invincibility timer is active, draw fuel ammo elsewhere
2813                                         pos_x = bottom_x + 140;
2814                                         pos_y = bottom_y - 72;
2815                                 }
2816                                 else { // if the invincibility timer is inactive, draw the fuel ammo there (it's rare to have invincibility + fuel anyway)
2817                                         pos_x = bottom_x + 140;
2818                                         pos_y = bottom_y - 20;
2819                                 }
2820                         }
2821                         else { // draw fuel on top of ammo if vid_conwidth < 800
2822                                 pos_x = bottom_x - 200;
2823                                 pos_y = bottom_y - 45;
2824                         }
2825                         drawpic(pos - '0 2 0' + '52 0 0', GetAmmoPicture(4), '20 20 0', '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2826                         if (a > 10)
2827                                 Sbar_DrawXNum(pos, a, 3, 0, 16, '1 1 1', 0, 0, sbar_alpha_fg, DRAWFLAG_NORMAL);
2828                         else
2829                                 Sbar_DrawXNum(pos, a, 3, 0, 16, '0.7 0 0', 0, 0, sbar_alpha_fg, DRAWFLAG_NORMAL);
2830                 }
2831
2832                 // draw scores and timer
2833                 Sbar_Score();
2834                 Sbar_Timer();
2835
2836                 // draw strength/invincibility icon and timer
2837                 CSQC_Strength_Timer();
2838
2839                 // weapon icons
2840                 if(cvar_or("sbar_showweaponicons", 1)) {
2841                         x = 1.0;
2842                         Sbar_DrawWeapon_Clear();
2843                         for(i = 1; i <= 24; ++i)
2844                         {
2845                                 if(weaponimpulse[i-1] >= 0)
2846                                 if(stat_weapons & x)
2847                                         Sbar_DrawWeapon(i-1, fade, (i == activeweapon), i);
2848                                 x *= 2;
2849                         }
2850                 }
2851
2852                 // draw gametype specific icons
2853                 if(gametype == GAME_KEYHUNT)
2854                         CSQC_kh_hud();
2855                 else if(gametype == GAME_CTF)
2856                         CSQC_ctf_hud();
2857                 else if(gametype == GAME_NEXBALL)
2858                         CSQC_nb_hud();
2859                 else if(gametype == GAME_CTS || gametype == GAME_RACE)
2860                         CSQC_race_hud();
2861         }
2862         return;
2863 }
2864
2865 // CTF HUD
2866 float redflag_prevframe, blueflag_prevframe; // status during previous frame
2867 float redflag_prevstatus, blueflag_prevstatus; // last remembered status
2868 float redflag_statuschange_time, blueflag_statuschange_time; // time when the status changed
2869
2870 void CSQC_ctf_hudreset(void)
2871 {
2872         redflag_prevstatus = blueflag_prevstatus = redflag_prevframe = blueflag_prevframe = redflag_statuschange_time = blueflag_statuschange_time = 0;
2873 }
2874
2875 void CSQC_ctf_hud(void)
2876 {
2877         vector bottomleft, redflag_pos, blueflag_pos, sz;
2878         float f; // every function should have that
2879         bottomleft_x = 0;
2880         bottomleft_y = vid_conheight;
2881         bottomleft_z = 0;
2882
2883         float redflag, blueflag; // current status
2884         float redflag_statuschange_elapsedtime, blueflag_statuschange_elapsedtime; // time since the status changed
2885         float stat_items;
2886
2887         stat_items = getstati(STAT_ITEMS);
2888         redflag = (stat_items/IT_RED_FLAG_TAKEN) & 3;
2889         blueflag = (stat_items/IT_BLUE_FLAG_TAKEN) & 3;
2890
2891         // when status CHANGES, set old status into prevstatus and current status into status
2892         if (redflag != redflag_prevframe)
2893         {
2894                 redflag_statuschange_time = time;
2895                 redflag_prevstatus = redflag_prevframe;
2896                 redflag_prevframe = redflag;
2897         }
2898
2899         if (blueflag != blueflag_prevframe)
2900         {
2901                 blueflag_statuschange_time = time;
2902                 blueflag_prevstatus = blueflag_prevframe;
2903                 blueflag_prevframe = blueflag;
2904         }
2905
2906         redflag_statuschange_elapsedtime = time - redflag_statuschange_time;
2907         blueflag_statuschange_elapsedtime = time - blueflag_statuschange_time;
2908
2909         float BLINK_FACTOR = 0.15;
2910         float BLINK_BASE = 0.85;
2911         // note:
2912         //   RMS = sqrt(BLINK_BASE^2 + 0.5 * BLINK_FACTOR^2)
2913         // thus
2914         //   BLINK_BASE = sqrt(RMS^2 - 0.5 * BLINK_FACTOR^2)
2915         // ensure RMS == 1
2916         float BLINK_FREQ = 5; // circle frequency, = 2*pi*frequency in hertz
2917
2918         string red_icon, red_icon_prevstatus;
2919         float red_alpha, red_alpha_prevstatus;
2920         red_alpha = red_alpha_prevstatus = 1;
2921         switch(redflag) {
2922                 case 1: red_icon = "gfx/hud/sb_flag_red_taken"; break;
2923                 case 2: red_icon = "gfx/hud/sb_flag_red_lost"; break;
2924                 case 3: red_icon = "gfx/hud/sb_flag_red_carrying"; red_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break;
2925                 default:
2926                         if((stat_items & IT_CTF_SHIELDED) && (myteam == COLOR_TEAM2))
2927                                 red_icon = "gfx/hud/sb_flag_red_shielded";
2928                         else
2929                                 red_icon = string_null;
2930                         break;
2931         }
2932         switch(redflag_prevstatus) {
2933                 case 1: red_icon_prevstatus = "gfx/hud/sb_flag_red_taken"; break;
2934                 case 2: red_icon_prevstatus = "gfx/hud/sb_flag_red_lost"; break;
2935                 case 3: red_icon_prevstatus = "gfx/hud/sb_flag_red_carrying"; red_alpha_prevstatus = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break;
2936                 default:
2937                         if(redflag == 3)
2938                                 red_icon_prevstatus = "gfx/hud/sb_flag_red_carrying"; // make it more visible
2939                         else if((stat_items & IT_CTF_SHIELDED) && (myteam == COLOR_TEAM2))
2940                                 red_icon_prevstatus = "gfx/hud/sb_flag_red_shielded";
2941                         else
2942                                 red_icon_prevstatus = string_null;
2943                         break;
2944         }
2945
2946         string blue_icon, blue_icon_prevstatus;
2947         float blue_alpha, blue_alpha_prevstatus;
2948         blue_alpha = blue_alpha_prevstatus = 1;
2949         switch(blueflag) {
2950                 case 1: blue_icon = "gfx/hud/sb_flag_blue_taken"; break;
2951                 case 2: blue_icon = "gfx/hud/sb_flag_blue_lost"; break;
2952                 case 3: blue_icon = "gfx/hud/sb_flag_blue_carrying"; blue_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break;
2953                 default:
2954                         if((stat_items & IT_CTF_SHIELDED) && (myteam == COLOR_TEAM1))
2955                                 blue_icon = "gfx/hud/sb_flag_blue_shielded";
2956                         else
2957                                 blue_icon = string_null;
2958                         break;
2959         }
2960         switch(blueflag_prevstatus) {
2961                 case 1: blue_icon_prevstatus = "gfx/hud/sb_flag_blue_taken"; break;
2962                 case 2: blue_icon_prevstatus = "gfx/hud/sb_flag_blue_lost"; break;
2963                 case 3: blue_icon_prevstatus = "gfx/hud/sb_flag_blue_carrying"; blue_alpha_prevstatus = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break;
2964                 default:
2965                         if(blueflag == 3)
2966                                 blue_icon_prevstatus = "gfx/hud/sb_flag_blue_carrying"; // make it more visible
2967                         else if((stat_items & IT_CTF_SHIELDED) && (myteam == COLOR_TEAM1))
2968                                 blue_icon_prevstatus = "gfx/hud/sb_flag_blue_shielded";
2969                         else
2970                                 blue_icon_prevstatus = string_null;
2971                         break;
2972         }
2973
2974         if (myteam == COLOR_TEAM1) { // always draw own flag on left
2975                 redflag_pos = bottomleft - '-4 50 0';
2976                 blueflag_pos = bottomleft - '-62 50 0';
2977         } else {
2978                 blueflag_pos = bottomleft - '-4 50 0';
2979                 redflag_pos = bottomleft - '-62 50 0';
2980         }
2981
2982         sz = '52 52 0';
2983
2984         f = bound(0, redflag_statuschange_elapsedtime*2, 1);
2985         if(red_icon_prevstatus && f < 1)
2986                 drawpic_expanding(redflag_pos, red_icon_prevstatus, sz, '1 1 1', sbar_alpha_fg * red_alpha_prevstatus, DRAWFLAG_NORMAL, f);
2987         if(red_icon)
2988                 drawpic(redflag_pos, red_icon, sz, '1 1 1', sbar_alpha_fg * red_alpha * f, DRAWFLAG_NORMAL);
2989
2990         f = bound(0, blueflag_statuschange_elapsedtime*2, 1);
2991         if(blue_icon_prevstatus && f < 1)
2992                 drawpic_expanding(blueflag_pos, blue_icon_prevstatus, sz, '1 1 1', sbar_alpha_fg * blue_alpha_prevstatus, DRAWFLAG_NORMAL, f);
2993         if(blue_icon)
2994                 drawpic(blueflag_pos, blue_icon, sz, '1 1 1', sbar_alpha_fg * blue_alpha * f, DRAWFLAG_NORMAL);
2995 }
2996
2997 // Keyhunt HUD
2998 float kh_runheretime;
2999
3000 void CSQC_kh_hudreset(void)
3001 {
3002         kh_runheretime = 0;
3003 }
3004
3005 void CSQC_kh_hud(void)
3006 {
3007         float kh_keys;
3008         float keyteam;
3009         float a, aa;
3010         vector p, pa, kh_size, kh_asize;
3011
3012         vector bottomleft;
3013         bottomleft_x = 0;
3014         bottomleft_y = vid_conheight;
3015         bottomleft_z = 0;
3016
3017         p_x = 6;
3018         p_y = vid_conheight - 34 - 3;
3019         p_z = 0;
3020
3021         kh_keys = getstati(STAT_KH_KEYS);
3022
3023         kh_size = '19 34 0';
3024         kh_asize = '19 10 0';
3025         pa = p + '0 -10 0';
3026
3027         float i, key;
3028
3029         float keycount;
3030         keycount = 0;
3031         for(i = 0; i < 4; ++i)
3032         {
3033                 key = floor(kh_keys / pow(32, i)) & 31;
3034                 keyteam = key - 1;
3035                 if(keyteam == 30 && keycount <= 4)
3036                         keycount += 4;
3037                 if(keyteam == myteam || keyteam == -1 || keyteam == 30)
3038                         keycount += 1;
3039         }
3040         // this yields 8 exactly if "RUN HERE" shows
3041
3042         if(keycount == 8)
3043         {
3044                 if(!kh_runheretime)
3045                         kh_runheretime = time;
3046                 pa_y -= fabs(sin((time - kh_runheretime) * 3.5)) * 6; // make the arrows jump in case of RUN HERE
3047         }
3048         else
3049                 kh_runheretime = 0;
3050
3051         for(i = 0; i < 4; ++i)
3052         {
3053                 key = floor(kh_keys / pow(32, i)) & 31;
3054                 keyteam = key - 1;
3055                 switch(keyteam)
3056                 {
3057                         case 30: // my key
3058                                 keyteam = myteam;
3059                                 a = 1;
3060                                 aa = 1;
3061                                 break;
3062                         case -1: // no key
3063                                 a = 0;
3064                                 aa = 0;
3065                                 break;
3066                         default: // owned or dropped
3067                                 a = 0.2;
3068                                 aa = 0.5;
3069                                 break;
3070                 }
3071                 a = a * sbar_alpha_fg;
3072                 aa = aa * sbar_alpha_fg;
3073                 if(a > 0)
3074                 {
3075                         switch(keyteam)
3076                         {
3077                                 case COLOR_TEAM1:
3078                                         drawpic (pa, "gfx/hud/sb_kh_redarrow", kh_asize, '1 1 1', aa, DRAWFLAG_NORMAL);  // show 30% alpha key
3079                                         break;
3080                                 case COLOR_TEAM2:
3081                                         drawpic (pa, "gfx/hud/sb_kh_bluearrow", kh_asize, '1 1 1', aa, DRAWFLAG_NORMAL);  // show 30% alpha key
3082                                         break;
3083                                 case COLOR_TEAM3:
3084                                         drawpic (pa, "gfx/hud/sb_kh_yellowarrow", kh_asize, '1 1 1', aa, DRAWFLAG_NORMAL);  // show 30% alpha key
3085                                         break;
3086                                 case COLOR_TEAM4:
3087                                         drawpic (pa, "gfx/hud/sb_kh_pinkarrow", kh_asize, '1 1 1', aa, DRAWFLAG_NORMAL);  // show 30% alpha key
3088                                         break;
3089                                 default:
3090                                         break;
3091                         }
3092                         switch(i) // YAY! switch(i) inside a for loop for i. DailyWTF, here we come!
3093                         {
3094                                 case 0:
3095                                         drawpic (p, "gfx/hud/sb_kh_red", kh_size, '1 1 1', a, DRAWFLAG_NORMAL);  // show 30% alpha key
3096                                         break;
3097                                 case 1:
3098                                         drawpic (p, "gfx/hud/sb_kh_blue", kh_size, '1 1 1', a, DRAWFLAG_NORMAL);  // show 30% alpha key
3099                                         break;
3100                                 case 2:
3101                                         drawpic (p, "gfx/hud/sb_kh_yellow", kh_size, '1 1 1', a, DRAWFLAG_NORMAL);  // show 30% alpha key
3102                                         break;
3103                                 case 3:
3104                                         drawpic (p, "gfx/hud/sb_kh_pink", kh_size, '1 1 1', a, DRAWFLAG_NORMAL);  // show 30% alpha key
3105                                         break;
3106                         }
3107                 }
3108                 p_x += 24;
3109                 pa_x += 24;
3110         }
3111 }
3112
3113 //Nexball HUD
3114 #define NBPB_SIZE '96 38 0'
3115 #define NBPB_BT 2                   //thickness
3116 #define NBPB_BRGB '1 1 1'
3117 #define NBPB_BALPH 1                //alpha
3118 #define NBPB_BFLAG DRAWFLAG_NORMAL
3119 #define NBPB_IALPH 0.4
3120 #define NBPB_IFLAG DRAWFLAG_NORMAL
3121 #define NBPB_IRGB '0.7 0.1 0'
3122
3123 void CSQC_nb_hud(void)
3124 {
3125         float stat_items, nb_pb_starttime, dt, p;
3126         vector pos;
3127
3128         stat_items = getstati(STAT_ITEMS);
3129         nb_pb_starttime = getstatf(STAT_NB_METERSTART);
3130
3131         pos_x = 4;
3132         pos_y = vid_conheight - 42;
3133         pos_z = 0;
3134
3135         //Manage the progress bar if any
3136         if (nb_pb_starttime > 0)
3137         {
3138                 vector s;
3139                 dt = mod(time - nb_pb_starttime, nb_pb_period);
3140                 // one period of positive triangle
3141                 p = 2 * dt / nb_pb_period;
3142                 if (p > 1)
3143                         p = 2 - p;
3144
3145                 s = NBPB_SIZE;
3146                 //Draw the filling
3147                 drawfill(pos, p * s_x * '1 0 0' + s_y * '0 1 0', NBPB_IRGB, NBPB_IALPH, NBPB_IFLAG);
3148
3149                 //Draw the box
3150                 s = NBPB_SIZE;
3151                 drawline(NBPB_BT, pos    , pos + '1 0 0' * s_x, NBPB_BRGB, NBPB_BALPH, NBPB_BFLAG);
3152                 drawline(NBPB_BT, pos    , pos + '0 1 0' * s_y, NBPB_BRGB, NBPB_BALPH, NBPB_BFLAG);
3153                 drawline(NBPB_BT, pos + s, pos + '1 0 0' * s_x, NBPB_BRGB, NBPB_BALPH, NBPB_BFLAG);
3154                 drawline(NBPB_BT, pos + s, pos + '0 1 0' * s_y, NBPB_BRGB, NBPB_BALPH, NBPB_BFLAG);
3155         }
3156
3157         pos_x += 12; //horizontal margin to the picture
3158         pos_y += 2; //vertical margin to the picture
3159
3160         if (stat_items & IT_KEY1)
3161                 drawpic(pos, "gfx/hud/sb_nexball_carrying", '80 34 0', '1 1 1', 1, DRAWFLAG_NORMAL);
3162 }
3163
3164 float crecordtime_prev; // last remembered crecordtime
3165 float crecordtime_change_time; // time when crecordtime last changed
3166 float srecordtime_prev; // last remembered srecordtime
3167 float srecordtime_change_time; // time when srecordtime last changed
3168 void CSQC_race_hud(void)
3169 {
3170         entity me;
3171         me = playerslots[player_localentnum - 1];
3172         float t, score;
3173         float f; // yet another function has this
3174         score = me.(scores[ps_primary]);
3175
3176         if not((scores_flags[ps_primary] & SFL_TIME) && !teamplay) // race/cts record display on HUD
3177                 return; // no records in the actual race
3178
3179         drawfont = sbar_bigfont;
3180         vector pos;
3181         pos_x = 2;
3182         pos_y = vid_conheight - 48;
3183
3184         // clientside personal record
3185         string rr;
3186         if(gametype == GAME_CTS)
3187                 rr = CTS_RECORD;
3188         else
3189                 rr = RACE_RECORD;
3190         t = stof(db_get(ClientProgsDB, strcat(shortmapname, rr, "time")));
3191
3192         if(score && score < t || !t)
3193                 db_put(ClientProgsDB, strcat(shortmapname, rr, "time"), ftos(score));
3194
3195         if(t != crecordtime_prev) {
3196                 crecordtime_prev = t;
3197                 crecordtime_change_time = time;
3198         }
3199         f = time - crecordtime_change_time;
3200
3201         if (f > 1) {
3202                 drawstring(pos, "Personal best ", '10 10 0', '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
3203                 drawstring(pos + '0 10 0', TIME_ENCODED_TOSTRING(t),'14 14 0', '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
3204         } else {
3205                 drawstring(pos, "Personal best ", '10 10 0', '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
3206                 drawstring(pos + '0 10 0', TIME_ENCODED_TOSTRING(t),'14 14 0', '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
3207
3208                 // expanding
3209                 drawstring(pos - '0 50 0' * f, "Personal best ", '10 10 0' + '30 30 0' * f, '1 1 1', sbar_alpha_fg * (1 - f), DRAWFLAG_NORMAL);
3210                 drawstring(pos + '0 10 0' - '0 30 0' * f, TIME_ENCODED_TOSTRING(t),'14 14 0' + '42 42 0' * f, '1 1 1', sbar_alpha_fg * (1 - f), DRAWFLAG_NORMAL);
3211         }
3212
3213         // server record
3214         pos_y += 26;
3215         t = race_server_record;
3216         if(t != srecordtime_prev) {
3217                 srecordtime_prev = t;
3218                 srecordtime_change_time = time;
3219         }
3220         f = time - srecordtime_change_time;
3221
3222         if (f > 1) {
3223                 drawstring(pos, "Server best ", '10 10 0', '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
3224                 drawstring(pos + '0 10 0', TIME_ENCODED_TOSTRING(t),'14 14 0', '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
3225         } else {
3226                 drawstring(pos, "Server best ", '10 10 0', '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
3227                 drawstring(pos + '0 10 0', TIME_ENCODED_TOSTRING(t),'14 14 0', '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
3228
3229                 // expanding
3230                 drawstring(pos - '0 50 0' * f, "Server best ", '10 10 0' + '30 30 0' * f, '1 1 1', sbar_alpha_fg * (1 - f), DRAWFLAG_NORMAL);
3231                 drawstring(pos + '0 10 0' - '0 30 0' * f, TIME_ENCODED_TOSTRING(t),'14 14 0' + '42 42 0' * f, '1 1 1', sbar_alpha_fg * (1 - f), DRAWFLAG_NORMAL);
3232         }
3233         drawfont = sbar_font;
3234 }