data/qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------
   2 // BEGIN REQUIRED CSQC FUNCTIONS
   3 //include "main.qh"
   4
   5 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
   6
   7 void cvar_clientsettemp(string cv, string val)
   8 {
   9         entity e;
  10         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
  11                 if(e.netname == cv)
  12                         goto saved;
  13         e = spawn();
  14         e.classname = "saved_cvar_value";
  15         e.netname = strzone(cv);
  16         e.message = strzone(cvar_string(cv));
  17 :saved
  18         cvar_set(cv, val);
  19 }
  20
  21 void cvar_clientsettemp_restore()
  22 {
  23         entity e;
  24         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
  25                         cvar_set(e.netname, e.message);
  26 }
  27
  28 void() menu_show_error =
  29 {
  30         drawstring('0 200 0', "ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!", '8 8 0', '1 0 0', 1, 0);
  31 };
  32
  33 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  34 // Useful for precaching things
  35
  36 void() menu_sub_null =
  37 {
  38 };
  39
  40 #ifdef USE_FTE
  41 float __engine_check;
  42 #endif
  43
  44 string forcefog;
  45 string cl_announcer_prev;
  46 void WaypointSprite_Load();
  47 void CSQC_Init(void)
  48 {
  49 #ifdef USE_FTE
  50 #pragma target ID
  51         __engine_check = checkextension("DP_SV_WRITEPICTURE");
  52         if(!__engine_check)
  53         {
  54                 print("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n");
  55                 localcmd("\ndisconnect\n");
  56                 return;
  57         }
  58 #pragma target FTE
  59 #endif
  60
  61         check_unacceptable_compiler_bugs();
  62
  63         float i;
  64         CSQC_CheckEngine();
  65
  66         binddb = db_create();
  67         tempdb = db_create();
  68         ClientProgsDB = db_load("client.db");
  69         compressShortVector_init();
  70
  71         drawfont = 0;
  72         menu_visible = FALSE;
  73         menu_show = menu_show_error;
  74         menu_action = menu_sub_null;
  75
  76         for(i = 0; i < 255; ++i)
  77                 if(getplayerkey(i, "viewentity") == "")
  78                         break;
  79         maxclients = i;
  80
  81         //ctf_temp_1 = "";
  82         // localcmd("alias order \"cmd order $*\""); enable if ctf-command thingy is used
  83         //registercmd("ctf_menu");
  84         registercmd("ons_map");
  85         //registercmd("menu_action");
  86
  87         registercmd("+button3");
  88         registercmd("-button3");
  89         registercmd("+button4");
  90         registercmd("-button4");
  91         registercmd("+showaccuracy");registercmd("-showaccuracy");
  92
  93 #ifndef CAMERATEST
  94         if(isdemo())
  95         {
  96 #endif
  97                 registercmd("+forward");registercmd("-forward");
  98                 registercmd("+back");registercmd("-back");
  99                 registercmd("+moveup");registercmd("-moveup");
 100                 registercmd("+movedown");registercmd("-movedown");
 101                 registercmd("+moveright");registercmd("-moveright");
 102                 registercmd("+moveleft");registercmd("-moveleft");
 103                 registercmd("+roll_right");registercmd("-roll_right");
 104                 registercmd("+roll_left");registercmd("-roll_left");
 105 #ifndef CAMERATEST
 106         }
 107 #endif
 108         registercvar("sbar_usecsqc", "1");
 109         registercvar("sbar_columns", "default", CVAR_SAVE);
 110
 111         gametype = 0;
 112
 113         // sbar_fields uses strunzone on the titles!
 114         for(i = 0; i < MAX_SBAR_FIELDS; ++i)
 115                 sbar_title[i] = strzone("(null)");
 116
 117         postinit = false;
 118
 119         calledhooks = 0;
 120
 121         teams = Sort_Spawn();
 122         players = Sort_Spawn();
 123
 124         GetTeam(COLOR_SPECTATOR, true); // add specs first
 125
 126         cvar_clientsettemp("_supports_weaponpriority", "1");
 127
 128         RegisterWeapons();
 129
 130         WaypointSprite_Load();
 131
 132         // precaches
 133         Projectile_Precache();
 134         GibSplash_Precache();
 135         Casings_Precache();
 136         DamageInfo_Precache();
 137         if(cvar_string("cl_announcer") != cl_announcer_prev) {
 138                 Announcer_Precache();
 139                 if(cl_announcer_prev)
 140                         strunzone(cl_announcer_prev);
 141                 cl_announcer_prev = strzone(cvar_string("cl_announcer"));
 142         }
 143         Tuba_Precache();
 144
 145 #ifdef UID
 146         {
 147                 // find the user ID
 148                 string uid;
 149                 registercvar("_cl_userid", "", CVAR_SAVE);
 150                 uid = cvar_string("_cl_userid");
 151                 if(strlen(uid) < 16)
 152                 {
 153                         uid = "";
 154                         for(i = 0; i < 4; ++i)
 155                                 uid = strcat(uid, substring(ftos(floor(10000 + random() * 10000)), 1, -1));
 156                 }
 157                 cvar_set("_cl_userid", uid);
 158                 localcmd(strcat("\ncmd uid ", uid, "\n"));
 159         }
 160 #endif
 161
 162         get_mi_min_max_texcoords(1); // try the CLEVER way first
 163         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 164         shortmapname = mi_shortname;
 165
 166         if(precache_pic(minimapname) == "")
 167         {
 168                 // but maybe we have a non-clever minimap
 169                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 170                 if(precache_pic(minimapname) == "")
 171                         minimapname = ""; // FAIL
 172                 else
 173                         get_mi_min_max_texcoords(0); // load new texcoords
 174         }
 175
 176         mi_center = (mi_min + mi_max) * 0.5;
 177         mi_scale = mi_max - mi_min;
 178         minimapname = strzone(minimapname);
 179 }
 180
 181 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 182 void CSQC_Shutdown(void)
 183 {
 184 #ifdef USE_FTE
 185 #pragma TARGET id
 186         if(!__engine_check)
 187                 return 0;
 188 #pragma TARGET fte
 189 #endif
 190
 191         remove(teams);
 192         remove(players);
 193         db_close(binddb);
 194         db_close(tempdb);
 195         db_save(ClientProgsDB, "client.db");
 196         db_close(ClientProgsDB);
 197
 198         cvar_clientsettemp_restore();
 199
 200         if(camera_active)
 201                 cvar_set("chase_active",ftos(chase_active_backup));
 202
 203         if not(isdemo())
 204         {
 205                 if not(calledhooks & HOOK_START)
 206                         localcmd("\n_cl_hook_gamestart nop;");
 207                 if not(calledhooks & HOOK_END)
 208                         localcmd("\ncl_hook_gameend;");
 209         }
 210 }
 211
 212 .float has_team;
 213 float SetTeam(entity o, float Team)
 214 {
 215         entity tm;
 216         if(teamplay)
 217         {
 218                 switch(Team)
 219                 {
 220                         case -1:
 221                         case COLOR_TEAM1:
 222                         case COLOR_TEAM2:
 223                         case COLOR_TEAM3:
 224                         case COLOR_TEAM4:
 225                                 break;
 226                         default:
 227                                 if(GetTeam(Team, false) == NULL)
 228                                 {
 229                                         print("trying to switch to unsupported team ", ftos(Team), "\n");
 230                                         Team = COLOR_SPECTATOR;
 231                                 }
 232                                 break;
 233                 }
 234         }
 235         else
 236         {
 237                 switch(Team)
 238                 {
 239                         case -1:
 240                         case 0:
 241                                 break;
 242                         default:
 243                                 if(GetTeam(Team, false) == NULL)
 244                                 {
 245                                         print("trying to switch to unsupported team ", ftos(Team), "\n");
 246                                         Team = COLOR_SPECTATOR;
 247                                 }
 248                                 break;
 249                 }
 250         }
 251         if(Team == -1) // leave
 252         {
 253                 if(o.has_team)
 254                 {
 255                         //print("(DISCONNECT) leave team ", ftos(o.team), "\n");
 256                         tm = GetTeam(o.team, false);
 257                         tm.team_size -= 1;
 258                         o.has_team = 0;
 259                         return TRUE;
 260                 }
 261         }
 262         else
 263         {
 264                 if not(o.has_team)
 265                 {
 266                         //print("(CONNECT) enter team ", ftos(o.team), "\n");
 267                         o.team = Team;
 268                         tm = GetTeam(Team, true);
 269                         tm.team_size += 1;
 270                         o.has_team = 1;
 271                         return TRUE;
 272                 }
 273                 else if(Team != o.team)
 274                 {
 275                         //print("(CHANGE) leave team ", ftos(o.team), "\n");
 276                         tm = GetTeam(o.team, false);
 277                         tm.team_size -= 1;
 278                         o.team = Team;
 279                         //print("(CHANGE) enter team ", ftos(o.team), "\n");
 280                         tm = GetTeam(Team, true);
 281                         tm.team_size += 1;
 282                         return TRUE;
 283                 }
 284         }
 285         return FALSE;
 286 }
 287
 288 void Playerchecker_Think()
 289 {
 290         float i;
 291         entity e;
 292         for(i = 0; i < maxclients; ++i)
 293         {
 294                 e = playerslots[i];
 295                 if(GetPlayerName(i) == "")
 296                 {
 297                         if(e.sort_prev)
 298                         {
 299                                 //print("playerchecker: KILL KILL KILL\n");
 300                                 // player disconnected
 301                                 SetTeam(e, -1);
 302                                 RemovePlayer(e);
 303                                 e.sort_prev = world;
 304                                 //e.gotscores = 0;
 305                         }
 306                 }
 307                 else
 308                 {
 309                         if not(e.sort_prev)
 310                         {
 311                                 //print("playerchecker: SPAWN SPAWN SPAWN\n");
 312                                 // player connected
 313                                 if not(e)
 314                                         playerslots[i] = e = spawn();
 315                                 e.sv_entnum = i;
 316                                 e.ping = 0;
 317                                 e.ping_packetloss = 0;
 318                                 e.ping_movementloss = 0;
 319                                 //e.gotscores = 0; // we might already have the scores...
 320                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with Sbar_UpdatePlayerTeams
 321                                 RegisterPlayer(e);
 322                                 Sbar_UpdatePlayerPos(e);
 323                         }
 324                 }
 325         }
 326         self.nextthink = time + 0.2;
 327 }
 328
 329 void Porto_Init();
 330 void TrueAim_Init();
 331 void PostInit(void)
 332 {
 333         print(strcat("PostInit\n    maxclients = ", ftos(maxclients), "\n"));
 334         localcmd(strcat("\nsbar_columns_set ", cvar_string("sbar_columns"), ";\n"));
 335
 336         entity playerchecker;
 337         playerchecker = spawn();
 338         playerchecker.think = Playerchecker_Think;
 339         playerchecker.nextthink = time + 0.2;
 340
 341         Porto_Init();
 342         TrueAim_Init();
 343
 344         postinit = true;
 345 }
 346
 347 // CSQC_ConsoleCommand : Used to parse commands in the console that have been registered with the "registercmd" function
 348 // Return value should be 1 if CSQC handled the command, otherwise return 0 to have the engine handle it.
 349 float button_zoom;
 350 void Cmd_Sbar_SetFields(float);
 351 void Cmd_Sbar_Help(float);
 352 float CSQC_ConsoleCommand(string strMessage)
 353 {
 354         float argc;
 355         // Tokenize String
 356         //argc = tokenize(strMessage);
 357         argc = tokenize_console(strMessage);
 358
 359         // Acquire Command
 360         local string strCmd;
 361         strCmd = argv(0);
 362
 363         if(strCmd == "+button4") { // zoom
 364                 // return false, because the message shall be sent to the server anyway (for demos/speccing)
 365                 if(ignore_plus_zoom)
 366                 {
 367                         --ignore_plus_zoom;
 368                         return false;
 369                 }
 370                 button_zoom = 1;
 371                 return true;
 372         } else if(strCmd == "-button4") { // zoom
 373                 if(ignore_minus_zoom)
 374                 {
 375                         --ignore_minus_zoom;
 376                         return false;
 377                 }
 378                 button_zoom = 0;
 379                 return true;
 380         } else if(strCmd == "+button3") { // secondary
 381                 button_attack2 = 1;
 382                 return false;
 383         } else if(strCmd == "-button3") { // secondary
 384                 button_attack2 = 0;
 385                 return false;
 386         } else if(strCmd == "+showscores") {
 387                 sb_showscores = true;
 388                 return true;
 389         } else if(strCmd == "-showscores") {
 390                 sb_showscores = false;
 391                 return true;
 392         } else if(strCmd == "+showaccuracy") {
 393                 sb_showaccuracy = true;
 394                 return true;
 395         } else if(strCmd == "-showaccuracy") {
 396                 sb_showaccuracy = false;
 397                 return true;
 398         }
 399
 400         if(camera_active)
 401         if(strCmd == "+forward" || strCmd == "-back") {
 402                 ++camera_direction_x;
 403                 return true;
 404         } else if(strCmd == "-forward" || strCmd == "+back") {
 405                 --camera_direction_x;
 406                 return true;
 407         } else if(strCmd == "+moveright" || strCmd == "-moveleft") {
 408                 --camera_direction_y;
 409                 return true;
 410         } else if(strCmd == "-moveright" || strCmd == "+moveleft") {
 411                 ++camera_direction_y;
 412                 return true;
 413         } else if(strCmd == "+moveup" || strCmd == "-movedown") {
 414                 ++camera_direction_z;
 415                 return true;
 416         } else if(strCmd == "-moveup" || strCmd == "+movedown") {
 417                 --camera_direction_z;
 418                 return true;
 419         } else if(strCmd == "+roll_right" || strCmd == "-roll_left") {
 420                 ++camera_roll;
 421                 return true;
 422         } else if(strCmd == "+roll_left" || strCmd == "-roll_right") {
 423                 --camera_roll;
 424                 return true;
 425         }
 426
 427         return false;
 428 }
 429
 430 .vector view_ofs;
 431 entity debug_shotorg;
 432 void ShotOrg_Draw()
 433 {
 434         self.origin = view_origin + view_forward * self.view_ofs_x + view_right * self.view_ofs_y + view_up * self.view_ofs_z;
 435         self.angles = view_angles;
 436         self.angles_x = -self.angles_x;
 437         if not(self.cnt)
 438                 R_AddEntity(self);
 439 }
 440 void ShotOrg_Draw2D()
 441 {
 442         vector coord2d_topleft, coord2d_topright, coord2d;
 443         string s;
 444         vector fs;
 445
 446         s = vtos(self.view_ofs);
 447         s = substring(s, 1, strlen(s) - 2);
 448         if(tokenize_console(s) == 3)
 449                 s = strcat(argv(0), " ", argv(1), " ", argv(2));
 450
 451         coord2d_topleft = project_3d_to_2d(self.origin + view_up * 4 - view_right * 4);
 452         coord2d_topright = project_3d_to_2d(self.origin + view_up * 4 + view_right * 4);
 453
 454         fs = '1 1 0' * ((coord2d_topright_x - coord2d_topleft_x) / stringwidth(s, FALSE, '8 8 0'));
 455
 456         coord2d = coord2d_topleft;
 457         if(fs_x < 8)
 458         {
 459                 coord2d_x += (coord2d_topright_x - coord2d_topleft_x) * (1 - 8 / fs_x) * 0.5;
 460                 fs = '8 8 0';
 461         }
 462         coord2d_y -= fs_y;
 463         coord2d_z = 0;
 464         drawstring(coord2d, s, fs, '1 1 1', 1, 0);
 465 }
 466
 467 void ShotOrg_Spawn()
 468 {
 469         debug_shotorg = spawn();
 470         debug_shotorg.draw = ShotOrg_Draw;
 471         debug_shotorg.draw2d = ShotOrg_Draw2D;
 472         debug_shotorg.renderflags = RF_VIEWMODEL;
 473         debug_shotorg.effects = EF_FULLBRIGHT;
 474         precache_model("models/shotorg_adjuster.md3");
 475         setmodel(debug_shotorg, "models/shotorg_adjuster.md3");
 476         debug_shotorg.scale = 2;
 477         debug_shotorg.view_ofs = '25 8 -8';
 478 }
 479
 480 void DrawDebugModel()
 481 {
 482         if(time - floor(time) > 0.5)
 483         {
 484                 PolyDrawModel(self);
 485         }
 486         else
 487         {
 488                 self.renderflags = 0;
 489                 R_AddEntity(self);
 490         }
 491 }
 492
 493 void GameCommand(string msg)
 494 {
 495         string s;
 496         float argc;
 497         entity e;
 498         argc = tokenize_console(msg);
 499
 500         if(argv(0) == "help" || argc == 0)
 501         {
 502                 print("Usage: cl_cmd COMMAND..., where possible commands are:\n");
 503                 print("  settemp cvar value\n");
 504                 print("  radar\n");
 505                 print("  sbar_columns_set ...\n");
 506                 print("  sbar_columns_help\n");
 507                 GameCommand_Generic("help");
 508                 return;
 509         }
 510
 511         if(GameCommand_Generic(msg))
 512                 return;
 513
 514         string cmd;
 515         cmd = argv(0);
 516         if(cmd == "mv_download") {
 517                 Cmd_MapVote_MapDownload(argc);
 518         }
 519         else if(cmd == "settemp") {
 520                 cvar_clientsettemp(argv(1), argv(2));
 521         }
 522         else if(cmd == "radar") {
 523                 ons_showmap = !ons_showmap;
 524         }
 525         else if(cmd == "sbar_columns_set") {
 526                 Cmd_Sbar_SetFields(argc);
 527         }
 528         else if(cmd == "sbar_columns_help") {
 529                 Cmd_Sbar_Help(argc);
 530         }
 531 #ifdef BLURTEST
 532         else if(cmd == "blurtest") {
 533                 blurtest_time0 = time;
 534                 blurtest_time1 = time + stof(argv(1));
 535                 blurtest_radius = stof(argv(2));
 536                 blurtest_power = stof(argv(3));
 537         }
 538 #endif
 539         else if(cmd == "shotorg_move") {
 540                 if(!debug_shotorg)
 541                         ShotOrg_Spawn();
 542                 else
 543                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stov(argv(1));
 544                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 545         }
 546         else if(cmd == "shotorg_movez") {
 547                 if(!debug_shotorg)
 548                         ShotOrg_Spawn();
 549                 else
 550                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stof(argv(1)) * (debug_shotorg.view_ofs * (1 / debug_shotorg.view_ofs_x)); // closer/farther, same xy pos
 551                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 552         }
 553         else if(cmd == "shotorg_set") {
 554                 if(!debug_shotorg)
 555                         ShotOrg_Spawn();
 556                 else
 557                         debug_shotorg.view_ofs = stov(argv(1));
 558                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 559         }
 560         else if(cmd == "shotorg_setz") {
 561                 if(!debug_shotorg)
 562                         ShotOrg_Spawn();
 563                 else
 564                         debug_shotorg.view_ofs = debug_shotorg.view_ofs * (stof(argv(1)) / debug_shotorg.view_ofs_x); // closer/farther, same xy pos
 565                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 566         }
 567         else if(cmd == "shotorg_toggle_hide") {
 568                 if(debug_shotorg)
 569                 {
 570                         debug_shotorg.cnt = !debug_shotorg.cnt;
 571                 }
 572         }
 573         else if(cmd == "shotorg_end") {
 574                 if(debug_shotorg)
 575                 {
 576                         print(vtos(debug_shotorg.view_ofs), "\n");
 577                         remove(debug_shotorg);
 578                         debug_shotorg = world;
 579                 }
 580                 localcmd("sv_cmd debug_shotorg\n");
 581         }
 582         else if(cmd == "sendcvar") {
 583                 s = cvar_string(argv(1));
 584                 if(argv(1) == "cl_weaponpriority")
 585                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 1);
 586                 else if(substring(argv(1), 0, 17) == "cl_weaponpriority" && strlen(argv(1)) == 18)
 587                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 0);
 588                 localcmd("cmd sentcvar ", argv(1), " \"", s, "\"\n");
 589         }
 590         else if(cmd == "spawn") {
 591                 s = argv(1);
 592                 e = spawn();
 593                 precache_model(s);
 594                 setmodel(e, s);
 595                 setorigin(e, view_origin);
 596                 e.angles = view_angles;
 597                 e.draw = DrawDebugModel;
 598                 e.classname = "debugmodel";
 599         }
 600         else
 601         {
 602                 print("Invalid command. For a list of supported commands, try cl_cmd help.\n");
 603         }
 604
 605         return;
 606 }
 607
 608 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 609 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 610 // All keys are in ascii.
 611 // bInputType = 0 is key pressed, 1 is key released, 2 is mouse input.
 612 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 613 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 614 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 615 {
 616         local float bSkipKey;
 617         bSkipKey = false;
 618
 619         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 620                 return true;
 621
 622         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 623                 return true;
 624
 625         if(menu_visible)
 626                 if(menu_action(bInputType, nPrimary, nSecondary))
 627                         return TRUE;
 628         return bSkipKey;
 629 }
 630
 631 // END REQUIRED CSQC FUNCTIONS
 632 // --------------------------------------------------------------------------
 633
 634 // --------------------------------------------------------------------------
 635 // BEGIN OPTIONAL CSQC FUNCTIONS
 636 void Ent_ReadEntCS()
 637 {
 638         InterpolateOrigin_Undo();
 639
 640         self.classname = "entcs_receiver";
 641         self.sv_entnum = ReadByte() - 1;
 642         self.origin_x = ReadShort();
 643         self.origin_y = ReadShort();
 644         self.origin_z = ReadShort();
 645         self.angles_y = ReadByte() * 360.0 / 256;
 646         self.origin_z = self.angles_x = self.angles_z = 0;
 647
 648         InterpolateOrigin_Note();
 649 }
 650
 651 void Ent_Remove();
 652
 653 void Ent_RemovePlayerScore()
 654 {
 655         float i;
 656
 657         if(self.owner)
 658         {
 659                 SetTeam(self.owner, -1);
 660                 self.owner.gotscores = 0;
 661                 for(i = 0; i < MAX_SCORE; ++i)
 662                         self.owner.(scores[i]) = 0; // clear all scores
 663         }
 664 }
 665
 666 void Ent_ReadPlayerScore()
 667 {
 668         float i, n;
 669         float isNew;
 670         entity o;
 671
 672         // damnit -.- don't want to go change every single .sv_entnum in sbar.qc AGAIN
 673         // (no I've never heard of M-x replace-string, sed, or anything like that)
 674         isNew = !self.owner; // workaround for DP bug
 675         n = ReadByte()-1;
 676
 677 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 678         if(!isNew && n != self.sv_entnum)
 679         {
 680                 print("A CSQC entity changed its owner!\n");
 681                 isNew = true;
 682                 Ent_Remove();
 683                 self.enttype = ENT_CLIENT_SCORES;
 684         }
 685 #endif
 686
 687         self.sv_entnum = n;
 688
 689         if not(playerslots[self.sv_entnum])
 690                 playerslots[self.sv_entnum] = spawn();
 691         o = self.owner = playerslots[self.sv_entnum];
 692         o.sv_entnum = self.sv_entnum;
 693         o.gotscores = 1;
 694
 695         //if not(o.sort_prev)
 696         //      RegisterPlayer(o);
 697         //playerchecker will do this for us later, if it has not already done so
 698
 699         float sf, lf;
 700 #if MAX_SCORE <= 8
 701         sf = ReadByte();
 702         lf = ReadByte();
 703 #else
 704         sf = ReadShort();
 705         lf = ReadShort();
 706 #endif
 707         float p;
 708         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 709                 if(sf & p)
 710                 {
 711                         if(lf & p)
 712                                 o.(scores[i]) = ReadInt24_t();
 713                         else
 714                                 o.(scores[i]) = ReadChar();
 715                 }
 716
 717         if(o.sort_prev)
 718                 Sbar_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 719
 720         self.entremove = Ent_RemovePlayerScore;
 721 }
 722
 723 void Ent_ReadTeamScore()
 724 {
 725         float i;
 726         entity o;
 727
 728         self.team = ReadByte();
 729         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 730
 731         float sf, lf;
 732 #if MAX_TEAMSCORE <= 8
 733         sf = ReadByte();
 734         lf = ReadByte();
 735 #else
 736         sf = ReadShort();
 737         lf = ReadShort();
 738 #endif
 739         float p;
 740         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 741                 if(sf & p)
 742                 {
 743                         if(lf & p)
 744                                 o.(teamscores[i]) = ReadInt24_t();
 745                         else
 746                                 o.(teamscores[i]) = ReadChar();
 747                 }
 748
 749         Sbar_UpdateTeamPos(o);
 750 }
 751
 752 void Net_Reset()
 753 {
 754 }
 755
 756 void Ent_ClientData()
 757 {
 758         float f;
 759         float newspectatee_status;
 760
 761         f = ReadByte();
 762
 763         sb_showscores_force = (f & 1);
 764
 765         if(f & 2)
 766         {
 767                 newspectatee_status = ReadByte();
 768                 if(newspectatee_status == player_localentnum)
 769                         newspectatee_status = -1; // observing
 770         }
 771         else
 772                 newspectatee_status = 0;
 773
 774         spectatorbutton_zoom = (f & 4);
 775
 776         if(f & 8)
 777         {
 778                 angles_held_status = 1;
 779                 angles_held_x = ReadAngle();
 780                 angles_held_y = ReadAngle();
 781                 angles_held_z = 0;
 782         }
 783         else
 784                 angles_held_status = 0;
 785
 786         if(newspectatee_status != spectatee_status)
 787         {
 788                 float i;
 789                 // clear the weapon accuracy stats
 790                 for(i = WEP_FIRST; i <= WEP_LAST; ++i) {
 791                         weapon_hits[i] = 0;
 792                         weapon_fired[i] = 0;
 793                 }
 794
 795                 // clear race stuff
 796                 race_laptime = 0;
 797                 race_checkpointtime = 0;
 798         }
 799         spectatee_status = newspectatee_status;
 800 }
 801
 802 void Ent_Nagger()
 803 {
 804         float nags, i, j, b, f;
 805
 806         nags = ReadByte();
 807
 808         if(nags & 128)
 809         {
 810                 if(vote_called_vote)
 811                         strunzone(vote_called_vote);
 812                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 813         }
 814
 815         if(nags & 1)
 816         {
 817                 for(j = 0; j < maxclients; ++j)
 818                         if(playerslots[j])
 819                                 playerslots[j].ready = 1;
 820                 for(i = 1; i <= maxclients; i += 8)
 821                 {
 822                         f = ReadByte();
 823                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 824                                 if not(f & b)
 825                                         if(playerslots[j])
 826                                                 playerslots[j].ready = 0;
 827                 }
 828         }
 829
 830         ready_waiting = (nags & 1);
 831         ready_waiting_for_me = (nags & 2);
 832         vote_waiting = (nags & 4);
 833         vote_waiting_for_me = (nags & 8);
 834         warmup_stage = (nags & 16);
 835 }
 836
 837 void Ent_RandomSeed()
 838 {
 839         float s;
 840         prandom_debug();
 841         s = ReadShort();
 842         psrandom(s);
 843 }
 844
 845 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 846 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 847 void Ent_RadarLink();
 848 void Ent_Init();
 849 void Ent_ScoresInfo();
 850 void(float bIsNewEntity) CSQC_Ent_Update =
 851 {
 852         float t;
 853         float savetime;
 854         t = ReadByte();
 855
 856         // set up the "time" global for received entities to be correct for interpolation purposes
 857         savetime = time;
 858         if(servertime)
 859         {
 860                 time = servertime;
 861         }
 862         else
 863         {
 864                 serverprevtime = time;
 865                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 866                 time = serverprevtime + serverdeltatime;
 867         }
 868
 869 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 870         if(self.enttype)
 871                 if(t != self.enttype)
 872                 {
 873                         print("A CSQC entity changed its type!\n");
 874                         Ent_Remove();
 875                         bIsNewEntity = 1;
 876                 }
 877 #endif
 878         self.enttype = t;
 879         switch(t)
 880         {
 881                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 882                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 883                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 884                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 885                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 886                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 887                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 888                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 889                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 890                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 891                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 892                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 893                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 894                 case ENT_CLIENT_INIT: Ent_Init(); break;
 895                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 896                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 897                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 898                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 899                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 900                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 901                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 902                 default:
 903                         error(strcat("unknown entity type in CSQC_Ent_Update: ", ftos(self.enttype), "\n"));
 904                         break;
 905         }
 906
 907         time = savetime;
 908 };
 909 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 910 // used when an entity changes its type. For an entity that someone interacts
 911 // with others, make sure it can no longer do so.
 912 void Ent_Remove()
 913 {
 914         if(self.entremove)
 915                 self.entremove();
 916
 917         self.enttype = 0;
 918         self.classname = "";
 919         self.draw = menu_sub_null;
 920         self.entremove = menu_sub_null;
 921         // TODO possibly set more stuff to defaults
 922 }
 923 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 924 void CSQC_Ent_Remove()
 925 {
 926         if(self.enttype)
 927                 Ent_Remove();
 928         remove(self);
 929 }
 930
 931 void Gamemode_Init()
 932 {
 933         if(gametype == GAME_ONSLAUGHT) {
 934                 print(strcat("Using ", minimapname, " as minimap.\n"));
 935                 precache_pic("gfx/ons-cp-neutral.tga");
 936                 precache_pic("gfx/ons-cp-red.tga");
 937                 precache_pic("gfx/ons-cp-blue.tga");
 938                 precache_pic("gfx/ons-frame.tga");
 939                 precache_pic("gfx/ons-frame-team.tga");
 940         } else if(gametype == GAME_KEYHUNT) {
 941                 precache_pic("gfx/sb_key_carrying");
 942                 precache_pic("gfx/sb_key_carrying_outline");
 943         }
 944
 945         if not(isdemo())
 946         {
 947                 localcmd("\n_cl_hook_gamestart ", GametypeNameFromType(gametype), ";");
 948                 calledhooks |= HOOK_START;
 949         }
 950 }
 951 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 952 void CSQC_Parse_StuffCmd(string strMessage)
 953 {
 954         localcmd(strMessage);
 955 }
 956 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 957 void CSQC_Parse_Print(string strMessage)
 958 {
 959         print(ColorTranslateRGB(strMessage));
 960 }
 961
 962 // CSQC_Parse_CenterPrint : Provides the centerprint string in the first parameter that the server provided.
 963 void CSQC_Parse_CenterPrint(string strMessage)
 964 {
 965         centerprint(strMessage);
 966 }
 967
 968 string notranslate_fogcmd1 = "\nfog ";
 969 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
 970 void Fog_Force()
 971 {
 972         // TODO somehow thwart prvm_globalset client ...
 973
 974         if(forcefog != "")
 975                 localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2));
 976 }
 977
 978 void Gamemode_Init();
 979 void Ent_ScoresInfo()
 980 {
 981         float i;
 982         self.classname = "ent_client_scores_info";
 983         gametype = ReadByte();
 984         for(i = 0; i < MAX_SCORE; ++i)
 985         {
 986                 scores_label[i] = strzone(ReadString());
 987                 scores_flags[i] = ReadByte();
 988         }
 989         for(i = 0; i < MAX_TEAMSCORE; ++i)
 990         {
 991                 teamscores_label[i] = strzone(ReadString());
 992                 teamscores_flags[i] = ReadByte();
 993         }
 994         Sbar_InitScores();
 995         Gamemode_Init();
 996 }
 997
 998 void Ent_Init()
 999 {
1000         self.classname = "ent_client_init";
1001
1002         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1003
1004         hook_shotorigin_x = ReadCoord();
1005         hook_shotorigin_y = ReadCoord();
1006         hook_shotorigin_z = ReadCoord();
1007
1008         if(forcefog)
1009                 strunzone(forcefog);
1010         forcefog = strzone(ReadString());
1011
1012         armorblockpercent = ReadByte() / 255.0;
1013
1014         g_weaponswitchdelay = ReadByte() / 255.0;
1015
1016         if(!postinit)
1017                 PostInit();
1018 }
1019
1020 void Net_ReadRace()
1021 {
1022         float b;
1023
1024         b = ReadByte();
1025
1026         switch(b)
1027         {
1028                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1029                         race_checkpoint = ReadByte();
1030                         race_time = ReadInt24_t();
1031                         race_previousbesttime = ReadInt24_t();
1032                         if(race_previousbestname)
1033                                 strunzone(race_previousbestname);
1034                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1035
1036                         race_checkpointtime = time;
1037
1038                         if(race_checkpoint == 0 || race_checkpoint == 254)
1039                         {
1040                                 race_penaltyaccumulator = 0;
1041                                 race_laptime = time; // valid
1042                         }
1043
1044                         break;
1045
1046                 case RACE_NET_CHECKPOINT_CLEAR:
1047                         race_laptime = 0;
1048                         race_checkpointtime = 0;
1049                         break;
1050
1051                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1052                         race_laptime = ReadCoord();
1053                         race_checkpointtime = -99999;
1054                         // fall through
1055                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1056                         race_nextcheckpoint = ReadByte();
1057
1058                         race_nextbesttime = ReadInt24_t();
1059                         if(race_nextbestname)
1060                                 strunzone(race_nextbestname);
1061                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1062                         break;
1063
1064                 case RACE_NET_CHECKPOINT_HIT_RACE:
1065                         race_mycheckpoint = ReadByte();
1066                         race_mycheckpointtime = time;
1067                         race_mycheckpointdelta = ReadInt24_t();
1068                         race_mycheckpointlapsdelta = ReadByte();
1069                         if(race_mycheckpointlapsdelta >= 128)
1070                                 race_mycheckpointlapsdelta -= 256;
1071                         if(race_mycheckpointenemy)
1072                                 strunzone(race_mycheckpointenemy);
1073                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1074                         break;
1075
1076                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1077                         race_othercheckpoint = ReadByte();
1078                         race_othercheckpointtime = time;
1079                         race_othercheckpointdelta = ReadInt24_t();
1080                         race_othercheckpointlapsdelta = ReadByte();
1081                         if(race_othercheckpointlapsdelta >= 128)
1082                                 race_othercheckpointlapsdelta -= 256;
1083                         if(race_othercheckpointenemy)
1084                                 strunzone(race_othercheckpointenemy);
1085                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1086                         break;
1087
1088                 case RACE_NET_PENALTY_RACE:
1089                         race_penaltyeventtime = time;
1090                         race_penaltytime = ReadShort();
1091                         //race_penaltyaccumulator += race_penaltytime;
1092                         if(race_penaltyreason)
1093                                 strunzone(race_penaltyreason);
1094                         race_penaltyreason = strzone(ReadString());
1095                         break;
1096
1097                 case RACE_NET_PENALTY_QUALIFYING:
1098                         race_penaltyeventtime = time;
1099                         race_penaltytime = ReadShort();
1100                         race_penaltyaccumulator += race_penaltytime;
1101                         if(race_penaltyreason)
1102                                 strunzone(race_penaltyreason);
1103                         race_penaltyreason = strzone(ReadString());
1104                         break;
1105
1106                 case RACE_NET_SERVER_RECORD:
1107                         race_server_record = ReadInt24_t();
1108                         break;
1109                 case RACE_NET_SPEED_AWARD:
1110                         race_speedaward = ReadInt24_t();
1111                         if(race_speedaward_holder)
1112                                 strunzone(race_speedaward_holder);
1113                         race_speedaward_holder = strzone(ReadString());
1114                         break;
1115                 case RACE_NET_SPEED_AWARD_BEST:
1116                         race_speedaward_alltimebest = ReadInt24_t();
1117                         if(race_speedaward_alltimebest_holder)
1118                                 strunzone(race_speedaward_alltimebest_holder);
1119                         race_speedaward_alltimebest_holder = strzone(ReadString());
1120                         break;
1121                 case RACE_NET_SERVER_RANKINGS:
1122                         float pos, prevpos, del;
1123                         pos = ReadShort();
1124                         prevpos = ReadShort();
1125                         del = ReadShort();
1126
1127                         // move other rankings out of the way
1128                         float i;
1129                         if (prevpos) {
1130                                 for (i=prevpos-1;i>pos-1;--i) {
1131                                         grecordtime[i] = grecordtime[i-1];
1132                                         if(grecordholder[i])
1133                                                 strunzone(grecordholder[i]);
1134                                         grecordholder[i] = strzone(grecordholder[i-1]);
1135                                 }
1136                         } else if (del) { // a record has been deleted by the admin
1137                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1138                                         if (i == RANKINGS_CNT-1) { // clear out last record
1139                                                 grecordtime[i] = 0;
1140                                                 if (grecordholder[i])
1141                                                         strunzone(grecordholder[i]);
1142                                                 grecordholder[i] = string_null;
1143                                         }
1144                                         else {
1145                                                 grecordtime[i] = grecordtime[i+1];
1146                                                 if (grecordholder[i])
1147                                                         strunzone(grecordholder[i]);
1148                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1149                                         }
1150                                 }
1151                         } else { // player has no ranked record yet
1152                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1153                                         grecordtime[i] = grecordtime[i-1];
1154                                         if(grecordholder[i])
1155                                                 strunzone(grecordholder[i]);
1156                                         grecordholder[i] = strzone(grecordholder[i-1]);
1157                                 }
1158                         }
1159
1160                         // store new ranking
1161                         if(grecordholder[pos-1] != "")
1162                                 strunzone(grecordholder[pos-1]);
1163                         grecordholder[pos-1] = strzone(ReadString());
1164                         grecordtime[pos-1] = ReadInt24_t();
1165                         if(grecordholder[pos-1] == GetPlayerName(player_localentnum -1))
1166                                 race_myrank = pos;
1167                         break;
1168                 case RACE_NET_SERVER_STATUS:
1169                         race_status = ReadShort();
1170                         if(race_status_name)
1171                                 strunzone(race_status_name);
1172                         race_status_name = strzone(ReadString());
1173         }
1174 }
1175
1176 void Net_ReadSpawn()
1177 {
1178         zoomin_effect = 1;
1179         current_viewzoom = 0.6;
1180 }
1181
1182 void Net_TeamNagger()
1183 {
1184         teamnagger = 1;
1185 }
1186
1187 void Net_ReadPingPLReport()
1188 {
1189         float e, pi, pl, ml;
1190         e = ReadByte();
1191         pi = ReadShort();
1192         pl = ReadByte();
1193         ml = ReadByte();
1194         if not(playerslots[e])
1195                 return;
1196         playerslots[e].ping = pi;
1197         playerslots[e].ping_packetloss = pl / 255.0;
1198         playerslots[e].ping_movementloss = ml / 255.0;
1199 }
1200
1201 void Net_VoteDialog(float highlight) {
1202         if(highlight) {
1203                 vote_highlighted = ReadShort();
1204                 return;
1205         }
1206
1207         vote_yescount = ReadShort();
1208         vote_nocount = ReadShort();
1209         vote_needed = ReadShort();
1210         vote_active = 1;
1211 }
1212
1213 void Net_VoteDialogReset() {
1214         vote_active = 0;
1215 }
1216
1217 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1218 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1219 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1220 float CSQC_Parse_TempEntity()
1221 {
1222         local float bHandled;
1223                 bHandled  = true;
1224         // Acquire TE ID
1225         local float nTEID;
1226                 nTEID = ReadByte();
1227
1228                 // NOTE: Could just do return instead of break...
1229         switch(nTEID)
1230         {
1231                 case TE_CSQC_PICTURE:
1232                         Net_MapVote_Picture();
1233                         bHandled = true;
1234                         break;
1235                 case TE_CSQC_RACE:
1236                         Net_ReadRace();
1237                         bHandled = true;
1238                         break;
1239                 case 13: // TE_BEAM
1240                         Net_GrapplingHook();
1241                         bHandled = true;
1242                         break;
1243                 case TE_CSQC_SPAWN:
1244                         Net_ReadSpawn();
1245                         bHandled = true;
1246                         break;
1247                 case TE_CSQC_ZCURVEPARTICLES:
1248                         Net_ReadZCurveParticles();
1249                         bHandled = true;
1250                         break;
1251                 case TE_CSQC_NEXGUNBEAMPARTICLE:
1252                         Net_ReadNexgunBeamParticle();
1253                         bHandled = true;
1254                         break;
1255                 case TE_CSQC_TEAMNAGGER:
1256                         Net_TeamNagger();
1257                         bHandled = true;
1258                         break;
1259                 case TE_CSQC_VOTE:
1260                         Net_VoteDialog(ReadByte());
1261                         bHandled = true;
1262                         break;
1263                 case TE_CSQC_VOTERESET:
1264                         Net_VoteDialogReset();
1265                         bHandled = true;
1266                         break;
1267                 case TE_CSQC_LIGHTNINGARC:
1268                         Net_ReadLightningarc();
1269                         bHandled = true;
1270                         break;
1271                 case TE_CSQC_PINGPLREPORT:
1272                         Net_ReadPingPLReport();
1273                         bHandled = true;
1274                         break;
1275                 case TE_CSQC_ANNOUNCE:
1276                         announce_snd = strzone(ReadString());
1277                         bHandled = true;
1278                         break;
1279                 default:
1280                         // No special logic for this temporary entity; return 0 so the engine can handle it
1281                         bHandled = false;
1282                         break;
1283         }
1284
1285         return bHandled;
1286 }
1287
1288 string getcommandkey(string text, string command)
1289 {
1290         string keys;
1291         float n, j, k, l;
1292
1293         if (!sbar_showbinds)
1294                 return text;
1295
1296         keys = db_get(binddb, command);
1297         if (!keys)
1298         {
1299                 n = tokenize(findkeysforcommand(command)); // uses '...' strings
1300                 for(j = 0; j < n; ++j)
1301                 {
1302                         k = stof(argv(j));
1303                         if(k != -1)
1304                         {
1305                                 if ("" == keys)
1306                                         keys = keynumtostring(k);
1307                                 else
1308                                         keys = strcat(keys, ", ", keynumtostring(k));
1309
1310                                 ++l;
1311                                 if (sbar_showbinds_limit > 0 && sbar_showbinds_limit >= l) break;
1312                         }
1313
1314                 }
1315                 db_put(binddb, command, keys);
1316         }
1317
1318         if ("" == keys) {
1319                 if (sbar_showbinds > 1)
1320                         return strcat(text, " (not bound)");
1321                 else
1322                         return text;
1323         }
1324         else if (sbar_showbinds > 1)
1325                 return strcat(text, " (", keys, ")");
1326         else
1327                 return keys;
1328 }