data/qcsrc/client/gibs.qc

   1 void SUB_RemoveOnNoImpact()
   2 {
   3         if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
   4                 remove(self);
   5 }
   6
   7 void Gib_Touch()
   8 {
   9         // TODO maybe bounce of walls, make more gibs, etc.
  10
  11         if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  12         {
  13                 remove(self);
  14                 return;
  15         }
  16
  17         sound(self, CHAN_PAIN, strcat("misc/gib_splat0", ftos(floor(random() * 4 + 1)), ".wav"), VOL_BASE, ATTN_NORM);
  18         pointparticles(particleeffectnum("blood"), self.origin + '0 0 1', '0 0 30', 10);
  19
  20         remove(self);
  21 }
  22
  23 void Gib_Draw()
  24 {
  25         vector oldorg;
  26         oldorg = self.origin;
  27
  28         Movetype_Physics(FALSE);
  29
  30         if(self.touch == Gib_Touch) // don't do this for the "chunk" thingie...
  31                 trailparticles(self, particleeffectnum("TR_SLIGHTBLOOD"), oldorg, self.origin);
  32         else
  33                 trailparticles(self, particleeffectnum("TR_BLOOD"), oldorg, self.origin);
  34
  35         self.renderflags = 0;
  36         self.alpha = bound(0, self.nextthink - time, 1);
  37
  38         if(self.alpha == 0)
  39                 remove(self);
  40         else
  41                 R_AddEntity(self);
  42 }
  43
  44 void TossGib (string mdlname, vector org, vector v, float destroyontouch)
  45 {
  46         entity gib;
  47
  48         // TODO remove some gibs according to cl_nogibs
  49
  50         gib = spawn();
  51         gib.classname = "gib";
  52         gib.move_movetype = MOVETYPE_BOUNCE;
  53         gib.gravity = 1;
  54         gib.solid = SOLID_CORPSE;
  55
  56         setmodel (gib, mdlname); // precision set above
  57
  58         setsize (gib, '-8 -8 -8', '8 8 8');
  59
  60         gib.draw = Gib_Draw;
  61         if(destroyontouch)
  62                 gib.move_touch = Gib_Touch;
  63         else
  64                 gib.move_touch = SUB_RemoveOnNoImpact;
  65
  66         gib.move_origin = gib.origin = org;
  67         gib.move_velocity = v + randomvec();
  68         gib.move_avelocity = randomvec() * vlen(gib.move_velocity);
  69         gib.move_time = time;
  70         gib.damageforcescale = 3.5;
  71
  72         gib.nextthink = time + 12 + random () * 4;
  73 }
  74
  75 void Ent_GibSplash()
  76 {
  77         float amount, type, isgentle;
  78         vector org, vel, mi, ma;
  79
  80         float c, gibfactor, randomvalue;
  81
  82         type = ReadByte(); // gibbage type
  83         amount = ReadByte() / 16.0; // gibbage amount
  84         org_x = ReadShort() * 4 + 2;
  85         org_y = ReadShort() * 4 + 2;
  86         org_z = ReadShort() * 4 + 2;
  87         vel = decompressShortVector(ReadShort());
  88         mi = decompressShortVector(ReadShort());
  89         ma = decompressShortVector(ReadShort());
  90
  91         isgentle = (type & 0x80 || cvar("cl_gentle"));
  92         type = type & 0x7F;
  93
  94         gibfactor = 1 - cvar("cl_nogibs");
  95         if(gibfactor <= 0)
  96                 return;
  97
  98         amount *= gibfactor;
  99
 100         if(cvar("ekg"))
 101                 amount *= 5;
 102
 103         if(type == 1) // full gibbage
 104         {
 105                 sound (self, CHAN_PAIN, "misc/gib.wav", VOL_BASE, ATTN_NORM);
 106
 107                 if(random() < amount)
 108                         TossGib("models/gibs/eye.md3", org, vel + randomvec() * 150, 0);
 109                 te_bloodshower(org + mi, org + ma, 1200, 1000 * amount);
 110                 if(random() < amount)
 111                         TossGib("models/gibs/bloodyskull.md3", org, vel + randomvec() * 100, 0);
 112
 113                 for(c = 0; c < amount; ++c)
 114                 {
 115                         randomvalue = amount - c;
 116
 117                         if(random() < randomvalue)
 118                                 TossGib ("models/gibs/arm.md3", org, vel + randomvec() * (random() * 120 + 90),0);
 119                         if(random() < randomvalue)
 120                                 TossGib ("models/gibs/arm.md3", org, vel + randomvec() * (random() * 120 + 90),0);
 121                         if(random() < randomvalue)
 122                                 TossGib ("models/gibs/chest.md3", org + '0 0 -12', vel + randomvec() * (random() * 120 + 80),0);
 123                         if(random() < randomvalue)
 124                                 TossGib ("models/gibs/smallchest.md3", org, vel + randomvec() * (random() * 120 + 80),0);
 125                         if(random() < randomvalue)
 126                                 TossGib ("models/gibs/leg1.md3", org + '0 0 -5', vel + randomvec() * (random() * 120 + 85),0);
 127                         if(random() < randomvalue)
 128                                 TossGib ("models/gibs/leg2.md3", org + '0 0 -9', vel + randomvec() * (random() * 120 + 85),0);
 129
 130                         // these splat on impact
 131                         if(random() < randomvalue)
 132                                 TossGib ("models/gibs/chunk.mdl", org, vel + randomvec() * 450,1);
 133                         if(random() < randomvalue)
 134                                 TossGib ("models/gibs/chunk.mdl", org, vel + randomvec() * 450,1);
 135                         if(random() < randomvalue)
 136                                 TossGib ("models/gibs/chunk.mdl", org, vel + randomvec() * 450,1);
 137                         if(random() < randomvalue)
 138                                 TossGib ("models/gibs/chunk.mdl", org, vel + randomvec() * 450,1);
 139                 }
 140         }
 141         else if(type == 2) // just blood
 142         {
 143                 pointparticles(particleeffectnum("blood"), org, vel, amount);
 144         }
 145         else if(type == 3) // single gib
 146         {
 147                 if(random() < amount)
 148                         TossGib ("models/gibs/chunk.mdl", org, vel, 1);
 149         }
 150 }
 151
 152 void GibSplash_Precache()
 153 {
 154         precache_model("models/gibs/chunk.mdl");
 155         precache_model("models/gibs/leg1.md3");
 156         precache_model("models/gibs/leg2.md3");
 157         precache_model("models/gibs/chest.md3");
 158         precache_model("models/gibs/smallchest.md3");
 159         precache_model("models/gibs/arm.md3");
 160         precache_model("models/gibs/bloodyskull.md3");
 161         precache_model("models/gibs/eye.md3");
 162 }