data/qcsrc/server/cl_client.qc

   1 void info_player_start (void)
   2 {
   3         self.classname = "info_player_deathmatch";
   4         relocate_spawnpoint();
   5 }
   6
   7 void info_player_deathmatch (void)
   8 {
   9         relocate_spawnpoint();
  10 }
  11
  12 float spawn_allbad;
  13 float spawn_allgood;
  14 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
  15 {
  16         local entity spot, player, nextspot, previousspot, newfirstspot;
  17         local float pcount;
  18         spot = firstspot;
  19         newfirstspot = world;
  20         previousspot = world;
  21         spawn_allgood = TRUE;
  22         spawn_allbad = TRUE;
  23         while (spot)
  24         {
  25                 nextspot = spot.chain;
  26                 // count team mismatches as bad spots
  27                 if (spot.team == teamcheck)
  28                 {
  29                         pcount = 0;
  30                         player = playerlist;
  31                         while (player)
  32                         {
  33                                 if (player != self)
  34                                 if (vlen(player.origin - spot.origin) < mindist)
  35                                         pcount = pcount + 1;
  36                                 player = player.chain;
  37                         }
  38                         if (!pcount)
  39                         {
  40                                 spawn_allbad = FALSE;
  41                                 if (newfirstspot)
  42                                         previousspot.chain = spot;
  43                                 else
  44                                         newfirstspot = spot;
  45                                 previousspot = spot;
  46                                 spot.chain = world;
  47                         }
  48                         else
  49                                 spawn_allgood = FALSE;
  50                 }
  51                 spot = nextspot;
  52         }
  53         // if we couldn't find ANY good points, return the original list
  54         if (!newfirstspot)
  55                 newfirstspot = firstspot;
  56         return newfirstspot;
  57 }
  58
  59 entity Spawn_RandomPoint(entity firstspot)
  60 {
  61         local entity spot;
  62         local float numspots;
  63         // count number of spots
  64         numspots = 0;
  65         spot = firstspot;
  66         while (spot)
  67         {
  68                 numspots = numspots + 1;
  69                 spot = spot.chain;
  70         }
  71         // pick a random one
  72         numspots = numspots * random();
  73         spot = firstspot;
  74         while (spot.chain && numspots >= 1)
  75         {
  76                 numspots = numspots - 1;
  77                 spot = spot.chain;
  78         }
  79         return spot;
  80 }
  81
  82 entity Spawn_FurthestPoint(entity firstspot, entity playerlist)
  83 {
  84         local entity best, spot, player;
  85         local float bestrating, rating;
  86         best = world;
  87         bestrating = -1000000;
  88         spot = firstspot;
  89         while (spot)
  90         {
  91                 rating = 1000000000;
  92                 player = playerlist;
  93                 while (player)
  94                 {
  95                         if (player != self)
  96                                 rating = min(rating, vlen(player.origin - spot.origin));
  97                         player = player.chain;
  98                 }
  99                 rating = rating + random() * 16;
 100                 if (bestrating < rating)
 101                 {
 102                         best = spot;
 103                         bestrating = rating;
 104                 }
 105                 spot = spot.chain;
 106         }
 107         return best;
 108 }
 109
 110 /*
 111 =============
 112 SelectSpawnPoint
 113
 114 Finds a point to respawn
 115 =============
 116 */
 117 entity SelectSpawnPoint (float anypoint)
 118 {
 119         local float teamcheck;
 120         local entity spot, firstspot, playerlist;
 121
 122         spot = find (world, classname, "testplayerstart");
 123         if (spot)
 124                 return spot;
 125
 126         teamcheck = 0;
 127
 128         if(!anypoint && cvar("g_ctf") )
 129                 teamcheck = self.team;
 130
 131         // get the list of players
 132         playerlist = findchain(classname, "player");
 133         // get the entire list of spots
 134         firstspot = findchain(classname, "info_player_deathmatch");
 135         // filter out the bad ones
 136         // (note this returns the original list if none survived)
 137         firstspot = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 138
 139         // there is 50/50 chance of choosing a random spot or the furthest spot
 140         // (this means that roughly every other spawn will be furthest, so you
 141         // usually won't get fragged at spawn twice in a row)
 142         if (arena_roundbased)
 143         {
 144                 firstspot = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 145                 spot = Spawn_RandomPoint(firstspot);
 146         }
 147         else if (random() > 0.5 || spawn_allbad || spawn_allgood)
 148                 spot = Spawn_RandomPoint(firstspot);
 149         else
 150                 spot = Spawn_FurthestPoint(firstspot, playerlist);
 151
 152         if (!spot)
 153         {
 154                 if(cvar("spawn_debug"))
 155                         GotoNextMap();
 156                 else
 157                         error ("PutClientInServer: no start points on level");
 158         }
 159
 160         return spot;
 161 }
 162
 163 /*
 164 =============
 165 CheckPlayerModel
 166
 167 Checks if the argument string can be a valid playermodel.
 168 Returns a valid one in doubt.
 169 =============
 170 */
 171 string FallbackPlayerModel = "models/player/marine.zym";
 172 string CheckPlayerModel(string plyermodel) {
 173         if(strlen(plyermodel) < 4)
 174                 return FallbackPlayerModel;
 175         if( substring(plyermodel,0,14) != "models/player/")
 176                 return FallbackPlayerModel;
 177         else if(cvar("sv_servermodelsonly"))
 178         {
 179                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 180                         return FallbackPlayerModel;
 181                 if(!fexists(plyermodel))
 182                         return FallbackPlayerModel;
 183         }
 184         return plyermodel;
 185 }
 186
 187 /*
 188 =============
 189 Client_customizeentityforclient
 190
 191 LOD reduction
 192 =============
 193 */
 194 float Client_customizeentityforclient()
 195 {
 196 #ifdef ALLOW_VARIABLE_LOD
 197         // self: me
 198         // other: the player viewing me
 199         float distance;
 200         float f;
 201
 202         if(self.flags & FL_NOTARGET) // we don't need LOD for spectators
 203                 return TRUE;
 204
 205         if(other.cvar_cl_playerdetailreduction <= 0)
 206         {
 207                 if(other.cvar_cl_playerdetailreduction <= -2)
 208                         self.modelindex = self.modelindex_lod2;
 209                 else if(other.cvar_cl_playerdetailreduction <= -1)
 210                         self.modelindex = self.modelindex_lod1;
 211                 else
 212                         self.modelindex = self.modelindex_lod0;
 213         }
 214         else
 215         {
 216                 distance = vlen(self.origin - other.origin);
 217                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 218                 if(f > 10000)
 219                         self.modelindex = self.modelindex_lod2;
 220                 else if(f > 5000)
 221                         self.modelindex = self.modelindex_lod1;
 222                 else
 223                         self.modelindex = self.modelindex_lod0;
 224         }
 225 #endif
 226
 227         return TRUE;
 228 }
 229
 230 void setmodel_lod(entity e, string modelname)
 231 {
 232 #ifdef ALLOW_VARIABLE_LOD
 233         string s;
 234
 235         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1.zym");
 236         if(fexists(s))
 237         {
 238                 precache_model(s);
 239                 setmodel(e, s);
 240                 self.modelindex_lod1 = self.modelindex;
 241         }
 242         else
 243                 self.modelindex_lod1 = -1;
 244
 245         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2.zym");
 246         if(fexists(s))
 247         {
 248                 precache_model(s);
 249                 setmodel(e, s);
 250                 self.modelindex_lod2 = self.modelindex;
 251         }
 252         else
 253                 self.modelindex_lod2 = -1;
 254
 255         precache_model(modelname);
 256         setmodel(e, modelname);
 257         self.modelindex_lod0 = self.modelindex;
 258
 259         if(self.modelindex_lod1 < 0)
 260                 self.modelindex_lod1 = self.modelindex;
 261
 262         if(self.modelindex_lod2 < 0)
 263                 self.modelindex_lod2 = self.modelindex;
 264 #else
 265         precache_model(modelname);
 266         setmodel(e, modelname);
 267 #endif
 268 }
 269
 270 /*
 271 =============
 272 PutObserverInServer
 273
 274 putting a client as observer in the server
 275 =============
 276 */
 277 void PutObserverInServer (void)
 278 {
 279         entity  spot;
 280         spot = SelectSpawnPoint (FALSE);
 281         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 282
 283         if(clienttype(self) == CLIENTTYPE_REAL)
 284         {
 285                 msg_entity = self;
 286                 WriteByte(MSG_ONE, SVC_SETVIEW);
 287                 WriteEntity(MSG_ONE, self);
 288         }
 289
 290         if (cvar("g_runematch"))
 291                 DropAllRunes(self);
 292
 293         if(self.frags <= 0 && self.frags > -666 && cvar("g_lms") && self.killcount != -666)
 294                 bprint (strcat("^4", self.netname, "^4 has no more lives left\n"));
 295         else if(self.killcount != -666)
 296                 bprint (strcat("^4", self.netname, "^4 is spectating now\n"));
 297
 298         self.classname = "observer";
 299         self.health = -666;
 300         self.takedamage = DAMAGE_NO;
 301         self.solid = SOLID_NOT;
 302         self.movetype = MOVETYPE_NOCLIP;
 303         self.flags = FL_CLIENT | FL_NOTARGET;
 304         self.armorvalue = 666;
 305         self.effects = 0;
 306         self.armorvalue = cvar("g_balance_armor_start");
 307         self.pauserotarmor_finished = 0;
 308         self.pauserothealth_finished = 0;
 309         self.pauseregen_finished = 0;
 310         self.damageforcescale = 0;
 311         self.death_time = 0;
 312         self.dead_time = 0;
 313         self.dead_frame = 0;
 314         self.die_frame = 0;
 315         self.deaths = 0;
 316         self.alpha = 0;
 317         self.scale = 0;
 318         self.fade_time = 0;
 319         self.pain_frame = 0;
 320         self.pain_finished = 0;
 321         self.strength_finished = 0;
 322         self.invincible_finished = 0;
 323         self.pushltime = 0;
 324         self.think = SUB_Null;
 325         self.nextthink = 0;
 326         self.hook_time = 0;
 327         self.runes = 0;
 328         self.deadflag = DEAD_NO;
 329         self.angles = spot.angles;
 330         self.angles_z = 0;
 331         self.fixangle = TRUE;
 332         self.crouch = FALSE;
 333
 334         self.view_ofs = PL_VIEW_OFS;
 335         setorigin (self, spot.origin);
 336         setsize (self, '0 0 0', '0 0 0');
 337         self.oldorigin = self.origin;
 338         self.items = 0;
 339         self.model = "";
 340         self.modelindex = 0;
 341         self.weapon = 0;
 342         self.weaponmodel = "";
 343         self.weaponentity = world;
 344         self.killcount = -666;
 345         self.velocity = '0 0 0';
 346         self.avelocity = '0 0 0';
 347         self.punchangle = '0 0 0';
 348         self.punchvector = '0 0 0';
 349         self.oldvelocity = self.velocity;
 350         self.customizeentityforclient = Client_customizeentityforclient;
 351
 352         if(cvar("g_arena"))
 353         {
 354                 if(self.frags != -2)
 355                 {
 356                         Spawnqueue_Insert(self);
 357                 }
 358                 else
 359                 {
 360                         Spawnqueue_Unmark(self);
 361                         Spawnqueue_Remove(self);
 362                 }
 363         }
 364         else if(!cvar("g_lms"))
 365                 self.frags = -666;
 366 }
 367
 368
 369 /*
 370 =============
 371 PutClientInServer
 372
 373 Called when a client spawns in the server
 374 =============
 375 */
 376 void PutClientInServer (void)
 377 {
 378         if(clienttype(self) == CLIENTTYPE_BOT)
 379         {
 380                 self.classname = "player";
 381         }
 382         else if(clienttype(self) == CLIENTTYPE_REAL)
 383         {
 384                 msg_entity = self;
 385                 WriteByte(MSG_ONE, SVC_SETVIEW);
 386                 WriteEntity(MSG_ONE, self);
 387         }
 388
 389         // player is dead and becomes observer
 390         if(cvar("g_lms") && self.frags < 1)
 391                 self.classname = "observer";
 392
 393         if(cvar("g_arena"))
 394         if(!self.spawned)
 395                 self.classname = "observer";
 396
 397         if(self.classname == "player") {
 398                 entity  spot;
 399
 400                 spot = SelectSpawnPoint (FALSE);
 401
 402                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 403
 404                 self.classname = "player";
 405                 self.iscreature = TRUE;
 406                 self.movetype = MOVETYPE_WALK;
 407                 self.solid = SOLID_SLIDEBOX;
 408                 self.flags = FL_CLIENT;
 409                 self.takedamage = DAMAGE_AIM;
 410                 self.effects = 0;
 411                 self.health = cvar("g_balance_health_start");
 412                 self.armorvalue = cvar("g_balance_armor_start");
 413                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 414                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 415                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 416                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 417                 self.damageforcescale = 2;
 418                 self.death_time = 0;
 419                 self.dead_time = 0;
 420                 self.dead_frame = 0;
 421                 self.die_frame = 0;
 422                 self.alpha = 0;
 423                 self.scale = 0;
 424                 self.fade_time = 0;
 425                 self.pain_frame = 0;
 426                 self.pain_finished = 0;
 427                 self.strength_finished = 0;
 428                 self.invincible_finished = 0;
 429                 self.pushltime = 0;
 430                 //self.speed_finished = 0;
 431                 //self.slowmo_finished = 0;
 432                 // players have no think function
 433                 self.think = SUB_Null;
 434                 self.nextthink = 0;
 435                 self.weapon = 0;
 436                 self.switchweapon = 0;
 437                 self.hook_time = 0;
 438
 439                 self.runes = 0;
 440
 441                 self.deadflag = DEAD_NO;
 442
 443                 self.angles = spot.angles;
 444
 445                 self.angles_z = 0; // never spawn tilted even if the spot says to
 446                 self.fixangle = TRUE; // turn this way immediately
 447                 self.velocity = '0 0 0';
 448                 self.avelocity = '0 0 0';
 449                 self.punchangle = '0 0 0';
 450                 self.punchvector = '0 0 0';
 451                 self.oldvelocity = self.velocity;
 452
 453                 self.viewzoom = 0.6;
 454
 455                 self.customizeentityforclient = Client_customizeentityforclient;
 456
 457                 if(cvar("sv_defaultcharacter") == 1 && !teams_matter) {
 458                         local string defaultmodel;
 459                         defaultmodel = CheckPlayerModel(cvar_string("sv_defaultplayermodel"));
 460                         setmodel_lod (self, defaultmodel);
 461                         self.skin = stof(cvar_string("sv_defaultplayerskin"));
 462                 } else {
 463                         self.playermodel = CheckPlayerModel(self.playermodel);
 464                         setmodel_lod (self, self.playermodel);
 465                         self.skin = stof(self.playerskin);
 466
 467                 }
 468
 469                 self.crouch = FALSE;
 470                 self.view_ofs = PL_VIEW_OFS;
 471                 setsize (self, PL_MIN, PL_MAX);
 472                 self.spawnorigin = spot.origin;
 473                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 474                 // don't reset back to last position, even if new position is stuck in solid
 475                 self.oldorigin = self.origin;
 476
 477                 if(cvar("g_lms"))
 478                 {
 479                         self.ammo_shells = cvar("g_lms_start_ammo_shells");
 480                         self.ammo_nails = cvar("g_lms_start_ammo_nails");
 481                         self.ammo_rockets = cvar("g_lms_start_ammo_rockets");
 482                         self.ammo_cells = cvar("g_lms_start_ammo_cells");
 483                         self.health = cvar("g_lms_start_health");
 484                         self.armorvalue = cvar("g_lms_start_armor");
 485                 }
 486                 else if (cvar("g_use_ammunition")) {
 487                         self.ammo_shells = cvar("g_start_ammo_shells");
 488                         self.ammo_nails = cvar("g_start_ammo_nails");
 489                         self.ammo_rockets = cvar("g_start_ammo_rockets");
 490                         self.ammo_cells = cvar("g_start_ammo_cells");
 491                 } else {
 492                         self.ammo_shells = 999;
 493                         self.ammo_nails = 999;
 494                         self.ammo_rockets = 999;
 495                         self.ammo_cells = 999;
 496                 }
 497
 498                 self.items = 0;
 499                 if (cvar("g_start_weapon_laser") || cvar("g_lms"))
 500                 {
 501                         self.items = self.items | IT_LASER;
 502                         self.switchweapon = WEP_LASER;
 503                 }
 504                 if (cvar("g_start_weapon_shotgun") || cvar("g_lms"))
 505                 {
 506                         self.items = self.items | IT_SHOTGUN;
 507                         self.switchweapon = WEP_SHOTGUN;
 508                 }
 509                 if (cvar("g_start_weapon_uzi") || cvar("g_lms"))
 510                 {
 511                         self.items = self.items | IT_UZI;
 512                         self.switchweapon = WEP_UZI;
 513                 }
 514                 if (cvar("g_start_weapon_grenadelauncher") || cvar("g_lms"))
 515                 {
 516                         self.items = self.items | IT_GRENADE_LAUNCHER;
 517                         self.switchweapon = WEP_GRENADE_LAUNCHER;
 518                 }
 519                 if (cvar("g_start_weapon_electro") || cvar("g_lms"))
 520                 {
 521                         self.items = self.items | IT_ELECTRO;
 522                         self.switchweapon = WEP_ELECTRO;
 523                 }
 524                 if (cvar("g_start_weapon_crylink") || cvar("g_lms"))
 525                 {
 526                         self.items = self.items | IT_CRYLINK;
 527                         self.switchweapon = WEP_CRYLINK;
 528                 }
 529                 if (cvar("g_start_weapon_nex") || cvar("g_lms"))
 530                 {
 531                         self.items = self.items | IT_NEX;
 532                         self.switchweapon = WEP_NEX;
 533                 }
 534                 if (cvar("g_start_weapon_hagar") || cvar("g_lms"))
 535                 {
 536                         self.items = self.items | IT_HAGAR;
 537                         self.switchweapon = WEP_HAGAR;
 538                 }
 539                 if (cvar("g_start_weapon_rocketlauncher") || cvar("g_lms"))
 540                 {
 541                         self.items = self.items | IT_ROCKET_LAUNCHER;
 542                         self.switchweapon = WEP_ROCKET_LAUNCHER;
 543                 }
 544
 545                 if(cvar("g_instagib"))
 546                 {
 547                         self.items = IT_NEX;
 548                         self.switchweapon = WEP_NEX;
 549                         self.ammo_cells = 999;
 550                 }
 551
 552                 if(cvar("g_rocketarena"))
 553                 {
 554                         self.items = IT_ROCKET_LAUNCHER;
 555                         self.switchweapon = WEP_ROCKET_LAUNCHER;
 556                         self.ammo_rockets = 999;
 557                 }
 558
 559                 if(cvar("g_nixnex"))
 560                 {
 561                         self.items = 0;
 562                         // will be done later
 563                 }
 564
 565                 if(cvar("g_minstagib"))
 566                 {
 567                         self.health = 100;
 568                         self.armorvalue = 0;
 569                         self.items = IT_NEX;
 570                         self.switchweapon = WEP_NEX;
 571                         self.ammo_cells = cvar("g_minstagib_ammo_start");
 572                         self.extralives = 0;
 573                         self.jump_interval = time;
 574                 }
 575
 576                 if(cvar("g_arena"))
 577                 {
 578                         Spawnqueue_Remove(self);
 579                         Spawnqueue_Mark(self);
 580                 }
 581
 582                 self.event_damage = PlayerDamage;
 583
 584                 self.bot_attack = TRUE;
 585
 586                 self.statdraintime = time + 5;
 587                 self.button0 = self.button1 = self.button2 = self.button3 = 0;
 588
 589                 if(self.killcount == -666) {
 590                         self.killcount = 0;
 591                         if(!cvar("g_arena"))
 592                         if(!cvar("g_lms"))
 593                                 self.frags = 0;
 594                 }
 595
 596                 self.cnt = WEP_LASER;
 597                 self.nixnex_lastchange_id = -1;
 598
 599                 CL_SpawnWeaponentity();
 600                 self.alpha = default_player_alpha;
 601                 self.exteriorweaponentity.alpha = default_player_alpha;
 602
 603                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 604                 self.lms_traveled_distance = 0;
 605
 606                 if(cvar("spawn_debug"))
 607                 {
 608                                 sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 609                                 remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 610                 }
 611
 612                 //stuffcmd(self, "chase_active 0");
 613                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 614         } else if(self.classname == "observer") {
 615                 PutObserverInServer ();
 616         }
 617 }
 618
 619 /*
 620 =============
 621 SetNewParms
 622 =============
 623 */
 624 void SetNewParms (void)
 625 {
 626
 627 }
 628
 629 /*
 630 =============
 631 SetChangeParms
 632 =============
 633 */
 634 void SetChangeParms (void)
 635 {
 636
 637 }
 638
 639 /*
 640 =============
 641 ClientKill
 642
 643 Called when a client types 'kill' in the console
 644 =============
 645 */
 646 void ClientKill (void)
 647 {
 648         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 649 }
 650
 651 /*
 652 =============
 653 ClientConnect
 654
 655 Called when a client connects to the server
 656 =============
 657 */
 658 string ColoredTeamName(float t);
 659 //void dom_player_join_team(entity pl);
 660 void ClientConnect (void)
 661 {
 662         self.classname = "player_joining";
 663         self.flags = self.flags | FL_CLIENT;
 664
 665         if(player_count<0) player_count = 0;
 666
 667         bot_clientconnect();
 668
 669         //if(cvar("g_domination"))
 670         //      dom_player_join_team(self);
 671
 672         //JoinBestTeam(self, FALSE);
 673
 674         if((cvar("sv_spectate") == 1 && !cvar("g_lms")) || cvar("g_campaign")) {
 675                 self.classname = "observer";
 676         } else {
 677                 self.classname = "player";
 678                 campaign_bots_may_start = 1;
 679         }
 680
 681         self.playerid = (playerid_last = playerid_last + 1);
 682         if(cvar("sv_eventlog"))
 683         {
 684                 string s;
 685                 if(clienttype(self) == CLIENTTYPE_REAL)
 686                         s = "player";
 687                 else
 688                         s = "bot";
 689                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", s, ":", self.netname), TRUE);
 690                 s = strcat(":team:", ftos(self.playerid), ":");
 691                 s = strcat(s, ftos(self.team));
 692                 GameLogEcho(s, FALSE);
 693         }
 694
 695         //stuffcmd(self, "set tmpviewsize $viewsize \n");
 696
 697         bprint ("^4",self.netname);
 698         bprint ("^4 connected");
 699
 700         if(cvar("g_domination") || cvar("g_ctf"))
 701         {
 702                 bprint(" and joined the ");
 703                 bprint(ColoredTeamName(self.team));
 704         }
 705
 706         bprint("\n");
 707
 708         self.welcomemessage_time = time + cvar("welcome_message_time");
 709         self.welcomemessage_time2 = 0;
 710
 711         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
 712         // send prediction settings to the client
 713         stuffcmd(self, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
 714         stuffcmd(self, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
 715         stuffcmd(self, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
 716         stuffcmd(self, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
 717         stuffcmd(self, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
 718         stuffcmd(self, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
 719         stuffcmd(self, strcat("cl_movement_jumpvelocity ", ftos(cvar("g_balance_jumpheight")), "\n"));
 720         stuffcmd(self, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
 721         stuffcmd(self, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
 722         stuffcmd(self, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
 723         stuffcmd(self, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
 724         stuffcmd(self, strcat("cl_movement_edgefriction 0\n"));
 725         // Wazat's grappling hook
 726         SetGrappleHookBindings();
 727
 728         // get autoswitch state from player
 729         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1; cmd autoswitch $1\"\n");
 730         stuffcmd(self, "cmd autoswitch $cl_autoswitch\n");
 731
 732         // get version info from player
 733         stuffcmd(self, "cmd clientversion $gameversion\n");
 734
 735         // get other cvars from player
 736         GetCvars(0);
 737
 738         // set cvar for team scoreboard
 739         if (teams_matter)
 740         {
 741                 local float t;
 742                 t = cvar("teamplay");
 743                 // we have to stuff the correct teamplay value because if this is a listen server, this changes the teamplay mode of the server itself, which is bad
 744                 stuffcmd(self, strcat("set teamplay ", ftos(t), "\n"));
 745         }
 746         else
 747                 stuffcmd(self, strcat("set teamplay 0\n"));
 748
 749         if(cvar("g_lms"))
 750         {
 751                 self.frags = cvar("fraglimit");
 752                 // no fraglimit was set, so player gets 999 lives
 753                 if(self.frags < 1)
 754                         self.frags = 999;
 755
 756                 // disallow player to join after the worst player has lost g_lms_last_join lives
 757                 // if "g_lms_join_anytime" new players spawn with same amount of lives as the worst active player
 758                 if(((cvar("fraglimit") - cvar("g_lms_last_join")) > lms_lowest_lives && !cvar("g_lms_join_anytime")) || lms_lowest_lives < 1)
 759                 {
 760                         self.frags = -666;
 761                         lms_dead_count += 1;
 762                 }
 763                 else if(cvar("fraglimit") > lms_lowest_lives)
 764                 {
 765                         self.frags = lms_lowest_lives;
 766                 }
 767         }
 768         else if(cvar("g_arena"))
 769         {
 770                 self.classname = "observer";
 771                 Spawnqueue_Insert(self);
 772         }
 773
 774         bot_relinkplayerlist();
 775
 776         self.jointime = time;
 777 }
 778
 779 /*
 780 =============
 781 ClientDisconnect
 782
 783 Called when a client disconnects from the server
 784 =============
 785 */
 786 void(entity e) DropFlag;
 787 .entity chatbubbleentity;
 788 .entity teambubbleentity;
 789 void ClientDisconnect (void)
 790 {
 791         float save;
 792         if(cvar("sv_eventlog"))
 793                 GameLogEcho(strcat(":part:", ftos(self.playerid)), FALSE);
 794         bprint ("^4",self.netname);
 795         bprint ("^4 disconnected\n");
 796
 797         if (self.chatbubbleentity)
 798         {
 799                 remove (self.chatbubbleentity);
 800                 self.chatbubbleentity = world;
 801         }
 802
 803         if (self.teambubbleentity)
 804         {
 805                 remove (self.teambubbleentity);
 806                 self.teambubbleentity = world;
 807         }
 808
 809         DropAllRunes(self);
 810
 811         if(self.flagcarried)
 812                 DropFlag(self.flagcarried);
 813
 814         save = self.flags;
 815         self.flags = self.flags - (self.flags & FL_CLIENT);
 816         bot_relinkplayerlist();
 817         self.flags = save;
 818
 819         // remove laserdot
 820         remove(self.weaponentity.lasertarget);
 821
 822         // player was dead, decrease dead count
 823         if(cvar("g_lms") && self.frags < 1)
 824                 lms_dead_count -= 1;
 825         else if(cvar("g_arena"))
 826         {
 827                 Spawnqueue_Unmark(self);
 828                 Spawnqueue_Remove(self);
 829         }
 830 }
 831
 832 .float buttonchat;
 833 void() ChatBubbleThink =
 834 {
 835         self.nextthink = time;
 836         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
 837         {
 838                 self.owner.chatbubbleentity = world;
 839                 remove(self);
 840                 return;
 841         }
 842         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
 843         if (self.owner.buttonchat && !self.owner.deadflag)
 844                 self.model = self.mdl;
 845         else
 846                 self.model = "";
 847 };
 848
 849 void() UpdateChatBubble =
 850 {
 851         if (!self.modelindex)
 852                 return;
 853         // spawn a chatbubble entity if needed
 854         if (!self.chatbubbleentity)
 855         {
 856                 self.chatbubbleentity = spawn();
 857                 self.chatbubbleentity.owner = self;
 858                 self.chatbubbleentity.exteriormodeltoclient = self;
 859                 self.chatbubbleentity.think = ChatBubbleThink;
 860                 self.chatbubbleentity.nextthink = time;
 861                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr");
 862                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 863                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
 864                 self.chatbubbleentity.model = "";
 865         }
 866 }
 867
 868
 869 void() TeamBubbleThink =
 870 {
 871         self.nextthink = time;
 872         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
 873         {
 874                 self.owner.teambubbleentity = world;
 875                 remove(self);
 876                 return;
 877         }
 878 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
 879         if (self.owner.buttonchat || self.owner.deadflag)
 880                 self.model = "";
 881         else
 882                 self.model = self.mdl;
 883
 884 };
 885
 886 float() ChatBubble_customizeentityforclient = {return (self.owner.team == other.team && other.killcount > -666);};
 887
 888 void() UpdateTeamBubble =
 889 {
 890         if (!self.modelindex || !cvar("teamplay"))
 891                 return;
 892         // spawn a teambubble entity if needed
 893         if (!self.teambubbleentity && cvar("teamplay"))
 894         {
 895                 self.teambubbleentity = spawn();
 896                 self.teambubbleentity.owner = self;
 897                 self.teambubbleentity.exteriormodeltoclient = self;
 898                 self.teambubbleentity.think = TeamBubbleThink;
 899                 self.teambubbleentity.nextthink = time;
 900                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr");
 901 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 902                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
 903                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
 904                 self.teambubbleentity.mdl = self.teambubbleentity.model;
 905                 self.teambubbleentity.model = self.teambubbleentity.mdl;
 906                 self.teambubbleentity.customizeentityforclient = ChatBubble_customizeentityforclient;
 907         }
 908 }
 909
 910 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
 911 // added to the model skins
 912 /*void() UpdateColorModHack =
 913 {
 914         local float c;
 915         c = self.clientcolors & 15;
 916         // LordHavoc: only bothering to support white, green, red, yellow, blue
 917              if (teamplay == 0) self.colormod = '0 0 0';
 918         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
 919         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
 920         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
 921         else if (c == 12) self.colormod = '1.22 1.22 0.10';
 922         else if (c == 13) self.colormod = '0.10 0.10 1.73';
 923         else self.colormod = '1 1 1';
 924 };*/
 925
 926 /*
 927 =============
 928 PlayerJump
 929
 930 When you press the jump key
 931 =============
 932 */
 933 void PlayerJump (void)
 934 {
 935         float mjumpheight;
 936
 937         mjumpheight = cvar("g_balance_jumpheight");
 938         if (self.waterlevel >= 2)
 939         {
 940                 if (self.watertype == CONTENT_WATER)
 941                         self.velocity_z = 200;
 942                 else if (self.watertype == CONTENT_SLIME)
 943                         self.velocity_z = 80;
 944                 else
 945                         self.velocity_z = 50;
 946
 947                 return;
 948         }
 949
 950
 951         if (!(self.flags & FL_ONGROUND))
 952                 return;
 953
 954         if (!(self.flags & FL_JUMPRELEASED))
 955                 return;
 956
 957         if(cvar("g_runematch"))
 958         {
 959                 if(self.runes & RUNE_SPEED)
 960                 {
 961                         if(self.runes & CURSE_SLOW)
 962                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_combo_jumpheight");
 963                         else
 964                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
 965                 }
 966                 else if(self.runes & CURSE_SLOW)
 967                 {
 968                         mjumpheight = mjumpheight * cvar("g_balance_curse_slow_jumpheight");
 969                 }
 970         }
 971
 972         if(cvar("g_minstagib") && (self.items & IT_INVINCIBLE))
 973         {
 974                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
 975         }
 976
 977         self.velocity_z = self.velocity_z + mjumpheight;
 978         self.oldvelocity_z = self.velocity_z;
 979
 980         self.flags = self.flags - FL_ONGROUND;
 981         self.flags = self.flags - FL_JUMPRELEASED;
 982 }
 983
 984 void() CheckWaterJump =
 985 {
 986         local vector start, end;
 987
 988 // check for a jump-out-of-water
 989         makevectors (self.angles);
 990         start = self.origin;
 991         start_z = start_z + 8;
 992         v_forward_z = 0;
 993         normalize(v_forward);
 994         end = start + v_forward*24;
 995         traceline (start, end, TRUE, self);
 996         if (trace_fraction < 1)
 997         {       // solid at waist
 998                 start_z = start_z + self.maxs_z - 8;
 999                 end = start + v_forward*24;
1000                 self.movedir = trace_plane_normal * -50;
1001                 traceline (start, end, TRUE, self);
1002                 if (trace_fraction == 1)
1003                 {       // open at eye level
1004                         self.flags = self.flags | FL_WATERJUMP;
1005                         self.velocity_z = 225;
1006                         self.flags = self.flags - (self.flags & FL_JUMPRELEASED);
1007                         self.teleport_time = time + 2;  // safety net
1008                         return;
1009                 }
1010         }
1011 };
1012
1013
1014 void respawn(void)
1015 {
1016         CopyBody(1);
1017         PutClientInServer();
1018 }
1019
1020 void player_powerups (void)
1021 {
1022         if (cvar("g_minstagib"))
1023         {
1024                 self.effects = EF_FULLBRIGHT;
1025                 if (self.items & IT_STRENGTH)
1026                 {
1027                         if (time > self.strength_finished)
1028                         {
1029                                 self.alpha = default_player_alpha;
1030                                 self.exteriorweaponentity.alpha = default_player_alpha;
1031                                 self.items = self.items - (self.items & IT_STRENGTH);
1032                                 sprint(self, "^3Invisibility has worn off\n");
1033                         }
1034                 }
1035                 else
1036                 {
1037                         if (time < self.strength_finished)
1038                         {
1039                                 self.alpha = cvar("g_minstagib_invis_alpha");
1040                                 self.exteriorweaponentity.alpha = cvar("g_minstagib_invis_alpha");
1041                                 self.items = self.items | IT_STRENGTH;
1042                                 sprint(self, "^3You are invisible\n");
1043                         }
1044                 }
1045
1046                 if (self.items & IT_INVINCIBLE)
1047                 {
1048                         if (time > self.invincible_finished)
1049                         {
1050                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1051                                 sprint(self, "^3Speed has worn off\n");
1052                         }
1053                 }
1054                 else
1055                 {
1056                         if (time < self.invincible_finished)
1057                         {
1058                                 self.items = self.items | IT_INVINCIBLE;
1059                                 sprint(self, "^3You are on speed\n");
1060                         }
1061                 }
1062                 return;
1063         }
1064
1065         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
1066         if (self.items & IT_STRENGTH)
1067         {
1068                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1069                 if (time > self.strength_finished)
1070                 {
1071                         self.items = self.items - (self.items & IT_STRENGTH);
1072                         sprint(self, "^3Strength has worn off\n");
1073                 }
1074         }
1075         else
1076         {
1077                 if (time < self.strength_finished)
1078                 {
1079                         self.items = self.items | IT_STRENGTH;
1080                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1081                 }
1082         }
1083         if (self.items & IT_INVINCIBLE)
1084         {
1085                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1086                 if (time > self.invincible_finished)
1087                 {
1088                         self.items = self.items - (self.items & IT_INVINCIBLE);
1089                         sprint(self, "^3Shield has worn off\n");
1090                 }
1091         }
1092         else
1093         {
1094                 if (time < self.invincible_finished)
1095                 {
1096                         self.items = self.items | IT_INVINCIBLE;
1097                         sprint(self, "^3Shield surrounds you\n");
1098                 }
1099         }
1100
1101         if (cvar("g_fullbrightplayers"))
1102                 self.effects = self.effects | EF_FULLBRIGHT;
1103
1104         // midair gamemode: damage only while in the air
1105         // if in midair mode, being on ground grants temporary invulnerability
1106         // (this is so that multishot weapon don't clear the ground flag on the
1107         // first damage in the frame, leaving the player vulnerable to the
1108         // remaining hits in the same frame)
1109         if (self.flags & FL_ONGROUND)
1110         if (cvar("g_midair"))
1111                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1112
1113         if (time < self.spawnshieldtime)
1114                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1115 }
1116
1117 void player_regen (void)
1118 {
1119         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1120         maxh = cvar("g_balance_health_stable");
1121         maxa = cvar("g_balance_armor_stable");
1122         limith = cvar("g_balance_health_limit");
1123         limita = cvar("g_balance_armor_limit");
1124
1125         if (cvar("g_minstagib") || (cvar("g_lms") && !cvar("g_lms_regenerate")))
1126                 return;
1127
1128         if(cvar("g_runematch"))
1129         {
1130                 max_mod = regen_mod = rot_mod = limit_mod = 1;
1131                 if (self.runes & RUNE_REGEN)
1132                 {
1133                         if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1134                         {
1135                                 regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1136                                 max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1137                                 limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1138                         }
1139                         else
1140                         {
1141                                 regen_mod = cvar("g_balance_rune_regen_regenrate");
1142                                 max_mod = cvar("g_balance_rune_regen_hpmod");
1143                                 limit_mod = cvar("g_balance_rune_regen_limitmod");
1144                         }
1145                 }
1146                 else if (self.runes & CURSE_VENOM)
1147                 {
1148                         max_mod = cvar("g_balance_curse_venom_hpmod");
1149                         if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1150                                 rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1151                         else
1152                                 rot_mod = cvar("g_balance_curse_venom_rotrate");
1153                         limit_mod = cvar("g_balance_curse_venom_limitmod");
1154                         //if (!self.runes & RUNE_REGEN)
1155                         //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1156                 }
1157                 maxh = maxh * max_mod;
1158                 //maxa = maxa * max_mod;
1159
1160                 if (time > self.pauserotarmor_finished)
1161                 {
1162                         if (self.armorvalue > maxa)
1163                                 self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime, 1000);
1164                 }
1165                 if (time > self.pauserothealth_finished)
1166                 {
1167                         if (self.health > maxh)
1168                                 self.health = bound(0, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime, 1000);
1169                 }
1170                 if (time > self.pauseregen_finished)
1171                 {
1172                         if (self.health < maxh)
1173                                 self.health = bound(0, self.health + (maxh- self.health) * regen_mod*cvar("g_balance_health_regen") * frametime  + 0.001, 1000);
1174                         if (self.armorvalue < maxa)
1175                                 self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_regen") * frametime  + 0.001, 1000);
1176                 }
1177         }
1178         else
1179         {
1180                 if (time > self.pauserothealth_finished)
1181                 if (self.health > maxh)
1182                         self.health = bound(0, self.health + (maxh - self.health) * cvar("g_balance_health_rot") * frametime, 1000);
1183                 if (time > self.pauserotarmor_finished)
1184                 if (self.armorvalue > maxa)
1185                         self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime, 1000);
1186                 if (time > self.pauseregen_finished)
1187                 {
1188                         if (self.health < maxh)
1189                                  self.health = bound(0, self.health + (maxh - self.health) * cvar("g_balance_health_regen") * frametime + 0.001, 1000);
1190                         if (self.armorvalue < maxa)
1191                                 self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_regen") * frametime + 0.001, 1000);
1192                 }
1193         }
1194
1195         if (self.health > limith)
1196                 self.health = limith;
1197         if(self.health < 1)
1198                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1199         if (self.armorvalue > limita)
1200                 self.armorvalue = limita;
1201 }
1202
1203 /*
1204 ======================
1205 spectate mode routines
1206 ======================
1207 */
1208 void SpectateCopy(entity spectatee) {
1209         self.armortype = spectatee.armortype;
1210         self.armorvalue = spectatee.armorvalue;
1211         self.currentammo = spectatee.currentammo;
1212         self.effects = spectatee.effects;
1213         self.health = spectatee.health;
1214         self.impulse = 0;
1215         self.items = spectatee.items;
1216         self.punchangle = spectatee.punchangle;
1217         self.view_ofs = spectatee.view_ofs;
1218         self.v_angle = spectatee.v_angle;
1219         self.viewzoom = spectatee.viewzoom;
1220         setorigin(self, spectatee.origin);
1221         setsize(self, spectatee.mins, spectatee.maxs);
1222 }
1223
1224 void SpectateUpdate() {
1225         if(!self.enemy)
1226                         PutObserverInServer();
1227
1228         if (self != self.enemy) {
1229                 if(self.enemy.flags & FL_NOTARGET)
1230                         PutObserverInServer();
1231                 SpectateCopy(self.enemy);
1232                 self.dmg_take = self.enemy.dmg_take;
1233                 self.dmg_save = self.enemy.dmg_save;
1234                 self.dmg_inflictor = self.enemy.dmg_inflictor;
1235                 self.fixangle = TRUE;
1236                 self.angles = self.enemy.v_angle;
1237                 //msg_entity = self;
1238                 //WriteByte(MSG_ONE, SVC_SETANGLE);
1239                 //WriteAngle(MSG_ONE, self.enemy.v_angle_x);
1240                 //WriteAngle(MSG_ONE, self.enemy.v_angle_y);
1241                 //WriteAngle(MSG_ONE, self.enemy.v_angle_z);
1242         }
1243 }
1244
1245 float SpectateNext() {
1246         other = find(self.enemy, classname, "player");
1247         if (!other) {
1248                 other = find(other, classname, "player");
1249         }
1250         if (other) {
1251                 self.enemy = other;
1252         }
1253         if(self.enemy.classname == "player") {
1254                 msg_entity = self;
1255                 WriteByte(MSG_ONE, SVC_SETVIEW);
1256                 WriteEntity(MSG_ONE, self.enemy);
1257                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1258                 SpectateUpdate();
1259                 return 1;
1260         } else {
1261                 return 0;
1262         }
1263 }
1264
1265 /*
1266 =============
1267 PlayerPreThink
1268
1269 Called every frame for each client before the physics are run
1270 =============
1271 */
1272 void PlayerPreThink (void)
1273 {
1274         if(self.classname == "player") {
1275                 local vector m1, m2;
1276
1277 //              if(self.netname == "Wazat")
1278 //                      bprint(strcat(self.classname, "\n"));
1279
1280                 CheckRules_Player();
1281
1282                 Nixnex_GiveCurrentWeapon();
1283
1284                 if(self.button7)
1285                         PrintWelcomeMessage(self);
1286
1287                 if(cvar("g_lms") || !cvar("sv_spectate"))
1288                 if((time - self.jointime) <= cvar("welcome_message_time"))
1289                         PrintWelcomeMessage(self);
1290
1291                 if (intermission_running)
1292                 {
1293                         IntermissionThink ();   // otherwise a button could be missed between
1294                         return;                                 // the think tics
1295                 }
1296
1297                 if (self.deadflag != DEAD_NO)
1298                 {
1299                         player_anim();
1300                         if (self.deadflag == DEAD_DYING)
1301                         {
1302                                 if (time > self.dead_time)
1303                                         self.deadflag = DEAD_DEAD;
1304                         }
1305                         else if (self.deadflag == DEAD_DEAD)
1306                         {
1307                                 if (cvar("g_lms") || cvar("g_arena") || cvar("g_forced_respawn"))
1308                                         self.deadflag = DEAD_RESPAWNABLE;
1309                                 else if (!self.button0 && !self.button2 && !self.button3)
1310                                         self.deadflag = DEAD_RESPAWNABLE;
1311                         }
1312                         else if (self.deadflag == DEAD_RESPAWNABLE)
1313                         {
1314                                 if (self.button0  ||
1315                                     self.button2  ||
1316                                     self.button3  ||
1317                                     self.button4  ||
1318                                     self.button5  ||
1319                                     self.button6  ||
1320                                     self.button7  ||
1321                                     self.button8  ||
1322                                     self.buttonuse ||
1323                                     cvar("g_lms") ||
1324                                     cvar("g_forced_respawn"))
1325                                         respawn();
1326                         }
1327                         return;
1328                 }
1329
1330                 if(cvar("g_lms") && !self.deadflag && cvar("g_lms_campcheck_interval"))
1331                 {
1332                         vector dist;
1333
1334                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
1335                         dist = self.oldorigin - self.origin;
1336                         dist_z = 0;
1337                         self.lms_traveled_distance += fabs(vlen(dist));
1338
1339                         if(cvar("g_campaign"))
1340                         if(!campaign_bots_may_start)
1341                         {
1342                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
1343                                 self.lms_traveled_distance = 0;
1344                         }
1345
1346                         if(time > self.lms_nextcheck)
1347                         {
1348                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
1349                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
1350                                 {
1351                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
1352                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
1353                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
1354                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
1355                                 }
1356                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
1357                                 self.lms_traveled_distance = 0;
1358                         }
1359                 }
1360
1361                 if (self.button5 && !self.hook.state)
1362                 {
1363                         if (!self.crouch)
1364                         {
1365                                 self.crouch = TRUE;
1366                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
1367                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
1368                         }
1369                 }
1370                 else
1371                 {
1372                         if (self.crouch)
1373                         {
1374                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
1375                                 if (!trace_startsolid)
1376                                 {
1377                                         self.crouch = FALSE;
1378                                         self.view_ofs = PL_VIEW_OFS;
1379                                         setsize (self, PL_MIN, PL_MAX);
1380                                 }
1381                         }
1382                 }
1383
1384                 if(cvar("sv_defaultcharacter") == 1 && !teams_matter) {
1385                         local string defaultmodel;
1386                         defaultmodel = CheckPlayerModel(cvar_string("sv_defaultplayermodel"));
1387
1388                         if (defaultmodel != self.model)
1389                         {
1390                                 m1 = self.mins;
1391                                 m2 = self.maxs;
1392                                 setmodel_lod (self, defaultmodel);
1393                                 setsize (self, m1, m2);
1394                         }
1395
1396                         if (self.skin != cvar("sv_defaultplayerskin"))
1397                                 self.skin = cvar("sv_defaultplayerskin");
1398                 } else {
1399                         if (self.playermodel != self.model)
1400                         {
1401                                 self.playermodel = CheckPlayerModel(self.playermodel);
1402                                 m1 = self.mins;
1403                                 m2 = self.maxs;
1404                                 setmodel_lod (self, self.playermodel);
1405                                 setsize (self, m1, m2);
1406                         }
1407
1408                         if (self.skin != stof(self.playerskin))
1409                                 self.skin = stof(self.playerskin);
1410                 }
1411                 // Savage: Check for nameless players
1412                 if (strlen(self.netname) < 1) {
1413                         self.netname = "Player";
1414                         stuffcmd(self, "name Player\n");
1415                 }
1416
1417                 GrapplingHookFrame();
1418
1419                 W_WeaponFrame();
1420
1421                 if (self.button4 || (self.weapon == WEP_NEX && self.button3))
1422                 {
1423                         if (cvar("g_minstagib") && self.button3)
1424                         {
1425                                 if (self.jump_interval <= (time + 0.1))
1426                                 {
1427                                         self.jump_interval = time + 1;
1428                                         W_Laser_Attack();
1429                                 }
1430                         }
1431                         else if (self.viewzoom > 0.4)
1432                                 self.viewzoom = max (0.4, self.viewzoom - frametime * 2);
1433                 }
1434                 else if (self.viewzoom < 1.0)
1435                         self.viewzoom = min (1.0, self.viewzoom + frametime);
1436
1437
1438                 if (self.button2)
1439                         PlayerJump ();
1440                 else
1441                         self.flags = self.flags | FL_JUMPRELEASED;
1442
1443                 player_powerups();
1444                 player_regen();
1445                 player_anim();
1446
1447                 if (cvar("g_minstagib"))
1448                         minstagib_ammocheck();
1449
1450                 //self.angles_y=self.v_angle_y + 90;   // temp
1451
1452                 if (self.waterlevel == 2)
1453                         CheckWaterJump ();
1454
1455                 //if (TetrisPreFrame()) return;
1456         } else if(gameover) {
1457                 if (intermission_running)
1458                         IntermissionThink ();   // otherwise a button could be missed between
1459                 return;
1460         } else if(self.classname == "observer") {
1461
1462                 if (self.flags & FL_JUMPRELEASED) {
1463                         if (self.button2 && self.version == cvar("gameversion")) {
1464                                 if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1465                                         self.flags = self.flags & !FL_JUMPRELEASED;
1466                                         self.classname = "player";
1467                                         if(cvar("g_campaign") || cvar("g_balance_teams"))
1468                                                 JoinBestTeam(self, 0);
1469                                         if(cvar("g_campaign"))
1470                                                 campaign_bots_may_start = 1;
1471                                         PutClientInServer();
1472                                         if(self.flags & !FL_NOTARGET)
1473                                                 bprint (strcat("^4", self.netname, "^4 is playing now\n"));
1474                                         centerprint(self,"");
1475                                         return;
1476                                 } else {
1477                                         self.flags = self.flags & !FL_JUMPRELEASED;
1478                                         stuffcmd(self,"menu_showteamselect\n");
1479                                         return;
1480                                 }
1481                         } else if(self.button0 && self.version == cvar("gameversion")) {
1482                                 self.flags = self.flags & !FL_JUMPRELEASED;
1483                                 if(SpectateNext() == 1) {
1484                                         self.classname = "spectator";
1485                                 }
1486                         }
1487                 } else {
1488                         if (!(self.button0 || self.button2)) {
1489                                 self.flags = self.flags | FL_JUMPRELEASED;
1490                         }
1491                 }
1492                 PrintWelcomeMessage(self);
1493         } else if(self.classname == "spectator") {
1494                 if (self.flags & FL_JUMPRELEASED) {
1495                         if (self.button2 && self.version == cvar("gameversion")) {
1496                                 if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1497                                         self.flags = self.flags & !FL_JUMPRELEASED;
1498                                         self.classname = "player";
1499                                         if(!cvar("g_lms"))
1500                                                 bprint (strcat("^4", self.netname, "^4 is playing now\n"));
1501
1502                                         if(cvar("g_campaign") || cvar("g_balance_teams"))
1503                                                 JoinBestTeam(self, 0);
1504                                         if(cvar("g_campaign"))
1505                                                 campaign_bots_may_start = 1;
1506                                         PutClientInServer();
1507                                         centerprint(self,"");
1508                                         return;
1509                                 } else {
1510                                         self.flags = self.flags & !FL_JUMPRELEASED;
1511                                         stuffcmd(self,"menu_showteamselect\n");
1512                                         return;
1513                                 }
1514                         } else if(self.button0) {
1515                                 self.flags = self.flags & !FL_JUMPRELEASED;
1516                                 if(SpectateNext() == 1) {
1517                                         self.classname = "spectator";
1518                                 } else {
1519                                         self.classname = "observer";
1520                                         PutClientInServer();
1521                                 }
1522                         } else if (self.button3) {
1523                                 self.flags = self.flags & !FL_JUMPRELEASED;
1524                                 self.classname = "observer";
1525                                 PutClientInServer();
1526                         } else {
1527                                 SpectateUpdate();
1528                         }
1529                 } else {
1530                         if (!(self.button0 || self.button3)) {
1531                                 self.flags = self.flags | FL_JUMPRELEASED;
1532                         }
1533                 }
1534                 PrintWelcomeMessage(self);
1535                 self.flags = self.flags | FL_CLIENT | FL_NOTARGET;
1536         }
1537 }
1538
1539
1540 /*
1541 =============
1542 PlayerPostThink
1543
1544 Called every frame for each client after the physics are run
1545 =============
1546 */
1547 void PlayerPostThink (void)
1548 {
1549         if(self.classname == "player") {
1550                 CheckRules_Player();
1551                 UpdateChatBubble();
1552                 UpdateTeamBubble();
1553                 if (self.deadflag == DEAD_NO)
1554                 if (self.impulse)
1555                         ImpulseCommands ();
1556                 if (intermission_running)
1557                         return;         // intermission or finale
1558
1559                 //PrintWelcomeMessage(self);
1560                 //if (TetrisPostFrame()) return;
1561         } else if (self.classname == "observer") {
1562                 //do nothing
1563         } else if (self.classname == "spectator") {
1564                 //do nothing
1565         }
1566         Arena_Warmup();
1567 }