data/qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------\r
   2 // BEGIN REQUIRED CSQC FUNCTIONS\r
   3 //include "main.qh"\r
   4 \r
   5 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED\r
   6 \r
   7 void cvar_clientsettemp(string cv, string val)\r
   8 {\r
   9         entity e;\r
  10         for(e = world; (e = find(e, classname, "saved_cvar_value")); )\r
  11                 if(e.netname == cv)\r
  12                         goto saved;\r
  13         e = spawn();\r
  14         e.classname = "saved_cvar_value";\r
  15         e.netname = strzone(cv);\r
  16         e.message = strzone(cvar_string(cv));\r
  17 :saved\r
  18         cvar_set(cv, val);\r
  19 }\r
  20 \r
  21 void cvar_clientsettemp_restore()\r
  22 {\r
  23         entity e;\r
  24         for(e = world; (e = find(e, classname, "saved_cvar_value")); )\r
  25                         cvar_set(e.netname, e.message);\r
  26 }\r
  27 \r
  28 void() menu_show_error =\r
  29 {\r
  30         drawstring('0 200 0', "ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!", '8 8 0', '1 0 0', 1, 0);\r
  31 };\r
  32 \r
  33 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)\r
  34 // Useful for precaching things\r
  35 \r
  36 void() menu_sub_null =\r
  37 {\r
  38 };\r
  39 \r
  40 #ifdef USE_FTE\r
  41 float __engine_check;\r
  42 #endif\r
  43 \r
  44 string config_get(string key, string defaultvalue)\r
  45 {\r
  46         string s;\r
  47         s = db_get(configdb, strcat("/s/", key));\r
  48         if(s == "")\r
  49                 return defaultvalue;\r
  50         else\r
  51                 return db_get(configdb, strcat("/v/", key));\r
  52 }\r
  53 \r
  54 string forcefog;\r
  55 void WaypointSprite_Load();\r
  56 void CSQC_Init(void)\r
  57 {\r
  58 #ifdef USE_FTE\r
  59 #pragma target ID\r
  60         __engine_check = checkextension("DP_SV_WRITEPICTURE");\r
  61         if(!__engine_check)\r
  62         {\r
  63                 print("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n");\r
  64                 localcmd("\ndisconnect\n");\r
  65                 return;\r
  66         }\r
  67 #pragma target FTE\r
  68 #endif\r
  69         \r
  70         float i;\r
  71         CSQC_CheckEngine();\r
  72         dprint_load();\r
  73 \r
  74         configdb = db_create();\r
  75         binddb = db_create();\r
  76         tempdb = db_create();\r
  77         compressShortVector_init();\r
  78 \r
  79         drawfont = 0;\r
  80         menu_visible = FALSE;\r
  81         menu_show = menu_show_error;\r
  82         menu_action = menu_sub_null;\r
  83         maxclients = 255; // we later get the real maxclients to speed up stuff\r
  84         //ctf_temp_1 = "";\r
  85         // localcmd("alias order \"cmd order $*\""); enable if ctf-command thingy is used\r
  86         //registercmd("ctf_menu");\r
  87         registercmd("ons_map");\r
  88         //registercmd("menu_action");\r
  89         registercmd("sbar_columns_set");\r
  90         registercmd("sbar_columns_help");\r
  91 \r
  92         registercmd("+button3");\r
  93         registercmd("-button3");\r
  94         registercmd("+button4");\r
  95         registercmd("-button4");\r
  96 \r
  97         registercvar("sbar_usecsqc", "1");\r
  98         registercvar("sbar_columns", "default", CVAR_SAVE);\r
  99 \r
 100         gametype = 0;\r
 101 \r
 102         // sbar_fields uses strunzone on the titles!\r
 103         for(i = 0; i < MAX_SBAR_FIELDS; ++i)\r
 104                 sbar_title[i] = strzone("(null)");\r
 105 \r
 106         postinit = false;\r
 107 \r
 108         teams = Sort_Spawn();\r
 109         players = Sort_Spawn();\r
 110         \r
 111         GetTeam(COLOR_SPECTATOR, true); // add specs first\r
 112 \r
 113         cvar_clientsettemp("_supports_weaponpriority", "1");\r
 114 \r
 115 \r
 116 \r
 117 \r
 118         cs_project_is_b0rked = TRUE;\r
 119         R_SetView(VF_VIEWPORT, '0 0 0', '640 480 0');\r
 120         R_SetView(VF_FOV, '90 90 0');\r
 121         R_SetView(VF_ORIGIN, '0 0 0');\r
 122         R_SetView(VF_ANGLES, '0 0 0');\r
 123         R_SetView(VF_PERSPECTIVE, 1);\r
 124         makevectors('0 0 0');\r
 125         vector v;\r
 126         v = cs_project(v_forward);\r
 127         if(v_x - 320 < +1)\r
 128         if(v_x - 320 > -1)\r
 129         if(v_y - 240 < +1)\r
 130         if(v_y - 240 > -1)\r
 131                 cs_project_is_b0rked = FALSE;\r
 132 \r
 133         RegisterWeapons();\r
 134 \r
 135         WaypointSprite_Load();\r
 136 \r
 137         Projectile_Precache();\r
 138         GibSplash_Precache();\r
 139         Casings_Precache();\r
 140         DamageInfo_Precache();\r
 141 }\r
 142 \r
 143 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)\r
 144 void CSQC_Shutdown(void)\r
 145 {\r
 146 #ifdef USE_FTE\r
 147 #pragma TARGET id\r
 148         if(!__engine_check)\r
 149                 return 0;\r
 150 #pragma TARGET fte\r
 151 #endif\r
 152 \r
 153         remove(teams);\r
 154         remove(players);\r
 155         db_close(configdb);\r
 156         db_close(binddb);\r
 157         db_close(tempdb);\r
 158 \r
 159         cvar_clientsettemp_restore();\r
 160 }\r
 161 \r
 162 .float has_team;\r
 163 float SetTeam(entity o, float Team)\r
 164 {\r
 165         entity tm;\r
 166         if(Team == -1) // leave\r
 167         {\r
 168                 if(o.has_team)\r
 169                 {\r
 170                         //print("(DISCONNECT) leave team ", ftos(o.team), "\n");\r
 171                         tm = GetTeam(o.team, false);\r
 172                         tm.team_size -= 1;\r
 173                         o.has_team = 0;\r
 174                         return TRUE;\r
 175                 }\r
 176         }\r
 177         else\r
 178         {\r
 179                 if not(o.has_team)\r
 180                 {\r
 181                         //print("(CONNECT) enter team ", ftos(o.team), "\n");\r
 182                         o.team = Team;\r
 183                         tm = GetTeam(Team, true);\r
 184                         tm.team_size += 1;\r
 185                         o.has_team = 1;\r
 186                         return TRUE;\r
 187                 }\r
 188                 else if(Team != o.team)\r
 189                 {\r
 190                         //print("(CHANGE) leave team ", ftos(o.team), "\n");\r
 191                         tm = GetTeam(o.team, false);\r
 192                         tm.team_size -= 1;\r
 193                         o.team = Team;\r
 194                         //print("(CHANGE) enter team ", ftos(o.team), "\n");\r
 195                         tm = GetTeam(Team, true);\r
 196                         tm.team_size += 1;\r
 197                         return TRUE;\r
 198                 }\r
 199         }\r
 200         return FALSE;\r
 201 }\r
 202 \r
 203 void Playerchecker_Think()\r
 204 {\r
 205         float i;\r
 206         entity e;\r
 207         for(i = 0; i < maxclients; ++i)\r
 208         {\r
 209                 e = playerslots[i];\r
 210                 if(GetPlayerName(i) == "")\r
 211                 {\r
 212                         if(e.sort_prev)\r
 213                         {\r
 214                                 //print("playerchecker: KILL KILL KILL\n");\r
 215                                 // player disconnected\r
 216                                 SetTeam(e, -1);\r
 217                                 RemovePlayer(e);\r
 218                                 e.sort_prev = world;\r
 219                                 //e.gotscores = 0;\r
 220                         }\r
 221                 }\r
 222                 else\r
 223                 {\r
 224                         if not(e.sort_prev)\r
 225                         {\r
 226                                 //print("playerchecker: SPAWN SPAWN SPAWN\n");\r
 227                                 // player connected\r
 228                                 if not(e)\r
 229                                         playerslots[i] = e = spawn();\r
 230                                 e.sv_entnum = i;\r
 231                                 //e.gotscores = 0; // we might already have the scores...\r
 232                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with Sbar_UpdatePlayerTeams\r
 233                                 RegisterPlayer(e);\r
 234                                 Sbar_UpdatePlayerPos(e);\r
 235                         }\r
 236                 }\r
 237         }\r
 238         self.nextthink = time + 0.2;\r
 239 }\r
 240 \r
 241 void Porto_Init();\r
 242 void PostInit(void)\r
 243 {\r
 244         print(strcat("PostInit\n    maxclients = ", ftos(maxclients), "\n"));\r
 245         localcmd(strcat("\nsbar_columns_set ", cvar_string("sbar_columns"), ";\n"));\r
 246 \r
 247         entity playerchecker;\r
 248         playerchecker = spawn();\r
 249         playerchecker.think = Playerchecker_Think;\r
 250         playerchecker.nextthink = time + 0.2;\r
 251 \r
 252         Porto_Init();\r
 253 \r
 254         postinit = true;\r
 255 }\r
 256 \r
 257 // CSQC_ConsoleCommand : Used to parse commands in the console that have been registered with the "registercmd" function\r
 258 // Return value should be 1 if CSQC handled the command, otherwise return 0 to have the engine handle it.\r
 259 float button_zoom;\r
 260 void Cmd_Sbar_SetFields(float);\r
 261 void Cmd_Sbar_Help(float);\r
 262 float CSQC_ConsoleCommand(string strMessage)\r
 263 {\r
 264         float argc;\r
 265         // Tokenize String\r
 266         //argc = tokenize(strMessage);\r
 267         argc = tokenize_sane(strMessage);\r
 268         \r
 269         // Acquire Command\r
 270         local string strCmd;\r
 271         strCmd = argv(0);\r
 272 \r
 273         if(strCmd == "+button4") { // zoom\r
 274                 // return false, because the message shall be sent to the server anyway (for demos/speccing)\r
 275                 if(ignore_plus_zoom)\r
 276                 {\r
 277                         --ignore_plus_zoom;\r
 278                         return false;\r
 279                 }\r
 280                 button_zoom = 1;\r
 281                 return true;\r
 282         } else if(strCmd == "-button4") { // zoom\r
 283                 if(ignore_minus_zoom)\r
 284                 {\r
 285                         --ignore_minus_zoom;\r
 286                         return false;\r
 287                 }\r
 288                 button_zoom = 0;\r
 289                 return true;\r
 290         } else if(strCmd == "+button3") { // secondary\r
 291                 button_attack2 = 1;\r
 292                 return false;\r
 293         } else if(strCmd == "-button3") { // secondary\r
 294                 button_attack2 = 0;\r
 295                 return false;\r
 296         } else if(strCmd == "+showscores") {\r
 297                 sb_showscores = true;\r
 298                 return true;\r
 299         } else if(strCmd == "-showscores") {\r
 300                 sb_showscores = false;\r
 301                 return true;\r
 302         }\r
 303         \r
 304         return false;\r
 305 }\r
 306 \r
 307 float GameCommand(string msg)\r
 308 {\r
 309         float argc;\r
 310         argc = tokenize_sane(msg);\r
 311         string cmd;\r
 312         cmd = argv(0);\r
 313         if(cmd == "mv_download") {\r
 314                 Cmd_MapVote_MapDownload(argc);\r
 315                 return true;\r
 316         }\r
 317         else if(cmd == "settemp") {\r
 318                 cvar_clientsettemp(argv(1), argv(2));\r
 319         }\r
 320         else if(cmd == "radar") {\r
 321                 ons_showmap = !ons_showmap;\r
 322         }\r
 323         else if(cmd == "sbar_columns_set") {\r
 324                 Cmd_Sbar_SetFields(argc);\r
 325         }\r
 326         else if(cmd == "sbar_columns_help") {\r
 327                 Cmd_Sbar_Help(argc);\r
 328         }\r
 329 #ifdef BLURTEST\r
 330         else if(cmd == "blurtest") {\r
 331                 blurtest_time0 = time;\r
 332                 blurtest_time1 = time + stof(argv(1));\r
 333                 blurtest_radius = stof(argv(2));\r
 334                 blurtest_power = stof(argv(3));\r
 335         }\r
 336 #endif\r
 337         \r
 338         return false;\r
 339 }\r
 340 \r
 341 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.\r
 342 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.\r
 343 // All keys are in ascii.\r
 344 // bInputType = 0 is key pressed, 1 is key released, 2 is mouse input.\r
 345 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.\r
 346 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.\r
 347 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)\r
 348 {\r
 349         local float bSkipKey;\r
 350         bSkipKey = false;\r
 351         \r
 352         if(menu_visible)\r
 353                 if(menu_action(bInputType, nPrimary, nSecondary))\r
 354                         return TRUE;\r
 355         return bSkipKey;\r
 356 }\r
 357 \r
 358 // END REQUIRED CSQC FUNCTIONS\r
 359 // --------------------------------------------------------------------------\r
 360 \r
 361 // --------------------------------------------------------------------------\r
 362 // BEGIN OPTIONAL CSQC FUNCTIONS\r
 363 void Ent_ReadEntCS()\r
 364 {\r
 365         InterpolateOrigin_Undo();\r
 366 \r
 367         self.classname = "entcs_receiver";\r
 368         self.sv_entnum = ReadByte() - 1;\r
 369         self.origin_x = ReadShort();\r
 370         self.origin_y = ReadShort();\r
 371         self.origin_z = ReadShort();\r
 372         self.angles_y = ReadByte() * 360.0 / 256;\r
 373         self.origin_z = self.angles_x = self.angles_z = 0;\r
 374 \r
 375         InterpolateOrigin_Note();\r
 376 }\r
 377 \r
 378 void Ent_RemoveEntCS()\r
 379 {\r
 380 }\r
 381 \r
 382 void Ent_Remove();\r
 383 void Ent_ReadPlayerScore()\r
 384 {\r
 385         float i, n;\r
 386         float isNew;\r
 387         entity o;\r
 388 \r
 389         // damnit -.- don't want to go change every single .sv_entnum in sbar.qc AGAIN\r
 390         // (no I've never heard of M-x replace-string, sed, or anything like that)\r
 391         isNew = !self.owner; // workaround for DP bug\r
 392         n = ReadByte()-1;\r
 393 \r
 394 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED\r
 395         if(!isNew && n != self.sv_entnum)\r
 396         {\r
 397                 print("A CSQC entity changed its owner!\n");\r
 398                 isNew = true;\r
 399                 Ent_Remove();\r
 400                 self.enttype = ENT_CLIENT_SCORES;\r
 401         }\r
 402 #endif\r
 403 \r
 404         self.sv_entnum = n;\r
 405 \r
 406         if not(playerslots[self.sv_entnum])\r
 407                 playerslots[self.sv_entnum] = spawn();\r
 408         o = self.owner = playerslots[self.sv_entnum];\r
 409         o.sv_entnum = self.sv_entnum;\r
 410         o.gotscores = 1;\r
 411 \r
 412         //if not(o.sort_prev)\r
 413         //      RegisterPlayer(o);\r
 414         //playerchecker will do this for us later, if it has not already done so\r
 415 \r
 416 #if MAX_SCORE <= 3\r
 417         for(i = 0; i < MAX_SCORE; ++i)\r
 418                 o.(scores[i]) = ReadShort();\r
 419 #else\r
 420         float sf;\r
 421 #if MAX_SCORE <= 8\r
 422         sf = ReadByte();\r
 423 #else\r
 424         sf = ReadShort();\r
 425 #endif\r
 426         float p;\r
 427         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)\r
 428                 if(sf & p)\r
 429                         o.(scores[i]) = ReadShort();\r
 430 #endif\r
 431 \r
 432         if(o.sort_prev)\r
 433                 Sbar_UpdatePlayerPos(o); // if not registered, we cannot do this yet!\r
 434 }\r
 435 \r
 436 void Ent_ReadTeamScore()\r
 437 {\r
 438         float i;\r
 439         entity o;\r
 440         \r
 441         self.team = ReadByte();\r
 442         o = self.owner = GetTeam(self.team, true);\r
 443 \r
 444 #if MAX_TEAMSCORE <= 3\r
 445         for(i = 0; i < MAX_TEAMSCORE; ++i)\r
 446                 o.(teamscores[i]) = ReadShort();\r
 447 #else\r
 448         float sf;\r
 449 #if MAX_TEAMSCORE <= 8\r
 450         sf = ReadByte();\r
 451 #else\r
 452         sf = ReadShort();\r
 453 #endif\r
 454         float p;\r
 455         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)\r
 456                 if(sf & p)\r
 457                         o.(teamscores[i]) = ReadShort();\r
 458 #endif\r
 459 \r
 460         Sbar_UpdateTeamPos(o);\r
 461 }\r
 462 \r
 463 void Ent_Nagger()\r
 464 {\r
 465         float nags;\r
 466 \r
 467         nags = ReadByte();\r
 468 \r
 469         if(nags & 128)\r
 470         {\r
 471                 if(vote_called_vote)\r
 472                         strunzone(vote_called_vote);\r
 473                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));\r
 474         }\r
 475 \r
 476         ready_waiting = (nags & 1);\r
 477         ready_waiting_for_me = (nags & 2);\r
 478         vote_waiting = (nags & 4);\r
 479         vote_waiting_for_me = (nags & 8);\r
 480 }\r
 481 \r
 482 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.\r
 483 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.\r
 484 void Ent_RadarLink();\r
 485 void Ent_Init();\r
 486 void Ent_ScoresInfo();\r
 487 void(float bIsNewEntity) CSQC_Ent_Update =\r
 488 {\r
 489         float t;\r
 490         float savetime;\r
 491         t = ReadByte();\r
 492 \r
 493         // set up the "time" global for received entities to be correct for interpolation purposes\r
 494         savetime = time;\r
 495         if(servertime)\r
 496                 time = servertime;\r
 497 \r
 498 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED\r
 499         if(self.enttype)\r
 500                 if(t != self.enttype)\r
 501                 {\r
 502                         print("A CSQC entity changed its type!\n");\r
 503                         Ent_Remove();\r
 504                 }\r
 505 #endif\r
 506         self.enttype = t;\r
 507         if(self.enttype == ENT_CLIENT_ENTCS)\r
 508                 Ent_ReadEntCS();\r
 509         else if(self.enttype == ENT_CLIENT_SCORES)\r
 510                 Ent_ReadPlayerScore();\r
 511         else if(self.enttype == ENT_CLIENT_TEAMSCORES)\r
 512                 Ent_ReadTeamScore();\r
 513         else if(self.enttype == ENT_CLIENT_POINTPARTICLES)\r
 514                 Ent_PointParticles();\r
 515         else if(self.enttype == ENT_CLIENT_RAINSNOW)\r
 516                 Ent_RainOrSnow();\r
 517         else if(self.enttype == ENT_CLIENT_LASER)\r
 518                 Ent_Laser();\r
 519         else if(self.enttype == ENT_CLIENT_NAGGER)\r
 520                 Ent_Nagger();\r
 521         else if(self.enttype == ENT_CLIENT_WAYPOINT)\r
 522                 Ent_WaypointSprite();\r
 523         else if(self.enttype == ENT_CLIENT_RADARLINK)\r
 524                 Ent_RadarLink();\r
 525         else if(self.enttype == ENT_CLIENT_PROJECTILE)\r
 526                 Ent_Projectile();\r
 527         else if(self.enttype == ENT_CLIENT_GIBSPLASH)\r
 528                 Ent_GibSplash();\r
 529         else if(self.enttype == ENT_CLIENT_DAMAGEINFO)\r
 530                 Ent_DamageInfo();\r
 531         else if(self.enttype == ENT_CLIENT_CASING)\r
 532                 Ent_Casing();\r
 533         else if(self.enttype == ENT_CLIENT_INIT)\r
 534                 Ent_Init();\r
 535         else if(self.enttype == ENT_CLIENT_SCORES_INFO)\r
 536                 Ent_ScoresInfo();\r
 537         else if(self.enttype == ENT_CLIENT_MAPVOTE)\r
 538                 Ent_MapVote();\r
 539         else\r
 540                 error(strcat("unknown entity type in CSQC_Ent_Update: ", ftos(self.enttype), "\n"));\r
 541         \r
 542         time = savetime;\r
 543 };\r
 544 // Destructor, but does NOT deallocate the entity by calling remove(). Also\r
 545 // used when an entity changes its type. For an entity that someone interacts\r
 546 // with others, make sure it can no longer do so.\r
 547 void Ent_Remove()\r
 548 {\r
 549         float i;\r
 550         if(self.enttype == ENT_CLIENT_ENTCS)\r
 551         {\r
 552                 Ent_RemoveEntCS();\r
 553         } else if(self.enttype == ENT_CLIENT_SCORES)\r
 554         {\r
 555                 if(self.owner)\r
 556                 {\r
 557                         SetTeam(self.owner, -1);\r
 558                         self.owner.gotscores = 0;\r
 559                         for(i = 0; i < MAX_SCORE; ++i)\r
 560                                 self.owner.(scores[i]) = 0; // clear all scores\r
 561                 }\r
 562         } else if(self.enttype == ENT_CLIENT_TEAMSCORES)\r
 563         {\r
 564                 /*\r
 565                 if(self.owner)\r
 566                         RemoveTeam(self.owner);\r
 567                 */\r
 568                 // we don't NEED to remove them... they won't display anyway\r
 569                 // plus, svqc never does this anyway\r
 570         } else if(self.enttype == ENT_CLIENT_POINTPARTICLES)\r
 571         {\r
 572                 Ent_PointParticles_Remove();\r
 573         }\r
 574         else if(self.enttype == ENT_CLIENT_WAYPOINT)\r
 575                 Ent_RemoveWaypointSprite();\r
 576         else if(self.enttype == ENT_CLIENT_PROJECTILE)\r
 577                 Ent_RemoveProjectile();\r
 578 \r
 579         self.enttype = 0;\r
 580         self.classname = "";\r
 581         self.draw = menu_sub_null;\r
 582         // TODO possibly set more stuff to defaults\r
 583 }\r
 584 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.\r
 585 void CSQC_Ent_Remove()\r
 586 {\r
 587         if(self.enttype)\r
 588                 Ent_Remove();\r
 589         remove(self);\r
 590 }\r
 591 \r
 592 void Gamemode_Init()\r
 593 {\r
 594         get_mi_min_max_texcoords(1); // try the CLEVER way first\r
 595         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");\r
 596         shortmapname = mi_shortname;\r
 597 \r
 598         if(precache_pic(minimapname) == "")\r
 599         {\r
 600                 // but maybe we have a non-clever minimap\r
 601                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");\r
 602                 if(precache_pic(minimapname) == "")\r
 603                         minimapname = ""; // FAIL\r
 604                 else\r
 605                         get_mi_min_max_texcoords(0); // load new texcoords\r
 606         }\r
 607 \r
 608         mi_center = (mi_min + mi_max) * 0.5;\r
 609         mi_scale = mi_max - mi_min;\r
 610         minimapname = strzone(minimapname);\r
 611 \r
 612         if(gametype == GAME_ONSLAUGHT) {\r
 613                 print(strcat("Using ", minimapname, " as minimap.\n"));\r
 614                 precache_pic("gfx/ons-cp-neutral.tga");\r
 615                 precache_pic("gfx/ons-cp-red.tga");\r
 616                 precache_pic("gfx/ons-cp-blue.tga");\r
 617                 precache_pic("gfx/ons-frame.tga");\r
 618                 precache_pic("gfx/ons-frame-team.tga");\r
 619         } else if(gametype == GAME_KEYHUNT) {\r
 620                 precache_pic("gfx/sb_key_carrying");\r
 621                 precache_pic("gfx/sb_key_carrying_outline");\r
 622         }\r
 623 }\r
 624 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.\r
 625 void CSQC_Parse_StuffCmd(string strMessage)\r
 626 {\r
 627         localcmd(strMessage);\r
 628 }\r
 629 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.\r
 630 void CSQC_Parse_Print(string strMessage)\r
 631 {\r
 632         print(ColorTranslateRGB(strMessage));\r
 633 }\r
 634 // CSQC_Parse_CenterPrint : Provides the centerprint string in the first parameter that the server provided.  To execute standard behavior, simply execute cprint with the string.\r
 635 void CSQC_Parse_CenterPrint(string strMessage)\r
 636 {\r
 637         cprint(ColorTranslateRGB(strMessage));\r
 638 }\r
 639 \r
 640 void CSQC_CheckRevision();\r
 641 \r
 642 void Fog_Force()\r
 643 {\r
 644         // TODO somehow thwart prvm_globalset client ...\r
 645 \r
 646         if(forcefog != "")\r
 647                 localcmd(strcat("\nfog ", forcefog, "\nr_fog_exp2 0\nr_drawfog 1\n"));\r
 648 }\r
 649 \r
 650 void Net_ReadFog()\r
 651 {\r
 652         if(forcefog)\r
 653                 strunzone(forcefog);\r
 654         ReadCoord(); // ignore fog interval\r
 655         forcefog = strzone(ReadString());\r
 656 }\r
 657 \r
 658 void Gamemode_Init();\r
 659 void Ent_ScoresInfo()\r
 660 {\r
 661         float i;\r
 662         self.classname = "ent_client_scores_info";\r
 663         gametype = ReadByte();\r
 664         for(i = 0; i < MAX_SCORE; ++i)\r
 665         {\r
 666                 scores_label[i] = strzone(ReadString());\r
 667                 scores_flags[i] = ReadByte();\r
 668         }\r
 669         for(i = 0; i < MAX_TEAMSCORE; ++i)\r
 670         {\r
 671                 teamscores_label[i] = strzone(ReadString());\r
 672                 teamscores_flags[i] = ReadByte();\r
 673         }\r
 674         Sbar_InitScores();\r
 675         Gamemode_Init();\r
 676 }\r
 677 \r
 678 void Ent_Init()\r
 679 {\r
 680         float i;\r
 681         self.classname = "ent_client_init";\r
 682 \r
 683         csqc_revision = ReadShort();\r
 684         maxclients = ReadByte();\r
 685         for(i = 0; i < 24; ++i)\r
 686                 weaponimpulse[i] = ReadByte() - 1;\r
 687         hook_shotorigin_x = ReadCoord();\r
 688         hook_shotorigin_y = ReadCoord();\r
 689         hook_shotorigin_z = ReadCoord();\r
 690         CSQC_CheckRevision();\r
 691         \r
 692         if(!postinit)\r
 693                 PostInit();\r
 694 }\r
 695 \r
 696 string Net_ReadPicture()\r
 697 {\r
 698         string img;\r
 699         if(csqc_flags & CSQC_FLAG_READPICTURE)\r
 700         {\r
 701                 img = ReadPicture();\r
 702                 print(strcat("Got Picture: ", img, "\n"));\r
 703         } else {\r
 704                 img = ReadString();\r
 705                 print(strcat("^3Warning: ^7Couldn't download ", img, ". This is probably because your engine build is outdated.\n"));\r
 706                 float psize, i;\r
 707                 psize = ReadShort();\r
 708                 // Can I be sure that ReadShort is 2 bytes and ReadLong is 4 bytes?\r
 709                 // Because then this could be optimized to first get all 4-byte-groups,\r
 710                 // then the remaining 2, then the remaining 1\r
 711                 for(i = 0; i < psize; ++i)\r
 712                         ReadByte();\r
 713         }\r
 714         return img;\r
 715 }\r
 716 \r
 717 void Net_Config()\r
 718 {\r
 719         string key, value;\r
 720         key = ReadString();\r
 721         value = ReadString();\r
 722         db_put(configdb, strcat("/v/", key), value);\r
 723         db_put(configdb, strcat("/s/", key), "1");\r
 724 }\r
 725 \r
 726 void Net_ReadRace()\r
 727 {\r
 728         float b;\r
 729 \r
 730         b = ReadByte();\r
 731 \r
 732         switch(b)\r
 733         {\r
 734                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:\r
 735                         race_checkpoint = ReadByte();\r
 736                         race_time = ReadShort();\r
 737                         race_previousbesttime = ReadShort();\r
 738                         if(race_previousbestname)\r
 739                                 strunzone(race_previousbestname);\r
 740                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));\r
 741 \r
 742                         race_checkpointtime = time;\r
 743 \r
 744                         if(race_checkpoint == 0)\r
 745                                 race_laptime = time; // valid\r
 746 \r
 747                         break;\r
 748 \r
 749                 case RACE_NET_CHECKPOINT_CLEAR:\r
 750                         race_laptime = 0;\r
 751                         race_checkpointtime = 0;\r
 752                         break;\r
 753 \r
 754                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:\r
 755                         race_laptime = ReadCoord();\r
 756                         race_checkpointtime = -99999;\r
 757                         // fall through\r
 758                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:\r
 759                         race_nextcheckpoint = ReadByte();\r
 760 \r
 761                         race_nextbesttime = ReadShort();\r
 762                         if(race_nextbestname)\r
 763                                 strunzone(race_nextbestname);\r
 764                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));\r
 765                         break;\r
 766 \r
 767                 case RACE_NET_CHECKPOINT_HIT_RACE:\r
 768                         race_mycheckpoint = ReadByte();\r
 769                         race_mycheckpointtime = time;\r
 770                         race_mycheckpointdelta = ReadShort();\r
 771                         race_mycheckpointlapsdelta = ReadByte();\r
 772                         if(race_mycheckpointlapsdelta >= 128)\r
 773                                 race_mycheckpointlapsdelta -= 256;\r
 774                         if(race_mycheckpointenemy)\r
 775                                 strunzone(race_mycheckpointenemy);\r
 776                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));\r
 777                         break;\r
 778 \r
 779                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:\r
 780                         race_othercheckpoint = ReadByte();\r
 781                         race_othercheckpointtime = time;\r
 782                         race_othercheckpointdelta = ReadShort();\r
 783                         race_othercheckpointlapsdelta = ReadByte();\r
 784                         if(race_othercheckpointlapsdelta >= 128)\r
 785                                 race_othercheckpointlapsdelta -= 256;\r
 786                         if(race_othercheckpointenemy)\r
 787                                 strunzone(race_othercheckpointenemy);\r
 788                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));\r
 789                         break;\r
 790         }\r
 791 }\r
 792 \r
 793 void Net_ReadForceScoreboard()\r
 794 {\r
 795         sb_showscores_force = ReadByte();\r
 796 }\r
 797 \r
 798 void Net_Reset()\r
 799 {\r
 800         float i;\r
 801         race_laptime = 0;\r
 802         race_checkpointtime = 0;\r
 803         for(i = 0; i < 24; ++i)\r
 804                 angles_held_status[i] = 0;\r
 805 }\r
 806 \r
 807 void Net_ReadSpectating()\r
 808 {\r
 809         float newspectatee_status;\r
 810         newspectatee_status = ReadByte();\r
 811         if(newspectatee_status == player_localentnum)\r
 812                 newspectatee_status = -1; // observing\r
 813         if(newspectatee_status != spectatee_status)\r
 814                 Net_Reset();\r
 815         spectatee_status = newspectatee_status;\r
 816 }\r
 817 \r
 818 void Net_ReadZoomNotify()\r
 819 {\r
 820         spectatorbutton_zoom = ReadByte();\r
 821 }\r
 822 \r
 823 void Net_ReadSpawn()\r
 824 {\r
 825         zoomin_effect = 1;\r
 826         current_viewzoom = 0.6;\r
 827 }\r
 828 \r
 829 void Net_ReadWarmupStage()\r
 830 {\r
 831         warmup_stage = ReadByte();\r
 832 }\r
 833 \r
 834 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.\r
 835 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.\r
 836 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.\r
 837 void Net_ReadHoldAngles();\r
 838 float CSQC_Parse_TempEntity()\r
 839 {\r
 840         local float bHandled;\r
 841                 bHandled  = true;\r
 842         // Acquire TE ID\r
 843         local float nTEID;\r
 844                 nTEID = ReadByte();\r
 845 \r
 846                 // NOTE: Could just do return instead of break...\r
 847         switch(nTEID)\r
 848         {\r
 849                 case TE_CSQC_PICTURE:\r
 850                         Net_MapVote_Picture();\r
 851                         bHandled = true;\r
 852                         break;\r
 853                 case TE_CSQC_CONFIG:\r
 854                         Net_Config();\r
 855                         bHandled = true;\r
 856                         break;\r
 857                 case TE_CSQC_RACE:\r
 858                         Net_ReadRace();\r
 859                         bHandled = true;\r
 860                         break;\r
 861                 case TE_CSQC_FORCESCOREBOARD:\r
 862                         Net_ReadForceScoreboard();\r
 863                         bHandled = true;\r
 864                         break;\r
 865                 case TE_CSQC_SPECTATING:\r
 866                         Net_ReadSpectating();\r
 867                         bHandled = true;\r
 868                         break;\r
 869                 case 13: // TE_BEAM\r
 870                         Net_GrapplingHook();\r
 871                         bHandled = true;\r
 872                         break;\r
 873                 case TE_CSQC_SPAWN:\r
 874                         Net_ReadSpawn();\r
 875                         bHandled = true;\r
 876                         break;\r
 877                 case TE_CSQC_ZOOMNOTIFY:\r
 878                         Net_ReadZoomNotify();\r
 879                         bHandled = true;\r
 880                         break;\r
 881                 case TE_CSQC_HOLDANGLES:\r
 882                         Net_ReadHoldAngles();\r
 883                         bHandled = true;\r
 884                         break;\r
 885                 case TE_CSQC_WARMUP:\r
 886                         Net_ReadWarmupStage();\r
 887                         bHandled = true;\r
 888                         break;\r
 889                 case TE_CSQC_FOG:\r
 890                         Net_ReadFog();\r
 891                         bHandled = true;\r
 892                         break;\r
 893                 default:\r
 894                         // No special logic for this temporary entity; return 0 so the engine can handle it\r
 895                         bHandled = false;\r
 896                         break;\r
 897         }\r
 898                 \r
 899         return bHandled;\r
 900 }\r
 901 \r
 902 // COMMIT-TODO: Update if necessare, before committing\r
 903 void CSQC_CheckRevision()\r
 904 {\r
 905         if(csqc_revision == CSQC_REVISION)\r
 906         {\r
 907                 print("^2SVQC and CSQC revisions are compatible.\n");\r
 908         } else if(csqc_revision < CSQC_REVISION) {\r
 909                 print("^1Your csprogs.dat (CSQC) version is newer than the one on the server.\n");\r
 910         } else if(csqc_revision > CSQC_REVISION) {\r
 911                 print("^1Your csprogs.dat (CSQC) is too old for this server.\n");\r
 912                 print("^1Please update to a newer version.\n");\r
 913         }\r
 914 }\r
 915 \r
 916 string getcommandkey(string text, string command)\r
 917 {\r
 918         string keys;\r
 919         float n, j, k, l;\r
 920 \r
 921         if (!sbar_showbinds)\r
 922                 return text;\r
 923 \r
 924         keys = db_get(binddb, command);\r
 925         if(csqc_flags & CSQC_FLAG_READPICTURE)\r
 926         {\r
 927                 if (!keys) \r
 928                 {\r
 929                         n = tokenize_insane(findkeysforcommand(command)); // uses '...' strings\r
 930                         for(j = 0; j < n; ++j)\r
 931                         {\r
 932                                 k = stof(argv(j));\r
 933                                 if(k != -1) \r
 934                                 {\r
 935                                         if ("" == keys)\r
 936                                                 keys = keynumtostring(k);\r
 937                                         else\r
 938                                                 keys = strcat(keys, ", ", keynumtostring(k));\r
 939 \r
 940                                         ++l;\r
 941                                         if (sbar_showbinds_limit > 0 && sbar_showbinds_limit >= l) break;\r
 942                                 }\r
 943                         \r
 944                         }\r
 945                         db_put(binddb, command, keys);\r
 946                 }\r
 947         }\r
 948         \r
 949         if ("" == keys) {\r
 950                 if (sbar_showbinds > 1)\r
 951                         return strcat(text, " (not bound)");\r
 952                 else\r
 953                         return text;\r
 954         }\r
 955         else if (sbar_showbinds > 1)\r
 956                 return strcat(text, " (", keys, ")");\r
 957         else\r
 958                 return keys;\r
 959 }\r