data/qcsrc/client/View.qc

   1 #define spider_rocket_icon "gfx/spiderbot/rocket_ico.tga"
   2 #define spider_rocket_targ "gfx/spiderbot/target.tga"
   3 #define SPIDER_CROSS "textures/spiderbot/cross.tga"
   4 #define rkt_size 32
   5 #define rld_size_x 256
   6 #define rld_size_y 16
   7
   8 entity porto;
   9 vector polyline[16];
  10 float trace_dphitcontents;
  11 float trace_networkentity;
  12 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
  13 float DPCONTENTS_SOLID = 1; // blocks player movement
  14 float DPCONTENTS_BODY = 32; // blocks player movement
  15 float DPCONTENTS_CORPSE = 64; // blocks player movement
  16 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
  17 void Porto_Draw()
  18 {
  19         vector p, dir, ang, q, nextdir;
  20         float idx, portal_number, portal1_idx;
  21
  22         if(activeweapon != WEP_PORTO || spectatee_status || gametype == GAME_NEXBALL)
  23                 return;
  24         if(intermission == 1)
  25                 return;
  26         if(intermission == 2)
  27                 return;
  28         if (getstati(STAT_HEALTH) <= 0)
  29                 return;
  30
  31         dir = view_forward;
  32
  33         if(angles_held_status)
  34         {
  35                 makevectors(angles_held);
  36                 dir = v_forward;
  37         }
  38
  39         p = view_origin;
  40
  41         polyline[0] = p;
  42         idx = 1;
  43         portal_number = 0;
  44         nextdir = dir;
  45
  46         for(;;)
  47         {
  48                 dir = nextdir;
  49                 traceline(p, p + 65536 * dir, TRUE, porto);
  50                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  51                         return;
  52                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  53                 p = trace_endpos;
  54                 polyline[idx] = p;
  55                 ++idx;
  56                 if(idx >= 16)
  57                         return;
  58                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  59                         continue;
  60                 ++portal_number;
  61                 ang = vectoangles2(trace_plane_normal, dir);
  62                 ang_x = -ang_x;
  63                 makevectors(ang);
  64                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  65                         return;
  66                 if(portal_number == 1)
  67                         portal1_idx = idx;
  68                 if(portal_number >= 2)
  69                         break;
  70         }
  71
  72         while(idx >= 2)
  73         {
  74                 p = polyline[idx-2];
  75                 q = polyline[idx-1];
  76                 if(idx == 2)
  77                         p = p - view_up * 16;
  78                 if(idx-1 >= portal1_idx)
  79                 {
  80                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL);
  81                 }
  82                 else
  83                 {
  84                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL);
  85                 }
  86                 --idx;
  87         }
  88 }
  89
  90 /**
  91  * Checks whether the server initiated a map restart (stat_game_starttime changed)
  92  *
  93  * TODO: Use a better solution where a common shared entitiy is used that contains
  94  * timelimit, fraglimit and game_starttime! Requires engine changes (remove STAT_TIMELIMIT
  95  * and STAT_FRAGLIMIT to be auto-sent)
  96  */
  97 void CheckForGamestartChange() {
  98         float startTime;
  99         startTime = getstatf(STAT_GAMESTARTTIME);
 100         if (previous_game_starttime != startTime) {
 101                 if ((time + 5.0) < startTime) {
 102                         //if connecting to server while restart was active don't always play prepareforbattle
 103                         sound(self, CHAN_VOICE, "announcer/robotic/prepareforbattle.wav", VOL_BASEVOICE, ATTN_NONE);
 104                 }
 105                 if (time < startTime) {
 106                         restartAnnouncer = spawn();
 107                         restartAnnouncer.think = restartAnnouncer_Think;
 108                         restartAnnouncer.nextthink = startTime - floor(startTime - time); //synchronize nextthink to startTime
 109                 }
 110         }
 111         previous_game_starttime = startTime;
 112 }
 113
 114 void Porto_Init()
 115 {
 116         porto = spawn();
 117         porto.classname = "porto";
 118         porto.draw = Porto_Draw;
 119         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 120 }
 121
 122 float drawtime;
 123
 124 float tan(float x)
 125 {
 126         return sin(x) / cos(x);
 127 }
 128 float atan2(float y, float x)
 129 {
 130         vector v;
 131         v = '1 0 0' * x + '0 1 0' * y;
 132         v = vectoangles(v);
 133         return v_y * 0.01745329251994329576;
 134 }
 135
 136 vector GetCurrentFov(float fov)
 137 {
 138         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 139
 140         zoomsensitivity = cvar("cl_zoomsensitivity");
 141         zoomfactor = cvar("cl_zoomfactor");
 142         if(zoomfactor < 1 || zoomfactor > 16)
 143                 zoomfactor = 2.5;
 144         zoomspeed = cvar("cl_zoomspeed");
 145         if(zoomspeed >= 0)
 146                 if(zoomspeed < 0.5 || zoomspeed > 16)
 147                         zoomspeed = 3.5;
 148
 149         zoomdir = button_zoom;
 150         if(getstati(STAT_ACTIVEWEAPON) == WEP_NEX) // do NOT use switchweapon here
 151                 zoomdir += button_attack2;
 152         if(spectatee_status > 0 || isdemo())
 153         {
 154                 if(spectatorbutton_zoom)
 155                         zoomdir = 0 + !zoomdir;
 156                         // do not even THINK about removing this 0
 157                         // _I_ know what I am doing
 158                         // fteqcc does not
 159         }
 160
 161         if(zoomdir)
 162                 zoomin_effect = 0;
 163
 164         if(zoomin_effect || camera_active)
 165         {
 166                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 167         }
 168         else
 169         {
 170                 if(zoomspeed < 0) // instant zoom
 171                 {
 172                         if(zoomdir)
 173                                 current_viewzoom = 1 / zoomfactor;
 174                         else
 175                                 current_viewzoom = 1;
 176                 }
 177                 else
 178                 {
 179                         if(zoomdir)
 180                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 181                         else
 182                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 183                 }
 184         }
 185
 186         if(almost_equals(current_viewzoom, 1))
 187                 current_zoomfraction = 0;
 188         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 189                 current_zoomfraction = 1;
 190         else
 191                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 192
 193         if(zoomsensitivity < 1)
 194                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 195         else
 196                 setsensitivityscale(1);
 197
 198         float frustumx, frustumy, fovx, fovy;
 199         frustumy = tan(fov * 0.00872664625997164788) * 0.75 * current_viewzoom;
 200         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 201         fovx = atan2(frustumx, 1) / 0.00872664625997164788;
 202         fovy = atan2(frustumy, 1) / 0.00872664625997164788;
 203
 204         return '1 0 0' * fovx + '0 1 0' * fovy;
 205 }
 206
 207 // this function must match W_SetupShot!
 208 float zoomscript_caught;
 209
 210 vector wcross_origin;
 211 entity trueaim;
 212
 213 #define SHOTTYPE_HITTEAM 1
 214 #define SHOTTYPE_HITOBSTRUCTION 2
 215 #define SHOTTYPE_HITWORLD 3
 216 #define SHOTTYPE_HITENEMY 4
 217
 218 void TrueAim_Init()
 219 {
 220         trueaim = spawn();
 221         trueaim.classname = "trueaim";
 222         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 223 }
 224
 225 float EnemyHitCheck()
 226 {
 227         float t;
 228         wcross_origin = project_3d_to_2d(trace_endpos);
 229         wcross_origin_z = 0;
 230         if(trace_networkentity < 1)
 231                 return SHOTTYPE_HITWORLD;
 232         if(trace_networkentity > maxclients)
 233                 return SHOTTYPE_HITWORLD;
 234         t = GetPlayerColor(trace_networkentity - 1);
 235         if(teamplay)
 236         if(t == myteam)
 237                 return SHOTTYPE_HITTEAM;
 238         if(t == COLOR_SPECTATOR)
 239                 return SHOTTYPE_HITWORLD;
 240         return SHOTTYPE_HITENEMY;
 241 }
 242
 243 float TrueAimCheck()
 244 {
 245         float nudge = 1; // added to traceline target and subtracted from result
 246         vector vecs, trueaimpoint, w_shotorg;
 247         vector mi, ma, dv;
 248         float shottype;
 249
 250         mi = ma = '0 0 0';
 251
 252         switch(activeweapon)
 253         {
 254                 case WEP_TUBA: // no aim
 255                 case WEP_PORTO: // shoots from eye
 256                 case WEP_HOOK: // no trueaim
 257                 case WEP_GRENADE_LAUNCHER: // toss curve
 258                         return SHOTTYPE_HITWORLD;
 259                 case WEP_CAMPINGRIFLE:
 260                         if(zoomscript_caught)
 261                         {
 262                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, trueaim);
 263                                 return EnemyHitCheck();
 264                         }
 265                         break;
 266                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 267                         mi = '-3 -3 -3';
 268                         ma = '3 3 3';
 269                         break;
 270                 case WEP_ELECTRO: // projectile has a size!
 271                         mi = '0 0 -3';
 272                         ma = '0 0 -3';
 273                         break;
 274         }
 275
 276         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 277
 278         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, MOVE_NOMONSTERS, trueaim);
 279         trueaimpoint = trace_endpos;
 280
 281         if(vecs_x > 0)
 282                 vecs_y = -vecs_y;
 283         else
 284                 vecs = '0 0 0';
 285
 286         dv = view_right * vecs_y + view_up * vecs_z;
 287         w_shotorg = view_origin + dv;
 288
 289         // now move the vecs forward as much as requested if possible
 290         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, trueaim); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 291         w_shotorg = trace_endpos - view_forward * nudge;
 292
 293         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, trueaim);
 294         shottype = EnemyHitCheck();
 295         if(shottype != SHOTTYPE_HITWORLD)
 296                 return shottype;
 297
 298 #if 0
 299         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 300         // or rather, I know why, but see no fix
 301         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 302                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 303                 return SHOTTYPE_HITOBSTRUCTION;
 304 #endif
 305
 306         return SHOTTYPE_HITWORLD;
 307 }
 308
 309 void CSQC_common_hud(void);
 310
 311 void CSQC_kh_hud(void);
 312 void CSQC_ctf_hud(void);
 313 void PostInit(void);
 314 void CSQC_Demo_Camera();
 315 float Sbar_WouldDrawScoreboard ();
 316 float view_set;
 317 float camera_mode;
 318 string NextFrameCommand;
 319 void CSQC_spider_HUD();
 320 void CSQC_UpdateView(float w, float h)
 321 {
 322         entity e;
 323         float fov;
 324         float f, i, j;
 325         vector v;
 326
 327         dprint_load();
 328         WaypointSprite_Load();
 329
 330         if(spectatee_status)
 331                 myteam = GetPlayerColor(spectatee_status - 1);
 332         else
 333                 myteam = GetPlayerColor(player_localentnum - 1);
 334
 335         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 336
 337         // Render the Scene
 338         if(!intermission || !view_set)
 339         {
 340                 view_origin = pmove_org + '0 0 1' * getstati(STAT_VIEWHEIGHT);
 341                 view_angles = input_angles;
 342                 makevectors(view_angles);
 343                 view_forward = v_forward;
 344                 view_right = v_right;
 345                 view_up = v_up;
 346                 view_set = 1;
 347         }
 348
 349         vid_width = w;
 350         vid_height = h;
 351
 352 #ifdef BLURTEST
 353         if(time > blurtest_time0 && time < blurtest_time1)
 354         {
 355                 float r, t;
 356
 357                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 358                 r = t * blurtest_radius;
 359                 f = 1 / pow(t, blurtest_power) - 1;
 360
 361                 cvar_set("r_glsl_postprocess", "1");
 362                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 363         }
 364         else
 365         {
 366                 cvar_set("r_glsl_postprocess", "0");
 367                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 368         }
 369 #endif
 370
 371         Fog_Force();
 372
 373         drawframetime = max(0.000001, time - drawtime);
 374         drawtime = time;
 375
 376         // watch for gametype changes here...
 377         // in ParseStuffCMD the cmd isn't executed yet :/
 378         // might even be better to add the gametype to TE_CSQC_INIT...?
 379         if(!postinit)
 380                 PostInit();
 381
 382         CheckForGamestartChange();
 383         maptimeAnnouncer();
 384
 385         fov = cvar("fov");
 386         if(button_zoom || fov <= 59.5)
 387         {
 388                 if(!zoomscript_caught)
 389                 {
 390                         localcmd("+button4\n");
 391                         zoomscript_caught = 1;
 392                         ignore_plus_zoom += 1;
 393                 }
 394         }
 395         else
 396         {
 397                 if(zoomscript_caught)
 398                 {
 399                         localcmd("-button4\n");
 400                         zoomscript_caught = 0;
 401                         ignore_minus_zoom += 1;
 402                 }
 403         }
 404
 405         sbar_alpha_fg = cvar("sbar_alpha_fg" );
 406         sbar_currentammo = cvar("sbar_showcurrentammo");
 407         sbar_hudselector = cvar("sbar_hudselector");
 408         sbar_hud_accuracy = cvar("sbar_hud_accuracy");
 409         ColorTranslateMode = cvar("cl_stripcolorcodes");
 410         activeweapon = getstati(STAT_SWITCHWEAPON);
 411         f = cvar("teamplay");
 412         if(f != teamplay)
 413         {
 414                 teamplay = f;
 415                 Sbar_InitScores();
 416         }
 417
 418         if(last_weapon != activeweapon) {
 419                 weapontime = time;
 420                 last_weapon = activeweapon;
 421         }
 422
 423         // ALWAYS Clear Current Scene First
 424         R_ClearScene();
 425
 426         // Assign Standard Viewflags
 427         // Draw the World (and sky)
 428         R_SetView(VF_DRAWWORLD, 1);
 429
 430         // Set the console size vars
 431         vid_conwidth = cvar("vid_conwidth");
 432         vid_conheight = cvar("vid_conheight");
 433         vid_pixelheight = cvar("vid_pixelheight");
 434
 435         R_SetView(VF_FOV, GetCurrentFov(fov));
 436
 437         // Camera for demo playback
 438         if(camera_active)
 439         {
 440                 if(cvar("camera_enable"))
 441                         CSQC_Demo_Camera();
 442                 else
 443                 {
 444                         cvar_set("chase_active", ftos(chase_active_backup));
 445                         cvar_set("cl_demo_mousegrab", "0");
 446                         camera_active = FALSE;
 447                 }
 448         }
 449 #ifdef CAMERATEST
 450         else if(cvar("camera_enable"))
 451 #else
 452         else if(cvar("camera_enable") && isdemo())
 453 #endif
 454         {
 455                 // Enable required Darkplaces cvars
 456                 chase_active_backup = cvar("chase_active");
 457                 cvar_set("chase_active", "2");
 458                 cvar_set("cl_demo_mousegrab", "1");
 459                 camera_active = TRUE;
 460                 camera_mode = FALSE;
 461         }
 462
 463         // Draw the Crosshair
 464         float scoreboard_active;
 465         scoreboard_active = Sbar_WouldDrawScoreboard();
 466         R_SetView(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 467
 468         // Draw the Engine Status Bar (the default Quake HUD)
 469         R_SetView(VF_DRAWENGINESBAR, 0);
 470
 471         // fetch this one only once per frame
 472         sbar_showbinds = cvar("sbar_showbinds");
 473         sbar_showbinds_limit = cvar("sbar_showbinds_limit");
 474
 475         // Update the mouse position
 476         /*
 477         mousepos_x = vid_conwidth;
 478         mousepos_y = vid_conheight;
 479         mousepos = mousepos*0.5 + getmousepos();
 480         */
 481
 482         e = self;
 483         for(self = world; (self = nextent(self)); )
 484                 if(self.draw)
 485                         self.draw();
 486         self = e;
 487
 488         R_AddEntities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 489         R_RenderScene();
 490
 491         // now switch to 2D drawing mode by calling a 2D drawing function
 492         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 493         // next R_RenderScene call
 494         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 495
 496         // Draw the mouse cursor
 497         // NOTE: drawpic must happen after R_RenderScene for some reason
 498         //drawpic(getmousepos(), "gfx/cursor.tga", '11 14 0', '1 1 1', 1, 0);
 499         //drawstring('50 50', ftos(game), '10 10 0', '1 1 1', 1, 0);
 500         //self = edict_num(player_localnum);
 501         //drawstring('0 0', vtos(pmove_org), '8 8 0', '1 1 1', 1, 0);
 502         //drawstring('0 8', strcat("ORG: ", vtos(self.origin), " state: ", ftos(self.ctf_state), " HP: ", ftos(self.health)), '8 8 0', '1 1 1', 1, 0);
 503         // as long as the ctf part isn't in, this is useless
 504         if(menu_visible)
 505                 menu_show();
 506
 507         /*if(gametype == GAME_CTF)
 508         {
 509                 ctf_view();
 510         } else */
 511
 512         // draw 2D entities
 513         e = self;
 514         for(self = world; (self = nextent(self)); )
 515                 if(self.draw2d)
 516                         self.draw2d();
 517         self = e;
 518
 519         // draw radar
 520         if(
 521                 ons_showmap
 522                 ||
 523                 (
 524                         !scoreboard_active
 525                         &&
 526                         cvar_string("cl_teamradar") != "0"
 527                         &&
 528                         (
 529                                 cvar("cl_teamradar") == 2
 530                                 ||
 531                                 teamplay
 532                         )
 533                 )
 534         )
 535                 teamradar_view();
 536
 537         if (cvar("cl_showpressedkeys")) // draw pressed keys when spectating and playing
 538         {
 539                 if(spectatee_status > 0 || cvar("cl_showpressedkeys") >= 2)
 540                         Sbar_DrawPressedKeys();
 541         }
 542
 543         if (cvar("cl_showspeed"))
 544                 Sbar_ShowSpeed();
 545
 546         // draw sbar
 547         if(cvar("r_letterbox") == 0)
 548                 Sbar_DrawCenterPrint(); // draw centerprint messages even if viewsize >= 120
 549
 550     float hud;
 551     hud = getstati(STAT_HUD);
 552     if(hud == HUD_SPIDEBOT)
 553     {
 554         vector sz;
 555         CSQC_spider_HUD();
 556         sz = drawgetimagesize(SPIDER_CROSS);
 557         sz_x *= cvar_or("cl_vehicle_spiderbot_cross_size",1);
 558         sz_y *= cvar_or("cl_vehicle_spiderbot_cross_size",1);
 559         drawpic('0.5 0 0' * (vid_conwidth - sz_x) + '0 0.5 0' * (vid_conheight - sz_y), SPIDER_CROSS, sz, '1 1 1', cvar_or("cl_vehicle_spiderbot_cross_alpha",0.6), DRAWFLAG_NORMAL);
 560     }
 561     else
 562     {
 563         if(cvar("r_letterbox") == 0)
 564             if(cvar("viewsize") < 120)
 565                 CSQC_common_hud();
 566
 567         // crosshair goes VERY LAST
 568         if(!scoreboard_active && !ons_showmap && !camera_active) {
 569                         // TrueAim check
 570                         float shottype;
 571                         float bullets, ring_scale;
 572                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 573                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 574                         wcross_origin_z = 0;
 575             if(cvar("crosshair_hittest"))
 576                         {
 577                                 vector wcross_oldorigin;
 578                                 wcross_oldorigin = wcross_origin;
 579                 shottype = TrueAimCheck();
 580                                 if(shottype == SHOTTYPE_HITWORLD)
 581                                 {
 582                                         v = wcross_origin - wcross_oldorigin;
 583                                         v_x /= vid_conwidth;
 584                                         v_y /= vid_conheight;
 585                                         if(vlen(v) > 0.01)
 586                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
 587                                 }
 588                                 if(!cvar("crosshair_hittest_showimpact"))
 589                                         wcross_origin = wcross_oldorigin;
 590                         }
 591             else
 592                 shottype = SHOTTYPE_HITWORLD;
 593
 594             string wcross_style;
 595             wcross_style = cvar_string("crosshair");
 596
 597             if (wcross_style != "0") {
 598                 vector wcross_color, wcross_size;
 599                 string wcross_wep, wcross_name;
 600                 float wcross_alpha, wcross_sizefloat;
 601
 602                 wcross_color_x = cvar("crosshair_color_red");
 603                 wcross_color_y = cvar("crosshair_color_green");
 604                 wcross_color_z = cvar("crosshair_color_blue");
 605                 wcross_alpha = cvar("crosshair_color_alpha");
 606                 wcross_sizefloat = cvar("crosshair_size");
 607                 if (cvar("crosshair_per_weapon")) {
 608                     e = get_weaponinfo(activeweapon);
 609                     if (e && e.netname != "")
 610                     {
 611                         wcross_wep = e.netname;
 612                         wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
 613                         if(wcross_style == "")
 614                             wcross_style = e.netname;
 615
 616                         if(!cvar("crosshair_color_override"))
 617                         {
 618                             wcross_color_x = cvar(strcat("crosshair_", wcross_wep, "_color_red"));
 619                             wcross_color_y = cvar(strcat("crosshair_", wcross_wep, "_color_green"));
 620                             wcross_color_z = cvar(strcat("crosshair_", wcross_wep, "_color_blue"));
 621                         }
 622
 623                         wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_color_alpha"));
 624                         wcross_sizefloat *= cvar(strcat("crosshair_", wcross_wep, "_size"));
 625                     }
 626                 }
 627
 628                 wcross_name = strcat("gfx/crosshair", wcross_style);
 629
 630                                 if(shottype == SHOTTYPE_HITENEMY)
 631                                         wcross_sizefloat *= cvar("crosshair_hittest"); // is not queried if hittest is 0
 632                                 if(shottype == SHOTTYPE_HITTEAM)
 633                                         wcross_sizefloat /= cvar("crosshair_hittest"); // is not queried if hittest is 0
 634
 635                 wcross_size = drawgetimagesize(wcross_name);
 636                 wcross_size_x *= wcross_sizefloat;
 637                 wcross_size_y *= wcross_sizefloat;
 638
 639                                 // ring around crosshair representing bullets left in camping rifle clip
 640                                 if (activeweapon == WEP_CAMPINGRIFLE)
 641                                 {
 642                                         ring_scale = cvar("crosshair_campingrifle_ring_size");
 643                                         bullets = bound(0, getstati(STAT_BULLETS_LOADED), 8);
 644                                 }
 645                                 else
 646                                         bullets = 0;
 647
 648                 if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && cvar("crosshair_hittest_blur")))
 649                 {
 650                     wcross_alpha *= 0.04 * 0.75;
 651                     for(i = -2; i <= 2; ++i)
 652                         for(j = -2; j <= 2; ++j)
 653                                                 {
 654                                                         if (bullets)
 655                                                                 drawpic(wcross_origin - '0.5 0 0' * (wcross_size_x * ring_scale + i) - '0 0.5 0' * (wcross_size_y * ring_scale + j), strcat("gfx/hud/rifle_ring_", ftos(bullets)), wcross_size * ring_scale, wcross_color, wcross_alpha, DRAWFLAG_NORMAL);
 656                             drawpic(wcross_origin - '0.5 0 0' * (wcross_size_x + i) - '0 0.5 0' * (wcross_size_y + j), wcross_name, wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL);
 657                                                 }
 658                 }
 659                 else
 660                 {
 661                                         if (bullets)
 662                                                 drawpic(wcross_origin - '0.5 0 0' * (wcross_size_x * ring_scale) - '0 0.5 0' * (wcross_size_y * ring_scale), strcat("gfx/hud/rifle_ring_", ftos(bullets)), wcross_size * ring_scale, wcross_color, wcross_alpha, DRAWFLAG_NORMAL);
 663                     drawpic(wcross_origin - '0.5 0 0' * (wcross_size_x) - '0 0.5 0' * ( wcross_size_y), wcross_name, wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL);
 664                 }
 665             }
 666         }
 667     }
 668
 669         if(NextFrameCommand)
 670         {
 671                 localcmd("\n", NextFrameCommand, "\n");
 672                 NextFrameCommand = string_null;
 673         }
 674
 675         // we must do this check AFTER a frame was rendered, or it won't work
 676         if(cs_project_is_b0rked == 0)
 677         {
 678                 string w0, h0;
 679                 w0 = cvar_string("vid_conwidth");
 680                 h0 = cvar_string("vid_conheight");
 681                 //R_SetView(VF_VIEWPORT, '0 0 0', '640 480 0');
 682                 //R_SetView(VF_FOV, '90 90 0');
 683                 R_SetView(VF_ORIGIN, '0 0 0');
 684                 R_SetView(VF_ANGLES, '0 0 0');
 685                 R_SetView(VF_PERSPECTIVE, 1);
 686                 makevectors('0 0 0');
 687                 vector v1, v2;
 688                 cvar_set("vid_conwidth", "800");
 689                 cvar_set("vid_conheight", "600");
 690                 v1 = cs_project(v_forward);
 691                 cvar_set("vid_conwidth", "640");
 692                 cvar_set("vid_conheight", "480");
 693                 v2 = cs_project(v_forward);
 694                 if(v1 == v2)
 695                         cs_project_is_b0rked = 1;
 696                 else
 697                         cs_project_is_b0rked = -1;
 698                 cvar_set("vid_conwidth", w0);
 699                 cvar_set("vid_conheight", h0);
 700         }
 701 }
 702
 703 void Sbar_Draw();
 704 void CSQC_spider_HUD()
 705 {
 706     float rockets,reload,heat,hp,shield,i;
 707     vector p,pp;
 708
 709     rockets = getstati(STAT_SPIDERBOT_ROCKETS);
 710     heat    = min(getstatf(STAT_SPIDERBOT_HEAT),1);
 711     reload  = min(getstatf(STAT_SPIDERBOT_RELOAD),1);
 712     hp      = min(getstatf(STAT_SPIDERBOT_HEALTH),1);
 713     shield  = min(getstatf(STAT_SPIDERBOT_SHIELD),1);
 714
 715     // Draw health bar
 716     p = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
 717     p = p + '0 1 0' * vid_conheight - '0 32 0';
 718     //pp = ('0 1 0' * hp) + ('1 0 0' * (1-hp));
 719     drawfill(p, '256 0 0' * shield + '0 8 0' , '0.5 0.5 1', 0.75, DRAWFLAG_NORMAL);
 720     p_y += 8;
 721     drawfill(p, '256 0 0' * hp + '0 8 0' , '0 1 0', 0.75, DRAWFLAG_NORMAL);
 722     p_x += 256 * hp;
 723     drawfill(p, '256 0 0' * (1-hp) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
 724
 725     // Draw minigun heat indicator
 726     p = '0.5 0 0' * (vid_conwidth - 256);
 727     p = p + '0 1 0' * vid_conheight - '0 34  0';
 728     drawfill(p, '256 0 0' * (1-heat) + '0 2 0' ,'0 0 1', 0.5, DRAWFLAG_NORMAL);
 729     p_x += 256 * (1-heat);
 730     drawfill(p, '256 0 0' * heat  + '0 2 0' , '1 0 0', 0.5, DRAWFLAG_NORMAL);
 731
 732     // Draw rocket icons for loaded/empty tubes.
 733     pp = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
 734     pp += '0 1 0' * vid_conheight - '0 64 0';
 735     for(i = 0; i < 8; ++i)
 736     {
 737         p = pp + '1 0 0' * (rkt_size * i);
 738         if(rockets == 8)
 739         {
 740             if(floor(reload * 8) == i)
 741             {
 742                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 0 0' + '0 1 0' * ((reload*8)-i), 0.75 , DRAWFLAG_NORMAL);
 743             }
 744             else if(i < reload * 8)
 745                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 1 0', 0.75 , DRAWFLAG_NORMAL);
 746             else
 747                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0.5 0.5 0.5', 0.75, DRAWFLAG_NORMAL);
 748         }
 749         else
 750         {
 751             if(i < rockets)
 752                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 0 0', 0.25, DRAWFLAG_NORMAL);
 753             else
 754                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 1 0' * reload, 0.75, DRAWFLAG_NORMAL);
 755         }
 756     }
 757
 758         if (sb_showscores)
 759         {
 760                 Sbar_DrawScoreboard();
 761                 Sbar_DrawCenterPrint();
 762         }
 763
 764 }
 765 void CSQC_common_hud(void)
 766 {
 767
 768         // Sbar_SortFrags(); done in Sbar_Draw
 769     float hud;
 770     hud = getstati(STAT_HUD);
 771
 772     //hud = 10;
 773     switch(hud)
 774     {
 775         case HUD_NORMAL:
 776             Sbar_Draw();
 777             break;
 778
 779         case HUD_SPIDEBOT:
 780             CSQC_spider_HUD();
 781             break;
 782     }
 783 }
 784
 785
 786 // following vectors must be global to allow seamless switching between camera modes
 787 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
 788 void CSQC_Demo_Camera()
 789 {
 790         float speed, attenuation, dimensions;
 791         vector tmp, delta;
 792
 793         if( cvar("camera_reset") || !camera_mode )
 794         {
 795                 camera_offset = '0 0 0';
 796                 current_angles = '0 0 0';
 797                 camera_direction = '0 0 0';
 798                 camera_offset_z += 30;
 799                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
 800                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
 801                 current_origin = view_origin;
 802                 current_camera_offset  = camera_offset;
 803                 cvar_set("camera_reset", "0");
 804                 camera_mode = CAMERA_CHASE;
 805         }
 806
 807         // Camera angles
 808         if( camera_roll )
 809                 mouse_angles_z += camera_roll * cvar("camera_speed_roll");
 810
 811         if(cvar("camera_look_player"))
 812         {
 813                 local vector dir;
 814                 local float n;
 815
 816                 dir = normalize(view_origin - current_position);
 817                 n = mouse_angles_z;
 818                 mouse_angles = vectoangles(dir);
 819                 mouse_angles_x = mouse_angles_x * -1;
 820                 mouse_angles_z = n;
 821         }
 822         else
 823         {
 824                 tmp = getmousepos() * 0.1;
 825                 if(vlen(tmp)>cvar("camera_mouse_treshold"))
 826                 {
 827                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
 828                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
 829                 }
 830         }
 831
 832         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
 833         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
 834         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
 835         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
 836
 837         // Fix difference when angles don't have the same sign
 838         delta = '0 0 0';
 839         if(mouse_angles_y < -60 && current_angles_y > 60)
 840                 delta = '0 360 0';
 841         if(mouse_angles_y > 60 && current_angles_y < -60)
 842                 delta = '0 -360 0';
 843
 844         if(cvar("camera_look_player"))
 845                 attenuation = cvar("camera_look_attenuation");
 846         else
 847                 attenuation = cvar("camera_speed_attenuation");
 848
 849         attenuation = 1 / max(1, attenuation);
 850         current_angles += (mouse_angles - current_angles + delta) * attenuation;
 851
 852         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
 853         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
 854         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
 855         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
 856
 857         // Camera position
 858         tmp = '0 0 0';
 859         dimensions = 0;
 860
 861         if( camera_direction_x )
 862         {
 863                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
 864                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
 865                 if( cvar("camera_forward_follows") && !cvar("camera_look_player") )
 866                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
 867                 ++dimensions;
 868         }
 869
 870         if( camera_direction_y )
 871         {
 872                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
 873                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
 874                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
 875                 ++dimensions;
 876         }
 877
 878         if( camera_direction_z )
 879         {
 880                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
 881                 ++dimensions;
 882         }
 883
 884         if(cvar("camera_free"))
 885                 speed = cvar("camera_speed_free");
 886         else
 887                 speed = cvar("camera_speed_chase");
 888
 889         if(dimensions)
 890         {
 891                 speed = speed * sqrt(1 / dimensions);
 892                 camera_offset += tmp * speed;
 893         }
 894
 895         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
 896
 897         // Camera modes
 898         if( cvar("camera_free") )
 899         {
 900                 if ( camera_mode == CAMERA_CHASE )
 901                 {
 902                         current_camera_offset = current_origin + current_camera_offset;
 903                         camera_offset = current_origin + camera_offset;
 904                 }
 905
 906                 camera_mode = CAMERA_FREE;
 907                 current_position = current_camera_offset;
 908         }
 909         else
 910         {
 911                 if ( camera_mode == CAMERA_FREE )
 912                 {
 913                         current_origin = view_origin;
 914                         camera_offset = camera_offset - current_origin;
 915                         current_camera_offset = current_camera_offset - current_origin;
 916                 }
 917
 918                 camera_mode = CAMERA_CHASE;
 919
 920                 if(cvar("camera_chase_smoothly"))
 921                         current_origin += (view_origin - current_origin) * attenuation;
 922                 else
 923                         current_origin = view_origin;
 924
 925                 current_position = current_origin + current_camera_offset;
 926         }
 927
 928         R_SetView(VF_ANGLES, current_angles);
 929         R_SetView(VF_ORIGIN, current_position);
 930 }