data/qcsrc/client/gibs.qc

   1 float  gibcount;
   2 entity giblist;
   3 .float silent;
   4
   5 void Gib_Delete()
   6 {
   7     --gibcount;
   8     remove(self);
   9 }
  10
  11 string species_prefix(float specnum)
  12 {
  13         switch(specnum)
  14         {
  15                 case SPECIES_HUMAN:       return "";
  16                 case SPECIES_ALIEN:       return "alien_";
  17                 case SPECIES_ROBOT_SHINY: return "robot_";
  18                 case SPECIES_ROBOT_RUSTY: return "robot_"; // use the same effects, only different gibs
  19                 case SPECIES_ANIMAL:      return "animal_";
  20                 case SPECIES_RESERVED:    return "reserved_";
  21                 default:         return "";
  22         }
  23 }
  24
  25 void new_te_bloodshower (float ef, vector org, float explosionspeed, float howmany)
  26 {
  27         float i, pmod;
  28         pmod = cvar("cl_particles_quality");
  29         for (i = 0; i < 250 * pmod; ++i)
  30                 pointparticles(ef, org, randomvec() * explosionspeed, howmany / 250);
  31 }
  32
  33 void SUB_RemoveOnNoImpact()
  34 {
  35         if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  36                 Gib_Delete();
  37 }
  38
  39 void Gib_Touch()
  40 {
  41         // TODO maybe bounce of walls, make more gibs, etc.
  42
  43         if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  44         {
  45                 Gib_Delete();
  46                 return;
  47         }
  48
  49         if(!self.silent)
  50                 sound(self, CHAN_PAIN, strcat("misc/gib_splat0", ftos(floor(prandom() * 4 + 1)), ".wav"), VOL_BASE, ATTN_NORM);
  51         pointparticles(particleeffectnum(strcat(species_prefix(self.cnt), "blood")), self.origin + '0 0 1', '0 0 30', 10);
  52
  53         Gib_Delete();
  54 }
  55
  56 void Gib_Draw()
  57 {
  58         vector oldorg;
  59         oldorg = self.origin;
  60
  61         Movetype_Physics_NoMatchServer();
  62         if(wasfreed(self))
  63                 return;
  64
  65         if(self.touch == Gib_Touch) // don't do this for the "chunk" thingie...
  66                 trailparticles(self, particleeffectnum(strcat(species_prefix(self.cnt), "TR_SLIGHTBLOOD")), oldorg, self.origin);
  67         else
  68                 trailparticles(self, particleeffectnum(strcat(species_prefix(self.cnt), "TR_BLOOD")), oldorg, self.origin);
  69
  70         self.renderflags = 0;
  71         self.alpha = bound(0, self.nextthink - time, 1);
  72
  73         if(self.alpha < ALPHA_MIN_VISIBLE)
  74                 Gib_Delete();
  75         else
  76                 R_AddEntity(self);
  77 }
  78
  79 void TossGib (string mdlname, vector org, vector vconst, vector vrand, float specnum, float destroyontouch, float issilent)
  80 {
  81         entity gib;
  82
  83         if not(giblist)
  84         giblist = spawn();
  85
  86         // TODO remove some gibs according to cl_nogibs
  87         gib = RubbleNew(giblist);
  88         ++gibcount;
  89         if(gibcount >= cvar_or("cl_gibs_maxcount",100))
  90         RubbleDrop(giblist,Gib_Delete);
  91
  92         //gib = spawn();
  93
  94         gib.classname = "gib";
  95         gib.move_movetype = MOVETYPE_BOUNCE;
  96         gib.gravity = 1;
  97         gib.solid = SOLID_CORPSE;
  98         gib.cnt = specnum;
  99         gib.silent = issilent;
 100
 101         setmodel (gib, mdlname); // precision set above
 102         gib.skin = specnum;
 103
 104         setsize (gib, '-8 -8 -8', '8 8 8');
 105
 106         gib.draw = Gib_Draw;
 107         if(destroyontouch)
 108                 gib.move_touch = Gib_Touch;
 109         else
 110                 gib.move_touch = SUB_RemoveOnNoImpact;
 111
 112         gib.move_origin = gib.origin = org;
 113         gib.move_velocity = vconst * cvar_or("cl_gibs_velocity_scale", 1) + vrand * cvar_or("cl_gibs_velocity_random", 1) + '0 0 1' * cvar("cl_gibs_velocity_up");
 114         gib.move_avelocity = prandomvec() * vlen(gib.move_velocity);
 115         gib.move_time = time;
 116         gib.damageforcescale = cvar_or("cl_gibs_damageforcescale", 3.5);
 117
 118         gib.nextthink = time + cvar_or("cl_gibs_lifetime", 14) * (1 + prandom() * 0.15);
 119 }
 120
 121 void Ent_GibSplash()
 122 {
 123         float amount, type, specnum;
 124         vector org, vel;
 125         string specstr;
 126         float issilent;
 127         string gentle_prefix;
 128
 129         float c, randomvalue;
 130
 131         type = ReadByte(); // gibbage type
 132         amount = ReadByte() / 16.0; // gibbage amount
 133         org_x = ReadShort() * 4 + 2;
 134         org_y = ReadShort() * 4 + 2;
 135         org_z = ReadShort() * 4 + 2;
 136         vel = decompressShortVector(ReadShort());
 137
 138         if(cvar("cl_gentle"))
 139                 type |= 0x80; // set gentle bit
 140
 141         if(type & 0x80)
 142         {
 143                 if(cvar("cl_gentle") > 1)
 144                         gentle_prefix = "";
 145                 else
 146                         gentle_prefix = "morphed_";
 147         }
 148
 149         if(cvar("cl_gentle"))
 150                 amount *= 1 - cvar("cl_nogibs");
 151
 152         if(cvar("ekg"))
 153                 amount *= 5;
 154
 155         if(amount <= 0)
 156                 return;
 157
 158         self.origin = org; // for the sounds
 159
 160         specnum = (type & 0x78) / 8; // blood/gibmodel type: using four bits (0..7, bit indexes 3,4,5)
 161         issilent = (type & 0x40);
 162         type = type & 0x87; // remove the species bits: bit 7 = gentle, bit 0,1,2 = kind of gib
 163         specstr = species_prefix(specnum);
 164
 165         switch(type)
 166         {
 167                 case 0x01:
 168                         if(!issilent)
 169                                 sound (self, CHAN_PAIN, "misc/gib.wav", VOL_BASE, ATTN_NORM);
 170
 171                         if(prandom() < amount)
 172                                 TossGib ("models/gibs/eye.md3", org, vel, prandomvec() * 150, specnum, 0, issilent);
 173                         new_te_bloodshower(particleeffectnum(strcat(specstr, "bloodshower")), org, 1200, amount);
 174                         if(prandom() < amount)
 175                                 TossGib ("models/gibs/bloodyskull.md3", org, vel, prandomvec() * 100, specnum, 0, issilent);
 176
 177                         for(c = 0; c < amount; ++c)
 178                         {
 179                                 randomvalue = amount - c;
 180
 181                                 if(prandom() < randomvalue)
 182                                         TossGib ("models/gibs/arm.md3", org, vel, prandomvec() * (prandom() * 120 + 90), specnum,0, issilent);
 183                                 if(prandom() < randomvalue)
 184                                         TossGib ("models/gibs/arm.md3", org, vel, prandomvec() * (prandom() * 120 + 90), specnum,0, issilent);
 185                                 if(prandom() < randomvalue)
 186                                         TossGib ("models/gibs/chest.md3", org + '0 0 -12', vel, prandomvec() * (prandom() * 120 + 80), specnum,0, issilent);
 187                                 if(prandom() < randomvalue)
 188                                         TossGib ("models/gibs/smallchest.md3", org, vel, prandomvec() * (prandom() * 120 + 80), specnum,0, issilent);
 189                                 if(prandom() < randomvalue)
 190                                         TossGib ("models/gibs/leg1.md3", org + '0 0 -5', vel, prandomvec() * (prandom() * 120 + 85), specnum,0, issilent);
 191                                 if(prandom() < randomvalue)
 192                                         TossGib ("models/gibs/leg2.md3", org + '0 0 -9', vel, prandomvec() * (prandom() * 120 + 85), specnum,0, issilent);
 193
 194                                 // these splat on impact
 195                                 if(prandom() < randomvalue)
 196                                         TossGib ("models/gibs/chunk.mdl", org, vel, prandomvec() * 450, specnum,1, issilent);
 197                                 if(prandom() < randomvalue)
 198                                         TossGib ("models/gibs/chunk.mdl", org, vel, prandomvec() * 450, specnum,1, issilent);
 199                                 if(prandom() < randomvalue)
 200                                         TossGib ("models/gibs/chunk.mdl", org, vel, prandomvec() * 450, specnum,1, issilent);
 201                                 if(prandom() < randomvalue)
 202                                         TossGib ("models/gibs/chunk.mdl", org, vel, prandomvec() * 450, specnum,1, issilent);
 203                         }
 204                         break;
 205                 case 0x02:
 206                         pointparticles(particleeffectnum(strcat(specstr, "blood")), org, vel, amount * 16);
 207                         break;
 208                 case 0x03:
 209                         if(prandom() < amount)
 210                                 TossGib ("models/gibs/chunk.mdl", org, vel, prandomvec() * (prandom() * 30 + 20), specnum, 1, issilent); // TODO maybe adjust to more randomization?
 211                         break;
 212                 case 0x81:
 213                         pointparticles(particleeffectnum(strcat(gentle_prefix, "damage_dissolve")), org, vel, amount);
 214                         break;
 215                 case 0x82:
 216                         pointparticles(particleeffectnum(strcat(gentle_prefix, "damage_hit")), org, vel, amount * 16);
 217                         break;
 218                 case 0x83:
 219                         // no gibs in gentle mode, sorry
 220                         break;
 221         }
 222 }
 223
 224 void GibSplash_Precache()
 225 {
 226         precache_model("models/gibs/chunk.mdl");
 227         precache_model("models/gibs/leg1.md3");
 228         precache_model("models/gibs/leg2.md3");
 229         precache_model("models/gibs/chest.md3");
 230         precache_model("models/gibs/smallchest.md3");
 231         precache_model("models/gibs/arm.md3");
 232         precache_model("models/gibs/bloodyskull.md3");
 233         precache_model("models/gibs/eye.md3");
 234
 235         precache_sound ("misc/gib.wav");
 236     precache_sound ("misc/gib_splat01.wav");
 237     precache_sound ("misc/gib_splat02.wav");
 238     precache_sound ("misc/gib_splat03.wav");
 239     precache_sound ("misc/gib_splat04.wav");
 240 }