data/qcsrc/server/cl_client.qc

   1 void info_player_start (void)
   2 {
   3         self.classname = "info_player_deathmatch";
   4         relocate_spawnpoint();
   5 }
   6
   7 void info_player_deathmatch (void)
   8 {
   9         relocate_spawnpoint();
  10 }
  11
  12 float spawn_allbad;
  13 float spawn_allgood;
  14 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
  15 {
  16         local entity spot, player, nextspot, previousspot, newfirstspot;
  17         local float pcount;
  18         spot = firstspot;
  19         newfirstspot = world;
  20         previousspot = world;
  21         spawn_allgood = TRUE;
  22         spawn_allbad = TRUE;
  23         while (spot)
  24         {
  25                 nextspot = spot.chain;
  26                 // count team mismatches as bad spots
  27                 if (spot.team == teamcheck)
  28                 {
  29                         pcount = 0;
  30                         player = playerlist;
  31                         while (player)
  32                         {
  33                                 if (player != self)
  34                                 if (vlen(player.origin - spot.origin) < mindist)
  35                                         pcount = pcount + 1;
  36                                 player = player.chain;
  37                         }
  38                         if (!pcount)
  39                         {
  40                                 spawn_allbad = FALSE;
  41                                 if (newfirstspot)
  42                                         previousspot.chain = spot;
  43                                 else
  44                                         newfirstspot = spot;
  45                                 previousspot = spot;
  46                                 spot.chain = world;
  47                         }
  48                         else
  49                                 spawn_allgood = FALSE;
  50                 }
  51                 spot = nextspot;
  52         }
  53         // if we couldn't find ANY good points, return the original list
  54         if (!newfirstspot)
  55                 newfirstspot = firstspot;
  56         return newfirstspot;
  57 }
  58
  59 entity Spawn_RandomPoint(entity firstspot)
  60 {
  61         local entity spot;
  62         local float numspots;
  63         // count number of spots
  64         numspots = 0;
  65         spot = firstspot;
  66         while (spot)
  67         {
  68                 numspots = numspots + 1;
  69                 spot = spot.chain;
  70         }
  71         // pick a random one
  72         numspots = numspots * random();
  73         spot = firstspot;
  74         while (spot.chain && numspots >= 1)
  75         {
  76                 numspots = numspots - 1;
  77                 spot = spot.chain;
  78         }
  79         return spot;
  80 }
  81
  82 entity Spawn_FurthestPoint(entity firstspot, entity playerlist)
  83 {
  84         local entity best, spot, player;
  85         local float bestrating, rating;
  86         best = world;
  87         bestrating = -1000000;
  88         spot = firstspot;
  89         while (spot)
  90         {
  91                 rating = 1000000000;
  92                 player = playerlist;
  93                 while (player)
  94                 {
  95                         if (player != self)
  96                                 rating = min(rating, vlen(player.origin - spot.origin));
  97                         player = player.chain;
  98                 }
  99                 rating = rating + random() * 16;
 100                 if (bestrating < rating)
 101                 {
 102                         best = spot;
 103                         bestrating = rating;
 104                 }
 105                 spot = spot.chain;
 106         }
 107         return best;
 108 }
 109
 110 /*
 111 =============
 112 SelectSpawnPoint
 113
 114 Finds a point to respawn
 115 =============
 116 */
 117 entity SelectSpawnPoint (float anypoint)
 118 {
 119         local float teamcheck;
 120         local entity spot, firstspot, playerlist;
 121
 122         spot = find (world, classname, "testplayerstart");
 123         if (spot)
 124                 return spot;
 125
 126         teamcheck = 0;
 127
 128         if(!anypoint && cvar("g_ctf") )
 129                 teamcheck = self.team;
 130
 131         // get the list of players
 132         playerlist = findchain(classname, "player");
 133         // get the entire list of spots
 134         firstspot = findchain(classname, "info_player_deathmatch");
 135         // filter out the bad ones
 136         // (note this returns the original list if none survived)
 137         firstspot = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 138
 139         // there is 50/50 chance of choosing a random spot or the furthest spot
 140         // (this means that roughly every other spawn will be furthest, so you
 141         // usually won't get fragged at spawn twice in a row)
 142         if (arena_roundbased)
 143         {
 144                 firstspot = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 145                 spot = Spawn_RandomPoint(firstspot);
 146         }
 147         else if (random() > 0.5 || spawn_allbad || spawn_allgood)
 148                 spot = Spawn_RandomPoint(firstspot);
 149         else
 150                 spot = Spawn_FurthestPoint(firstspot, playerlist);
 151
 152         if (!spot)
 153         {
 154                 if(cvar("spawn_debug"))
 155                         GotoNextMap();
 156                 else
 157                         error ("PutClientInServer: no start points on level");
 158         }
 159
 160         return spot;
 161 }
 162
 163 /*
 164 =============
 165 CheckPlayerModel
 166
 167 Checks if the argument string can be a valid playermodel.
 168 Returns a valid one in doubt.
 169 =============
 170 */
 171 string FallbackPlayerModel = "models/player/marine.zym";
 172 string CheckPlayerModel(string plyermodel) {
 173         if(strlen(plyermodel) < 4)
 174                 return FallbackPlayerModel;
 175         if( substring(plyermodel,0,14) != "models/player/")
 176                 return FallbackPlayerModel;
 177         else if(cvar("sv_servermodelsonly"))
 178         {
 179                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 180                         return FallbackPlayerModel;
 181                 if(!fexists(plyermodel))
 182                         return FallbackPlayerModel;
 183         }
 184         return plyermodel;
 185 }
 186
 187 /*
 188 =============
 189 Client_customizeentityforclient
 190
 191 LOD reduction
 192 =============
 193 */
 194 float Client_customizeentityforclient()
 195 {
 196 #ifdef ALLOW_VARIABLE_LOD
 197         // self: me
 198         // other: the player viewing me
 199         float distance;
 200         float f;
 201
 202         if(self.flags & FL_NOTARGET) // we don't need LOD for spectators
 203                 return TRUE;
 204
 205         if(other.cvar_cl_playerdetailreduction <= 0)
 206         {
 207                 if(other.cvar_cl_playerdetailreduction <= -2)
 208                         self.modelindex = self.modelindex_lod2;
 209                 else if(other.cvar_cl_playerdetailreduction <= -1)
 210                         self.modelindex = self.modelindex_lod1;
 211                 else
 212                         self.modelindex = self.modelindex_lod0;
 213         }
 214         else
 215         {
 216                 distance = vlen(self.origin - other.origin);
 217                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 218                 if(f > 10000)
 219                         self.modelindex = self.modelindex_lod2;
 220                 else if(f > 5000)
 221                         self.modelindex = self.modelindex_lod1;
 222                 else
 223                         self.modelindex = self.modelindex_lod0;
 224         }
 225 #endif
 226
 227         return TRUE;
 228 }
 229
 230 void setmodel_lod(entity e, string modelname)
 231 {
 232 #ifdef ALLOW_VARIABLE_LOD
 233         string s;
 234
 235         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1.zym");
 236         if(fexists(s))
 237         {
 238                 precache_model(s);
 239                 setmodel(e, s);
 240                 self.modelindex_lod1 = self.modelindex;
 241         }
 242         else
 243                 self.modelindex_lod1 = -1;
 244
 245         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2.zym");
 246         if(fexists(s))
 247         {
 248                 precache_model(s);
 249                 setmodel(e, s);
 250                 self.modelindex_lod2 = self.modelindex;
 251         }
 252         else
 253                 self.modelindex_lod2 = -1;
 254
 255         precache_model(modelname);
 256         setmodel(e, modelname);
 257         self.modelindex_lod0 = self.modelindex;
 258
 259         if(self.modelindex_lod1 < 0)
 260                 self.modelindex_lod1 = self.modelindex;
 261
 262         if(self.modelindex_lod2 < 0)
 263                 self.modelindex_lod2 = self.modelindex;
 264 #else
 265         precache_model(modelname);
 266         setmodel(e, modelname);
 267 #endif
 268 }
 269
 270 /*
 271 =============
 272 PutObserverInServer
 273
 274 putting a client as observer in the server
 275 =============
 276 */
 277 void PutObserverInServer (void)
 278 {
 279         entity  spot;
 280         spot = SelectSpawnPoint (FALSE);
 281         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 282
 283         if(clienttype(self) == CLIENTTYPE_REAL)
 284         {
 285                 msg_entity = self;
 286                 WriteByte(MSG_ONE, SVC_SETVIEW);
 287                 WriteEntity(MSG_ONE, self);
 288         }
 289
 290         WaypointSprite_PlayerDead();
 291
 292         DropAllRunes(self);
 293
 294         if(self.flagcarried)
 295                 DropFlag(self.flagcarried);
 296
 297         DistributeFragsAmongTeam(self, self.team, 1);
 298
 299         if(self.frags <= 0 && self.frags > -666 && cvar("g_lms") && self.killcount != -666)
 300                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 301         else if(self.killcount != -666)
 302                 bprint ("^4", self.netname, "^4 is spectating now\n");
 303
 304         self.classname = "observer";
 305         self.health = -666;
 306         self.takedamage = DAMAGE_NO;
 307         self.solid = SOLID_NOT;
 308         self.movetype = MOVETYPE_NOCLIP;
 309         self.flags = FL_CLIENT | FL_NOTARGET;
 310         self.armorvalue = 666;
 311         self.effects = 0;
 312         self.armorvalue = cvar("g_balance_armor_start");
 313         self.pauserotarmor_finished = 0;
 314         self.pauserothealth_finished = 0;
 315         self.pauseregen_finished = 0;
 316         self.damageforcescale = 0;
 317         self.death_time = 0;
 318         self.dead_time = 0;
 319         self.dead_frame = 0;
 320         self.die_frame = 0;
 321         self.deaths = 0;
 322         self.alpha = 0;
 323         self.scale = 0;
 324         self.fade_time = 0;
 325         self.pain_frame = 0;
 326         self.pain_finished = 0;
 327         self.strength_finished = 0;
 328         self.invincible_finished = 0;
 329         self.pushltime = 0;
 330         self.think = SUB_Null;
 331         self.nextthink = 0;
 332         self.hook_time = 0;
 333         self.runes = 0;
 334         self.deadflag = DEAD_NO;
 335         self.angles = spot.angles;
 336         self.angles_z = 0;
 337         self.fixangle = TRUE;
 338         self.crouch = FALSE;
 339
 340         self.view_ofs = PL_VIEW_OFS;
 341         setorigin (self, spot.origin);
 342         setsize (self, '0 0 0', '0 0 0');
 343         self.oldorigin = self.origin;
 344         self.items = 0;
 345         self.model = "";
 346         self.modelindex = 0;
 347         self.weapon = 0;
 348         self.weaponmodel = "";
 349         self.weaponentity = world;
 350         self.killcount = -666;
 351         self.velocity = '0 0 0';
 352         self.avelocity = '0 0 0';
 353         self.punchangle = '0 0 0';
 354         self.punchvector = '0 0 0';
 355         self.oldvelocity = self.velocity;
 356         self.customizeentityforclient = Client_customizeentityforclient;
 357
 358         if(cvar("g_arena"))
 359         {
 360                 if(self.frags != -2)
 361                 {
 362                         Spawnqueue_Insert(self);
 363                 }
 364                 else
 365                 {
 366                         Spawnqueue_Unmark(self);
 367                         Spawnqueue_Remove(self);
 368                 }
 369         }
 370         else if(!cvar("g_lms"))
 371                 self.frags = -666;
 372 }
 373
 374
 375 /*
 376 =============
 377 PutClientInServer
 378
 379 Called when a client spawns in the server
 380 =============
 381 */
 382 void PutClientInServer (void)
 383 {
 384         if(clienttype(self) == CLIENTTYPE_BOT)
 385         {
 386                 self.classname = "player";
 387         }
 388         else if(clienttype(self) == CLIENTTYPE_REAL)
 389         {
 390                 msg_entity = self;
 391                 WriteByte(MSG_ONE, SVC_SETVIEW);
 392                 WriteEntity(MSG_ONE, self);
 393         }
 394
 395         // player is dead and becomes observer
 396         if(cvar("g_lms") && self.frags < 1)
 397                 self.classname = "observer";
 398
 399         if(cvar("g_arena"))
 400         if(!self.spawned)
 401                 self.classname = "observer";
 402
 403         if(self.classname == "player") {
 404                 entity  spot;
 405
 406                 spot = SelectSpawnPoint (FALSE);
 407
 408                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 409
 410                 self.classname = "player";
 411                 self.iscreature = TRUE;
 412                 self.movetype = MOVETYPE_WALK;
 413                 self.solid = SOLID_SLIDEBOX;
 414                 self.flags = FL_CLIENT;
 415                 self.takedamage = DAMAGE_AIM;
 416                 self.effects = 0;
 417                 self.health = cvar("g_balance_health_start");
 418                 self.air_finished = time + 12;
 419                 self.dmg = 2;
 420                 self.armorvalue = cvar("g_balance_armor_start");
 421                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 422                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 423                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 424                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 425                 self.damageforcescale = 2;
 426                 self.death_time = 0;
 427                 self.dead_time = 0;
 428                 self.dead_frame = 0;
 429                 self.die_frame = 0;
 430                 self.alpha = 0;
 431                 self.scale = 0;
 432                 self.fade_time = 0;
 433                 self.pain_frame = 0;
 434                 self.pain_finished = 0;
 435                 self.strength_finished = 0;
 436                 self.invincible_finished = 0;
 437                 self.pushltime = 0;
 438                 //self.speed_finished = 0;
 439                 //self.slowmo_finished = 0;
 440                 // players have no think function
 441                 self.think = SUB_Null;
 442                 self.nextthink = 0;
 443                 self.weapon = 0;
 444                 self.switchweapon = 0;
 445                 self.hook_time = 0;
 446
 447                 self.runes = 0;
 448
 449                 self.deadflag = DEAD_NO;
 450
 451                 self.angles = spot.angles;
 452
 453                 self.angles_z = 0; // never spawn tilted even if the spot says to
 454                 self.fixangle = TRUE; // turn this way immediately
 455                 self.velocity = '0 0 0';
 456                 self.avelocity = '0 0 0';
 457                 self.punchangle = '0 0 0';
 458                 self.punchvector = '0 0 0';
 459                 self.oldvelocity = self.velocity;
 460
 461                 self.viewzoom = 0.6;
 462                 self.has_zoomed = 0;
 463
 464                 self.customizeentityforclient = Client_customizeentityforclient;
 465
 466                 if(cvar("sv_defaultcharacter") == 1 && !teams_matter) {
 467                         local string defaultmodel;
 468                         defaultmodel = CheckPlayerModel(cvar_string("sv_defaultplayermodel"));
 469                         setmodel_lod (self, defaultmodel);
 470                         self.skin = stof(cvar_string("sv_defaultplayerskin"));
 471                 } else {
 472                         self.playermodel = CheckPlayerModel(self.playermodel);
 473                         setmodel_lod (self, self.playermodel);
 474                         if(teams_matter)
 475                                 self.skin = math_mod(stof(self.playerskin), NUM_PLAYERSKINS_TEAMPLAY);
 476                         else
 477                                 self.skin = stof(self.playerskin);
 478                 }
 479
 480                 self.crouch = FALSE;
 481                 self.view_ofs = PL_VIEW_OFS;
 482                 setsize (self, PL_MIN, PL_MAX);
 483                 self.spawnorigin = spot.origin;
 484                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 485                 // don't reset back to last position, even if new position is stuck in solid
 486                 self.oldorigin = self.origin;
 487
 488                 if(cvar("g_lms"))
 489                 {
 490                         self.ammo_shells = cvar("g_lms_start_ammo_shells");
 491                         self.ammo_nails = cvar("g_lms_start_ammo_nails");
 492                         self.ammo_rockets = cvar("g_lms_start_ammo_rockets");
 493                         self.ammo_cells = cvar("g_lms_start_ammo_cells");
 494                         self.health = cvar("g_lms_start_health");
 495                         self.armorvalue = cvar("g_lms_start_armor");
 496                 }
 497                 else if (cvar("g_use_ammunition")) {
 498                         self.ammo_shells = cvar("g_start_ammo_shells");
 499                         self.ammo_nails = cvar("g_start_ammo_nails");
 500                         self.ammo_rockets = cvar("g_start_ammo_rockets");
 501                         self.ammo_cells = cvar("g_start_ammo_cells");
 502                 } else {
 503                         self.ammo_shells = 999;
 504                         self.ammo_nails = 999;
 505                         self.ammo_rockets = 999;
 506                         self.ammo_cells = 999;
 507                 }
 508
 509                 self.items = 0;
 510                 if (cvar("g_start_weapon_laser") || cvar("g_lms"))
 511                 {
 512                         self.items = self.items | IT_LASER;
 513                         self.switchweapon = WEP_LASER;
 514                 }
 515                 if (cvar("g_start_weapon_shotgun") || cvar("g_lms"))
 516                 {
 517                         self.items = self.items | IT_SHOTGUN;
 518                         self.switchweapon = WEP_SHOTGUN;
 519                 }
 520                 if (cvar("g_start_weapon_uzi") || cvar("g_lms"))
 521                 {
 522                         self.items = self.items | IT_UZI;
 523                         self.switchweapon = WEP_UZI;
 524                 }
 525                 if (cvar("g_start_weapon_grenadelauncher") || cvar("g_lms"))
 526                 {
 527                         self.items = self.items | IT_GRENADE_LAUNCHER;
 528                         self.switchweapon = WEP_GRENADE_LAUNCHER;
 529                 }
 530                 if (cvar("g_start_weapon_electro") || cvar("g_lms"))
 531                 {
 532                         self.items = self.items | IT_ELECTRO;
 533                         self.switchweapon = WEP_ELECTRO;
 534                 }
 535                 if (cvar("g_start_weapon_crylink") || cvar("g_lms"))
 536                 {
 537                         self.items = self.items | IT_CRYLINK;
 538                         self.switchweapon = WEP_CRYLINK;
 539                 }
 540                 if (cvar("g_start_weapon_nex") || cvar("g_lms"))
 541                 {
 542                         self.items = self.items | IT_NEX;
 543                         self.switchweapon = WEP_NEX;
 544                 }
 545                 if (cvar("g_start_weapon_hagar") || cvar("g_lms"))
 546                 {
 547                         self.items = self.items | IT_HAGAR;
 548                         self.switchweapon = WEP_HAGAR;
 549                 }
 550                 if (cvar("g_start_weapon_rocketlauncher") || cvar("g_lms"))
 551                 {
 552                         self.items = self.items | IT_ROCKET_LAUNCHER;
 553                         self.switchweapon = WEP_ROCKET_LAUNCHER;
 554                 }
 555
 556                 if(cvar("g_instagib"))
 557                 {
 558                         self.items = IT_NEX;
 559                         self.switchweapon = WEP_NEX;
 560                         self.ammo_cells = 999;
 561                 }
 562
 563                 if(cvar("g_rocketarena"))
 564                 {
 565                         self.items = IT_ROCKET_LAUNCHER;
 566                         self.switchweapon = WEP_ROCKET_LAUNCHER;
 567                         self.ammo_rockets = 999;
 568                 }
 569
 570                 if(cvar("g_nixnex"))
 571                 {
 572                         self.items = 0;
 573                         // will be done later
 574                 }
 575
 576                 if(cvar("g_minstagib"))
 577                 {
 578                         self.health = 100;
 579                         self.armorvalue = 0;
 580                         self.items = IT_NEX;
 581                         self.switchweapon = WEP_NEX;
 582                         self.ammo_cells = cvar("g_minstagib_ammo_start");
 583                         self.jump_interval = time;
 584                 }
 585
 586                 if(cvar("g_arena"))
 587                 {
 588                         Spawnqueue_Remove(self);
 589                         Spawnqueue_Mark(self);
 590                 }
 591
 592                 self.event_damage = PlayerDamage;
 593
 594                 self.bot_attack = TRUE;
 595
 596                 self.statdraintime = time + 5;
 597                 self.button0 = self.button1 = self.button2 = self.button3 = 0;
 598
 599                 if(self.killcount == -666) {
 600                         self.killcount = 0;
 601                         if(!cvar("g_arena"))
 602                         if(!cvar("g_lms"))
 603                                 self.frags = 0;
 604                 }
 605
 606                 self.cnt = WEP_LASER;
 607                 self.nixnex_lastchange_id = -1;
 608
 609                 CL_SpawnWeaponentity();
 610                 self.alpha = default_player_alpha;
 611                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 612
 613                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 614                 self.lms_traveled_distance = 0;
 615
 616                 if(cvar("spawn_debug"))
 617                 {
 618                                 sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 619                                 remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 620                 }
 621
 622                 //stuffcmd(self, "chase_active 0");
 623                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 624         } else if(self.classname == "observer") {
 625                 PutObserverInServer ();
 626         }
 627 }
 628
 629 /*
 630 =============
 631 SetNewParms
 632 =============
 633 */
 634 void SetNewParms (void)
 635 {
 636
 637 }
 638
 639 /*
 640 =============
 641 SetChangeParms
 642 =============
 643 */
 644 void SetChangeParms (void)
 645 {
 646
 647 }
 648
 649 /*
 650 =============
 651 ClientKill
 652
 653 Called when a client types 'kill' in the console
 654 =============
 655 */
 656 void ClientKill (void)
 657 {
 658         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 659 }
 660
 661 void FixClientCvars(entity e)
 662 {
 663         // send prediction settings to the client
 664         stuffcmd(e, "\nin_bindmap 0 0\n");
 665         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
 666         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
 667         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
 668         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
 669         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
 670         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
 671         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
 672         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("g_balance_jumpheight")), "\n"));
 673         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
 674         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
 675         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
 676         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
 677         stuffcmd(e, "cl_movement_edgefriction 1\n");
 678 }
 679
 680 /*
 681 =============
 682 ClientConnect
 683
 684 Called when a client connects to the server
 685 =============
 686 */
 687 string ColoredTeamName(float t);
 688 //void dom_player_join_team(entity pl);
 689 void ClientConnect (void)
 690 {
 691         local string s;
 692
 693         self.classname = "player_joining";
 694         self.flags = self.flags | FL_CLIENT;
 695         self.version_nagtime = time + 10 + random() * 10;
 696
 697         if(player_count<0)
 698         {
 699                 dprint("BUG player count is lower than zero, this cannot happen!\n");
 700                 player_count = 0;
 701         }
 702
 703         bot_clientconnect();
 704
 705         //if(cvar("g_domination"))
 706         //      dom_player_join_team(self);
 707
 708         //JoinBestTeam(self, FALSE);
 709
 710         if((cvar("sv_spectate") == 1 && !cvar("g_lms")) || cvar("g_campaign")) {
 711                 self.classname = "observer";
 712         } else {
 713                 self.classname = "player";
 714                 campaign_bots_may_start = 1;
 715         }
 716
 717         self.playerid = (playerid_last = playerid_last + 1);
 718         if(cvar("sv_eventlog"))
 719         {
 720                 if(clienttype(self) == CLIENTTYPE_REAL)
 721                         s = "player";
 722                 else
 723                         s = "bot";
 724                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", s, ":", self.netname), TRUE);
 725                 s = strcat(":team:", ftos(self.playerid), ":");
 726                 s = strcat(s, ftos(self.team));
 727                 GameLogEcho(s, FALSE);
 728         }
 729
 730         //stuffcmd(self, "set tmpviewsize $viewsize \n");
 731
 732         bprint ("^4",self.netname);
 733         bprint ("^4 connected");
 734
 735         if(cvar("g_domination") || cvar("g_ctf"))
 736         {
 737                 bprint(" and joined the ");
 738                 bprint(ColoredTeamName(self.team));
 739         }
 740
 741         bprint("\n");
 742
 743         self.welcomemessage_time = 0;
 744
 745         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
 746         // TODO: is this being used for anything else than cd tracks?
 747         // Remember: SVC_CDTRACK exists. Maybe it should be used.
 748
 749         FixClientCvars(self);
 750
 751         // waypoint sprites
 752         WaypointSprite_InitClient(self);
 753
 754         // Wazat's grappling hook
 755         SetGrappleHookBindings();
 756
 757         // get autoswitch state from player
 758         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1; cmd autoswitch $1\"\n");
 759         stuffcmd(self, "cmd autoswitch $cl_autoswitch\n");
 760
 761         // get version info from player
 762         stuffcmd(self, "cmd clientversion $gameversion\n");
 763
 764         // get other cvars from player
 765         GetCvars(0);
 766
 767         // set cvar for team scoreboard
 768         if (teams_matter)
 769         {
 770                 local float t;
 771                 t = cvar("teamplay");
 772                 // we have to stuff the correct teamplay value because if this is a listen server, this changes the teamplay mode of the server itself, which is bad
 773                 stuffcmd(self, strcat("set teamplay ", ftos(t), "\n"));
 774         }
 775         else
 776                 stuffcmd(self, "set teamplay 0\n");
 777
 778         if(cvar("g_lms"))
 779         {
 780                 self.frags = cvar("fraglimit");
 781                 // no fraglimit was set, so player gets 999 lives
 782                 if(self.frags < 1)
 783                         self.frags = 999;
 784
 785                 self.frags = LMS_NewPlayerLives();
 786                 if(!self.frags)
 787                 {
 788                         self.frags = -666;
 789                 }
 790         }
 791         else if(cvar("g_arena"))
 792         {
 793                 self.classname = "observer";
 794                 Spawnqueue_Insert(self);
 795         }
 796
 797         bot_relinkplayerlist();
 798
 799         self.jointime = time;
 800 }
 801
 802 /*
 803 =============
 804 ClientDisconnect
 805
 806 Called when a client disconnects from the server
 807 =============
 808 */
 809 void(entity e) DropFlag;
 810 .entity chatbubbleentity;
 811 .entity teambubbleentity;
 812 void ClientDisconnect (void)
 813 {
 814         float save;
 815         if(cvar("sv_eventlog"))
 816                 GameLogEcho(strcat(":part:", ftos(self.playerid)), FALSE);
 817         bprint ("^4",self.netname);
 818         bprint ("^4 disconnected\n");
 819
 820         if (self.chatbubbleentity)
 821         {
 822                 remove (self.chatbubbleentity);
 823                 self.chatbubbleentity = world;
 824         }
 825
 826         if (self.teambubbleentity)
 827         {
 828                 remove (self.teambubbleentity);
 829                 self.teambubbleentity = world;
 830         }
 831
 832         WaypointSprite_PlayerGone();
 833
 834         DropAllRunes(self);
 835
 836         if(self.flagcarried)
 837                 DropFlag(self.flagcarried);
 838
 839         DistributeFragsAmongTeam(self, self.team, 1);
 840
 841         save = self.flags;
 842         self.flags = self.flags - (self.flags & FL_CLIENT);
 843         bot_relinkplayerlist();
 844         self.flags = save;
 845
 846         // remove laserdot
 847         if(self.weaponentity)
 848                 if(self.weaponentity.lasertarget)
 849                         remove(self.weaponentity.lasertarget);
 850
 851         if(cvar("g_arena"))
 852         {
 853                 Spawnqueue_Unmark(self);
 854                 Spawnqueue_Remove(self);
 855         }
 856
 857         // free cvars
 858         GetCvars(-1);
 859 }
 860
 861 .float buttonchat;
 862 void() ChatBubbleThink =
 863 {
 864         self.nextthink = time;
 865         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
 866         {
 867                 self.owner.chatbubbleentity = world;
 868                 remove(self);
 869                 return;
 870         }
 871         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
 872         if (self.owner.buttonchat && !self.owner.deadflag)
 873                 self.model = self.mdl;
 874         else
 875                 self.model = "";
 876 };
 877
 878 void() UpdateChatBubble =
 879 {
 880         if (!self.modelindex)
 881                 return;
 882         // spawn a chatbubble entity if needed
 883         if (!self.chatbubbleentity)
 884         {
 885                 self.chatbubbleentity = spawn();
 886                 self.chatbubbleentity.owner = self;
 887                 self.chatbubbleentity.exteriormodeltoclient = self;
 888                 self.chatbubbleentity.think = ChatBubbleThink;
 889                 self.chatbubbleentity.nextthink = time;
 890                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr");
 891                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 892                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
 893                 self.chatbubbleentity.model = "";
 894         }
 895 }
 896
 897
 898 void() TeamBubbleThink =
 899 {
 900         self.nextthink = time;
 901         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
 902         {
 903                 self.owner.teambubbleentity = world;
 904                 remove(self);
 905                 return;
 906         }
 907 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
 908         if (self.owner.buttonchat || self.owner.deadflag)
 909                 self.model = "";
 910         else
 911                 self.model = self.mdl;
 912
 913 };
 914
 915 float() TeamBubble_customizeentityforclient
 916 {
 917         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
 918 }
 919
 920 void() UpdateTeamBubble =
 921 {
 922         if (!self.modelindex || !cvar("teamplay"))
 923                 return;
 924         // spawn a teambubble entity if needed
 925         if (!self.teambubbleentity && cvar("teamplay"))
 926         {
 927                 self.teambubbleentity = spawn();
 928                 self.teambubbleentity.owner = self;
 929                 self.teambubbleentity.exteriormodeltoclient = self;
 930                 self.teambubbleentity.think = TeamBubbleThink;
 931                 self.teambubbleentity.nextthink = time;
 932                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr");
 933 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 934                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
 935                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
 936                 self.teambubbleentity.mdl = self.teambubbleentity.model;
 937                 self.teambubbleentity.model = self.teambubbleentity.mdl;
 938                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
 939         }
 940 }
 941
 942 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
 943 // added to the model skins
 944 /*void() UpdateColorModHack =
 945 {
 946         local float c;
 947         c = self.clientcolors & 15;
 948         // LordHavoc: only bothering to support white, green, red, yellow, blue
 949              if (teamplay == 0) self.colormod = '0 0 0';
 950         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
 951         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
 952         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
 953         else if (c == 12) self.colormod = '1.22 1.22 0.10';
 954         else if (c == 13) self.colormod = '0.10 0.10 1.73';
 955         else self.colormod = '1 1 1';
 956 };*/
 957
 958 void respawn(void)
 959 {
 960         CopyBody(1);
 961         PutClientInServer();
 962 }
 963
 964 void player_powerups (void)
 965 {
 966         if (cvar("g_minstagib"))
 967         {
 968                 self.effects = EF_FULLBRIGHT;
 969                 if (self.items & IT_STRENGTH)
 970                 {
 971                         if (time > self.strength_finished)
 972                         {
 973                                 self.alpha = default_player_alpha;
 974                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 975                                 self.items = self.items - (self.items & IT_STRENGTH);
 976                                 sprint(self, "^3Invisibility has worn off\n");
 977                         }
 978                 }
 979                 else
 980                 {
 981                         if (time < self.strength_finished)
 982                         {
 983                                 self.alpha = cvar("g_minstagib_invis_alpha");
 984                                 self.exteriorweaponentity.alpha = cvar("g_minstagib_invis_alpha");
 985                                 self.items = self.items | IT_STRENGTH;
 986                                 sprint(self, "^3You are invisible\n");
 987                         }
 988                 }
 989
 990                 if (self.items & IT_INVINCIBLE)
 991                 {
 992                         if (time > self.invincible_finished)
 993                         {
 994                                 self.items = self.items - (self.items & IT_INVINCIBLE);
 995                                 sprint(self, "^3Speed has worn off\n");
 996                         }
 997                 }
 998                 else
 999                 {
1000                         if (time < self.invincible_finished)
1001                         {
1002                                 self.items = self.items | IT_INVINCIBLE;
1003                                 sprint(self, "^3You are on speed\n");
1004                         }
1005                 }
1006                 return;
1007         }
1008
1009         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
1010         if (self.items & IT_STRENGTH)
1011         {
1012                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1013                 if (time > self.strength_finished)
1014                 {
1015                         self.items = self.items - (self.items & IT_STRENGTH);
1016                         sprint(self, "^3Strength has worn off\n");
1017                 }
1018         }
1019         else
1020         {
1021                 if (time < self.strength_finished)
1022                 {
1023                         self.items = self.items | IT_STRENGTH;
1024                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1025                 }
1026         }
1027         if (self.items & IT_INVINCIBLE)
1028         {
1029                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1030                 if (time > self.invincible_finished)
1031                 {
1032                         self.items = self.items - (self.items & IT_INVINCIBLE);
1033                         sprint(self, "^3Shield has worn off\n");
1034                 }
1035         }
1036         else
1037         {
1038                 if (time < self.invincible_finished)
1039                 {
1040                         self.items = self.items | IT_INVINCIBLE;
1041                         sprint(self, "^3Shield surrounds you\n");
1042                 }
1043         }
1044
1045         if (cvar("g_fullbrightplayers"))
1046                 self.effects = self.effects | EF_FULLBRIGHT;
1047
1048         // midair gamemode: damage only while in the air
1049         // if in midair mode, being on ground grants temporary invulnerability
1050         // (this is so that multishot weapon don't clear the ground flag on the
1051         // first damage in the frame, leaving the player vulnerable to the
1052         // remaining hits in the same frame)
1053         if (self.flags & FL_ONGROUND)
1054         if (cvar("g_midair"))
1055                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1056
1057         if (time < self.spawnshieldtime)
1058                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1059 }
1060
1061 float CalcRegen(float current, float stable, float maxv, float regenfactor)
1062 {
1063         if(current > stable)
1064                 return current;
1065         else if(current > stable - 0.25) // when close enough, "snap"
1066                 return stable;
1067         else
1068                 return bound(0, current + (stable - current) * regenfactor * frametime, maxv);
1069 }
1070
1071 void player_regen (void)
1072 {
1073         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1074         maxh = cvar("g_balance_health_stable");
1075         maxa = cvar("g_balance_armor_stable");
1076         limith = cvar("g_balance_health_limit");
1077         limita = cvar("g_balance_armor_limit");
1078
1079         if (cvar("g_minstagib") || (cvar("g_lms") && !cvar("g_lms_regenerate")))
1080                 return;
1081
1082         if(cvar("g_runematch"))
1083         {
1084                 max_mod = regen_mod = rot_mod = limit_mod = 1;
1085                 if (self.runes & RUNE_REGEN)
1086                 {
1087                         if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1088                         {
1089                                 regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1090                                 max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1091                                 limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1092                         }
1093                         else
1094                         {
1095                                 regen_mod = cvar("g_balance_rune_regen_regenrate");
1096                                 max_mod = cvar("g_balance_rune_regen_hpmod");
1097                                 limit_mod = cvar("g_balance_rune_regen_limitmod");
1098                         }
1099                 }
1100                 else if (self.runes & CURSE_VENOM)
1101                 {
1102                         max_mod = cvar("g_balance_curse_venom_hpmod");
1103                         if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1104                                 rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1105                         else
1106                                 rot_mod = cvar("g_balance_curse_venom_rotrate");
1107                         limit_mod = cvar("g_balance_curse_venom_limitmod");
1108                         //if (!self.runes & RUNE_REGEN)
1109                         //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1110                 }
1111                 maxh = maxh * max_mod;
1112                 //maxa = maxa * max_mod;
1113
1114                 if (time > self.pauserotarmor_finished)
1115                 {
1116                         if (self.armorvalue > maxa)
1117                                 self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime, 1000);
1118                 }
1119                 if (time > self.pauserothealth_finished)
1120                 {
1121                         if (self.health > maxh)
1122                                 self.health = bound(0, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime, 1000);
1123                 }
1124                 if (time > self.pauseregen_finished)
1125                 {
1126                         self.health = CalcRegen(self.health, maxh, 1000, regen_mod * cvar("g_balance_health_regen"));
1127                         self.armorvalue = CalcRegen(self.armorvalue, maxa, 1000, cvar("g_balance_armor_regen"));
1128                 }
1129         }
1130         else
1131         {
1132                 if (time > self.pauserothealth_finished)
1133                 if (self.health > maxh)
1134                         self.health = bound(0, self.health + (maxh - self.health) * cvar("g_balance_health_rot") * frametime, 1000);
1135                 if (time > self.pauserotarmor_finished)
1136                 if (self.armorvalue > maxa)
1137                         self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime, 1000);
1138                 if (time > self.pauseregen_finished)
1139                 {
1140                         self.health = CalcRegen(self.health, maxh, 1000, cvar("g_balance_health_regen"));
1141                         self.armorvalue = CalcRegen(self.armorvalue, maxa, 1000, cvar("g_balance_armor_regen"));
1142                 }
1143         }
1144
1145         if (self.health > limith)
1146                 self.health = limith;
1147         if(self.health < 1)
1148                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1149         if (self.armorvalue > limita)
1150                 self.armorvalue = limita;
1151 }
1152
1153 /*
1154 ======================
1155 spectate mode routines
1156 ======================
1157 */
1158 void SpectateCopy(entity spectatee) {
1159         self.armortype = spectatee.armortype;
1160         self.armorvalue = spectatee.armorvalue;
1161         self.currentammo = spectatee.currentammo;
1162         self.effects = spectatee.effects;
1163         self.health = spectatee.health;
1164         self.impulse = 0;
1165         self.items = spectatee.items;
1166         self.punchangle = spectatee.punchangle;
1167         self.view_ofs = spectatee.view_ofs;
1168         self.v_angle = spectatee.v_angle;
1169         self.viewzoom = spectatee.viewzoom;
1170         setorigin(self, spectatee.origin);
1171         setsize(self, spectatee.mins, spectatee.maxs);
1172 }
1173
1174 void SpectateUpdate() {
1175         if(!self.enemy)
1176                         PutObserverInServer();
1177
1178         if (self != self.enemy) {
1179                 if(self.enemy.flags & FL_NOTARGET)
1180                         PutObserverInServer();
1181                 SpectateCopy(self.enemy);
1182                 self.dmg_take = self.enemy.dmg_take;
1183                 self.dmg_save = self.enemy.dmg_save;
1184                 self.dmg_inflictor = self.enemy.dmg_inflictor;
1185                 self.fixangle = TRUE;
1186                 self.angles = self.enemy.v_angle;
1187                 //msg_entity = self;
1188                 //WriteByte(MSG_ONE, SVC_SETANGLE);
1189                 //WriteAngle(MSG_ONE, self.enemy.v_angle_x);
1190                 //WriteAngle(MSG_ONE, self.enemy.v_angle_y);
1191                 //WriteAngle(MSG_ONE, self.enemy.v_angle_z);
1192         }
1193 }
1194
1195 float SpectateNext() {
1196         other = find(self.enemy, classname, "player");
1197         if (!other) {
1198                 other = find(other, classname, "player");
1199         }
1200         if (other) {
1201                 self.enemy = other;
1202         }
1203         if(self.enemy.classname == "player") {
1204                 msg_entity = self;
1205                 WriteByte(MSG_ONE, SVC_SETVIEW);
1206                 WriteEntity(MSG_ONE, self.enemy);
1207                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1208                 SpectateUpdate();
1209                 return 1;
1210         } else {
1211                 return 0;
1212         }
1213 }
1214
1215 /*
1216 =============
1217 ShowRespawnCountdown()
1218
1219 Update a respawn countdown display.
1220 =============
1221 */
1222 void ShowRespawnCountdown()
1223 {
1224         float number;
1225         if(self.deadflag == DEAD_NO) // just respawned?
1226                 return;
1227         else
1228         {
1229                 number = ceil(self.death_time - time);
1230                 if(number <= 0)
1231                         return;
1232                 if(number <= self.respawn_countdown)
1233                 {
1234                         self.respawn_countdown = number - 1;
1235                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1236                                 stuffcmd(self, strcat("play2 announcer/robotic/", ftos(number), ".ogg\n"));
1237                 }
1238         }
1239 }
1240
1241 void LeaveSpectatorMode()
1242 {
1243         if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1244                 self.classname = "player";
1245                 if(cvar("g_campaign") || cvar("g_balance_teams"))
1246                         JoinBestTeam(self, 0);
1247                 if(cvar("g_campaign"))
1248                         campaign_bots_may_start = 1;
1249                 PutClientInServer();
1250                 if(!(self.flags & FL_NOTARGET))
1251                         bprint ("^4", self.netname, "^4 is playing now\n");
1252                 centerprint(self,"");
1253                 return;
1254         } else {
1255                 stuffcmd(self,"menu_showteamselect\n");
1256                 return;
1257         }
1258 }
1259
1260 /*
1261 =============
1262 PlayerPreThink
1263
1264 Called every frame for each client before the physics are run
1265 =============
1266 */
1267 void() ctf_setstatus;
1268 .float vote_nagtime;
1269 void PlayerPreThink (void)
1270 {
1271         if(strlen(self.netname) > 0)
1272                 if(substring(self.netname, strlen(self.netname) - 1, 1) == "^")
1273                         self.netname = strzone(strcat(substring(self.netname, 0, strlen(self.netname) - 1), " ")); // BROKEN COLORS can be annoying!
1274
1275         // version nagging
1276         if(self.version_nagtime)
1277                 if(self.cvar_g_nexuizversion)
1278                         if(time > self.version_nagtime)
1279                         {
1280                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
1281                                         if(self.cvar_g_nexuizversion != cvar_string("g_nexuizversion"))
1282                                         {
1283                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "\n");
1284                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "\n"));
1285                                         }
1286                                 self.version_nagtime = 0;
1287                         }
1288
1289         // vote nagging
1290         if(self.cvar_scr_centertime)
1291                 if(time > self.vote_nagtime)
1292                 {
1293                         VoteNag();
1294                         self.vote_nagtime = time + self.cvar_scr_centertime * 0.6;
1295                 }
1296
1297         if(self.classname == "player") {
1298                 local vector m1, m2;
1299
1300 //              if(self.netname == "Wazat")
1301 //                      bprint(self.classname, "\n");
1302
1303                 CheckRules_Player();
1304
1305                 if(self.button7)
1306                         PrintWelcomeMessage(self);
1307
1308                 if(cvar("g_lms") || !cvar("sv_spectate"))
1309                 if((time - self.jointime) <= cvar("welcome_message_time"))
1310                         PrintWelcomeMessage(self);
1311
1312                 if (intermission_running)
1313                 {
1314                         IntermissionThink ();   // otherwise a button could be missed between
1315                         return;                                 // the think tics
1316                 }
1317
1318                 if(time > self.teleport_time)
1319                 {
1320                         self.effects = self.effects - (self.effects & EF_NODRAW);
1321                         if(self.weaponentity)
1322                                 self.weaponentity.flags = self.weaponentity.flags - (self.weaponentity.flags & EF_NODRAW);
1323                 }
1324
1325                 Nixnex_GiveCurrentWeapon();
1326                 UpdateSelectedPlayer();
1327
1328                 if (self.deadflag != DEAD_NO)
1329                 {
1330                         float button_pressed, force_respawn;
1331                         player_anim();
1332                         button_pressed = (self.button0 || self.button2 || self.button3 || self.button6 || self.buttonuse);
1333                         force_respawn = (cvar("g_lms") || cvar("g_forced_respawn"));
1334                         if (self.deadflag == DEAD_DYING)
1335                         {
1336                                 if(force_respawn)
1337                                         self.deadflag = DEAD_RESPAWNING;
1338                                 else if(!button_pressed)
1339                                         self.deadflag = DEAD_DEAD;
1340                         }
1341                         else if (self.deadflag == DEAD_DEAD)
1342                         {
1343                                 if(button_pressed)
1344                                         self.deadflag = DEAD_RESPAWNABLE;
1345                         }
1346                         else if (self.deadflag == DEAD_RESPAWNABLE)
1347                         {
1348                                 if(!button_pressed)
1349                                         self.deadflag = DEAD_RESPAWNING;
1350                         }
1351                         else if (self.deadflag == DEAD_RESPAWNING)
1352                         {
1353                                 if(time > self.death_time)
1354                                         respawn();
1355                         }
1356                         ShowRespawnCountdown();
1357                         return;
1358                 }
1359
1360                 if(cvar("g_lms") && !self.deadflag && cvar("g_lms_campcheck_interval"))
1361                 {
1362                         vector dist;
1363
1364                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
1365                         dist = self.oldorigin - self.origin;
1366                         dist_z = 0;
1367                         self.lms_traveled_distance += fabs(vlen(dist));
1368
1369                         if(cvar("g_campaign"))
1370                         if(!campaign_bots_may_start)
1371                         {
1372                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
1373                                 self.lms_traveled_distance = 0;
1374                         }
1375
1376                         if(time > self.lms_nextcheck)
1377                         {
1378                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
1379                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
1380                                 {
1381                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
1382                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
1383                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
1384                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
1385                                 }
1386                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
1387                                 self.lms_traveled_distance = 0;
1388                         }
1389                 }
1390
1391                 if (self.button5 && !self.hook.state)
1392                 {
1393                         if (!self.crouch)
1394                         {
1395                                 self.crouch = TRUE;
1396                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
1397                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
1398                         }
1399                 }
1400                 else
1401                 {
1402                         if (self.crouch)
1403                         {
1404                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
1405                                 if (!trace_startsolid)
1406                                 {
1407                                         self.crouch = FALSE;
1408                                         self.view_ofs = PL_VIEW_OFS;
1409                                         setsize (self, PL_MIN, PL_MAX);
1410                                 }
1411                         }
1412                 }
1413
1414                 if(cvar("sv_defaultcharacter") == 1 && !teams_matter) {
1415                         local string defaultmodel;
1416                         defaultmodel = CheckPlayerModel(cvar_string("sv_defaultplayermodel"));
1417
1418                         if (defaultmodel != self.model)
1419                         {
1420                                 m1 = self.mins;
1421                                 m2 = self.maxs;
1422                                 setmodel_lod (self, defaultmodel);
1423                                 setsize (self, m1, m2);
1424                         }
1425
1426                         if (self.skin != cvar("sv_defaultplayerskin"))
1427                                 self.skin = cvar("sv_defaultplayerskin");
1428                 } else {
1429                         if (self.playermodel != self.model)
1430                         {
1431                                 self.playermodel = CheckPlayerModel(self.playermodel);
1432                                 m1 = self.mins;
1433                                 m2 = self.maxs;
1434                                 setmodel_lod (self, self.playermodel);
1435                                 setsize (self, m1, m2);
1436                         }
1437
1438                         if(teams_matter)
1439                         {
1440                                 if (self.skin != math_mod(stof(self.playerskin), NUM_PLAYERSKINS_TEAMPLAY))
1441                                         self.skin = math_mod(stof(self.playerskin), NUM_PLAYERSKINS_TEAMPLAY);
1442                         }
1443                         else
1444                         {
1445                                 if (self.skin != stof(self.playerskin))
1446                                         self.skin = stof(self.playerskin);
1447                         }
1448                 }
1449
1450                 GrapplingHookFrame();
1451
1452                 W_WeaponFrame();
1453
1454                 if (cvar("g_minstagib"))
1455                         if(self.button3)
1456                                 if (self.jump_interval <= (time + 0.1))
1457                                 {
1458                                         self.jump_interval = time + 1;
1459                                         W_Laser_Attack();
1460                                 }
1461
1462                 {
1463                         float zoomfactor, zoomspeed, zoomdir;
1464                         zoomfactor = self.cvar_cl_zoomfactor;
1465                         if(zoomfactor < 1 || zoomfactor > 16)
1466                                 zoomfactor = 2.5;
1467                         zoomspeed = self.cvar_cl_zoomspeed;
1468                         if(zoomspeed >= 0) // < 0 is instant zoom
1469                                 if(zoomspeed < 0.5 || zoomspeed > 16)
1470                                         zoomspeed = 3.5;
1471
1472                         zoomdir = self.button4;
1473                         if(self.button3)
1474                                 if(self.weapon == WEP_NEX)
1475                                         if(!cvar("g_minstagib"))
1476                                                 zoomdir = 1;
1477
1478                         if(zoomdir)
1479                                 self.has_zoomed = 1;
1480
1481                         if(self.has_zoomed)
1482                         {
1483                                 if(zoomspeed <= 0) // instant zoom
1484                                 {
1485                                         if(zoomdir)
1486                                                 self.viewzoom = 1 / zoomfactor;
1487                                         else
1488                                                 self.viewzoom = 1;
1489                                 }
1490                                 else
1491                                 {
1492                                         // geometric zoom would be:
1493                                         //   self.viewzoom = bound(1 / zoomfactor, self.viewzoom * pow(zoomfactor, (zoomdir ? -1 : 1) * frametime * zoomspeed), 1);
1494                                         // however, testing showed that arithmetic/harmonic zoom works better
1495                                         if(zoomdir)
1496                                                 // self.viewzoom = 1 / bound(1, 1 / self.viewzoom + (zoomdir ? 1 : -1) * frametime * zoomspeed * (zoomfactor - 1), zoomfactor);
1497                                                 // zoom in = arithmetic: 1x, 2x, 3x, 4x, ..., 8x
1498                                                 self.viewzoom = 1 / bound(1, 1 / self.viewzoom + frametime * zoomspeed * (zoomfactor - 1), zoomfactor);
1499                                         else
1500                                                 // self.viewzoom = bound(1 / zoomfactor, self.viewzoom + (zoomdir ? -1 : 1) * frametime * zoomspeed * (1 - 1 / zoomfactor), 1);
1501                                                 // zoom out = harmonic: 8/1x, 8/2x, 8/3x, 8/4x, ..., 8/8x
1502                                                 self.viewzoom = bound(1 / zoomfactor, self.viewzoom + frametime * zoomspeed * (1 - 1 / zoomfactor), 1);
1503                                 }
1504                         }
1505                         else
1506                                 self.viewzoom = min(1, self.viewzoom + frametime); // spawn zoom-in
1507                 }
1508
1509                 player_powerups();
1510                 player_regen();
1511                 player_anim();
1512
1513                 if (cvar("g_minstagib"))
1514                         minstagib_ammocheck();
1515
1516                 ctf_setstatus();
1517
1518                 //self.angles_y=self.v_angle_y + 90;   // temp
1519
1520                 //if (TetrisPreFrame()) return;
1521         } else if(gameover) {
1522                 if (intermission_running)
1523                         IntermissionThink ();   // otherwise a button could be missed between
1524                 return;
1525         } else if(self.classname == "observer") {
1526
1527                 if (self.flags & FL_JUMPRELEASED) {
1528                         if (self.button2 && self.version == cvar("gameversion")) {
1529                                 self.welcomemessage_time = 0;
1530                                 self.flags = self.flags - FL_JUMPRELEASED;
1531                                 LeaveSpectatorMode();
1532                                 return;
1533                         } else if(self.button0 && self.version == cvar("gameversion")) {
1534                                 self.welcomemessage_time = 0;
1535                                 self.flags = self.flags - FL_JUMPRELEASED;
1536                                 if(SpectateNext() == 1) {
1537                                         self.classname = "spectator";
1538                                 }
1539                         }
1540                 } else {
1541                         if (!(self.button0 || self.button2)) {
1542                                 self.flags = self.flags | FL_JUMPRELEASED;
1543                         }
1544                 }
1545                 PrintWelcomeMessage(self);
1546         } else if(self.classname == "spectator") {
1547                 if (self.flags & FL_JUMPRELEASED) {
1548                         if (self.button2 && self.version == cvar("gameversion")) {
1549                                 self.welcomemessage_time = 0;
1550                                 self.flags = self.flags - FL_JUMPRELEASED;
1551                                 LeaveSpectatorMode();
1552                                 return;
1553                         } else if(self.button0) {
1554                                 self.welcomemessage_time = 0;
1555                                 self.flags = self.flags - FL_JUMPRELEASED;
1556                                 if(SpectateNext() == 1) {
1557                                         self.classname = "spectator";
1558                                 } else {
1559                                         self.classname = "observer";
1560                                         PutClientInServer();
1561                                 }
1562                         } else if (self.button3) {
1563                                 self.welcomemessage_time = 0;
1564                                 self.flags = self.flags - FL_JUMPRELEASED;
1565                                 self.classname = "observer";
1566                                 PutClientInServer();
1567                         } else {
1568                                 SpectateUpdate();
1569                         }
1570                 } else {
1571                         if (!(self.button0 || self.button3)) {
1572                                 self.flags = self.flags | FL_JUMPRELEASED;
1573                         }
1574                 }
1575                 PrintWelcomeMessage(self);
1576                 self.flags = self.flags | FL_CLIENT | FL_NOTARGET;
1577         }
1578 }
1579
1580
1581 /*
1582 =============
1583 PlayerPostThink
1584
1585 Called every frame for each client after the physics are run
1586 =============
1587 */
1588 void PlayerPostThink (void)
1589 {
1590         // Savage: Check for nameless players
1591         if (strlen(self.netname) < 1) {
1592                 self.netname = "Player";
1593                 stuffcmd(self, "seta _cl_name Player\n");
1594         }
1595
1596         if(self.classname == "player") {
1597                 CheckRules_Player();
1598                 UpdateChatBubble();
1599                 UpdateTeamBubble();
1600                 if (self.impulse)
1601                         ImpulseCommands ();
1602                 if (intermission_running)
1603                         return;         // intermission or finale
1604
1605                 //PrintWelcomeMessage(self);
1606                 //if (TetrisPostFrame()) return;
1607         } else if (self.classname == "observer") {
1608                 //do nothing
1609         } else if (self.classname == "spectator") {
1610                 //do nothing
1611         }
1612         Arena_Warmup();
1613 }