data/qcsrc/server/cl_client.qc

   1 void info_player_start (void)
   2 {
   3         self.classname = "info_player_deathmatch";
   4         relocate_spawnpoint();
   5 }
   6
   7 void info_player_deathmatch (void)
   8 {
   9         relocate_spawnpoint();
  10 }
  11
  12 float spawn_allbad;
  13 float spawn_allgood;
  14 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
  15 {
  16         local entity spot, player, nextspot, previousspot, newfirstspot;
  17         local float pcount;
  18         spot = firstspot;
  19         newfirstspot = world;
  20         previousspot = world;
  21         spawn_allgood = TRUE;
  22         spawn_allbad = TRUE;
  23         while (spot)
  24         {
  25                 nextspot = spot.chain;
  26                 // count team mismatches as bad spots
  27                 if (spot.team == teamcheck)
  28                 {
  29                         pcount = 0;
  30                         player = playerlist;
  31                         while (player)
  32                         {
  33                                 if (player != self)
  34                                 if (vlen(player.origin - spot.origin) < mindist)
  35                                         pcount = pcount + 1;
  36                                 player = player.chain;
  37                         }
  38                         if (!pcount)
  39                         {
  40                                 spawn_allbad = FALSE;
  41                                 if (newfirstspot)
  42                                         previousspot.chain = spot;
  43                                 else
  44                                         newfirstspot = spot;
  45                                 previousspot = spot;
  46                                 spot.chain = world;
  47                         }
  48                         else
  49                                 spawn_allgood = FALSE;
  50                 }
  51                 spot = nextspot;
  52         }
  53         // if we couldn't find ANY good points, return the original list
  54         if (!newfirstspot)
  55                 newfirstspot = firstspot;
  56         return newfirstspot;
  57 }
  58
  59 entity Spawn_RandomPoint(entity firstspot)
  60 {
  61         local entity spot;
  62         local float numspots;
  63         // count number of spots
  64         numspots = 0;
  65         spot = firstspot;
  66         while (spot)
  67         {
  68                 numspots = numspots + 1;
  69                 spot = spot.chain;
  70         }
  71         // pick a random one
  72         numspots = numspots * random();
  73         spot = firstspot;
  74         while (spot.chain && numspots >= 1)
  75         {
  76                 numspots = numspots - 1;
  77                 spot = spot.chain;
  78         }
  79         return spot;
  80 }
  81
  82 entity Spawn_FurthestPoint(entity firstspot, entity playerlist)
  83 {
  84         local entity best, spot, player;
  85         local float bestrating, rating;
  86         best = world;
  87         bestrating = -1000000;
  88         spot = firstspot;
  89         while (spot)
  90         {
  91                 rating = 1000000000;
  92                 player = playerlist;
  93                 while (player)
  94                 {
  95                         if (player != self)
  96                                 rating = min(rating, vlen(player.origin - spot.origin));
  97                         player = player.chain;
  98                 }
  99                 rating = rating + random() * 16;
 100                 if (bestrating < rating)
 101                 {
 102                         best = spot;
 103                         bestrating = rating;
 104                 }
 105                 spot = spot.chain;
 106         }
 107         return best;
 108 }
 109
 110 /*
 111 =============
 112 SelectSpawnPoint
 113
 114 Finds a point to respawn
 115 =============
 116 */
 117 entity SelectSpawnPoint (float anypoint)
 118 {
 119         local float teamcheck;
 120         local entity spot, firstspot, playerlist;
 121
 122         spot = find (world, classname, "testplayerstart");
 123         if (spot)
 124                 return spot;
 125
 126         teamcheck = 0;
 127
 128         if(!anypoint && cvar("g_ctf") )
 129                 teamcheck = self.team;
 130
 131         // get the list of players
 132         playerlist = findchain(classname, "player");
 133         // get the entire list of spots
 134         firstspot = findchain(classname, "info_player_deathmatch");
 135         // filter out the bad ones
 136         // (note this returns the original list if none survived)
 137         firstspot = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 138
 139         // there is 50/50 chance of choosing a random spot or the furthest spot
 140         // (this means that roughly every other spawn will be furthest, so you
 141         // usually won't get fragged at spawn twice in a row)
 142         if (arena_roundbased)
 143         {
 144                 firstspot = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 145                 spot = Spawn_RandomPoint(firstspot);
 146         }
 147         else if (random() > 0.5 || spawn_allbad || spawn_allgood)
 148                 spot = Spawn_RandomPoint(firstspot);
 149         else
 150                 spot = Spawn_FurthestPoint(firstspot, playerlist);
 151
 152         if (!spot)
 153         {
 154                 if(cvar("spawn_debug"))
 155                         GotoNextMap();
 156                 else
 157                         error ("PutClientInServer: no start points on level");
 158         }
 159
 160         return spot;
 161 }
 162
 163 /*
 164 =============
 165 CheckPlayerModel
 166
 167 Checks if the argument string can be a valid playermodel.
 168 Returns a valid one in doubt.
 169 =============
 170 */
 171 string FallbackPlayerModel = "models/player/marine.zym";
 172 string CheckPlayerModel(string plyermodel) {
 173         if(strlen(plyermodel) < 4)
 174                 return FallbackPlayerModel;
 175         if( substring(plyermodel,0,14) != "models/player/")
 176                 return FallbackPlayerModel;
 177         else if(cvar("sv_servermodelsonly"))
 178         {
 179                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 180                         return FallbackPlayerModel;
 181                 if(!fexists(plyermodel))
 182                         return FallbackPlayerModel;
 183         }
 184         return plyermodel;
 185 }
 186
 187 /*
 188 =============
 189 Client_customizeentityforclient
 190
 191 LOD reduction
 192 =============
 193 */
 194 float Client_customizeentityforclient()
 195 {
 196 #ifdef ALLOW_VARIABLE_LOD
 197         // self: me
 198         // other: the player viewing me
 199         float distance;
 200         float f;
 201
 202         if(self.flags & FL_NOTARGET) // we don't need LOD for spectators
 203                 return TRUE;
 204
 205         if(other.cvar_cl_playerdetailreduction <= 0)
 206         {
 207                 if(other.cvar_cl_playerdetailreduction <= -2)
 208                         self.modelindex = self.modelindex_lod2;
 209                 else if(other.cvar_cl_playerdetailreduction <= -1)
 210                         self.modelindex = self.modelindex_lod1;
 211                 else
 212                         self.modelindex = self.modelindex_lod0;
 213         }
 214         else
 215         {
 216                 distance = vlen(self.origin - other.origin);
 217                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 218                 if(f > 10000)
 219                         self.modelindex = self.modelindex_lod2;
 220                 else if(f > 5000)
 221                         self.modelindex = self.modelindex_lod1;
 222                 else
 223                         self.modelindex = self.modelindex_lod0;
 224         }
 225 #endif
 226
 227         return TRUE;
 228 }
 229
 230 void setmodel_lod(entity e, string modelname)
 231 {
 232 #ifdef ALLOW_VARIABLE_LOD
 233         string s;
 234
 235         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1.zym");
 236         if(fexists(s))
 237         {
 238                 precache_model(s);
 239                 setmodel(e, s);
 240                 self.modelindex_lod1 = self.modelindex;
 241         }
 242         else
 243                 self.modelindex_lod1 = -1;
 244
 245         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2.zym");
 246         if(fexists(s))
 247         {
 248                 precache_model(s);
 249                 setmodel(e, s);
 250                 self.modelindex_lod2 = self.modelindex;
 251         }
 252         else
 253                 self.modelindex_lod2 = -1;
 254
 255         precache_model(modelname);
 256         setmodel(e, modelname);
 257         self.modelindex_lod0 = self.modelindex;
 258
 259         if(self.modelindex_lod1 < 0)
 260                 self.modelindex_lod1 = self.modelindex;
 261
 262         if(self.modelindex_lod2 < 0)
 263                 self.modelindex_lod2 = self.modelindex;
 264 #else
 265         precache_model(modelname);
 266         setmodel(e, modelname);
 267 #endif
 268 }
 269
 270 /*
 271 =============
 272 PutObserverInServer
 273
 274 putting a client as observer in the server
 275 =============
 276 */
 277 void PutObserverInServer (void)
 278 {
 279         entity  spot;
 280         spot = SelectSpawnPoint (FALSE);
 281         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 282
 283         if(clienttype(self) == CLIENTTYPE_REAL)
 284         {
 285                 msg_entity = self;
 286                 WriteByte(MSG_ONE, SVC_SETVIEW);
 287                 WriteEntity(MSG_ONE, self);
 288         }
 289
 290         DropAllRunes(self);
 291
 292         if(self.flagcarried)
 293                 DropFlag(self.flagcarried);
 294
 295         DistributeFragsAmongTeam(self, self.team, 1);
 296
 297         if(self.frags <= 0 && self.frags > -666 && cvar("g_lms") && self.killcount != -666)
 298                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 299         else if(self.killcount != -666)
 300                 bprint ("^4", self.netname, "^4 is spectating now\n");
 301
 302         self.classname = "observer";
 303         self.health = -666;
 304         self.takedamage = DAMAGE_NO;
 305         self.solid = SOLID_NOT;
 306         self.movetype = MOVETYPE_NOCLIP;
 307         self.flags = FL_CLIENT | FL_NOTARGET;
 308         self.armorvalue = 666;
 309         self.effects = 0;
 310         self.armorvalue = cvar("g_balance_armor_start");
 311         self.pauserotarmor_finished = 0;
 312         self.pauserothealth_finished = 0;
 313         self.pauseregen_finished = 0;
 314         self.damageforcescale = 0;
 315         self.death_time = 0;
 316         self.dead_time = 0;
 317         self.dead_frame = 0;
 318         self.die_frame = 0;
 319         self.deaths = 0;
 320         self.alpha = 0;
 321         self.scale = 0;
 322         self.fade_time = 0;
 323         self.pain_frame = 0;
 324         self.pain_finished = 0;
 325         self.strength_finished = 0;
 326         self.invincible_finished = 0;
 327         self.pushltime = 0;
 328         self.think = SUB_Null;
 329         self.nextthink = 0;
 330         self.hook_time = 0;
 331         self.runes = 0;
 332         self.deadflag = DEAD_NO;
 333         self.angles = spot.angles;
 334         self.angles_z = 0;
 335         self.fixangle = TRUE;
 336         self.crouch = FALSE;
 337
 338         self.view_ofs = PL_VIEW_OFS;
 339         setorigin (self, spot.origin);
 340         setsize (self, '0 0 0', '0 0 0');
 341         self.oldorigin = self.origin;
 342         self.items = 0;
 343         self.model = "";
 344         self.modelindex = 0;
 345         self.weapon = 0;
 346         self.weaponmodel = "";
 347         self.weaponentity = world;
 348         self.killcount = -666;
 349         self.velocity = '0 0 0';
 350         self.avelocity = '0 0 0';
 351         self.punchangle = '0 0 0';
 352         self.punchvector = '0 0 0';
 353         self.oldvelocity = self.velocity;
 354         self.customizeentityforclient = Client_customizeentityforclient;
 355
 356         if(cvar("g_arena"))
 357         {
 358                 if(self.frags != -2)
 359                 {
 360                         Spawnqueue_Insert(self);
 361                 }
 362                 else
 363                 {
 364                         Spawnqueue_Unmark(self);
 365                         Spawnqueue_Remove(self);
 366                 }
 367         }
 368         else if(!cvar("g_lms"))
 369                 self.frags = -666;
 370 }
 371
 372
 373 /*
 374 =============
 375 PutClientInServer
 376
 377 Called when a client spawns in the server
 378 =============
 379 */
 380 void PutClientInServer (void)
 381 {
 382         if(clienttype(self) == CLIENTTYPE_BOT)
 383         {
 384                 self.classname = "player";
 385         }
 386         else if(clienttype(self) == CLIENTTYPE_REAL)
 387         {
 388                 msg_entity = self;
 389                 WriteByte(MSG_ONE, SVC_SETVIEW);
 390                 WriteEntity(MSG_ONE, self);
 391         }
 392
 393         // player is dead and becomes observer
 394         if(cvar("g_lms") && self.frags < 1)
 395                 self.classname = "observer";
 396
 397         if(cvar("g_arena"))
 398         if(!self.spawned)
 399                 self.classname = "observer";
 400
 401         if(self.classname == "player") {
 402                 entity  spot;
 403
 404                 spot = SelectSpawnPoint (FALSE);
 405
 406                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 407
 408                 self.classname = "player";
 409                 self.iscreature = TRUE;
 410                 self.movetype = MOVETYPE_WALK;
 411                 self.solid = SOLID_SLIDEBOX;
 412                 self.flags = FL_CLIENT;
 413                 self.takedamage = DAMAGE_AIM;
 414                 self.effects = 0;
 415                 self.health = cvar("g_balance_health_start");
 416                 self.armorvalue = cvar("g_balance_armor_start");
 417                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 418                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 419                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 420                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 421                 self.damageforcescale = 2;
 422                 self.death_time = 0;
 423                 self.dead_time = 0;
 424                 self.dead_frame = 0;
 425                 self.die_frame = 0;
 426                 self.alpha = 0;
 427                 self.scale = 0;
 428                 self.fade_time = 0;
 429                 self.pain_frame = 0;
 430                 self.pain_finished = 0;
 431                 self.strength_finished = 0;
 432                 self.invincible_finished = 0;
 433                 self.pushltime = 0;
 434                 //self.speed_finished = 0;
 435                 //self.slowmo_finished = 0;
 436                 // players have no think function
 437                 self.think = SUB_Null;
 438                 self.nextthink = 0;
 439                 self.weapon = 0;
 440                 self.switchweapon = 0;
 441                 self.hook_time = 0;
 442
 443                 self.runes = 0;
 444
 445                 self.deadflag = DEAD_NO;
 446
 447                 self.angles = spot.angles;
 448
 449                 self.angles_z = 0; // never spawn tilted even if the spot says to
 450                 self.fixangle = TRUE; // turn this way immediately
 451                 self.velocity = '0 0 0';
 452                 self.avelocity = '0 0 0';
 453                 self.punchangle = '0 0 0';
 454                 self.punchvector = '0 0 0';
 455                 self.oldvelocity = self.velocity;
 456
 457                 self.viewzoom = 0.6;
 458
 459                 self.customizeentityforclient = Client_customizeentityforclient;
 460
 461                 if(cvar("sv_defaultcharacter") == 1 && !teams_matter) {
 462                         local string defaultmodel;
 463                         defaultmodel = CheckPlayerModel(cvar_string("sv_defaultplayermodel"));
 464                         setmodel_lod (self, defaultmodel);
 465                         self.skin = stof(cvar_string("sv_defaultplayerskin"));
 466                 } else {
 467                         self.playermodel = CheckPlayerModel(self.playermodel);
 468                         setmodel_lod (self, self.playermodel);
 469                         if(teams_matter)
 470                                 self.skin = math_mod(stof(self.playerskin), NUM_PLAYERSKINS_TEAMPLAY);
 471                         else
 472                                 self.skin = stof(self.playerskin);
 473                 }
 474
 475                 self.crouch = FALSE;
 476                 self.view_ofs = PL_VIEW_OFS;
 477                 setsize (self, PL_MIN, PL_MAX);
 478                 self.spawnorigin = spot.origin;
 479                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 480                 // don't reset back to last position, even if new position is stuck in solid
 481                 self.oldorigin = self.origin;
 482
 483                 if(cvar("g_lms"))
 484                 {
 485                         self.ammo_shells = cvar("g_lms_start_ammo_shells");
 486                         self.ammo_nails = cvar("g_lms_start_ammo_nails");
 487                         self.ammo_rockets = cvar("g_lms_start_ammo_rockets");
 488                         self.ammo_cells = cvar("g_lms_start_ammo_cells");
 489                         self.health = cvar("g_lms_start_health");
 490                         self.armorvalue = cvar("g_lms_start_armor");
 491                 }
 492                 else if (cvar("g_use_ammunition")) {
 493                         self.ammo_shells = cvar("g_start_ammo_shells");
 494                         self.ammo_nails = cvar("g_start_ammo_nails");
 495                         self.ammo_rockets = cvar("g_start_ammo_rockets");
 496                         self.ammo_cells = cvar("g_start_ammo_cells");
 497                 } else {
 498                         self.ammo_shells = 999;
 499                         self.ammo_nails = 999;
 500                         self.ammo_rockets = 999;
 501                         self.ammo_cells = 999;
 502                 }
 503
 504                 self.items = 0;
 505                 if (cvar("g_start_weapon_laser") || cvar("g_lms"))
 506                 {
 507                         self.items = self.items | IT_LASER;
 508                         self.switchweapon = WEP_LASER;
 509                 }
 510                 if (cvar("g_start_weapon_shotgun") || cvar("g_lms"))
 511                 {
 512                         self.items = self.items | IT_SHOTGUN;
 513                         self.switchweapon = WEP_SHOTGUN;
 514                 }
 515                 if (cvar("g_start_weapon_uzi") || cvar("g_lms"))
 516                 {
 517                         self.items = self.items | IT_UZI;
 518                         self.switchweapon = WEP_UZI;
 519                 }
 520                 if (cvar("g_start_weapon_grenadelauncher") || cvar("g_lms"))
 521                 {
 522                         self.items = self.items | IT_GRENADE_LAUNCHER;
 523                         self.switchweapon = WEP_GRENADE_LAUNCHER;
 524                 }
 525                 if (cvar("g_start_weapon_electro") || cvar("g_lms"))
 526                 {
 527                         self.items = self.items | IT_ELECTRO;
 528                         self.switchweapon = WEP_ELECTRO;
 529                 }
 530                 if (cvar("g_start_weapon_crylink") || cvar("g_lms"))
 531                 {
 532                         self.items = self.items | IT_CRYLINK;
 533                         self.switchweapon = WEP_CRYLINK;
 534                 }
 535                 if (cvar("g_start_weapon_nex") || cvar("g_lms"))
 536                 {
 537                         self.items = self.items | IT_NEX;
 538                         self.switchweapon = WEP_NEX;
 539                 }
 540                 if (cvar("g_start_weapon_hagar") || cvar("g_lms"))
 541                 {
 542                         self.items = self.items | IT_HAGAR;
 543                         self.switchweapon = WEP_HAGAR;
 544                 }
 545                 if (cvar("g_start_weapon_rocketlauncher") || cvar("g_lms"))
 546                 {
 547                         self.items = self.items | IT_ROCKET_LAUNCHER;
 548                         self.switchweapon = WEP_ROCKET_LAUNCHER;
 549                 }
 550
 551                 if(cvar("g_instagib"))
 552                 {
 553                         self.items = IT_NEX;
 554                         self.switchweapon = WEP_NEX;
 555                         self.ammo_cells = 999;
 556                 }
 557
 558                 if(cvar("g_rocketarena"))
 559                 {
 560                         self.items = IT_ROCKET_LAUNCHER;
 561                         self.switchweapon = WEP_ROCKET_LAUNCHER;
 562                         self.ammo_rockets = 999;
 563                 }
 564
 565                 if(cvar("g_nixnex"))
 566                 {
 567                         self.items = 0;
 568                         // will be done later
 569                 }
 570
 571                 if(cvar("g_minstagib"))
 572                 {
 573                         self.health = 100;
 574                         self.armorvalue = 0;
 575                         self.items = IT_NEX;
 576                         self.switchweapon = WEP_NEX;
 577                         self.ammo_cells = cvar("g_minstagib_ammo_start");
 578                         self.jump_interval = time;
 579                 }
 580
 581                 if(cvar("g_arena"))
 582                 {
 583                         Spawnqueue_Remove(self);
 584                         Spawnqueue_Mark(self);
 585                 }
 586
 587                 self.event_damage = PlayerDamage;
 588
 589                 self.bot_attack = TRUE;
 590
 591                 self.statdraintime = time + 5;
 592                 self.button0 = self.button1 = self.button2 = self.button3 = 0;
 593
 594                 if(self.killcount == -666) {
 595                         self.killcount = 0;
 596                         if(!cvar("g_arena"))
 597                         if(!cvar("g_lms"))
 598                                 self.frags = 0;
 599                 }
 600
 601                 self.cnt = WEP_LASER;
 602                 self.nixnex_lastchange_id = -1;
 603
 604                 CL_SpawnWeaponentity();
 605                 self.alpha = default_player_alpha;
 606                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 607
 608                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 609                 self.lms_traveled_distance = 0;
 610
 611                 if(cvar("spawn_debug"))
 612                 {
 613                                 sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 614                                 remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 615                 }
 616
 617                 //stuffcmd(self, "chase_active 0");
 618                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 619         } else if(self.classname == "observer") {
 620                 PutObserverInServer ();
 621         }
 622 }
 623
 624 /*
 625 =============
 626 SetNewParms
 627 =============
 628 */
 629 void SetNewParms (void)
 630 {
 631
 632 }
 633
 634 /*
 635 =============
 636 SetChangeParms
 637 =============
 638 */
 639 void SetChangeParms (void)
 640 {
 641
 642 }
 643
 644 /*
 645 =============
 646 ClientKill
 647
 648 Called when a client types 'kill' in the console
 649 =============
 650 */
 651 void ClientKill (void)
 652 {
 653         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 654 }
 655
 656 void FixClientCvars(entity e)
 657 {
 658         // send prediction settings to the client
 659         stuffcmd(e, "\nin_bindmap 0 0\n");
 660         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
 661         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
 662         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
 663         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
 664         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
 665         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
 666         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
 667         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("g_balance_jumpheight")), "\n"));
 668         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
 669         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
 670         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
 671         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
 672         stuffcmd(e, "cl_movement_edgefriction 1\n");
 673 }
 674
 675 /*
 676 =============
 677 ClientConnect
 678
 679 Called when a client connects to the server
 680 =============
 681 */
 682 string ColoredTeamName(float t);
 683 //void dom_player_join_team(entity pl);
 684 void ClientConnect (void)
 685 {
 686         local string s;
 687
 688         self.classname = "player_joining";
 689         self.flags = self.flags | FL_CLIENT;
 690         self.version_nagtime = time + 10 + random() * 10;
 691
 692         if(player_count<0)
 693         {
 694                 dprint("BUG player count is lower than zero, this cannot happen!\n");
 695                 player_count = 0;
 696         }
 697
 698         bot_clientconnect();
 699
 700         //if(cvar("g_domination"))
 701         //      dom_player_join_team(self);
 702
 703         //JoinBestTeam(self, FALSE);
 704
 705         if((cvar("sv_spectate") == 1 && !cvar("g_lms")) || cvar("g_campaign")) {
 706                 self.classname = "observer";
 707         } else {
 708                 self.classname = "player";
 709                 campaign_bots_may_start = 1;
 710         }
 711
 712         self.playerid = (playerid_last = playerid_last + 1);
 713         if(cvar("sv_eventlog"))
 714         {
 715                 if(clienttype(self) == CLIENTTYPE_REAL)
 716                         s = "player";
 717                 else
 718                         s = "bot";
 719                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", s, ":", self.netname), TRUE);
 720                 s = strcat(":team:", ftos(self.playerid), ":");
 721                 s = strcat(s, ftos(self.team));
 722                 GameLogEcho(s, FALSE);
 723         }
 724
 725         //stuffcmd(self, "set tmpviewsize $viewsize \n");
 726
 727         bprint ("^4",self.netname);
 728         bprint ("^4 connected");
 729
 730         if(cvar("g_domination") || cvar("g_ctf"))
 731         {
 732                 bprint(" and joined the ");
 733                 bprint(ColoredTeamName(self.team));
 734         }
 735
 736         bprint("\n");
 737
 738         self.welcomemessage_time = 0;
 739
 740         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
 741         // TODO: is this being used for anything else than cd tracks?
 742         // Remember: SVC_CDTRACK exists. Maybe it should be used.
 743
 744         FixClientCvars(self);
 745
 746         // Wazat's grappling hook
 747         SetGrappleHookBindings();
 748
 749         // get autoswitch state from player
 750         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1; cmd autoswitch $1\"\n");
 751         stuffcmd(self, "cmd autoswitch $cl_autoswitch\n");
 752
 753         // get version info from player
 754         stuffcmd(self, "cmd clientversion $gameversion\n");
 755
 756         // get other cvars from player
 757         GetCvars(0);
 758
 759         // set cvar for team scoreboard
 760         if (teams_matter)
 761         {
 762                 local float t;
 763                 t = cvar("teamplay");
 764                 // we have to stuff the correct teamplay value because if this is a listen server, this changes the teamplay mode of the server itself, which is bad
 765                 stuffcmd(self, strcat("set teamplay ", ftos(t), "\n"));
 766         }
 767         else
 768                 stuffcmd(self, "set teamplay 0\n");
 769
 770         if(cvar("g_lms"))
 771         {
 772                 self.frags = cvar("fraglimit");
 773                 // no fraglimit was set, so player gets 999 lives
 774                 if(self.frags < 1)
 775                         self.frags = 999;
 776
 777                 self.frags = LMS_NewPlayerLives();
 778                 if(!self.frags)
 779                 {
 780                         self.frags = -666;
 781                 }
 782         }
 783         else if(cvar("g_arena"))
 784         {
 785                 self.classname = "observer";
 786                 Spawnqueue_Insert(self);
 787         }
 788
 789         bot_relinkplayerlist();
 790
 791         self.jointime = time;
 792 }
 793
 794 /*
 795 =============
 796 ClientDisconnect
 797
 798 Called when a client disconnects from the server
 799 =============
 800 */
 801 void(entity e) DropFlag;
 802 .entity chatbubbleentity;
 803 .entity teambubbleentity;
 804 void ClientDisconnect (void)
 805 {
 806         float save;
 807         if(cvar("sv_eventlog"))
 808                 GameLogEcho(strcat(":part:", ftos(self.playerid)), FALSE);
 809         bprint ("^4",self.netname);
 810         bprint ("^4 disconnected\n");
 811
 812         if (self.chatbubbleentity)
 813         {
 814                 remove (self.chatbubbleentity);
 815                 self.chatbubbleentity = world;
 816         }
 817
 818         if (self.teambubbleentity)
 819         {
 820                 remove (self.teambubbleentity);
 821                 self.teambubbleentity = world;
 822         }
 823
 824         DropAllRunes(self);
 825
 826         if(self.flagcarried)
 827                 DropFlag(self.flagcarried);
 828
 829         DistributeFragsAmongTeam(self, self.team, 1);
 830
 831         save = self.flags;
 832         self.flags = self.flags - (self.flags & FL_CLIENT);
 833         bot_relinkplayerlist();
 834         self.flags = save;
 835
 836         // remove laserdot
 837         if(self.weaponentity)
 838                 if(self.weaponentity.lasertarget)
 839                         remove(self.weaponentity.lasertarget);
 840
 841         if(cvar("g_arena"))
 842         {
 843                 Spawnqueue_Unmark(self);
 844                 Spawnqueue_Remove(self);
 845         }
 846
 847         // free cvars
 848         GetCvars(-1);
 849 }
 850
 851 .float buttonchat;
 852 void() ChatBubbleThink =
 853 {
 854         self.nextthink = time;
 855         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
 856         {
 857                 self.owner.chatbubbleentity = world;
 858                 remove(self);
 859                 return;
 860         }
 861         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
 862         if (self.owner.buttonchat && !self.owner.deadflag)
 863                 self.model = self.mdl;
 864         else
 865                 self.model = "";
 866 };
 867
 868 void() UpdateChatBubble =
 869 {
 870         if (!self.modelindex)
 871                 return;
 872         // spawn a chatbubble entity if needed
 873         if (!self.chatbubbleentity)
 874         {
 875                 self.chatbubbleentity = spawn();
 876                 self.chatbubbleentity.owner = self;
 877                 self.chatbubbleentity.exteriormodeltoclient = self;
 878                 self.chatbubbleentity.think = ChatBubbleThink;
 879                 self.chatbubbleentity.nextthink = time;
 880                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr");
 881                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 882                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
 883                 self.chatbubbleentity.model = "";
 884         }
 885 }
 886
 887
 888 void() TeamBubbleThink =
 889 {
 890         self.nextthink = time;
 891         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
 892         {
 893                 self.owner.teambubbleentity = world;
 894                 remove(self);
 895                 return;
 896         }
 897 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
 898         if (self.owner.buttonchat || self.owner.deadflag)
 899                 self.model = "";
 900         else
 901                 self.model = self.mdl;
 902
 903 };
 904
 905 float() TeamBubble_customizeentityforclient
 906 {
 907         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
 908 }
 909
 910 void() UpdateTeamBubble =
 911 {
 912         if (!self.modelindex || !cvar("teamplay"))
 913                 return;
 914         // spawn a teambubble entity if needed
 915         if (!self.teambubbleentity && cvar("teamplay"))
 916         {
 917                 self.teambubbleentity = spawn();
 918                 self.teambubbleentity.owner = self;
 919                 self.teambubbleentity.exteriormodeltoclient = self;
 920                 self.teambubbleentity.think = TeamBubbleThink;
 921                 self.teambubbleentity.nextthink = time;
 922                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr");
 923 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 924                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
 925                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
 926                 self.teambubbleentity.mdl = self.teambubbleentity.model;
 927                 self.teambubbleentity.model = self.teambubbleentity.mdl;
 928                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
 929         }
 930 }
 931
 932 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
 933 // added to the model skins
 934 /*void() UpdateColorModHack =
 935 {
 936         local float c;
 937         c = self.clientcolors & 15;
 938         // LordHavoc: only bothering to support white, green, red, yellow, blue
 939              if (teamplay == 0) self.colormod = '0 0 0';
 940         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
 941         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
 942         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
 943         else if (c == 12) self.colormod = '1.22 1.22 0.10';
 944         else if (c == 13) self.colormod = '0.10 0.10 1.73';
 945         else self.colormod = '1 1 1';
 946 };*/
 947
 948 void respawn(void)
 949 {
 950         CopyBody(1);
 951         PutClientInServer();
 952 }
 953
 954 void player_powerups (void)
 955 {
 956         if (cvar("g_minstagib"))
 957         {
 958                 self.effects = EF_FULLBRIGHT;
 959                 if (self.items & IT_STRENGTH)
 960                 {
 961                         if (time > self.strength_finished)
 962                         {
 963                                 self.alpha = default_player_alpha;
 964                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 965                                 self.items = self.items - (self.items & IT_STRENGTH);
 966                                 sprint(self, "^3Invisibility has worn off\n");
 967                         }
 968                 }
 969                 else
 970                 {
 971                         if (time < self.strength_finished)
 972                         {
 973                                 self.alpha = cvar("g_minstagib_invis_alpha");
 974                                 self.exteriorweaponentity.alpha = cvar("g_minstagib_invis_alpha");
 975                                 self.items = self.items | IT_STRENGTH;
 976                                 sprint(self, "^3You are invisible\n");
 977                         }
 978                 }
 979
 980                 if (self.items & IT_INVINCIBLE)
 981                 {
 982                         if (time > self.invincible_finished)
 983                         {
 984                                 self.items = self.items - (self.items & IT_INVINCIBLE);
 985                                 sprint(self, "^3Speed has worn off\n");
 986                         }
 987                 }
 988                 else
 989                 {
 990                         if (time < self.invincible_finished)
 991                         {
 992                                 self.items = self.items | IT_INVINCIBLE;
 993                                 sprint(self, "^3You are on speed\n");
 994                         }
 995                 }
 996                 return;
 997         }
 998
 999         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
1000         if (self.items & IT_STRENGTH)
1001         {
1002                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1003                 if (time > self.strength_finished)
1004                 {
1005                         self.items = self.items - (self.items & IT_STRENGTH);
1006                         sprint(self, "^3Strength has worn off\n");
1007                 }
1008         }
1009         else
1010         {
1011                 if (time < self.strength_finished)
1012                 {
1013                         self.items = self.items | IT_STRENGTH;
1014                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1015                 }
1016         }
1017         if (self.items & IT_INVINCIBLE)
1018         {
1019                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1020                 if (time > self.invincible_finished)
1021                 {
1022                         self.items = self.items - (self.items & IT_INVINCIBLE);
1023                         sprint(self, "^3Shield has worn off\n");
1024                 }
1025         }
1026         else
1027         {
1028                 if (time < self.invincible_finished)
1029                 {
1030                         self.items = self.items | IT_INVINCIBLE;
1031                         sprint(self, "^3Shield surrounds you\n");
1032                 }
1033         }
1034
1035         if (cvar("g_fullbrightplayers"))
1036                 self.effects = self.effects | EF_FULLBRIGHT;
1037
1038         // midair gamemode: damage only while in the air
1039         // if in midair mode, being on ground grants temporary invulnerability
1040         // (this is so that multishot weapon don't clear the ground flag on the
1041         // first damage in the frame, leaving the player vulnerable to the
1042         // remaining hits in the same frame)
1043         if (self.flags & FL_ONGROUND)
1044         if (cvar("g_midair"))
1045                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1046
1047         if (time < self.spawnshieldtime)
1048                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1049 }
1050
1051 float CalcRegen(float current, float stable, float maxv, float regenfactor)
1052 {
1053         if(current > stable)
1054                 return current;
1055         else if(current > stable - 0.25) // when close enough, "snap"
1056                 return stable;
1057         else
1058                 return bound(0, current + (stable - current) * regenfactor * frametime, maxv);
1059 }
1060
1061 void player_regen (void)
1062 {
1063         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1064         maxh = cvar("g_balance_health_stable");
1065         maxa = cvar("g_balance_armor_stable");
1066         limith = cvar("g_balance_health_limit");
1067         limita = cvar("g_balance_armor_limit");
1068
1069         if (cvar("g_minstagib") || (cvar("g_lms") && !cvar("g_lms_regenerate")))
1070                 return;
1071
1072         if(cvar("g_runematch"))
1073         {
1074                 max_mod = regen_mod = rot_mod = limit_mod = 1;
1075                 if (self.runes & RUNE_REGEN)
1076                 {
1077                         if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1078                         {
1079                                 regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1080                                 max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1081                                 limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1082                         }
1083                         else
1084                         {
1085                                 regen_mod = cvar("g_balance_rune_regen_regenrate");
1086                                 max_mod = cvar("g_balance_rune_regen_hpmod");
1087                                 limit_mod = cvar("g_balance_rune_regen_limitmod");
1088                         }
1089                 }
1090                 else if (self.runes & CURSE_VENOM)
1091                 {
1092                         max_mod = cvar("g_balance_curse_venom_hpmod");
1093                         if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1094                                 rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1095                         else
1096                                 rot_mod = cvar("g_balance_curse_venom_rotrate");
1097                         limit_mod = cvar("g_balance_curse_venom_limitmod");
1098                         //if (!self.runes & RUNE_REGEN)
1099                         //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1100                 }
1101                 maxh = maxh * max_mod;
1102                 //maxa = maxa * max_mod;
1103
1104                 if (time > self.pauserotarmor_finished)
1105                 {
1106                         if (self.armorvalue > maxa)
1107                                 self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime, 1000);
1108                 }
1109                 if (time > self.pauserothealth_finished)
1110                 {
1111                         if (self.health > maxh)
1112                                 self.health = bound(0, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime, 1000);
1113                 }
1114                 if (time > self.pauseregen_finished)
1115                 {
1116                         self.health = CalcRegen(self.health, maxh, 1000, regen_mod * cvar("g_balance_health_regen"));
1117                         self.armorvalue = CalcRegen(self.armorvalue, maxa, 1000, cvar("g_balance_armor_regen"));
1118                 }
1119         }
1120         else
1121         {
1122                 if (time > self.pauserothealth_finished)
1123                 if (self.health > maxh)
1124                         self.health = bound(0, self.health + (maxh - self.health) * cvar("g_balance_health_rot") * frametime, 1000);
1125                 if (time > self.pauserotarmor_finished)
1126                 if (self.armorvalue > maxa)
1127                         self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime, 1000);
1128                 if (time > self.pauseregen_finished)
1129                 {
1130                         self.health = CalcRegen(self.health, maxh, 1000, cvar("g_balance_health_regen"));
1131                         self.armorvalue = CalcRegen(self.armorvalue, maxa, 1000, cvar("g_balance_armor_regen"));
1132                 }
1133         }
1134
1135         if (self.health > limith)
1136                 self.health = limith;
1137         if(self.health < 1)
1138                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1139         if (self.armorvalue > limita)
1140                 self.armorvalue = limita;
1141 }
1142
1143 /*
1144 ======================
1145 spectate mode routines
1146 ======================
1147 */
1148 void SpectateCopy(entity spectatee) {
1149         self.armortype = spectatee.armortype;
1150         self.armorvalue = spectatee.armorvalue;
1151         self.currentammo = spectatee.currentammo;
1152         self.effects = spectatee.effects;
1153         self.health = spectatee.health;
1154         self.impulse = 0;
1155         self.items = spectatee.items;
1156         self.punchangle = spectatee.punchangle;
1157         self.view_ofs = spectatee.view_ofs;
1158         self.v_angle = spectatee.v_angle;
1159         self.viewzoom = spectatee.viewzoom;
1160         setorigin(self, spectatee.origin);
1161         setsize(self, spectatee.mins, spectatee.maxs);
1162 }
1163
1164 void SpectateUpdate() {
1165         if(!self.enemy)
1166                         PutObserverInServer();
1167
1168         if (self != self.enemy) {
1169                 if(self.enemy.flags & FL_NOTARGET)
1170                         PutObserverInServer();
1171                 SpectateCopy(self.enemy);
1172                 self.dmg_take = self.enemy.dmg_take;
1173                 self.dmg_save = self.enemy.dmg_save;
1174                 self.dmg_inflictor = self.enemy.dmg_inflictor;
1175                 self.fixangle = TRUE;
1176                 self.angles = self.enemy.v_angle;
1177                 //msg_entity = self;
1178                 //WriteByte(MSG_ONE, SVC_SETANGLE);
1179                 //WriteAngle(MSG_ONE, self.enemy.v_angle_x);
1180                 //WriteAngle(MSG_ONE, self.enemy.v_angle_y);
1181                 //WriteAngle(MSG_ONE, self.enemy.v_angle_z);
1182         }
1183 }
1184
1185 float SpectateNext() {
1186         other = find(self.enemy, classname, "player");
1187         if (!other) {
1188                 other = find(other, classname, "player");
1189         }
1190         if (other) {
1191                 self.enemy = other;
1192         }
1193         if(self.enemy.classname == "player") {
1194                 msg_entity = self;
1195                 WriteByte(MSG_ONE, SVC_SETVIEW);
1196                 WriteEntity(MSG_ONE, self.enemy);
1197                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1198                 SpectateUpdate();
1199                 return 1;
1200         } else {
1201                 return 0;
1202         }
1203 }
1204
1205 /*
1206 =============
1207 ShowRespawnCountdown()
1208
1209 Update a respawn countdown display.
1210 =============
1211 */
1212 void ShowRespawnCountdown()
1213 {
1214         float number;
1215         if(self.deadflag == DEAD_NO) // just respawned?
1216                 return;
1217         else
1218         {
1219                 number = ceil(self.death_time - time);
1220                 if(number <= 0)
1221                         return;
1222                 if(number <= self.respawn_countdown)
1223                 {
1224                         self.respawn_countdown = number - 1;
1225                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1226                                 stuffcmd(self, strcat("play2 announcer/robotic/", ftos(number), ".ogg\n"));
1227                 }
1228         }
1229 }
1230
1231 void LeaveSpectatorMode()
1232 {
1233         if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1234                 self.classname = "player";
1235                 if(cvar("g_campaign") || cvar("g_balance_teams"))
1236                         JoinBestTeam(self, 0);
1237                 if(cvar("g_campaign"))
1238                         campaign_bots_may_start = 1;
1239                 PutClientInServer();
1240                 if(!(self.flags & FL_NOTARGET))
1241                         bprint ("^4", self.netname, "^4 is playing now\n");
1242                 centerprint(self,"");
1243                 return;
1244         } else {
1245                 stuffcmd(self,"menu_showteamselect\n");
1246                 return;
1247         }
1248 }
1249
1250 /*
1251 =============
1252 PlayerPreThink
1253
1254 Called every frame for each client before the physics are run
1255 =============
1256 */
1257 void() ctf_setstatus;
1258 .float vote_nagtime;
1259 void PlayerPreThink (void)
1260 {
1261         if(strlen(self.netname) > 0)
1262                 if(substring(self.netname, strlen(self.netname) - 1, 1) == "^")
1263                         self.netname = strzone(strcat(substring(self.netname, 0, strlen(self.netname) - 1), " ")); // BROKEN COLORS can be annoying!
1264
1265         // version nagging
1266         if(self.version_nagtime)
1267                 if(self.cvar_g_nexuizversion)
1268                         if(time > self.version_nagtime)
1269                         {
1270                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
1271                                         if(self.cvar_g_nexuizversion != cvar_string("g_nexuizversion"))
1272                                         {
1273                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "\n");
1274                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "\n"));
1275                                         }
1276                                 self.version_nagtime = 0;
1277                         }
1278
1279         // vote nagging
1280         if(self.cvar_scr_centertime)
1281                 if(time > self.vote_nagtime)
1282                 {
1283                         VoteNag();
1284                         self.vote_nagtime = time + self.cvar_scr_centertime * 0.6;
1285                 }
1286
1287         if(self.classname == "player") {
1288                 local vector m1, m2;
1289
1290 //              if(self.netname == "Wazat")
1291 //                      bprint(self.classname, "\n");
1292
1293                 CheckRules_Player();
1294
1295                 Nixnex_GiveCurrentWeapon();
1296
1297                 if(self.button7)
1298                         PrintWelcomeMessage(self);
1299
1300                 if(cvar("g_lms") || !cvar("sv_spectate"))
1301                 if((time - self.jointime) <= cvar("welcome_message_time"))
1302                         PrintWelcomeMessage(self);
1303
1304                 if (intermission_running)
1305                 {
1306                         IntermissionThink ();   // otherwise a button could be missed between
1307                         return;                                 // the think tics
1308                 }
1309
1310                 if (self.deadflag != DEAD_NO)
1311                 {
1312                         float button_pressed, force_respawn;
1313                         player_anim();
1314                         button_pressed = (self.button0 || self.button2 || self.button3 || self.button6 || self.buttonuse);
1315                         force_respawn = (cvar("g_lms") || cvar("g_forced_respawn"));
1316                         if (self.deadflag == DEAD_DYING)
1317                         {
1318                                 if(force_respawn)
1319                                         self.deadflag = DEAD_RESPAWNING;
1320                                 else if(!button_pressed)
1321                                         self.deadflag = DEAD_DEAD;
1322                         }
1323                         else if (self.deadflag == DEAD_DEAD)
1324                         {
1325                                 if(button_pressed)
1326                                         self.deadflag = DEAD_RESPAWNABLE;
1327                         }
1328                         else if (self.deadflag == DEAD_RESPAWNABLE)
1329                         {
1330                                 if(!button_pressed)
1331                                         self.deadflag = DEAD_RESPAWNING;
1332                         }
1333                         else if (self.deadflag == DEAD_RESPAWNING)
1334                         {
1335                                 if(time > self.death_time)
1336                                         respawn();
1337                         }
1338                         ShowRespawnCountdown();
1339                         return;
1340                 }
1341
1342                 if(cvar("g_lms") && !self.deadflag && cvar("g_lms_campcheck_interval"))
1343                 {
1344                         vector dist;
1345
1346                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
1347                         dist = self.oldorigin - self.origin;
1348                         dist_z = 0;
1349                         self.lms_traveled_distance += fabs(vlen(dist));
1350
1351                         if(cvar("g_campaign"))
1352                         if(!campaign_bots_may_start)
1353                         {
1354                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
1355                                 self.lms_traveled_distance = 0;
1356                         }
1357
1358                         if(time > self.lms_nextcheck)
1359                         {
1360                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
1361                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
1362                                 {
1363                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
1364                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
1365                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
1366                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
1367                                 }
1368                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
1369                                 self.lms_traveled_distance = 0;
1370                         }
1371                 }
1372
1373                 if (self.button5 && !self.hook.state)
1374                 {
1375                         if (!self.crouch)
1376                         {
1377                                 self.crouch = TRUE;
1378                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
1379                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
1380                         }
1381                 }
1382                 else
1383                 {
1384                         if (self.crouch)
1385                         {
1386                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
1387                                 if (!trace_startsolid)
1388                                 {
1389                                         self.crouch = FALSE;
1390                                         self.view_ofs = PL_VIEW_OFS;
1391                                         setsize (self, PL_MIN, PL_MAX);
1392                                 }
1393                         }
1394                 }
1395
1396                 if(cvar("sv_defaultcharacter") == 1 && !teams_matter) {
1397                         local string defaultmodel;
1398                         defaultmodel = CheckPlayerModel(cvar_string("sv_defaultplayermodel"));
1399
1400                         if (defaultmodel != self.model)
1401                         {
1402                                 m1 = self.mins;
1403                                 m2 = self.maxs;
1404                                 setmodel_lod (self, defaultmodel);
1405                                 setsize (self, m1, m2);
1406                         }
1407
1408                         if (self.skin != cvar("sv_defaultplayerskin"))
1409                                 self.skin = cvar("sv_defaultplayerskin");
1410                 } else {
1411                         if (self.playermodel != self.model)
1412                         {
1413                                 self.playermodel = CheckPlayerModel(self.playermodel);
1414                                 m1 = self.mins;
1415                                 m2 = self.maxs;
1416                                 setmodel_lod (self, self.playermodel);
1417                                 setsize (self, m1, m2);
1418                         }
1419
1420                         if(teams_matter)
1421                         {
1422                                 if (self.skin != math_mod(stof(self.playerskin), NUM_PLAYERSKINS_TEAMPLAY))
1423                                         self.skin = math_mod(stof(self.playerskin), NUM_PLAYERSKINS_TEAMPLAY);
1424                         }
1425                         else
1426                         {
1427                                 if (self.skin != stof(self.playerskin))
1428                                         self.skin = stof(self.playerskin);
1429                         }
1430                 }
1431
1432                 GrapplingHookFrame();
1433
1434                 W_WeaponFrame();
1435
1436                 if (self.button4 || (self.weapon == WEP_NEX && self.button3))
1437                 {
1438                         if (cvar("g_minstagib") && self.button3)
1439                         {
1440                                 if (self.jump_interval <= (time + 0.1))
1441                                 {
1442                                         self.jump_interval = time + 1;
1443                                         W_Laser_Attack();
1444                                 }
1445                         }
1446                         else if (self.viewzoom > 0.4)
1447                                 self.viewzoom = max (0.4, self.viewzoom - frametime * 2);
1448                 }
1449                 else if (self.viewzoom < 1.0)
1450                         self.viewzoom = min (1.0, self.viewzoom + frametime);
1451
1452                 player_powerups();
1453                 player_regen();
1454                 player_anim();
1455
1456                 if (cvar("g_minstagib"))
1457                         minstagib_ammocheck();
1458
1459                 ctf_setstatus();
1460
1461                 //self.angles_y=self.v_angle_y + 90;   // temp
1462
1463                 if (self.waterlevel == 2)
1464                         CheckWaterJump ();
1465
1466                 //if (TetrisPreFrame()) return;
1467         } else if(gameover) {
1468                 if (intermission_running)
1469                         IntermissionThink ();   // otherwise a button could be missed between
1470                 return;
1471         } else if(self.classname == "observer") {
1472
1473                 if (self.flags & FL_JUMPRELEASED) {
1474                         if (self.button2 && self.version == cvar("gameversion")) {
1475                                 self.welcomemessage_time = 0;
1476                                 self.flags = self.flags - FL_JUMPRELEASED;
1477                                 LeaveSpectatorMode();
1478                                 return;
1479                         } else if(self.button0 && self.version == cvar("gameversion")) {
1480                                 self.welcomemessage_time = 0;
1481                                 self.flags = self.flags - FL_JUMPRELEASED;
1482                                 if(SpectateNext() == 1) {
1483                                         self.classname = "spectator";
1484                                 }
1485                         }
1486                 } else {
1487                         if (!(self.button0 || self.button2)) {
1488                                 self.flags = self.flags | FL_JUMPRELEASED;
1489                         }
1490                 }
1491                 PrintWelcomeMessage(self);
1492         } else if(self.classname == "spectator") {
1493                 if (self.flags & FL_JUMPRELEASED) {
1494                         if (self.button2 && self.version == cvar("gameversion")) {
1495                                 self.welcomemessage_time = 0;
1496                                 self.flags = self.flags - FL_JUMPRELEASED;
1497                                 LeaveSpectatorMode();
1498                                 return;
1499                         } else if(self.button0) {
1500                                 self.welcomemessage_time = 0;
1501                                 self.flags = self.flags - FL_JUMPRELEASED;
1502                                 if(SpectateNext() == 1) {
1503                                         self.classname = "spectator";
1504                                 } else {
1505                                         self.classname = "observer";
1506                                         PutClientInServer();
1507                                 }
1508                         } else if (self.button3) {
1509                                 self.welcomemessage_time = 0;
1510                                 self.flags = self.flags - FL_JUMPRELEASED;
1511                                 self.classname = "observer";
1512                                 PutClientInServer();
1513                         } else {
1514                                 SpectateUpdate();
1515                         }
1516                 } else {
1517                         if (!(self.button0 || self.button3)) {
1518                                 self.flags = self.flags | FL_JUMPRELEASED;
1519                         }
1520                 }
1521                 PrintWelcomeMessage(self);
1522                 self.flags = self.flags | FL_CLIENT | FL_NOTARGET;
1523         }
1524 }
1525
1526
1527 /*
1528 =============
1529 PlayerPostThink
1530
1531 Called every frame for each client after the physics are run
1532 =============
1533 */
1534 void PlayerPostThink (void)
1535 {
1536         // Savage: Check for nameless players
1537         if (strlen(self.netname) < 1) {
1538                 self.netname = "Player";
1539                 stuffcmd(self, "seta _cl_name Player\n");
1540         }
1541
1542         if(self.classname == "player") {
1543                 CheckRules_Player();
1544                 UpdateChatBubble();
1545                 UpdateTeamBubble();
1546                 if (self.deadflag == DEAD_NO)
1547                 if (self.impulse)
1548                         ImpulseCommands ();
1549                 if (intermission_running)
1550                         return;         // intermission or finale
1551
1552                 //PrintWelcomeMessage(self);
1553                 //if (TetrisPostFrame()) return;
1554         } else if (self.classname == "observer") {
1555                 //do nothing
1556         } else if (self.classname == "spectator") {
1557                 //do nothing
1558         }
1559         Arena_Warmup();
1560 }