data/qcsrc/server/cl_client.qc

   1 void info_player_start (void)
   2 {
   3         self.classname = "info_player_deathmatch";
   4         relocate_spawnpoint();
   5 }
   6
   7 void info_player_deathmatch (void)
   8 {
   9         relocate_spawnpoint();
  10 }
  11
  12 float spawn_allbad;
  13 float spawn_allgood;
  14 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
  15 {
  16         local entity spot, player, nextspot, previousspot, newfirstspot;
  17         local float pcount;
  18         spot = firstspot;
  19         newfirstspot = world;
  20         previousspot = world;
  21         spawn_allgood = TRUE;
  22         spawn_allbad = TRUE;
  23         while (spot)
  24         {
  25                 nextspot = spot.chain;
  26                 // count team mismatches as bad spots
  27                 if (spot.team == teamcheck)
  28                 {
  29                         pcount = 0;
  30                         player = playerlist;
  31                         while (player)
  32                         {
  33                                 if (player != self)
  34                                 if (vlen(player.origin - spot.origin) < mindist)
  35                                         pcount = pcount + 1;
  36                                 player = player.chain;
  37                         }
  38                         if (!pcount)
  39                         {
  40                                 spawn_allbad = FALSE;
  41                                 if (newfirstspot)
  42                                         previousspot.chain = spot;
  43                                 else
  44                                         newfirstspot = spot;
  45                                 previousspot = spot;
  46                                 spot.chain = world;
  47                         }
  48                         else
  49                                 spawn_allgood = FALSE;
  50                 }
  51                 spot = nextspot;
  52         }
  53         // if we couldn't find ANY good points, return the original list
  54         if (!newfirstspot)
  55                 newfirstspot = firstspot;
  56         return newfirstspot;
  57 }
  58
  59 entity Spawn_RandomPoint(entity firstspot)
  60 {
  61         local entity spot;
  62         local float numspots;
  63         // count number of spots
  64         numspots = 0;
  65         spot = firstspot;
  66         while (spot)
  67         {
  68                 numspots = numspots + 1;
  69                 spot = spot.chain;
  70         }
  71         // pick a random one
  72         numspots = numspots * random();
  73         spot = firstspot;
  74         while (spot.chain && numspots >= 1)
  75         {
  76                 numspots = numspots - 1;
  77                 spot = spot.chain;
  78         }
  79         return spot;
  80 }
  81
  82 entity Spawn_FurthestPoint(entity firstspot, entity playerlist)
  83 {
  84         local entity best, spot, player;
  85         local float bestrating, rating;
  86         best = world;
  87         bestrating = -1000000;
  88         spot = firstspot;
  89         while (spot)
  90         {
  91                 rating = 1000000000;
  92                 player = playerlist;
  93                 while (player)
  94                 {
  95                         if (player != self)
  96                                 rating = min(rating, vlen(player.origin - spot.origin));
  97                         player = player.chain;
  98                 }
  99                 rating = rating + random() * 16;
 100                 if (bestrating < rating)
 101                 {
 102                         best = spot;
 103                         bestrating = rating;
 104                 }
 105                 spot = spot.chain;
 106         }
 107         return best;
 108 }
 109
 110 /*
 111 =============
 112 SelectSpawnPoint
 113
 114 Finds a point to respawn
 115 =============
 116 */
 117 entity SelectSpawnPoint (float anypoint)
 118 {
 119         local float teamcheck;
 120         local entity spot, firstspot, playerlist;
 121
 122         spot = find (world, classname, "testplayerstart");
 123         if (spot)
 124                 return spot;
 125
 126         teamcheck = 0;
 127
 128         if(!anypoint && cvar("g_ctf") )
 129                 teamcheck = self.team;
 130
 131         // get the list of players
 132         playerlist = findchain(classname, "player");
 133         // get the entire list of spots
 134         firstspot = findchain(classname, "info_player_deathmatch");
 135         // filter out the bad ones
 136         // (note this returns the original list if none survived)
 137         firstspot = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 138
 139         // there is 50/50 chance of choosing a random spot or the furthest spot
 140         // (this means that roughly every other spawn will be furthest, so you
 141         // usually won't get fragged at spawn twice in a row)
 142         if (arena_roundbased)
 143         {
 144                 firstspot = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 145                 spot = Spawn_RandomPoint(firstspot);
 146         }
 147         else if (random() > 0.5 || spawn_allbad || spawn_allgood)
 148                 spot = Spawn_RandomPoint(firstspot);
 149         else
 150                 spot = Spawn_FurthestPoint(firstspot, playerlist);
 151
 152         if (!spot)
 153         {
 154                 if(cvar("spawn_debug"))
 155                         GotoNextMap();
 156                 else
 157                         error ("PutClientInServer: no start points on level");
 158         }
 159
 160         return spot;
 161 }
 162
 163 /*
 164 =============
 165 CheckPlayerModel
 166
 167 Checks if the argument string can be a valid playermodel.
 168 Returns a valid one in doubt.
 169 =============
 170 */
 171 string FallbackPlayerModel = "models/player/marine.zym";
 172 string CheckPlayerModel(string plyermodel) {
 173         if(strlen(plyermodel) < 4)
 174                 return FallbackPlayerModel;
 175         if( substring(plyermodel,0,14) != "models/player/")
 176                 return FallbackPlayerModel;
 177         else if(cvar("sv_servermodelsonly"))
 178         {
 179                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 180                         return FallbackPlayerModel;
 181                 if(!fexists(plyermodel))
 182                         return FallbackPlayerModel;
 183         }
 184         return plyermodel;
 185 }
 186
 187 /*
 188 =============
 189 Client_customizeentityforclient
 190
 191 LOD reduction
 192 =============
 193 */
 194 float Client_customizeentityforclient()
 195 {
 196 #ifdef ALLOW_VARIABLE_LOD
 197         // self: me
 198         // other: the player viewing me
 199         float distance;
 200         float f;
 201
 202         if(self.flags & FL_NOTARGET) // we don't need LOD for spectators
 203                 return TRUE;
 204
 205         if(other.cvar_cl_playerdetailreduction <= 0)
 206         {
 207                 if(other.cvar_cl_playerdetailreduction <= -2)
 208                         self.modelindex = self.modelindex_lod2;
 209                 else if(other.cvar_cl_playerdetailreduction <= -1)
 210                         self.modelindex = self.modelindex_lod1;
 211                 else
 212                         self.modelindex = self.modelindex_lod0;
 213         }
 214         else
 215         {
 216                 distance = vlen(self.origin - other.origin);
 217                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 218                 if(f > 10000)
 219                         self.modelindex = self.modelindex_lod2;
 220                 else if(f > 5000)
 221                         self.modelindex = self.modelindex_lod1;
 222                 else
 223                         self.modelindex = self.modelindex_lod0;
 224         }
 225 #endif
 226
 227         return TRUE;
 228 }
 229
 230 void setmodel_lod(entity e, string modelname)
 231 {
 232 #ifdef ALLOW_VARIABLE_LOD
 233         string s;
 234
 235         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1.zym");
 236         if(fexists(s))
 237         {
 238                 precache_model(s);
 239                 setmodel(e, s);
 240                 self.modelindex_lod1 = self.modelindex;
 241         }
 242         else
 243                 self.modelindex_lod1 = -1;
 244
 245         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2.zym");
 246         if(fexists(s))
 247         {
 248                 precache_model(s);
 249                 setmodel(e, s);
 250                 self.modelindex_lod2 = self.modelindex;
 251         }
 252         else
 253                 self.modelindex_lod2 = -1;
 254
 255         precache_model(modelname);
 256         setmodel(e, modelname);
 257         self.modelindex_lod0 = self.modelindex;
 258
 259         if(self.modelindex_lod1 < 0)
 260                 self.modelindex_lod1 = self.modelindex;
 261
 262         if(self.modelindex_lod2 < 0)
 263                 self.modelindex_lod2 = self.modelindex;
 264 #else
 265         precache_model(modelname);
 266         setmodel(e, modelname);
 267 #endif
 268 }
 269
 270 /*
 271 =============
 272 PutObserverInServer
 273
 274 putting a client as observer in the server
 275 =============
 276 */
 277 void PutObserverInServer (void)
 278 {
 279         entity  spot;
 280         spot = SelectSpawnPoint (FALSE);
 281         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 282
 283         if(clienttype(self) == CLIENTTYPE_REAL)
 284         {
 285                 msg_entity = self;
 286                 WriteByte(MSG_ONE, SVC_SETVIEW);
 287                 WriteEntity(MSG_ONE, self);
 288         }
 289
 290         DropAllRunes(self);
 291
 292         if(self.flagcarried)
 293                 DropFlag(self.flagcarried);
 294
 295         DistributeFragsAmongTeam(self, self.team, 1);
 296
 297         if(self.frags <= 0 && self.frags > -666 && cvar("g_lms") && self.killcount != -666)
 298                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 299         else if(self.killcount != -666)
 300                 bprint ("^4", self.netname, "^4 is spectating now\n");
 301
 302         self.classname = "observer";
 303         self.health = -666;
 304         self.takedamage = DAMAGE_NO;
 305         self.solid = SOLID_NOT;
 306         self.movetype = MOVETYPE_NOCLIP;
 307         self.flags = FL_CLIENT | FL_NOTARGET;
 308         self.armorvalue = 666;
 309         self.effects = 0;
 310         self.armorvalue = cvar("g_balance_armor_start");
 311         self.pauserotarmor_finished = 0;
 312         self.pauserothealth_finished = 0;
 313         self.pauseregen_finished = 0;
 314         self.damageforcescale = 0;
 315         self.death_time = 0;
 316         self.dead_time = 0;
 317         self.dead_frame = 0;
 318         self.die_frame = 0;
 319         self.deaths = 0;
 320         self.alpha = 0;
 321         self.scale = 0;
 322         self.fade_time = 0;
 323         self.pain_frame = 0;
 324         self.pain_finished = 0;
 325         self.strength_finished = 0;
 326         self.invincible_finished = 0;
 327         self.pushltime = 0;
 328         self.think = SUB_Null;
 329         self.nextthink = 0;
 330         self.hook_time = 0;
 331         self.runes = 0;
 332         self.deadflag = DEAD_NO;
 333         self.angles = spot.angles;
 334         self.angles_z = 0;
 335         self.fixangle = TRUE;
 336         self.crouch = FALSE;
 337
 338         self.view_ofs = PL_VIEW_OFS;
 339         setorigin (self, spot.origin);
 340         setsize (self, '0 0 0', '0 0 0');
 341         self.oldorigin = self.origin;
 342         self.items = 0;
 343         self.model = "";
 344         self.modelindex = 0;
 345         self.weapon = 0;
 346         self.weaponmodel = "";
 347         self.weaponentity = world;
 348         self.killcount = -666;
 349         self.velocity = '0 0 0';
 350         self.avelocity = '0 0 0';
 351         self.punchangle = '0 0 0';
 352         self.punchvector = '0 0 0';
 353         self.oldvelocity = self.velocity;
 354         self.customizeentityforclient = Client_customizeentityforclient;
 355
 356         if(cvar("g_arena"))
 357         {
 358                 if(self.frags != -2)
 359                 {
 360                         Spawnqueue_Insert(self);
 361                 }
 362                 else
 363                 {
 364                         Spawnqueue_Unmark(self);
 365                         Spawnqueue_Remove(self);
 366                 }
 367         }
 368         else if(!cvar("g_lms"))
 369                 self.frags = -666;
 370 }
 371
 372
 373 /*
 374 =============
 375 PutClientInServer
 376
 377 Called when a client spawns in the server
 378 =============
 379 */
 380 void PutClientInServer (void)
 381 {
 382         if(clienttype(self) == CLIENTTYPE_BOT)
 383         {
 384                 self.classname = "player";
 385         }
 386         else if(clienttype(self) == CLIENTTYPE_REAL)
 387         {
 388                 msg_entity = self;
 389                 WriteByte(MSG_ONE, SVC_SETVIEW);
 390                 WriteEntity(MSG_ONE, self);
 391         }
 392
 393         // player is dead and becomes observer
 394         if(cvar("g_lms") && self.frags < 1)
 395                 self.classname = "observer";
 396
 397         if(cvar("g_arena"))
 398         if(!self.spawned)
 399                 self.classname = "observer";
 400
 401         if(self.classname == "player") {
 402                 entity  spot;
 403
 404                 spot = SelectSpawnPoint (FALSE);
 405
 406                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 407
 408                 self.classname = "player";
 409                 self.iscreature = TRUE;
 410                 self.movetype = MOVETYPE_WALK;
 411                 self.solid = SOLID_SLIDEBOX;
 412                 self.flags = FL_CLIENT;
 413                 self.takedamage = DAMAGE_AIM;
 414                 self.effects = 0;
 415                 self.health = cvar("g_balance_health_start");
 416                 self.air_finished = time + 12;
 417                 self.dmg = 2;
 418                 self.armorvalue = cvar("g_balance_armor_start");
 419                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 420                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 421                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 422                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 423                 self.damageforcescale = 2;
 424                 self.death_time = 0;
 425                 self.dead_time = 0;
 426                 self.dead_frame = 0;
 427                 self.die_frame = 0;
 428                 self.alpha = 0;
 429                 self.scale = 0;
 430                 self.fade_time = 0;
 431                 self.pain_frame = 0;
 432                 self.pain_finished = 0;
 433                 self.strength_finished = 0;
 434                 self.invincible_finished = 0;
 435                 self.pushltime = 0;
 436                 //self.speed_finished = 0;
 437                 //self.slowmo_finished = 0;
 438                 // players have no think function
 439                 self.think = SUB_Null;
 440                 self.nextthink = 0;
 441                 self.weapon = 0;
 442                 self.switchweapon = 0;
 443                 self.hook_time = 0;
 444
 445                 self.runes = 0;
 446
 447                 self.deadflag = DEAD_NO;
 448
 449                 self.angles = spot.angles;
 450
 451                 self.angles_z = 0; // never spawn tilted even if the spot says to
 452                 self.fixangle = TRUE; // turn this way immediately
 453                 self.velocity = '0 0 0';
 454                 self.avelocity = '0 0 0';
 455                 self.punchangle = '0 0 0';
 456                 self.punchvector = '0 0 0';
 457                 self.oldvelocity = self.velocity;
 458
 459                 self.viewzoom = 0.6;
 460
 461                 self.customizeentityforclient = Client_customizeentityforclient;
 462
 463                 if(cvar("sv_defaultcharacter") == 1 && !teams_matter) {
 464                         local string defaultmodel;
 465                         defaultmodel = CheckPlayerModel(cvar_string("sv_defaultplayermodel"));
 466                         setmodel_lod (self, defaultmodel);
 467                         self.skin = stof(cvar_string("sv_defaultplayerskin"));
 468                 } else {
 469                         self.playermodel = CheckPlayerModel(self.playermodel);
 470                         setmodel_lod (self, self.playermodel);
 471                         if(teams_matter)
 472                                 self.skin = math_mod(stof(self.playerskin), NUM_PLAYERSKINS_TEAMPLAY);
 473                         else
 474                                 self.skin = stof(self.playerskin);
 475                 }
 476
 477                 self.crouch = FALSE;
 478                 self.view_ofs = PL_VIEW_OFS;
 479                 setsize (self, PL_MIN, PL_MAX);
 480                 self.spawnorigin = spot.origin;
 481                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 482                 // don't reset back to last position, even if new position is stuck in solid
 483                 self.oldorigin = self.origin;
 484
 485                 if(cvar("g_lms"))
 486                 {
 487                         self.ammo_shells = cvar("g_lms_start_ammo_shells");
 488                         self.ammo_nails = cvar("g_lms_start_ammo_nails");
 489                         self.ammo_rockets = cvar("g_lms_start_ammo_rockets");
 490                         self.ammo_cells = cvar("g_lms_start_ammo_cells");
 491                         self.health = cvar("g_lms_start_health");
 492                         self.armorvalue = cvar("g_lms_start_armor");
 493                 }
 494                 else if (cvar("g_use_ammunition")) {
 495                         self.ammo_shells = cvar("g_start_ammo_shells");
 496                         self.ammo_nails = cvar("g_start_ammo_nails");
 497                         self.ammo_rockets = cvar("g_start_ammo_rockets");
 498                         self.ammo_cells = cvar("g_start_ammo_cells");
 499                 } else {
 500                         self.ammo_shells = 999;
 501                         self.ammo_nails = 999;
 502                         self.ammo_rockets = 999;
 503                         self.ammo_cells = 999;
 504                 }
 505
 506                 self.items = 0;
 507                 if (cvar("g_start_weapon_laser") || cvar("g_lms"))
 508                 {
 509                         self.items = self.items | IT_LASER;
 510                         self.switchweapon = WEP_LASER;
 511                 }
 512                 if (cvar("g_start_weapon_shotgun") || cvar("g_lms"))
 513                 {
 514                         self.items = self.items | IT_SHOTGUN;
 515                         self.switchweapon = WEP_SHOTGUN;
 516                 }
 517                 if (cvar("g_start_weapon_uzi") || cvar("g_lms"))
 518                 {
 519                         self.items = self.items | IT_UZI;
 520                         self.switchweapon = WEP_UZI;
 521                 }
 522                 if (cvar("g_start_weapon_grenadelauncher") || cvar("g_lms"))
 523                 {
 524                         self.items = self.items | IT_GRENADE_LAUNCHER;
 525                         self.switchweapon = WEP_GRENADE_LAUNCHER;
 526                 }
 527                 if (cvar("g_start_weapon_electro") || cvar("g_lms"))
 528                 {
 529                         self.items = self.items | IT_ELECTRO;
 530                         self.switchweapon = WEP_ELECTRO;
 531                 }
 532                 if (cvar("g_start_weapon_crylink") || cvar("g_lms"))
 533                 {
 534                         self.items = self.items | IT_CRYLINK;
 535                         self.switchweapon = WEP_CRYLINK;
 536                 }
 537                 if (cvar("g_start_weapon_nex") || cvar("g_lms"))
 538                 {
 539                         self.items = self.items | IT_NEX;
 540                         self.switchweapon = WEP_NEX;
 541                 }
 542                 if (cvar("g_start_weapon_hagar") || cvar("g_lms"))
 543                 {
 544                         self.items = self.items | IT_HAGAR;
 545                         self.switchweapon = WEP_HAGAR;
 546                 }
 547                 if (cvar("g_start_weapon_rocketlauncher") || cvar("g_lms"))
 548                 {
 549                         self.items = self.items | IT_ROCKET_LAUNCHER;
 550                         self.switchweapon = WEP_ROCKET_LAUNCHER;
 551                 }
 552
 553                 if(cvar("g_instagib"))
 554                 {
 555                         self.items = IT_NEX;
 556                         self.switchweapon = WEP_NEX;
 557                         self.ammo_cells = 999;
 558                 }
 559
 560                 if(cvar("g_rocketarena"))
 561                 {
 562                         self.items = IT_ROCKET_LAUNCHER;
 563                         self.switchweapon = WEP_ROCKET_LAUNCHER;
 564                         self.ammo_rockets = 999;
 565                 }
 566
 567                 if(cvar("g_nixnex"))
 568                 {
 569                         self.items = 0;
 570                         // will be done later
 571                 }
 572
 573                 if(cvar("g_minstagib"))
 574                 {
 575                         self.health = 100;
 576                         self.armorvalue = 0;
 577                         self.items = IT_NEX;
 578                         self.switchweapon = WEP_NEX;
 579                         self.ammo_cells = cvar("g_minstagib_ammo_start");
 580                         self.jump_interval = time;
 581                 }
 582
 583                 if(cvar("g_arena"))
 584                 {
 585                         Spawnqueue_Remove(self);
 586                         Spawnqueue_Mark(self);
 587                 }
 588
 589                 self.event_damage = PlayerDamage;
 590
 591                 self.bot_attack = TRUE;
 592
 593                 self.statdraintime = time + 5;
 594                 self.button0 = self.button1 = self.button2 = self.button3 = 0;
 595
 596                 if(self.killcount == -666) {
 597                         self.killcount = 0;
 598                         if(!cvar("g_arena"))
 599                         if(!cvar("g_lms"))
 600                                 self.frags = 0;
 601                 }
 602
 603                 self.cnt = WEP_LASER;
 604                 self.nixnex_lastchange_id = -1;
 605
 606                 CL_SpawnWeaponentity();
 607                 self.alpha = default_player_alpha;
 608                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 609
 610                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 611                 self.lms_traveled_distance = 0;
 612
 613                 if(cvar("spawn_debug"))
 614                 {
 615                                 sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 616                                 remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 617                 }
 618
 619                 //stuffcmd(self, "chase_active 0");
 620                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 621         } else if(self.classname == "observer") {
 622                 PutObserverInServer ();
 623         }
 624 }
 625
 626 /*
 627 =============
 628 SetNewParms
 629 =============
 630 */
 631 void SetNewParms (void)
 632 {
 633
 634 }
 635
 636 /*
 637 =============
 638 SetChangeParms
 639 =============
 640 */
 641 void SetChangeParms (void)
 642 {
 643
 644 }
 645
 646 /*
 647 =============
 648 ClientKill
 649
 650 Called when a client types 'kill' in the console
 651 =============
 652 */
 653 void ClientKill (void)
 654 {
 655         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 656 }
 657
 658 void FixClientCvars(entity e)
 659 {
 660         // send prediction settings to the client
 661         stuffcmd(e, "\nin_bindmap 0 0\n");
 662         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
 663         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
 664         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
 665         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
 666         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
 667         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
 668         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
 669         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("g_balance_jumpheight")), "\n"));
 670         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
 671         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
 672         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
 673         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
 674         stuffcmd(e, "cl_movement_edgefriction 1\n");
 675 }
 676
 677 /*
 678 =============
 679 ClientConnect
 680
 681 Called when a client connects to the server
 682 =============
 683 */
 684 string ColoredTeamName(float t);
 685 //void dom_player_join_team(entity pl);
 686 void ClientConnect (void)
 687 {
 688         local string s;
 689
 690         self.classname = "player_joining";
 691         self.flags = self.flags | FL_CLIENT;
 692         self.version_nagtime = time + 10 + random() * 10;
 693
 694         if(player_count<0)
 695         {
 696                 dprint("BUG player count is lower than zero, this cannot happen!\n");
 697                 player_count = 0;
 698         }
 699
 700         bot_clientconnect();
 701
 702         //if(cvar("g_domination"))
 703         //      dom_player_join_team(self);
 704
 705         //JoinBestTeam(self, FALSE);
 706
 707         if((cvar("sv_spectate") == 1 && !cvar("g_lms")) || cvar("g_campaign")) {
 708                 self.classname = "observer";
 709         } else {
 710                 self.classname = "player";
 711                 campaign_bots_may_start = 1;
 712         }
 713
 714         self.playerid = (playerid_last = playerid_last + 1);
 715         if(cvar("sv_eventlog"))
 716         {
 717                 if(clienttype(self) == CLIENTTYPE_REAL)
 718                         s = "player";
 719                 else
 720                         s = "bot";
 721                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", s, ":", self.netname), TRUE);
 722                 s = strcat(":team:", ftos(self.playerid), ":");
 723                 s = strcat(s, ftos(self.team));
 724                 GameLogEcho(s, FALSE);
 725         }
 726
 727         //stuffcmd(self, "set tmpviewsize $viewsize \n");
 728
 729         bprint ("^4",self.netname);
 730         bprint ("^4 connected");
 731
 732         if(cvar("g_domination") || cvar("g_ctf"))
 733         {
 734                 bprint(" and joined the ");
 735                 bprint(ColoredTeamName(self.team));
 736         }
 737
 738         bprint("\n");
 739
 740         self.welcomemessage_time = 0;
 741
 742         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
 743         // TODO: is this being used for anything else than cd tracks?
 744         // Remember: SVC_CDTRACK exists. Maybe it should be used.
 745
 746         FixClientCvars(self);
 747
 748         // Wazat's grappling hook
 749         SetGrappleHookBindings();
 750
 751         // get autoswitch state from player
 752         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1; cmd autoswitch $1\"\n");
 753         stuffcmd(self, "cmd autoswitch $cl_autoswitch\n");
 754
 755         // get version info from player
 756         stuffcmd(self, "cmd clientversion $gameversion\n");
 757
 758         // get other cvars from player
 759         GetCvars(0);
 760
 761         // set cvar for team scoreboard
 762         if (teams_matter)
 763         {
 764                 local float t;
 765                 t = cvar("teamplay");
 766                 // we have to stuff the correct teamplay value because if this is a listen server, this changes the teamplay mode of the server itself, which is bad
 767                 stuffcmd(self, strcat("set teamplay ", ftos(t), "\n"));
 768         }
 769         else
 770                 stuffcmd(self, "set teamplay 0\n");
 771
 772         if(cvar("g_lms"))
 773         {
 774                 self.frags = cvar("fraglimit");
 775                 // no fraglimit was set, so player gets 999 lives
 776                 if(self.frags < 1)
 777                         self.frags = 999;
 778
 779                 self.frags = LMS_NewPlayerLives();
 780                 if(!self.frags)
 781                 {
 782                         self.frags = -666;
 783                 }
 784         }
 785         else if(cvar("g_arena"))
 786         {
 787                 self.classname = "observer";
 788                 Spawnqueue_Insert(self);
 789         }
 790
 791         bot_relinkplayerlist();
 792
 793         self.jointime = time;
 794 }
 795
 796 /*
 797 =============
 798 ClientDisconnect
 799
 800 Called when a client disconnects from the server
 801 =============
 802 */
 803 void(entity e) DropFlag;
 804 .entity chatbubbleentity;
 805 .entity teambubbleentity;
 806 void ClientDisconnect (void)
 807 {
 808         float save;
 809         if(cvar("sv_eventlog"))
 810                 GameLogEcho(strcat(":part:", ftos(self.playerid)), FALSE);
 811         bprint ("^4",self.netname);
 812         bprint ("^4 disconnected\n");
 813
 814         if (self.chatbubbleentity)
 815         {
 816                 remove (self.chatbubbleentity);
 817                 self.chatbubbleentity = world;
 818         }
 819
 820         if (self.teambubbleentity)
 821         {
 822                 remove (self.teambubbleentity);
 823                 self.teambubbleentity = world;
 824         }
 825
 826         DropAllRunes(self);
 827
 828         if(self.flagcarried)
 829                 DropFlag(self.flagcarried);
 830
 831         DistributeFragsAmongTeam(self, self.team, 1);
 832
 833         save = self.flags;
 834         self.flags = self.flags - (self.flags & FL_CLIENT);
 835         bot_relinkplayerlist();
 836         self.flags = save;
 837
 838         // remove laserdot
 839         if(self.weaponentity)
 840                 if(self.weaponentity.lasertarget)
 841                         remove(self.weaponentity.lasertarget);
 842
 843         if(cvar("g_arena"))
 844         {
 845                 Spawnqueue_Unmark(self);
 846                 Spawnqueue_Remove(self);
 847         }
 848
 849         // free cvars
 850         GetCvars(-1);
 851 }
 852
 853 .float buttonchat;
 854 void() ChatBubbleThink =
 855 {
 856         self.nextthink = time;
 857         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
 858         {
 859                 self.owner.chatbubbleentity = world;
 860                 remove(self);
 861                 return;
 862         }
 863         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
 864         if (self.owner.buttonchat && !self.owner.deadflag)
 865                 self.model = self.mdl;
 866         else
 867                 self.model = "";
 868 };
 869
 870 void() UpdateChatBubble =
 871 {
 872         if (!self.modelindex)
 873                 return;
 874         // spawn a chatbubble entity if needed
 875         if (!self.chatbubbleentity)
 876         {
 877                 self.chatbubbleentity = spawn();
 878                 self.chatbubbleentity.owner = self;
 879                 self.chatbubbleentity.exteriormodeltoclient = self;
 880                 self.chatbubbleentity.think = ChatBubbleThink;
 881                 self.chatbubbleentity.nextthink = time;
 882                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr");
 883                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 884                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
 885                 self.chatbubbleentity.model = "";
 886         }
 887 }
 888
 889
 890 void() TeamBubbleThink =
 891 {
 892         self.nextthink = time;
 893         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
 894         {
 895                 self.owner.teambubbleentity = world;
 896                 remove(self);
 897                 return;
 898         }
 899 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
 900         if (self.owner.buttonchat || self.owner.deadflag)
 901                 self.model = "";
 902         else
 903                 self.model = self.mdl;
 904
 905 };
 906
 907 float() TeamBubble_customizeentityforclient
 908 {
 909         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
 910 }
 911
 912 void() UpdateTeamBubble =
 913 {
 914         if (!self.modelindex || !cvar("teamplay"))
 915                 return;
 916         // spawn a teambubble entity if needed
 917         if (!self.teambubbleentity && cvar("teamplay"))
 918         {
 919                 self.teambubbleentity = spawn();
 920                 self.teambubbleentity.owner = self;
 921                 self.teambubbleentity.exteriormodeltoclient = self;
 922                 self.teambubbleentity.think = TeamBubbleThink;
 923                 self.teambubbleentity.nextthink = time;
 924                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr");
 925 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 926                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
 927                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
 928                 self.teambubbleentity.mdl = self.teambubbleentity.model;
 929                 self.teambubbleentity.model = self.teambubbleentity.mdl;
 930                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
 931         }
 932 }
 933
 934 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
 935 // added to the model skins
 936 /*void() UpdateColorModHack =
 937 {
 938         local float c;
 939         c = self.clientcolors & 15;
 940         // LordHavoc: only bothering to support white, green, red, yellow, blue
 941              if (teamplay == 0) self.colormod = '0 0 0';
 942         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
 943         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
 944         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
 945         else if (c == 12) self.colormod = '1.22 1.22 0.10';
 946         else if (c == 13) self.colormod = '0.10 0.10 1.73';
 947         else self.colormod = '1 1 1';
 948 };*/
 949
 950 void respawn(void)
 951 {
 952         CopyBody(1);
 953         PutClientInServer();
 954 }
 955
 956 void player_powerups (void)
 957 {
 958         if (cvar("g_minstagib"))
 959         {
 960                 self.effects = EF_FULLBRIGHT;
 961                 if (self.items & IT_STRENGTH)
 962                 {
 963                         if (time > self.strength_finished)
 964                         {
 965                                 self.alpha = default_player_alpha;
 966                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 967                                 self.items = self.items - (self.items & IT_STRENGTH);
 968                                 sprint(self, "^3Invisibility has worn off\n");
 969                         }
 970                 }
 971                 else
 972                 {
 973                         if (time < self.strength_finished)
 974                         {
 975                                 self.alpha = cvar("g_minstagib_invis_alpha");
 976                                 self.exteriorweaponentity.alpha = cvar("g_minstagib_invis_alpha");
 977                                 self.items = self.items | IT_STRENGTH;
 978                                 sprint(self, "^3You are invisible\n");
 979                         }
 980                 }
 981
 982                 if (self.items & IT_INVINCIBLE)
 983                 {
 984                         if (time > self.invincible_finished)
 985                         {
 986                                 self.items = self.items - (self.items & IT_INVINCIBLE);
 987                                 sprint(self, "^3Speed has worn off\n");
 988                         }
 989                 }
 990                 else
 991                 {
 992                         if (time < self.invincible_finished)
 993                         {
 994                                 self.items = self.items | IT_INVINCIBLE;
 995                                 sprint(self, "^3You are on speed\n");
 996                         }
 997                 }
 998                 return;
 999         }
1000
1001         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
1002         if (self.items & IT_STRENGTH)
1003         {
1004                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1005                 if (time > self.strength_finished)
1006                 {
1007                         self.items = self.items - (self.items & IT_STRENGTH);
1008                         sprint(self, "^3Strength has worn off\n");
1009                 }
1010         }
1011         else
1012         {
1013                 if (time < self.strength_finished)
1014                 {
1015                         self.items = self.items | IT_STRENGTH;
1016                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1017                 }
1018         }
1019         if (self.items & IT_INVINCIBLE)
1020         {
1021                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1022                 if (time > self.invincible_finished)
1023                 {
1024                         self.items = self.items - (self.items & IT_INVINCIBLE);
1025                         sprint(self, "^3Shield has worn off\n");
1026                 }
1027         }
1028         else
1029         {
1030                 if (time < self.invincible_finished)
1031                 {
1032                         self.items = self.items | IT_INVINCIBLE;
1033                         sprint(self, "^3Shield surrounds you\n");
1034                 }
1035         }
1036
1037         if (cvar("g_fullbrightplayers"))
1038                 self.effects = self.effects | EF_FULLBRIGHT;
1039
1040         // midair gamemode: damage only while in the air
1041         // if in midair mode, being on ground grants temporary invulnerability
1042         // (this is so that multishot weapon don't clear the ground flag on the
1043         // first damage in the frame, leaving the player vulnerable to the
1044         // remaining hits in the same frame)
1045         if (self.flags & FL_ONGROUND)
1046         if (cvar("g_midair"))
1047                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1048
1049         if (time < self.spawnshieldtime)
1050                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1051 }
1052
1053 float CalcRegen(float current, float stable, float maxv, float regenfactor)
1054 {
1055         if(current > stable)
1056                 return current;
1057         else if(current > stable - 0.25) // when close enough, "snap"
1058                 return stable;
1059         else
1060                 return bound(0, current + (stable - current) * regenfactor * frametime, maxv);
1061 }
1062
1063 void player_regen (void)
1064 {
1065         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1066         maxh = cvar("g_balance_health_stable");
1067         maxa = cvar("g_balance_armor_stable");
1068         limith = cvar("g_balance_health_limit");
1069         limita = cvar("g_balance_armor_limit");
1070
1071         if (cvar("g_minstagib") || (cvar("g_lms") && !cvar("g_lms_regenerate")))
1072                 return;
1073
1074         if(cvar("g_runematch"))
1075         {
1076                 max_mod = regen_mod = rot_mod = limit_mod = 1;
1077                 if (self.runes & RUNE_REGEN)
1078                 {
1079                         if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1080                         {
1081                                 regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1082                                 max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1083                                 limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1084                         }
1085                         else
1086                         {
1087                                 regen_mod = cvar("g_balance_rune_regen_regenrate");
1088                                 max_mod = cvar("g_balance_rune_regen_hpmod");
1089                                 limit_mod = cvar("g_balance_rune_regen_limitmod");
1090                         }
1091                 }
1092                 else if (self.runes & CURSE_VENOM)
1093                 {
1094                         max_mod = cvar("g_balance_curse_venom_hpmod");
1095                         if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1096                                 rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1097                         else
1098                                 rot_mod = cvar("g_balance_curse_venom_rotrate");
1099                         limit_mod = cvar("g_balance_curse_venom_limitmod");
1100                         //if (!self.runes & RUNE_REGEN)
1101                         //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1102                 }
1103                 maxh = maxh * max_mod;
1104                 //maxa = maxa * max_mod;
1105
1106                 if (time > self.pauserotarmor_finished)
1107                 {
1108                         if (self.armorvalue > maxa)
1109                                 self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime, 1000);
1110                 }
1111                 if (time > self.pauserothealth_finished)
1112                 {
1113                         if (self.health > maxh)
1114                                 self.health = bound(0, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime, 1000);
1115                 }
1116                 if (time > self.pauseregen_finished)
1117                 {
1118                         self.health = CalcRegen(self.health, maxh, 1000, regen_mod * cvar("g_balance_health_regen"));
1119                         self.armorvalue = CalcRegen(self.armorvalue, maxa, 1000, cvar("g_balance_armor_regen"));
1120                 }
1121         }
1122         else
1123         {
1124                 if (time > self.pauserothealth_finished)
1125                 if (self.health > maxh)
1126                         self.health = bound(0, self.health + (maxh - self.health) * cvar("g_balance_health_rot") * frametime, 1000);
1127                 if (time > self.pauserotarmor_finished)
1128                 if (self.armorvalue > maxa)
1129                         self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime, 1000);
1130                 if (time > self.pauseregen_finished)
1131                 {
1132                         self.health = CalcRegen(self.health, maxh, 1000, cvar("g_balance_health_regen"));
1133                         self.armorvalue = CalcRegen(self.armorvalue, maxa, 1000, cvar("g_balance_armor_regen"));
1134                 }
1135         }
1136
1137         if (self.health > limith)
1138                 self.health = limith;
1139         if(self.health < 1)
1140                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1141         if (self.armorvalue > limita)
1142                 self.armorvalue = limita;
1143 }
1144
1145 /*
1146 ======================
1147 spectate mode routines
1148 ======================
1149 */
1150 void SpectateCopy(entity spectatee) {
1151         self.armortype = spectatee.armortype;
1152         self.armorvalue = spectatee.armorvalue;
1153         self.currentammo = spectatee.currentammo;
1154         self.effects = spectatee.effects;
1155         self.health = spectatee.health;
1156         self.impulse = 0;
1157         self.items = spectatee.items;
1158         self.punchangle = spectatee.punchangle;
1159         self.view_ofs = spectatee.view_ofs;
1160         self.v_angle = spectatee.v_angle;
1161         self.viewzoom = spectatee.viewzoom;
1162         setorigin(self, spectatee.origin);
1163         setsize(self, spectatee.mins, spectatee.maxs);
1164 }
1165
1166 void SpectateUpdate() {
1167         if(!self.enemy)
1168                         PutObserverInServer();
1169
1170         if (self != self.enemy) {
1171                 if(self.enemy.flags & FL_NOTARGET)
1172                         PutObserverInServer();
1173                 SpectateCopy(self.enemy);
1174                 self.dmg_take = self.enemy.dmg_take;
1175                 self.dmg_save = self.enemy.dmg_save;
1176                 self.dmg_inflictor = self.enemy.dmg_inflictor;
1177                 self.fixangle = TRUE;
1178                 self.angles = self.enemy.v_angle;
1179                 //msg_entity = self;
1180                 //WriteByte(MSG_ONE, SVC_SETANGLE);
1181                 //WriteAngle(MSG_ONE, self.enemy.v_angle_x);
1182                 //WriteAngle(MSG_ONE, self.enemy.v_angle_y);
1183                 //WriteAngle(MSG_ONE, self.enemy.v_angle_z);
1184         }
1185 }
1186
1187 float SpectateNext() {
1188         other = find(self.enemy, classname, "player");
1189         if (!other) {
1190                 other = find(other, classname, "player");
1191         }
1192         if (other) {
1193                 self.enemy = other;
1194         }
1195         if(self.enemy.classname == "player") {
1196                 msg_entity = self;
1197                 WriteByte(MSG_ONE, SVC_SETVIEW);
1198                 WriteEntity(MSG_ONE, self.enemy);
1199                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1200                 SpectateUpdate();
1201                 return 1;
1202         } else {
1203                 return 0;
1204         }
1205 }
1206
1207 /*
1208 =============
1209 ShowRespawnCountdown()
1210
1211 Update a respawn countdown display.
1212 =============
1213 */
1214 void ShowRespawnCountdown()
1215 {
1216         float number;
1217         if(self.deadflag == DEAD_NO) // just respawned?
1218                 return;
1219         else
1220         {
1221                 number = ceil(self.death_time - time);
1222                 if(number <= 0)
1223                         return;
1224                 if(number <= self.respawn_countdown)
1225                 {
1226                         self.respawn_countdown = number - 1;
1227                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1228                                 stuffcmd(self, strcat("play2 announcer/robotic/", ftos(number), ".ogg\n"));
1229                 }
1230         }
1231 }
1232
1233 void LeaveSpectatorMode()
1234 {
1235         if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1236                 self.classname = "player";
1237                 if(cvar("g_campaign") || cvar("g_balance_teams"))
1238                         JoinBestTeam(self, 0);
1239                 if(cvar("g_campaign"))
1240                         campaign_bots_may_start = 1;
1241                 PutClientInServer();
1242                 if(!(self.flags & FL_NOTARGET))
1243                         bprint ("^4", self.netname, "^4 is playing now\n");
1244                 centerprint(self,"");
1245                 return;
1246         } else {
1247                 stuffcmd(self,"menu_showteamselect\n");
1248                 return;
1249         }
1250 }
1251
1252 /*
1253 =============
1254 PlayerPreThink
1255
1256 Called every frame for each client before the physics are run
1257 =============
1258 */
1259 void() ctf_setstatus;
1260 .float vote_nagtime;
1261 void PlayerPreThink (void)
1262 {
1263         if(strlen(self.netname) > 0)
1264                 if(substring(self.netname, strlen(self.netname) - 1, 1) == "^")
1265                         self.netname = strzone(strcat(substring(self.netname, 0, strlen(self.netname) - 1), " ")); // BROKEN COLORS can be annoying!
1266
1267         // version nagging
1268         if(self.version_nagtime)
1269                 if(self.cvar_g_nexuizversion)
1270                         if(time > self.version_nagtime)
1271                         {
1272                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
1273                                         if(self.cvar_g_nexuizversion != cvar_string("g_nexuizversion"))
1274                                         {
1275                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "\n");
1276                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "\n"));
1277                                         }
1278                                 self.version_nagtime = 0;
1279                         }
1280
1281         // vote nagging
1282         if(self.cvar_scr_centertime)
1283                 if(time > self.vote_nagtime)
1284                 {
1285                         VoteNag();
1286                         self.vote_nagtime = time + self.cvar_scr_centertime * 0.6;
1287                 }
1288
1289         if(self.classname == "player") {
1290                 local vector m1, m2;
1291
1292 //              if(self.netname == "Wazat")
1293 //                      bprint(self.classname, "\n");
1294
1295                 CheckRules_Player();
1296
1297                 if(self.button7)
1298                         PrintWelcomeMessage(self);
1299
1300                 if(cvar("g_lms") || !cvar("sv_spectate"))
1301                 if((time - self.jointime) <= cvar("welcome_message_time"))
1302                         PrintWelcomeMessage(self);
1303
1304                 if (intermission_running)
1305                 {
1306                         IntermissionThink ();   // otherwise a button could be missed between
1307                         return;                                 // the think tics
1308                 }
1309
1310                 Nixnex_GiveCurrentWeapon();
1311                 UpdateSelectedPlayer();
1312
1313                 if (self.deadflag != DEAD_NO)
1314                 {
1315                         float button_pressed, force_respawn;
1316                         player_anim();
1317                         button_pressed = (self.button0 || self.button2 || self.button3 || self.button6 || self.buttonuse);
1318                         force_respawn = (cvar("g_lms") || cvar("g_forced_respawn"));
1319                         if (self.deadflag == DEAD_DYING)
1320                         {
1321                                 if(force_respawn)
1322                                         self.deadflag = DEAD_RESPAWNING;
1323                                 else if(!button_pressed)
1324                                         self.deadflag = DEAD_DEAD;
1325                         }
1326                         else if (self.deadflag == DEAD_DEAD)
1327                         {
1328                                 if(button_pressed)
1329                                         self.deadflag = DEAD_RESPAWNABLE;
1330                         }
1331                         else if (self.deadflag == DEAD_RESPAWNABLE)
1332                         {
1333                                 if(!button_pressed)
1334                                         self.deadflag = DEAD_RESPAWNING;
1335                         }
1336                         else if (self.deadflag == DEAD_RESPAWNING)
1337                         {
1338                                 if(time > self.death_time)
1339                                         respawn();
1340                         }
1341                         ShowRespawnCountdown();
1342                         return;
1343                 }
1344
1345                 if(cvar("g_lms") && !self.deadflag && cvar("g_lms_campcheck_interval"))
1346                 {
1347                         vector dist;
1348
1349                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
1350                         dist = self.oldorigin - self.origin;
1351                         dist_z = 0;
1352                         self.lms_traveled_distance += fabs(vlen(dist));
1353
1354                         if(cvar("g_campaign"))
1355                         if(!campaign_bots_may_start)
1356                         {
1357                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
1358                                 self.lms_traveled_distance = 0;
1359                         }
1360
1361                         if(time > self.lms_nextcheck)
1362                         {
1363                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
1364                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
1365                                 {
1366                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
1367                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
1368                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
1369                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
1370                                 }
1371                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
1372                                 self.lms_traveled_distance = 0;
1373                         }
1374                 }
1375
1376                 if (self.button5 && !self.hook.state)
1377                 {
1378                         if (!self.crouch)
1379                         {
1380                                 self.crouch = TRUE;
1381                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
1382                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
1383                         }
1384                 }
1385                 else
1386                 {
1387                         if (self.crouch)
1388                         {
1389                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
1390                                 if (!trace_startsolid)
1391                                 {
1392                                         self.crouch = FALSE;
1393                                         self.view_ofs = PL_VIEW_OFS;
1394                                         setsize (self, PL_MIN, PL_MAX);
1395                                 }
1396                         }
1397                 }
1398
1399                 if(cvar("sv_defaultcharacter") == 1 && !teams_matter) {
1400                         local string defaultmodel;
1401                         defaultmodel = CheckPlayerModel(cvar_string("sv_defaultplayermodel"));
1402
1403                         if (defaultmodel != self.model)
1404                         {
1405                                 m1 = self.mins;
1406                                 m2 = self.maxs;
1407                                 setmodel_lod (self, defaultmodel);
1408                                 setsize (self, m1, m2);
1409                         }
1410
1411                         if (self.skin != cvar("sv_defaultplayerskin"))
1412                                 self.skin = cvar("sv_defaultplayerskin");
1413                 } else {
1414                         if (self.playermodel != self.model)
1415                         {
1416                                 self.playermodel = CheckPlayerModel(self.playermodel);
1417                                 m1 = self.mins;
1418                                 m2 = self.maxs;
1419                                 setmodel_lod (self, self.playermodel);
1420                                 setsize (self, m1, m2);
1421                         }
1422
1423                         if(teams_matter)
1424                         {
1425                                 if (self.skin != math_mod(stof(self.playerskin), NUM_PLAYERSKINS_TEAMPLAY))
1426                                         self.skin = math_mod(stof(self.playerskin), NUM_PLAYERSKINS_TEAMPLAY);
1427                         }
1428                         else
1429                         {
1430                                 if (self.skin != stof(self.playerskin))
1431                                         self.skin = stof(self.playerskin);
1432                         }
1433                 }
1434
1435                 GrapplingHookFrame();
1436
1437                 W_WeaponFrame();
1438
1439                 if (self.button4 || (self.weapon == WEP_NEX && self.button3))
1440                 {
1441                         if (cvar("g_minstagib") && self.button3)
1442                         {
1443                                 if (self.jump_interval <= (time + 0.1))
1444                                 {
1445                                         self.jump_interval = time + 1;
1446                                         W_Laser_Attack();
1447                                 }
1448                         }
1449                         else if (self.viewzoom > 0.4)
1450                                 self.viewzoom = max (0.4, self.viewzoom - frametime * 2);
1451                 }
1452                 else if (self.viewzoom < 1.0)
1453                         self.viewzoom = min (1.0, self.viewzoom + frametime);
1454
1455                 player_powerups();
1456                 player_regen();
1457                 player_anim();
1458
1459                 if (cvar("g_minstagib"))
1460                         minstagib_ammocheck();
1461
1462                 ctf_setstatus();
1463
1464                 //self.angles_y=self.v_angle_y + 90;   // temp
1465
1466                 //if (TetrisPreFrame()) return;
1467         } else if(gameover) {
1468                 if (intermission_running)
1469                         IntermissionThink ();   // otherwise a button could be missed between
1470                 return;
1471         } else if(self.classname == "observer") {
1472
1473                 if (self.flags & FL_JUMPRELEASED) {
1474                         if (self.button2 && self.version == cvar("gameversion")) {
1475                                 self.welcomemessage_time = 0;
1476                                 self.flags = self.flags - FL_JUMPRELEASED;
1477                                 LeaveSpectatorMode();
1478                                 return;
1479                         } else if(self.button0 && self.version == cvar("gameversion")) {
1480                                 self.welcomemessage_time = 0;
1481                                 self.flags = self.flags - FL_JUMPRELEASED;
1482                                 if(SpectateNext() == 1) {
1483                                         self.classname = "spectator";
1484                                 }
1485                         }
1486                 } else {
1487                         if (!(self.button0 || self.button2)) {
1488                                 self.flags = self.flags | FL_JUMPRELEASED;
1489                         }
1490                 }
1491                 PrintWelcomeMessage(self);
1492         } else if(self.classname == "spectator") {
1493                 if (self.flags & FL_JUMPRELEASED) {
1494                         if (self.button2 && self.version == cvar("gameversion")) {
1495                                 self.welcomemessage_time = 0;
1496                                 self.flags = self.flags - FL_JUMPRELEASED;
1497                                 LeaveSpectatorMode();
1498                                 return;
1499                         } else if(self.button0) {
1500                                 self.welcomemessage_time = 0;
1501                                 self.flags = self.flags - FL_JUMPRELEASED;
1502                                 if(SpectateNext() == 1) {
1503                                         self.classname = "spectator";
1504                                 } else {
1505                                         self.classname = "observer";
1506                                         PutClientInServer();
1507                                 }
1508                         } else if (self.button3) {
1509                                 self.welcomemessage_time = 0;
1510                                 self.flags = self.flags - FL_JUMPRELEASED;
1511                                 self.classname = "observer";
1512                                 PutClientInServer();
1513                         } else {
1514                                 SpectateUpdate();
1515                         }
1516                 } else {
1517                         if (!(self.button0 || self.button3)) {
1518                                 self.flags = self.flags | FL_JUMPRELEASED;
1519                         }
1520                 }
1521                 PrintWelcomeMessage(self);
1522                 self.flags = self.flags | FL_CLIENT | FL_NOTARGET;
1523         }
1524 }
1525
1526
1527 /*
1528 =============
1529 PlayerPostThink
1530
1531 Called every frame for each client after the physics are run
1532 =============
1533 */
1534 void PlayerPostThink (void)
1535 {
1536         // Savage: Check for nameless players
1537         if (strlen(self.netname) < 1) {
1538                 self.netname = "Player";
1539                 stuffcmd(self, "seta _cl_name Player\n");
1540         }
1541
1542         if(self.classname == "player") {
1543                 CheckRules_Player();
1544                 UpdateChatBubble();
1545                 UpdateTeamBubble();
1546                 if (self.deadflag == DEAD_NO)
1547                 if (self.impulse)
1548                         ImpulseCommands ();
1549                 if (intermission_running)
1550                         return;         // intermission or finale
1551
1552                 //PrintWelcomeMessage(self);
1553                 //if (TetrisPostFrame()) return;
1554         } else if (self.classname == "observer") {
1555                 //do nothing
1556         } else if (self.classname == "spectator") {
1557                 //do nothing
1558         }
1559         Arena_Warmup();
1560 }