data/qcsrc/client/View.qc

   1 #define spider_rocket_icon "gfx/spiderbot/rocket_ico.tga"
   2 #define spider_rocket_targ "gfx/spiderbot/target.tga"
   3 #define SPIDER_CROSS "textures/spiderbot/cross.tga"
   4 #define rkt_size 32
   5 #define rld_size_x 256
   6 #define rld_size_y 16
   7
   8 void CSQC_WAKIZASHI_HUD();
   9
  10 entity porto;
  11 vector polyline[16];
  12 float trace_dphitcontents;
  13 float trace_networkentity;
  14 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
  15 float DPCONTENTS_SOLID = 1; // blocks player movement
  16 float DPCONTENTS_BODY = 32; // blocks player movement
  17 float DPCONTENTS_CORPSE = 64; // blocks player movement
  18 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
  19 void Porto_Draw()
  20 {
  21         vector p, dir, ang, q, nextdir;
  22         float idx, portal_number, portal1_idx;
  23
  24         if(activeweapon != WEP_PORTO || spectatee_status || gametype == GAME_NEXBALL)
  25                 return;
  26         if(intermission == 1)
  27                 return;
  28         if(intermission == 2)
  29                 return;
  30         if (getstati(STAT_HEALTH) <= 0)
  31                 return;
  32
  33         dir = view_forward;
  34
  35         if(angles_held_status)
  36         {
  37                 makevectors(angles_held);
  38                 dir = v_forward;
  39         }
  40
  41         p = view_origin;
  42
  43         polyline[0] = p;
  44         idx = 1;
  45         portal_number = 0;
  46         nextdir = dir;
  47
  48         for(;;)
  49         {
  50                 dir = nextdir;
  51                 traceline(p, p + 65536 * dir, TRUE, porto);
  52                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  53                         return;
  54                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  55                 p = trace_endpos;
  56                 polyline[idx] = p;
  57                 ++idx;
  58                 if(idx >= 16)
  59                         return;
  60                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  61                         continue;
  62                 ++portal_number;
  63                 ang = vectoangles2(trace_plane_normal, dir);
  64                 ang_x = -ang_x;
  65                 makevectors(ang);
  66                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  67                         return;
  68                 if(portal_number == 1)
  69                         portal1_idx = idx;
  70                 if(portal_number >= 2)
  71                         break;
  72         }
  73
  74         while(idx >= 2)
  75         {
  76                 p = polyline[idx-2];
  77                 q = polyline[idx-1];
  78                 if(idx == 2)
  79                         p = p - view_up * 16;
  80                 if(idx-1 >= portal1_idx)
  81                 {
  82                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL);
  83                 }
  84                 else
  85                 {
  86                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL);
  87                 }
  88                 --idx;
  89         }
  90 }
  91
  92 /**
  93  * Checks whether the server initiated a map restart (stat_game_starttime changed)
  94  *
  95  * TODO: Use a better solution where a common shared entitiy is used that contains
  96  * timelimit, fraglimit and game_starttime! Requires engine changes (remove STAT_TIMELIMIT
  97  * and STAT_FRAGLIMIT to be auto-sent)
  98  */
  99 void CheckForGamestartChange() {
 100         float startTime;
 101         startTime = getstatf(STAT_GAMESTARTTIME);
 102         if (previous_game_starttime != startTime) {
 103                 if ((time + 5.0) < startTime) {
 104                         //if connecting to server while restart was active don't always play prepareforbattle
 105                         sound(self, CHAN_VOICE, strcat("announcer/", cvar_string("cl_announcer"), "/prepareforbattle.wav"), VOL_BASEVOICE, ATTN_NONE);
 106                 }
 107                 if (time < startTime) {
 108                         restartAnnouncer = spawn();
 109                         restartAnnouncer.think = restartAnnouncer_Think;
 110                         restartAnnouncer.nextthink = startTime - floor(startTime - time); //synchronize nextthink to startTime
 111                 }
 112         }
 113         previous_game_starttime = startTime;
 114 }
 115
 116 void Porto_Init()
 117 {
 118         porto = spawn();
 119         porto.classname = "porto";
 120         porto.draw = Porto_Draw;
 121         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 122 }
 123
 124 float drawtime;
 125 float avgspeed;
 126 vector GetCurrentFov(float fov)
 127 {
 128         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir, velocityzoom;
 129
 130         zoomsensitivity = cvar("cl_zoomsensitivity");
 131         zoomfactor = cvar("cl_zoomfactor");
 132         if(zoomfactor < 1 || zoomfactor > 16)
 133                 zoomfactor = 2.5;
 134         zoomspeed = cvar("cl_zoomspeed");
 135         if(zoomspeed >= 0)
 136                 if(zoomspeed < 0.5 || zoomspeed > 16)
 137                         zoomspeed = 3.5;
 138
 139         zoomdir = button_zoom;
 140         if(getstati(STAT_ACTIVEWEAPON) == WEP_NEX) // do NOT use switchweapon here
 141                 zoomdir += button_attack2;
 142         if(spectatee_status > 0 || isdemo())
 143         {
 144                 if(spectatorbutton_zoom)
 145                         zoomdir = 0 + !zoomdir;
 146                 // do not even THINK about removing this 0
 147                 // _I_ know what I am doing
 148                 // fteqcc does not
 149         }
 150
 151         if(zoomdir)
 152                 zoomin_effect = 0;
 153
 154         if(zoomin_effect || camera_active)
 155         {
 156                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 157         }
 158         else
 159         {
 160                 if(zoomspeed < 0) // instant zoom
 161                 {
 162                         if(zoomdir)
 163                                 current_viewzoom = 1 / zoomfactor;
 164                         else
 165                                 current_viewzoom = 1;
 166                 }
 167                 else
 168                 {
 169                         if(zoomdir)
 170                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 171                         else
 172                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 173                 }
 174         }
 175
 176         if(almost_equals(current_viewzoom, 1))
 177                 current_zoomfraction = 0;
 178         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 179                 current_zoomfraction = 1;
 180         else
 181                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 182
 183         if(zoomsensitivity < 1)
 184                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 185         else
 186                 setsensitivityscale(1);
 187
 188         velocityzoom = bound(0, drawframetime / max(0.000000001, cvar_or("cl_velocityzoomtime", 0.3)), 1);
 189         avgspeed = avgspeed * (1 - velocityzoom) + (vlen(pmove_vel) / 1000) * velocityzoom;
 190         velocityzoom = exp(float2range11(avgspeed * -cvar_or("cl_velocityzoom", 0) / 1) * 1);
 191
 192         //print(ftos(avgspeed), " avgspeed, ", ftos(cvar_or("cl_velocityzoom", 0)), " cvar, ", ftos(velocityzoom), " return\n"); // for debugging
 193
 194         float frustumx, frustumy, fovx, fovy;
 195         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 196         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 197         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 198         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 199
 200         return '1 0 0' * fovx + '0 1 0' * fovy;
 201 }
 202
 203 // this function must match W_SetupShot!
 204 float zoomscript_caught;
 205
 206 vector wcross_origin;
 207 float wcross_scale_prev, wcross_alpha_prev;
 208 vector wcross_color_prev;
 209 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 210 vector wcross_color_goal_prev;
 211 float wcross_changedonetime;
 212
 213 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 214 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 215 float wcross_name_changestarttime, wcross_name_changedonetime;
 216 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 217 entity trueaim;
 218 entity trueaim_rifle;
 219
 220 #define SHOTTYPE_HITTEAM 1
 221 #define SHOTTYPE_HITOBSTRUCTION 2
 222 #define SHOTTYPE_HITWORLD 3
 223 #define SHOTTYPE_HITENEMY 4
 224
 225 void TrueAim_Init()
 226 {
 227         trueaim = spawn();
 228         trueaim.classname = "trueaim";
 229         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 230         trueaim_rifle = spawn();
 231         trueaim_rifle.classname = "trueaim_rifle";
 232         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 233 }
 234
 235 float EnemyHitCheck()
 236 {
 237         float t;
 238         wcross_origin = project_3d_to_2d(trace_endpos);
 239         wcross_origin_z = 0;
 240         if(trace_networkentity < 1)
 241                 return SHOTTYPE_HITWORLD;
 242         if(trace_networkentity > maxclients)
 243                 return SHOTTYPE_HITWORLD;
 244         t = GetPlayerColor(trace_networkentity - 1);
 245         if(teamplay)
 246                 if(t == myteam)
 247                         return SHOTTYPE_HITTEAM;
 248         if(t == COLOR_SPECTATOR)
 249                 return SHOTTYPE_HITWORLD;
 250         return SHOTTYPE_HITENEMY;
 251 }
 252
 253 float TrueAimCheck()
 254 {
 255         float nudge = 1; // added to traceline target and subtracted from result
 256         vector vecs, trueaimpoint, w_shotorg;
 257         vector mi, ma, dv;
 258         float shottype;
 259         entity ta;
 260         float mv;
 261
 262         mi = ma = '0 0 0';
 263         ta = trueaim;
 264         mv = MOVE_NOMONSTERS;
 265
 266         switch(activeweapon)
 267         {
 268                 case WEP_TUBA: // no aim
 269                 case WEP_PORTO: // shoots from eye
 270                 case WEP_HOOK: // no trueaim
 271                 case WEP_GRENADE_LAUNCHER: // toss curve
 272                         return SHOTTYPE_HITWORLD;
 273                 case WEP_NEX:
 274                 case WEP_MINSTANEX:
 275                         mv = MOVE_NORMAL;
 276                         break;
 277                 case WEP_CAMPINGRIFLE:
 278                         ta = trueaim_rifle;
 279                         mv = MOVE_NORMAL;
 280                         if(zoomscript_caught)
 281                         {
 282                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 283                                 return EnemyHitCheck();
 284                         }
 285                         break;
 286                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 287                         mi = '-3 -3 -3';
 288                         ma = '3 3 3';
 289                         break;
 290                 case WEP_FIREBALL: // projectile has a size!
 291                         mi = '-16 -16 -16';
 292                         ma = '16 16 16';
 293                         break;
 294                 case WEP_ELECTRO: // projectile has a size!
 295                         mi = '0 0 -3';
 296                         ma = '0 0 -3';
 297                         break;
 298         }
 299
 300         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 301
 302         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 303         trueaimpoint = trace_endpos;
 304
 305         if(vecs_x > 0)
 306                 vecs_y = -vecs_y;
 307         else
 308                 vecs = '0 0 0';
 309
 310         dv = view_right * vecs_y + view_up * vecs_z;
 311         w_shotorg = view_origin + dv;
 312
 313         // now move the vecs forward as much as requested if possible
 314         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 315         w_shotorg = trace_endpos - view_forward * nudge;
 316
 317         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 318         shottype = EnemyHitCheck();
 319         if(shottype != SHOTTYPE_HITWORLD)
 320                 return shottype;
 321
 322 #if 0
 323         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 324         // or rather, I know why, but see no fix
 325         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 326                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 327                 return SHOTTYPE_HITOBSTRUCTION;
 328 #endif
 329
 330         return SHOTTYPE_HITWORLD;
 331 }
 332
 333 void CSQC_common_hud(void);
 334
 335 void CSQC_kh_hud(void);
 336 void CSQC_ctf_hud(void);
 337 void PostInit(void);
 338 void CSQC_Demo_Camera();
 339 float Sbar_WouldDrawScoreboard ();
 340 float view_set;
 341 float camera_mode;
 342 string NextFrameCommand;
 343 void CSQC_spider_HUD();
 344 void CSQC_UpdateView(float w, float h)
 345 {
 346         entity e;
 347         float fov;
 348         float f, i, j;
 349         vector v;
 350
 351         WaypointSprite_Load();
 352
 353         if(spectatee_status)
 354                 myteam = GetPlayerColor(spectatee_status - 1);
 355         else
 356                 myteam = GetPlayerColor(player_localentnum - 1);
 357
 358         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 359
 360         // Render the Scene
 361         if(!intermission || !view_set)
 362         {
 363                 view_origin = pmove_org + '0 0 1' * getstati(STAT_VIEWHEIGHT);
 364                 makevectors(view_angles);
 365                 view_forward = v_forward;
 366                 view_right = v_right;
 367                 view_up = v_up;
 368                 view_set = 1;
 369         }
 370
 371         float hudconf_active;
 372         hudconf_active = cvar("hud_configure");
 373         if(hudconf_active)
 374                 R_SetView(VF_ANGLES, self.angles); // TODO: this should freeze the view as it is, not change it to '0 0 0' or whatever it currently does...
 375
 376         vid_width = w;
 377         vid_height = h;
 378
 379 #ifdef BLURTEST
 380         if(time > blurtest_time0 && time < blurtest_time1)
 381         {
 382                 float r, t;
 383
 384                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 385                 r = t * blurtest_radius;
 386                 f = 1 / pow(t, blurtest_power) - 1;
 387
 388                 cvar_set("r_glsl_postprocess", "1");
 389                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 390         }
 391         else
 392         {
 393                 cvar_set("r_glsl_postprocess", "0");
 394                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 395         }
 396 #endif
 397
 398         Fog_Force();
 399
 400         drawframetime = max(0.000001, time - drawtime);
 401         drawtime = time;
 402
 403         // watch for gametype changes here...
 404         // in ParseStuffCMD the cmd isn't executed yet :/
 405         // might even be better to add the gametype to TE_CSQC_INIT...?
 406         if(!postinit)
 407                 PostInit();
 408
 409         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 410                 if(calledhooks & HOOK_START)
 411                 {
 412                         localcmd("\ncl_hook_gameend;");
 413                         calledhooks |= HOOK_END;
 414                 }
 415
 416         CheckForGamestartChange();
 417         serverAnnouncer();
 418         maptimeAnnouncer();
 419         carrierAnnouncer();
 420
 421         fov = cvar("fov");
 422         if(button_zoom || fov <= 59.5)
 423         {
 424                 if(!zoomscript_caught)
 425                 {
 426                         localcmd("+button4\n");
 427                         zoomscript_caught = 1;
 428                         ignore_plus_zoom += 1;
 429                 }
 430         }
 431         else
 432         {
 433                 if(zoomscript_caught)
 434                 {
 435                         localcmd("-button4\n");
 436                         zoomscript_caught = 0;
 437                         ignore_minus_zoom += 1;
 438                 }
 439         }
 440
 441         hud_alpha_fg = cvar_or("hud_alpha_fg", 1) * (1 - cvar("_menu_alpha"));
 442         sbar_currentammo = cvar("hud_showcurrentammo");
 443         hud_hudselector = cvar("hud_hudselector");
 444         hud_accuracy_hud = cvar_or("hud_accuracy_hud", 1);
 445         ColorTranslateMode = cvar("cl_stripcolorcodes");
 446         activeweapon = getstati(STAT_SWITCHWEAPON);
 447         f = cvar("teamplay");
 448         if(f != teamplay)
 449         {
 450                 teamplay = f;
 451                 Sbar_InitScores();
 452         }
 453
 454         if(last_weapon != activeweapon) {
 455                 weapontime = time;
 456                 last_weapon = activeweapon;
 457         }
 458
 459         // ALWAYS Clear Current Scene First
 460         R_ClearScene();
 461
 462         // Assign Standard Viewflags
 463         // Draw the World (and sky)
 464         R_SetView(VF_DRAWWORLD, 1);
 465
 466         // Set the console size vars
 467         vid_conwidth = cvar("vid_conwidth");
 468         vid_conheight = cvar("vid_conheight");
 469         vid_pixelheight = cvar("vid_pixelheight");
 470
 471         R_SetView(VF_FOV, GetCurrentFov(fov));
 472
 473         // Camera for demo playback
 474         if(camera_active)
 475         {
 476                 if(cvar("camera_enable"))
 477                         CSQC_Demo_Camera();
 478                 else
 479                 {
 480                         cvar_set("chase_active", ftos(chase_active_backup));
 481                         cvar_set("cl_demo_mousegrab", "0");
 482                         camera_active = FALSE;
 483                 }
 484         }
 485 #ifdef CAMERATEST
 486         else if(cvar("camera_enable"))
 487 #else
 488         else if(cvar("camera_enable") && isdemo())
 489 #endif
 490         {
 491                 // Enable required Darkplaces cvars
 492                 chase_active_backup = cvar("chase_active");
 493                 cvar_set("chase_active", "2");
 494                 cvar_set("cl_demo_mousegrab", "1");
 495                 camera_active = TRUE;
 496                 camera_mode = FALSE;
 497         }
 498
 499         // Draw the Crosshair
 500         float scoreboard_active;
 501         scoreboard_active = Sbar_WouldDrawScoreboard();
 502         R_SetView(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 503
 504         // Draw the Engine Status Bar (the default Quake HUD)
 505         R_SetView(VF_DRAWENGINESBAR, 0);
 506
 507         // fetch this one only once per frame
 508         sbar_showbinds = cvar("sbar_showbinds");
 509         sbar_showbinds_limit = cvar("sbar_showbinds_limit");
 510
 511         // Update the mouse position
 512         /*
 513            mousepos_x = vid_conwidth;
 514            mousepos_y = vid_conheight;
 515            mousepos = mousepos*0.5 + getmousepos();
 516          */
 517
 518         e = self;
 519         for(self = world; (self = nextent(self)); )
 520                 if(self.draw)
 521                         self.draw();
 522         self = e;
 523
 524         R_AddEntities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 525         R_RenderScene();
 526
 527         // now switch to 2D drawing mode by calling a 2D drawing function
 528         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 529         // next R_RenderScene call
 530         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 531
 532         // Draw the mouse cursor
 533         // NOTE: drawpic must happen after R_RenderScene for some reason
 534         //drawpic(getmousepos(), "gfx/cursor.tga", '11 14 0', '1 1 1', 1, 0);
 535         //drawstring('50 50', ftos(game), '10 10 0', '1 1 1', 1, 0);
 536         //self = edict_num(player_localnum);
 537         //drawstring('0 0', vtos(pmove_org), '8 8 0', '1 1 1', 1, 0);
 538         //drawstring('0 8', strcat("ORG: ", vtos(self.origin), " state: ", ftos(self.ctf_state), " HP: ", ftos(self.health)), '8 8 0', '1 1 1', 1, 0);
 539         // as long as the ctf part isn't in, this is useless
 540         if(menu_visible)
 541                 menu_show();
 542
 543         /*if(gametype == GAME_CTF)
 544           {
 545           ctf_view();
 546           } else */
 547
 548         // draw 2D entities
 549         e = self;
 550         for(self = world; (self = nextent(self)); )
 551                 if(self.draw2d)
 552                         self.draw2d();
 553         self = e;
 554
 555         // draw radar
 556         if(
 557                         ons_showmap
 558                         ||
 559                         (
 560                          !scoreboard_active
 561                          &&
 562                          cvar_string("cl_teamradar") != "0"
 563                          &&
 564                          (
 565                           cvar("cl_teamradar") == 2
 566                           ||
 567                           teamplay
 568                          )
 569                         )
 570           )
 571                 teamradar_view();
 572
 573         // draw sbar
 574         if(cvar("r_letterbox") == 0) {
 575                 if (cvar("cl_showpressedkeys")) { // draw pressed keys when spectating and playing
 576                         if(spectatee_status > 0 || cvar("cl_showpressedkeys") >= 2)
 577                                 HUD_DrawPressedKeys();
 578                 }
 579
 580                 if (cvar("cl_showspeed"))
 581                         HUD_ShowSpeed();
 582                 if (cvar("cl_showacceleration"))
 583                         HUD_ShowAcceleration();
 584
 585                 HUD_DrawCenterPrint(); // draw centerprint messages even if viewsize >= 120
 586         }
 587
 588         float hud;
 589         hud = getstati(STAT_HUD);
 590         if(hud == HUD_SPIDERBOT)
 591         {
 592                 CSQC_spider_HUD();
 593         }
 594         else if(hud == HUD_WAKIZASHI)
 595         CSQC_WAKIZASHI_HUD();
 596         else
 597         {
 598                 if(cvar("r_letterbox") == 0)
 599                         if(cvar("viewsize") < 120)
 600                                 CSQC_common_hud();
 601
 602                 // crosshair goes VERY LAST
 603                 if(!scoreboard_active && !ons_showmap && !camera_active && !hudconf_active) {
 604                         // TrueAim check
 605                         float shottype;
 606                         float bullets, ring_scale;
 607                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 608                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 609                         wcross_origin_z = 0;
 610                         if(cvar("crosshair_hittest"))
 611                         {
 612                                 vector wcross_oldorigin;
 613                                 wcross_oldorigin = wcross_origin;
 614                                 shottype = TrueAimCheck();
 615                                 if(shottype == SHOTTYPE_HITWORLD)
 616                                 {
 617                                         v = wcross_origin - wcross_oldorigin;
 618                                         v_x /= vid_conwidth;
 619                                         v_y /= vid_conheight;
 620                                         if(vlen(v) > 0.01)
 621                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
 622                                 }
 623                                 if(!cvar("crosshair_hittest_showimpact"))
 624                                         wcross_origin = wcross_oldorigin;
 625                         }
 626                         else
 627                                 shottype = SHOTTYPE_HITWORLD;
 628
 629                         string wcross_style;
 630                         wcross_style = cvar_string("crosshair");
 631
 632                         if (wcross_style != "0") {
 633                                 vector wcross_color, wcross_size;
 634                                 string wcross_wep, wcross_name;
 635                                 float wcross_alpha, wcross_scale, wcross_blur, wcross_resolution;
 636
 637                                 wcross_color_x = cvar("crosshair_color_red");
 638                                 wcross_color_y = cvar("crosshair_color_green");
 639                                 wcross_color_z = cvar("crosshair_color_blue");
 640                                 wcross_alpha = cvar("crosshair_color_alpha");
 641                                 wcross_resolution = cvar("crosshair_size");
 642                                 if (cvar("crosshair_per_weapon")) {
 643                                         e = get_weaponinfo(activeweapon);
 644                                         if (e && e.netname != "")
 645                                         {
 646                                                 wcross_wep = e.netname;
 647                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
 648                                                 if(wcross_style == "")
 649                                                         wcross_style = e.netname;
 650
 651                                                 if(!cvar("crosshair_color_override"))
 652                                                 {
 653                                                         wcross_color_x = cvar(strcat("crosshair_", wcross_wep, "_color_red"));
 654                                                         wcross_color_y = cvar(strcat("crosshair_", wcross_wep, "_color_green"));
 655                                                         wcross_color_z = cvar(strcat("crosshair_", wcross_wep, "_color_blue"));
 656                                                 }
 657
 658                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_color_alpha"));
 659                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
 660                                         }
 661                                 }
 662
 663                                 wcross_name = strcat("gfx/crosshair", wcross_style);
 664
 665                                 if(cvar("crosshair_effect_scalefade"))
 666                                 {
 667                                         wcross_scale = wcross_resolution;
 668                                         wcross_resolution = 1;
 669                                 }
 670                                 else
 671                                 {
 672                                         wcross_scale = 1;
 673                                 }
 674
 675                                 if(shottype == SHOTTYPE_HITENEMY)
 676                                         wcross_scale *= cvar("crosshair_hittest"); // is not queried if hittest is 0
 677                                 if(shottype == SHOTTYPE_HITTEAM)
 678                                         wcross_scale /= cvar("crosshair_hittest"); // is not queried if hittest is 0
 679
 680                                 f = cvar("crosshair_effect_speed");
 681                                 if(f < 0)
 682                                         f *= -2 * g_weaponswitchdelay;
 683                                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
 684                                 {
 685                                         wcross_changedonetime = time + f;
 686                                 }
 687                                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
 688                                 {
 689                                         wcross_name_changestarttime = time;
 690                                         wcross_name_changedonetime = time + f;
 691                                         if(wcross_name_goal_prev_prev)
 692                                                 strunzone(wcross_name_goal_prev_prev);
 693                                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
 694                                         wcross_name_goal_prev = strzone(wcross_name);
 695                                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
 696                                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
 697                                         wcross_resolution_goal_prev = wcross_resolution;
 698                                 }
 699
 700                                 wcross_scale_goal_prev = wcross_scale;
 701                                 wcross_alpha_goal_prev = wcross_alpha;
 702                                 wcross_color_goal_prev = wcross_color;
 703
 704                                 if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && cvar("crosshair_hittest_blur") && !cvar("chase_active")))
 705                                 {
 706                                         wcross_blur = 1;
 707                                         wcross_alpha *= 0.75;
 708                                 }
 709                                 else
 710                                         wcross_blur = 0;
 711                                 // *_prev is at time-frametime
 712                                 // * is at wcross_changedonetime+f
 713                                 // what do we have at time?
 714                                 if(time < wcross_changedonetime)
 715                                 {
 716                                         f = frametime / (wcross_changedonetime - time + frametime);
 717                                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
 718                                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
 719                                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
 720                                 }
 721
 722                                 wcross_scale_prev = wcross_scale;
 723                                 wcross_alpha_prev = wcross_alpha;
 724                                 wcross_color_prev = wcross_color;
 725
 726                                 wcross_scale *= 1 - cvar("_menu_alpha");
 727                                 wcross_alpha *= 1 - cvar("_menu_alpha");
 728
 729                                 // ring around crosshair representing bullets left in camping rifle clip
 730                                 if (activeweapon == WEP_CAMPINGRIFLE)
 731                                 {
 732                                         ring_scale = cvar("crosshair_campingrifle_ring_size");
 733                                         bullets = bound(0, getstati(STAT_BULLETS_LOADED), 8);
 734                                 }
 735                                 else
 736                                         bullets = 0;
 737
 738 #define CROSSHAIR_DRAW_RING(i,j,sz,wcross_name,wcross_alpha) \
 739                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x * ring_scale + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y * ring_scale + j * wcross_blur)), strcat("gfx/hud/rifle_ring_", ftos(bullets)), sz * wcross_size * ring_scale, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
 740
 741 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
 742                                 do \
 743                                 { \
 744                                         if(wcross_blur > 0) \
 745                                         { \
 746                                                 for(i = -2; i <= 2; ++i) \
 747                                                         for(j = -2; j <= 2; ++j) \
 748                                                                 M(i,j,sz,wcross_name,wcross_alpha*0.04); \
 749                                         } \
 750                                         else \
 751                                         { \
 752                                                 M(0,0,sz,wcross_name,wcross_alpha); \
 753                                         } \
 754                                 } \
 755                                 while(0)
 756
 757 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
 758                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
 759
 760 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
 761                                 CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
 762
 763                                 if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
 764                                 {
 765                                         f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
 766                                         wcross_size = drawgetimagesize(wcross_name_goal_prev_prev) * wcross_scale;
 767                                         CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
 768                                         f = 1 - f;
 769                                 }
 770                                 else
 771                                 {
 772                                         f = 1;
 773                                 }
 774
 775                                 wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
 776                                 if(bullets)
 777                                 {
 778                                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_RING, wcross_resolution, wcross_name, wcross_alpha);
 779                                 }
 780                                 CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
 781                                 wcross_name_alpha_goal_prev = f;
 782                         }
 783                 }
 784                 else
 785                 {
 786                         wcross_scale_prev = 0;
 787                         wcross_alpha_prev = 0;
 788                         wcross_scale_goal_prev = 0;
 789                         wcross_alpha_goal_prev = 0;
 790                         wcross_changedonetime = 0;
 791                         if(wcross_name_goal_prev)
 792                                 strunzone(wcross_name_goal_prev);
 793                         wcross_name_goal_prev = string_null;
 794                         if(wcross_name_goal_prev_prev)
 795                                 strunzone(wcross_name_goal_prev_prev);
 796                         wcross_name_goal_prev_prev = string_null;
 797                         wcross_name_changestarttime = 0;
 798                         wcross_name_changedonetime = 0;
 799                         wcross_name_alpha_goal_prev = 0;
 800                         wcross_name_alpha_goal_prev_prev = 0;
 801                         wcross_resolution_goal_prev = 0;
 802                         wcross_resolution_goal_prev_prev = 0;
 803                 }
 804         }
 805
 806         if(NextFrameCommand)
 807         {
 808                 localcmd("\n", NextFrameCommand, "\n");
 809                 NextFrameCommand = string_null;
 810         }
 811
 812         // we must do this check AFTER a frame was rendered, or it won't work
 813         if(cs_project_is_b0rked == 0)
 814         {
 815                 string w0, h0;
 816                 w0 = cvar_string("vid_conwidth");
 817                 h0 = cvar_string("vid_conheight");
 818                 //R_SetView(VF_VIEWPORT, '0 0 0', '640 480 0');
 819                 //R_SetView(VF_FOV, '90 90 0');
 820                 R_SetView(VF_ORIGIN, '0 0 0');
 821                 R_SetView(VF_ANGLES, '0 0 0');
 822                 R_SetView(VF_PERSPECTIVE, 1);
 823                 makevectors('0 0 0');
 824                 vector v1, v2;
 825                 cvar_set("vid_conwidth", "800");
 826                 cvar_set("vid_conheight", "600");
 827                 v1 = cs_project(v_forward);
 828                 cvar_set("vid_conwidth", "640");
 829                 cvar_set("vid_conheight", "480");
 830                 v2 = cs_project(v_forward);
 831                 if(v1 == v2)
 832                         cs_project_is_b0rked = 1;
 833                 else
 834                         cs_project_is_b0rked = -1;
 835                 cvar_set("vid_conwidth", w0);
 836                 cvar_set("vid_conheight", h0);
 837         }
 838
 839         if(hudconf_active)
 840                 HUD_Panel_Mouse();
 841         // be safe against triggerbots until everyone has the fixed engine
 842         // this call is meant to overwrite the trace globals by something
 843         // unsuspicious
 844         traceline('0 0 0', '0 0 0', MOVE_WORLDONLY, world);
 845 }
 846
 847 void CSQC_spider_HUD()
 848 {
 849         float rockets,reload,heat,hp,shield,i;
 850         vector p,pp;
 851
 852     p = drawgetimagesize(SPIDER_CROSS);
 853     p_x *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
 854     p_y *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
 855     drawpic('0.5 0 0' * (vid_conwidth - p_x) + '0 0.5 0' * (vid_conheight - p_y), SPIDER_CROSS, p, '1 1 1', cvar_or("cl_vehicle_spiderbot_cross_alpha",0.6), DRAWFLAG_NORMAL);
 856
 857     hp      = bound(0,getstatf(STAT_VEHICLESTAT_HEALTH), 1);
 858         shield  = bound(0,getstatf(STAT_VEHICLESTAT_SHIELD), 1);
 859         heat    = min(getstatf(STAT_VEHICLESTAT_RELOAD1), 1);
 860         rockets =     getstati(STAT_VEHICLESTAT_AMMO2);
 861         reload  = min(getstatf(STAT_VEHICLESTAT_RELOAD2), 1);
 862
 863         // Draw health bar
 864         p = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
 865         p = p + '0 1 0' * vid_conheight - '0 32 0';
 866         //pp = ('0 1 0' * hp) + ('1 0 0' * (1-hp));
 867         drawfill(p, '256 0 0' * shield + '0 8 0' , '0.5 0.5 1', 0.75, DRAWFLAG_NORMAL);
 868         p_y += 8;
 869         drawfill(p, '256 0 0' * hp + '0 8 0' , '0 1 0', 0.75, DRAWFLAG_NORMAL);
 870         p_x += 256 * hp;
 871         drawfill(p, '256 0 0' * (1-hp) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
 872
 873         // Draw minigun heat indicator
 874         p = '0.5 0 0' * (vid_conwidth - 256);
 875         p = p + '0 1 0' * vid_conheight - '0 34  0';
 876         drawfill(p, '256 0 0' * (1-heat) + '0 2 0' ,'0 0 1', 0.5, DRAWFLAG_NORMAL);
 877         p_x += 256 * (1-heat);
 878         drawfill(p, '256 0 0' * heat  + '0 2 0' , '1 0 0', 0.5, DRAWFLAG_NORMAL);
 879
 880         // Draw rocket icons for loaded/empty tubes.
 881         pp = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
 882         pp += '0 1 0' * vid_conheight - '0 64 0';
 883         for(i = 0; i < 8; ++i)
 884         {
 885                 p = pp + '1 0 0' * (rkt_size * i);
 886                 if(rockets == 8)
 887                 {
 888                         if(floor(reload * 8) == i)
 889                         {
 890                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 0 0' + '0 1 0' * ((reload*8)-i), 0.75 , DRAWFLAG_NORMAL);
 891                         }
 892                         else if(i < reload * 8)
 893                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 1 0', 0.75 , DRAWFLAG_NORMAL);
 894                         else
 895                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0.5 0.5 0.5', 0.75, DRAWFLAG_NORMAL);
 896                 }
 897                 else
 898                 {
 899                         if(i < rockets)
 900                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 0 0', 0.25, DRAWFLAG_NORMAL);
 901                         else
 902                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 1 0' * reload, 0.75, DRAWFLAG_NORMAL);
 903                 }
 904         }
 905
 906         if (sb_showscores)
 907         {
 908                 Sbar_DrawScoreboard();
 909                 HUD_DrawCenterPrint();
 910         }
 911
 912 }
 913
 914 void CSQC_WAKIZASHI_HUD()
 915 {
 916         // 0--1 floats. 1 = 100%, 0.6 = 50%.
 917         float health, shield, energy, rockets;
 918
 919         vector p;
 920
 921     p = drawgetimagesize(SPIDER_CROSS);
 922     p_x *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
 923     p_y *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
 924     drawpic('0.5 0 0' * (vid_conwidth - p_x) + '0 0.5 0' * (vid_conheight - p_y), SPIDER_CROSS, p, '1 1 1', cvar_or("cl_vehicle_spiderbot_cross_alpha",0.6), DRAWFLAG_NORMAL);
 925
 926 /*
 927 const float STAT_VEHICLESTAT_HEALTH  = 60;
 928 const float STAT_VEHICLESTAT_SHIELD  = 61;
 929 const float STAT_VEHICLESTAT_ENERGY  = 62;
 930 const float STAT_VEHICLESTAT_AMMO1   = 63;
 931 const float STAT_VEHICLESTAT_RELAOD1 = 64;
 932 const float STAT_VEHICLESTAT_AMMO2   = 65;
 933 const float STAT_VEHICLESTAT_RELOAD2 = 66;
 934 */
 935     health  = min(getstatf(STAT_VEHICLESTAT_HEALTH),  1);
 936         shield  = min(getstatf(STAT_VEHICLESTAT_SHIELD),  1);
 937         energy  = min(getstatf(STAT_VEHICLESTAT_ENERGY),  1);
 938         rockets = bound(0,getstatf(STAT_VEHICLESTAT_RELOAD1), 1);
 939
 940
 941         p = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
 942         p = p + '0 1 0' * vid_conheight - '0 32 0';
 943
 944         // Draw health bar
 945         p_y += 8;
 946         drawfill(p, '256 0 0' * health + '0 8 0' , '0 0.7 0', 0.75, DRAWFLAG_NORMAL);
 947         p_x += 256 * health;
 948         drawfill(p, '256 0 0' * (1 - health) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
 949
 950         // Draw shiled bar
 951         p_x -= 256 * health;
 952         p_y += 4;
 953         drawfill(p, '256 0 0' * shield + '0 4 0' , '0.25 0.25 1', 0.5, DRAWFLAG_NORMAL);
 954
 955         // Draw energy
 956         //p_x -= 256 * health;
 957         p_y -= 8;
 958         drawfill(p, '256 0 0' * energy + '0 4 0' , '1 1 1', 0.75, DRAWFLAG_NORMAL);
 959
 960         // Draw rockets bar
 961         p_y += 12;
 962         drawfill(p, '256 0 0' * rockets + '0 4 0' , '1 0 0', 0.75, DRAWFLAG_NORMAL);
 963
 964
 965         /*
 966         // Draw energy bar
 967         p = '0.5 0 0' * (vid_conwidth - 256);
 968         p = p + '0 1 0' * vid_conheight - '0 34  0';
 969         drawfill(p, '256 0 0' * (1 - energy) + '0 2 0' ,'0 0 1', 0.5, DRAWFLAG_NORMAL);
 970         p_x += 256 * (1 - energy);
 971         drawfill(p, '256 0 0' * energy  + '0 2 0' , '1 0 0', 0.5, DRAWFLAG_NORMAL);
 972
 973         // Draw rockets bar
 974         p_y += 8;
 975         drawfill(p, '256 0 0' * rockets + '0 8 0' , '1 0 0', 0.75, DRAWFLAG_NORMAL);
 976         p_x += 256 * health;
 977         drawfill(p, '256 0 0' * (1 - rockets) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
 978     */
 979
 980
 981         if (sb_showscores)
 982         {
 983                 Sbar_DrawScoreboard();
 984                 HUD_DrawCenterPrint();
 985         }
 986
 987 }
 988
 989
 990 void CSQC_common_hud(void)
 991 {
 992         // Sbar_SortFrags(); done in Sbar_Draw
 993         float hud;
 994         hud = getstati(STAT_HUD);
 995
 996         //hud = 10;
 997         switch(hud)
 998         {
 999                 case HUD_NORMAL:
1000                         HUD_Main();
1001                         break;
1002
1003                 case HUD_SPIDERBOT:
1004                         CSQC_spider_HUD();
1005                         break;
1006
1007                 case HUD_WAKIZASHI:
1008                         CSQC_WAKIZASHI_HUD();
1009                         break;
1010         }
1011 }
1012
1013
1014 // following vectors must be global to allow seamless switching between camera modes
1015 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1016 void CSQC_Demo_Camera()
1017 {
1018         float speed, attenuation, dimensions;
1019         vector tmp, delta;
1020
1021         if( cvar("camera_reset") || !camera_mode )
1022         {
1023                 camera_offset = '0 0 0';
1024                 current_angles = '0 0 0';
1025                 camera_direction = '0 0 0';
1026                 camera_offset_z += 30;
1027                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1028                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1029                 current_origin = view_origin;
1030                 current_camera_offset  = camera_offset;
1031                 cvar_set("camera_reset", "0");
1032                 camera_mode = CAMERA_CHASE;
1033         }
1034
1035         // Camera angles
1036         if( camera_roll )
1037                 mouse_angles_z += camera_roll * cvar("camera_speed_roll");
1038
1039         if(cvar("camera_look_player"))
1040         {
1041                 local vector dir;
1042                 local float n;
1043
1044                 dir = normalize(view_origin - current_position);
1045                 n = mouse_angles_z;
1046                 mouse_angles = vectoangles(dir);
1047                 mouse_angles_x = mouse_angles_x * -1;
1048                 mouse_angles_z = n;
1049         }
1050         else
1051         {
1052                 tmp = getmousepos() * 0.1;
1053                 if(vlen(tmp)>cvar("camera_mouse_treshold"))
1054                 {
1055                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1056                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1057                 }
1058         }
1059
1060         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1061         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1062         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1063         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1064
1065         // Fix difference when angles don't have the same sign
1066         delta = '0 0 0';
1067         if(mouse_angles_y < -60 && current_angles_y > 60)
1068                 delta = '0 360 0';
1069         if(mouse_angles_y > 60 && current_angles_y < -60)
1070                 delta = '0 -360 0';
1071
1072         if(cvar("camera_look_player"))
1073                 attenuation = cvar("camera_look_attenuation");
1074         else
1075                 attenuation = cvar("camera_speed_attenuation");
1076
1077         attenuation = 1 / max(1, attenuation);
1078         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1079
1080         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1081         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1082         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1083         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1084
1085         // Camera position
1086         tmp = '0 0 0';
1087         dimensions = 0;
1088
1089         if( camera_direction_x )
1090         {
1091                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1092                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1093                 if( cvar("camera_forward_follows") && !cvar("camera_look_player") )
1094                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1095                 ++dimensions;
1096         }
1097
1098         if( camera_direction_y )
1099         {
1100                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1101                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1102                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1103                 ++dimensions;
1104         }
1105
1106         if( camera_direction_z )
1107         {
1108                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1109                 ++dimensions;
1110         }
1111
1112         if(cvar("camera_free"))
1113                 speed = cvar("camera_speed_free");
1114         else
1115                 speed = cvar("camera_speed_chase");
1116
1117         if(dimensions)
1118         {
1119                 speed = speed * sqrt(1 / dimensions);
1120                 camera_offset += tmp * speed;
1121         }
1122
1123         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1124
1125         // Camera modes
1126         if( cvar("camera_free") )
1127         {
1128                 if ( camera_mode == CAMERA_CHASE )
1129                 {
1130                         current_camera_offset = current_origin + current_camera_offset;
1131                         camera_offset = current_origin + camera_offset;
1132                 }
1133
1134                 camera_mode = CAMERA_FREE;
1135                 current_position = current_camera_offset;
1136         }
1137         else
1138         {
1139                 if ( camera_mode == CAMERA_FREE )
1140                 {
1141                         current_origin = view_origin;
1142                         camera_offset = camera_offset - current_origin;
1143                         current_camera_offset = current_camera_offset - current_origin;
1144                 }
1145
1146                 camera_mode = CAMERA_CHASE;
1147
1148                 if(cvar("camera_chase_smoothly"))
1149                         current_origin += (view_origin - current_origin) * attenuation;
1150                 else
1151                         current_origin = view_origin;
1152
1153                 current_position = current_origin + current_camera_offset;
1154         }
1155
1156         R_SetView(VF_ANGLES, current_angles);
1157         R_SetView(VF_ORIGIN, current_position);
1158 }