data/qcsrc/client/damage.qc

   1 .float silent;
   2
   3 void Ent_DamageInfo()
   4 {
   5         float hittype, dmg, rad, edge, thisdmg, forcemul;
   6         float issilent;
   7         vector force, org, thisforce;
   8         entity oldself;
   9
  10         oldself = self;
  11
  12         hittype = ReadShort();
  13
  14         issilent = (hittype & 0x8000);
  15         hittype = (hittype & 0x7FFF);
  16
  17         org_x = ReadCoord();
  18         org_y = ReadCoord();
  19         org_z = ReadCoord();
  20
  21         dmg = ReadByte();
  22         rad = ReadByte();
  23         edge = ReadByte();
  24         force = decompressShortVector(ReadShort());
  25
  26         if(rad < 0)
  27         {
  28                 rad = -rad;
  29                 forcemul = -1;
  30         }
  31         else
  32                 forcemul = 1;
  33
  34         for(self = findradius(org, rad); self; self = self.chain)
  35         {
  36                 if(rad)
  37                 {
  38                         thisdmg = vlen(self.origin - org) / rad;
  39                         if(thisdmg >= 1)
  40                                 continue;
  41                         if(dmg)
  42                         {
  43                                 thisdmg = dmg + (edge - dmg) * thisdmg;
  44                                 thisforce = forcemul * vlen(force) * (thisdmg / dmg) * normalize(self.origin - org);
  45                         }
  46                         else
  47                         {
  48                                 thisdmg = 0;
  49                                 thisforce = forcemul * vlen(force) * normalize(self.origin - org);
  50                         }
  51                 }
  52                 else
  53                 {
  54                         thisdmg = dmg;
  55                         thisforce = forcemul * force;
  56                 }
  57
  58                 //print("check ", ftos(num_for_edict(self)), " ", self.classname, "\n");
  59                 //print(ftos(self.damageforcescale), "\n");
  60                 //print(vtos(thisforce), "\n");
  61                 if(self.damageforcescale)
  62                         if(vlen(thisforce))
  63                         {
  64                                 self.move_velocity = self.move_velocity + self.damageforcescale * thisforce;
  65                                 self.move_flags &~= FL_ONGROUND;
  66                                 //print("pushed ", ftos(num_for_edict(self)), " loose\n");
  67                         }
  68
  69                 if(issilent)
  70                         self.silent = 1;
  71
  72                 if(self.event_damage)
  73                         self.event_damage(thisdmg, hittype, org, thisforce);
  74         }
  75
  76         self = oldself;
  77
  78         setorigin(self, org); // for sound() calls
  79
  80         // TODO spawn particle effects and sounds based on hittype
  81
  82         if(!DEATH_ISSPECIAL(hittype))
  83         {
  84                 float hitwep, secondary, bounce, headshot;
  85                 vector org2, backoff;
  86                 float r;
  87
  88                 hitwep = DEATH_WEAPONOFWEAPONDEATH(hittype);
  89                 secondary = hittype & HITTYPE_SECONDARY;
  90                 bounce = hittype & HITTYPE_BOUNCE;
  91                 headshot = hittype & HITTYPE_HEADSHOT;
  92                 r = prandom();
  93
  94                 traceline(org - normalize(force) * 16, org + normalize(force) * 16, MOVE_NOMONSTERS, world);
  95                 if(trace_fraction < 1 && hitwep != WEP_NEX && hitwep != WEP_MINSTANEX)
  96                         backoff = trace_plane_normal;
  97                 else
  98                         backoff = -1 * normalize(force);
  99
 100                 switch(hitwep)
 101                 {
 102                         case WEP_LASER:
 103                                 org2 = org + backoff * 6;
 104                                 pointparticles(particleeffectnum("laser_impact"), org2, backoff * 1000, 1);
 105                                 if(!issilent)
 106                                         sound(self, CHAN_PROJECTILE, "weapons/laserimpact.wav", VOL_BASE, ATTN_NORM);
 107                                 break;
 108                         case WEP_SHOTGUN:
 109                                 org2 = org + backoff * 2;
 110                                 pointparticles(particleeffectnum("shotgun_impact"), org2, backoff * 1000, 1);
 111                                 if(!issilent)
 112                                 {
 113                                         if(r < 0.05)
 114                                                 sound(self, CHAN_PROJECTILE, "weapons/ric1.wav", VOL_BASE, ATTN_NORM);
 115                                         else if(r < 0.1)
 116                                                 sound(self, CHAN_PROJECTILE, "weapons/ric2.wav", VOL_BASE, ATTN_NORM);
 117                                         else if(r < 0.2)
 118                                                 sound(self, CHAN_PROJECTILE, "weapons/ric3.wav", VOL_BASE, ATTN_NORM);
 119                                 }
 120                                 break;
 121                         case WEP_UZI:
 122                                 org2 = org + backoff * 2;
 123                                 pointparticles(particleeffectnum("machinegun_impact"), org2, backoff * 1000, 1);
 124                                 if(!issilent)
 125                                         if(r < 0.05)
 126                                                 sound(self, CHAN_PROJECTILE, "weapons/ric1.wav", VOL_BASE, ATTN_NORM);
 127                                         else if(r < 0.1)
 128                                                 sound(self, CHAN_PROJECTILE, "weapons/ric2.wav", VOL_BASE, ATTN_NORM);
 129                                         else if(r < 0.2)
 130                                                 sound(self, CHAN_PROJECTILE, "weapons/ric3.wav", VOL_BASE, ATTN_NORM);
 131                                 break;
 132                         case WEP_GRENADE_LAUNCHER:
 133                                 org2 = org + backoff * 12;
 134                                 pointparticles(particleeffectnum("grenade_explode"), org2, '0 0 0', 1);
 135                                 if(!issilent)
 136                                         sound(self, CHAN_PROJECTILE, "weapons/grenade_impact.wav", VOL_BASE, ATTN_NORM);
 137                                 break;
 138                         case WEP_ELECTRO:
 139                                 org2 = org + backoff * 6;
 140                                 if(secondary)
 141                                 {
 142                                         pointparticles(particleeffectnum("electro_ballexplode"), org2, '0 0 0', 1);
 143                                         if(!issilent)
 144                                                 sound(self, CHAN_PROJECTILE, "weapons/electro_impact.wav", VOL_BASE, ATTN_NORM);
 145                                 }
 146                                 else
 147                                 {
 148                                         if(bounce)
 149                                         {
 150                                                 // this is sent as "primary bounce" to distinguish it from secondary bounced balls
 151                                                 pointparticles(particleeffectnum("electro_combo"), org2, '0 0 0', 1);
 152                                                 if(!issilent)
 153                                                         sound(self, CHAN_PROJECTILE, "weapons/electro_impact_combo.wav", VOL_BASE, ATTN_NORM);
 154                                         }
 155                                         else
 156                                         {
 157                                                 pointparticles(particleeffectnum("electro_impact"), org2, '0 0 0', 1);
 158                                                 if(!issilent)
 159                                                         sound(self, CHAN_PROJECTILE, "weapons/electro_impact.wav", VOL_BASE, ATTN_NORM);
 160                                         }
 161                                 }
 162                                 break;
 163                         case WEP_CRYLINK:
 164                                 org2 = org + backoff * 2;
 165                                 if(secondary)
 166                                 {
 167                                         pointparticles(particleeffectnum("crylink_impact"), org2, '0 0 0', 1);
 168                                         if(!issilent)
 169                                                 sound(self, CHAN_PROJECTILE, "weapons/crylink_impact2.wav", VOL_BASE, ATTN_NORM);
 170                                 }
 171                                 else
 172                                 {
 173                                         pointparticles(particleeffectnum("crylink_impactbig"), org2, '0 0 0', 1);
 174                                         if(!issilent)
 175                                                 sound(self, CHAN_PROJECTILE, "weapons/crylink_impact.wav", VOL_BASE, ATTN_NORM);
 176                                 }
 177                                 break;
 178                         case WEP_NEX:
 179                                 org2 = org + backoff * 6;
 180                                 pointparticles(particleeffectnum("nex_impact"), org2, '0 0 0', 1);
 181                                 if(!issilent)
 182                                         sound(self, CHAN_PROJECTILE, "weapons/neximpact.wav", VOL_BASE, ATTN_NORM);
 183                                 break;
 184                         case WEP_HAGAR:
 185                                 org2 = org + backoff * 6;
 186                                 pointparticles(particleeffectnum("hagar_explode"), org2, '0 0 0', 1);
 187                                 if(!issilent)
 188                                 {
 189                                         if (r<0.15)
 190                                                 sound(self, CHAN_PROJECTILE, "weapons/hagexp1.wav", VOL_BASE, ATTN_NORM);
 191                                         else if (r<0.7)
 192                                                 sound(self, CHAN_PROJECTILE, "weapons/hagexp2.wav", VOL_BASE, ATTN_NORM);
 193                                         else
 194                                                 sound(self, CHAN_PROJECTILE, "weapons/hagexp3.wav", VOL_BASE, ATTN_NORM);
 195                                 }
 196                                 break;
 197                         case WEP_ROCKET_LAUNCHER:
 198                                 org2 = org + backoff * 12;
 199                                 pointparticles(particleeffectnum("rocket_explode"), org2, '0 0 0', 1);
 200                                 if(!issilent)
 201                                         sound(self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 202                                 break;
 203                         case WEP_PORTO:
 204                                 print("Since when does Porto send DamageInfo?\n");
 205                                 break;
 206                         case WEP_MINSTANEX:
 207                                 org2 = org + backoff * 6;
 208                                 pointparticles(particleeffectnum("nex_impact"), org2, '0 0 0', 1);
 209                                 if(!issilent)
 210                                         sound(self, CHAN_PROJECTILE, "weapons/neximpact.wav", VOL_BASE, ATTN_NORM);
 211                                 break;
 212                         case WEP_HOOK:
 213                                 org2 = org + backoff * 2;
 214                                 pointparticles(particleeffectnum("hookbomb_explode"), org2, '0 0 0', 1);
 215                                 if(!issilent)
 216                                         sound(self, CHAN_PROJECTILE, "weapons/hookbomb_impact.wav", VOL_BASE, ATTN_NORM);
 217                                 break;
 218                         case WEP_SEEKER:
 219                                 org2 = org + backoff * 6;
 220                                 if(secondary)
 221                                 {
 222                                         pointparticles(particleeffectnum("flac_explode"), org2, '0 0 0', 1);
 223                                         if(!issilent)
 224                                         {
 225                                                 if (r<0.15)
 226                                                         sound(self, CHAN_PROJECTILE, "weapons/flacexp1.wav", 1, ATTN_NORM);
 227                                                 else if (r<0.7)
 228                                                         sound(self, CHAN_PROJECTILE, "weapons/flacexp2.wav", 1, ATTN_NORM);
 229                                                 else
 230                                                         sound(self, CHAN_PROJECTILE, "weapons/flacexp3.wav", 1, ATTN_NORM);
 231                                         }
 232                                 }
 233                                 else
 234                                 {
 235                                         if(bounce)
 236                                         {
 237                                                 pointparticles(particleeffectnum("hagar_explode"), org2, '0 0 0', 1);
 238                                                 if(!issilent)
 239                                                 {
 240                                                         if (r<0.15)
 241                                                                 sound(self, CHAN_PROJECTILE, "weapons/tagexp1.wav", 1, ATTN_NORM);
 242                                                         else if (r<0.7)
 243                                                                 sound(self, CHAN_PROJECTILE, "weapons/tagexp2.wav", 1, ATTN_NORM);
 244                                                         else
 245                                                                 sound(self, CHAN_PROJECTILE, "weapons/tagexp3.wav", 1, ATTN_NORM);
 246                                                 }
 247                                         }
 248                                         else if(headshot)
 249                                         {
 250                                                 if(!issilent)
 251                                                         sound(self, CHAN_PROJECTILE, "weapons/tag_impact.wav", 1, ATTN_NORM);
 252                                         }
 253                                         else
 254                                         {
 255                                                 pointparticles(particleeffectnum("hagar_explode"), org2, '0 0 0', 1);
 256                                                 if(!issilent)
 257                                                 {
 258                                                         if (r<0.15)
 259                                                                 sound(self, CHAN_PROJECTILE, "weapons/seekerexp1.wav", 1, ATTN_NORM);
 260                                                         else if (r<0.7)
 261                                                                 sound(self, CHAN_PROJECTILE, "weapons/seekerexp2.wav", 1, ATTN_NORM);
 262                                                         else
 263                                                                 sound(self, CHAN_PROJECTILE, "weapons/seekerexp3.wav", 1, ATTN_NORM);
 264                                                 }
 265                                         }
 266                                 }
 267                                 break;
 268                         case WEP_HLAC:
 269                                 org2 = org + backoff * 6;
 270                                 pointparticles(particleeffectnum("laser_impact"), org2, backoff * 1000, 1);
 271                                 if(!issilent)
 272                                         sound(self, CHAN_PROJECTILE, "weapons/laserimpact.wav", VOL_BASE, ATTN_NORM);
 273                                 break;
 274                         case WEP_CAMPINGRIFLE:
 275                                 org2 = org + backoff * 2;
 276                                 pointparticles(particleeffectnum("machinegun_impact"), org2, backoff * 1000, 1);
 277                                 if(!issilent)
 278                                 {
 279                                         if(r < 0.2)
 280                                                 sound(self, CHAN_PROJECTILE, "weapons/ric1.wav", VOL_BASE, ATTN_NORM);
 281                                         else if(r < 0.4)
 282                                                 sound(self, CHAN_PROJECTILE, "weapons/ric2.wav", VOL_BASE, ATTN_NORM);
 283                                         else if(r < 0.5)
 284                                                 sound(self, CHAN_PROJECTILE, "weapons/ric3.wav", VOL_BASE, ATTN_NORM);
 285                                 }
 286                                 break;
 287                         case WEP_TUBA:
 288                                 break;
 289                         default:
 290                                 dprint("Unhandled damage of weapon ", ftos(hitwep), "\n");
 291                                 break;
 292                 }
 293         }
 294 }
 295
 296 void DamageInfo_Precache()
 297 {
 298         precache_sound("weapons/crylink_impact2.wav");
 299         precache_sound("weapons/crylink_impact.wav");
 300         precache_sound("weapons/electro_impact.wav");
 301         precache_sound("weapons/electro_impact_combo.wav");
 302         precache_sound("weapons/flacexp1.wav");
 303         precache_sound("weapons/flacexp2.wav");
 304         precache_sound("weapons/flacexp3.wav");
 305         precache_sound("weapons/grenade_impact.wav");
 306         precache_sound("weapons/hagexp1.wav");
 307         precache_sound("weapons/hagexp2.wav");
 308         precache_sound("weapons/hagexp3.wav");
 309         precache_sound("weapons/hookbomb_impact.wav");
 310         precache_sound("weapons/laserimpact.wav");
 311         precache_sound("weapons/neximpact.wav");
 312         precache_sound("weapons/ric1.wav");
 313         precache_sound("weapons/ric2.wav");
 314         precache_sound("weapons/ric3.wav");
 315         precache_sound("weapons/rocket_impact.wav");
 316         precache_sound("weapons/seekerexp1.wav");
 317         precache_sound("weapons/seekerexp2.wav");
 318         precache_sound("weapons/seekerexp3.wav");
 319         precache_sound("weapons/tagexp1.wav");
 320         precache_sound("weapons/tagexp2.wav");
 321         precache_sound("weapons/tagexp3.wav");
 322         precache_sound("weapons/tag_impact.wav");
 323 }