data/qcsrc/client/projectile.qc

   1 .float spawntime;
   2 .vector trail_oldorigin;
   3
   4 void SUB_Null()
   5 {
   6 }
   7
   8 void SUB_Stop()
   9 {
  10         self.move_velocity = self.move_avelocity = '0 0 0';
  11         self.move_movetype = MOVETYPE_NONE;
  12 }
  13
  14 .float count; // set if clientside projectile
  15 .float cnt; // sound index
  16 .float gravity;
  17 .float snd_looping;
  18
  19 void Projectile_DrawTrail(vector to)
  20 {
  21         vector from;
  22         from = self.trail_oldorigin;
  23         self.trail_oldorigin = to;
  24         switch(self.cnt)
  25         {
  26                 case PROJECTILE_ROCKET:
  27                         trailparticles(self, particleeffectnum("TR_ROCKET"), from, to);
  28                         break;
  29                 case PROJECTILE_TAG:
  30                         trailparticles(self, particleeffectnum("TR_VORESPIKE"), from, to);
  31                         break;
  32                 case PROJECTILE_ELECTRO_BEAM:
  33                         trailparticles(self, particleeffectnum("TR_NEXUIZPLASMA"), from, to);
  34                         break;
  35                 case PROJECTILE_GRENADE:
  36                         trailparticles(self, particleeffectnum("TR_KNIGHTSPIKE"), from, to);
  37                         break;
  38                 case PROJECTILE_GRENADE_BOUNCING:
  39                         trailparticles(self, particleeffectnum("TR_KNIGHTSPIKE"), from, to);
  40                         break;
  41                 case PROJECTILE_PORTO_RED:
  42                         trailparticles(self, particleeffectnum("TR_WIZSPIKE"), from, to);
  43                         break;
  44                 case PROJECTILE_PORTO_BLUE:
  45                         trailparticles(self, particleeffectnum("TR_WIZSPIKE"), from, to);
  46                         break;
  47                 case PROJECTILE_FLAC:
  48                         trailparticles(self, particleeffectnum("TR_VORESPIKE"), from, to);
  49                         break;
  50                 case PROJECTILE_SEEKER:
  51                         trailparticles(self, particleeffectnum("TR_ROCKET"), from, to);
  52                         break;
  53                 case PROJECTILE_HOOKBOMB:
  54                         trailparticles(self, particleeffectnum("TR_KNIGHTSPIKE"), from, to);
  55                         break;
  56                 case PROJECTILE_HAGAR:
  57                         trailparticles(self, particleeffectnum("TR_GRENADE"), from, to);
  58                         break;
  59                 case PROJECTILE_HAGAR_BOUNCING:
  60                         trailparticles(self, particleeffectnum("TR_GRENADE"), from, to);
  61                         break;
  62                 default:
  63                         break;
  64         }
  65
  66 }
  67
  68 void Projectile_Draw()
  69 {
  70         vector rot;
  71         vector trailorigin;
  72
  73         if(self.count & 0x80)
  74         {
  75                 //self.move_flags &~= FL_ONGROUND;
  76                 Movetype_Physics(TRUE);
  77                 if(!(self.move_flags & FL_ONGROUND))
  78                         self.angles = vectoangles(self.velocity);
  79         }
  80         else
  81         {
  82                 InterpolateOrigin_Do();
  83         }
  84
  85         if(!(self.move_flags & FL_ONGROUND))
  86         {
  87                 rot = '0 0 0';
  88                 switch(self.cnt)
  89                 {
  90                         /*
  91                         case PROJECTILE_GRENADE:
  92                                 rot = '-2000 0 0'; // forward
  93                                 break;
  94                         */
  95                         case PROJECTILE_GRENADE_BOUNCING:
  96                                 rot = '0 -1000 0'; // sideways
  97                                 break;
  98                         case PROJECTILE_HOOKBOMB:
  99                                 rot = '1000 0 0'; // forward
 100                                 break;
 101                         default:
 102                                 break;
 103                 }
 104                 self.angles = AnglesTransform_Multiply(self.angles, rot * (time - self.spawntime));
 105
 106                 fixedmakevectors(self.angles);
 107
 108                 trailorigin = self.origin;
 109                 switch(self.cnt)
 110                 {
 111                         case PROJECTILE_GRENADE:
 112                         case PROJECTILE_GRENADE_BOUNCING:
 113                                 trailorigin += v_right * 1 + v_forward * -10;
 114                                 break;
 115                         default:
 116                                 break;
 117                 }
 118                 Projectile_DrawTrail(trailorigin);
 119         }
 120
 121         switch(self.cnt)
 122         {
 123                 case PROJECTILE_BULLET_GLOWING:
 124                         R_AddDynamicLight(self.origin, 50, '1 1 0');
 125                         break;
 126                 default:
 127                         break;
 128         }
 129
 130         self.renderflags = 0;
 131
 132         if((self.count & 0x80) || (self.iflags & IFLAG_VALID))
 133                 R_AddEntity(self);
 134 }
 135
 136 void loopsound(entity e, float ch, string samp, float vol, float attn)
 137 {
 138         if(csqc_flags & CSQC_FLAG_COLORCODES)
 139         {
 140                 sound(e, ch, samp, vol, attn);
 141                 e.snd_looping = 1;
 142         }
 143 }
 144
 145 void Ent_RemoveProjectile()
 146 {
 147         if(self.snd_looping)
 148                 sound(self, CHAN_PROJECTILE, "misc/null.wav", VOL_BASE, ATTN_NORM);
 149
 150         if(self.count & 0x80)
 151         {
 152                 tracebox(self.origin, self.mins, self.maxs, self.origin + self.velocity * 0.05, MOVE_NORMAL, self);
 153                 Projectile_DrawTrail(trace_endpos);
 154         }
 155 }
 156
 157 void Ent_Projectile()
 158 {
 159         float f;
 160
 161         // projectile properties:
 162         //   kind (interpolated, or clientside)
 163         //
 164         //   modelindex
 165         //   origin
 166         //   scale
 167         //   if clientside:
 168         //     velocity
 169         //     gravity
 170         //   soundindex (hardcoded list)
 171         //   effects
 172         //
 173         // projectiles don't send angles, because they always follow the velocity
 174
 175         f = ReadByte();
 176         self.count = (f & 0x80);
 177         self.iflags = (self.iflags & IFLAG_INTERNALMASK) | IFLAG_AUTOANGLES | IFLAG_ANGLES;
 178         self.move_flags &~= FL_ONGROUND;
 179         self.solid = SOLID_TRIGGER;
 180         //self.effects = EF_NOMODELFLAGS;
 181
 182         // sv_gameplayfix_delayprojectiles
 183         if(!self.move_time)
 184         {
 185                 self.move_time = time + ticrate;
 186                 self.spawntime = time + ticrate;
 187         }
 188         else
 189                 self.move_time = max(self.move_time, time);
 190
 191         if(!(self.count & 0x80))
 192                 InterpolateOrigin_Undo();
 193
 194         if(f & 1)
 195         {
 196                 self.origin_x = ReadCoord();
 197                 self.origin_y = ReadCoord();
 198                 self.origin_z = ReadCoord();
 199                 if(self.count & 0x80)
 200                 {
 201                         self.velocity_x = ReadCoord();
 202                         self.velocity_y = ReadCoord();
 203                         self.velocity_z = ReadCoord();
 204                         self.gravity = ReadCoord();
 205
 206                         self.move_origin = self.origin;
 207                         self.move_velocity = self.velocity;
 208                 }
 209
 210                 self.trail_oldorigin = self.origin;
 211         }
 212
 213         if(f & 2)
 214         {
 215                 self.cnt = ReadByte();
 216
 217                 self.scale = 1;
 218                 switch(self.cnt)
 219                 {
 220                         case PROJECTILE_ELECTRO: setmodel(self, "models/ebomb.mdl"); break;
 221                         case PROJECTILE_ROCKET: setmodel(self, "models/rocket.md3"); self.scale = 3; break;
 222                         case PROJECTILE_TAG: setmodel(self, "models/laser.mdl"); break;
 223                         case PROJECTILE_BULLET: setmodel(self, "models/tracer.mdl"); break;
 224                         case PROJECTILE_BULLET_GLOWING: setmodel(self, "models/tracer.mdl"); break;
 225                         case PROJECTILE_CRYLINK: setmodel(self, "models/plasmatrail.mdl"); break;
 226                         case PROJECTILE_ELECTRO_BEAM: setmodel(self, "models/elaser.mdl"); break;
 227                         case PROJECTILE_GRENADE: setmodel(self, "models/grenademodel.md3"); break;
 228                         case PROJECTILE_GRENADE_BOUNCING: setmodel(self, "models/grenademodel.md3"); break;
 229                         case PROJECTILE_LASER: setmodel(self, "models/laser.mdl"); break;
 230                         case PROJECTILE_HLAC: setmodel(self, "models/hlac_bullet.md3"); break;
 231                         case PROJECTILE_SEEKER: setmodel(self, "models/tagrocket.md3"); self.scale = 2; break;
 232                         case PROJECTILE_FLAC: setmodel(self, "models/hagarmissile.mdl"); self.scale = 0.4; break;
 233                         case PROJECTILE_PORTO_RED: setmodel(self, "models/grenademodel.md3"); self.scale = 4; break;
 234                         case PROJECTILE_PORTO_BLUE: setmodel(self, "models/grenademodel.md3"); self.scale = 4; break;
 235                         case PROJECTILE_HOOKBOMB: setmodel(self, "models/grenademodel.md3"); break;
 236                         case PROJECTILE_HAGAR: setmodel(self, "models/hagarmissile.mdl"); self.scale = 0.4; break;
 237                         case PROJECTILE_HAGAR_BOUNCING: setmodel(self, "models/hagarmissile.mdl"); self.scale = 0.4; break;
 238                         default:
 239                                 error("Received invalid CSQC projectile, can't work with this!");
 240                                 break;
 241                 }
 242
 243                 self.mins = '0 0 0';
 244                 self.maxs = '0 0 0';
 245                 self.colormod = '0 0 0';
 246                 self.move_touch = SUB_Stop;
 247                 self.move_movetype = MOVETYPE_TOSS;
 248
 249                 switch(self.cnt)
 250                 {
 251                         case PROJECTILE_ELECTRO:
 252                                 // only new engines support sound moving with object
 253                                 loopsound(self, CHAN_PROJECTILE, "weapons/electro_fly.wav", VOL_BASE, ATTN_NORM);
 254                                 self.mins = '0 0 -3';
 255                                 self.maxs = '0 0 -3';
 256                                 self.move_movetype = MOVETYPE_BOUNCE;
 257                                 self.move_touch = SUB_Null;
 258                                 break;
 259                         case PROJECTILE_ROCKET:
 260                                 loopsound(self, CHAN_PROJECTILE, "weapons/rocket_fly.wav", VOL_BASE, ATTN_NORM);
 261                                 self.mins = '-3 -3 -3';
 262                                 self.maxs = '3 3 3';
 263                                 break;
 264                         case PROJECTILE_TAG:
 265                                 loopsound(self, CHAN_PROJECTILE, "weapons/tag_rocket_fly.wav", VOL_BASE, ATTN_NORM);
 266                                 self.mins = '-2 -2 -2';
 267                                 self.maxs = '2 2 2';
 268                                 break;
 269                         case PROJECTILE_GRENADE_BOUNCING:
 270                                 self.mins = '0 0 -3';
 271                                 self.maxs = '0 0 -3';
 272                                 self.move_movetype = MOVETYPE_BOUNCE;
 273                                 self.move_touch = SUB_Null;
 274                                 break;
 275                         case PROJECTILE_SEEKER:
 276                                 self.mins = '-2 -2 -2';
 277                                 self.maxs = '2 2 2';
 278                                 break;
 279                         case PROJECTILE_PORTO_RED:
 280                                 self.colormod = '2 1 1';
 281                                 self.alpha = 0.5;
 282                                 self.move_movetype = MOVETYPE_BOUNCE;
 283                                 self.move_touch = SUB_Null;
 284                                 break;
 285                         case PROJECTILE_PORTO_BLUE:
 286                                 self.colormod = '1 1 2';
 287                                 self.alpha = 0.5;
 288                                 self.move_movetype = MOVETYPE_BOUNCE;
 289                                 self.move_touch = SUB_Null;
 290                                 break;
 291                         case PROJECTILE_HAGAR_BOUNCING:
 292                                 self.move_movetype = MOVETYPE_BOUNCE;
 293                                 self.move_touch = SUB_Null;
 294                                 break;
 295                         default:
 296                                 break;
 297                 }
 298         }
 299
 300         if(self.gravity)
 301         {
 302                 if(self.move_movetype == MOVETYPE_FLY)
 303                         self.move_movetype = MOVETYPE_TOSS;
 304                 if(self.move_movetype == MOVETYPE_BOUNCEMISSILE)
 305                         self.move_movetype = MOVETYPE_BOUNCE;
 306         }
 307         else
 308         {
 309                 if(self.move_movetype == MOVETYPE_TOSS)
 310                         self.move_movetype = MOVETYPE_FLY;
 311                 if(self.move_movetype == MOVETYPE_BOUNCE)
 312                         self.move_movetype = MOVETYPE_BOUNCEMISSILE;
 313         }
 314
 315         if(!(self.count & 0x80))
 316                 InterpolateOrigin_Note();
 317
 318         self.draw = Projectile_Draw;
 319         self.entremove = Ent_RemoveProjectile;
 320 }
 321
 322 void Projectile_Precache()
 323 {
 324         precache_model("models/ebomb.mdl");
 325         precache_model("models/elaser.mdl");
 326         precache_model("models/grenademodel.md3");
 327         precache_model("models/hagarmissile.mdl");
 328         precache_model("models/hlac_bullet.md3");
 329         precache_model("models/laser.mdl");
 330         precache_model("models/plasmatrail.mdl");
 331         precache_model("models/rocket.md3");
 332         precache_model("models/tagrocket.md3");
 333         precache_model("models/tracer.mdl");
 334         precache_sound("weapons/electro_fly.wav");
 335         precache_sound("weapons/rocket_fly.wav");
 336         precache_sound("weapons/tag_rocket_fly.wav");
 337 }