data/qcsrc/server/cl_client.qc

   1 void info_player_start (void)
   2 {
   3         info_player_deathmatch();
   4 }
   5
   6 void info_player_deathmatch (void)
   7 {
   8         self.classname = "info_player_deathmatch";
   9         relocate_spawnpoint();
  10 }
  11
  12 float spawn_allbad;
  13 float spawn_allgood;
  14 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
  15 {
  16         local entity spot, player, nextspot, previousspot, newfirstspot;
  17         local float pcount;
  18         spot = firstspot;
  19         newfirstspot = world;
  20         previousspot = world;
  21         spawn_allgood = TRUE;
  22         spawn_allbad = TRUE;
  23         while (spot)
  24         {
  25                 nextspot = spot.chain;
  26                 // count team mismatches as bad spots
  27                 if (spot.team == teamcheck)
  28                 {
  29                         pcount = 0;
  30                         player = playerlist;
  31                         while (player)
  32                         {
  33                                 if (player != self)
  34                                 if (vlen(player.origin - spot.origin) < mindist)
  35                                         pcount = pcount + 1;
  36                                 player = player.chain;
  37                         }
  38                         if (!pcount)
  39                         {
  40                                 spawn_allbad = FALSE;
  41                                 if (newfirstspot)
  42                                         previousspot.chain = spot;
  43                                 else
  44                                         newfirstspot = spot;
  45                                 previousspot = spot;
  46                                 spot.chain = world;
  47                         }
  48                         else
  49                                 spawn_allgood = FALSE;
  50                 }
  51                 spot = nextspot;
  52         }
  53         // if we couldn't find ANY good points, return the original list
  54         if (!newfirstspot)
  55                 newfirstspot = firstspot;
  56         return newfirstspot;
  57 }
  58
  59 entity Spawn_RandomPoint(entity firstspot)
  60 {
  61         local entity spot;
  62         local float numspots;
  63         // count number of spots
  64         numspots = 0;
  65         spot = firstspot;
  66         while (spot)
  67         {
  68                 numspots = numspots + 1;
  69                 spot = spot.chain;
  70         }
  71         // pick a random one
  72         numspots = numspots * random();
  73         spot = firstspot;
  74         while (spot.chain && numspots >= 1)
  75         {
  76                 numspots = numspots - 1;
  77                 spot = spot.chain;
  78         }
  79         return spot;
  80 }
  81
  82 entity Spawn_FurthestPoint(entity firstspot, entity playerlist)
  83 {
  84         local entity best, spot, player;
  85         local float bestrating, rating;
  86         best = world;
  87         bestrating = -1000000;
  88         spot = firstspot;
  89         while (spot)
  90         {
  91                 rating = 1000000000;
  92                 player = playerlist;
  93                 while (player)
  94                 {
  95                         if (player != self)
  96                                 rating = min(rating, vlen(player.origin - spot.origin));
  97                         player = player.chain;
  98                 }
  99                 rating = rating + random() * 16;
 100                 if (bestrating < rating)
 101                 {
 102                         best = spot;
 103                         bestrating = rating;
 104                 }
 105                 spot = spot.chain;
 106         }
 107         return best;
 108 }
 109
 110 /*
 111 =============
 112 SelectSpawnPoint
 113
 114 Finds a point to respawn
 115 =============
 116 */
 117 entity SelectSpawnPoint (float anypoint)
 118 {
 119         local float teamcheck;
 120         local entity spot, firstspot, playerlist;
 121
 122         spot = find (world, classname, "testplayerstart");
 123         if (spot)
 124                 return spot;
 125
 126         teamcheck = 0;
 127
 128         if(!anypoint && cvar("g_ctf") )
 129                 teamcheck = self.team;
 130
 131         // get the list of players
 132         playerlist = findchain(classname, "player");
 133         // get the entire list of spots
 134         firstspot = findchain(classname, "info_player_deathmatch");
 135         // filter out the bad ones
 136         // (note this returns the original list if none survived)
 137         firstspot = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 138
 139         // there is 50/50 chance of choosing a random spot or the furthest spot
 140         // (this means that roughly every other spawn will be furthest, so you
 141         // usually won't get fragged at spawn twice in a row)
 142         if (arena_roundbased)
 143         {
 144                 firstspot = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 145                 spot = Spawn_RandomPoint(firstspot);
 146         }
 147         else if (random() > 0.5 || spawn_allbad || spawn_allgood)
 148                 spot = Spawn_RandomPoint(firstspot);
 149         else
 150                 spot = Spawn_FurthestPoint(firstspot, playerlist);
 151
 152         if (!spot)
 153         {
 154                 if(cvar("spawn_debug"))
 155                         GotoNextMap();
 156                 else
 157                         error ("PutClientInServer: no start points on level");
 158         }
 159
 160         return spot;
 161 }
 162
 163 /*
 164 =============
 165 CheckPlayerModel
 166
 167 Checks if the argument string can be a valid playermodel.
 168 Returns a valid one in doubt.
 169 =============
 170 */
 171 string FallbackPlayerModel = "models/player/marine.zym";
 172 string CheckPlayerModel(string plyermodel) {
 173         if(strlen(plyermodel) < 4)
 174                 return FallbackPlayerModel;
 175         if( substring(plyermodel,0,14) != "models/player/")
 176                 return FallbackPlayerModel;
 177         else if(cvar("sv_servermodelsonly"))
 178         {
 179                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 180                         return FallbackPlayerModel;
 181                 if(!fexists(plyermodel))
 182                         return FallbackPlayerModel;
 183         }
 184         return plyermodel;
 185 }
 186
 187 /*
 188 =============
 189 Client_customizeentityforclient
 190
 191 LOD reduction
 192 =============
 193 */
 194 float Client_customizeentityforclient()
 195 {
 196 #ifdef ALLOW_VARIABLE_LOD
 197         // self: me
 198         // other: the player viewing me
 199         float distance;
 200         float f;
 201
 202         if(self.flags & FL_NOTARGET) // we don't need LOD for spectators
 203                 return TRUE;
 204
 205         if(other.cvar_cl_playerdetailreduction <= 0)
 206         {
 207                 if(other.cvar_cl_playerdetailreduction <= -2)
 208                         self.modelindex = self.modelindex_lod2;
 209                 else if(other.cvar_cl_playerdetailreduction <= -1)
 210                         self.modelindex = self.modelindex_lod1;
 211                 else
 212                         self.modelindex = self.modelindex_lod0;
 213         }
 214         else
 215         {
 216                 distance = vlen(self.origin - other.origin);
 217                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 218                 if(f > 10000)
 219                         self.modelindex = self.modelindex_lod2;
 220                 else if(f > 5000)
 221                         self.modelindex = self.modelindex_lod1;
 222                 else
 223                         self.modelindex = self.modelindex_lod0;
 224         }
 225 #endif
 226
 227         return TRUE;
 228 }
 229
 230 void setmodel_lod(entity e, string modelname)
 231 {
 232 #ifdef ALLOW_VARIABLE_LOD
 233         string s;
 234
 235         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1.zym");
 236         if(fexists(s))
 237         {
 238                 precache_model(s);
 239                 setmodel(e, s); // players have high precision
 240                 self.modelindex_lod1 = self.modelindex;
 241         }
 242         else
 243                 self.modelindex_lod1 = -1;
 244
 245         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2.zym");
 246         if(fexists(s))
 247         {
 248                 precache_model(s);
 249                 setmodel(e, s); // players have high precision
 250                 self.modelindex_lod2 = self.modelindex;
 251         }
 252         else
 253                 self.modelindex_lod2 = -1;
 254
 255         precache_model(modelname);
 256         setmodel(e, modelname); // players have high precision
 257         self.modelindex_lod0 = self.modelindex;
 258
 259         if(self.modelindex_lod1 < 0)
 260                 self.modelindex_lod1 = self.modelindex;
 261
 262         if(self.modelindex_lod2 < 0)
 263                 self.modelindex_lod2 = self.modelindex;
 264 #else
 265         precache_model(modelname);
 266         setmodel(e, modelname); // players have high precision
 267 #endif
 268 }
 269
 270 /*
 271 =============
 272 PutObserverInServer
 273
 274 putting a client as observer in the server
 275 =============
 276 */
 277 void PutObserverInServer (void)
 278 {
 279         entity  spot;
 280         spot = SelectSpawnPoint (FALSE);
 281         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 282
 283         if(clienttype(self) == CLIENTTYPE_REAL)
 284         {
 285                 msg_entity = self;
 286                 WriteByte(MSG_ONE, SVC_SETVIEW);
 287                 WriteEntity(MSG_ONE, self);
 288         }
 289
 290         DropAllRunes(self);
 291         kh_Key_DropAll(self);
 292
 293         if(self.flagcarried)
 294                 DropFlag(self.flagcarried);
 295
 296         WaypointSprite_PlayerDead();
 297
 298         DistributeFragsAmongTeam(self, self.team, 1);
 299
 300         if(self.frags <= 0 && self.frags > -666 && cvar("g_lms") && self.killcount != -666)
 301                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 302         else if(self.killcount != -666)
 303                 bprint ("^4", self.netname, "^4 is spectating now\n");
 304
 305         self.classname = "observer";
 306         self.health = -666;
 307         self.takedamage = DAMAGE_NO;
 308         self.solid = SOLID_NOT;
 309         self.movetype = MOVETYPE_NOCLIP;
 310         self.flags = FL_CLIENT | FL_NOTARGET;
 311         self.armorvalue = 666;
 312         self.effects = 0;
 313         self.armorvalue = cvar("g_balance_armor_start");
 314         self.pauserotarmor_finished = 0;
 315         self.pauserothealth_finished = 0;
 316         self.pauseregen_finished = 0;
 317         self.damageforcescale = 0;
 318         self.death_time = 0;
 319         self.dead_time = 0;
 320         self.dead_frame = 0;
 321         self.die_frame = 0;
 322         self.deaths = 0;
 323         self.alpha = 0;
 324         self.scale = 0;
 325         self.fade_time = 0;
 326         self.pain_frame = 0;
 327         self.pain_finished = 0;
 328         self.strength_finished = 0;
 329         self.invincible_finished = 0;
 330         self.pushltime = 0;
 331         self.think = SUB_Null;
 332         self.nextthink = 0;
 333         self.hook_time = 0;
 334         self.runes = 0;
 335         self.deadflag = DEAD_NO;
 336         self.angles = spot.angles;
 337         self.angles_z = 0;
 338         self.fixangle = TRUE;
 339         self.crouch = FALSE;
 340
 341         self.view_ofs = PL_VIEW_OFS;
 342         setorigin (self, spot.origin);
 343         setsize (self, '0 0 0', '0 0 0');
 344         self.oldorigin = self.origin;
 345         self.items = 0;
 346         self.model = "";
 347         self.modelindex = 0;
 348         self.weapon = 0;
 349         self.weaponmodel = "";
 350         self.weaponentity = world;
 351         self.killcount = -666;
 352         self.velocity = '0 0 0';
 353         self.avelocity = '0 0 0';
 354         self.punchangle = '0 0 0';
 355         self.punchvector = '0 0 0';
 356         self.oldvelocity = self.velocity;
 357         self.customizeentityforclient = Client_customizeentityforclient;
 358
 359         if(cvar("g_arena"))
 360         {
 361                 if(self.frags != -2)
 362                 {
 363                         Spawnqueue_Insert(self);
 364                 }
 365                 else
 366                 {
 367                         Spawnqueue_Unmark(self);
 368                         Spawnqueue_Remove(self);
 369                 }
 370         }
 371         else if(!cvar("g_lms"))
 372                 self.frags = -666;
 373 }
 374
 375
 376 /*
 377 =============
 378 PutClientInServer
 379
 380 Called when a client spawns in the server
 381 =============
 382 */
 383 void PutClientInServer (void)
 384 {
 385         if(clienttype(self) == CLIENTTYPE_BOT)
 386         {
 387                 self.classname = "player";
 388         }
 389         else if(clienttype(self) == CLIENTTYPE_REAL)
 390         {
 391                 msg_entity = self;
 392                 WriteByte(MSG_ONE, SVC_SETVIEW);
 393                 WriteEntity(MSG_ONE, self);
 394         }
 395
 396         // player is dead and becomes observer
 397         if(cvar("g_lms") && self.frags < 1)
 398                 self.classname = "observer";
 399
 400         if(cvar("g_arena"))
 401         if(!self.spawned)
 402                 self.classname = "observer";
 403
 404         if(self.classname == "player") {
 405                 entity  spot;
 406
 407                 spot = SelectSpawnPoint (FALSE);
 408
 409                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 410
 411                 self.classname = "player";
 412                 self.iscreature = TRUE;
 413                 self.movetype = MOVETYPE_WALK;
 414                 self.solid = SOLID_SLIDEBOX;
 415                 self.flags = FL_CLIENT;
 416                 self.takedamage = DAMAGE_AIM;
 417                 self.effects = 0;
 418                 self.health = cvar("g_balance_health_start");
 419                 self.air_finished = time + 12;
 420                 self.dmg = 2;
 421                 self.armorvalue = cvar("g_balance_armor_start");
 422                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 423                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 424                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 425                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 426                 self.damageforcescale = 2;
 427                 self.death_time = 0;
 428                 self.dead_time = 0;
 429                 self.dead_frame = 0;
 430                 self.die_frame = 0;
 431                 self.alpha = 0;
 432                 self.scale = 0;
 433                 self.fade_time = 0;
 434                 self.pain_frame = 0;
 435                 self.pain_finished = 0;
 436                 self.strength_finished = 0;
 437                 self.invincible_finished = 0;
 438                 self.pushltime = 0;
 439                 //self.speed_finished = 0;
 440                 //self.slowmo_finished = 0;
 441                 // players have no think function
 442                 self.think = SUB_Null;
 443                 self.nextthink = 0;
 444                 self.weapon = 0;
 445                 self.switchweapon = 0;
 446                 self.hook_time = 0;
 447
 448                 self.runes = 0;
 449
 450                 self.deadflag = DEAD_NO;
 451
 452                 self.angles = spot.angles;
 453
 454                 self.angles_z = 0; // never spawn tilted even if the spot says to
 455                 self.fixangle = TRUE; // turn this way immediately
 456                 self.velocity = '0 0 0';
 457                 self.avelocity = '0 0 0';
 458                 self.punchangle = '0 0 0';
 459                 self.punchvector = '0 0 0';
 460                 self.oldvelocity = self.velocity;
 461
 462                 self.viewzoom = 0.6;
 463                 self.has_zoomed = 0;
 464
 465                 self.customizeentityforclient = Client_customizeentityforclient;
 466
 467                 if(cvar("sv_defaultcharacter") == 1 && !teams_matter) {
 468                         local string defaultmodel;
 469                         defaultmodel = CheckPlayerModel(cvar_string("sv_defaultplayermodel"));
 470                         setmodel_lod (self, defaultmodel);
 471                         self.skin = stof(cvar_string("sv_defaultplayerskin"));
 472                 } else {
 473                         self.playermodel = CheckPlayerModel(self.playermodel);
 474                         setmodel_lod (self, self.playermodel);
 475                         if(teams_matter)
 476                                 self.skin = math_mod(stof(self.playerskin), NUM_PLAYERSKINS_TEAMPLAY);
 477                         else
 478                                 self.skin = stof(self.playerskin);
 479                 }
 480
 481                 self.crouch = FALSE;
 482                 self.view_ofs = PL_VIEW_OFS;
 483                 setsize (self, PL_MIN, PL_MAX);
 484                 self.spawnorigin = spot.origin;
 485                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 486                 // don't reset back to last position, even if new position is stuck in solid
 487                 self.oldorigin = self.origin;
 488
 489                 if(cvar("g_lms"))
 490                 {
 491                         self.ammo_shells = cvar("g_lms_start_ammo_shells");
 492                         self.ammo_nails = cvar("g_lms_start_ammo_nails");
 493                         self.ammo_rockets = cvar("g_lms_start_ammo_rockets");
 494                         self.ammo_cells = cvar("g_lms_start_ammo_cells");
 495                         self.health = cvar("g_lms_start_health");
 496                         self.armorvalue = cvar("g_lms_start_armor");
 497                 }
 498                 else if (cvar("g_use_ammunition")) {
 499                         self.ammo_shells = cvar("g_start_ammo_shells");
 500                         self.ammo_nails = cvar("g_start_ammo_nails");
 501                         self.ammo_rockets = cvar("g_start_ammo_rockets");
 502                         self.ammo_cells = cvar("g_start_ammo_cells");
 503                 } else {
 504                         self.ammo_shells = 999;
 505                         self.ammo_nails = 999;
 506                         self.ammo_rockets = 999;
 507                         self.ammo_cells = 999;
 508                 }
 509
 510                 self.items = 0;
 511                 if (cvar("g_start_weapon_laser") || cvar("g_lms"))
 512                 {
 513                         self.items = self.items | IT_LASER;
 514                         self.switchweapon = WEP_LASER;
 515                 }
 516                 if (cvar("g_start_weapon_shotgun") || cvar("g_lms"))
 517                 {
 518                         self.items = self.items | IT_SHOTGUN;
 519                         self.switchweapon = WEP_SHOTGUN;
 520                 }
 521                 if (cvar("g_start_weapon_uzi") || cvar("g_lms"))
 522                 {
 523                         self.items = self.items | IT_UZI;
 524                         self.switchweapon = WEP_UZI;
 525                 }
 526                 if (cvar("g_start_weapon_grenadelauncher") || cvar("g_lms"))
 527                 {
 528                         self.items = self.items | IT_GRENADE_LAUNCHER;
 529                         self.switchweapon = WEP_GRENADE_LAUNCHER;
 530                 }
 531                 if (cvar("g_start_weapon_electro") || cvar("g_lms"))
 532                 {
 533                         self.items = self.items | IT_ELECTRO;
 534                         self.switchweapon = WEP_ELECTRO;
 535                 }
 536                 if (cvar("g_start_weapon_crylink") || cvar("g_lms"))
 537                 {
 538                         self.items = self.items | IT_CRYLINK;
 539                         self.switchweapon = WEP_CRYLINK;
 540                 }
 541                 if (cvar("g_start_weapon_nex") || cvar("g_lms"))
 542                 {
 543                         self.items = self.items | IT_NEX;
 544                         self.switchweapon = WEP_NEX;
 545                 }
 546                 if (cvar("g_start_weapon_hagar") || cvar("g_lms"))
 547                 {
 548                         self.items = self.items | IT_HAGAR;
 549                         self.switchweapon = WEP_HAGAR;
 550                 }
 551                 if (cvar("g_start_weapon_rocketlauncher") || cvar("g_lms"))
 552                 {
 553                         self.items = self.items | IT_ROCKET_LAUNCHER;
 554                         self.switchweapon = WEP_ROCKET_LAUNCHER;
 555                 }
 556
 557                 if(cvar("g_instagib"))
 558                 {
 559                         self.items = IT_NEX;
 560                         self.switchweapon = WEP_NEX;
 561                         self.ammo_cells = 999;
 562                 }
 563
 564                 if(cvar("g_rocketarena"))
 565                 {
 566                         self.items = IT_ROCKET_LAUNCHER;
 567                         self.switchweapon = WEP_ROCKET_LAUNCHER;
 568                         self.ammo_rockets = 999;
 569                 }
 570
 571                 if(cvar("g_nixnex"))
 572                 {
 573                         self.items = 0;
 574                         // will be done later
 575                 }
 576
 577                 if(cvar("g_minstagib"))
 578                 {
 579                         self.health = 100;
 580                         self.armorvalue = 0;
 581                         self.items = IT_NEX;
 582                         self.switchweapon = WEP_NEX;
 583                         self.ammo_cells = cvar("g_minstagib_ammo_start");
 584                         self.jump_interval = time;
 585                 }
 586
 587                 if(cvar("g_arena"))
 588                 {
 589                         Spawnqueue_Remove(self);
 590                         Spawnqueue_Mark(self);
 591                 }
 592
 593                 self.event_damage = PlayerDamage;
 594
 595                 self.bot_attack = TRUE;
 596
 597                 self.statdraintime = time + 5;
 598                 self.button0 = self.button1 = self.button2 = self.button3 = 0;
 599
 600                 if(self.killcount == -666) {
 601                         self.killcount = 0;
 602                         if(!cvar("g_arena"))
 603                         if(!cvar("g_lms"))
 604                                 self.frags = 0;
 605                 }
 606
 607                 self.cnt = WEP_LASER;
 608                 self.nixnex_lastchange_id = -1;
 609
 610                 CL_SpawnWeaponentity();
 611                 self.alpha = default_player_alpha;
 612                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 613
 614                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 615                 self.lms_traveled_distance = 0;
 616
 617                 if(cvar("spawn_debug"))
 618                 {
 619                                 sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 620                                 remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 621                 }
 622
 623                 //stuffcmd(self, "chase_active 0");
 624                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 625         } else if(self.classname == "observer") {
 626                 PutObserverInServer ();
 627         }
 628 }
 629
 630 /*
 631 =============
 632 SetNewParms
 633 =============
 634 */
 635 void SetNewParms (void)
 636 {
 637
 638 }
 639
 640 /*
 641 =============
 642 SetChangeParms
 643 =============
 644 */
 645 void SetChangeParms (void)
 646 {
 647
 648 }
 649
 650 /*
 651 =============
 652 ClientKill
 653
 654 Called when a client types 'kill' in the console
 655 =============
 656 */
 657 void ClientKill (void)
 658 {
 659         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 660 }
 661
 662 void FixClientCvars(entity e)
 663 {
 664         // send prediction settings to the client
 665         stuffcmd(e, "\nin_bindmap 0 0\n");
 666         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
 667         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
 668         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
 669         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
 670         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
 671         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
 672         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
 673         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("g_balance_jumpheight")), "\n"));
 674         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
 675         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
 676         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
 677         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
 678         stuffcmd(e, "cl_movement_edgefriction 1\n");
 679 }
 680
 681 /*
 682 =============
 683 ClientConnect
 684
 685 Called when a client connects to the server
 686 =============
 687 */
 688 string ColoredTeamName(float t);
 689 //void dom_player_join_team(entity pl);
 690 void ClientConnect (void)
 691 {
 692         local string s;
 693
 694         self.classname = "player_joining";
 695         self.flags = self.flags | FL_CLIENT;
 696         self.version_nagtime = time + 10 + random() * 10;
 697
 698         if(player_count<0)
 699         {
 700                 dprint("BUG player count is lower than zero, this cannot happen!\n");
 701                 player_count = 0;
 702         }
 703
 704         bot_clientconnect();
 705
 706         //if(cvar("g_domination"))
 707         //      dom_player_join_team(self);
 708
 709         //JoinBestTeam(self, FALSE);
 710
 711         if((cvar("sv_spectate") == 1 && !cvar("g_lms")) || cvar("g_campaign")) {
 712                 self.classname = "observer";
 713         } else {
 714                 self.classname = "player";
 715                 campaign_bots_may_start = 1;
 716         }
 717
 718         self.playerid = (playerid_last = playerid_last + 1);
 719         if(cvar("sv_eventlog"))
 720         {
 721                 if(clienttype(self) == CLIENTTYPE_REAL)
 722                         s = "player";
 723                 else
 724                         s = "bot";
 725                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", s, ":", self.netname), TRUE);
 726                 s = strcat(":team:", ftos(self.playerid), ":");
 727                 s = strcat(s, ftos(self.team));
 728                 GameLogEcho(s, FALSE);
 729         }
 730
 731         //stuffcmd(self, "set tmpviewsize $viewsize \n");
 732
 733         bprint ("^4",self.netname);
 734         bprint ("^4 connected");
 735
 736         if(cvar("g_domination") || cvar("g_ctf"))
 737         {
 738                 bprint(" and joined the ");
 739                 bprint(ColoredTeamName(self.team));
 740         }
 741
 742         bprint("\n");
 743
 744         self.welcomemessage_time = 0;
 745
 746         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
 747         // TODO: is this being used for anything else than cd tracks?
 748         // Remember: SVC_CDTRACK exists. Maybe it should be used.
 749
 750         FixClientCvars(self);
 751
 752         // waypoint sprites
 753         WaypointSprite_InitClient(self);
 754
 755         // Wazat's grappling hook
 756         SetGrappleHookBindings();
 757
 758         // get autoswitch state from player when he toggles it
 759         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n");
 760
 761         // get version info from player
 762         stuffcmd(self, "cmd clientversion $gameversion\n");
 763
 764         // get other cvars from player
 765         GetCvars(0);
 766
 767         // set cvar for team scoreboard
 768         if (teams_matter)
 769         {
 770                 local float t;
 771                 t = cvar("teamplay");
 772                 // we have to stuff the correct teamplay value because if this is a listen server, this changes the teamplay mode of the server itself, which is bad
 773                 stuffcmd(self, strcat("set teamplay ", ftos(t), "\n"));
 774         }
 775         else
 776                 stuffcmd(self, "set teamplay 0\n");
 777
 778         if(cvar("g_lms"))
 779         {
 780                 self.frags = cvar("fraglimit");
 781                 // no fraglimit was set, so player gets 999 lives
 782                 if(self.frags < 1)
 783                         self.frags = 999;
 784
 785                 self.frags = LMS_NewPlayerLives();
 786                 if(!self.frags)
 787                 {
 788                         self.frags = -666;
 789                 }
 790         }
 791         else if(cvar("g_arena"))
 792         {
 793                 self.classname = "observer";
 794                 Spawnqueue_Insert(self);
 795         }
 796
 797         bot_relinkplayerlist();
 798
 799         self.jointime = time;
 800 }
 801
 802 /*
 803 =============
 804 ClientDisconnect
 805
 806 Called when a client disconnects from the server
 807 =============
 808 */
 809 void(entity e) DropFlag;
 810 .entity chatbubbleentity;
 811 .entity teambubbleentity;
 812 void ClientDisconnect (void)
 813 {
 814         float save;
 815         if(cvar("sv_eventlog"))
 816                 GameLogEcho(strcat(":part:", ftos(self.playerid)), FALSE);
 817         bprint ("^4",self.netname);
 818         bprint ("^4 disconnected\n");
 819
 820         if (self.chatbubbleentity)
 821         {
 822                 remove (self.chatbubbleentity);
 823                 self.chatbubbleentity = world;
 824         }
 825
 826         if (self.teambubbleentity)
 827         {
 828                 remove (self.teambubbleentity);
 829                 self.teambubbleentity = world;
 830         }
 831
 832         WaypointSprite_PlayerGone();
 833
 834         DropAllRunes(self);
 835         kh_Key_DropAll(self);
 836
 837         if(self.flagcarried)
 838                 DropFlag(self.flagcarried);
 839
 840         DistributeFragsAmongTeam(self, self.team, 1);
 841
 842         save = self.flags;
 843         self.flags = self.flags - (self.flags & FL_CLIENT);
 844         bot_relinkplayerlist();
 845         self.flags = save;
 846
 847         // remove laserdot
 848         if(self.weaponentity)
 849                 if(self.weaponentity.lasertarget)
 850                         remove(self.weaponentity.lasertarget);
 851
 852         if(cvar("g_arena"))
 853         {
 854                 Spawnqueue_Unmark(self);
 855                 Spawnqueue_Remove(self);
 856         }
 857
 858         // free cvars
 859         GetCvars(-1);
 860 }
 861
 862 .float buttonchat;
 863 void() ChatBubbleThink =
 864 {
 865         self.nextthink = time;
 866         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
 867         {
 868                 self.owner.chatbubbleentity = world;
 869                 remove(self);
 870                 return;
 871         }
 872         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
 873         if (self.owner.buttonchat && !self.owner.deadflag)
 874                 self.model = self.mdl;
 875         else
 876                 self.model = "";
 877 };
 878
 879 void() UpdateChatBubble =
 880 {
 881         if (!self.modelindex)
 882                 return;
 883         // spawn a chatbubble entity if needed
 884         if (!self.chatbubbleentity)
 885         {
 886                 self.chatbubbleentity = spawn();
 887                 self.chatbubbleentity.owner = self;
 888                 self.chatbubbleentity.exteriormodeltoclient = self;
 889                 self.chatbubbleentity.think = ChatBubbleThink;
 890                 self.chatbubbleentity.nextthink = time;
 891                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
 892                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 893                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
 894                 self.chatbubbleentity.model = "";
 895                 self.chatbubbleentity.effects = EF_LOWPRECISION;
 896         }
 897 }
 898
 899
 900 void() TeamBubbleThink =
 901 {
 902         self.nextthink = time;
 903         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
 904         {
 905                 self.owner.teambubbleentity = world;
 906                 remove(self);
 907                 return;
 908         }
 909 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
 910         if (self.owner.buttonchat || self.owner.deadflag)
 911                 self.model = "";
 912         else
 913                 self.model = self.mdl;
 914
 915 };
 916
 917 float() TeamBubble_customizeentityforclient
 918 {
 919         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
 920 }
 921
 922 void() UpdateTeamBubble =
 923 {
 924         if (!self.modelindex || !cvar("teamplay"))
 925                 return;
 926         // spawn a teambubble entity if needed
 927         if (!self.teambubbleentity && cvar("teamplay"))
 928         {
 929                 self.teambubbleentity = spawn();
 930                 self.teambubbleentity.owner = self;
 931                 self.teambubbleentity.exteriormodeltoclient = self;
 932                 self.teambubbleentity.think = TeamBubbleThink;
 933                 self.teambubbleentity.nextthink = time;
 934                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
 935 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 936                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
 937                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
 938                 self.teambubbleentity.mdl = self.teambubbleentity.model;
 939                 self.teambubbleentity.model = self.teambubbleentity.mdl;
 940                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
 941                 self.teambubbleentity.effects = EF_LOWPRECISION;
 942         }
 943 }
 944
 945 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
 946 // added to the model skins
 947 /*void() UpdateColorModHack =
 948 {
 949         local float c;
 950         c = self.clientcolors & 15;
 951         // LordHavoc: only bothering to support white, green, red, yellow, blue
 952              if (teamplay == 0) self.colormod = '0 0 0';
 953         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
 954         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
 955         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
 956         else if (c == 12) self.colormod = '1.22 1.22 0.10';
 957         else if (c == 13) self.colormod = '0.10 0.10 1.73';
 958         else self.colormod = '1 1 1';
 959 };*/
 960
 961 void respawn(void)
 962 {
 963         CopyBody(1);
 964         PutClientInServer();
 965 }
 966
 967 void player_powerups (void)
 968 {
 969         if (cvar("g_minstagib"))
 970         {
 971                 self.effects = EF_FULLBRIGHT;
 972                 if (self.items & IT_STRENGTH)
 973                 {
 974                         if (time > self.strength_finished)
 975                         {
 976                                 self.alpha = default_player_alpha;
 977                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 978                                 self.items = self.items - (self.items & IT_STRENGTH);
 979                                 sprint(self, "^3Invisibility has worn off\n");
 980                         }
 981                 }
 982                 else
 983                 {
 984                         if (time < self.strength_finished)
 985                         {
 986                                 self.alpha = cvar("g_minstagib_invis_alpha");
 987                                 self.exteriorweaponentity.alpha = cvar("g_minstagib_invis_alpha");
 988                                 self.items = self.items | IT_STRENGTH;
 989                                 sprint(self, "^3You are invisible\n");
 990                         }
 991                 }
 992
 993                 if (self.items & IT_INVINCIBLE)
 994                 {
 995                         if (time > self.invincible_finished)
 996                         {
 997                                 self.items = self.items - (self.items & IT_INVINCIBLE);
 998                                 sprint(self, "^3Speed has worn off\n");
 999                         }
1000                 }
1001                 else
1002                 {
1003                         if (time < self.invincible_finished)
1004                         {
1005                                 self.items = self.items | IT_INVINCIBLE;
1006                                 sprint(self, "^3You are on speed\n");
1007                         }
1008                 }
1009                 return;
1010         }
1011
1012         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
1013         if (self.items & IT_STRENGTH)
1014         {
1015                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1016                 if (time > self.strength_finished)
1017                 {
1018                         self.items = self.items - (self.items & IT_STRENGTH);
1019                         sprint(self, "^3Strength has worn off\n");
1020                 }
1021         }
1022         else
1023         {
1024                 if (time < self.strength_finished)
1025                 {
1026                         self.items = self.items | IT_STRENGTH;
1027                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1028                 }
1029         }
1030         if (self.items & IT_INVINCIBLE)
1031         {
1032                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1033                 if (time > self.invincible_finished)
1034                 {
1035                         self.items = self.items - (self.items & IT_INVINCIBLE);
1036                         sprint(self, "^3Shield has worn off\n");
1037                 }
1038         }
1039         else
1040         {
1041                 if (time < self.invincible_finished)
1042                 {
1043                         self.items = self.items | IT_INVINCIBLE;
1044                         sprint(self, "^3Shield surrounds you\n");
1045                 }
1046         }
1047
1048         if (cvar("g_fullbrightplayers"))
1049                 self.effects = self.effects | EF_FULLBRIGHT;
1050
1051         // midair gamemode: damage only while in the air
1052         // if in midair mode, being on ground grants temporary invulnerability
1053         // (this is so that multishot weapon don't clear the ground flag on the
1054         // first damage in the frame, leaving the player vulnerable to the
1055         // remaining hits in the same frame)
1056         if (self.flags & FL_ONGROUND)
1057         if (cvar("g_midair"))
1058                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1059
1060         if (time < self.spawnshieldtime)
1061                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1062 }
1063
1064 float CalcRegen(float current, float stable, float regenfactor)
1065 {
1066         if(current > stable)
1067                 return current;
1068         else if(current > stable - 0.25) // when close enough, "snap"
1069                 return stable;
1070         else
1071                 return min(stable, current + (stable - current) * regenfactor * frametime);
1072 }
1073
1074 void player_regen (void)
1075 {
1076         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1077         maxh = cvar("g_balance_health_stable");
1078         maxa = cvar("g_balance_armor_stable");
1079         limith = cvar("g_balance_health_limit");
1080         limita = cvar("g_balance_armor_limit");
1081
1082         if (cvar("g_minstagib") || (cvar("g_lms") && !cvar("g_lms_regenerate")))
1083                 return;
1084
1085         max_mod = regen_mod = rot_mod = limit_mod = 1;
1086
1087         if (self.runes & RUNE_REGEN)
1088         {
1089                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1090                 {
1091                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1092                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1093                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1094                 }
1095                 else
1096                 {
1097                         regen_mod = cvar("g_balance_rune_regen_regenrate");
1098                         max_mod = cvar("g_balance_rune_regen_hpmod");
1099                         limit_mod = cvar("g_balance_rune_regen_limitmod");
1100                 }
1101         }
1102         else if (self.runes & CURSE_VENOM)
1103         {
1104                 max_mod = cvar("g_balance_curse_venom_hpmod");
1105                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1106                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1107                 else
1108                         rot_mod = cvar("g_balance_curse_venom_rotrate");
1109                 limit_mod = cvar("g_balance_curse_venom_limitmod");
1110                 //if (!self.runes & RUNE_REGEN)
1111                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1112         }
1113         maxh = maxh * max_mod;
1114         //maxa = maxa * max_mod;
1115         limith = limith * limit_mod;
1116         limita = limita * limit_mod;
1117
1118         if (self.armorvalue > maxa)
1119         {
1120                 if (time > self.pauserotarmor_finished)
1121                 {
1122                         self.armorvalue = max(maxa, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime);
1123                         self.armorvalue = max(maxa, self.armorvalue - cvar("g_balance_armor_rotlinear") * frametime);
1124                 }
1125         }
1126         else if (self.armorvalue < maxa)
1127         {
1128                 if (time > self.pauseregen_finished)
1129                 {
1130                         self.armorvalue = CalcRegen(self.armorvalue, maxa, cvar("g_balance_armor_regen"));
1131                         self.armorvalue = min(maxa, self.armorvalue + cvar("g_balance_armor_regenlinear") * frametime);
1132                 }
1133         }
1134         if (self.health > maxh)
1135         {
1136                 if (time > self.pauserothealth_finished)
1137                 {
1138                         self.health = max(maxh, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime);
1139                         self.health = max(maxh, self.health - rot_mod*cvar("g_balance_health_rotlinear") * frametime);
1140                 }
1141         }
1142         else if (self.health < maxh)
1143         {
1144                 if (time > self.pauseregen_finished)
1145                 {
1146                         self.health = CalcRegen(self.health, maxh, regen_mod * cvar("g_balance_health_regen"));
1147                         self.health = min(maxh, self.health + regen_mod*cvar("g_balance_health_regenlinear") * frametime);
1148                 }
1149         }
1150
1151         if (self.health > limith)
1152                 self.health = limith;
1153         if (self.armorvalue > limita)
1154                 self.armorvalue = limita;
1155
1156         // if player rotted to death...  die!
1157         if(self.health < 1)
1158                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1159 }
1160
1161 /*
1162 ======================
1163 spectate mode routines
1164 ======================
1165 */
1166 void SpectateCopy(entity spectatee) {
1167         self.armortype = spectatee.armortype;
1168         self.armorvalue = spectatee.armorvalue;
1169         self.currentammo = spectatee.currentammo;
1170         self.effects = spectatee.effects;
1171         self.health = spectatee.health;
1172         self.impulse = 0;
1173         self.items = spectatee.items;
1174         self.punchangle = spectatee.punchangle;
1175         self.view_ofs = spectatee.view_ofs;
1176         self.v_angle = spectatee.v_angle;
1177         self.viewzoom = spectatee.viewzoom;
1178         setorigin(self, spectatee.origin);
1179         setsize(self, spectatee.mins, spectatee.maxs);
1180 }
1181
1182 void SpectateUpdate() {
1183         if(!self.enemy)
1184                         PutObserverInServer();
1185
1186         if (self != self.enemy) {
1187                 if(self.enemy.flags & FL_NOTARGET)
1188                         PutObserverInServer();
1189                 SpectateCopy(self.enemy);
1190                 self.dmg_take = self.enemy.dmg_take;
1191                 self.dmg_save = self.enemy.dmg_save;
1192                 self.dmg_inflictor = self.enemy.dmg_inflictor;
1193                 self.fixangle = TRUE;
1194                 self.angles = self.enemy.v_angle;
1195                 //msg_entity = self;
1196                 //WriteByte(MSG_ONE, SVC_SETANGLE);
1197                 //WriteAngle(MSG_ONE, self.enemy.v_angle_x);
1198                 //WriteAngle(MSG_ONE, self.enemy.v_angle_y);
1199                 //WriteAngle(MSG_ONE, self.enemy.v_angle_z);
1200         }
1201 }
1202
1203 float SpectateNext() {
1204         other = find(self.enemy, classname, "player");
1205         if (!other) {
1206                 other = find(other, classname, "player");
1207         }
1208         if (other) {
1209                 self.enemy = other;
1210         }
1211         if(self.enemy.classname == "player") {
1212                 msg_entity = self;
1213                 WriteByte(MSG_ONE, SVC_SETVIEW);
1214                 WriteEntity(MSG_ONE, self.enemy);
1215                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1216                 SpectateUpdate();
1217                 return 1;
1218         } else {
1219                 return 0;
1220         }
1221 }
1222
1223 /*
1224 =============
1225 ShowRespawnCountdown()
1226
1227 Update a respawn countdown display.
1228 =============
1229 */
1230 void ShowRespawnCountdown()
1231 {
1232         float number;
1233         if(self.deadflag == DEAD_NO) // just respawned?
1234                 return;
1235         else
1236         {
1237                 number = ceil(self.death_time - time);
1238                 if(number <= 0)
1239                         return;
1240                 if(number <= self.respawn_countdown)
1241                 {
1242                         self.respawn_countdown = number - 1;
1243                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1244                                 play2(self, strcat("announcer/robotic/", ftos(number), ".ogg"));
1245                 }
1246         }
1247 }
1248
1249 void LeaveSpectatorMode()
1250 {
1251         if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1252                 self.classname = "player";
1253                 if(cvar("g_campaign") || cvar("g_balance_teams"))
1254                         JoinBestTeam(self, 0);
1255                 if(cvar("g_campaign"))
1256                         campaign_bots_may_start = 1;
1257                 PutClientInServer();
1258                 if(!(self.flags & FL_NOTARGET))
1259                         bprint ("^4", self.netname, "^4 is playing now\n");
1260                 centerprint(self,"");
1261                 return;
1262         } else {
1263                 stuffcmd(self,"menu_showteamselect\n");
1264                 return;
1265         }
1266 }
1267
1268 /*
1269 =============
1270 PlayerPreThink
1271
1272 Called every frame for each client before the physics are run
1273 =============
1274 */
1275 void() ctf_setstatus;
1276 .float vote_nagtime;
1277 void PlayerPreThink (void)
1278 {
1279         // version nagging
1280         if(self.version_nagtime)
1281                 if(self.cvar_g_nexuizversion)
1282                         if(time > self.version_nagtime)
1283                         {
1284                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
1285                                         if(self.cvar_g_nexuizversion != cvar_string("g_nexuizversion"))
1286                                         {
1287                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "\n");
1288                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "\n"));
1289                                         }
1290                                 self.version_nagtime = 0;
1291                         }
1292
1293         // vote nagging
1294         if(self.cvar_scr_centertime)
1295                 if(time > self.vote_nagtime)
1296                 {
1297                         VoteNag();
1298                         self.vote_nagtime = time + self.cvar_scr_centertime * 0.6;
1299                 }
1300
1301         if(self.classname == "player") {
1302                 local vector m1, m2;
1303
1304 //              if(self.netname == "Wazat")
1305 //                      bprint(self.classname, "\n");
1306
1307                 CheckRules_Player();
1308
1309                 if(self.button7)
1310                         PrintWelcomeMessage(self);
1311
1312                 if(cvar("g_lms") || !cvar("sv_spectate"))
1313                 if((time - self.jointime) <= cvar("welcome_message_time"))
1314                         PrintWelcomeMessage(self);
1315
1316                 if (intermission_running)
1317                 {
1318                         IntermissionThink ();   // otherwise a button could be missed between
1319                         return;                                 // the think tics
1320                 }
1321
1322                 if(time > self.teleport_time)
1323                 {
1324                         self.effects = self.effects - (self.effects & EF_NODRAW);
1325                         if(self.weaponentity)
1326                                 self.weaponentity.flags = self.weaponentity.flags - (self.weaponentity.flags & EF_NODRAW);
1327                 }
1328
1329                 Nixnex_GiveCurrentWeapon();
1330                 UpdateSelectedPlayer();
1331
1332                 if (self.deadflag != DEAD_NO)
1333                 {
1334                         float button_pressed, force_respawn;
1335                         player_anim();
1336                         button_pressed = (self.button0 || self.button2 || self.button3 || self.button6 || self.buttonuse);
1337                         force_respawn = (cvar("g_lms") || cvar("g_forced_respawn"));
1338                         if (self.deadflag == DEAD_DYING)
1339                         {
1340                                 if(force_respawn)
1341                                         self.deadflag = DEAD_RESPAWNING;
1342                                 else if(!button_pressed)
1343                                         self.deadflag = DEAD_DEAD;
1344                         }
1345                         else if (self.deadflag == DEAD_DEAD)
1346                         {
1347                                 if(button_pressed)
1348                                         self.deadflag = DEAD_RESPAWNABLE;
1349                         }
1350                         else if (self.deadflag == DEAD_RESPAWNABLE)
1351                         {
1352                                 if(!button_pressed)
1353                                         self.deadflag = DEAD_RESPAWNING;
1354                         }
1355                         else if (self.deadflag == DEAD_RESPAWNING)
1356                         {
1357                                 if(time > self.death_time)
1358                                         respawn();
1359                         }
1360                         ShowRespawnCountdown();
1361                         return;
1362                 }
1363
1364                 if(cvar("g_lms") && !self.deadflag && cvar("g_lms_campcheck_interval"))
1365                 {
1366                         vector dist;
1367
1368                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
1369                         dist = self.oldorigin - self.origin;
1370                         dist_z = 0;
1371                         self.lms_traveled_distance += fabs(vlen(dist));
1372
1373                         if(cvar("g_campaign"))
1374                         if(!campaign_bots_may_start)
1375                         {
1376                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
1377                                 self.lms_traveled_distance = 0;
1378                         }
1379
1380                         if(time > self.lms_nextcheck)
1381                         {
1382                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
1383                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
1384                                 {
1385                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
1386                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
1387                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
1388                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
1389                                 }
1390                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
1391                                 self.lms_traveled_distance = 0;
1392                         }
1393                 }
1394
1395                 if (self.button5 && !self.hook.state)
1396                 {
1397                         if (!self.crouch)
1398                         {
1399                                 self.crouch = TRUE;
1400                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
1401                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
1402                         }
1403                 }
1404                 else
1405                 {
1406                         if (self.crouch)
1407                         {
1408                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
1409                                 if (!trace_startsolid)
1410                                 {
1411                                         self.crouch = FALSE;
1412                                         self.view_ofs = PL_VIEW_OFS;
1413                                         setsize (self, PL_MIN, PL_MAX);
1414                                 }
1415                         }
1416                 }
1417
1418                 if(cvar("sv_defaultcharacter") == 1 && !teams_matter) {
1419                         local string defaultmodel;
1420                         defaultmodel = CheckPlayerModel(cvar_string("sv_defaultplayermodel"));
1421
1422                         if (defaultmodel != self.model)
1423                         {
1424                                 m1 = self.mins;
1425                                 m2 = self.maxs;
1426                                 setmodel_lod (self, defaultmodel);
1427                                 setsize (self, m1, m2);
1428                         }
1429
1430                         if (self.skin != cvar("sv_defaultplayerskin"))
1431                                 self.skin = cvar("sv_defaultplayerskin");
1432                 } else {
1433                         if (self.playermodel != self.model)
1434                         {
1435                                 self.playermodel = CheckPlayerModel(self.playermodel);
1436                                 m1 = self.mins;
1437                                 m2 = self.maxs;
1438                                 setmodel_lod (self, self.playermodel);
1439                                 setsize (self, m1, m2);
1440                         }
1441
1442                         if(teams_matter)
1443                         {
1444                                 if (self.skin != math_mod(stof(self.playerskin), NUM_PLAYERSKINS_TEAMPLAY))
1445                                         self.skin = math_mod(stof(self.playerskin), NUM_PLAYERSKINS_TEAMPLAY);
1446                         }
1447                         else
1448                         {
1449                                 if (self.skin != stof(self.playerskin))
1450                                         self.skin = stof(self.playerskin);
1451                         }
1452                 }
1453
1454                 GrapplingHookFrame();
1455
1456                 W_WeaponFrame();
1457
1458                 {
1459                         float zoomfactor, zoomspeed, zoomdir;
1460                         zoomfactor = self.cvar_cl_zoomfactor;
1461                         if(zoomfactor < 1 || zoomfactor > 16)
1462                                 zoomfactor = 2.5;
1463                         zoomspeed = self.cvar_cl_zoomspeed;
1464                         if(zoomspeed >= 0) // < 0 is instant zoom
1465                                 if(zoomspeed < 0.5 || zoomspeed > 16)
1466                                         zoomspeed = 3.5;
1467
1468                         zoomdir = self.button4;
1469                         if(self.button3)
1470                                 if(self.weapon == WEP_NEX)
1471                                         if(!cvar("g_minstagib"))
1472                                                 zoomdir = 1;
1473
1474                         if(zoomdir)
1475                                 self.has_zoomed = 1;
1476
1477                         if(self.has_zoomed)
1478                         {
1479                                 if(zoomspeed <= 0) // instant zoom
1480                                 {
1481                                         if(zoomdir)
1482                                                 self.viewzoom = 1 / zoomfactor;
1483                                         else
1484                                                 self.viewzoom = 1;
1485                                 }
1486                                 else
1487                                 {
1488                                         // geometric zoom would be:
1489                                         //   self.viewzoom = bound(1 / zoomfactor, self.viewzoom * pow(zoomfactor, (zoomdir ? -1 : 1) * frametime * zoomspeed), 1);
1490                                         // however, testing showed that arithmetic/harmonic zoom works better
1491                                         if(zoomdir)
1492                                                 // self.viewzoom = 1 / bound(1, 1 / self.viewzoom + (zoomdir ? 1 : -1) * frametime * zoomspeed * (zoomfactor - 1), zoomfactor);
1493                                                 // zoom in = arithmetic: 1x, 2x, 3x, 4x, ..., 8x
1494                                                 self.viewzoom = 1 / bound(1, 1 / self.viewzoom + frametime * zoomspeed * (zoomfactor - 1), zoomfactor);
1495                                         else
1496                                                 // self.viewzoom = bound(1 / zoomfactor, self.viewzoom + (zoomdir ? -1 : 1) * frametime * zoomspeed * (1 - 1 / zoomfactor), 1);
1497                                                 // zoom out = harmonic: 8/1x, 8/2x, 8/3x, 8/4x, ..., 8/8x
1498                                                 self.viewzoom = bound(1 / zoomfactor, self.viewzoom + frametime * zoomspeed * (1 - 1 / zoomfactor), 1);
1499                                 }
1500                         }
1501                         else
1502                                 self.viewzoom = min(1, self.viewzoom + frametime); // spawn zoom-in
1503                 }
1504
1505                 player_powerups();
1506                 player_regen();
1507                 player_anim();
1508
1509                 if (cvar("g_minstagib"))
1510                         minstagib_ammocheck();
1511
1512                 ctf_setstatus();
1513                 kh_setstatus();
1514
1515                 //self.angles_y=self.v_angle_y + 90;   // temp
1516
1517                 //if (TetrisPreFrame()) return;
1518         } else if(gameover) {
1519                 if (intermission_running)
1520                         IntermissionThink ();   // otherwise a button could be missed between
1521                 return;
1522         } else if(self.classname == "observer") {
1523
1524                 if (self.flags & FL_JUMPRELEASED) {
1525                         if (self.button2 && self.version == cvar("gameversion")) {
1526                                 self.welcomemessage_time = 0;
1527                                 self.flags = self.flags - FL_JUMPRELEASED;
1528                                 LeaveSpectatorMode();
1529                                 return;
1530                         } else if(self.button0 && self.version == cvar("gameversion")) {
1531                                 self.welcomemessage_time = 0;
1532                                 self.flags = self.flags - FL_JUMPRELEASED;
1533                                 if(SpectateNext() == 1) {
1534                                         self.classname = "spectator";
1535                                 }
1536                         }
1537                 } else {
1538                         if (!(self.button0 || self.button2)) {
1539                                 self.flags = self.flags | FL_JUMPRELEASED;
1540                         }
1541                 }
1542                 PrintWelcomeMessage(self);
1543         } else if(self.classname == "spectator") {
1544                 if (self.flags & FL_JUMPRELEASED) {
1545                         if (self.button2 && self.version == cvar("gameversion")) {
1546                                 self.welcomemessage_time = 0;
1547                                 self.flags = self.flags - FL_JUMPRELEASED;
1548                                 LeaveSpectatorMode();
1549                                 return;
1550                         } else if(self.button0) {
1551                                 self.welcomemessage_time = 0;
1552                                 self.flags = self.flags - FL_JUMPRELEASED;
1553                                 if(SpectateNext() == 1) {
1554                                         self.classname = "spectator";
1555                                 } else {
1556                                         self.classname = "observer";
1557                                         PutClientInServer();
1558                                 }
1559                         } else if (self.button3) {
1560                                 self.welcomemessage_time = 0;
1561                                 self.flags = self.flags - FL_JUMPRELEASED;
1562                                 self.classname = "observer";
1563                                 PutClientInServer();
1564                         } else {
1565                                 SpectateUpdate();
1566                         }
1567                 } else {
1568                         if (!(self.button0 || self.button3)) {
1569                                 self.flags = self.flags | FL_JUMPRELEASED;
1570                         }
1571                 }
1572                 PrintWelcomeMessage(self);
1573                 self.flags = self.flags | FL_CLIENT | FL_NOTARGET;
1574         }
1575 }
1576
1577
1578 /*
1579 =============
1580 PlayerPostThink
1581
1582 Called every frame for each client after the physics are run
1583 =============
1584 */
1585 void PlayerPostThink (void)
1586 {
1587         // Savage: Check for nameless players
1588         if (strlen(self.netname) < 1) {
1589                 self.netname = "Player";
1590                 stuffcmd(self, "seta _cl_name Player\n");
1591         }
1592
1593         if(self.classname == "player") {
1594                 CheckRules_Player();
1595                 UpdateChatBubble();
1596                 UpdateTeamBubble();
1597                 if (self.impulse)
1598                         ImpulseCommands ();
1599                 if (intermission_running)
1600                         return;         // intermission or finale
1601
1602                 //PrintWelcomeMessage(self);
1603                 //if (TetrisPostFrame()) return;
1604         } else if (self.classname == "observer") {
1605                 //do nothing
1606         } else if (self.classname == "spectator") {
1607                 //do nothing
1608         }
1609         Arena_Warmup();
1610 }