data/qcsrc/server/cl_client.qc

   1 void info_player_start (void)
   2 {
   3         self.classname = "info_player_deathmatch";
   4         relocate_spawnpoint();
   5 }
   6
   7 void info_player_deathmatch (void)
   8 {
   9         relocate_spawnpoint();
  10 }
  11
  12 float spawn_allbad;
  13 float spawn_allgood;
  14 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
  15 {
  16         local entity spot, player, nextspot, previousspot, newfirstspot;
  17         local float pcount;
  18         spot = firstspot;
  19         newfirstspot = world;
  20         previousspot = world;
  21         spawn_allgood = TRUE;
  22         spawn_allbad = TRUE;
  23         while (spot)
  24         {
  25                 nextspot = spot.chain;
  26                 // count team mismatches as bad spots
  27                 if (spot.team == teamcheck)
  28                 {
  29                         pcount = 0;
  30                         player = playerlist;
  31                         while (player)
  32                         {
  33                                 if (player != self)
  34                                 if (vlen(player.origin - spot.origin) < mindist)
  35                                         pcount = pcount + 1;
  36                                 player = player.chain;
  37                         }
  38                         if (!pcount)
  39                         {
  40                                 spawn_allbad = FALSE;
  41                                 if (newfirstspot)
  42                                         previousspot.chain = spot;
  43                                 else
  44                                         newfirstspot = spot;
  45                                 previousspot = spot;
  46                                 spot.chain = world;
  47                         }
  48                         else
  49                                 spawn_allgood = FALSE;
  50                 }
  51                 spot = nextspot;
  52         }
  53         // if we couldn't find ANY good points, return the original list
  54         if (!newfirstspot)
  55                 newfirstspot = firstspot;
  56         return newfirstspot;
  57 }
  58
  59 entity Spawn_RandomPoint(entity firstspot)
  60 {
  61         local entity spot;
  62         local float numspots;
  63         // count number of spots
  64         numspots = 0;
  65         spot = firstspot;
  66         while (spot)
  67         {
  68                 numspots = numspots + 1;
  69                 spot = spot.chain;
  70         }
  71         // pick a random one
  72         numspots = numspots * random();
  73         spot = firstspot;
  74         while (spot.chain && numspots >= 1)
  75         {
  76                 numspots = numspots - 1;
  77                 spot = spot.chain;
  78         }
  79         return spot;
  80 }
  81
  82 entity Spawn_FurthestPoint(entity firstspot, entity playerlist)
  83 {
  84         local entity best, spot, player;
  85         local float bestrating, rating;
  86         best = world;
  87         bestrating = -1000000;
  88         spot = firstspot;
  89         while (spot)
  90         {
  91                 rating = 1000000000;
  92                 player = playerlist;
  93                 while (player)
  94                 {
  95                         if (player != self)
  96                                 rating = min(rating, vlen(player.origin - spot.origin));
  97                         player = player.chain;
  98                 }
  99                 rating = rating + random() * 16;
 100                 if (bestrating < rating)
 101                 {
 102                         best = spot;
 103                         bestrating = rating;
 104                 }
 105                 spot = spot.chain;
 106         }
 107         return best;
 108 }
 109
 110 /*
 111 =============
 112 SelectSpawnPoint
 113
 114 Finds a point to respawn
 115 =============
 116 */
 117 entity SelectSpawnPoint (float anypoint)
 118 {
 119         local float teamcheck;
 120         local entity spot, firstspot, playerlist;
 121
 122         spot = find (world, classname, "testplayerstart");
 123         if (spot)
 124                 return spot;
 125
 126         teamcheck = 0;
 127
 128         if(!anypoint && cvar("g_ctf") )
 129                 teamcheck = self.team;
 130
 131         // get the list of players
 132         playerlist = findchain(classname, "player");
 133         // get the entire list of spots
 134         firstspot = findchain(classname, "info_player_deathmatch");
 135         // filter out the bad ones
 136         // (note this returns the original list if none survived)
 137         firstspot = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 138
 139         // there is 50/50 chance of choosing a random spot or the furthest spot
 140         // (this means that roughly every other spawn will be furthest, so you
 141         // usually won't get fragged at spawn twice in a row)
 142         if (arena_roundbased)
 143         {
 144                 firstspot = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 145                 spot = Spawn_RandomPoint(firstspot);
 146         }
 147         else if (random() > 0.5 || spawn_allbad || spawn_allgood)
 148                 spot = Spawn_RandomPoint(firstspot);
 149         else
 150                 spot = Spawn_FurthestPoint(firstspot, playerlist);
 151
 152         if (!spot)
 153         {
 154                 if(cvar("spawn_debug"))
 155                         GotoNextMap();
 156                 else
 157                         error ("PutClientInServer: no start points on level");
 158         }
 159
 160         return spot;
 161 }
 162
 163 /*
 164 =============
 165 CheckPlayerModel
 166
 167 Checks if the argument string can be a valid playermodel.
 168 Returns a valid one in doubt.
 169 =============
 170 */
 171 string FallbackPlayerModel = "models/player/marine.zym";
 172 string CheckPlayerModel(string plyermodel) {
 173         if(strlen(plyermodel) < 4)
 174                 return FallbackPlayerModel;
 175         if( substring(plyermodel,0,14) != "models/player/")
 176                 return FallbackPlayerModel;
 177         else if(cvar("sv_servermodelsonly"))
 178         {
 179                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 180                         return FallbackPlayerModel;
 181                 if(!fexists(plyermodel))
 182                         return FallbackPlayerModel;
 183         }
 184         return plyermodel;
 185 }
 186
 187 /*
 188 =============
 189 Client_customizeentityforclient
 190
 191 LOD reduction
 192 =============
 193 */
 194 float Client_customizeentityforclient()
 195 {
 196 #ifdef ALLOW_VARIABLE_LOD
 197         // self: me
 198         // other: the player viewing me
 199         float distance;
 200         float f;
 201
 202         if(self.flags & FL_NOTARGET) // we don't need LOD for spectators
 203                 return TRUE;
 204
 205         if(other.cvar_cl_playerdetailreduction <= 0)
 206         {
 207                 if(other.cvar_cl_playerdetailreduction <= -2)
 208                         self.modelindex = self.modelindex_lod2;
 209                 else if(other.cvar_cl_playerdetailreduction <= -1)
 210                         self.modelindex = self.modelindex_lod1;
 211                 else
 212                         self.modelindex = self.modelindex_lod0;
 213         }
 214         else
 215         {
 216                 distance = vlen(self.origin - other.origin);
 217                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 218                 if(f > 10000)
 219                         self.modelindex = self.modelindex_lod2;
 220                 else if(f > 5000)
 221                         self.modelindex = self.modelindex_lod1;
 222                 else
 223                         self.modelindex = self.modelindex_lod0;
 224         }
 225 #endif
 226
 227         return TRUE;
 228 }
 229
 230 void setmodel_lod(entity e, string modelname)
 231 {
 232 #ifdef ALLOW_VARIABLE_LOD
 233         string s;
 234
 235         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1.zym");
 236         if(fexists(s))
 237         {
 238                 precache_model(s);
 239                 setmodel(e, s);
 240                 self.modelindex_lod1 = self.modelindex;
 241         }
 242         else
 243                 self.modelindex_lod1 = -1;
 244
 245         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2.zym");
 246         if(fexists(s))
 247         {
 248                 precache_model(s);
 249                 setmodel(e, s);
 250                 self.modelindex_lod2 = self.modelindex;
 251         }
 252         else
 253                 self.modelindex_lod2 = -1;
 254
 255         precache_model(modelname);
 256         setmodel(e, modelname);
 257         self.modelindex_lod0 = self.modelindex;
 258
 259         if(self.modelindex_lod1 < 0)
 260                 self.modelindex_lod1 = self.modelindex;
 261
 262         if(self.modelindex_lod2 < 0)
 263                 self.modelindex_lod2 = self.modelindex;
 264 #else
 265         precache_model(modelname);
 266         setmodel(e, modelname);
 267 #endif
 268 }
 269
 270 /*
 271 =============
 272 PutObserverInServer
 273
 274 putting a client as observer in the server
 275 =============
 276 */
 277 void PutObserverInServer (void)
 278 {
 279         entity  spot;
 280         spot = SelectSpawnPoint (FALSE);
 281         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 282
 283         if(clienttype(self) == CLIENTTYPE_REAL)
 284         {
 285                 msg_entity = self;
 286                 WriteByte(MSG_ONE, SVC_SETVIEW);
 287                 WriteEntity(MSG_ONE, self);
 288         }
 289
 290         DropAllRunes(self);
 291
 292         if(self.flagcarried)
 293                 DropFlag(self.flagcarried);
 294
 295         DistributeFragsAmongTeam(self, self.team, 1);
 296
 297         if(self.frags <= 0 && self.frags > -666 && cvar("g_lms") && self.killcount != -666)
 298                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 299         else if(self.killcount != -666)
 300                 bprint ("^4", self.netname, "^4 is spectating now\n");
 301
 302         self.classname = "observer";
 303         self.health = -666;
 304         self.takedamage = DAMAGE_NO;
 305         self.solid = SOLID_NOT;
 306         self.movetype = MOVETYPE_NOCLIP;
 307         self.flags = FL_CLIENT | FL_NOTARGET;
 308         self.armorvalue = 666;
 309         self.effects = 0;
 310         self.armorvalue = cvar("g_balance_armor_start");
 311         self.pauserotarmor_finished = 0;
 312         self.pauserothealth_finished = 0;
 313         self.pauseregen_finished = 0;
 314         self.damageforcescale = 0;
 315         self.death_time = 0;
 316         self.dead_time = 0;
 317         self.dead_frame = 0;
 318         self.die_frame = 0;
 319         self.deaths = 0;
 320         self.alpha = 0;
 321         self.scale = 0;
 322         self.fade_time = 0;
 323         self.pain_frame = 0;
 324         self.pain_finished = 0;
 325         self.strength_finished = 0;
 326         self.invincible_finished = 0;
 327         self.pushltime = 0;
 328         self.think = SUB_Null;
 329         self.nextthink = 0;
 330         self.hook_time = 0;
 331         self.runes = 0;
 332         self.deadflag = DEAD_NO;
 333         self.angles = spot.angles;
 334         self.angles_z = 0;
 335         self.fixangle = TRUE;
 336         self.crouch = FALSE;
 337
 338         self.view_ofs = PL_VIEW_OFS;
 339         setorigin (self, spot.origin);
 340         setsize (self, '0 0 0', '0 0 0');
 341         self.oldorigin = self.origin;
 342         self.items = 0;
 343         self.model = "";
 344         self.modelindex = 0;
 345         self.weapon = 0;
 346         self.weaponmodel = "";
 347         self.weaponentity = world;
 348         self.killcount = -666;
 349         self.velocity = '0 0 0';
 350         self.avelocity = '0 0 0';
 351         self.punchangle = '0 0 0';
 352         self.punchvector = '0 0 0';
 353         self.oldvelocity = self.velocity;
 354         self.customizeentityforclient = Client_customizeentityforclient;
 355
 356         if(cvar("g_arena"))
 357         {
 358                 if(self.frags != -2)
 359                 {
 360                         Spawnqueue_Insert(self);
 361                 }
 362                 else
 363                 {
 364                         Spawnqueue_Unmark(self);
 365                         Spawnqueue_Remove(self);
 366                 }
 367         }
 368         else if(!cvar("g_lms"))
 369                 self.frags = -666;
 370 }
 371
 372
 373 /*
 374 =============
 375 PutClientInServer
 376
 377 Called when a client spawns in the server
 378 =============
 379 */
 380 void PutClientInServer (void)
 381 {
 382         if(clienttype(self) == CLIENTTYPE_BOT)
 383         {
 384                 self.classname = "player";
 385         }
 386         else if(clienttype(self) == CLIENTTYPE_REAL)
 387         {
 388                 msg_entity = self;
 389                 WriteByte(MSG_ONE, SVC_SETVIEW);
 390                 WriteEntity(MSG_ONE, self);
 391         }
 392
 393         // player is dead and becomes observer
 394         if(cvar("g_lms") && self.frags < 1)
 395                 self.classname = "observer";
 396
 397         if(cvar("g_arena"))
 398         if(!self.spawned)
 399                 self.classname = "observer";
 400
 401         if(self.classname == "player") {
 402                 entity  spot;
 403
 404                 spot = SelectSpawnPoint (FALSE);
 405
 406                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 407
 408                 self.classname = "player";
 409                 self.iscreature = TRUE;
 410                 self.movetype = MOVETYPE_WALK;
 411                 self.solid = SOLID_SLIDEBOX;
 412                 self.flags = FL_CLIENT;
 413                 self.takedamage = DAMAGE_AIM;
 414                 self.effects = 0;
 415                 self.health = cvar("g_balance_health_start");
 416                 self.air_finished = time + 12;
 417                 self.dmg = 2;
 418                 self.armorvalue = cvar("g_balance_armor_start");
 419                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 420                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 421                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 422                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 423                 self.damageforcescale = 2;
 424                 self.death_time = 0;
 425                 self.dead_time = 0;
 426                 self.dead_frame = 0;
 427                 self.die_frame = 0;
 428                 self.alpha = 0;
 429                 self.scale = 1;
 430                 if(maptype == MAPTYPE_Q1BSP)
 431                         self.scale = 0.85;
 432                 self.fade_time = 0;
 433                 self.pain_frame = 0;
 434                 self.pain_finished = 0;
 435                 self.strength_finished = 0;
 436                 self.invincible_finished = 0;
 437                 self.pushltime = 0;
 438                 //self.speed_finished = 0;
 439                 //self.slowmo_finished = 0;
 440                 // players have no think function
 441                 self.think = SUB_Null;
 442                 self.nextthink = 0;
 443                 self.weapon = 0;
 444                 self.switchweapon = 0;
 445                 self.hook_time = 0;
 446
 447                 self.runes = 0;
 448
 449                 self.deadflag = DEAD_NO;
 450
 451                 self.angles = spot.angles;
 452
 453                 self.angles_z = 0; // never spawn tilted even if the spot says to
 454                 self.fixangle = TRUE; // turn this way immediately
 455                 self.velocity = '0 0 0';
 456                 self.avelocity = '0 0 0';
 457                 self.punchangle = '0 0 0';
 458                 self.punchvector = '0 0 0';
 459                 self.oldvelocity = self.velocity;
 460
 461                 self.viewzoom = 0.6;
 462
 463                 self.customizeentityforclient = Client_customizeentityforclient;
 464
 465                 if(cvar("sv_defaultcharacter") == 1 && !teams_matter) {
 466                         local string defaultmodel;
 467                         defaultmodel = CheckPlayerModel(cvar_string("sv_defaultplayermodel"));
 468                         setmodel_lod (self, defaultmodel);
 469                         self.skin = stof(cvar_string("sv_defaultplayerskin"));
 470                 } else {
 471                         self.playermodel = CheckPlayerModel(self.playermodel);
 472                         setmodel_lod (self, self.playermodel);
 473                         if(teams_matter)
 474                                 self.skin = math_mod(stof(self.playerskin), NUM_PLAYERSKINS_TEAMPLAY);
 475                         else
 476                                 self.skin = stof(self.playerskin);
 477                 }
 478
 479                 self.crouch = FALSE;
 480                 self.view_ofs = PL_VIEW_OFS * self.scale;
 481                 setsize (self, PL_MIN * self.scale, PL_MAX * self.scale);
 482                 self.spawnorigin = spot.origin;
 483                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 484                 // don't reset back to last position, even if new position is stuck in solid
 485                 self.oldorigin = self.origin;
 486
 487                 if(cvar("g_lms"))
 488                 {
 489                         self.ammo_shells = cvar("g_lms_start_ammo_shells");
 490                         self.ammo_nails = cvar("g_lms_start_ammo_nails");
 491                         self.ammo_rockets = cvar("g_lms_start_ammo_rockets");
 492                         self.ammo_cells = cvar("g_lms_start_ammo_cells");
 493                         self.health = cvar("g_lms_start_health");
 494                         self.armorvalue = cvar("g_lms_start_armor");
 495                 }
 496                 else if (cvar("g_use_ammunition")) {
 497                         self.ammo_shells = cvar("g_start_ammo_shells");
 498                         self.ammo_nails = cvar("g_start_ammo_nails");
 499                         self.ammo_rockets = cvar("g_start_ammo_rockets");
 500                         self.ammo_cells = cvar("g_start_ammo_cells");
 501                 } else {
 502                         self.ammo_shells = 999;
 503                         self.ammo_nails = 999;
 504                         self.ammo_rockets = 999;
 505                         self.ammo_cells = 999;
 506                 }
 507
 508                 self.items = 0;
 509                 if (cvar("g_start_weapon_laser") || cvar("g_lms"))
 510                 {
 511                         self.items = self.items | IT_LASER;
 512                         self.switchweapon = WEP_LASER;
 513                 }
 514                 if (cvar("g_start_weapon_shotgun") || cvar("g_lms"))
 515                 {
 516                         self.items = self.items | IT_SHOTGUN;
 517                         self.switchweapon = WEP_SHOTGUN;
 518                 }
 519                 if (cvar("g_start_weapon_uzi") || cvar("g_lms"))
 520                 {
 521                         self.items = self.items | IT_UZI;
 522                         self.switchweapon = WEP_UZI;
 523                 }
 524                 if (cvar("g_start_weapon_grenadelauncher") || cvar("g_lms"))
 525                 {
 526                         self.items = self.items | IT_GRENADE_LAUNCHER;
 527                         self.switchweapon = WEP_GRENADE_LAUNCHER;
 528                 }
 529                 if (cvar("g_start_weapon_electro") || cvar("g_lms"))
 530                 {
 531                         self.items = self.items | IT_ELECTRO;
 532                         self.switchweapon = WEP_ELECTRO;
 533                 }
 534                 if (cvar("g_start_weapon_crylink") || cvar("g_lms"))
 535                 {
 536                         self.items = self.items | IT_CRYLINK;
 537                         self.switchweapon = WEP_CRYLINK;
 538                 }
 539                 if (cvar("g_start_weapon_nex") || cvar("g_lms"))
 540                 {
 541                         self.items = self.items | IT_NEX;
 542                         self.switchweapon = WEP_NEX;
 543                 }
 544                 if (cvar("g_start_weapon_hagar") || cvar("g_lms"))
 545                 {
 546                         self.items = self.items | IT_HAGAR;
 547                         self.switchweapon = WEP_HAGAR;
 548                 }
 549                 if (cvar("g_start_weapon_rocketlauncher") || cvar("g_lms"))
 550                 {
 551                         self.items = self.items | IT_ROCKET_LAUNCHER;
 552                         self.switchweapon = WEP_ROCKET_LAUNCHER;
 553                 }
 554
 555                 if(cvar("g_instagib"))
 556                 {
 557                         self.items = IT_NEX;
 558                         self.switchweapon = WEP_NEX;
 559                         self.ammo_cells = 999;
 560                 }
 561
 562                 if(cvar("g_rocketarena"))
 563                 {
 564                         self.items = IT_ROCKET_LAUNCHER;
 565                         self.switchweapon = WEP_ROCKET_LAUNCHER;
 566                         self.ammo_rockets = 999;
 567                 }
 568
 569                 if(cvar("g_nixnex"))
 570                 {
 571                         self.items = 0;
 572                         // will be done later
 573                 }
 574
 575                 if(cvar("g_minstagib"))
 576                 {
 577                         self.health = 100;
 578                         self.armorvalue = 0;
 579                         self.items = IT_NEX;
 580                         self.switchweapon = WEP_NEX;
 581                         self.ammo_cells = cvar("g_minstagib_ammo_start");
 582                         self.jump_interval = time;
 583                 }
 584
 585                 if(cvar("g_arena"))
 586                 {
 587                         Spawnqueue_Remove(self);
 588                         Spawnqueue_Mark(self);
 589                 }
 590
 591                 self.event_damage = PlayerDamage;
 592
 593                 self.bot_attack = TRUE;
 594
 595                 self.statdraintime = time + 5;
 596                 self.button0 = self.button1 = self.button2 = self.button3 = 0;
 597
 598                 if(self.killcount == -666) {
 599                         self.killcount = 0;
 600                         if(!cvar("g_arena"))
 601                         if(!cvar("g_lms"))
 602                                 self.frags = 0;
 603                 }
 604
 605                 self.cnt = WEP_LASER;
 606                 self.nixnex_lastchange_id = -1;
 607
 608                 CL_SpawnWeaponentity();
 609                 self.alpha = default_player_alpha;
 610                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 611
 612                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 613                 self.lms_traveled_distance = 0;
 614
 615                 if(cvar("spawn_debug"))
 616                 {
 617                                 sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 618                                 remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 619                 }
 620
 621                 //stuffcmd(self, "chase_active 0");
 622                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 623         } else if(self.classname == "observer") {
 624                 PutObserverInServer ();
 625         }
 626 }
 627
 628 /*
 629 =============
 630 SetNewParms
 631 =============
 632 */
 633 void SetNewParms (void)
 634 {
 635
 636 }
 637
 638 /*
 639 =============
 640 SetChangeParms
 641 =============
 642 */
 643 void SetChangeParms (void)
 644 {
 645
 646 }
 647
 648 /*
 649 =============
 650 ClientKill
 651
 652 Called when a client types 'kill' in the console
 653 =============
 654 */
 655 void ClientKill (void)
 656 {
 657         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 658 }
 659
 660 void FixClientCvars(entity e)
 661 {
 662         // send prediction settings to the client
 663         stuffcmd(e, "\nin_bindmap 0 0\n");
 664         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
 665         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
 666         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
 667         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
 668         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
 669         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
 670         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
 671         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("g_balance_jumpheight")), "\n"));
 672         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
 673         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
 674         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
 675         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
 676         stuffcmd(e, "cl_movement_edgefriction 1\n");
 677 }
 678
 679 /*
 680 =============
 681 ClientConnect
 682
 683 Called when a client connects to the server
 684 =============
 685 */
 686 string ColoredTeamName(float t);
 687 //void dom_player_join_team(entity pl);
 688 void ClientConnect (void)
 689 {
 690         local string s;
 691
 692         self.classname = "player_joining";
 693         self.flags = self.flags | FL_CLIENT;
 694         self.version_nagtime = time + 10 + random() * 10;
 695
 696         if(player_count<0)
 697         {
 698                 dprint("BUG player count is lower than zero, this cannot happen!\n");
 699                 player_count = 0;
 700         }
 701
 702         bot_clientconnect();
 703
 704         //if(cvar("g_domination"))
 705         //      dom_player_join_team(self);
 706
 707         //JoinBestTeam(self, FALSE);
 708
 709         if((cvar("sv_spectate") == 1 && !cvar("g_lms")) || cvar("g_campaign")) {
 710                 self.classname = "observer";
 711         } else {
 712                 self.classname = "player";
 713                 campaign_bots_may_start = 1;
 714         }
 715
 716         self.playerid = (playerid_last = playerid_last + 1);
 717         if(cvar("sv_eventlog"))
 718         {
 719                 if(clienttype(self) == CLIENTTYPE_REAL)
 720                         s = "player";
 721                 else
 722                         s = "bot";
 723                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", s, ":", self.netname), TRUE);
 724                 s = strcat(":team:", ftos(self.playerid), ":");
 725                 s = strcat(s, ftos(self.team));
 726                 GameLogEcho(s, FALSE);
 727         }
 728
 729         //stuffcmd(self, "set tmpviewsize $viewsize \n");
 730
 731         bprint ("^4",self.netname);
 732         bprint ("^4 connected");
 733
 734         if(cvar("g_domination") || cvar("g_ctf"))
 735         {
 736                 bprint(" and joined the ");
 737                 bprint(ColoredTeamName(self.team));
 738         }
 739
 740         bprint("\n");
 741
 742         self.welcomemessage_time = 0;
 743
 744         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
 745         // TODO: is this being used for anything else than cd tracks?
 746         // Remember: SVC_CDTRACK exists. Maybe it should be used.
 747
 748         FixClientCvars(self);
 749
 750         // Wazat's grappling hook
 751         SetGrappleHookBindings();
 752
 753         // get autoswitch state from player
 754         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1; cmd autoswitch $1\"\n");
 755         stuffcmd(self, "cmd autoswitch $cl_autoswitch\n");
 756
 757         // get version info from player
 758         stuffcmd(self, "cmd clientversion $gameversion\n");
 759
 760         // get other cvars from player
 761         GetCvars(0);
 762
 763         // set cvar for team scoreboard
 764         if (teams_matter)
 765         {
 766                 local float t;
 767                 t = cvar("teamplay");
 768                 // we have to stuff the correct teamplay value because if this is a listen server, this changes the teamplay mode of the server itself, which is bad
 769                 stuffcmd(self, strcat("set teamplay ", ftos(t), "\n"));
 770         }
 771         else
 772                 stuffcmd(self, "set teamplay 0\n");
 773
 774         if(cvar("g_lms"))
 775         {
 776                 self.frags = cvar("fraglimit");
 777                 // no fraglimit was set, so player gets 999 lives
 778                 if(self.frags < 1)
 779                         self.frags = 999;
 780
 781                 self.frags = LMS_NewPlayerLives();
 782                 if(!self.frags)
 783                 {
 784                         self.frags = -666;
 785                 }
 786         }
 787         else if(cvar("g_arena"))
 788         {
 789                 self.classname = "observer";
 790                 Spawnqueue_Insert(self);
 791         }
 792
 793         bot_relinkplayerlist();
 794
 795         self.jointime = time;
 796 }
 797
 798 /*
 799 =============
 800 ClientDisconnect
 801
 802 Called when a client disconnects from the server
 803 =============
 804 */
 805 void(entity e) DropFlag;
 806 .entity chatbubbleentity;
 807 .entity teambubbleentity;
 808 void ClientDisconnect (void)
 809 {
 810         float save;
 811         if(cvar("sv_eventlog"))
 812                 GameLogEcho(strcat(":part:", ftos(self.playerid)), FALSE);
 813         bprint ("^4",self.netname);
 814         bprint ("^4 disconnected\n");
 815
 816         if (self.chatbubbleentity)
 817         {
 818                 remove (self.chatbubbleentity);
 819                 self.chatbubbleentity = world;
 820         }
 821
 822         if (self.teambubbleentity)
 823         {
 824                 remove (self.teambubbleentity);
 825                 self.teambubbleentity = world;
 826         }
 827
 828         DropAllRunes(self);
 829
 830         if(self.flagcarried)
 831                 DropFlag(self.flagcarried);
 832
 833         DistributeFragsAmongTeam(self, self.team, 1);
 834
 835         save = self.flags;
 836         self.flags = self.flags - (self.flags & FL_CLIENT);
 837         bot_relinkplayerlist();
 838         self.flags = save;
 839
 840         // remove laserdot
 841         if(self.weaponentity)
 842                 if(self.weaponentity.lasertarget)
 843                         remove(self.weaponentity.lasertarget);
 844
 845         if(cvar("g_arena"))
 846         {
 847                 Spawnqueue_Unmark(self);
 848                 Spawnqueue_Remove(self);
 849         }
 850
 851         // free cvars
 852         GetCvars(-1);
 853 }
 854
 855 .float buttonchat;
 856 void() ChatBubbleThink =
 857 {
 858         self.nextthink = time;
 859         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
 860         {
 861                 self.owner.chatbubbleentity = world;
 862                 remove(self);
 863                 return;
 864         }
 865         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
 866         if (self.owner.buttonchat && !self.owner.deadflag)
 867                 self.model = self.mdl;
 868         else
 869                 self.model = "";
 870 };
 871
 872 void() UpdateChatBubble =
 873 {
 874         if (!self.modelindex)
 875                 return;
 876         // spawn a chatbubble entity if needed
 877         if (!self.chatbubbleentity)
 878         {
 879                 self.chatbubbleentity = spawn();
 880                 self.chatbubbleentity.owner = self;
 881                 self.chatbubbleentity.exteriormodeltoclient = self;
 882                 self.chatbubbleentity.think = ChatBubbleThink;
 883                 self.chatbubbleentity.nextthink = time;
 884                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr");
 885                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 886                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
 887                 self.chatbubbleentity.model = "";
 888         }
 889 }
 890
 891
 892 void() TeamBubbleThink =
 893 {
 894         self.nextthink = time;
 895         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
 896         {
 897                 self.owner.teambubbleentity = world;
 898                 remove(self);
 899                 return;
 900         }
 901 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
 902         if (self.owner.buttonchat || self.owner.deadflag)
 903                 self.model = "";
 904         else
 905                 self.model = self.mdl;
 906
 907 };
 908
 909 float() TeamBubble_customizeentityforclient
 910 {
 911         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
 912 }
 913
 914 void() UpdateTeamBubble =
 915 {
 916         if (!self.modelindex || !cvar("teamplay"))
 917                 return;
 918         // spawn a teambubble entity if needed
 919         if (!self.teambubbleentity && cvar("teamplay"))
 920         {
 921                 self.teambubbleentity = spawn();
 922                 self.teambubbleentity.owner = self;
 923                 self.teambubbleentity.exteriormodeltoclient = self;
 924                 self.teambubbleentity.think = TeamBubbleThink;
 925                 self.teambubbleentity.nextthink = time;
 926                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr");
 927 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 928                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
 929                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
 930                 self.teambubbleentity.mdl = self.teambubbleentity.model;
 931                 self.teambubbleentity.model = self.teambubbleentity.mdl;
 932                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
 933         }
 934 }
 935
 936 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
 937 // added to the model skins
 938 /*void() UpdateColorModHack =
 939 {
 940         local float c;
 941         c = self.clientcolors & 15;
 942         // LordHavoc: only bothering to support white, green, red, yellow, blue
 943              if (teamplay == 0) self.colormod = '0 0 0';
 944         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
 945         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
 946         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
 947         else if (c == 12) self.colormod = '1.22 1.22 0.10';
 948         else if (c == 13) self.colormod = '0.10 0.10 1.73';
 949         else self.colormod = '1 1 1';
 950 };*/
 951
 952 void respawn(void)
 953 {
 954         CopyBody(1);
 955         PutClientInServer();
 956 }
 957
 958 void player_powerups (void)
 959 {
 960         if (cvar("g_minstagib"))
 961         {
 962                 self.effects = EF_FULLBRIGHT;
 963                 if (self.items & IT_STRENGTH)
 964                 {
 965                         if (time > self.strength_finished)
 966                         {
 967                                 self.alpha = default_player_alpha;
 968                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 969                                 self.items = self.items - (self.items & IT_STRENGTH);
 970                                 sprint(self, "^3Invisibility has worn off\n");
 971                         }
 972                 }
 973                 else
 974                 {
 975                         if (time < self.strength_finished)
 976                         {
 977                                 self.alpha = cvar("g_minstagib_invis_alpha");
 978                                 self.exteriorweaponentity.alpha = cvar("g_minstagib_invis_alpha");
 979                                 self.items = self.items | IT_STRENGTH;
 980                                 sprint(self, "^3You are invisible\n");
 981                         }
 982                 }
 983
 984                 if (self.items & IT_INVINCIBLE)
 985                 {
 986                         if (time > self.invincible_finished)
 987                         {
 988                                 self.items = self.items - (self.items & IT_INVINCIBLE);
 989                                 sprint(self, "^3Speed has worn off\n");
 990                         }
 991                 }
 992                 else
 993                 {
 994                         if (time < self.invincible_finished)
 995                         {
 996                                 self.items = self.items | IT_INVINCIBLE;
 997                                 sprint(self, "^3You are on speed\n");
 998                         }
 999                 }
1000                 return;
1001         }
1002
1003         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
1004         if (self.items & IT_STRENGTH)
1005         {
1006                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1007                 if (time > self.strength_finished)
1008                 {
1009                         self.items = self.items - (self.items & IT_STRENGTH);
1010                         sprint(self, "^3Strength has worn off\n");
1011                 }
1012         }
1013         else
1014         {
1015                 if (time < self.strength_finished)
1016                 {
1017                         self.items = self.items | IT_STRENGTH;
1018                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1019                 }
1020         }
1021         if (self.items & IT_INVINCIBLE)
1022         {
1023                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1024                 if (time > self.invincible_finished)
1025                 {
1026                         self.items = self.items - (self.items & IT_INVINCIBLE);
1027                         sprint(self, "^3Shield has worn off\n");
1028                 }
1029         }
1030         else
1031         {
1032                 if (time < self.invincible_finished)
1033                 {
1034                         self.items = self.items | IT_INVINCIBLE;
1035                         sprint(self, "^3Shield surrounds you\n");
1036                 }
1037         }
1038
1039         if (cvar("g_fullbrightplayers"))
1040                 self.effects = self.effects | EF_FULLBRIGHT;
1041
1042         // midair gamemode: damage only while in the air
1043         // if in midair mode, being on ground grants temporary invulnerability
1044         // (this is so that multishot weapon don't clear the ground flag on the
1045         // first damage in the frame, leaving the player vulnerable to the
1046         // remaining hits in the same frame)
1047         if (self.flags & FL_ONGROUND)
1048         if (cvar("g_midair"))
1049                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1050
1051         if (time < self.spawnshieldtime)
1052                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1053 }
1054
1055 float CalcRegen(float current, float stable, float maxv, float regenfactor)
1056 {
1057         if(current > stable)
1058                 return current;
1059         else if(current > stable - 0.25) // when close enough, "snap"
1060                 return stable;
1061         else
1062                 return bound(0, current + (stable - current) * regenfactor * frametime, maxv);
1063 }
1064
1065 void player_regen (void)
1066 {
1067         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1068         maxh = cvar("g_balance_health_stable");
1069         maxa = cvar("g_balance_armor_stable");
1070         limith = cvar("g_balance_health_limit");
1071         limita = cvar("g_balance_armor_limit");
1072
1073         if (cvar("g_minstagib") || (cvar("g_lms") && !cvar("g_lms_regenerate")))
1074                 return;
1075
1076         if(cvar("g_runematch"))
1077         {
1078                 max_mod = regen_mod = rot_mod = limit_mod = 1;
1079                 if (self.runes & RUNE_REGEN)
1080                 {
1081                         if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1082                         {
1083                                 regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1084                                 max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1085                                 limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1086                         }
1087                         else
1088                         {
1089                                 regen_mod = cvar("g_balance_rune_regen_regenrate");
1090                                 max_mod = cvar("g_balance_rune_regen_hpmod");
1091                                 limit_mod = cvar("g_balance_rune_regen_limitmod");
1092                         }
1093                 }
1094                 else if (self.runes & CURSE_VENOM)
1095                 {
1096                         max_mod = cvar("g_balance_curse_venom_hpmod");
1097                         if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1098                                 rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1099                         else
1100                                 rot_mod = cvar("g_balance_curse_venom_rotrate");
1101                         limit_mod = cvar("g_balance_curse_venom_limitmod");
1102                         //if (!self.runes & RUNE_REGEN)
1103                         //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1104                 }
1105                 maxh = maxh * max_mod;
1106                 //maxa = maxa * max_mod;
1107
1108                 if (time > self.pauserotarmor_finished)
1109                 {
1110                         if (self.armorvalue > maxa)
1111                                 self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime, 1000);
1112                 }
1113                 if (time > self.pauserothealth_finished)
1114                 {
1115                         if (self.health > maxh)
1116                                 self.health = bound(0, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime, 1000);
1117                 }
1118                 if (time > self.pauseregen_finished)
1119                 {
1120                         self.health = CalcRegen(self.health, maxh, 1000, regen_mod * cvar("g_balance_health_regen"));
1121                         self.armorvalue = CalcRegen(self.armorvalue, maxa, 1000, cvar("g_balance_armor_regen"));
1122                 }
1123         }
1124         else
1125         {
1126                 if (time > self.pauserothealth_finished)
1127                 if (self.health > maxh)
1128                         self.health = bound(0, self.health + (maxh - self.health) * cvar("g_balance_health_rot") * frametime, 1000);
1129                 if (time > self.pauserotarmor_finished)
1130                 if (self.armorvalue > maxa)
1131                         self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime, 1000);
1132                 if (time > self.pauseregen_finished)
1133                 {
1134                         self.health = CalcRegen(self.health, maxh, 1000, cvar("g_balance_health_regen"));
1135                         self.armorvalue = CalcRegen(self.armorvalue, maxa, 1000, cvar("g_balance_armor_regen"));
1136                 }
1137         }
1138
1139         if (self.health > limith)
1140                 self.health = limith;
1141         if(self.health < 1)
1142                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1143         if (self.armorvalue > limita)
1144                 self.armorvalue = limita;
1145 }
1146
1147 /*
1148 ======================
1149 spectate mode routines
1150 ======================
1151 */
1152 void SpectateCopy(entity spectatee) {
1153         self.armortype = spectatee.armortype;
1154         self.armorvalue = spectatee.armorvalue;
1155         self.currentammo = spectatee.currentammo;
1156         self.effects = spectatee.effects;
1157         self.health = spectatee.health;
1158         self.impulse = 0;
1159         self.items = spectatee.items;
1160         self.punchangle = spectatee.punchangle;
1161         self.view_ofs = spectatee.view_ofs;
1162         self.v_angle = spectatee.v_angle;
1163         self.viewzoom = spectatee.viewzoom;
1164         setorigin(self, spectatee.origin);
1165         setsize(self, spectatee.mins, spectatee.maxs);
1166 }
1167
1168 void SpectateUpdate() {
1169         if(!self.enemy)
1170                         PutObserverInServer();
1171
1172         if (self != self.enemy) {
1173                 if(self.enemy.flags & FL_NOTARGET)
1174                         PutObserverInServer();
1175                 SpectateCopy(self.enemy);
1176                 self.dmg_take = self.enemy.dmg_take;
1177                 self.dmg_save = self.enemy.dmg_save;
1178                 self.dmg_inflictor = self.enemy.dmg_inflictor;
1179                 self.fixangle = TRUE;
1180                 self.angles = self.enemy.v_angle;
1181                 //msg_entity = self;
1182                 //WriteByte(MSG_ONE, SVC_SETANGLE);
1183                 //WriteAngle(MSG_ONE, self.enemy.v_angle_x);
1184                 //WriteAngle(MSG_ONE, self.enemy.v_angle_y);
1185                 //WriteAngle(MSG_ONE, self.enemy.v_angle_z);
1186         }
1187 }
1188
1189 float SpectateNext() {
1190         other = find(self.enemy, classname, "player");
1191         if (!other) {
1192                 other = find(other, classname, "player");
1193         }
1194         if (other) {
1195                 self.enemy = other;
1196         }
1197         if(self.enemy.classname == "player") {
1198                 msg_entity = self;
1199                 WriteByte(MSG_ONE, SVC_SETVIEW);
1200                 WriteEntity(MSG_ONE, self.enemy);
1201                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1202                 SpectateUpdate();
1203                 return 1;
1204         } else {
1205                 return 0;
1206         }
1207 }
1208
1209 /*
1210 =============
1211 ShowRespawnCountdown()
1212
1213 Update a respawn countdown display.
1214 =============
1215 */
1216 void ShowRespawnCountdown()
1217 {
1218         float number;
1219         if(self.deadflag == DEAD_NO) // just respawned?
1220                 return;
1221         else
1222         {
1223                 number = ceil(self.death_time - time);
1224                 if(number <= 0)
1225                         return;
1226                 if(number <= self.respawn_countdown)
1227                 {
1228                         self.respawn_countdown = number - 1;
1229                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1230                                 stuffcmd(self, strcat("play2 announcer/robotic/", ftos(number), ".ogg\n"));
1231                 }
1232         }
1233 }
1234
1235 void LeaveSpectatorMode()
1236 {
1237         if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1238                 self.classname = "player";
1239                 if(cvar("g_campaign") || cvar("g_balance_teams"))
1240                         JoinBestTeam(self, 0);
1241                 if(cvar("g_campaign"))
1242                         campaign_bots_may_start = 1;
1243                 PutClientInServer();
1244                 if(!(self.flags & FL_NOTARGET))
1245                         bprint ("^4", self.netname, "^4 is playing now\n");
1246                 centerprint(self,"");
1247                 return;
1248         } else {
1249                 stuffcmd(self,"menu_showteamselect\n");
1250                 return;
1251         }
1252 }
1253
1254 /*
1255 =============
1256 PlayerPreThink
1257
1258 Called every frame for each client before the physics are run
1259 =============
1260 */
1261 void() ctf_setstatus;
1262 .float vote_nagtime;
1263 void PlayerPreThink (void)
1264 {
1265         if(strlen(self.netname) > 0)
1266                 if(substring(self.netname, strlen(self.netname) - 1, 1) == "^")
1267                         self.netname = strzone(strcat(substring(self.netname, 0, strlen(self.netname) - 1), " ")); // BROKEN COLORS can be annoying!
1268
1269         // version nagging
1270         if(self.version_nagtime)
1271                 if(self.cvar_g_nexuizversion)
1272                         if(time > self.version_nagtime)
1273                         {
1274                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
1275                                         if(self.cvar_g_nexuizversion != cvar_string("g_nexuizversion"))
1276                                         {
1277                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "\n");
1278                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "\n"));
1279                                         }
1280                                 self.version_nagtime = 0;
1281                         }
1282
1283         // vote nagging
1284         if(self.cvar_scr_centertime)
1285                 if(time > self.vote_nagtime)
1286                 {
1287                         VoteNag();
1288                         self.vote_nagtime = time + self.cvar_scr_centertime * 0.6;
1289                 }
1290
1291         if(self.classname == "player") {
1292                 local vector m1, m2;
1293
1294 //              if(self.netname == "Wazat")
1295 //                      bprint(self.classname, "\n");
1296
1297                 CheckRules_Player();
1298
1299                 if(self.button7)
1300                         PrintWelcomeMessage(self);
1301
1302                 if(cvar("g_lms") || !cvar("sv_spectate"))
1303                 if((time - self.jointime) <= cvar("welcome_message_time"))
1304                         PrintWelcomeMessage(self);
1305
1306                 if (intermission_running)
1307                 {
1308                         IntermissionThink ();   // otherwise a button could be missed between
1309                         return;                                 // the think tics
1310                 }
1311
1312                 Nixnex_GiveCurrentWeapon();
1313                 UpdateSelectedPlayer();
1314
1315                 if (self.deadflag != DEAD_NO)
1316                 {
1317                         float button_pressed, force_respawn;
1318                         player_anim();
1319                         button_pressed = (self.button0 || self.button2 || self.button3 || self.button6 || self.buttonuse);
1320                         force_respawn = (cvar("g_lms") || cvar("g_forced_respawn"));
1321                         if (self.deadflag == DEAD_DYING)
1322                         {
1323                                 if(force_respawn)
1324                                         self.deadflag = DEAD_RESPAWNING;
1325                                 else if(!button_pressed)
1326                                         self.deadflag = DEAD_DEAD;
1327                         }
1328                         else if (self.deadflag == DEAD_DEAD)
1329                         {
1330                                 if(button_pressed)
1331                                         self.deadflag = DEAD_RESPAWNABLE;
1332                         }
1333                         else if (self.deadflag == DEAD_RESPAWNABLE)
1334                         {
1335                                 if(!button_pressed)
1336                                         self.deadflag = DEAD_RESPAWNING;
1337                         }
1338                         else if (self.deadflag == DEAD_RESPAWNING)
1339                         {
1340                                 if(time > self.death_time)
1341                                         respawn();
1342                         }
1343                         ShowRespawnCountdown();
1344                         return;
1345                 }
1346
1347                 if(cvar("g_lms") && !self.deadflag && cvar("g_lms_campcheck_interval"))
1348                 {
1349                         vector dist;
1350
1351                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
1352                         dist = self.oldorigin - self.origin;
1353                         dist_z = 0;
1354                         self.lms_traveled_distance += fabs(vlen(dist));
1355
1356                         if(cvar("g_campaign"))
1357                         if(!campaign_bots_may_start)
1358                         {
1359                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
1360                                 self.lms_traveled_distance = 0;
1361                         }
1362
1363                         if(time > self.lms_nextcheck)
1364                         {
1365                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
1366                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
1367                                 {
1368                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
1369                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
1370                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
1371                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
1372                                 }
1373                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
1374                                 self.lms_traveled_distance = 0;
1375                         }
1376                 }
1377
1378                 if (self.button5 && !self.hook.state)
1379                 {
1380                         if (!self.crouch)
1381                         {
1382                                 self.crouch = TRUE;
1383                                 self.view_ofs = PL_CROUCH_VIEW_OFS * self.scale;
1384                                 setsize (self, PL_CROUCH_MIN * self.scale, PL_CROUCH_MAX * self.scale);
1385                         }
1386                 }
1387                 else
1388                 {
1389                         if (self.crouch)
1390                         {
1391                                 tracebox(self.origin, PL_MIN * self.scale, PL_MAX * self.scale, self.origin, FALSE, self);
1392                                 if (!trace_startsolid)
1393                                 {
1394                                         self.crouch = FALSE;
1395                                         self.view_ofs = PL_VIEW_OFS * self.scale;
1396                                         setsize (self, PL_MIN * self.scale, PL_MAX * self.scale);
1397                                 }
1398                         }
1399                 }
1400
1401                 if(cvar("sv_defaultcharacter") == 1 && !teams_matter) {
1402                         local string defaultmodel;
1403                         defaultmodel = CheckPlayerModel(cvar_string("sv_defaultplayermodel"));
1404
1405                         if (defaultmodel != self.model)
1406                         {
1407                                 m1 = self.mins;
1408                                 m2 = self.maxs;
1409                                 setmodel_lod (self, defaultmodel);
1410                                 setsize (self, m1, m2);
1411                         }
1412
1413                         if (self.skin != cvar("sv_defaultplayerskin"))
1414                                 self.skin = cvar("sv_defaultplayerskin");
1415                 } else {
1416                         if (self.playermodel != self.model)
1417                         {
1418                                 self.playermodel = CheckPlayerModel(self.playermodel);
1419                                 m1 = self.mins;
1420                                 m2 = self.maxs;
1421                                 setmodel_lod (self, self.playermodel);
1422                                 setsize (self, m1, m2);
1423                         }
1424
1425                         if(teams_matter)
1426                         {
1427                                 if (self.skin != math_mod(stof(self.playerskin), NUM_PLAYERSKINS_TEAMPLAY))
1428                                         self.skin = math_mod(stof(self.playerskin), NUM_PLAYERSKINS_TEAMPLAY);
1429                         }
1430                         else
1431                         {
1432                                 if (self.skin != stof(self.playerskin))
1433                                         self.skin = stof(self.playerskin);
1434                         }
1435                 }
1436
1437                 GrapplingHookFrame();
1438
1439                 W_WeaponFrame();
1440
1441                 if (self.button4 || (self.weapon == WEP_NEX && self.button3))
1442                 {
1443                         if (cvar("g_minstagib") && self.button3)
1444                         {
1445                                 if (self.jump_interval <= (time + 0.1))
1446                                 {
1447                                         self.jump_interval = time + 1;
1448                                         W_Laser_Attack();
1449                                 }
1450                         }
1451                         else if (self.viewzoom > 0.4)
1452                                 self.viewzoom = max (0.4, self.viewzoom - frametime * 2);
1453                 }
1454                 else if (self.viewzoom < 1.0)
1455                         self.viewzoom = min (1.0, self.viewzoom + frametime);
1456
1457                 player_powerups();
1458                 player_regen();
1459                 player_anim();
1460
1461                 if (cvar("g_minstagib"))
1462                         minstagib_ammocheck();
1463
1464                 ctf_setstatus();
1465
1466                 //self.angles_y=self.v_angle_y + 90;   // temp
1467
1468                 //if (TetrisPreFrame()) return;
1469         } else if(gameover) {
1470                 if (intermission_running)
1471                         IntermissionThink ();   // otherwise a button could be missed between
1472                 return;
1473         } else if(self.classname == "observer") {
1474
1475                 if (self.flags & FL_JUMPRELEASED) {
1476                         if (self.button2 && self.version == cvar("gameversion")) {
1477                                 self.welcomemessage_time = 0;
1478                                 self.flags = self.flags - FL_JUMPRELEASED;
1479                                 LeaveSpectatorMode();
1480                                 return;
1481                         } else if(self.button0 && self.version == cvar("gameversion")) {
1482                                 self.welcomemessage_time = 0;
1483                                 self.flags = self.flags - FL_JUMPRELEASED;
1484                                 if(SpectateNext() == 1) {
1485                                         self.classname = "spectator";
1486                                 }
1487                         }
1488                 } else {
1489                         if (!(self.button0 || self.button2)) {
1490                                 self.flags = self.flags | FL_JUMPRELEASED;
1491                         }
1492                 }
1493                 PrintWelcomeMessage(self);
1494         } else if(self.classname == "spectator") {
1495                 if (self.flags & FL_JUMPRELEASED) {
1496                         if (self.button2 && self.version == cvar("gameversion")) {
1497                                 self.welcomemessage_time = 0;
1498                                 self.flags = self.flags - FL_JUMPRELEASED;
1499                                 LeaveSpectatorMode();
1500                                 return;
1501                         } else if(self.button0) {
1502                                 self.welcomemessage_time = 0;
1503                                 self.flags = self.flags - FL_JUMPRELEASED;
1504                                 if(SpectateNext() == 1) {
1505                                         self.classname = "spectator";
1506                                 } else {
1507                                         self.classname = "observer";
1508                                         PutClientInServer();
1509                                 }
1510                         } else if (self.button3) {
1511                                 self.welcomemessage_time = 0;
1512                                 self.flags = self.flags - FL_JUMPRELEASED;
1513                                 self.classname = "observer";
1514                                 PutClientInServer();
1515                         } else {
1516                                 SpectateUpdate();
1517                         }
1518                 } else {
1519                         if (!(self.button0 || self.button3)) {
1520                                 self.flags = self.flags | FL_JUMPRELEASED;
1521                         }
1522                 }
1523                 PrintWelcomeMessage(self);
1524                 self.flags = self.flags | FL_CLIENT | FL_NOTARGET;
1525         }
1526 }
1527
1528
1529 /*
1530 =============
1531 PlayerPostThink
1532
1533 Called every frame for each client after the physics are run
1534 =============
1535 */
1536 void PlayerPostThink (void)
1537 {
1538         // Savage: Check for nameless players
1539         if (strlen(self.netname) < 1) {
1540                 self.netname = "Player";
1541                 stuffcmd(self, "seta _cl_name Player\n");
1542         }
1543
1544         if(self.classname == "player") {
1545                 CheckRules_Player();
1546                 UpdateChatBubble();
1547                 UpdateTeamBubble();
1548                 if (self.deadflag == DEAD_NO)
1549                 if (self.impulse)
1550                         ImpulseCommands ();
1551                 if (intermission_running)
1552                         return;         // intermission or finale
1553
1554                 //PrintWelcomeMessage(self);
1555                 //if (TetrisPostFrame()) return;
1556         } else if (self.classname == "observer") {
1557                 //do nothing
1558         } else if (self.classname == "spectator") {
1559                 //do nothing
1560         }
1561         Arena_Warmup();
1562 }