data/qcsrc/client/View.qc

   1 vector angles_held[24];\r
   2 void Net_ReadHoldAngles()\r
   3 {\r
   4         float wpn;\r
   5         vector v;\r
   6         wpn = ReadByte();\r
   7         --wpn;\r
   8         angles_held_status[wpn] = ReadByte();\r
   9         if(angles_held_status[wpn])\r
  10         {\r
  11                 v_x = ReadCoord();\r
  12                 v_y = ReadCoord();\r
  13                 v_z = 0;\r
  14                 angles_held[wpn] = v;\r
  15         }\r
  16 }\r
  17 \r
  18 entity porto;\r
  19 vector polyline[16];\r
  20 float trace_dphitcontents;\r
  21 float Q3SURFACEFLAG_SLICK = 2; // low friction surface\r
  22 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement\r
  23 void Porto_Draw()\r
  24 {\r
  25         vector p, dir, ang, q, nextdir;\r
  26         float idx, portal_number, portal1_idx;\r
  27 \r
  28         if(activeweapon != WEP_PORTO)\r
  29                 return;\r
  30 \r
  31         dir = view_forward;\r
  32 \r
  33         if(angles_held_status[WEP_PORTO-1])\r
  34         {\r
  35                 makevectors(angles_held[WEP_PORTO-1]);\r
  36                 dir = v_forward;\r
  37         }\r
  38 \r
  39         p = view_origin;\r
  40 \r
  41         polyline[0] = p;\r
  42         idx = 1;\r
  43         portal_number = 0;\r
  44         nextdir = dir;\r
  45 \r
  46         for(;;)\r
  47         {\r
  48                 dir = nextdir;\r
  49                 traceline(p, p + 65536 * dir, TRUE, world);\r
  50                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)\r
  51                         return;\r
  52                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal\r
  53                 p = trace_endpos;\r
  54                 polyline[idx] = p;\r
  55                 ++idx;\r
  56                 if(idx >= 16)\r
  57                         return;\r
  58                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)\r
  59                         continue;\r
  60                 ++portal_number;\r
  61                 ang = vectoangles2(trace_plane_normal, dir);\r
  62                 ang_x = -ang_x;\r
  63                 makevectors(ang);\r
  64                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))\r
  65                         return;\r
  66                 if(portal_number == 1)\r
  67                         portal1_idx = idx;\r
  68                 if(portal_number >= 2)\r
  69                         break;\r
  70         }\r
  71 \r
  72         while(idx >= 2)\r
  73         {\r
  74                 p = polyline[idx-2];\r
  75                 q = polyline[idx-1];\r
  76                 if(idx == 2)\r
  77                         p = p - view_up * 16;\r
  78                 if(idx-1 >= portal1_idx)\r
  79                 {\r
  80                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL);\r
  81                 }\r
  82                 else\r
  83                 {\r
  84                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL);\r
  85                 }\r
  86                 --idx;\r
  87         }\r
  88 }\r
  89 \r
  90 float DPCONTENTS_SOLID = 1; // hit a bmodel, not a bounding box\r
  91 float DPCONTENTS_BODY = 32; // hit a bounding box, not a bmodel\r
  92 void Porto_Init()\r
  93 {\r
  94         porto = spawn();\r
  95         porto.classname = "porto";\r
  96         porto.draw = Porto_Draw;\r
  97         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;\r
  98 }\r
  99 \r
 100 float drawtime;\r
 101 \r
 102 float tan(float x)\r
 103 { \r
 104         return sin(x) / cos(x);\r
 105 }\r
 106 float atan2(float y, float x)\r
 107 {\r
 108         vector v;\r
 109         v = '1 0 0' * x + '0 1 0' * y;\r
 110         v = vectoangles(v);\r
 111         return v_y * 0.01745329251994329576;\r
 112 }\r
 113 \r
 114 vector GetCurrentFov(float fov)\r
 115 {\r
 116         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;\r
 117 \r
 118         zoomsensitivity = cvar("cl_zoomsensitivity");\r
 119         zoomfactor = cvar("cl_zoomfactor");\r
 120         if(zoomfactor < 1 || zoomfactor > 16)\r
 121                 zoomfactor = 2.5;\r
 122         zoomspeed = cvar("cl_zoomspeed");\r
 123         if(zoomspeed >= 0)\r
 124                 if(zoomspeed < 0.5 || zoomspeed > 16)\r
 125                         zoomspeed = 3.5;\r
 126 \r
 127         zoomdir = button_zoom;\r
 128         if(getstati(STAT_ACTIVEWEAPON) == WEP_NEX) // do NOT use switchweapon here\r
 129                 zoomdir += button_attack2;\r
 130         if(spectatee_status > 0 || isdemo())\r
 131         {\r
 132                 if(spectatorbutton_zoom)\r
 133                         zoomdir = 0 + !zoomdir;\r
 134                         // do not even THINK about removing this 0\r
 135                         // _I_ know what I am doing\r
 136                         // fteqcc does not\r
 137         }\r
 138 \r
 139         if(zoomdir)\r
 140                 zoomin_effect = 0;\r
 141 \r
 142         if(zoomin_effect)\r
 143         {\r
 144                 current_viewzoom = min(1, current_viewzoom + drawframetime);\r
 145         }\r
 146         else\r
 147         {\r
 148                 if(zoomspeed < 0) // instant zoom\r
 149                 {\r
 150                         if(zoomdir)\r
 151                                 current_viewzoom = 1 / zoomfactor;\r
 152                         else\r
 153                                 current_viewzoom = 1;\r
 154                 }\r
 155                 else\r
 156                 {\r
 157                         if(zoomdir)\r
 158                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);\r
 159                         else\r
 160                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);\r
 161                 }\r
 162         }\r
 163 \r
 164         current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);\r
 165 \r
 166         if(zoomsensitivity < 1)\r
 167                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));\r
 168         else\r
 169                 setsensitivityscale(1);\r
 170 \r
 171         float frustumx, frustumy, fovx, fovy;\r
 172         frustumy = tan(fov * 0.00872664625997164788) * 0.75 * current_viewzoom;\r
 173         frustumx = frustumy * cvar("vid_width") / cvar("vid_height") / cvar("vid_pixelheight");\r
 174         fovx = atan2(frustumx, 1) / 0.00872664625997164788;\r
 175         fovy = atan2(frustumy, 1) / 0.00872664625997164788;\r
 176 \r
 177         return '1 0 0' * fovx + '0 1 0' * fovy;\r
 178 }\r
 179 \r
 180 void CSQC_common_hud(void);\r
 181 \r
 182 void CSQC_kh_hud(void);\r
 183 void CSQC_ctf_hud(void);\r
 184 void PostInit(void);\r
 185 float Sbar_WouldDrawScoreboard ();\r
 186 float zoomscript_caught;\r
 187 void CSQC_UpdateView(void)\r
 188 {\r
 189         entity e;\r
 190         float fov;\r
 191 \r
 192         Fog_Force();\r
 193 \r
 194         drawframetime = max(0.000001, time - drawtime);\r
 195         drawtime = time;\r
 196 \r
 197         // watch for gametype changes here...\r
 198         // in ParseStuffCMD the cmd isn't executed yet :/\r
 199         // might even be better to add the gametype to TE_CSQC_INIT...?\r
 200         if(!postinit)\r
 201                 PostInit();\r
 202 \r
 203         fov = cvar("fov");\r
 204         if(button_zoom || fov <= 59.5)\r
 205         {\r
 206                 if(!zoomscript_caught)\r
 207                 {\r
 208                         localcmd("+button4\n");\r
 209                         zoomscript_caught = 1;\r
 210                         ignore_plus_zoom += 1;\r
 211                 }\r
 212         }\r
 213         else\r
 214         {\r
 215                 if(zoomscript_caught)\r
 216                 {\r
 217                         localcmd("-button4\n");\r
 218                         zoomscript_caught = 0;\r
 219                         ignore_minus_zoom += 1;\r
 220                 }\r
 221         }\r
 222         \r
 223         sbar_alpha_fg = cvar("sbar_alpha_fg" );\r
 224         sbar_hudselector = cvar("sbar_hudselector");\r
 225         activeweapon = getstati(STAT_SWITCHWEAPON);\r
 226         teamplay = cvar("teamplay");\r
 227 \r
 228         if(last_weapon != activeweapon) {\r
 229                 weapontime = time;\r
 230                 last_weapon = activeweapon;\r
 231         }\r
 232 \r
 233         // ALWAYS Clear Current Scene First\r
 234         R_ClearScene();\r
 235 \r
 236         // Assign Standard Viewflags\r
 237         // Draw the World (and sky)\r
 238         R_SetView(VF_DRAWWORLD, 1);\r
 239 \r
 240         R_SetView(VF_FOV, GetCurrentFov(fov));\r
 241         \r
 242         // Draw the Crosshair\r
 243         R_SetView(VF_DRAWCROSSHAIR, !Sbar_WouldDrawScoreboard());\r
 244         \r
 245         // Draw the Engine Status Bar (the default Quake HUD)\r
 246         draw_enginesbar = !cvar("sbar_usecsqc");\r
 247         R_SetView(VF_DRAWENGINESBAR, draw_enginesbar);\r
 248 \r
 249         // Set the console size vars\r
 250         vid_conwidth = cvar("vid_conwidth");\r
 251         vid_conheight = cvar("vid_conheight");\r
 252 \r
 253         // fetch this one only once per frame\r
 254         sbar_showbinds = cvar("sbar_showbinds");\r
 255         sbar_showbinds_limit = cvar("sbar_showbinds_limit");\r
 256 \r
 257         // Update the mouse position\r
 258         /*\r
 259         mousepos_x = vid_conwidth;\r
 260         mousepos_y = vid_conheight;\r
 261         mousepos = mousepos*0.5 + getmousepos();\r
 262         */\r
 263 \r
 264         R_AddEntities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);\r
 265 \r
 266         // Render the Scene\r
 267         \r
 268         view_origin = pmove_org + '0 0 1' * getstati(STAT_VIEWHEIGHT);\r
 269         view_angles = input_angles;\r
 270         makevectors(view_angles);\r
 271         view_forward = v_forward;\r
 272         view_right = v_right;\r
 273         view_up = v_up;\r
 274         \r
 275         e = self;\r
 276         for(self = world; (self = nextent(self)); )\r
 277                 if(self.draw)\r
 278                         self.draw();\r
 279         self = e;\r
 280         R_RenderScene();\r
 281 \r
 282         // Draw the mouse cursor\r
 283         // NOTE: drawpic must happen after R_RenderScene for some reason\r
 284         //drawpic(getmousepos(), "gfx/cursor.tga", '11 14 0', '1 1 1', 1, 0);\r
 285         //drawstring('50 50', ftos(game), '10 10 0', '1 1 1', 1, 0);\r
 286         //self = edict_num(player_localnum);\r
 287         //drawstring('0 0', vtos(pmove_org), '8 8 0', '1 1 1', 1, 0);\r
 288         //drawstring('0 8', strcat("ORG: ", vtos(self.origin), " state: ", ftos(self.ctf_state), " HP: ", ftos(self.health)), '8 8 0', '1 1 1', 1, 0);\r
 289         // as long as the ctf part isn't in, this is useless\r
 290         if(menu_visible)\r
 291                 menu_show();\r
 292         \r
 293         /*if(gametype == GAME_CTF)\r
 294         {\r
 295                 ctf_view();\r
 296         } else */\r
 297         if(!draw_enginesbar)\r
 298         {\r
 299                 if(cvar("r_letterbox") == 0)\r
 300                 if(cvar("viewsize") < 120)\r
 301                         CSQC_common_hud();\r
 302         }\r
 303         \r
 304         if(gametype == GAME_ONSLAUGHT)\r
 305         {\r
 306                 //drawstring('0 0', minimapname, '8 8 0', '1 1 1', 1, 0);\r
 307                 //drawsetcliparea(0,0,800,600);\r
 308                 ons_view();\r
 309                 //drawresetcliparea();\r
 310         }\r
 311         else if(teamplay)\r
 312                 teamradar_view();\r
 313 }\r
 314 \r
 315 void Sbar_Draw();\r
 316 void CSQC_common_hud(void)\r
 317 {\r
 318         // Sbar_SortFrags(); done in Sbar_Draw\r
 319         Sbar_Draw();\r
 320 }\r
 321 \r
 322 // KeyHunt HUD by victim\r
 323 void CSQC_kh_hud(void)\r
 324 {\r
 325         // HUD 0 has the weapons on the right hand side - temporarily shown when needed\r
 326         // HUD 1 has the weapons on the bottom - permanently\r
 327 \r
 328         // use the following two binds to check the icons move correctly\r
 329         // bind g "toggle sbar_flagstatus_right; echo Menu right $sbar_flagstatus_right"  // move the icons\r
 330         // bind h "toggle sbar_hudselector; echo HUD $sbar_hudselector"  // change the HUD\r
 331 \r
 332         float kh_keys, kh_keys_status, kh_teams_set;\r
 333         float kh_margin_x, kh_margin_y, kh_key_box;\r
 334         string kh_carrying, kh_outline;\r
 335         vector red_pos, blue_pos, yellow_pos, pink_pos, kh_size;\r
 336         vector red, blue, yellow, pink;\r
 337 \r
 338         kh_keys = getstati(STAT_KH_KEYS);\r
 339         kh_keys_status = kh_keys / 256;\r
 340         kh_teams_set = cvar("_teams_available");  // set in keyhunt.qc\r
 341 \r
 342         kh_margin_y = 8;\r
 343         kh_margin_x = (cvar("sbar_flagstatus_right") * sbar_hudselector * (vid_conwidth - 67)) + 10;\r
 344 //      sbar_flagstatus_right 0/1; sbar_hudselector 0/1; screen width - key width + margin\r
 345 \r
 346         red_pos_x = blue_pos_x = yellow_pos_x = pink_pos_x = kh_margin_x;\r
 347 \r
 348         kh_key_box = 120;\r
 349 \r
 350         pink_pos_y = kh_margin_y + 0;  // top\r
 351         yellow_pos_y = kh_margin_y + kh_key_box;\r
 352         blue_pos_y = kh_margin_y + kh_key_box * 2;\r
 353         red_pos_y = kh_margin_y + kh_key_box * 3;  //bottom\r
 354 \r
 355         red = '1 0 0';\r
 356         blue = '0 0 1';\r
 357         yellow = '1 1 0';\r
 358         pink = '1 0 1';\r
 359 \r
 360         kh_size = '0 0 0';  // don't resize the image\r
 361 \r
 362         kh_carrying = "gfx/sb_kh_full";\r
 363         kh_outline = "gfx/sb_kh_outline";\r
 364 \r
 365 //      drawpic(vector position, string pic, vector size, vector rgb, float alpha, float flag)\r
 366 //      vector position = '0 0';  // 'x y' 0 0 (the origin) is the top left. X 0 - 799, Y 0 - 599\r
 367 \r
 368 //      vector size = '0 0';  // 'x y' changes the x & y dimensions. '0 0' gives the default pic size\r
 369 //      vector rgb = '0 0 0';  // 'r g b' range 0 - 1\r
 370 \r
 371         if (kh_keys_status & 1)  // red\r
 372                 drawpic (red_pos, kh_carrying, kh_size, red, 0.2, 0);  // show 20% alpha key\r
 373         else\r
 374                 drawpic (red_pos, kh_outline, kh_size, red, 0.4, 0);  // show key outline 40% alpha\r
 375 \r
 376         if (kh_keys & 1)\r
 377                 drawpic (red_pos, kh_carrying, kh_size, red, 1.0, 0);  // show solid key 100% alpha\r
 378 \r
 379 \r
 380         if (kh_keys_status & 2)  // blue\r
 381                 drawpic (blue_pos, kh_carrying, kh_size, blue, 0.2, 0);\r
 382         else\r
 383                 drawpic (blue_pos, kh_outline, kh_size, blue, 0.4, 0);\r
 384 \r
 385         if (kh_keys & 2)\r
 386                 drawpic (blue_pos, kh_carrying, kh_size, blue, 1.0, 0);\r
 387 \r
 388 \r
 389         if (kh_teams_set & 4)  // yellow\r
 390         {\r
 391                 if (kh_keys_status & 4)\r
 392                         drawpic (yellow_pos, kh_carrying, kh_size, yellow, 0.2, 0);\r
 393                 else\r
 394                         drawpic (yellow_pos, kh_outline, kh_size, yellow, 0.4, 0);\r
 395 \r
 396                 if (kh_keys & 4)\r
 397                         drawpic (yellow_pos, kh_carrying, kh_size, yellow, 1.0, 0);\r
 398         }\r
 399 \r
 400 \r
 401         if (kh_teams_set & 8)  // pink\r
 402         {\r
 403                 if (kh_keys_status & 8)\r
 404                         drawpic (pink_pos, kh_carrying, kh_size, pink, 0.2, 0);\r
 405                 else\r
 406                         drawpic (pink_pos, kh_outline, kh_size, pink, 0.4, 0);\r
 407 \r
 408                 if (kh_keys & 8)\r
 409                         drawpic (pink_pos, kh_carrying, kh_size, pink, 1.0, 0);\r
 410         }\r
 411 \r
 412 }\r